New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
obs_inter_sup.F90 in NEMO/branches/2021/dev_r14116_HPC-10_mcastril_Mixed_Precision_implementation/src/OCE/OBS – NEMO

source: NEMO/branches/2021/dev_r14116_HPC-10_mcastril_Mixed_Precision_implementation/src/OCE/OBS/obs_inter_sup.F90 @ 15540

Last change on this file since 15540 was 15540, checked in by sparonuz, 3 years ago

Mixed precision version, tested up to 30 years on ORCA2.
  • Property svn:keywords set to Id
File size: 13.8 KB
Line 
1MODULE obs_inter_sup
2   !!=====================================================================
3   !!                       ***  MODULE obs_inter_sup  ***
4   !! Observation diagnostics: Support for interpolation
5   !!=====================================================================
6
7   !!----------------------------------------------------------------------
8   !!   obs_int_comm_3d : Get 3D interpolation stencil
9   !!   obs_int_comm_2d : Get 2D interpolation stencil
10   !!---------------------------------------------------------------------
11   !! * Modules used
12   USE par_kind        ! Precision variables
13   USE dom_oce         ! Domain variables
14   USE mpp_map         ! Map of processor points
15   USE lib_mpp         ! MPP stuff
16   USE obs_mpp         ! MPP stuff for observations
17   USE obs_grid        ! Grid tools
18   USE in_out_manager  ! I/O stuff
19
20   IMPLICIT NONE
21
22   !! * Routine accessibility
23   PRIVATE
24   
25   PUBLIC obs_int_comm_3d, & ! Get 3D interpolation stencil
26      &   obs_int_comm_2d    ! Get 2D interpolation stencil
27   
28   !!----------------------------------------------------------------------
29   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
30   !! $Id$
31   !! Software governed by the CeCILL license (see ./LICENSE)
32   !!----------------------------------------------------------------------
33
34CONTAINS
35
36   SUBROUTINE obs_int_comm_3d( kptsi, kptsj, kobs, kpi, kpj, kpk, kgrdi, kgrdj, &
37      &                        pval, pgval, kproc )
38      !!----------------------------------------------------------------------
39      !!                    ***  ROUTINE obs_int_comm_3d  ***
40      !!         
41      !! ** Purpose : Get 3D interpolation stencil
42      !!
43      !! ** Method  : Either on-demand communication with
44      !!              obs_int_comm_3d_global
45      !!              or local memory with
46      !!              obs_int_comm_3D_local
47      !!              depending on ln_global_grid
48      !!
49      !! ** Action  :
50      !!
51      !! History :
52      !!        !  08-02  (K. Mogensen)  Original code
53      !!----------------------------------------------------------------------
54      !! * Arguments
55      INTEGER, INTENT(IN) :: kptsi     ! Number of i horizontal points per stencil
56      INTEGER, INTENT(IN) :: kptsj     ! Number of j horizontal points per stencil
57      INTEGER, INTENT(IN) :: kobs      ! Local number of observations
58      INTEGER, INTENT(IN) :: kpi       ! Number of points in i direction
59      INTEGER, INTENT(IN) :: kpj       ! Number of points in j direction
60      INTEGER, INTENT(IN) :: kpk       ! Number of levels
61      INTEGER, DIMENSION(kptsi,kptsj,kobs), INTENT(IN) :: &
62         & kgrdi, &         ! i,j indicies for each stencil
63         & kgrdj
64      INTEGER, OPTIONAL, DIMENSION(kptsi,kptsj,kobs), INTENT(IN) :: &
65         & kproc            ! Precomputed processor for each i,j,iobs points
66      REAL(KIND=dp), DIMENSION(kpi,kpj,kpk), INTENT(IN) ::&
67         & pval             ! Local 3D array to extract data from
68      REAL(KIND=dp), DIMENSION(kptsi,kptsj,kpk,kobs), INTENT(OUT) ::&
69         & pgval            ! Stencil at each point
70      !! * Local declarations
71     
72      IF (ln_grid_global) THEN
73         
74         IF (PRESENT(kproc)) THEN
75
76            CALL obs_int_comm_3d_global( kptsi, kptsj, kobs, kpi, kpj, kpk, kgrdi, &
77               &                         kgrdj, pval, pgval, kproc=kproc )
78
79         ELSE
80
81            CALL obs_int_comm_3d_global( kptsi, kptsj, kobs, kpi, kpj, kpk, kgrdi, &
82               &                         kgrdj, pval, pgval )
83
84         ENDIF
85
86      ELSE
87
88         CALL obs_int_comm_3d_local( kptsi, kptsj, kobs, kpi, kpj, kpk, kgrdi, kgrdj, &
89            &                        pval, pgval )
90
91      ENDIF
92
93   END SUBROUTINE obs_int_comm_3d
94
95   SUBROUTINE obs_int_comm_2d( kptsi, kptsj, kobs, kpi, kpj, kgrdi, kgrdj, pval, pgval, &
96      &                        kproc )
97      !!----------------------------------------------------------------------
98      !!                    ***  ROUTINE obs_int_comm_2d  ***
99      !!         
100      !! ** Purpose : Get 2D interpolation stencil
101      !!
102      !! ** Method  : Call to obs_int_comm_3d
103      !!
104      !! ** Action  :
105      !!
106      !! History :
107      !!        !  08-02  (K. Mogensen)  Original code
108      !!----------------------------------------------------------------------
109      !!
110      !! * Arguments
111      INTEGER, INTENT(IN) :: kptsi        ! Number of i horizontal points per stencil
112      INTEGER, INTENT(IN) :: kptsj        ! Number of j horizontal points per stencil
113      INTEGER, INTENT(IN) :: kobs          ! Local number of observations
114      INTEGER, INTENT(IN) :: kpi          ! Number of model grid points in i direction
115      INTEGER, INTENT(IN) :: kpj          ! Number of model grid points in j direction
116      INTEGER, DIMENSION(kptsi,kptsj,kobs), INTENT(IN) :: &
117         & kgrdi, &         ! i,j indicies for each stencil
118         & kgrdj
119      INTEGER, OPTIONAL, DIMENSION(kptsi,kptsj,kobs), INTENT(IN) :: &
120         & kproc            ! Precomputed processor for each i,j,iobs points
121      REAL(KIND=dp), DIMENSION(kpi,kpj), INTENT(IN) ::&
122         & pval             ! Local 3D array to extra data from
123      REAL(KIND=dp), DIMENSION(kptsi,kptsj,kobs), INTENT(OUT) ::&
124         & pgval            ! Stencil at each point
125      !! * Local declarations
126      REAL(KIND=dp), DIMENSION(jpi,jpj,1) ::   zval
127      REAL(KIND=dp), DIMENSION(kptsi,kptsj,1,kobs) ::  zgval
128
129      ! Set up local "3D" buffer
130
131      zval(:,:,1) = pval(:,:)
132
133      ! Call the 3D version
134
135      IF (PRESENT(kproc)) THEN
136
137         CALL obs_int_comm_3d( kptsi, kptsj, kobs, kpi, kpj, 1, kgrdi, kgrdj, zval, &
138            &                  zgval, kproc=kproc )
139      ELSE
140
141         CALL obs_int_comm_3d( kptsi, kptsj, kobs, kpi, kpj, 1, kgrdi, kgrdj, zval, &
142            &                  zgval )
143
144      ENDIF
145
146      ! Copy "3D" data back to 2D
147
148      pgval(:,:,:) = zgval(:,:,1,:)
149
150   END SUBROUTINE obs_int_comm_2d
151
152   SUBROUTINE obs_int_comm_3d_global( kptsi, kptsj, kobs, kpi, kpj, kpk, kgrdi, kgrdj, &
153      &                               pval, pgval, kproc )
154      !!----------------------------------------------------------------------
155      !!                    ***  ROUTINE obs_int_comm_3d_global  ***
156      !!         
157      !! ** Purpose : Get 3D interpolation stencil (global version)
158      !!
159      !! ** Method  : On-demand communication where each processor send its
160      !!              list of (i,j) of points to all processors and receive
161      !!              the corresponding values
162      !!
163      !! ** Action  :
164      !!
165      !! History :
166      !!        !  08-02  (K. Mogensen)  Original code
167      !!----------------------------------------------------------------------
168      !! * Arguments
169      INTEGER, INTENT(IN) :: kptsi     ! Number of i horizontal points per stencil
170      INTEGER, INTENT(IN) :: kptsj     ! Number of j horizontal points per stencil
171      INTEGER, INTENT(IN) :: kobs      ! Local number of observations
172      INTEGER, INTENT(IN) :: kpi       ! Number of model points in i direction
173      INTEGER, INTENT(IN) :: kpj       ! Number of model points in j direction
174      INTEGER, INTENT(IN) :: kpk       ! Number of levels
175      INTEGER, DIMENSION(kptsi,kptsj,kobs), INTENT(IN) :: &
176         & kgrdi, &         ! i,j indicies for each stencil
177         & kgrdj
178      INTEGER, OPTIONAL, DIMENSION(kptsi,kptsj,kobs), INTENT(IN) :: &
179         & kproc            ! Precomputed processor for each i,j,iobs points
180      REAL(KIND=dp), DIMENSION(kpi,kpj,kpk), INTENT(IN) ::&
181         & pval             ! Local 3D array to extract data from
182      REAL(KIND=dp), DIMENSION(kptsi,kptsj,kpk,kobs), INTENT(OUT) ::&
183         & pgval            ! Stencil at each point
184      !! * Local declarations
185      REAL(KIND=dp), DIMENSION(:,:), ALLOCATABLE :: &
186         & zsend, &
187         & zrecv
188      INTEGER, DIMENSION(:), ALLOCATABLE :: &
189         & igrdij_send, &
190         & igrdij_recv
191      INTEGER, DIMENSION(kptsi,kptsj,kobs) :: &
192         & iorder, &
193         & iproc
194      INTEGER :: nplocal(jpnij)
195      INTEGER :: npglobal(jpnij)
196      INTEGER :: ji
197      INTEGER :: jj
198      INTEGER :: jk
199      INTEGER :: jp
200      INTEGER :: jobs
201      INTEGER :: it
202      INTEGER :: itot
203      INTEGER :: ii
204      INTEGER :: ij
205
206      ! Check valid points
207
208      IF ( ( MAXVAL(kgrdi) > jpiglo ) .OR. ( MINVAL(kgrdi) < 1 ) .OR. &
209         & ( MAXVAL(kgrdj) > jpjglo ) .OR. ( MINVAL(kgrdj) < 1 ) ) THEN
210
211         CALL ctl_stop( 'Error in obs_int_comm_3d_global', &
212            &           'Point outside global domain' )
213
214      ENDIF
215
216      ! Count number of points on each processors
217
218      nplocal(:) = 0
219      IF (PRESENT(kproc)) THEN
220         iproc(:,:,:) = kproc(:,:,:)
221         DO jobs = 1, kobs
222            DO jj = 1, kptsj
223               DO ji = 1, kptsi
224                  nplocal(iproc(ji,jj,jobs)) = nplocal(iproc(ji,jj,jobs)) + 1
225               END DO
226            END DO
227         END DO
228      ELSE
229         DO jobs = 1, kobs
230            DO jj = 1, kptsj
231               DO ji = 1, kptsi
232                  iproc(ji,jj,jobs) = mppmap(kgrdi(ji,jj,jobs),&
233                     &                       kgrdj(ji,jj,jobs))
234                  nplocal(iproc(ji,jj,jobs)) = nplocal(iproc(ji,jj,jobs)) + 1
235               END DO
236            END DO
237         END DO
238      ENDIF
239
240      ! Send local number of points and receive points on current domain
241
242      CALL mpp_alltoall_int( 1, nplocal, npglobal )
243
244      ! Allocate message parsing workspace
245
246      itot = SUM(npglobal)
247
248      ALLOCATE( &
249         & igrdij_send(kptsi*kptsj*kobs*2), &
250         & igrdij_recv(itot*2),             &
251         & zsend(kpk,itot),                 &
252         & zrecv(kpk,kptsi*kptsj*kobs)      &
253         & )
254
255      ! Pack buffers for list of points
256
257      it = 0
258      DO jp = 1, jpnij 
259         DO jobs = 1, kobs
260            DO jj = 1, kptsj
261               DO ji = 1, kptsi
262                  IF ( iproc(ji,jj,jobs) == jp ) THEN
263                     it = it + 1
264                     iorder(ji,jj,jobs) = it
265                     igrdij_send(2*it-1) = kgrdi(ji,jj,jobs)
266                     igrdij_send(2*it  ) = kgrdj(ji,jj,jobs)
267                  ENDIF
268               END DO
269            END DO
270         END DO
271      END DO
272
273      ! Send and recieve buffers for list of points
274
275      CALL mpp_alltoallv_int( igrdij_send, kptsi*kptsj*kobs*2, nplocal(:)*2, &
276         &                    igrdij_recv, itot*2, npglobal(:)*2 )
277
278      ! Pack interpolation data to be sent
279
280      DO ji = 1, itot
281         ii = mi1(igrdij_recv(2*ji-1))
282         ij = mj1(igrdij_recv(2*ji))
283         DO jk = 1, kpk
284            zsend(jk,ji) = pval(ii,ij,jk)
285         END DO
286      END DO
287
288      ! Re-adjust sizes
289
290      nplocal(:)  = kpk*nplocal(:)
291      npglobal(:) = kpk*npglobal(:)
292
293
294      ! Send and receive data for interpolation stencil
295
296      CALL mpp_alltoallv_real( zsend, kpk*itot,             npglobal, &
297         &                     zrecv, kpk*kptsi*kptsj*kobs, nplocal )
298
299      ! Copy the received data into output data structure
300     
301      DO jobs = 1, kobs
302         DO jj = 1, kptsj
303            DO ji = 1, kptsi
304               it = iorder(ji,jj,jobs) 
305               DO jk = 1, kpk
306                  pgval(ji,jj,jk,jobs) = zrecv(jk,it)
307               END DO
308            END DO
309         END DO
310      END DO
311
312      ! Deallocate message parsing workspace
313
314      DEALLOCATE( &
315         & igrdij_send, &
316         & igrdij_recv, &
317         & zsend,       &
318         & zrecv        &
319         & )
320
321   END SUBROUTINE obs_int_comm_3d_global
322   
323   SUBROUTINE obs_int_comm_3d_local( kptsi, kptsj, kobs, kpi, kpj, kpk, kgrdi, kgrdj, &
324      &                              pval, pgval )
325      !!----------------------------------------------------------------------
326      !!                    ***  ROUTINE obs_int_comm_3d_global  ***
327      !!         
328      !! ** Purpose : Get 3D interpolation stencil (global version)
329      !!
330      !! ** Method  : On-demand communication where each processor send its
331      !!              list of (i,j) of points to all processors and receive
332      !!              the corresponding values
333      !!
334      !! ** Action  :
335      !!
336      !! History :
337      !!        !  08-02  (K. Mogensen)  Original code
338      !!----------------------------------------------------------------------
339      !! * Arguments
340      INTEGER, INTENT(IN) :: kptsi        ! Number of i horizontal points per stencil
341      INTEGER, INTENT(IN) :: kptsj        ! Number of j horizontal points per stencil
342      INTEGER, INTENT(IN) :: kobs         ! Local number of observations
343      INTEGER, INTENT(IN) :: kpi          ! Number of model points in i direction
344      INTEGER, INTENT(IN) :: kpj          ! Number of model points in j direction
345      INTEGER, INTENT(IN) :: kpk          ! Number of levels
346      INTEGER, DIMENSION(kptsi,kptsj,kobs), INTENT(IN) :: &
347         & kgrdi, &         ! i,j indicies for each stencil
348         & kgrdj
349      REAL(KIND=dp), DIMENSION(kpi,kpj,kpk), INTENT(IN) ::&
350         & pval             ! Local 3D array to extract data from
351      REAL(KIND=dp), DIMENSION(kptsi,kptsj,kpk,kobs), INTENT(OUT) ::&
352         & pgval            ! Stencil at each point
353      !! * Local declarations
354      INTEGER ::  ji
355      INTEGER ::  jj
356      INTEGER ::  jk
357      INTEGER ::  jobs
358
359      ! Check valid points
360
361      IF ( ( MAXVAL(kgrdi) > jpi ) .OR. ( MINVAL(kgrdi) < 1 ) .OR. &
362         & ( MAXVAL(kgrdj) > jpj ) .OR. ( MINVAL(kgrdj) < 1 ) ) THEN
363         
364         CALL ctl_stop( 'Error in obs_int_comm_3d_local', &
365            &           'Point outside local domain' )
366 
367      ENDIF
368
369      ! Copy local data
370
371      DO jobs = 1, kobs
372         DO jj = 1, kptsj
373            DO ji = 1, kptsi
374               DO jk = 1, kpk
375                  pgval(ji,jj,jk,jobs) = &
376                     &            pval(kgrdi(ji,jj,jobs),kgrdj(ji,jj,jobs),jk)
377               END DO
378            END DO
379         END DO
380      END DO
381
382   END SUBROUTINE obs_int_comm_3d_local
383
384END MODULE obs_inter_sup
385 
Note: See TracBrowser for help on using the repository browser.