| 1 | MODULE dynspg |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE dynspg *** |
|---|
| 4 | !! Ocean dynamics: surface pressure gradient control |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 1.0 ! 2005-12 (C. Talandier, G. Madec, V. Garnier) Original code |
|---|
| 7 | !! 3.2 ! 2009-07 (R. Benshila) Suppression of rigid-lid option |
|---|
| 8 | !! 4.2 ! 2020-12 (G. Madec, E. Clementi) add Bernoulli Head for |
|---|
| 9 | !! wave coupling |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | !! dyn_spg : update the dynamics trend with surface pressure gradient |
|---|
| 14 | !! dyn_spg_init: initialization, namelist read, and parameters control |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | USE oce ! ocean dynamics and tracers variables |
|---|
| 17 | USE dom_oce ! ocean space and time domain variables |
|---|
| 18 | USE c1d ! 1D vertical configuration |
|---|
| 19 | USE phycst ! physical constants |
|---|
| 20 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 21 | USE sbc_ice , ONLY : snwice_mass, snwice_mass_b |
|---|
| 22 | USE sbcapr ! surface boundary condition: atmospheric pressure |
|---|
| 23 | USE sbcwave, ONLY : bhd_wave |
|---|
| 24 | USE dynspg_exp ! surface pressure gradient (dyn_spg_exp routine) |
|---|
| 25 | USE dynspg_ts ! surface pressure gradient (dyn_spg_ts routine) |
|---|
| 26 | USE tide_mod ! |
|---|
| 27 | USE trd_oce ! trends: ocean variables |
|---|
| 28 | USE trddyn ! trend manager: dynamics |
|---|
| 29 | ! |
|---|
| 30 | USE prtctl ! Print control (prt_ctl routine) |
|---|
| 31 | USE in_out_manager ! I/O manager |
|---|
| 32 | USE lib_mpp ! MPP library |
|---|
| 33 | USE timing ! Timing |
|---|
| 34 | |
|---|
| 35 | IMPLICIT NONE |
|---|
| 36 | PRIVATE |
|---|
| 37 | |
|---|
| 38 | PUBLIC dyn_spg ! routine called by step module |
|---|
| 39 | PUBLIC dyn_spg_init ! routine called by opa module |
|---|
| 40 | |
|---|
| 41 | INTEGER :: nspg = 0 ! type of surface pressure gradient scheme defined from lk_dynspg_... |
|---|
| 42 | |
|---|
| 43 | ! ! Parameter to control the surface pressure gradient scheme |
|---|
| 44 | INTEGER, PARAMETER :: np_TS = 1 ! split-explicit time stepping (Time-Splitting) |
|---|
| 45 | INTEGER, PARAMETER :: np_EXP = 0 ! explicit time stepping |
|---|
| 46 | INTEGER, PARAMETER :: np_NO =-1 ! no surface pressure gradient, no scheme |
|---|
| 47 | ! |
|---|
| 48 | REAL(dp) :: zt0step ! Time of day at the beginning of the time step |
|---|
| 49 | |
|---|
| 50 | !! * Substitutions |
|---|
| 51 | # include "do_loop_substitute.h90" |
|---|
| 52 | # include "single_precision_substitute.h90" |
|---|
| 53 | !!---------------------------------------------------------------------- |
|---|
| 54 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 55 | !! $Id$ |
|---|
| 56 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 57 | !!---------------------------------------------------------------------- |
|---|
| 58 | CONTAINS |
|---|
| 59 | |
|---|
| 60 | SUBROUTINE dyn_spg( kt, Kbb, Kmm, Krhs, puu, pvv, pssh, puu_b, pvv_b, Kaa, k_only_ADV ) |
|---|
| 61 | !!---------------------------------------------------------------------- |
|---|
| 62 | !! *** ROUTINE dyn_spg *** |
|---|
| 63 | !! |
|---|
| 64 | !! ** Purpose : compute surface pressure gradient including the |
|---|
| 65 | !! atmospheric pressure forcing (ln_apr_dyn=T). |
|---|
| 66 | !! |
|---|
| 67 | !! ** Method : Two schemes: |
|---|
| 68 | !! - explicit : the spg is evaluated at now |
|---|
| 69 | !! - split-explicit : a time splitting technique is used |
|---|
| 70 | !! |
|---|
| 71 | !! ln_apr_dyn=T : the atmospheric pressure forcing is applied |
|---|
| 72 | !! as the gradient of the inverse barometer ssh: |
|---|
| 73 | !! apgu = - 1/rho0 di[apr] = 0.5*grav di[ssh_ib+ssh_ibb] |
|---|
| 74 | !! apgv = - 1/rho0 dj[apr] = 0.5*grav dj[ssh_ib+ssh_ibb] |
|---|
| 75 | !! Note that as all external forcing a time averaging over a two rn_Dt |
|---|
| 76 | !! period is used to prevent the divergence of odd and even time step. |
|---|
| 77 | !!---------------------------------------------------------------------- |
|---|
| 78 | INTEGER , INTENT( in ) :: kt ! ocean time-step index |
|---|
| 79 | INTEGER , INTENT( in ) :: Kbb, Kmm, Krhs, Kaa ! ocean time level indices |
|---|
| 80 | REAL(dp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation |
|---|
| 81 | REAL(dp), DIMENSION(jpi,jpj,jpt) , INTENT(inout) :: pssh ! SSH |
|---|
| 82 | REAL(dp), DIMENSION(jpi,jpj,jpt) , INTENT(inout) :: puu_b, pvv_b !barotropic velocities at main time levels |
|---|
| 83 | INTEGER , OPTIONAL , INTENT( in ) :: k_only_ADV ! only Advection in the RHS |
|---|
| 84 | ! |
|---|
| 85 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 86 | REAL(wp) :: zg_2, zintp, zgrho0r, zld! local scalars |
|---|
| 87 | REAL(dp) :: z2dt! local scalars |
|---|
| 88 | REAL(wp) , DIMENSION(jpi,jpj) :: zpgu, zpgv ! 2D workspace |
|---|
| 89 | REAL(dp), ALLOCATABLE, DIMENSION(:,:) :: zpice |
|---|
| 90 | REAL(dp), ALLOCATABLE, DIMENSION(:,:,:) :: ztrdu, ztrdv |
|---|
| 91 | !!---------------------------------------------------------------------- |
|---|
| 92 | ! |
|---|
| 93 | IF( ln_timing ) CALL timing_start('dyn_spg') |
|---|
| 94 | ! |
|---|
| 95 | IF( l_trddyn ) THEN ! temporary save of ta and sa trends |
|---|
| 96 | ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) ) |
|---|
| 97 | ztrdu(:,:,:) = puu(:,:,:,Krhs) |
|---|
| 98 | ztrdv(:,:,:) = pvv(:,:,:,Krhs) |
|---|
| 99 | ENDIF |
|---|
| 100 | ! |
|---|
| 101 | IF( ln_apr_dyn & ! atmos. pressure |
|---|
| 102 | .OR. ( .NOT.ln_dynspg_ts .AND. (ln_tide_pot .AND. ln_tide) ) & ! tide potential (no time slitting) |
|---|
| 103 | .OR. ln_ice_embd & ! embedded sea-ice |
|---|
| 104 | .OR. ( ln_wave .and. ln_bern_srfc ) ) THEN ! depth-independent Bernoulli head |
|---|
| 105 | ! |
|---|
| 106 | DO_2D( 0, 0, 0, 0 ) |
|---|
| 107 | zpgu(ji,jj) = 0._wp |
|---|
| 108 | zpgv(ji,jj) = 0._wp |
|---|
| 109 | END_2D |
|---|
| 110 | ! |
|---|
| 111 | IF( ln_apr_dyn .AND. .NOT.ln_dynspg_ts ) THEN !== Atmospheric pressure gradient (added later in time-split case) ==! |
|---|
| 112 | zg_2 = grav * 0.5 |
|---|
| 113 | DO_2D( 0, 0, 0, 0 ) ! gradient of Patm using inverse barometer ssh |
|---|
| 114 | zpgu(ji,jj) = zpgu(ji,jj) + zg_2 * ( ssh_ib (ji+1,jj) - ssh_ib (ji,jj) & |
|---|
| 115 | & + ssh_ibb(ji+1,jj) - ssh_ibb(ji,jj) ) * r1_e1u(ji,jj) |
|---|
| 116 | zpgv(ji,jj) = zpgv(ji,jj) + zg_2 * ( ssh_ib (ji,jj+1) - ssh_ib (ji,jj) & |
|---|
| 117 | & + ssh_ibb(ji,jj+1) - ssh_ibb(ji,jj) ) * r1_e2v(ji,jj) |
|---|
| 118 | END_2D |
|---|
| 119 | ENDIF |
|---|
| 120 | ! |
|---|
| 121 | ! !== tide potential forcing term ==! |
|---|
| 122 | IF( .NOT.ln_dynspg_ts .AND. ( ln_tide_pot .AND. ln_tide ) ) THEN ! N.B. added directly at sub-time-step in ts-case |
|---|
| 123 | ! |
|---|
| 124 | ! Update tide potential at the beginning of current time step |
|---|
| 125 | zt0step = REAL(nsec_day, wp)-0.5_wp*rn_Dt |
|---|
| 126 | CALL upd_tide(zt0step, Kmm) |
|---|
| 127 | ! |
|---|
| 128 | DO_2D( 0, 0, 0, 0 ) ! add tide potential forcing |
|---|
| 129 | zpgu(ji,jj) = zpgu(ji,jj) + grav * ( pot_astro(ji+1,jj) - pot_astro(ji,jj) ) * r1_e1u(ji,jj) |
|---|
| 130 | zpgv(ji,jj) = zpgv(ji,jj) + grav * ( pot_astro(ji,jj+1) - pot_astro(ji,jj) ) * r1_e2v(ji,jj) |
|---|
| 131 | END_2D |
|---|
| 132 | ! |
|---|
| 133 | IF (ln_scal_load) THEN |
|---|
| 134 | zld = rn_scal_load * grav |
|---|
| 135 | DO_2D( 0, 0, 0, 0 ) ! add scalar approximation for load potential |
|---|
| 136 | zpgu(ji,jj) = zpgu(ji,jj) + zld * ( pssh(ji+1,jj,Kmm) - pssh(ji,jj,Kmm) ) * r1_e1u(ji,jj) |
|---|
| 137 | zpgv(ji,jj) = zpgv(ji,jj) + zld * ( pssh(ji,jj+1,Kmm) - pssh(ji,jj,Kmm) ) * r1_e2v(ji,jj) |
|---|
| 138 | END_2D |
|---|
| 139 | ENDIF |
|---|
| 140 | ENDIF |
|---|
| 141 | ! |
|---|
| 142 | IF( ln_ice_embd ) THEN !== embedded sea ice: Pressure gradient due to snow-ice mass ==! |
|---|
| 143 | ALLOCATE( zpice(jpi,jpj) ) |
|---|
| 144 | zintp = REAL( MOD( kt-1, nn_fsbc ) ) / REAL( nn_fsbc ) |
|---|
| 145 | zgrho0r = - grav * r1_rho0 |
|---|
| 146 | zpice(:,:) = ( zintp * snwice_mass(:,:) + ( 1.- zintp ) * snwice_mass_b(:,:) ) * zgrho0r |
|---|
| 147 | DO_2D( 0, 0, 0, 0 ) |
|---|
| 148 | zpgu(ji,jj) = zpgu(ji,jj) + ( zpice(ji+1,jj) - zpice(ji,jj) ) * r1_e1u(ji,jj) |
|---|
| 149 | zpgv(ji,jj) = zpgv(ji,jj) + ( zpice(ji,jj+1) - zpice(ji,jj) ) * r1_e2v(ji,jj) |
|---|
| 150 | END_2D |
|---|
| 151 | DEALLOCATE( zpice ) |
|---|
| 152 | ENDIF |
|---|
| 153 | ! |
|---|
| 154 | IF( ln_wave .and. ln_bern_srfc ) THEN !== Add J terms: depth-independent Bernoulli head |
|---|
| 155 | DO_2D( 0, 0, 0, 0 ) |
|---|
| 156 | zpgu(ji,jj) = zpgu(ji,jj) + ( bhd_wave(ji+1,jj) - bhd_wave(ji,jj) ) / e1u(ji,jj) !++ bhd_wave from wave model in m2/s2 [BHD parameters in WW3] |
|---|
| 157 | zpgv(ji,jj) = zpgv(ji,jj) + ( bhd_wave(ji,jj+1) - bhd_wave(ji,jj) ) / e2v(ji,jj) |
|---|
| 158 | END_2D |
|---|
| 159 | ENDIF |
|---|
| 160 | ! |
|---|
| 161 | DO_3D( 0, 0, 0, 0, 1, jpkm1 ) !== Add all terms to the general trend |
|---|
| 162 | puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zpgu(ji,jj) |
|---|
| 163 | pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zpgv(ji,jj) |
|---|
| 164 | END_3D |
|---|
| 165 | ! |
|---|
| 166 | !!gm add here a call to dyn_trd for ice pressure gradient, the surf pressure trends ???? |
|---|
| 167 | ! |
|---|
| 168 | ENDIF |
|---|
| 169 | ! |
|---|
| 170 | SELECT CASE ( nspg ) !== surface pressure gradient computed and add to the general trend ==! |
|---|
| 171 | CASE ( np_EXP ) ; CALL dyn_spg_exp( kt, Kmm, puu, pvv, Krhs ) ! explicit |
|---|
| 172 | CASE ( np_TS ) ; CALL dyn_spg_ts ( kt, Kbb, Kmm, Krhs, puu, pvv, pssh, puu_b, pvv_b, Kaa, k_only_ADV ) ! time-splitting |
|---|
| 173 | END SELECT |
|---|
| 174 | ! |
|---|
| 175 | IF( l_trddyn ) THEN ! save the surface pressure gradient trends for further diagnostics |
|---|
| 176 | ztrdu(:,:,:) = puu(:,:,:,Krhs) - ztrdu(:,:,:) |
|---|
| 177 | ztrdv(:,:,:) = pvv(:,:,:,Krhs) - ztrdv(:,:,:) |
|---|
| 178 | CALL trd_dyn( ztrdu, ztrdv, jpdyn_spg, kt, Kmm ) |
|---|
| 179 | DEALLOCATE( ztrdu , ztrdv ) |
|---|
| 180 | ENDIF |
|---|
| 181 | ! ! print mean trends (used for debugging) |
|---|
| 182 | IF(sn_cfctl%l_prtctl) CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' spg - Ua: ', mask1=umask, & |
|---|
| 183 | & tab3d_2=pvv(:,:,:,Krhs), clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' ) |
|---|
| 184 | ! |
|---|
| 185 | IF( ln_timing ) CALL timing_stop('dyn_spg') |
|---|
| 186 | ! |
|---|
| 187 | END SUBROUTINE dyn_spg |
|---|
| 188 | |
|---|
| 189 | |
|---|
| 190 | SUBROUTINE dyn_spg_init |
|---|
| 191 | !!--------------------------------------------------------------------- |
|---|
| 192 | !! *** ROUTINE dyn_spg_init *** |
|---|
| 193 | !! |
|---|
| 194 | !! ** Purpose : Control the consistency between namelist options for |
|---|
| 195 | !! surface pressure gradient schemes |
|---|
| 196 | !!---------------------------------------------------------------------- |
|---|
| 197 | INTEGER :: ioptio, ios ! local integers |
|---|
| 198 | ! |
|---|
| 199 | NAMELIST/namdyn_spg/ ln_dynspg_exp , ln_dynspg_ts, & |
|---|
| 200 | & ln_bt_fw, ln_bt_av , ln_bt_auto , & |
|---|
| 201 | & nn_e , rn_bt_cmax, nn_bt_flt, rn_bt_alpha |
|---|
| 202 | !!---------------------------------------------------------------------- |
|---|
| 203 | ! |
|---|
| 204 | IF(lwp) THEN |
|---|
| 205 | WRITE(numout,*) |
|---|
| 206 | WRITE(numout,*) 'dyn_spg_init : choice of the surface pressure gradient scheme' |
|---|
| 207 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 208 | ENDIF |
|---|
| 209 | ! |
|---|
| 210 | READ ( numnam_ref, namdyn_spg, IOSTAT = ios, ERR = 901) |
|---|
| 211 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_spg in reference namelist' ) |
|---|
| 212 | ! |
|---|
| 213 | READ ( numnam_cfg, namdyn_spg, IOSTAT = ios, ERR = 902 ) |
|---|
| 214 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namdyn_spg in configuration namelist' ) |
|---|
| 215 | IF(lwm) WRITE ( numond, namdyn_spg ) |
|---|
| 216 | ! |
|---|
| 217 | IF(lwp) THEN ! Namelist print |
|---|
| 218 | WRITE(numout,*) ' Namelist : namdyn_spg ' |
|---|
| 219 | WRITE(numout,*) ' Explicit free surface ln_dynspg_exp = ', ln_dynspg_exp |
|---|
| 220 | WRITE(numout,*) ' Free surface with time splitting ln_dynspg_ts = ', ln_dynspg_ts |
|---|
| 221 | ENDIF |
|---|
| 222 | ! ! Control of surface pressure gradient scheme options |
|---|
| 223 | nspg = np_NO ; ioptio = 0 |
|---|
| 224 | IF( ln_dynspg_exp ) THEN ; nspg = np_EXP ; ioptio = ioptio + 1 ; ENDIF |
|---|
| 225 | IF( ln_dynspg_ts ) THEN ; nspg = np_TS ; ioptio = ioptio + 1 ; ENDIF |
|---|
| 226 | ! |
|---|
| 227 | IF( ioptio > 1 ) CALL ctl_stop( 'Choose only one surface pressure gradient scheme' ) |
|---|
| 228 | IF( ioptio == 0 ) CALL ctl_warn( 'NO surface pressure gradient trend in momentum Eqs.' ) |
|---|
| 229 | IF( ln_dynspg_exp .AND. ln_isfcav ) & |
|---|
| 230 | & CALL ctl_stop( ' dynspg_exp not tested with ice shelf cavity ' ) |
|---|
| 231 | ! |
|---|
| 232 | IF(lwp) THEN |
|---|
| 233 | WRITE(numout,*) |
|---|
| 234 | IF( nspg == np_EXP ) WRITE(numout,*) ' ==>>> explicit free surface' |
|---|
| 235 | IF( nspg == np_TS ) WRITE(numout,*) ' ==>>> free surface with time splitting scheme' |
|---|
| 236 | IF( nspg == np_NO ) WRITE(numout,*) ' ==>>> No surface surface pressure gradient trend in momentum Eqs.' |
|---|
| 237 | ENDIF |
|---|
| 238 | ! |
|---|
| 239 | IF( nspg == np_TS ) THEN ! split-explicit scheme initialisation |
|---|
| 240 | CALL dyn_spg_ts_init ! do it first: set nn_e used to allocate some arrays later on |
|---|
| 241 | ENDIF |
|---|
| 242 | ! |
|---|
| 243 | END SUBROUTINE dyn_spg_init |
|---|
| 244 | |
|---|
| 245 | !!====================================================================== |
|---|
| 246 | END MODULE dynspg |
|---|
