Context Navigation

dynhpg.F90 @ 15540

Last change on this file since 15540 was 15540, checked in by sparonuz, 3 years ago
Mixed precision version, tested up to 30 years on ORCA2.
Property svn:keywords set to `Id`
File size: 76.0 KB

Line
1	MODULE dynhpg
2	!!======================================================================
3	!! * MODULE dynhpg *
4	!! Ocean dynamics: hydrostatic pressure gradient trend
5	!!======================================================================
6	!! History : OPA ! 1987-09 (P. Andrich, M.-A. Foujols) hpg_zco: Original code
7	!! 5.0 ! 1991-11 (G. Madec)
8	!! 7.0 ! 1996-01 (G. Madec) hpg_sco: Original code for s-coordinates
9	!! 8.0 ! 1997-05 (G. Madec) split dynber into dynkeg and dynhpg
10	!! 8.5 ! 2002-07 (G. Madec) F90: Free form and module
11	!! 8.5 ! 2002-08 (A. Bozec) hpg_zps: Original code
12	!! NEMO 1.0 ! 2005-10 (A. Beckmann, B.W. An) various s-coordinate options
13	!! ! Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14	!! - ! 2005-11 (G. Madec) style & small optimisation
15	!! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
16	!! 3.4 ! 2011-11 (H. Liu) hpg_prj: Original code for s-coordinates
17	!! ! (A. Coward) suppression of hel, wdj and rot options
18	!! 3.6 ! 2014-11 (P. Mathiot) hpg_isf: original code for ice shelf cavity
19	!! 4.2 ! 2020-12 (M. Bell, A. Young) hpg_djc: revised djc scheme
20	!!----------------------------------------------------------------------
21
22	!!----------------------------------------------------------------------
23	!! dyn_hpg : update the momentum trend with the now horizontal
24	!! gradient of the hydrostatic pressure
25	!! dyn_hpg_init : initialisation and control of options
26	!! hpg_zco : z-coordinate scheme
27	!! hpg_zps : z-coordinate plus partial steps (interpolation)
28	!! hpg_sco : s-coordinate (standard jacobian formulation)
29	!! hpg_isf : s-coordinate (sco formulation) adapted to ice shelf
30	!! hpg_djc : s-coordinate (Density Jacobian with Cubic polynomial)
31	!! hpg_prj : s-coordinate (Pressure Jacobian with Cubic polynomial)
32	!!----------------------------------------------------------------------
33	USE oce ! ocean dynamics and tracers
34	USE isf_oce , ONLY : risfload ! ice shelf (risfload variable)
35	USE isfload , ONLY : isf_load ! ice shelf (isf_load routine )
36	USE sbc_oce ! surface variable (only for the flag with ice shelf)
37	USE dom_oce ! ocean space and time domain
38	USE wet_dry ! wetting and drying
39	USE phycst ! physical constants
40	USE trd_oce ! trends: ocean variables
41	USE trddyn ! trend manager: dynamics
42	USE zpshde ! partial step: hor. derivative (zps_hde routine)
43	!
44	USE in_out_manager ! I/O manager
45	USE prtctl ! Print control
46	USE lbclnk ! lateral boundary condition
47	USE lib_mpp ! MPP library
48	USE eosbn2 ! compute density
49	USE timing ! Timing
50	USE iom
51
52	IMPLICIT NONE
53	PRIVATE
54
55	PUBLIC dyn_hpg ! routine called by step module
56	PUBLIC dyn_hpg_init ! routine called by opa module
57
58	! !!* Namelist namdyn_hpg : hydrostatic pressure gradient
59	LOGICAL, PUBLIC :: ln_hpg_zco !: z-coordinate - full steps
60	LOGICAL, PUBLIC :: ln_hpg_zps !: z-coordinate - partial steps (interpolation)
61	LOGICAL, PUBLIC :: ln_hpg_sco !: s-coordinate (standard jacobian formulation)
62	LOGICAL, PUBLIC :: ln_hpg_djc !: s-coordinate (Density Jacobian with Cubic polynomial)
63	LOGICAL, PUBLIC :: ln_hpg_prj !: s-coordinate (Pressure Jacobian scheme)
64	LOGICAL, PUBLIC :: ln_hpg_isf !: s-coordinate similar to sco modify for isf
65
66	! !! Flag to control the type of hydrostatic pressure gradient
67	INTEGER, PARAMETER :: np_ERROR =-10 ! error in specification of lateral diffusion
68	INTEGER, PARAMETER :: np_zco = 0 ! z-coordinate - full steps
69	INTEGER, PARAMETER :: np_zps = 1 ! z-coordinate - partial steps (interpolation)
70	INTEGER, PARAMETER :: np_sco = 2 ! s-coordinate (standard jacobian formulation)
71	INTEGER, PARAMETER :: np_djc = 3 ! s-coordinate (Density Jacobian with Cubic polynomial)
72	INTEGER, PARAMETER :: np_prj = 4 ! s-coordinate (Pressure Jacobian scheme)
73	INTEGER, PARAMETER :: np_isf = 5 ! s-coordinate similar to sco modify for isf
74	!
75	INTEGER, PUBLIC :: nhpg !: type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
76	!
77	LOGICAL :: ln_hpg_djc_vnh, ln_hpg_djc_vnv ! flag to specify hpg_djc boundary condition type
78	REAL(dp), PUBLIC :: aco_bc_hor, bco_bc_hor, aco_bc_vrt, bco_bc_vrt !: coefficients for hpg_djc hor and vert boundary conditions
79
80	!! * Substitutions
81	# include "do_loop_substitute.h90"
82	# include "domzgr_substitute.h90"
83	# include "single_precision_substitute.h90"
84
85	!!----------------------------------------------------------------------
86	!! NEMO/OCE 4.0 , NEMO Consortium (2018)
87	!! $Id$
88	!! Software governed by the CeCILL license (see ./LICENSE)
89	!!----------------------------------------------------------------------
90	CONTAINS
91
92	SUBROUTINE dyn_hpg( kt, Kmm, puu, pvv, Krhs )
93	!!---------------------------------------------------------------------
94	!! * ROUTINE dyn_hpg *
95	!!
96	!! ** Method : Call the hydrostatic pressure gradient routine
97	!! using the scheme defined in the namelist
98	!!
99	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
100	!! - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
101	!!----------------------------------------------------------------------
102	INTEGER , INTENT( in ) :: kt ! ocean time-step index
103	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
104	REAL(dp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
105	!
106	REAL(dp), ALLOCATABLE, DIMENSION(:,:,:) :: ztrdu, ztrdv
107	!!----------------------------------------------------------------------
108	!
109	IF( ln_timing ) CALL timing_start('dyn_hpg')
110	!
111	IF( l_trddyn ) THEN ! Temporary saving of puu(:,:,:,Krhs) and pvv(:,:,:,Krhs) trends (l_trddyn)
112	ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
113	ztrdu(:,:,:) = puu(:,:,:,Krhs)
114	ztrdv(:,:,:) = pvv(:,:,:,Krhs)
115	ENDIF
116	!
117	SELECT CASE ( nhpg ) ! Hydrostatic pressure gradient computation
118	CASE ( np_zco ) ; CALL hpg_zco ( kt, Kmm, puu, pvv, Krhs ) ! z-coordinate
119	CASE ( np_zps ) ; CALL hpg_zps ( kt, Kmm, puu, pvv, Krhs ) ! z-coordinate plus partial steps (interpolation)
120	CASE ( np_sco ) ; CALL hpg_sco ( kt, Kmm, puu, pvv, Krhs ) ! s-coordinate (standard jacobian formulation)
121	CASE ( np_djc ) ; CALL hpg_djc ( kt, Kmm, puu, pvv, Krhs ) ! s-coordinate (Density Jacobian with Cubic polynomial)
122	CASE ( np_prj ) ; CALL hpg_prj ( kt, Kmm, puu, pvv, Krhs ) ! s-coordinate (Pressure Jacobian scheme)
123	CASE ( np_isf ) ; CALL hpg_isf ( kt, Kmm, puu, pvv, Krhs ) ! s-coordinate similar to sco modify for ice shelf
124	END SELECT
125	!
126	IF( l_trddyn ) THEN ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
127	ztrdu(:,:,:) = puu(:,:,:,Krhs) - ztrdu(:,:,:)
128	ztrdv(:,:,:) = pvv(:,:,:,Krhs) - ztrdv(:,:,:)
129	CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt, Kmm )
130	DEALLOCATE( ztrdu , ztrdv )
131	ENDIF
132	!
133	IF(sn_cfctl%l_prtctl) CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' hpg - Ua: ', mask1=umask, &
134	& tab3d_2=pvv(:,:,:,Krhs), clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' )
135	!
136	IF( ln_timing ) CALL timing_stop('dyn_hpg')
137	!
138	END SUBROUTINE dyn_hpg
139
140
141	SUBROUTINE dyn_hpg_init( Kmm )
142	!!----------------------------------------------------------------------
143	!! * ROUTINE dyn_hpg_init *
144	!!
145	!! ** Purpose : initializations for the hydrostatic pressure gradient
146	!! computation and consistency control
147	!!
148	!! ** Action : Read the namelist namdyn_hpg and check the consistency
149	!! with the type of vertical coordinate used (zco, zps, sco)
150	!!----------------------------------------------------------------------
151	INTEGER, INTENT( in ) :: Kmm ! ocean time level index
152	!
153	INTEGER :: ioptio = 0 ! temporary integer
154	INTEGER :: ios ! Local integer output status for namelist read
155	!!
156	INTEGER :: ji, jj, jk, ikt ! dummy loop indices ISF
157	REAL(dp), ALLOCATABLE, DIMENSION(:,:,:) :: zts_top, zrhd ! hypothesys on isf density
158	REAL(dp), ALLOCATABLE, DIMENSION(:,:) :: zrhdtop_isf ! density at bottom of ISF
159	REAL(dp), ALLOCATABLE, DIMENSION(:,:) :: ziceload ! density at bottom of ISF
160	!!
161	NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco, &
162	& ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, &
163	& ln_hpg_djc_vnh, ln_hpg_djc_vnv
164	!!----------------------------------------------------------------------
165	!
166	READ ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
167	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist' )
168	!
169	READ ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
170	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist' )
171	IF(lwm) WRITE ( numond, namdyn_hpg )
172	!
173	IF(lwp) THEN ! Control print
174	WRITE(numout,*)
175	WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
176	WRITE(numout,*) '~~~~~~~~~~~~'
177	WRITE(numout,*) ' Namelist namdyn_hpg : choice of hpg scheme'
178	WRITE(numout,*) ' z-coord. - full steps ln_hpg_zco = ', ln_hpg_zco
179	WRITE(numout,*) ' z-coord. - partial steps (interpolation) ln_hpg_zps = ', ln_hpg_zps
180	WRITE(numout,*) ' s-coord. (standard jacobian formulation) ln_hpg_sco = ', ln_hpg_sco
181	WRITE(numout,*) ' s-coord. (standard jacobian formulation) for isf ln_hpg_isf = ', ln_hpg_isf
182	WRITE(numout,*) ' s-coord. (Density Jacobian: Cubic polynomial) ln_hpg_djc = ', ln_hpg_djc
183	WRITE(numout,*) ' s-coord. (Pressure Jacobian: Cubic polynomial) ln_hpg_prj = ', ln_hpg_prj
184	ENDIF
185	!
186	IF( .NOT.ln_linssh .AND. (ln_hpg_zco.OR.ln_hpg_zps) ) &
187	& CALL ctl_stop( 'dyn_hpg_init : non-linear free surface incompatible with hpg_zco or hpg_zps' )
188	!
189	IF( (.NOT.ln_hpg_isf .AND. ln_isfcav) .OR. (ln_hpg_isf .AND. .NOT.ln_isfcav) ) &
190	& CALL ctl_stop( 'dyn_hpg_init : ln_hpg_isf=T requires ln_isfcav=T and vice versa' )
191	!
192	#if defined key_qco
193	IF( ln_hpg_isf ) THEN
194	CALL ctl_stop( 'dyn_hpg_init : key_qco and ln_hpg_isf not yet compatible' )
195	ENDIF
196	#endif
197	!
198	! ! Set nhpg from ln_hpg_... flags & consistency check
199	nhpg = np_ERROR
200	ioptio = 0
201	IF( ln_hpg_zco ) THEN ; nhpg = np_zco ; ioptio = ioptio +1 ; ENDIF
202	IF( ln_hpg_zps ) THEN ; nhpg = np_zps ; ioptio = ioptio +1 ; ENDIF
203	IF( ln_hpg_sco ) THEN ; nhpg = np_sco ; ioptio = ioptio +1 ; ENDIF
204	IF( ln_hpg_djc ) THEN ; nhpg = np_djc ; ioptio = ioptio +1 ; ENDIF
205	IF( ln_hpg_prj ) THEN ; nhpg = np_prj ; ioptio = ioptio +1 ; ENDIF
206	IF( ln_hpg_isf ) THEN ; nhpg = np_isf ; ioptio = ioptio +1 ; ENDIF
207	!
208	IF( ioptio /= 1 ) CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
209	!
210	IF(lwp) THEN
211	WRITE(numout,*)
212	SELECT CASE( nhpg )
213	CASE( np_zco ) ; WRITE(numout,*) ' ==>>> z-coord. - full steps '
214	CASE( np_zps ) ; WRITE(numout,*) ' ==>>> z-coord. - partial steps (interpolation)'
215	CASE( np_sco ) ; WRITE(numout,*) ' ==>>> s-coord. (standard jacobian formulation)'
216	CASE( np_djc ) ; WRITE(numout,*) ' ==>>> s-coord. (Density Jacobian: Cubic polynomial)'
217	CASE( np_prj ) ; WRITE(numout,*) ' ==>>> s-coord. (Pressure Jacobian: Cubic polynomial)'
218	CASE( np_isf ) ; WRITE(numout,*) ' ==>>> s-coord. (standard jacobian formulation) for isf'
219	END SELECT
220	WRITE(numout,*)
221	ENDIF
222	!
223	IF ( ln_hpg_djc ) THEN
224	IF (ln_hpg_djc_vnh) THEN ! Von Neumann boundary condition
225	IF(lwp) WRITE(numout,*) ' horizontal bc: von Neumann '
226	aco_bc_hor = 6.0_wp/5.0_wp
227	bco_bc_hor = 7.0_wp/15.0_wp
228	ELSE ! Linear extrapolation
229	IF(lwp) WRITE(numout,*) ' horizontal bc: linear extrapolation'
230	aco_bc_hor = 3.0_wp/2.0_wp
231	bco_bc_hor = 1.0_wp/2.0_wp
232	END IF
233	IF (ln_hpg_djc_vnv) THEN ! Von Neumann boundary condition
234	IF(lwp) WRITE(numout,*) ' vertical bc: von Neumann '
235	aco_bc_vrt = 6.0_wp/5.0_wp
236	bco_bc_vrt = 7.0_wp/15.0_wp
237	ELSE ! Linear extrapolation
238	IF(lwp) WRITE(numout,*) ' vertical bc: linear extrapolation'
239	aco_bc_vrt = 3.0_wp/2.0_wp
240	bco_bc_vrt = 1.0_wp/2.0_wp
241	END IF
242	END IF
243	!
244	END SUBROUTINE dyn_hpg_init
245
246
247	SUBROUTINE hpg_zco( kt, Kmm, puu, pvv, Krhs )
248	!!---------------------------------------------------------------------
249	!! * ROUTINE hpg_zco *
250	!!
251	!! ** Method : z-coordinate case, levels are horizontal surfaces.
252	!! The now hydrostatic pressure gradient at a given level, jk,
253	!! is computed by taking the vertical integral of the in-situ
254	!! density gradient along the model level from the suface to that
255	!! level: zhpi = grav .....
256	!! zhpj = grav .....
257	!! add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
258	!! puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
259	!! pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
260	!!
261	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
262	!!----------------------------------------------------------------------
263	INTEGER , INTENT( in ) :: kt ! ocean time-step index
264	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
265	REAL(dp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
266	!
267	INTEGER :: ji, jj, jk ! dummy loop indices
268	REAL(dp) :: zcoef0, zcoef1 ! temporary scalars
269	REAL(dp), DIMENSION(A2D(nn_hls)) :: zhpi, zhpj
270	!!----------------------------------------------------------------------
271	!
272	IF( .NOT. l_istiled .OR. ntile == 1 ) THEN ! Do only on the first tile
273	IF( kt == nit000 ) THEN
274	IF(lwp) WRITE(numout,*)
275	IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
276	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate case '
277	ENDIF
278	ENDIF
279	!
280	zcoef0 = - grav * 0.5_wp ! Local constant initialization
281	!
282	DO_2D( 0, 0, 0, 0 ) ! Surface value
283	zcoef1 = zcoef0 * e3w(ji,jj,1,Kmm)
284	! ! hydrostatic pressure gradient
285	zhpi(ji,jj) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
286	zhpj(ji,jj) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
287	! ! add to the general momentum trend
288	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj)
289	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj)
290	END_2D
291	!
292	DO_3D( 0, 0, 0, 0, 2, jpkm1 ) ! interior value (2=<jk=<jpkm1)
293	zcoef1 = zcoef0 * e3w(ji,jj,jk,Kmm)
294	! ! hydrostatic pressure gradient
295	zhpi(ji,jj) = zhpi(ji,jj) + zcoef1 * ( ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) ) &
296	& - ( rhd(ji ,jj,jk)+rhd(ji ,jj,jk-1) ) ) * r1_e1u(ji,jj)
297
298	zhpj(ji,jj) = zhpj(ji,jj) + zcoef1 * ( ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) ) &
299	& - ( rhd(ji,jj, jk)+rhd(ji,jj ,jk-1) ) ) * r1_e2v(ji,jj)
300	! ! add to the general momentum trend
301	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj)
302	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj)
303	END_3D
304	!
305	END SUBROUTINE hpg_zco
306
307
308	SUBROUTINE hpg_zps( kt, Kmm, puu, pvv, Krhs )
309	!!---------------------------------------------------------------------
310	!! * ROUTINE hpg_zps *
311	!!
312	!! ** Method : z-coordinate plus partial steps case. blahblah...
313	!!
314	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
315	!!----------------------------------------------------------------------
316	INTEGER , INTENT( in ) :: kt ! ocean time-step index
317	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
318	REAL(dp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
319	!!
320	INTEGER :: ji, jj, jk ! dummy loop indices
321	INTEGER :: iku, ikv ! temporary integers
322	REAL(dp) :: zcoef0, zcoef1, zcoef2, zcoef3 ! temporary scalars
323	REAL(dp), DIMENSION(A2D(nn_hls),jpk ) :: zhpi, zhpj
324	REAL(dp), DIMENSION(A2D(nn_hls),jpts) :: zgtsu, zgtsv
325	REAL(dp), DIMENSION(A2D(nn_hls) ) :: zgru, zgrv
326	!!----------------------------------------------------------------------
327	!
328	IF( .NOT. l_istiled .OR. ntile == 1 ) THEN ! Do only on the first tile
329	IF( kt == nit000 ) THEN
330	IF(lwp) WRITE(numout,*)
331	IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
332	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate with partial steps - vector optimization'
333	ENDIF
334	ENDIF
335
336	! Partial steps: Compute NOW horizontal gradient of t, s, rd at the last ocean level
337	CALL zps_hde( kt, Kmm, jpts, ts(:,:,:,:,Kmm), zgtsu, zgtsv, rhd, zgru , zgrv )
338
339	! Local constant initialization
340	zcoef0 = - grav * 0.5_wp
341
342	! Surface value (also valid in partial step case)
343	DO_2D( 0, 0, 0, 0 )
344	zcoef1 = zcoef0 * e3w(ji,jj,1,Kmm)
345	! hydrostatic pressure gradient
346	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
347	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
348	! add to the general momentum trend
349	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
350	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
351	END_2D
352
353	! interior value (2=<jk=<jpkm1)
354	DO_3D( 0, 0, 0, 0, 2, jpkm1 )
355	zcoef1 = zcoef0 * e3w(ji,jj,jk,Kmm)
356	! hydrostatic pressure gradient
357	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
358	& + zcoef1 * ( ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) &
359	& - ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) ) ) * r1_e1u(ji,jj)
360
361	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
362	& + zcoef1 * ( ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) &
363	& - ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) ) ) * r1_e2v(ji,jj)
364	! add to the general momentum trend
365	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
366	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
367	END_3D
368
369	! partial steps correction at the last level (use zgru & zgrv computed in zpshde.F90)
370	DO_2D( 0, 0, 0, 0 )
371	iku = mbku(ji,jj)
372	ikv = mbkv(ji,jj)
373	zcoef2 = zcoef0 * MIN( e3w(ji,jj,iku,Kmm), e3w(ji+1,jj ,iku,Kmm) )
374	zcoef3 = zcoef0 * MIN( e3w(ji,jj,ikv,Kmm), e3w(ji ,jj+1,ikv,Kmm) )
375	IF( iku > 1 ) THEN ! on i-direction (level 2 or more)
376	puu (ji,jj,iku,Krhs) = puu(ji,jj,iku,Krhs) - zhpi(ji,jj,iku) ! subtract old value
377	zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1) & ! compute the new one
378	& + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + zgru(ji,jj) ) * r1_e1u(ji,jj)
379	puu (ji,jj,iku,Krhs) = puu(ji,jj,iku,Krhs) + zhpi(ji,jj,iku) ! add the new one to the general momentum trend
380	ENDIF
381	IF( ikv > 1 ) THEN ! on j-direction (level 2 or more)
382	pvv (ji,jj,ikv,Krhs) = pvv(ji,jj,ikv,Krhs) - zhpj(ji,jj,ikv) ! subtract old value
383	zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1) & ! compute the new one
384	& + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + zgrv(ji,jj) ) * r1_e2v(ji,jj)
385	pvv (ji,jj,ikv,Krhs) = pvv(ji,jj,ikv,Krhs) + zhpj(ji,jj,ikv) ! add the new one to the general momentum trend
386	ENDIF
387	END_2D
388	!
389	END SUBROUTINE hpg_zps
390
391
392	SUBROUTINE hpg_sco( kt, Kmm, puu, pvv, Krhs )
393	!!---------------------------------------------------------------------
394	!! * ROUTINE hpg_sco *
395	!!
396	!! ** Method : s-coordinate case. Jacobian scheme.
397	!! The now hydrostatic pressure gradient at a given level, jk,
398	!! is computed by taking the vertical integral of the in-situ
399	!! density gradient along the model level from the suface to that
400	!! level. s-coordinates (ln_sco): a corrective term is added
401	!! to the horizontal pressure gradient :
402	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
403	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
404	!! add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
405	!! puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
406	!! pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
407	!!
408	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
409	!!----------------------------------------------------------------------
410	INTEGER , INTENT( in ) :: kt ! ocean time-step index
411	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
412	REAL(dp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
413	!!
414	INTEGER :: ji, jj, jk, jii, jjj ! dummy loop indices
415	REAL(wp) :: zcoef0, zuap, zvap! local scalars
416	REAL(dp) :: ztmp! local scalars
417	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
418	REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zhpi, zhpj
419	REAL(wp), DIMENSION(:,:), ALLOCATABLE :: zcpx, zcpy !W/D pressure filter
420	!!----------------------------------------------------------------------
421	!
422	IF( ln_wd_il ) ALLOCATE(zcpx(A2D(nn_hls)), zcpy(A2D(nn_hls)))
423	!
424	IF( .NOT. l_istiled .OR. ntile == 1 ) THEN ! Do only on the first tile
425	IF( kt == nit000 ) THEN
426	IF(lwp) WRITE(numout,*)
427	IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
428	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, OCE original scheme used'
429	ENDIF
430	ENDIF
431	!
432	zcoef0 = - grav * 0.5_wp
433	!
434	IF( ln_wd_il ) THEN
435	DO_2D( 0, 0, 0, 0 )
436	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
437	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) .AND. &
438	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) ) &
439	& > rn_wdmin1 + rn_wdmin2
440	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. ( &
441	& MAX( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
442	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
443
444	IF(ll_tmp1) THEN
445	zcpx(ji,jj) = 1.0_wp
446	ELSE IF(ll_tmp2) THEN
447	! no worries about ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm) = 0, it won't happen ! here
448	zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
449	& / (ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm)) )
450	ELSE
451	zcpx(ji,jj) = 0._wp
452	END IF
453
454	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
455	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) .AND. &
456	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) ) &
457	& > rn_wdmin1 + rn_wdmin2
458	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. ( &
459	& MAX( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
460	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
461
462	IF(ll_tmp1) THEN
463	zcpy(ji,jj) = 1.0_wp
464	ELSE IF(ll_tmp2) THEN
465	! no worries about ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm) = 0, it won't happen ! here
466	zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
467	& / (ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm)) )
468	ELSE
469	zcpy(ji,jj) = 0._wp
470	END IF
471	END_2D
472	END IF
473	!
474	DO_2D( 0, 0, 0, 0 ) ! Surface value
475	! ! hydrostatic pressure gradient along s-surfaces
476	zhpi(ji,jj,1) = zcoef0 * r1_e1u(ji,jj) &
477	& * ( e3w(ji+1,jj ,1,Kmm) * rhd(ji+1,jj ,1) &
478	& - e3w(ji ,jj ,1,Kmm) * rhd(ji ,jj ,1) )
479	zhpj(ji,jj,1) = zcoef0 * r1_e2v(ji,jj) &
480	& * ( e3w(ji ,jj+1,1,Kmm) * rhd(ji ,jj+1,1) &
481	& - e3w(ji ,jj ,1,Kmm) * rhd(ji ,jj ,1) )
482	! ! s-coordinate pressure gradient correction
483	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) ) &
484	& * ( gde3w(ji+1,jj,1) - gde3w(ji,jj,1) ) * r1_e1u(ji,jj)
485	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) ) &
486	& * ( gde3w(ji,jj+1,1) - gde3w(ji,jj,1) ) * r1_e2v(ji,jj)
487	!
488	IF( ln_wd_il ) THEN
489	zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
490	zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj)
491	zuap = zuap * zcpx(ji,jj)
492	zvap = zvap * zcpy(ji,jj)
493	ENDIF
494	! ! add to the general momentum trend
495	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1) + zuap
496	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1) + zvap
497	END_2D
498	!
499	DO_3D( 0, 0, 0, 0, 2, jpkm1 ) ! interior value (2=<jk=<jpkm1)
500	! ! hydrostatic pressure gradient along s-surfaces
501	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj) &
502	& * ( e3w(ji+1,jj,jk,Kmm) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) &
503	& - e3w(ji ,jj,jk,Kmm) * ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) ) )
504	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj) &
505	& * ( e3w(ji,jj+1,jk,Kmm) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) &
506	& - e3w(ji,jj ,jk,Kmm) * ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) ) )
507	! ! s-coordinate pressure gradient correction
508	zuap = -zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) ) &
509	& * ( gde3w(ji+1,jj ,jk) - gde3w(ji,jj,jk) ) * r1_e1u(ji,jj)
510	zvap = -zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) ) &
511	& * ( gde3w(ji ,jj+1,jk) - gde3w(ji,jj,jk) ) * r1_e2v(ji,jj)
512	!
513	IF( ln_wd_il ) THEN
514	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
515	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj)
516	zuap = zuap * zcpx(ji,jj)
517	zvap = zvap * zcpy(ji,jj)
518	ENDIF
519	!
520	! add to the general momentum trend
521	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk) + zuap
522	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk) + zvap
523	END_3D
524	!
525	IF( ln_wd_il ) DEALLOCATE( zcpx , zcpy )
526	!
527	END SUBROUTINE hpg_sco
528
529
530	SUBROUTINE hpg_isf( kt, Kmm, puu, pvv, Krhs )
531	!!---------------------------------------------------------------------
532	!! * ROUTINE hpg_isf *
533	!!
534	!! ** Method : s-coordinate case. Jacobian scheme.
535	!! The now hydrostatic pressure gradient at a given level, jk,
536	!! is computed by taking the vertical integral of the in-situ
537	!! density gradient along the model level from the suface to that
538	!! level. s-coordinates (ln_sco): a corrective term is added
539	!! to the horizontal pressure gradient :
540	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
541	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
542	!! add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
543	!! puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
544	!! pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
545	!! iceload is added
546	!!
547	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
548	!!----------------------------------------------------------------------
549	INTEGER , INTENT( in ) :: kt ! ocean time-step index
550	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
551	REAL(dp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
552	!!
553	INTEGER :: ji, jj, jk ! dummy loop indices
554	INTEGER :: ikt , ikti1, iktj1 ! local integer
555	REAL(dp) :: ze3w, ze3wi1, ze3wj1 ! local scalars
556	REAL(dp) :: zcoef0, zuap, zvap ! - -
557	REAL(dp), DIMENSION(A2D(nn_hls),jpk ) :: zhpi, zhpj
558	REAL(dp), DIMENSION(A2D(nn_hls),jpts) :: zts_top
559	REAL(dp), DIMENSION(A2D(nn_hls)) :: zrhdtop_oce
560	!!----------------------------------------------------------------------
561	!
562	zcoef0 = - grav * 0.5_wp ! Local constant initialization
563	!
564	! ! iniitialised to 0. zhpi zhpi
565	zhpi(:,:,:) = 0._wp ; zhpj(:,:,:) = 0._wp
566
567	! compute rhd at the ice/oce interface (ocean side)
568	! usefull to reduce residual current in the test case ISOMIP with no melting
569	DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
570	ikt = mikt(ji,jj)
571	zts_top(ji,jj,1) = ts(ji,jj,ikt,1,Kmm)
572	zts_top(ji,jj,2) = ts(ji,jj,ikt,2,Kmm)
573	END_2D
574	CALL eos( zts_top, CASTDP(risfdep), zrhdtop_oce )
575
576	! !===========================!
577	! !===== surface value =====!
578	! !===========================!
579	DO_2D( 0, 0, 0, 0 )
580	ikt = mikt(ji ,jj ) ; ze3w = e3w(ji ,jj ,ikt ,Kmm)
581	ikti1 = mikt(ji+1,jj ) ; ze3wi1 = e3w(ji+1,jj ,ikti1,Kmm)
582	iktj1 = mikt(ji ,jj+1) ; ze3wj1 = e3w(ji ,jj+1,iktj1,Kmm)
583	! ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
584	! ! we assume ISF is in isostatic equilibrium
585	zhpi(ji,jj,1) = zcoef0 * r1_e1u(ji,jj) * ( risfload(ji+1,jj) - risfload(ji,jj) &
586	& + 0.5_wp * ( ze3wi1 * ( rhd(ji+1,jj,ikti1) + zrhdtop_oce(ji+1,jj) ) &
587	& - ze3w * ( rhd(ji ,jj,ikt ) + zrhdtop_oce(ji ,jj) ) ) )
588	zhpj(ji,jj,1) = zcoef0 * r1_e2v(ji,jj) * ( risfload(ji,jj+1) - risfload(ji,jj) &
589	& + 0.5_wp * ( ze3wj1 * ( rhd(ji,jj+1,iktj1) + zrhdtop_oce(ji,jj+1) ) &
590	& - ze3w * ( rhd(ji,jj ,ikt ) + zrhdtop_oce(ji,jj ) ) ) )
591	! ! s-coordinate pressure gradient correction (=0 if z coordinate)
592	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) ) &
593	& * ( gde3w(ji+1,jj,1) - gde3w(ji,jj,1) ) * r1_e1u(ji,jj)
594	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) ) &
595	& * ( gde3w(ji,jj+1,1) - gde3w(ji,jj,1) ) * r1_e2v(ji,jj)
596	! ! add to the general momentum trend
597	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
598	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
599	END_2D
600	!
601	! !=============================!
602	! !===== interior values =====!
603	! !=============================!
604	DO_3D( 0, 0, 0, 0, 2, jpkm1 )
605	ze3w = e3w(ji ,jj ,jk,Kmm)
606	ze3wi1 = e3w(ji+1,jj ,jk,Kmm)
607	ze3wj1 = e3w(ji ,jj+1,jk,Kmm)
608	! ! hydrostatic pressure gradient along s-surfaces
609	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj) &
610	& * ( ze3wi1 * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) * wmask(ji+1,jj,jk) &
611	& - ze3w * ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) ) * wmask(ji ,jj,jk) )
612	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj) &
613	& * ( ze3wj1 * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) * wmask(ji,jj+1,jk) &
614	& - ze3w * ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) ) * wmask(ji,jj ,jk) )
615	! ! s-coordinate pressure gradient correction
616	zuap = -zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) ) &
617	& * ( gde3w(ji+1,jj ,jk) - gde3w(ji,jj,jk) ) / e1u(ji,jj)
618	zvap = -zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) ) &
619	& * ( gde3w(ji ,jj+1,jk) - gde3w(ji,jj,jk) ) / e2v(ji,jj)
620	! ! add to the general momentum trend
621	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
622	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
623	END_3D
624	!
625	END SUBROUTINE hpg_isf
626
627
628	SUBROUTINE hpg_djc( kt, Kmm, puu, pvv, Krhs )
629	!!---------------------------------------------------------------------
630	!! * ROUTINE hpg_djc *
631	!!
632	!! ** Method : Density Jacobian with Cubic polynomial scheme
633	!!
634	!! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
635	!!----------------------------------------------------------------------
636	INTEGER , INTENT( in ) :: kt ! ocean time-step index
637	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
638	REAL(dp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
639	!!
640	INTEGER :: ji, jj, jk ! dummy loop indices
641	INTEGER :: iktb, iktt ! jk indices at tracer points for top and bottom points
642	REAL(dp) :: zcoef0, zep, cffw ! temporary scalars
643	REAL(dp) :: z_grav_10, z1_12, z1_cff
644	REAL(dp) :: cffu, cffx ! " "
645	REAL(dp) :: cffv, cffy ! " "
646	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
647	REAL(dp), DIMENSION(A2D(nn_hls),jpk) :: zhpi, zhpj
648
649	REAL(dp), DIMENSION(A2D(nn_hls),jpk) :: zdzx, zdzy, zdzz ! Primitive grid differences ('delta_xyz')
650	REAL(dp), DIMENSION(A2D(nn_hls),jpk) :: zdz_i, zdz_j, zdz_k ! Harmonic average of primitive grid differences ('d_xyz')
651	REAL(dp), DIMENSION(A2D(nn_hls),jpk) :: zdrhox, zdrhoy, zdrhoz ! Primitive rho differences ('delta_rho')
652	REAL(dp), DIMENSION(A2D(nn_hls),jpk) :: zdrho_i, zdrho_j, zdrho_k ! Harmonic average of primitive rho differences ('d_rho')
653	REAL(dp), DIMENSION(A2D(nn_hls),jpk) :: z_rho_i, z_rho_j, z_rho_k ! Face intergrals
654	REAL(dp), DIMENSION(A2D(nn_hls)) :: zz_dz_i, zz_dz_j, zz_drho_i, zz_drho_j ! temporary arrays
655	REAL(wp), DIMENSION(:,:), ALLOCATABLE :: zcpx, zcpy !W/D pressure filter
656	!!----------------------------------------------------------------------
657	!
658	IF( ln_wd_il ) THEN
659	ALLOCATE( zcpx(A2D(nn_hls)) , zcpy(A2D(nn_hls)) )
660	DO_2D( 0, 0, 0, 0 )
661	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
662	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) .AND. &
663	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) ) &
664	& > rn_wdmin1 + rn_wdmin2
665	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. ( &
666	& MAX( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
667	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
668	IF(ll_tmp1) THEN
669	zcpx(ji,jj) = 1.0_wp
670	ELSE IF(ll_tmp2) THEN
671	! no worries about ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm) = 0, it won't happen ! here
672	zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
673	& / (ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm)) )
674	ELSE
675	zcpx(ji,jj) = 0._wp
676	END IF
677
678	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
679	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) .AND. &
680	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) ) &
681	& > rn_wdmin1 + rn_wdmin2
682	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. ( &
683	& MAX( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
684	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
685
686	IF(ll_tmp1) THEN
687	zcpy(ji,jj) = 1.0_wp
688	ELSE IF(ll_tmp2) THEN
689	! no worries about ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm) = 0, it won't happen ! here
690	zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
691	& / (ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm)) )
692	ELSE
693	zcpy(ji,jj) = 0._wp
694	END IF
695	END_2D
696	END IF
697
698	IF( .NOT. l_istiled .OR. ntile == 1 ) THEN ! Do only on the first tile
699	IF( kt == nit000 ) THEN
700	IF(lwp) WRITE(numout,*)
701	IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
702	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, density Jacobian with cubic polynomial scheme'
703	ENDIF
704	ENDIF
705
706	! Local constant initialization
707	zcoef0 = - grav * 0.5_wp
708	z_grav_10 = grav / 10._wp
709	z1_12 = 1.0_wp / 12._wp
710
711	!----------------------------------------------------------------------------------------
712	! 1. compute and store elementary vertical differences in provisional arrays
713	!----------------------------------------------------------------------------------------
714
715	!!bug gm Not a true bug, but... zdzz=e3w for zdzx, zdzy verify what it is really
716
717	DO_3D( 1, 1, 1, 1, 2, jpkm1 )
718	zdrhoz(ji,jj,jk) = rhd (ji ,jj ,jk) - rhd (ji,jj,jk-1)
719	zdzz (ji,jj,jk) = - gde3w(ji ,jj ,jk) + gde3w(ji,jj,jk-1)
720	END_3D
721
722	!-------------------------------------------------------------------------
723	! 2. compute harmonic averages for vertical differences using eq. 5.18
724	!-------------------------------------------------------------------------
725	zep = 1.e-15
726
727	!! mb zdrho_k, zdz_k, zdrho_i, zdz_i, zdrho_j, zdz_j re-centred about the point (ji,jj,jk)
728	zdrho_k(:,:,:) = 0._wp
729	zdz_k (:,:,:) = 0._wp
730
731	DO_3D( 1, 1, 1, 1, 2, jpk-2 )
732	cffw = MAX( 2._wp * zdrhoz(ji,jj,jk) * zdrhoz(ji,jj,jk+1), 0._wp )
733	z1_cff = zdrhoz(ji,jj,jk) + zdrhoz(ji,jj,jk+1)
734	zdrho_k(ji,jj,jk) = cffw / SIGN( MAX( ABS(z1_cff), zep ), z1_cff )
735	zdz_k(ji,jj,jk) = 2._wp * zdzz(ji,jj,jk) * zdzz(ji,jj,jk+1) &
736	& / ( zdzz(ji,jj,jk) + zdzz(ji,jj,jk+1) )
737	END_3D
738
739	!----------------------------------------------------------------------------------
740	! 3. apply boundary conditions at top and bottom using 5.36-5.37
741	!----------------------------------------------------------------------------------
742
743	! mb for sea-ice shelves we will need to re-write this upper boundary condition in the same form as the lower boundary condition
744	DO_2D( 1, 1, 1, 1 )
745	zdrho_k(ji,jj,1) = aco_bc_vrt * ( rhd (ji,jj,2) - rhd (ji,jj,1) ) - bco_bc_vrt * zdrho_k(ji,jj,2)
746	zdz_k (ji,jj,1) = aco_bc_vrt * (-gde3w(ji,jj,2) + gde3w(ji,jj,1) ) - bco_bc_vrt * zdz_k (ji,jj,2)
747	END_2D
748
749	DO_2D( 1, 1, 1, 1 )
750	IF ( mbkt(ji,jj)>1 ) THEN
751	iktb = mbkt(ji,jj)
752	zdrho_k(ji,jj,iktb) = aco_bc_vrt * ( rhd(ji,jj,iktb) - rhd(ji,jj,iktb-1) ) - bco_bc_vrt * zdrho_k(ji,jj,iktb-1)
753	zdz_k (ji,jj,iktb) = aco_bc_vrt * (-gde3w(ji,jj,iktb) + gde3w(ji,jj,iktb-1) ) - bco_bc_vrt * zdz_k (ji,jj,iktb-1)
754	END IF
755	END_2D
756
757	!--------------------------------------------------------------
758	! 4. Compute side face integrals
759	!-------------------------------------------------------------
760
761	!! ssh replaces e3w_n ; gde3w is a depth; the formulae involve heights
762	!! rho_k stores grav * FX / rho_0
763
764	!--------------------------------------------------------------
765	! 4. a) Upper half of top-most grid box, compute and store
766	!-------------------------------------------------------------
767	! *** AY note: ssh(ji,jj,Kmm) + gde3w(ji,jj,1) = e3w(ji,jj,1,Kmm)
768	DO_2D( 0, 1, 0, 1)
769	z_rho_k(ji,jj,1) = grav * ( ssh(ji,jj,Kmm) + gde3w(ji,jj,1) ) &
770	& * ( rhd(ji,jj,1) &
771	& + 0.5_wp * ( rhd (ji,jj,2) - rhd (ji,jj,1) ) &
772	& * ( ssh (ji,jj,Kmm) + gde3w(ji,jj,1) ) &
773	& / ( - gde3w(ji,jj,2) + gde3w(ji,jj,1) ) )
774	END_2D
775
776	!--------------------------------------------------------------
777	! 4. b) Interior faces, compute and store
778	!-------------------------------------------------------------
779
780	DO_3D( 0, 1, 0, 1, 2, jpkm1 )
781	z_rho_k(ji,jj,jk) = zcoef0 * ( rhd (ji,jj,jk) + rhd (ji,jj,jk-1) ) &
782	& * ( - gde3w(ji,jj,jk) + gde3w(ji,jj,jk-1) ) &
783	& + z_grav_10 * ( &
784	& ( zdrho_k (ji,jj,jk) - zdrho_k (ji,jj,jk-1) ) &
785	& * ( - gde3w(ji,jj,jk) + gde3w(ji,jj,jk-1) - z1_12 * ( zdz_k (ji,jj,jk) + zdz_k (ji,jj,jk-1) ) ) &
786	& - ( zdz_k (ji,jj,jk) - zdz_k (ji,jj,jk-1) ) &
787	& * ( rhd (ji,jj,jk) - rhd (ji,jj,jk-1) - z1_12 * ( zdrho_k(ji,jj,jk) + zdrho_k(ji,jj,jk-1) ) ) &
788	& )
789	END_3D
790
791	!----------------------------------------------------------------------------------------
792	! 5. compute and store elementary horizontal differences in provisional arrays
793	!----------------------------------------------------------------------------------------
794	zdrhox(:,:,:) = 0._wp
795	zdzx (:,:,:) = 0._wp
796	zdrhoy(:,:,:) = 0._wp
797	zdzy (:,:,:) = 0._wp
798
799	DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )
800	zdrhox(ji,jj,jk) = rhd (ji+1,jj ,jk) - rhd (ji ,jj ,jk)
801	zdzx (ji,jj,jk) = gde3w(ji ,jj ,jk) - gde3w(ji+1,jj ,jk)
802	zdrhoy(ji,jj,jk) = rhd (ji ,jj+1,jk) - rhd (ji ,jj ,jk)
803	zdzy (ji,jj,jk) = gde3w(ji ,jj ,jk) - gde3w(ji ,jj+1,jk)
804	END_3D
805
806	IF( nn_hls == 1 ) CALL lbc_lnk( 'dynhpg', zdrhox, 'U', -1._wp, zdzx, 'U', -1._wp, zdrhoy, 'V', -1._wp, zdzy, 'V', -1._wp )
807
808	!-------------------------------------------------------------------------
809	! 6. compute harmonic averages using eq. 5.18
810	!-------------------------------------------------------------------------
811
812	DO_3D( 0, 1, 0, 1, 1, jpkm1 )
813	cffu = MAX( 2._wp * zdrhox(ji-1,jj,jk) * zdrhox(ji,jj,jk), 0._wp )
814	z1_cff = zdrhox(ji-1,jj,jk) + zdrhox(ji,jj,jk)
815	zdrho_i(ji,jj,jk) = cffu / SIGN( MAX( ABS(z1_cff), zep ), z1_cff )
816
817	cffx = MAX( 2._wp * zdzx(ji-1,jj,jk) * zdzx(ji,jj,jk), 0._wp )
818	z1_cff = zdzx(ji-1,jj,jk) + zdzx(ji,jj,jk)
819	zdz_i(ji,jj,jk) = cffx / SIGN( MAX( ABS(z1_cff), zep ), z1_cff )
820
821	cffv = MAX( 2._wp * zdrhoy(ji,jj-1,jk) * zdrhoy(ji,jj,jk), 0._wp )
822	z1_cff = zdrhoy(ji,jj-1,jk) + zdrhoy(ji,jj,jk)
823	zdrho_j(ji,jj,jk) = cffv / SIGN( MAX( ABS(z1_cff), zep ), z1_cff )
824
825	cffy = MAX( 2._wp * zdzy(ji,jj-1,jk) * zdzy(ji,jj,jk), 0._wp )
826	z1_cff = zdzy(ji,jj-1,jk) + zdzy(ji,jj,jk)
827	zdz_j(ji,jj,jk) = cffy / SIGN( MAX( ABS(z1_cff), zep ), z1_cff )
828	END_3D
829
830	!!! Note that zdzx, zdzy, zdzz, zdrhox, zdrhoy and zdrhoz should NOT be used beyond this point
831
832	!----------------------------------------------------------------------------------
833	! 6B. apply boundary conditions at side boundaries using 5.36-5.37
834	!----------------------------------------------------------------------------------
835
836	DO jk = 1, jpkm1
837	zz_drho_i(:,:) = zdrho_i(:,:,jk)
838	zz_dz_i (:,:) = zdz_i (:,:,jk)
839	zz_drho_j(:,:) = zdrho_j(:,:,jk)
840	zz_dz_j (:,:) = zdz_j (:,:,jk)
841	! Walls coming from left: should check from 2 to jpi-1 (and jpj=2-jpj)
842	DO_2D( 0, 0, 0, 1 )
843	IF ( umask(ji,jj,jk) > 0.5_wp .AND. umask(ji-1,jj,jk) < 0.5_wp .AND. umask(ji+1,jj,jk) > 0.5_wp) THEN
844	zz_drho_i(ji,jj) = aco_bc_hor * ( rhd (ji+1,jj,jk) - rhd (ji,jj,jk) ) - bco_bc_hor * zdrho_i(ji+1,jj,jk)
845	zz_dz_i (ji,jj) = aco_bc_hor * (-gde3w(ji+1,jj,jk) + gde3w(ji,jj,jk) ) - bco_bc_hor * zdz_i (ji+1,jj,jk)
846	END IF
847	END_2D
848	! Walls coming from right: should check from 3 to jpi (and jpj=2-jpj)
849	DO_2D( -1, 1, 0, 1 )
850	IF ( umask(ji,jj,jk) < 0.5_wp .AND. umask(ji-1,jj,jk) > 0.5_wp .AND. umask(ji-2,jj,jk) > 0.5_wp) THEN
851	zz_drho_i(ji,jj) = aco_bc_hor * ( rhd (ji,jj,jk) - rhd (ji-1,jj,jk) ) - bco_bc_hor * zdrho_i(ji-1,jj,jk)
852	zz_dz_i (ji,jj) = aco_bc_hor * (-gde3w(ji,jj,jk) + gde3w(ji-1,jj,jk) ) - bco_bc_hor * zdz_i (ji-1,jj,jk)
853	END IF
854	END_2D
855	! Walls coming from left: should check from 2 to jpj-1 (and jpi=2-jpi)
856	DO_2D( 0, 1, 0, 0 )
857	IF ( vmask(ji,jj,jk) > 0.5_wp .AND. vmask(ji,jj-1,jk) < 0.5_wp .AND. vmask(ji,jj+1,jk) > 0.5_wp) THEN
858	zz_drho_j(ji,jj) = aco_bc_hor * ( rhd (ji,jj+1,jk) - rhd (ji,jj,jk) ) - bco_bc_hor * zdrho_j(ji,jj+1,jk)
859	zz_dz_j (ji,jj) = aco_bc_hor * (-gde3w(ji,jj+1,jk) + gde3w(ji,jj,jk) ) - bco_bc_hor * zdz_j (ji,jj+1,jk)
860	END IF
861	END_2D
862	! Walls coming from right: should check from 3 to jpj (and jpi=2-jpi)
863	DO_2D( 0, 1, -1, 1 )
864	IF ( vmask(ji,jj,jk) < 0.5_wp .AND. vmask(ji,jj-1,jk) > 0.5_wp .AND. vmask(ji,jj-2,jk) > 0.5_wp) THEN
865	zz_drho_j(ji,jj) = aco_bc_hor * ( rhd (ji,jj,jk) - rhd (ji,jj-1,jk) ) - bco_bc_hor * zdrho_j(ji,jj-1,jk)
866	zz_dz_j (ji,jj) = aco_bc_hor * (-gde3w(ji,jj,jk) + gde3w(ji,jj-1,jk) ) - bco_bc_hor * zdz_j (ji,jj-1,jk)
867	END IF
868	END_2D
869	zdrho_i(:,:,jk) = zz_drho_i(:,:)
870	zdz_i (:,:,jk) = zz_dz_i (:,:)
871	zdrho_j(:,:,jk) = zz_drho_j(:,:)
872	zdz_j (:,:,jk) = zz_dz_j (:,:)
873	END DO
874
875	!--------------------------------------------------------------
876	! 7. Calculate integrals on side faces
877	!-------------------------------------------------------------
878
879	DO_3D( 0, 0, 0, 0, 1, jpkm1 )
880	! two -ve signs cancel in next two lines (within zcoef0 and because gde3w is a depth not a height)
881	z_rho_i(ji,jj,jk) = zcoef0 * ( rhd (ji+1,jj,jk) + rhd (ji,jj,jk) ) &
882	& * ( gde3w(ji+1,jj,jk) - gde3w(ji,jj,jk) )
883	IF ( umask(ji-1, jj, jk) > 0.5 .OR. umask(ji+1, jj, jk) > 0.5 ) THEN
884	z_rho_i(ji,jj,jk) = z_rho_i(ji,jj,jk) - z_grav_10 * ( &
885	& ( zdrho_i (ji+1,jj,jk) - zdrho_i (ji,jj,jk) ) &
886	& * ( - gde3w(ji+1,jj,jk) + gde3w(ji,jj,jk) - z1_12 * ( zdz_i (ji+1,jj,jk) + zdz_i (ji,jj,jk) ) ) &
887	& - ( zdz_i (ji+1,jj,jk) - zdz_i (ji,jj,jk) ) &
888	& * ( rhd (ji+1,jj,jk) - rhd (ji,jj,jk) - z1_12 * ( zdrho_i(ji+1,jj,jk) + zdrho_i(ji,jj,jk) ) ) &
889	& )
890	END IF
891
892	z_rho_j(ji,jj,jk) = zcoef0 * ( rhd (ji,jj+1,jk) + rhd (ji,jj,jk) ) &
893	& * ( gde3w(ji,jj+1,jk) - gde3w(ji,jj,jk) )
894	IF ( vmask(ji, jj-1, jk) > 0.5 .OR. vmask(ji, jj+1, jk) > 0.5 ) THEN
895	z_rho_j(ji,jj,jk) = z_rho_j(ji,jj,jk) - z_grav_10 * ( &
896	& ( zdrho_j (ji,jj+1,jk) - zdrho_j (ji,jj,jk) ) &
897	& * ( - gde3w(ji,jj+1,jk) + gde3w(ji,jj,jk) - z1_12 * ( zdz_j (ji,jj+1,jk) + zdz_j (ji,jj,jk) ) ) &
898	& - ( zdz_j (ji,jj+1,jk) - zdz_j (ji,jj,jk) ) &
899	& * ( rhd (ji,jj+1,jk) - rhd (ji,jj,jk) - z1_12 * ( zdrho_j(ji,jj+1,jk) + zdrho_j(ji,jj,jk) ) ) &
900	& )
901	END IF
902	END_3D
903
904	!--------------------------------------------------------------
905	! 8. Integrate in the vertical
906	!-------------------------------------------------------------
907	!
908	! ---------------
909	! Surface value
910	! ---------------
911	DO_2D( 0, 0, 0, 0 )
912	zhpi(ji,jj,1) = ( z_rho_k(ji,jj,1) - z_rho_k(ji+1,jj ,1) - z_rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
913	zhpj(ji,jj,1) = ( z_rho_k(ji,jj,1) - z_rho_k(ji ,jj+1,1) - z_rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
914	IF( ln_wd_il ) THEN
915	zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
916	zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj)
917	ENDIF
918	! add to the general momentum trend
919	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
920	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
921	END_2D
922
923	! ----------------
924	! interior value (2=<jk=<jpkm1)
925	! ----------------
926	DO_3D( 0, 0, 0, 0, 2, jpkm1 )
927	! hydrostatic pressure gradient along s-surfaces
928	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
929	& + ( ( z_rho_k(ji,jj,jk) - z_rho_k(ji+1,jj,jk ) ) &
930	& - ( z_rho_i(ji,jj,jk) - z_rho_i(ji ,jj,jk-1) ) ) * r1_e1u(ji,jj)
931	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
932	& + ( ( z_rho_k(ji,jj,jk) - z_rho_k(ji,jj+1,jk ) ) &
933	& -( z_rho_j(ji,jj,jk) - z_rho_j(ji,jj ,jk-1) ) ) * r1_e2v(ji,jj)
934	IF( ln_wd_il ) THEN
935	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
936	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj)
937	ENDIF
938	! add to the general momentum trend
939	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
940	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
941	END_3D
942	!
943	IF( ln_wd_il ) DEALLOCATE( zcpx, zcpy )
944	!
945	END SUBROUTINE hpg_djc
946
947
948	SUBROUTINE hpg_prj( kt, Kmm, puu, pvv, Krhs )
949	!!---------------------------------------------------------------------
950	!! * ROUTINE hpg_prj *
951	!!
952	!! ** Method : s-coordinate case.
953	!! A Pressure-Jacobian horizontal pressure gradient method
954	!! based on the constrained cubic-spline interpolation for
955	!! all vertical coordinate systems
956	!!
957	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
958	!!----------------------------------------------------------------------
959	INTEGER, PARAMETER :: polynomial_type = 1 ! 1: cubic spline, 2: linear
960	INTEGER , INTENT( in ) :: kt ! ocean time-step index
961	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
962	REAL(dp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
963	!!
964	INTEGER :: ji, jj, jk, jkk ! dummy loop indices
965	REAL(dp) :: zcoef0, znad ! local scalars
966	!
967	!! The local variables for the correction term
968	INTEGER :: jk1, jis, jid, jjs, jjd
969	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
970	REAL(dp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
971	REAL(dp) :: zrhdt1
972	REAL(dp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
973	REAL(dp), DIMENSION(A2D(nn_hls)) :: zpgu, zpgv ! 2D workspace
974	REAL(dp), DIMENSION(A2D(nn_hls)) :: zsshu_n, zsshv_n
975	REAL(dp), DIMENSION(A2D(nn_hls),jpk) :: zdept, zrhh
976	REAL(dp), DIMENSION(A2D(nn_hls),jpk) :: zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
977	REAL(wp), DIMENSION(:,:), ALLOCATABLE :: zcpx, zcpy !W/D pressure filter
978	!!----------------------------------------------------------------------
979	!
980	IF( .NOT. l_istiled .OR. ntile == 1 ) THEN ! Do only on the first tile
981	IF( kt == nit000 ) THEN
982	IF(lwp) WRITE(numout,*)
983	IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
984	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, cubic spline pressure Jacobian'
985	ENDIF
986	ENDIF
987
988	! Local constant initialization
989	zcoef0 = - grav
990	znad = 1._wp
991	IF( ln_linssh ) znad = 1._wp
992	!
993	! ---------------
994	! Surface pressure gradient to be removed
995	! ---------------
996	DO_2D( 0, 0, 0, 0 )
997	zpgu(ji,jj) = - grav * ( ssh(ji+1,jj,Kmm) - ssh(ji,jj,Kmm) ) * r1_e1u(ji,jj)
998	zpgv(ji,jj) = - grav * ( ssh(ji,jj+1,Kmm) - ssh(ji,jj,Kmm) ) * r1_e2v(ji,jj)
999	END_2D
1000	!
1001	IF( ln_wd_il ) THEN
1002	ALLOCATE( zcpx(A2D(nn_hls)) , zcpy(A2D(nn_hls)) )
1003	DO_2D( 0, 0, 0, 0 )
1004	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
1005	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) .AND. &
1006	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) ) > &
1007	& rn_wdmin1 + rn_wdmin2
1008	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. &
1009	& ( MAX( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
1010	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
1011
1012	IF(ll_tmp1) THEN
1013	zcpx(ji,jj) = 1.0_wp
1014	ELSE IF(ll_tmp2) THEN
1015	! no worries about ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm) = 0, it won't happen ! here
1016	zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
1017	& / (ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm)) )
1018	zcpx(ji,jj) = MAX(MIN( zcpx(ji,jj) , 1.0_wp),0.0_wp)
1019	ELSE
1020	zcpx(ji,jj) = 0._wp
1021	END IF
1022
1023	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
1024	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) .AND. &
1025	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) ) > &
1026	& rn_wdmin1 + rn_wdmin2
1027	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. &
1028	& ( MAX( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
1029	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
1030
1031	IF(ll_tmp1) THEN
1032	zcpy(ji,jj) = 1.0_wp
1033	ELSE IF(ll_tmp2) THEN
1034	! no worries about ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm) = 0, it won't happen ! here
1035	zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
1036	& / (ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm)) )
1037	zcpy(ji,jj) = MAX(MIN( zcpy(ji,jj) , 1.0_wp),0.0_wp)
1038	ELSE
1039	zcpy(ji,jj) = 0._wp
1040	ENDIF
1041	END_2D
1042	ENDIF
1043
1044	! Clean 3-D work arrays
1045	zhpi(:,:,:) = 0._wp
1046	zrhh(:,:,:) = rhd(A2D(nn_hls),:)
1047
1048	! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1049	DO_2D( 1, 1, 1, 1 )
1050	jk = mbkt(ji,jj)
1051	IF( jk <= 1 ) THEN ; zrhh(ji,jj, : ) = 0._wp
1052	ELSEIF( jk == 2 ) THEN ; zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
1053	ELSEIF( jk < jpkm1 ) THEN
1054	DO jkk = jk+1, jpk
1055	zrhh(ji,jj,jkk) = interp1(gde3w(ji,jj,jkk ), gde3w(ji,jj,jkk-1), &
1056	& gde3w(ji,jj,jkk-2), zrhh (ji,jj,jkk-1), zrhh(ji,jj,jkk-2))
1057	END DO
1058	ENDIF
1059	END_2D
1060
1061	! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1062	DO_2D( 1, 1, 1, 1 )
1063	zdept(ji,jj,1) = 0.5_wp * e3w(ji,jj,1,Kmm) - ssh(ji,jj,Kmm)
1064	END_2D
1065
1066	DO_3D( 1, 1, 1, 1, 2, jpk )
1067	zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w(ji,jj,jk,Kmm)
1068	END_3D
1069
1070	fsp(:,:,:) = zrhh (:,:,:)
1071	xsp(:,:,:) = zdept(:,:,:)
1072
1073	! Construct the vertical density profile with the
1074	! constrained cubic spline interpolation
1075	! rho(z) = asp + bspz + cspz^2 + dsp*z^3
1076	CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1077
1078	! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1079	DO_2D( 0, 1, 0, 1 )
1080	zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1), &
1081	& csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w(ji,jj,1,Kmm)
1082
1083	! assuming linear profile across the top half surface layer
1084	zhpi(ji,jj,1) = 0.5_wp * e3w(ji,jj,1,Kmm) * zrhdt1
1085	END_2D
1086
1087	! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1088	DO_3D( 0, 1, 0, 1, 2, jpkm1 )
1089	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + &
1090	& integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk), &
1091	& asp (ji,jj,jk-1), bsp (ji,jj,jk-1), &
1092	& csp (ji,jj,jk-1), dsp (ji,jj,jk-1) )
1093	END_3D
1094
1095	! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1096
1097	! Prepare zsshu_n and zsshv_n
1098	DO_2D( 0, 0, 0, 0 )
1099	!!gm BUG ? if it is ssh at u- & v-point then it should be:
1100	! zsshu_n(ji,jj) = (e1e2t(ji,jj) * ssh(ji,jj,Kmm) + e1e2t(ji+1,jj) * ssh(ji+1,jj,Kmm)) * &
1101	! & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1102	! zsshv_n(ji,jj) = (e1e2t(ji,jj) * ssh(ji,jj,Kmm) + e1e2t(ji,jj+1) * ssh(ji,jj+1,Kmm)) * &
1103	! & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1104	!!gm not this:
1105	zsshu_n(ji,jj) = (e1e2u(ji,jj) * ssh(ji,jj,Kmm) + e1e2u(ji+1, jj) * ssh(ji+1,jj,Kmm)) * &
1106	& r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1107	zsshv_n(ji,jj) = (e1e2v(ji,jj) * ssh(ji,jj,Kmm) + e1e2v(ji+1, jj) * ssh(ji,jj+1,Kmm)) * &
1108	& r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1109	END_2D
1110
1111	DO_2D( 0, 0, 0, 0 )
1112	zu(ji,jj,1) = - ( e3u(ji,jj,1,Kmm) - zsshu_n(ji,jj) )
1113	zv(ji,jj,1) = - ( e3v(ji,jj,1,Kmm) - zsshv_n(ji,jj) )
1114	END_2D
1115
1116	DO_3D( 0, 0, 0, 0, 2, jpkm1 )
1117	zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u(ji,jj,jk,Kmm)
1118	zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v(ji,jj,jk,Kmm)
1119	END_3D
1120
1121	DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1122	zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u(ji,jj,jk,Kmm)
1123	zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v(ji,jj,jk,Kmm)
1124	END_3D
1125
1126	DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1127	zu(ji,jj,jk) = MIN( zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) ) )
1128	zu(ji,jj,jk) = MAX( zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) ) )
1129	zv(ji,jj,jk) = MIN( zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) ) )
1130	zv(ji,jj,jk) = MAX( zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) ) )
1131	END_3D
1132
1133
1134	DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1135	zpwes = 0._wp; zpwed = 0._wp
1136	zpnss = 0._wp; zpnsd = 0._wp
1137	zuijk = zu(ji,jj,jk)
1138	zvijk = zv(ji,jj,jk)
1139
1140	!!!!! for u equation
1141	IF( jk <= mbku(ji,jj) ) THEN
1142	IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1143	jis = ji + 1; jid = ji
1144	ELSE
1145	jis = ji; jid = ji +1
1146	ENDIF
1147
1148	! integrate the pressure on the shallow side
1149	jk1 = jk
1150	DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1151	IF( jk1 == mbku(ji,jj) ) THEN
1152	zuijk = -zdept(jis,jj,jk1)
1153	EXIT
1154	ENDIF
1155	zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1156	zpwes = zpwes + &
1157	integ_spline(zdept(jis,jj,jk1), zdeps, &
1158	asp(jis,jj,jk1), bsp(jis,jj,jk1), &
1159	csp(jis,jj,jk1), dsp(jis,jj,jk1))
1160	jk1 = jk1 + 1
1161	END DO
1162
1163	! integrate the pressure on the deep side
1164	jk1 = jk
1165	DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1166	IF( jk1 == 1 ) THEN
1167	zdeps = zdept(jid,jj,1) + MIN(zuijk, ssh(jid,jj,Kmm)*znad)
1168	zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1169	bsp(jid,jj,1) , csp(jid,jj,1), &
1170	dsp(jid,jj,1)) * zdeps
1171	zpwed = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1172	EXIT
1173	ENDIF
1174	zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1175	zpwed = zpwed + &
1176	integ_spline(zdeps, zdept(jid,jj,jk1), &
1177	asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1), &
1178	csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1179	jk1 = jk1 - 1
1180	END DO
1181
1182	! update the momentum trends in u direction
1183	zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1184	IF( .NOT.ln_linssh ) THEN
1185	zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1186	& ( REAL(jis-jid, wp) * (zpwes + zpwed) + (ssh(ji+1,jj,Kmm)-ssh(ji,jj,Kmm)) )
1187	ELSE
1188	zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1189	ENDIF
1190	IF( ln_wd_il ) THEN
1191	zdpdx1 = zdpdx1 * zcpx(ji,jj) * wdrampu(ji,jj)
1192	zdpdx2 = zdpdx2 * zcpx(ji,jj) * wdrampu(ji,jj)
1193	ENDIF
1194	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + (zdpdx1 + zdpdx2 - zpgu(ji,jj)) * umask(ji,jj,jk)
1195	ENDIF
1196
1197	!!!!! for v equation
1198	IF( jk <= mbkv(ji,jj) ) THEN
1199	IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1200	jjs = jj + 1; jjd = jj
1201	ELSE
1202	jjs = jj ; jjd = jj + 1
1203	ENDIF
1204
1205	! integrate the pressure on the shallow side
1206	jk1 = jk
1207	DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1208	IF( jk1 == mbkv(ji,jj) ) THEN
1209	zvijk = -zdept(ji,jjs,jk1)
1210	EXIT
1211	ENDIF
1212	zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1213	zpnss = zpnss + &
1214	integ_spline(zdept(ji,jjs,jk1), zdeps, &
1215	asp(ji,jjs,jk1), bsp(ji,jjs,jk1), &
1216	csp(ji,jjs,jk1), dsp(ji,jjs,jk1) )
1217	jk1 = jk1 + 1
1218	END DO
1219
1220	! integrate the pressure on the deep side
1221	jk1 = jk
1222	DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1223	IF( jk1 == 1 ) THEN
1224	zdeps = zdept(ji,jjd,1) + MIN(zvijk, ssh(ji,jjd,Kmm)*znad)
1225	zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1226	bsp(ji,jjd,1) , csp(ji,jjd,1), &
1227	dsp(ji,jjd,1) ) * zdeps
1228	zpnsd = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1229	EXIT
1230	ENDIF
1231	zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1232	zpnsd = zpnsd + &
1233	integ_spline(zdeps, zdept(ji,jjd,jk1), &
1234	asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1235	csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1236	jk1 = jk1 - 1
1237	END DO
1238
1239	! update the momentum trends in v direction
1240	zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1241	IF( .NOT.ln_linssh ) THEN
1242	zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1243	( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (ssh(ji,jj+1,Kmm)-ssh(ji,jj,Kmm)) )
1244	ELSE
1245	zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1246	ENDIF
1247	IF( ln_wd_il ) THEN
1248	zdpdy1 = zdpdy1 * zcpy(ji,jj) * wdrampv(ji,jj)
1249	zdpdy2 = zdpdy2 * zcpy(ji,jj) * wdrampv(ji,jj)
1250	ENDIF
1251
1252	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + (zdpdy1 + zdpdy2 - zpgv(ji,jj)) * vmask(ji,jj,jk)
1253	ENDIF
1254	!
1255	END_3D
1256	!
1257	IF( ln_wd_il ) DEALLOCATE( zcpx, zcpy )
1258	!
1259	END SUBROUTINE hpg_prj
1260
1261
1262	SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1263	!!----------------------------------------------------------------------
1264	!! * ROUTINE cspline *
1265	!!
1266	!! ** Purpose : constrained cubic spline interpolation
1267	!!
1268	!! ** Method : f(x) = asp + bspx + cspx^2 + dsp*x^3
1269	!!
1270	!! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1271	!!----------------------------------------------------------------------
1272	REAL(dp), DIMENSION(A2D(nn_hls),jpk), INTENT(in ) :: fsp, xsp ! value and coordinate
1273	REAL(dp), DIMENSION(A2D(nn_hls),jpk), INTENT( out) :: asp, bsp, csp, dsp ! coefficients of the interpoated function
1274	INTEGER , INTENT(in ) :: polynomial_type ! 1: cubic spline ; 2: Linear
1275	!
1276	INTEGER :: ji, jj, jk ! dummy loop indices
1277	REAL(dp) :: zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1278	REAL(dp) :: zdxtmp1, zdxtmp2, zalpha
1279	REAL(dp) :: zdf(jpk)
1280	!!----------------------------------------------------------------------
1281	!
1282	IF (polynomial_type == 1) THEN ! Constrained Cubic Spline
1283	DO_2D( 1, 1, 1, 1 )
1284	!!Fritsch&Butland's method, 1984 (preferred, but more computation)
1285	! DO jk = 2, jpkm1-1
1286	! zdxtmp1 = xsp(ji,jj,jk) - xsp(ji,jj,jk-1)
1287	! zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1288	! zdf1 = ( fsp(ji,jj,jk) - fsp(ji,jj,jk-1) ) / zdxtmp1
1289	! zdf2 = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp2
1290	!
1291	! zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1292	!
1293	! IF(zdf1 * zdf2 <= 0._wp) THEN
1294	! zdf(jk) = 0._wp
1295	! ELSE
1296	! zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1297	! ENDIF
1298	! END DO
1299
1300	!!Simply geometric average
1301	DO jk = 2, jpk-2
1302	zdf1 = (fsp(ji,jj,jk ) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk ) - xsp(ji,jj,jk-1))
1303	zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk )) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk ))
1304
1305	IF(zdf1 * zdf2 <= 0._wp) THEN
1306	zdf(jk) = 0._wp
1307	ELSE
1308	zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1309	ENDIF
1310	END DO
1311
1312	zdf(1) = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1313	& ( xsp(ji,jj,2) - xsp(ji,jj,1) ) - 0.5_wp * zdf(2)
1314	zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1315	& ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpk - 2)
1316
1317	DO jk = 1, jpk-2
1318	zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1319	ztmp1 = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1320	ztmp2 = 6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1321	zddf1 = -2._wp * ztmp1 + ztmp2
1322	ztmp1 = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1323	zddf2 = 2._wp * ztmp1 - ztmp2
1324
1325	dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1326	csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1327	bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1328	& csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1329	& dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1330	& xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1331	asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1332	& (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1333	& dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1334	END DO
1335	END_2D
1336
1337	ELSEIF ( polynomial_type == 2 ) THEN ! Linear
1338	DO_3D( 1, 1, 1, 1, 1, jpk-2 )
1339	zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1340	ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1341
1342	dsp(ji,jj,jk) = 0._wp
1343	csp(ji,jj,jk) = 0._wp
1344	bsp(ji,jj,jk) = ztmp1 / zdxtmp
1345	asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1346	END_3D
1347	!
1348	ELSE
1349	CALL ctl_stop( 'invalid polynomial type in cspline' )
1350	ENDIF
1351	!
1352	END SUBROUTINE cspline
1353
1354
1355	FUNCTION interp1(x, xl, xr, fl, fr) RESULT(f)
1356	!!----------------------------------------------------------------------
1357	!! * ROUTINE interp1 *
1358	!!
1359	!! ** Purpose : 1-d linear interpolation
1360	!!
1361	!! ** Method : interpolation is straight forward
1362	!! extrapolation is also permitted (no value limit)
1363	!!----------------------------------------------------------------------
1364	REAL(dp), INTENT(in) :: x, xl, xr, fl, fr
1365	REAL(dp) :: f ! result of the interpolation (extrapolation)
1366	REAL(dp) :: zdeltx
1367	!!----------------------------------------------------------------------
1368	!
1369	zdeltx = xr - xl
1370	IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1371	f = 0.5_wp * (fl + fr)
1372	ELSE
1373	f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1374	ENDIF
1375	!
1376	END FUNCTION interp1
1377
1378
1379	FUNCTION interp2( x, a, b, c, d ) RESULT(f)
1380	!!----------------------------------------------------------------------
1381	!! * ROUTINE interp1 *
1382	!!
1383	!! ** Purpose : 1-d constrained cubic spline interpolation
1384	!!
1385	!! ** Method : cubic spline interpolation
1386	!!
1387	!!----------------------------------------------------------------------
1388	REAL(wp), INTENT(in) :: x, a, b, c, d
1389	REAL(dp) :: f ! value from the interpolation
1390	!!----------------------------------------------------------------------
1391	!
1392	f = a + x* ( b + x * ( c + d * x ) )
1393	!
1394	END FUNCTION interp2
1395
1396
1397	FUNCTION interp3( x, a, b, c, d ) RESULT(f)
1398	!!----------------------------------------------------------------------
1399	!! * ROUTINE interp1 *
1400	!!
1401	!! ** Purpose : Calculate the first order of derivative of
1402	!! a cubic spline function y=a+bx+cx^2+d*x^3
1403	!!
1404	!! ** Method : f=dy/dx=b+2cx+3dx^2
1405	!!
1406	!!----------------------------------------------------------------------
1407	REAL(dp), INTENT(in) :: x, a, b, c, d
1408	REAL(dp) :: f ! value from the interpolation
1409	!!----------------------------------------------------------------------
1410	!
1411	f = b + x * ( 2._wp * c + 3._wp * d * x)
1412	!
1413	END FUNCTION interp3
1414
1415
1416	FUNCTION integ_spline( xl, xr, a, b, c, d ) RESULT(f)
1417	!!----------------------------------------------------------------------
1418	!! * ROUTINE interp1 *
1419	!!
1420	!! ** Purpose : 1-d constrained cubic spline integration
1421	!!
1422	!! ** Method : integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1423	!!
1424	!!----------------------------------------------------------------------
1425	REAL(dp), INTENT(in) :: xl, xr, a, b, c, d
1426	REAL(dp) :: za1, za2, za3
1427	REAL(dp) :: f ! integration result
1428	!!----------------------------------------------------------------------
1429	!
1430	za1 = 0.5_wp * b
1431	za2 = c / 3.0_wp
1432	za3 = 0.25_wp * d
1433	!
1434	f = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1435	& xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1436	!
1437	END FUNCTION integ_spline
1438
1439	!!======================================================================
1440	END MODULE dynhpg

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: NEMO/branches/2021/dev_r14116_HPC-10_mcastril_Mixed_Precision_implementation/src/OCE/DYN/dynhpg.F90 @ 15540

Download in other formats: