New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv.F90 in NEMO/branches/2021/dev_r14116_HPC-10_mcastril_Mixed_Precision_implementation/src/OCE/TRA – NEMO

source: NEMO/branches/2021/dev_r14116_HPC-10_mcastril_Mixed_Precision_implementation/src/OCE/TRA/traadv.F90 @ 14986

Last change on this file since 14986 was 14986, checked in by sparonuz, 3 years ago

Merge trunk -r14984:HEAD
  • Property svn:keywords set to Id
File size: 18.0 KB
Line 
1MODULE traadv
2   !!==============================================================================
3   !!                       ***  MODULE  traadv  ***
4   !! Ocean active tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-09  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!            3.6  !  2011-06  (G. Madec)  Addition of Mixed Layer Eddy parameterisation
9   !!            3.7  !  2014-05  (G. Madec)  Add 2nd/4th order cases for CEN and FCT schemes
10   !!             -   !  2014-12  (G. Madec) suppression of cross land advection option
11   !!            3.6  !  2015-06  (E. Clementi) Addition of Stokes drift in case of wave coupling
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv       : compute ocean tracer advection trend
16   !!   tra_adv_init  : control the different options of advection scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   ! TEMP: [tiling] This change not necessary after all lbc_lnks removed in the nn_hls = 2 case in tra_adv_fct
21   USE domtile
22   USE domvvl         ! variable vertical scale factors
23   USE sbcwave        ! wave module
24   USE sbc_oce        ! surface boundary condition: ocean
25   USE traadv_cen     ! centered scheme            (tra_adv_cen  routine)
26   USE traadv_fct     ! FCT      scheme            (tra_adv_fct  routine)
27   USE traadv_mus     ! MUSCL    scheme            (tra_adv_mus  routine)
28   USE traadv_ubs     ! UBS      scheme            (tra_adv_ubs  routine)
29   USE traadv_qck     ! QUICKEST scheme            (tra_adv_qck  routine)
30   USE tramle         ! Mixed Layer Eddy transport (tra_mle_trp  routine)
31   USE ldftra         ! Eddy Induced transport     (ldf_eiv_trp  routine)
32   USE ldfslp         ! Lateral diffusion: slopes of neutral surfaces
33   USE trd_oce        ! trends: ocean variables
34   USE trdtra         ! trends manager: tracers
35   USE diaptr         ! Poleward heat transport
36   !
37   USE in_out_manager ! I/O manager
38   USE iom            ! I/O module
39   USE prtctl         ! Print control
40   USE lib_mpp        ! MPP library
41   USE timing         ! Timing
42
43   IMPLICIT NONE
44   PRIVATE
45
46   PUBLIC   tra_adv        ! called by step.F90
47   PUBLIC   tra_adv_init   ! called by nemogcm.F90
48
49   !                            !!* Namelist namtra_adv *
50   LOGICAL ::   ln_traadv_OFF    ! no advection on T and S
51   LOGICAL ::   ln_traadv_cen    ! centered scheme flag
52   INTEGER ::      nn_cen_h, nn_cen_v   ! =2/4 : horizontal and vertical choices of the order of CEN scheme
53   LOGICAL ::   ln_traadv_fct    ! FCT scheme flag
54   INTEGER ::      nn_fct_h, nn_fct_v   ! =2/4 : horizontal and vertical choices of the order of FCT scheme
55   LOGICAL ::   ln_traadv_mus    ! MUSCL scheme flag
56   LOGICAL ::      ln_mus_ups           ! use upstream scheme in vivcinity of river mouths
57   LOGICAL ::   ln_traadv_ubs    ! UBS scheme flag
58   INTEGER ::      nn_ubs_v             ! =2/4 : vertical choice of the order of UBS scheme
59   LOGICAL ::   ln_traadv_qck    ! QUICKEST scheme flag
60
61   INTEGER, PUBLIC ::   nadv             ! choice of the type of advection scheme
62   !                             ! associated indices:
63   INTEGER, PARAMETER, PUBLIC ::   np_NO_adv  = 0   ! no T-S advection
64   INTEGER, PARAMETER, PUBLIC ::   np_CEN     = 1   ! 2nd/4th order centered scheme
65   INTEGER, PARAMETER, PUBLIC ::   np_FCT     = 2   ! 2nd/4th order Flux Corrected Transport scheme
66   INTEGER, PARAMETER, PUBLIC ::   np_MUS     = 3   ! MUSCL scheme
67   INTEGER, PARAMETER, PUBLIC ::   np_UBS     = 4   ! 3rd order Upstream Biased Scheme
68   INTEGER, PARAMETER, PUBLIC ::   np_QCK     = 5   ! QUICK scheme
69
70   !! * Substitutions
71#  include "do_loop_substitute.h90"
72#  include "domzgr_substitute.h90"
73#  include "single_precision_substitute.h90"
74   !!----------------------------------------------------------------------
75   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
76   !! $Id$
77   !! Software governed by the CeCILL license (see ./LICENSE)
78   !!----------------------------------------------------------------------
79CONTAINS
80
81   SUBROUTINE tra_adv( kt, Kbb, Kmm, pts, Krhs )
82      !!----------------------------------------------------------------------
83      !!                  ***  ROUTINE tra_adv  ***
84      !!
85      !! ** Purpose :   compute the ocean tracer advection trend.
86      !!
87      !! ** Method  : - Update (uu(:,:,:,Krhs),vv(:,:,:,Krhs)) with the advection term following nadv
88      !!----------------------------------------------------------------------
89      INTEGER                                  , INTENT(in)    :: kt             ! ocean time-step index
90      INTEGER                                  , INTENT(in)    :: Kbb, Kmm, Krhs ! time level indices
91      REAL(dp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts            ! active tracers and RHS of tracer equation
92      !
93      INTEGER ::   ji, jj, jk   ! dummy loop index
94      ! TEMP: [tiling] This change not necessary and can be A2D(nn_hls) after all lbc_lnks removed in the nn_hls = 2 case in tra_adv_fct
95      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE, SAVE :: zuu, zvv, zww   ! 3D workspace
96      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: ztrdt, ztrds
97      ! TEMP: [tiling] This change not necessary after all lbc_lnks removed in the nn_hls = 2 case in tra_adv_fct
98      LOGICAL :: lskip
99      !!----------------------------------------------------------------------
100      !
101      IF( ln_timing )   CALL timing_start('tra_adv')
102      !
103      lskip = .FALSE.
104
105      ! TEMP: [tiling] These changes not necessary after all lbc_lnks removed in the nn_hls = 2 case in tra_adv_fct
106      IF( .NOT. l_istiled .OR. ntile == 1 )  THEN                       ! Do only on the first tile
107         ALLOCATE( zuu(jpi,jpj,jpk), zvv(jpi,jpj,jpk), zww(jpi,jpj,jpk) )
108      ENDIF
109
110      ! TEMP: [tiling] These changes not necessary after all lbc_lnks removed in the nn_hls = 2 case in tra_adv_fct
111      IF( ln_tile .AND. nadv == np_FCT )  THEN
112         IF( ntile == 1 ) THEN
113            CALL dom_tile_stop( ldhold=.TRUE. )
114         ELSE
115            lskip = .TRUE.
116         ENDIF
117      ENDIF
118      IF( .NOT. lskip ) THEN
119         !                                         !==  effective transport  ==!
120         IF( ln_wave .AND. ln_sdw )  THEN
121            DO_3D_OVR( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
122               zuu(ji,jj,jk) = e2u  (ji,jj) * e3u(ji,jj,jk,Kmm) * ( uu(ji,jj,jk,Kmm) + usd(ji,jj,jk) )
123               zvv(ji,jj,jk) = e1v  (ji,jj) * e3v(ji,jj,jk,Kmm) * ( vv(ji,jj,jk,Kmm) + vsd(ji,jj,jk) )
124               zww(ji,jj,jk) = e1e2t(ji,jj)                     * ( ww(ji,jj,jk)     + wsd(ji,jj,jk) )
125            END_3D
126         ELSE
127            DO_3D_OVR( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
128               zuu(ji,jj,jk) = e2u  (ji,jj) * e3u(ji,jj,jk,Kmm) * uu(ji,jj,jk,Kmm)               ! eulerian transport only
129               zvv(ji,jj,jk) = e1v  (ji,jj) * e3v(ji,jj,jk,Kmm) * vv(ji,jj,jk,Kmm)
130               zww(ji,jj,jk) = e1e2t(ji,jj)                     * ww(ji,jj,jk)
131            END_3D
132         ENDIF
133         !
134         IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN                                ! add z-tilde and/or vvl corrections
135            DO_3D_OVR( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
136               zuu(ji,jj,jk) = zuu(ji,jj,jk) + un_td(ji,jj,jk)
137               zvv(ji,jj,jk) = zvv(ji,jj,jk) + vn_td(ji,jj,jk)
138            END_3D
139         ENDIF
140         !
141         DO_2D_OVR( nn_hls, nn_hls-1, nn_hls, nn_hls-1 )
142            zuu(ji,jj,jpk) = 0._wp                                                      ! no transport trough the bottom
143            zvv(ji,jj,jpk) = 0._wp
144            zww(ji,jj,jpk) = 0._wp
145         END_2D
146         !
147         IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad )   &
148            &              CALL ldf_eiv_trp( kt, nit000, zuu, zvv, zww, 'TRA', Kmm, Krhs )   ! add the eiv transport (if necessary)
149         !
150         IF( ln_mle    )   CALL tra_mle_trp( kt, nit000, zuu, zvv, zww, 'TRA', Kmm       )   ! add the mle transport (if necessary)
151         !
152         ! TEMP: [tiling] This change not necessary after all lbc_lnks removed in the nn_hls = 2 case in tra_adv_fct
153         IF( .NOT. l_istiled .OR. ntile == nijtile )  THEN                ! Do only on the last tile
154            CALL iom_put( "uocetr_eff", zuu )                                        ! output effective transport
155            CALL iom_put( "vocetr_eff", zvv )
156            CALL iom_put( "wocetr_eff", zww )
157         ENDIF
158         !
159!!gm ???
160         ! TEMP: [tiling] This copy-in not necessary after all lbc_lnks removed in the nn_hls = 2 case in tra_adv_fct
161         CALL dia_ptr( kt, Kmm, zvv(A2D(nn_hls),:) )                                    ! diagnose the effective MSF
162!!gm ???
163         !
164
165         IF( l_trdtra )   THEN                    !* Save ta and sa trends
166            ALLOCATE( ztrdt(jpi,jpj,jpk), ztrds(jpi,jpj,jpk) )
167            ztrdt(:,:,:) = pts(:,:,:,jp_tem,Krhs)
168            ztrds(:,:,:) = pts(:,:,:,jp_sal,Krhs)
169         ENDIF
170         !
171         SELECT CASE ( nadv )                      !==  compute advection trend and add it to general trend  ==!
172         !
173         CASE ( np_CEN )                                 ! Centered scheme : 2nd / 4th order
174            CALL tra_adv_cen    ( kt, nit000, 'TRA',         zuu, zvv, zww, Kmm, pts, jpts, Krhs, nn_cen_h, nn_cen_v )
175         CASE ( np_FCT )                                 ! FCT scheme      : 2nd / 4th order
176               CALL tra_adv_fct    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, nn_fct_h, nn_fct_v )
177         CASE ( np_MUS )                                 ! MUSCL
178                CALL tra_adv_mus    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, ln_mus_ups )
179         CASE ( np_UBS )                                 ! UBS
180            CALL tra_adv_ubs    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, nn_ubs_v   )
181         CASE ( np_QCK )                                 ! QUICKEST
182            CALL tra_adv_qck    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs )
183         !
184         END SELECT
185         !
186         IF( l_trdtra )   THEN                      ! save the advective trends for further diagnostics
187            DO jk = 1, jpkm1
188               ztrdt(:,:,jk) = pts(:,:,jk,jp_tem,Krhs) - ztrdt(:,:,jk)
189               ztrds(:,:,jk) = pts(:,:,jk,jp_sal,Krhs) - ztrds(:,:,jk)
190            END DO
191            CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_totad, ztrdt )
192            CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_totad, ztrds )
193            DEALLOCATE( ztrdt, ztrds )
194         ENDIF
195
196         ! TEMP: [tiling] This change not necessary after all lbc_lnks removed in the nn_hls = 2 case in tra_adv_fct
197         IF( ln_tile .AND. .NOT. l_istiled ) CALL dom_tile_start( ldhold=.TRUE. )
198      ENDIF
199      !                                              ! print mean trends (used for debugging)
200      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=CASTWP(pts(:,:,:,jp_tem,Krhs)), clinfo1=' adv  - Ta: ', mask1=tmask, &
201         &                                  tab3d_2=CASTWP(pts(:,:,:,jp_sal,Krhs)), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
202
203      ! TEMP: [tiling] This change not necessary after all lbc_lnks removed in the nn_hls = 2 case in tra_adv_fct
204      IF( .NOT. l_istiled .OR. ntile == nijtile )  THEN                ! Do only for the full domain
205         DEALLOCATE( zuu, zvv, zww )
206      ENDIF
207      !
208      IF( ln_timing )   CALL timing_stop( 'tra_adv' )
209      !
210   END SUBROUTINE tra_adv
211
212
213   SUBROUTINE tra_adv_init
214      !!---------------------------------------------------------------------
215      !!                  ***  ROUTINE tra_adv_init  ***
216      !!
217      !! ** Purpose :   Control the consistency between namelist options for
218      !!              tracer advection schemes and set nadv
219      !!----------------------------------------------------------------------
220      INTEGER ::   ioptio, ios   ! Local integers
221      !
222      NAMELIST/namtra_adv/ ln_traadv_OFF,                        &   ! No advection
223         &                 ln_traadv_cen , nn_cen_h, nn_cen_v,   &   ! CEN
224         &                 ln_traadv_fct , nn_fct_h, nn_fct_v,   &   ! FCT
225         &                 ln_traadv_mus , ln_mus_ups,           &   ! MUSCL
226         &                 ln_traadv_ubs ,           nn_ubs_v,   &   ! UBS
227         &                 ln_traadv_qck                             ! QCK
228      !!----------------------------------------------------------------------
229      !
230      !                                !==  Namelist  ==!
231      READ  ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
232901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtra_adv in reference namelist' )
233      !
234      READ  ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
235902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtra_adv in configuration namelist' )
236      IF(lwm) WRITE( numond, namtra_adv )
237      !
238      IF(lwp) THEN                           ! Namelist print
239         WRITE(numout,*)
240         WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
241         WRITE(numout,*) '~~~~~~~~~~~~'
242         WRITE(numout,*) '   Namelist namtra_adv : chose a advection scheme for tracers'
243         WRITE(numout,*) '      No advection on T & S                     ln_traadv_OFF = ', ln_traadv_OFF
244         WRITE(numout,*) '      centered scheme                           ln_traadv_cen = ', ln_traadv_cen
245         WRITE(numout,*) '            horizontal 2nd/4th order               nn_cen_h   = ', nn_fct_h
246         WRITE(numout,*) '            vertical   2nd/4th order               nn_cen_v   = ', nn_fct_v
247         WRITE(numout,*) '      Flux Corrected Transport scheme           ln_traadv_fct = ', ln_traadv_fct
248         WRITE(numout,*) '            horizontal 2nd/4th order               nn_fct_h   = ', nn_fct_h
249         WRITE(numout,*) '            vertical   2nd/4th order               nn_fct_v   = ', nn_fct_v
250         WRITE(numout,*) '      MUSCL scheme                              ln_traadv_mus = ', ln_traadv_mus
251         WRITE(numout,*) '            + upstream scheme near river mouths    ln_mus_ups = ', ln_mus_ups
252         WRITE(numout,*) '      UBS scheme                                ln_traadv_ubs = ', ln_traadv_ubs
253         WRITE(numout,*) '            vertical   2nd/4th order               nn_ubs_v   = ', nn_ubs_v
254         WRITE(numout,*) '      QUICKEST scheme                           ln_traadv_qck = ', ln_traadv_qck
255      ENDIF
256      !
257      !                                !==  Parameter control & set nadv ==!
258      ioptio = 0
259      IF( ln_traadv_OFF ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_NO_adv   ;   ENDIF
260      IF( ln_traadv_cen ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_CEN      ;   ENDIF
261      IF( ln_traadv_fct ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_FCT      ;   ENDIF
262      IF( ln_traadv_mus ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_MUS      ;   ENDIF
263      IF( ln_traadv_ubs ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_UBS      ;   ENDIF
264      IF( ln_traadv_qck ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_QCK      ;   ENDIF
265      !
266      IF( ioptio /= 1 )   CALL ctl_stop( 'tra_adv_init: Choose ONE advection option in namelist namtra_adv' )
267      !
268      IF( ln_traadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 )   &          ! Centered
269                        .AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 )   ) THEN
270        CALL ctl_stop( 'tra_adv_init: CEN scheme, choose 2nd or 4th order' )
271      ENDIF
272      IF( ln_traadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 )   &          ! FCT
273                        .AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 )   ) THEN
274        CALL ctl_stop( 'tra_adv_init: FCT scheme, choose 2nd or 4th order' )
275      ENDIF
276      ! TEMP: [tiling] This change not necessary after all lbc_lnks removed in the nn_hls = 2 case in tra_adv_fct
277      IF( ln_traadv_fct .AND. ln_tile ) THEN
278         CALL ctl_warn( 'tra_adv_init: FCT scheme does not yet work with tiling' )
279      ENDIF
280      IF( ln_traadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 )   ) THEN     ! UBS
281        CALL ctl_stop( 'tra_adv_init: UBS scheme, choose 2nd or 4th order' )
282      ENDIF
283      IF( ln_traadv_ubs .AND. nn_ubs_v == 4 ) THEN
284         CALL ctl_warn( 'tra_adv_init: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
285      ENDIF
286      IF( ln_isfcav ) THEN                                                       ! ice-shelf cavities
287         IF(  ln_traadv_cen .AND. nn_cen_v == 4    .OR.   &                            ! NO 4th order with ISF
288            & ln_traadv_fct .AND. nn_fct_v == 4   )   CALL ctl_stop( 'tra_adv_init: 4th order COMPACT scheme not allowed with ISF' )
289      ENDIF
290      !
291      !                                !==  Print the choice  ==!
292      IF(lwp) THEN
293         WRITE(numout,*)
294         SELECT CASE ( nadv )
295         CASE( np_NO_adv  )   ;   WRITE(numout,*) '   ==>>>   NO T-S advection'
296         CASE( np_CEN     )   ;   WRITE(numout,*) '   ==>>>   CEN      scheme is used. Horizontal order: ', nn_cen_h,   &
297            &                                                                        ' Vertical   order: ', nn_cen_v
298         CASE( np_FCT     )   ;   WRITE(numout,*) '   ==>>>   FCT      scheme is used. Horizontal order: ', nn_fct_h,   &
299            &                                                                        ' Vertical   order: ', nn_fct_v
300         CASE( np_MUS     )   ;   WRITE(numout,*) '   ==>>>   MUSCL    scheme is used'
301         CASE( np_UBS     )   ;   WRITE(numout,*) '   ==>>>   UBS      scheme is used'
302         CASE( np_QCK     )   ;   WRITE(numout,*) '   ==>>>   QUICKEST scheme is used'
303         END SELECT
304      ENDIF
305      !
306      CALL tra_mle_init            !== initialisation of the Mixed Layer Eddy parametrisation (MLE)  ==!
307      !
308   END SUBROUTINE tra_adv_init
309
310  !!======================================================================
311END MODULE traadv
Note: See TracBrowser for help on using the repository browser.