New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcfwb.F90 in NEMO/branches/2021/dev_r14116_HPC-10_mcastril_Mixed_Precision_implementation/src/OCE/SBC – NEMO

source: NEMO/branches/2021/dev_r14116_HPC-10_mcastril_Mixed_Precision_implementation/src/OCE/SBC/sbcfwb.F90 @ 15660

Last change on this file since 15660 was 15540, checked in by sparonuz, 3 years ago

Mixed precision version, tested up to 30 years on ORCA2.
  • Property svn:keywords set to Id
File size: 13.5 KB
Line 
1MODULE sbcfwb
2   !!======================================================================
3   !!                       ***  MODULE  sbcfwb  ***
4   !! Ocean fluxes   : domain averaged freshwater budget
5   !!======================================================================
6   !! History :  OPA  ! 2001-02  (E. Durand)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-08  (G. Madec)  Surface module
9   !!            3.2  ! 2009-07  (C. Talandier) emp mean s spread over erp area
10   !!            3.6  ! 2014-11  (P. Mathiot  ) add ice shelf melting
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_fwb       : freshwater budget for global ocean configurations (free surface & forced mode)
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and tracers
17   USE dom_oce        ! ocean space and time domain
18   USE sbc_oce        ! surface ocean boundary condition
19   USE isf_oce , ONLY : fwfisf_cav, fwfisf_par                    ! ice shelf melting contribution
20   USE sbc_ice , ONLY : snwice_mass, snwice_mass_b, snwice_fmass
21   USE phycst         ! physical constants
22   USE sbcrnf         ! ocean runoffs
23   USE sbcssr         ! Sea-Surface damping terms
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            ! IOM
27   USE lib_mpp        ! distribued memory computing library
28   USE timing         ! Timing
29   USE lbclnk         ! ocean lateral boundary conditions
30   USE lib_fortran    !
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   sbc_fwb    ! routine called by step
36
37   REAL(wp) ::   rn_fwb0   ! initial freshwater adjustment flux [kg/m2/s] (nn_fwb = 2 only)
38   REAL(dp) ::   a_fwb     ! annual domain averaged freshwater budget from the
39                           ! previous year
40   REAL(dp) ::   area      ! global mean ocean surface (interior domain)
41
42#  include "single_precision_substitute.h90"
43
44   !!----------------------------------------------------------------------
45   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
46   !! $Id$
47   !! Software governed by the CeCILL license (see ./LICENSE)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc, Kmm )
52      !!---------------------------------------------------------------------
53      !!                  ***  ROUTINE sbc_fwb  ***
54      !!
55      !! ** Purpose :   Control the mean sea surface drift
56      !!
57      !! ** Method  :   several ways  depending on kn_fwb
58      !!                =0 no control
59      !!                =1 global mean of emp set to zero at each nn_fsbc time step
60      !!                =2 annual global mean corrected from previous year
61      !!                =3 global mean of emp set to zero at each nn_fsbc time step
62      !!                   & spread out over erp area depending its sign
63      !! Note: if sea ice is embedded it is taken into account when computing the budget
64      !!----------------------------------------------------------------------
65      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
66      INTEGER, INTENT( in ) ::   kn_fsbc  !
67      INTEGER, INTENT( in ) ::   kn_fwb   ! ocean time-step index
68      INTEGER, INTENT( in ) ::   Kmm      ! ocean time level index
69      !
70      INTEGER  ::   ios, inum, ikty       ! local integers
71      REAL(wp) ::   z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp                ! local scalars
72      REAL(wp) ::   zsurf_neg, zsurf_pos, zsurf_tospread, zcoef          !   -      -
73      REAL(dp), ALLOCATABLE, DIMENSION(:,:) ::   ztmsk_neg, ztmsk_pos, z_wgt ! 2D workspaces
74      REAL(dp), ALLOCATABLE, DIMENSION(:,:) ::   ztmsk_tospread, zerp_cor    !   -      -
75      REAL(dp)   ,DIMENSION(1) ::   z_fwfprv 
76      COMPLEX(dp),DIMENSION(1) ::   y_fwfnow 
77      !
78      NAMELIST/namsbc_fwb/rn_fwb0
79      !!----------------------------------------------------------------------
80      !
81      IF( kt == nit000 ) THEN
82         READ( numnam_ref, namsbc_fwb, IOSTAT = ios, ERR = 901 )
83901      IF( ios /= 0 ) CALL ctl_nam( ios, 'namsbc_fwb in reference namelist'     )
84         READ( numnam_cfg, namsbc_fwb, IOSTAT = ios, ERR = 902 )
85902      IF( ios >  0 ) CALL ctl_nam( ios, 'namsbc_fwb in configuration namelist' )
86         IF(lwm) WRITE( numond, namsbc_fwb )
87         IF(lwp) THEN
88            WRITE(numout,*)
89            WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction'
90            WRITE(numout,*) '~~~~~~~'
91            IF( kn_fwb == 1 )   WRITE(numout,*) '          instantaneously set to zero'
92            IF( kn_fwb == 3 )   WRITE(numout,*) '          fwf set to zero and spread out over erp area'
93            IF( kn_fwb == 2 ) THEN
94               WRITE(numout,*) '          adjusted from previous year budget'
95               WRITE(numout,*)
96               WRITE(numout,*) '   Namelist namsbc_fwb'
97               WRITE(numout,*) '      Initial freshwater adjustment flux [kg/m2/s] = ', rn_fwb0
98            END IF
99         ENDIF
100         !
101         IF( kn_fwb == 3 .AND. nn_sssr /= 2 )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' )
102         IF( kn_fwb == 3 .AND. ln_isfcav    )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 with ln_isfcav = .TRUE. not working, we stop ' )
103         !
104         area = glob_sum( 'sbcfwb', e1e2t(:,:) * tmask(:,:,1))           ! interior global domain surface
105         ! isf cavities are excluded because it can feedback to the melting with generation of inhibition of plumes
106         ! and in case of no melt, it can generate HSSW.
107         !
108#if ! defined key_si3 && ! defined key_cice
109         snwice_mass_b(:,:) = 0.e0               ! no sea-ice model is being used : no snow+ice mass
110         snwice_mass  (:,:) = 0.e0
111         snwice_fmass (:,:) = 0.e0
112#endif
113         !
114      ENDIF
115
116      SELECT CASE ( kn_fwb )
117      !
118      CASE ( 1 )                             !==  global mean fwf set to zero  ==!
119         !
120         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
121            y_fwfnow(1) = local_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf_cav(:,:) + fwfisf_par(:,:) - snwice_fmass(:,:) ) )
122            CALL mpp_delay_sum( 'sbcfwb', 'fwb', y_fwfnow(:), z_fwfprv(:), kt == nitend - nn_fsbc + 1 )
123            z_fwfprv(1) = z_fwfprv(1) / area
124            zcoef = z_fwfprv(1) * rcp
125            emp(:,:) = emp(:,:) - z_fwfprv(1)        * tmask(:,:,1)
126            qns(:,:) = qns(:,:) + zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
127            ! outputs
128            IF( iom_use('hflx_fwb_cea') )  CALL iom_put( 'hflx_fwb_cea', zcoef * sst_m(:,:) * tmask(:,:,1) )
129            IF( iom_use('vflx_fwb_cea') )  CALL iom_put( 'vflx_fwb_cea', z_fwfprv(1)        * tmask(:,:,1) )
130         ENDIF
131         !
132      CASE ( 2 )                             !==  fw adjustment based on fw budget at the end of the previous year  ==!
133         !
134         IF( kt == nit000 ) THEN                                                                    ! initialisation
135            !                                                                                       ! set the fw adjustment (a_fwb)
136            IF ( ln_rstart .AND. iom_varid( numror, 'a_fwb',   ldstop = .FALSE. ) > 0 ) THEN        !    as read from restart file
137               IF(lwp) WRITE(numout,*) 'sbc_fwb : reading FW-budget adjustment from restart file'
138               CALL iom_get( numror, 'a_fwb',   a_fwb )
139            ELSE                                                                                    !    as specified in namelist
140               a_fwb = rn_fwb0
141            END IF
142            !
143            IF(lwp)WRITE(numout,*)
144            IF(lwp)WRITE(numout,*)'sbc_fwb : initial freshwater-budget adjustment = ', a_fwb, 'kg/m2/s'
145            !
146         ENDIF   
147         !                                         ! Update a_fwb if new year start
148         ikty = 365 * 86400 / rn_Dt                  !!bug  use of 365 days leap year or 360d year !!!!!!!
149         IF( MOD( kt, ikty ) == 0 ) THEN
150                                                      ! mean sea level taking into account the ice+snow
151                                                      ! sum over the global domain
152            a_fwb   = glob_sum( 'sbcfwb', e1e2t(:,:) * ( ssh(:,:,Kmm) + snwice_mass(:,:) * r1_rho0 ) )
153            a_fwb   = a_fwb * 1.e+3 / ( area * rday * 365. )     ! convert in Kg/m3/s = mm/s
154!!gm        !                                                      !!bug 365d year
155         ENDIF
156         !
157         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN         ! correct the freshwater fluxes
158            zcoef = a_fwb * rcp
159            emp(:,:) = emp(:,:) + a_fwb              * tmask(:,:,1)
160            qns(:,:) = qns(:,:) - zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
161            ! outputs
162            IF( iom_use('hflx_fwb_cea') )  CALL iom_put( 'hflx_fwb_cea', -zcoef * sst_m(:,:) * tmask(:,:,1) )
163            IF( iom_use('vflx_fwb_cea') )  CALL iom_put( 'vflx_fwb_cea', -a_fwb              * tmask(:,:,1) )
164         ENDIF
165         ! Output restart information
166         IF( lrst_oce ) THEN
167            IF(lwp) WRITE(numout,*)
168            IF(lwp) WRITE(numout,*) 'sbc_fwb : writing FW-budget adjustment to ocean restart file at it = ', kt
169            IF(lwp) WRITE(numout,*) '~~~~'
170            CALL iom_rstput( kt, nitrst, numrow, 'a_fwb',   a_fwb )
171         END IF
172         !
173         IF( kt == nitend .AND. lwp ) WRITE(numout,*) 'sbc_fwb : final freshwater-budget adjustment = ', a_fwb, 'kg/m2/s'
174         !
175      CASE ( 3 )                             !==  global fwf set to zero and spread out over erp area  ==!
176         !
177         ALLOCATE( ztmsk_neg(jpi,jpj) , ztmsk_pos(jpi,jpj) , ztmsk_tospread(jpi,jpj) , z_wgt(jpi,jpj) , zerp_cor(jpi,jpj) )
178         !
179         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
180            ztmsk_pos(:,:) = tmask_i(:,:)                      ! Select <0 and >0 area of erp
181            WHERE( erp < 0._wp )   ztmsk_pos = 0._wp
182            ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:)
183            !                                                  ! fwf global mean (excluding ocean to ice/snow exchanges)
184            z_fwf     = glob_sum( 'sbcfwb', e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf_cav(:,:) + fwfisf_par(:,:) - snwice_fmass(:,:) ) ) / area
185            !           
186            IF( z_fwf < 0._wp ) THEN         ! spread out over >0 erp area to increase evaporation
187               zsurf_pos = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_pos(:,:) )
188               zsurf_tospread      = zsurf_pos
189               ztmsk_tospread(:,:) = ztmsk_pos(:,:)
190            ELSE                             ! spread out over <0 erp area to increase precipitation
191               zsurf_neg = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_neg(:,:) )  ! Area filled by <0 and >0 erp
192               zsurf_tospread      = zsurf_neg
193               ztmsk_tospread(:,:) = ztmsk_neg(:,:)
194            ENDIF
195            !
196            zsum_fwf   = glob_sum( 'sbcfwb', e1e2t(:,:) * z_fwf )         ! fwf global mean over <0 or >0 erp area
197!!gm :  zsum_fwf   = z_fwf * area   ???  it is right?  I think so....
198            z_fwf_nsrf =  zsum_fwf / ( zsurf_tospread + rsmall )
199            !                                                  ! weight to respect erp field 2D structure
200            zsum_erp   = glob_sum( 'sbcfwb', ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) )
201            z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall )
202            !                                                  ! final correction term to apply
203            zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:)
204            !
205!!gm   ===>>>>  lbc_lnk should be useless as all the computation is done over the whole domain !
206            CALL lbc_lnk( 'sbcfwb', zerp_cor, 'T', 1.0_wp )
207            !
208            emp(:,:) = emp(:,:) + zerp_cor(:,:)
209            qns(:,:) = qns(:,:) - zerp_cor(:,:) * rcp * sst_m(:,:)  ! account for change to the heat budget due to fw correction
210            erp(:,:) = erp(:,:) + zerp_cor(:,:)
211            ! outputs
212            IF( iom_use('hflx_fwb_cea') )  CALL iom_put( 'hflx_fwb_cea', -zerp_cor(:,:) * rcp * sst_m(:,:) )
213            IF( iom_use('vflx_fwb_cea') )  CALL iom_put( 'vflx_fwb_cea', -zerp_cor(:,:) )
214            !
215            IF( lwp ) THEN                   ! control print
216               IF( z_fwf < 0._wp ) THEN
217                  WRITE(numout,*)'   z_fwf < 0'
218                  WRITE(numout,*)'   SUM(erp+)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
219               ELSE
220                  WRITE(numout,*)'   z_fwf >= 0'
221                  WRITE(numout,*)'   SUM(erp-)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
222               ENDIF
223               WRITE(numout,*)'   SUM(empG)     = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv'
224               WRITE(numout,*)'   z_fwf         = ', z_fwf      ,' Kg/m2/s'
225               WRITE(numout,*)'   z_fwf_nsrf    = ', z_fwf_nsrf ,' Kg/m2/s'
226               WRITE(numout,*)'   MIN(zerp_cor) = ', MINVAL(zerp_cor) 
227               WRITE(numout,*)'   MAX(zerp_cor) = ', MAXVAL(zerp_cor) 
228            ENDIF
229         ENDIF
230         DEALLOCATE( ztmsk_neg , ztmsk_pos , ztmsk_tospread , z_wgt , zerp_cor )
231         !
232      CASE DEFAULT                           !==  you should never be there  ==!
233         CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' )
234         !
235      END SELECT
236      !
237   END SUBROUTINE sbc_fwb
238
239   !!======================================================================
240END MODULE sbcfwb
Note: See TracBrowser for help on using the repository browser.