Context Navigation

sbcrnf.F90 @ 15660

Last change on this file since 15660 was 15540, checked in by sparonuz, 3 years ago
Mixed precision version, tested up to 30 years on ORCA2.
Property svn:keywords set to `Id`
File size: 30.6 KB

Line
1	MODULE sbcrnf
2	!!======================================================================
3	!! * MODULE sbcrnf *
4	!! Ocean forcing: river runoff
5	!!=====================================================================
6	!! History : OPA ! 2000-11 (R. Hordoir, E. Durand) NetCDF FORMAT
7	!! NEMO 1.0 ! 2002-09 (G. Madec) F90: Free form and module
8	!! 3.0 ! 2006-07 (G. Madec) Surface module
9	!! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put
10	!! 3.3 ! 2010-10 (R. Furner, G. Madec) runoff distributed over ocean levels
11	!!----------------------------------------------------------------------
12
13	!!----------------------------------------------------------------------
14	!! sbc_rnf : monthly runoffs read in a NetCDF file
15	!! sbc_rnf_init : runoffs initialisation
16	!! rnf_mouth : set river mouth mask
17	!!----------------------------------------------------------------------
18	USE dom_oce ! ocean space and time domain
19	USE phycst ! physical constants
20	USE sbc_oce ! surface boundary condition variables
21	USE eosbn2 ! Equation Of State
22	USE closea, ONLY: l_clo_rnf, clo_rnf ! closed seas
23	!
24	USE in_out_manager ! I/O manager
25	USE fldread ! read input field at current time step
26	USE iom ! I/O module
27	USE lib_mpp ! MPP library
28
29	IMPLICIT NONE
30	PRIVATE
31
32	PUBLIC sbc_rnf ! called in sbcmod module
33	PUBLIC sbc_rnf_div ! called in divhor module
34	PUBLIC sbc_rnf_alloc ! called in sbcmod module
35	PUBLIC sbc_rnf_init ! called in sbcmod module
36
37	! !!* namsbc_rnf namelist *
38	CHARACTER(len=100) :: cn_dir !: Root directory for location of rnf files
39	LOGICAL , PUBLIC :: ln_rnf_depth !: depth river runoffs attribute specified in a file
40	LOGICAL :: ln_rnf_depth_ini !: depth river runoffs computed at the initialisation
41	REAL(wp) :: rn_rnf_max !: maximum value of the runoff climatologie (ln_rnf_depth_ini =T)
42	REAL(wp) :: rn_dep_max !: depth over which runoffs is spread (ln_rnf_depth_ini =T)
43	INTEGER :: nn_rnf_depth_file !: create (=1) a runoff depth file or not (=0)
44	LOGICAL , PUBLIC :: ln_rnf_icb !: iceberg flux is specified in a file
45	LOGICAL :: ln_rnf_tem !: temperature river runoffs attribute specified in a file
46	LOGICAL , PUBLIC :: ln_rnf_sal !: salinity river runoffs attribute specified in a file
47	TYPE(FLD_N) , PUBLIC :: sn_rnf !: information about the runoff file to be read
48	TYPE(FLD_N) :: sn_cnf !: information about the runoff mouth file to be read
49	TYPE(FLD_N) :: sn_i_rnf !: information about the iceberg flux file to be read
50	TYPE(FLD_N) :: sn_s_rnf !: information about the salinities of runoff file to be read
51	TYPE(FLD_N) :: sn_t_rnf !: information about the temperatures of runoff file to be read
52	TYPE(FLD_N) :: sn_dep_rnf !: information about the depth which river inflow affects
53	LOGICAL , PUBLIC :: ln_rnf_mouth !: specific treatment in mouths vicinity
54	REAL(wp) :: rn_hrnf !: runoffs, depth over which enhanced vertical mixing is used
55	REAL(wp) , PUBLIC :: rn_avt_rnf !: runoffs, value of the additional vertical mixing coef. [m2/s]
56	REAL(wp) , PUBLIC :: rn_rfact !: multiplicative factor for runoff
57
58	LOGICAL , PUBLIC :: l_rnfcpl = .false. !: runoffs recieved from oasis
59	INTEGER , PUBLIC :: nkrnf = 0 !: nb of levels over which Kz is increased at river mouths
60
61	REAL(dp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: rnfmsk !: river mouth mask (hori.)
62	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) :: rnfmsk_z !: river mouth mask (vert.)
63	REAL(dp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: h_rnf !: depth of runoff in m
64	INTEGER, PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: nk_rnf !: depth of runoff in model levels
65	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: rnf_tsc!: before and now T & S runoff contents [K.m/s & PSU.m/s]
66	REAL(dp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: rnf_tsc_b!: before and now T & S runoff contents [K.m/s & PSU.m/s]
67
68	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_rnf ! structure: river runoff (file information, fields read)
69	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_i_rnf ! structure: iceberg flux (file information, fields read)
70	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_s_rnf ! structure: river runoff salinity (file information, fields read)
71	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_t_rnf ! structure: river runoff temperature (file information, fields read)
72
73	!! * Substitutions
74	# include "do_loop_substitute.h90"
75	# include "domzgr_substitute.h90"
76	!!----------------------------------------------------------------------
77	!! NEMO/OCE 4.0 , NEMO Consortium (2018)
78	!! $Id$
79	!! Software governed by the CeCILL license (see ./LICENSE)
80	!!----------------------------------------------------------------------
81	CONTAINS
82
83	INTEGER FUNCTION sbc_rnf_alloc()
84	!!----------------------------------------------------------------------
85	!! * ROUTINE sbc_rnf_alloc *
86	!!----------------------------------------------------------------------
87	ALLOCATE( rnfmsk(jpi,jpj) , rnfmsk_z(jpk) , &
88	& h_rnf (jpi,jpj) , nk_rnf (jpi,jpj) , &
89	& rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
90	!
91	CALL mpp_sum ( 'sbcrnf', sbc_rnf_alloc )
92	IF( sbc_rnf_alloc > 0 ) CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
93	END FUNCTION sbc_rnf_alloc
94
95
96	SUBROUTINE sbc_rnf( kt )
97	!!----------------------------------------------------------------------
98	!! * ROUTINE sbc_rnf *
99	!!
100	!! ** Purpose : Introduce a climatological run off forcing
101	!!
102	!! ** Method : Set each river mouth with a monthly climatology
103	!! provided from different data.
104	!! CAUTION : upward water flux, runoff forced to be < 0
105	!!
106	!! ** Action : runoff updated runoff field at time-step kt
107	!!----------------------------------------------------------------------
108	INTEGER, INTENT(in) :: kt ! ocean time step
109	!
110	INTEGER :: ji, jj ! dummy loop indices
111	INTEGER :: z_err = 0 ! dummy integer for error handling
112	!!----------------------------------------------------------------------
113	REAL(dp), DIMENSION(jpi,jpj) :: ztfrz ! freezing point used for temperature correction
114	!
115	!
116	! !-------------------!
117	! ! Update runoff !
118	! !-------------------!
119	!
120	!
121	IF( .NOT. l_rnfcpl ) THEN
122	CALL fld_read ( kt, nn_fsbc, sf_rnf ) ! Read Runoffs data and provide it at kt ( runoffs + iceberg )
123	IF( ln_rnf_icb ) CALL fld_read ( kt, nn_fsbc, sf_i_rnf ) ! idem for iceberg flux if required
124	ENDIF
125	IF( ln_rnf_tem ) CALL fld_read ( kt, nn_fsbc, sf_t_rnf ) ! idem for runoffs temperature if required
126	IF( ln_rnf_sal ) CALL fld_read ( kt, nn_fsbc, sf_s_rnf ) ! idem for runoffs salinity if required
127	!
128	IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
129	!
130	IF( .NOT. l_rnfcpl ) THEN
131	rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) * tmask(:,:,1) ! updated runoff value at time step kt
132	IF( ln_rnf_icb ) THEN
133	fwficb(:,:) = rn_rfact * ( sf_i_rnf(1)%fnow(:,:,1) ) * tmask(:,:,1) ! updated runoff value at time step kt
134	rnf(:,:) = rnf(:,:) + fwficb(:,:)
135	qns(:,:) = qns(:,:) - fwficb(:,:) * rLfus
136	!!qns_tot(:,:) = qns_tot(:,:) - fwficb(:,:) * rLfus
137	!!qns_oce(:,:) = qns_oce(:,:) - fwficb(:,:) * rLfus
138	CALL iom_put( 'iceberg_cea' , fwficb(:,:) ) ! output iceberg flux
139	CALL iom_put( 'hflx_icb_cea' , -fwficb(:,:) * rLfus ) ! output Heat Flux into Sea Water due to Iceberg Thermodynamics -->
140	ENDIF
141	ENDIF
142	!
143	! ! set temperature & salinity content of runoffs
144	IF( ln_rnf_tem ) THEN ! use runoffs temperature data
145	rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rho0
146	CALL eos_fzp( sss_m(:,:), ztfrz(:,:) )
147	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp ) ! if missing data value use SST as runoffs temperature
148	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rho0
149	END WHERE
150	ELSE ! use SST as runoffs temperature
151	!CEOD River is fresh water so must at least be 0 unless we consider ice
152	rnf_tsc(:,:,jp_tem) = MAX( sst_m(:,:), 0.0_wp ) * rnf(:,:) * r1_rho0
153	ENDIF
154	! ! use runoffs salinity data
155	IF( ln_rnf_sal ) rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rho0
156	! ! else use S=0 for runoffs (done one for all in the init)
157	CALL iom_put( 'runoffs' , rnf(:,:) ) ! output runoff mass flux
158	IF( iom_use('hflx_rnf_cea') ) CALL iom_put( 'hflx_rnf_cea', rnf_tsc(:,:,jp_tem) * rho0 * rcp ) ! output runoff sensible heat (W/m2)
159	IF( iom_use('sflx_rnf_cea') ) CALL iom_put( 'sflx_rnf_cea', rnf_tsc(:,:,jp_sal) * rho0 ) ! output runoff salt flux (g/m2/s)
160	ENDIF
161	!
162	! ! ---------------------------------------- !
163	IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 !
164	! ! ---------------------------------------- !
165	IF( ln_rstart .AND. .NOT.l_1st_euler ) THEN !* Restart: read in restart file
166	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields red in the restart file', lrxios
167	CALL iom_get( numror, jpdom_auto, 'rnf_b' , rnf_b ) ! before runoff
168	CALL iom_get( numror, jpdom_auto, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) ) ! before heat content of runoff
169	CALL iom_get( numror, jpdom_auto, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) ) ! before salinity content of runoff
170	ELSE !* no restart: set from nit000 values
171	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields set to nit000'
172	rnf_b (:,: ) = rnf (:,: )
173	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
174	ENDIF
175	ENDIF
176	! ! ---------------------------------------- !
177	IF( lrst_oce ) THEN ! Write in the ocean restart file !
178	! ! ---------------------------------------- !
179	IF(lwp) WRITE(numout,*)
180	IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ', &
181	& 'at it= ', kt,' date= ', ndastp
182	IF(lwp) WRITE(numout,*) '~~~~'
183	CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf )
184	CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
185	CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
186	ENDIF
187	!
188	END SUBROUTINE sbc_rnf
189
190
191	SUBROUTINE sbc_rnf_div( phdivn, Kmm )
192	!!----------------------------------------------------------------------
193	!! * ROUTINE sbc_rnf *
194	!!
195	!! ** Purpose : update the horizontal divergence with the runoff inflow
196	!!
197	!! ** Method :
198	!! CAUTION : rnf is positive (inflow) decreasing the
199	!! divergence and expressed in m/s
200	!!
201	!! ** Action : phdivn decreased by the runoff inflow
202	!!----------------------------------------------------------------------
203	INTEGER , INTENT(in ) :: Kmm ! ocean time level index
204	REAL(dp), DIMENSION(:,:,:), INTENT(inout) :: phdivn ! horizontal divergence
205	!!
206	INTEGER :: ji, jj, jk ! dummy loop indices
207	REAL(wp) :: zfact ! local scalar
208	!!----------------------------------------------------------------------
209	!
210	zfact = 0.5_wp
211	!
212	IF( ln_rnf_depth .OR. ln_rnf_depth_ini ) THEN !== runoff distributed over several levels ==!
213	IF( ln_linssh ) THEN !* constant volume case : just apply the runoff input flow
214	DO_2D_OVR( nn_hls-1, nn_hls, nn_hls-1, nn_hls )
215	DO jk = 1, nk_rnf(ji,jj)
216	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rho0 / h_rnf(ji,jj)
217	END DO
218	END_2D
219	ELSE !* variable volume case
220	DO_2D_OVR( nn_hls, nn_hls, nn_hls, nn_hls ) ! update the depth over which runoffs are distributed
221	h_rnf(ji,jj) = 0._wp
222	DO jk = 1, nk_rnf(ji,jj) ! recalculates h_rnf to be the depth in metres
223	h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm) ! to the bottom of the relevant grid box
224	END DO
225	! ! apply the runoff input flow
226	DO jk = 1, nk_rnf(ji,jj)
227	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rho0 / h_rnf(ji,jj)
228	END DO
229	END_2D
230	ENDIF
231	ELSE !== runoff put only at the surface ==!
232	DO_2D_OVR( nn_hls, nn_hls, nn_hls, nn_hls )
233	h_rnf (ji,jj) = e3t (ji,jj,1,Kmm) ! update h_rnf to be depth of top box
234	phdivn(ji,jj,1) = phdivn(ji,jj,1) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rho0 / e3t(ji,jj,1,Kmm)
235	END_2D
236	ENDIF
237	!
238	END SUBROUTINE sbc_rnf_div
239
240
241	SUBROUTINE sbc_rnf_init( Kmm )
242	!!----------------------------------------------------------------------
243	!! * ROUTINE sbc_rnf_init *
244	!!
245	!! ** Purpose : Initialisation of the runoffs if (ln_rnf=T)
246	!!
247	!! ** Method : - read the runoff namsbc_rnf namelist
248	!!
249	!! ** Action : - read parameters
250	!!----------------------------------------------------------------------
251	INTEGER, INTENT(in) :: Kmm ! ocean time level index
252	CHARACTER(len=32) :: rn_dep_file ! runoff file name
253	INTEGER :: ji, jj, jk, jm ! dummy loop indices
254	INTEGER :: ierror, inum ! temporary integer
255	INTEGER :: ios ! Local integer output status for namelist read
256	INTEGER :: nbrec ! temporary integer
257	REAL(wp) :: zacoef
258	REAL(dp), DIMENSION(jpi,jpj,2) :: zrnfcl
259	!!
260	NAMELIST/namsbc_rnf/ cn_dir , ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, ln_rnf_icb, &
261	& sn_rnf, sn_cnf , sn_i_rnf, sn_s_rnf , sn_t_rnf , sn_dep_rnf, &
262	& ln_rnf_mouth , rn_hrnf , rn_avt_rnf, rn_rfact, &
263	& ln_rnf_depth_ini , rn_dep_max , rn_rnf_max, nn_rnf_depth_file
264	!!----------------------------------------------------------------------
265	!
266	! !== allocate runoff arrays
267	IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
268	!
269	IF( .NOT. ln_rnf ) THEN ! no specific treatment in vicinity of river mouths
270	ln_rnf_mouth = .FALSE. ! default definition needed for example by sbc_ssr or by tra_adv_muscl
271	nkrnf = 0
272	rnf (:,:) = 0.0_wp
273	rnf_b (:,:) = 0.0_wp
274	rnfmsk (:,:) = 0.0_wp
275	rnfmsk_z(:) = 0.0_wp
276	RETURN
277	ENDIF
278	!
279	! ! ============
280	! ! Namelist
281	! ! ============
282	!
283	READ ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
284	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist' )
285
286	READ ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
287	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist' )
288	IF(lwm) WRITE ( numond, namsbc_rnf )
289	!
290	! ! Control print
291	IF(lwp) THEN
292	WRITE(numout,*)
293	WRITE(numout,*) 'sbc_rnf_init : runoff '
294	WRITE(numout,*) '~~~~~~~~~~~~ '
295	WRITE(numout,*) ' Namelist namsbc_rnf'
296	WRITE(numout,*) ' specific river mouths treatment ln_rnf_mouth = ', ln_rnf_mouth
297	WRITE(numout,*) ' river mouth additional Kz rn_avt_rnf = ', rn_avt_rnf
298	WRITE(numout,*) ' depth of river mouth additional mixing rn_hrnf = ', rn_hrnf
299	WRITE(numout,*) ' multiplicative factor for runoff rn_rfact = ', rn_rfact
300	ENDIF
301	! ! ==================
302	! ! Type of runoff
303	! ! ==================
304	!
305	IF( .NOT. l_rnfcpl ) THEN
306	ALLOCATE( sf_rnf(1), STAT=ierror ) ! Create sf_rnf structure (runoff inflow)
307	IF(lwp) WRITE(numout,*)
308	IF(lwp) WRITE(numout,*) ' ==>>> runoffs inflow read in a file'
309	IF( ierror > 0 ) THEN
310	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_rnf structure' ) ; RETURN
311	ENDIF
312	ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1) )
313	IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
314	CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf', no_print )
315	!
316	IF( ln_rnf_icb ) THEN ! Create (if required) sf_i_rnf structure
317	IF(lwp) WRITE(numout,*)
318	IF(lwp) WRITE(numout,*) ' iceberg flux read in a file'
319	ALLOCATE( sf_i_rnf(1), STAT=ierror )
320	IF( ierror > 0 ) THEN
321	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_i_rnf structure' ) ; RETURN
322	ENDIF
323	ALLOCATE( sf_i_rnf(1)%fnow(jpi,jpj,1) )
324	IF( sn_i_rnf%ln_tint ) ALLOCATE( sf_i_rnf(1)%fdta(jpi,jpj,1,2) )
325	CALL fld_fill (sf_i_rnf, (/ sn_i_rnf /), cn_dir, 'sbc_rnf_init', 'read iceberg flux data', 'namsbc_rnf' )
326	ELSE
327	fwficb(:,:) = 0._wp
328	ENDIF
329
330	ENDIF
331	!
332	IF( ln_rnf_tem ) THEN ! Create (if required) sf_t_rnf structure
333	IF(lwp) WRITE(numout,*)
334	IF(lwp) WRITE(numout,*) ' ==>>> runoffs temperatures read in a file'
335	ALLOCATE( sf_t_rnf(1), STAT=ierror )
336	IF( ierror > 0 ) THEN
337	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' ) ; RETURN
338	ENDIF
339	ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1) )
340	IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
341	CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf', no_print )
342	ENDIF
343	!
344	IF( ln_rnf_sal ) THEN ! Create (if required) sf_s_rnf and sf_t_rnf structures
345	IF(lwp) WRITE(numout,*)
346	IF(lwp) WRITE(numout,*) ' ==>>> runoffs salinities read in a file'
347	ALLOCATE( sf_s_rnf(1), STAT=ierror )
348	IF( ierror > 0 ) THEN
349	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' ) ; RETURN
350	ENDIF
351	ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1) )
352	IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
353	CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf', no_print )
354	ENDIF
355	!
356	IF( ln_rnf_depth ) THEN ! depth of runoffs set from a file
357	IF(lwp) WRITE(numout,*)
358	IF(lwp) WRITE(numout,*) ' ==>>> runoffs depth read in a file'
359	rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
360	IF( .NOT. sn_dep_rnf%ln_clim ) THEN ; WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear ! add year
361	IF( sn_dep_rnf%clftyp == 'monthly' ) WRITE(rn_dep_file, '(a,"m",i2)' ) TRIM( rn_dep_file ), nmonth ! add month
362	ENDIF
363	CALL iom_open ( rn_dep_file, inum ) ! open file
364	CALL iom_get ( inum, jpdom_global, sn_dep_rnf%clvar, h_rnf ) ! read the river mouth array
365	CALL iom_close( inum ) ! close file
366	!
367	nk_rnf(:,:) = 0 ! set the number of level over which river runoffs are applied
368	DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
369	IF( h_rnf(ji,jj) > 0._wp ) THEN
370	jk = 2
371	DO WHILE ( jk < mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1
372	END DO
373	nk_rnf(ji,jj) = jk
374	ELSEIF( h_rnf(ji,jj) == -1._wp ) THEN ; nk_rnf(ji,jj) = 1
375	ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN ; nk_rnf(ji,jj) = mbkt(ji,jj)
376	ELSE
377	CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999' )
378	WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
379	ENDIF
380	END_2D
381	DO_2D( nn_hls, nn_hls, nn_hls, nn_hls ) ! set the associated depth
382	h_rnf(ji,jj) = 0._wp
383	DO jk = 1, nk_rnf(ji,jj)
384	h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)
385	END DO
386	END_2D
387	!
388	ELSE IF( ln_rnf_depth_ini ) THEN ! runoffs applied at the surface
389	!
390	IF(lwp) WRITE(numout,*)
391	IF(lwp) WRITE(numout,*) ' ==>>> depth of runoff computed once from max value of runoff'
392	IF(lwp) WRITE(numout,*) ' max value of the runoff climatologie (over global domain) rn_rnf_max = ', rn_rnf_max
393	IF(lwp) WRITE(numout,*) ' depth over which runoffs is spread rn_dep_max = ', rn_dep_max
394	IF(lwp) WRITE(numout,*) ' create (=1) a runoff depth file or not (=0) nn_rnf_depth_file = ', nn_rnf_depth_file
395
396	CALL iom_open( TRIM( sn_rnf%clname ), inum ) ! open runoff file
397	nbrec = iom_getszuld( inum )
398	zrnfcl(:,:,1) = 0._wp ! init the max to 0. in 1
399	DO jm = 1, nbrec
400	CALL iom_get( inum, jpdom_global, TRIM( sn_rnf%clvar ), zrnfcl(:,:,2), jm ) ! read the value in 2
401	zrnfcl(:,:,1) = MAXVAL( zrnfcl(:,:,:), DIM=3 ) ! store the maximum value in time in 1
402	END DO
403	CALL iom_close( inum )
404	!
405	h_rnf(:,:) = 1.
406	!
407	zacoef = rn_dep_max / rn_rnf_max ! coef of linear relation between runoff and its depth (150m for max of runoff)
408	!
409	WHERE( zrnfcl(:,:,1) > 0._wp ) h_rnf(:,:) = zacoef * zrnfcl(:,:,1) ! compute depth for all runoffs
410	!
411	DO_2D( nn_hls, nn_hls, nn_hls, nn_hls ) ! take in account min depth of ocean rn_hmin
412	IF( zrnfcl(ji,jj,1) > 0._wp ) THEN
413	jk = mbkt(ji,jj)
414	h_rnf(ji,jj) = MIN( h_rnf(ji,jj), gdept_0(ji,jj,jk ) )
415	ENDIF
416	END_2D
417	!
418	nk_rnf(:,:) = 0 ! number of levels on which runoffs are distributed
419	DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
420	IF( zrnfcl(ji,jj,1) > 0._wp ) THEN
421	jk = 2
422	DO WHILE ( jk < mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1
423	END DO
424	nk_rnf(ji,jj) = jk
425	ELSE
426	nk_rnf(ji,jj) = 1
427	ENDIF
428	END_2D
429	!
430	DO_2D( nn_hls, nn_hls, nn_hls, nn_hls ) ! set the associated depth
431	h_rnf(ji,jj) = 0._wp
432	DO jk = 1, nk_rnf(ji,jj)
433	h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)
434	END DO
435	END_2D
436	!
437	IF( nn_rnf_depth_file == 1 ) THEN ! save output nb levels for runoff
438	IF(lwp) WRITE(numout,*) ' ==>>> create runoff depht file'
439	CALL iom_open ( TRIM( sn_dep_rnf%clname ), inum, ldwrt = .TRUE. )
440	CALL iom_rstput( 0, 0, inum, 'rodepth', h_rnf )
441	CALL iom_close ( inum )
442	ENDIF
443	ELSE ! runoffs applied at the surface
444	nk_rnf(:,:) = 1
445	h_rnf (:,:) = e3t(:,:,1,Kmm)
446	ENDIF
447	!
448	rnf(:,:) = 0._wp ! runoff initialisation
449	rnf_tsc(:,:,:) = 0._wp ! runoffs temperature & salinty contents initilisation
450	!
451	! ! ========================
452	! ! River mouth vicinity
453	! ! ========================
454	!
455	IF( ln_rnf_mouth ) THEN ! Specific treatment in vicinity of river mouths :
456	! ! - Increase Kz in surface layers ( rn_hrnf > 0 )
457	! ! - set to zero SSS damping (ln_ssr=T)
458	! ! - mixed upstream-centered (ln_traadv_cen2=T)
459	!
460	IF( ln_rnf_depth ) CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already', &
461	& 'be spread through depth by ln_rnf_depth' )
462	!
463	nkrnf = 0 ! Number of level over which Kz increase
464	IF( rn_hrnf > 0._wp ) THEN
465	nkrnf = 2
466	DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf ) ; nkrnf = nkrnf + 1
467	END DO
468	IF( ln_sco ) CALL ctl_warn( 'sbc_rnf_init: number of levels over which Kz is increased is computed for zco...' )
469	ENDIF
470	IF(lwp) WRITE(numout,*)
471	IF(lwp) WRITE(numout,*) ' ==>>> Specific treatment used in vicinity of river mouths :'
472	IF(lwp) WRITE(numout,*) ' - Increase Kz in surface layers (if rn_hrnf > 0 )'
473	IF(lwp) WRITE(numout,*) ' by ', rn_avt_rnf,' m2/s over ', nkrnf, ' w-levels'
474	IF(lwp) WRITE(numout,*) ' - set to zero SSS damping (if ln_ssr=T)'
475	IF(lwp) WRITE(numout,*) ' - mixed upstream-centered (if ln_traadv_cen2=T)'
476	!
477	CALL rnf_mouth ! set river mouth mask
478	!
479	ELSE ! No treatment at river mouths
480	IF(lwp) WRITE(numout,*)
481	IF(lwp) WRITE(numout,*) ' ==>>> No specific treatment at river mouths'
482	rnfmsk (:,:) = 0._wp
483	rnfmsk_z(:) = 0._wp
484	nkrnf = 0
485	ENDIF
486	!
487	END SUBROUTINE sbc_rnf_init
488
489
490	SUBROUTINE rnf_mouth
491	!!----------------------------------------------------------------------
492	!! * ROUTINE rnf_mouth *
493	!!
494	!! ** Purpose : define the river mouths mask
495	!!
496	!! ** Method : read the river mouth mask (=0/1) in the river runoff
497	!! climatological file. Defined a given vertical structure.
498	!! CAUTION, the vertical structure is hard coded on the
499	!! first 5 levels.
500	!! This fields can be used to:
501	!! - set an upstream advection scheme
502	!! (ln_rnf_mouth=T and ln_traadv_cen2=T)
503	!! - increase vertical on the top nn_krnf vertical levels
504	!! at river runoff input grid point (nn_krnf>=2, see step.F90)
505	!! - set to zero SSS restoring flux at river mouth grid points
506	!!
507	!! ** Action : rnfmsk set to 1 at river runoff input, 0 elsewhere
508	!! rnfmsk_z vertical structure
509	!!----------------------------------------------------------------------
510	INTEGER :: inum ! temporary integers
511	CHARACTER(len=140) :: cl_rnfile ! runoff file name
512	!!----------------------------------------------------------------------
513	!
514	IF(lwp) WRITE(numout,*)
515	IF(lwp) WRITE(numout,*) ' rnf_mouth : river mouth mask'
516	IF(lwp) WRITE(numout,*) ' ~~~~~~~~~ '
517	!
518	cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
519	IF( .NOT. sn_cnf%ln_clim ) THEN ; WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear ! add year
520	IF( sn_cnf%clftyp == 'monthly' ) WRITE(cl_rnfile, '(a,"m",i2)' ) TRIM( cl_rnfile ), nmonth ! add month
521	ENDIF
522	!
523	! horizontal mask (read in NetCDF file)
524	CALL iom_open ( cl_rnfile, inum ) ! open file
525	CALL iom_get ( inum, jpdom_global, sn_cnf%clvar, rnfmsk ) ! read the river mouth array
526	CALL iom_close( inum ) ! close file
527	!
528	IF( l_clo_rnf ) CALL clo_rnf( rnfmsk ) ! closed sea inflow set as river mouth
529	!
530	rnfmsk_z(:) = 0._wp ! vertical structure
531	rnfmsk_z(1) = 1.0
532	rnfmsk_z(2) = 1.0 ! **********
533	rnfmsk_z(3) = 0.5 ! HARD CODED on the 5 first levels
534	rnfmsk_z(4) = 0.25 ! **********
535	rnfmsk_z(5) = 0.125
536	!
537	END SUBROUTINE rnf_mouth
538
539	!!======================================================================
540	END MODULE sbcrnf

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: NEMO/branches/2021/dev_r14116_HPC-10_mcastril_Mixed_Precision_implementation/src/OCE/SBC/sbcrnf.F90 @ 15660

Download in other formats: