New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynadv_cen2.F90 in NEMO/branches/2021/dev_r14116_HPC-10_mcastril_Mixed_Precision_implementation/src/OCE/DYN – NEMO

source: NEMO/branches/2021/dev_r14116_HPC-10_mcastril_Mixed_Precision_implementation/src/OCE/DYN/dynadv_cen2.F90 @ 15540

Last change on this file since 15540 was 15540, checked in by sparonuz, 3 years ago

Mixed precision version, tested up to 30 years on ORCA2.
  • Property svn:keywords set to Id
File size: 7.7 KB
Line 
1MODULE dynadv_cen2
2   !!======================================================================
3   !!                       ***  MODULE  dynadv  ***
4   !! Ocean dynamics: Update the momentum trend with the flux form advection
5   !!                 using a 2nd order centred scheme
6   !!======================================================================
7   !! History :  2.0  ! 2006-08  (G. Madec, S. Theetten)  Original code
8   !!            3.2  ! 2009-07  (R. Benshila)  Suppression of rigid-lid option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   dyn_adv_cen2  : flux form momentum advection (ln_dynadv_cen2=T) using a 2nd order centred scheme 
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers
15   USE dom_oce        ! ocean space and time domain
16   USE trd_oce        ! trends: ocean variables
17   USE trddyn         ! trend manager: dynamics
18   !
19   USE in_out_manager ! I/O manager
20   USE lib_mpp        ! MPP library
21   USE prtctl         ! Print control
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   dyn_adv_cen2   ! routine called by step.F90
27
28   !! * Substitutions
29#  include "do_loop_substitute.h90"
30#  include "domzgr_substitute.h90"
31#  include "single_precision_substitute.h90"
32   !!----------------------------------------------------------------------
33   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
34   !! $Id$
35   !! Software governed by the CeCILL license (see ./LICENSE)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   SUBROUTINE dyn_adv_cen2( kt, Kmm, puu, pvv, Krhs )
40      !!----------------------------------------------------------------------
41      !!                  ***  ROUTINE dyn_adv_cen2  ***
42      !!
43      !! ** Purpose :   Compute the now momentum advection trend in flux form
44      !!              and the general trend of the momentum equation.
45      !!
46      !! ** Method  :   Trend evaluated using now fields (centered in time)
47      !!
48      !! ** Action  :   (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) updated with the now vorticity term trend
49      !!----------------------------------------------------------------------
50      INTEGER                             , INTENT( in )  ::  kt           ! ocean time-step index
51      INTEGER                             , INTENT( in )  ::  Kmm, Krhs    ! ocean time level indices
52      REAL(dp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv     ! ocean velocities and RHS of momentum equation
53      !
54      INTEGER  ::   ji, jj, jk   ! dummy loop indices
55      REAL(dp), DIMENSION(A2D(nn_hls),jpk) :: zfu_t, zfu_uw
56      REAL(dp), DIMENSION(A2D(nn_hls),jpk) :: zfu_f, zfu
57      REAL(dp), DIMENSION(A2D(nn_hls),jpk) :: zfv_t, zfv_vw
58      REAL(dp), DIMENSION(A2D(nn_hls),jpk) :: zfv_f, zfv, zfw
59      !!----------------------------------------------------------------------
60      !
61      IF( .NOT. l_istiled .OR. ntile == 1 )  THEN                       ! Do only on the first tile
62         IF( kt == nit000 .AND. lwp ) THEN
63            WRITE(numout,*)
64            WRITE(numout,*) 'dyn_adv_cen2 : 2nd order flux form momentum advection'
65            WRITE(numout,*) '~~~~~~~~~~~~'
66         ENDIF
67      ENDIF
68      !
69      IF( l_trddyn ) THEN           ! trends: store the input trends
70         zfu_uw(:,:,:) = puu(:,:,:,Krhs)
71         zfv_vw(:,:,:) = pvv(:,:,:,Krhs)
72      ENDIF
73      !
74      !                             !==  Horizontal advection  ==!
75      !
76      DO jk = 1, jpkm1                    ! horizontal transport
77         DO_2D( 1, 1, 1, 1 )
78            zfu(ji,jj,jk) = 0.25_wp * e2u(ji,jj) * e3u(ji,jj,jk,Kmm) * puu(ji,jj,jk,Kmm)
79            zfv(ji,jj,jk) = 0.25_wp * e1v(ji,jj) * e3v(ji,jj,jk,Kmm) * pvv(ji,jj,jk,Kmm)
80         END_2D
81         DO_2D( 1, 0, 1, 0 )              ! horizontal momentum fluxes (at T- and F-point)
82            zfu_t(ji+1,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji+1,jj,jk) ) * ( puu(ji,jj,jk,Kmm) + puu(ji+1,jj  ,jk,Kmm) )
83            zfv_f(ji  ,jj  ,jk) = ( zfv(ji,jj,jk) + zfv(ji+1,jj,jk) ) * ( puu(ji,jj,jk,Kmm) + puu(ji  ,jj+1,jk,Kmm) )
84            zfu_f(ji  ,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji,jj+1,jk) ) * ( pvv(ji,jj,jk,Kmm) + pvv(ji+1,jj  ,jk,Kmm) )
85            zfv_t(ji  ,jj+1,jk) = ( zfv(ji,jj,jk) + zfv(ji,jj+1,jk) ) * ( pvv(ji,jj,jk,Kmm) + pvv(ji  ,jj+1,jk,Kmm) )
86         END_2D
87         DO_2D( 0, 0, 0, 0 )              ! divergence of horizontal momentum fluxes
88            puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) - (  zfu_t(ji+1,jj,jk) - zfu_t(ji,jj  ,jk)    &
89               &                           + zfv_f(ji  ,jj,jk) - zfv_f(ji,jj-1,jk)  ) * r1_e1e2u(ji,jj)   &
90               &                           / e3u(ji,jj,jk,Kmm)
91            pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) - (  zfu_f(ji,jj  ,jk) - zfu_f(ji-1,jj,jk)    &
92               &                           + zfv_t(ji,jj+1,jk) - zfv_t(ji  ,jj,jk)  ) * r1_e1e2v(ji,jj)   &
93               &                           / e3v(ji,jj,jk,Kmm)
94         END_2D
95      END DO
96      !
97      IF( l_trddyn ) THEN           ! trends: send trend to trddyn for diagnostic
98         zfu_uw(:,:,:) = puu(:,:,:,Krhs) - zfu_uw(:,:,:)
99         zfv_vw(:,:,:) = pvv(:,:,:,Krhs) - zfv_vw(:,:,:)
100         CALL trd_dyn( zfu_uw, zfv_vw, jpdyn_keg, kt, Kmm )
101         zfu_t(:,:,:) = puu(:,:,:,Krhs)
102         zfv_t(:,:,:) = pvv(:,:,:,Krhs)
103      ENDIF
104      !
105      !                             !==  Vertical advection  ==!
106      !
107      DO_2D( 0, 0, 0, 0 )                 ! surface/bottom advective fluxes set to zero
108         zfu_uw(ji,jj,jpk) = 0._wp   ;   zfv_vw(ji,jj,jpk) = 0._wp
109         zfu_uw(ji,jj, 1 ) = 0._wp   ;   zfv_vw(ji,jj, 1 ) = 0._wp
110      END_2D
111      IF( ln_linssh ) THEN                ! linear free surface: advection through the surface
112         DO_2D( 0, 0, 0, 0 )
113            zfu_uw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * ww(ji,jj,1) + e1e2t(ji+1,jj) * ww(ji+1,jj,1) ) * puu(ji,jj,1,Kmm)
114            zfv_vw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * ww(ji,jj,1) + e1e2t(ji,jj+1) * ww(ji,jj+1,1) ) * pvv(ji,jj,1,Kmm)
115         END_2D
116      ENDIF
117      DO jk = 2, jpkm1                    ! interior advective fluxes
118         DO_2D( 0, 1, 0, 1 )                  ! 1/4 * Vertical transport
119            zfw(ji,jj,jk) = 0.25_wp * e1e2t(ji,jj) * ww(ji,jj,jk)
120         END_2D
121         DO_2D( 0, 0, 0, 0 )
122            zfu_uw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji+1,jj  ,jk) ) * ( puu(ji,jj,jk,Kmm) + puu(ji,jj,jk-1,Kmm) )
123            zfv_vw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji  ,jj+1,jk) ) * ( pvv(ji,jj,jk,Kmm) + pvv(ji,jj,jk-1,Kmm) )
124         END_2D
125      END DO
126      DO_3D( 0, 0, 0, 0, 1, jpkm1 )       ! divergence of vertical momentum flux divergence
127         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) - ( zfu_uw(ji,jj,jk) - zfu_uw(ji,jj,jk+1) ) * r1_e1e2u(ji,jj)   &
128            &                                      / e3u(ji,jj,jk,Kmm)
129         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) - ( zfv_vw(ji,jj,jk) - zfv_vw(ji,jj,jk+1) ) * r1_e1e2v(ji,jj)   &
130            &                                      / e3v(ji,jj,jk,Kmm)
131      END_3D
132      !
133      IF( l_trddyn ) THEN                 ! trends: send trend to trddyn for diagnostic
134         zfu_t(:,:,:) = puu(:,:,:,Krhs) - zfu_t(:,:,:)
135         zfv_t(:,:,:) = pvv(:,:,:,Krhs) - zfv_t(:,:,:)
136         CALL trd_dyn( zfu_t, zfv_t, jpdyn_zad, kt, Kmm )
137      ENDIF
138      !                                   ! Control print
139      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' cen2 adv - Ua: ', mask1=umask,   &
140         &                                  tab3d_2=pvv(:,:,:,Krhs), clinfo2=           ' Va: ', mask2=vmask, clinfo3='dyn' )
141      !
142   END SUBROUTINE dyn_adv_cen2
143
144   !!==============================================================================
145END MODULE dynadv_cen2
Note: See TracBrowser for help on using the repository browser.