New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_cen.F90 in NEMO/branches/2021/dev_r14116_HPC-10_mcastril_Mixed_Precision_implementation/src/OCE/TRA – NEMO

source: NEMO/branches/2021/dev_r14116_HPC-10_mcastril_Mixed_Precision_implementation/src/OCE/TRA/traadv_cen.F90 @ 14986

Last change on this file since 14986 was 14986, checked in by sparonuz, 3 years ago

Merge trunk -r14984:HEAD
  • Property svn:keywords set to Id
File size: 10.7 KB
Line 
1MODULE traadv_cen
2   !!======================================================================
3   !!                     ***  MODULE  traadv_cen  ***
4   !! Ocean  tracers:   advective trend (2nd/4th order centered)
5   !!======================================================================
6   !! History :  3.7  ! 2014-05  (G. Madec)  original code
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   tra_adv_cen   : update the tracer trend with the advection trends using a centered or scheme (2nd or 4th order)
11   !!                   NB: on the vertical it is actually a 4th order COMPACT scheme which is used
12   !!----------------------------------------------------------------------
13   USE dom_oce        ! ocean space and time domain
14   USE eosbn2         ! equation of state
15   USE traadv_fct     ! acces to routine interp_4th_cpt
16   USE trd_oce        ! trends: ocean variables
17   USE trdtra         ! trends manager: tracers
18   USE diaptr         ! poleward transport diagnostics
19   USE diaar5         ! AR5 diagnostics
20   !
21   USE in_out_manager ! I/O manager
22   USE iom            ! IOM library
23   USE trc_oce        ! share passive tracers/Ocean variables
24   USE lib_mpp        ! MPP library
25#if defined key_loop_fusion
26   USE traadv_cen_lf  ! centered scheme            (tra_adv_cen  routine - loop fusion version)
27#endif
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   tra_adv_cen   ! called by traadv.F90
33
34   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
35
36   LOGICAL ::   l_trd   ! flag to compute trends
37   LOGICAL ::   l_ptr   ! flag to compute poleward transport
38   LOGICAL ::   l_hst   ! flag to compute heat/salt transport
39
40   !! * Substitutions
41#  include "do_loop_substitute.h90"
42#  include "domzgr_substitute.h90"
43#  include "single_precision_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
46   !! $Id$
47   !! Software governed by the CeCILL license (see ./LICENSE)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE tra_adv_cen( kt, kit000, cdtype, pU, pV, pW,     &
52      &                    Kmm, pt, kjpt, Krhs, kn_cen_h, kn_cen_v )
53      !!----------------------------------------------------------------------
54      !!                  ***  ROUTINE tra_adv_cen  ***
55      !!
56      !! ** Purpose :   Compute the now trend due to the advection of tracers
57      !!      and add it to the general trend of passive tracer equations.
58      !!
59      !! ** Method  :   The advection is evaluated by a 2nd or 4th order scheme
60      !!               using now fields (leap-frog scheme).
61      !!       kn_cen_h = 2  ==>> 2nd order centered scheme on the horizontal
62      !!                = 4  ==>> 4th order    -        -       -      -
63      !!       kn_cen_v = 2  ==>> 2nd order centered scheme on the vertical
64      !!                = 4  ==>> 4th order COMPACT  scheme     -      -
65      !!
66      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
67      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
68      !!             - poleward advective heat and salt transport (l_diaptr=T)
69      !!----------------------------------------------------------------------
70      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
71      INTEGER                                  , INTENT(in   ) ::   Kmm, Krhs       ! ocean time level indices
72      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
73      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
74      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
75      INTEGER                                  , INTENT(in   ) ::   kn_cen_h        ! =2/4 (2nd or 4th order scheme)
76      INTEGER                                  , INTENT(in   ) ::   kn_cen_v        ! =2/4 (2nd or 4th order scheme)
77      ! TEMP: [tiling] This can be A2D(nn_hls) after all lbc_lnks removed in the nn_hls = 2 case in tra_adv_fct
78      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume flux components
79      REAL(dp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
80      !
81      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
82      INTEGER  ::   ierr             ! local integer
83      REAL(wp) ::   zC2t_u, zC4t_u   ! local scalars
84      REAL(wp) ::   zC2t_v, zC4t_v   !   -      -
85      REAL(wp), DIMENSION(A2D(nn_hls),jpk) ::   zwx, zwy, zwz, ztu, ztv, ztw
86      !!----------------------------------------------------------------------
87      !
88#if defined key_loop_fusion
89      CALL tra_adv_cen_lf    ( kt, nit000, cdtype, pU, pV, pW, Kmm, pt, kjpt, Krhs, kn_cen_h, kn_cen_v )
90#else
91      IF( .NOT. l_istiled .OR. ntile == 1 )  THEN                       ! Do only on the first tile
92         IF( kt == kit000 )  THEN
93            IF(lwp) WRITE(numout,*)
94            IF(lwp) WRITE(numout,*) 'tra_adv_cen : centered advection scheme on ', cdtype, ' order h/v =', kn_cen_h,'/', kn_cen_v
95            IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~ '
96         ENDIF
97         !                          ! set local switches
98         l_trd = .FALSE.
99         l_hst = .FALSE.
100         l_ptr = .FALSE.
101         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )       l_trd = .TRUE.
102         IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) )  )    l_ptr = .TRUE.
103         IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
104            &                          iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
105      ENDIF
106      !
107      !
108      zwz(:,:, 1 ) = 0._wp       ! surface & bottom vertical flux set to zero for all tracers
109      zwz(:,:,jpk) = 0._wp
110      !
111      DO jn = 1, kjpt            !==  loop over the tracers  ==!
112         !
113         SELECT CASE( kn_cen_h )       !--  Horizontal fluxes  --!
114         !
115         CASE(  2  )                         !* 2nd order centered
116            DO_3D( 1, 0, 1, 0, 1, jpkm1 )
117               zwx(ji,jj,jk) = 0.5_wp * pU(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm) )
118               zwy(ji,jj,jk) = 0.5_wp * pV(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm) )
119            END_3D
120            !
121         CASE(  4  )                         !* 4th order centered
122            ztu(:,:,jpk) = 0._wp                   ! Bottom value : flux set to zero
123            ztv(:,:,jpk) = 0._wp
124            DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )          ! masked gradient
125               ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
126               ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
127            END_3D
128            IF (nn_hls==1) CALL lbc_lnk( 'traadv_cen', ztu, 'U', -1.0_wp , ztv, 'V', -1.0_wp, ld4only= .TRUE. )   ! Lateral boundary cond.
129            !
130            DO_3D( nn_hls-1, 0, nn_hls-1, 0, 1, jpkm1 )           ! Horizontal advective fluxes
131               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! C2 interpolation of T at u- & v-points (x2)
132               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
133               !                                                  ! C4 interpolation of T at u- & v-points (x2)
134               zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj,jk) - ztu(ji+1,jj,jk) )
135               zC4t_v =  zC2t_v + r1_6 * ( ztv(ji,jj-1,jk) - ztv(ji,jj+1,jk) )
136               !                                                  ! C4 fluxes
137               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * zC4t_u
138               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * zC4t_v
139            END_3D
140            IF (nn_hls==1) CALL lbc_lnk( 'traadv_cen', zwx, 'U', -1._wp , zwy, 'V', -1._wp )
141            !
142         CASE DEFAULT
143            CALL ctl_stop( 'traadv_cen: wrong value for nn_cen' )
144         END SELECT
145         !
146         SELECT CASE( kn_cen_v )       !--  Vertical fluxes  --!   (interior)
147         !
148         CASE(  2  )                         !* 2nd order centered
149            DO_3D( 0, 0, 0, 0, 2, jpk )
150               zwz(ji,jj,jk) = 0.5 * pW(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj,jk-1,jn,Kmm) ) * wmask(ji,jj,jk)
151            END_3D
152            !
153         CASE(  4  )                         !* 4th order compact
154            CALL interp_4th_cpt( CASTWP(pt(:,:,:,jn,Kmm)) , ztw )      ! ztw = interpolated value of T at w-point
155            DO_3D( 0, 0, 0, 0, 2, jpkm1 )
156               zwz(ji,jj,jk) = pW(ji,jj,jk) * ztw(ji,jj,jk) * wmask(ji,jj,jk)
157            END_3D
158            !
159         END SELECT
160         !
161         IF( ln_linssh ) THEN                !* top value   (linear free surf. only as zwz is multiplied by wmask)
162            IF( ln_isfcav ) THEN                  ! ice-shelf cavities (top of the ocean)
163               DO_2D( 1, 1, 1, 1 )
164                  zwz(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kmm)
165               END_2D
166            ELSE                                   ! no ice-shelf cavities (only ocean surface)
167               DO_2D( 1, 1, 1, 1 )
168                  zwz(ji,jj,1) = pW(ji,jj,1) * pt(ji,jj,1,jn,Kmm)
169               END_2D
170            ENDIF
171         ENDIF
172         !
173         DO_3D( 0, 0, 0, 0, 1, jpkm1 )   !--  Divergence of advective fluxes  --!
174            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs)    &
175               &             - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )    &
176               &                + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )    &
177               &                + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1)  ) &
178               &                * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
179         END_3D
180         !                               ! trend diagnostics
181         IF( l_trd ) THEN
182            CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, zwx, pU, CASTWP(pt(:,:,:,jn,Kmm)) )
183            CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, zwy, pV, CASTWP(pt(:,:,:,jn,Kmm)) )
184            CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, zwz, pW, CASTWP(pt(:,:,:,jn,Kmm)) )
185         ENDIF
186         !                                 ! "Poleward" heat and salt transports
187         IF( l_ptr )   CALL dia_ptr_hst( jn, 'adv', zwy(:,:,:) )
188         !                                 !  heat and salt transport
189         IF( l_hst )   CALL dia_ar5_hst( jn, 'adv', zwx(:,:,:), zwy(:,:,:) )
190         !
191      END DO
192      !
193#endif
194   END SUBROUTINE tra_adv_cen
195
196   !!======================================================================
197END MODULE traadv_cen
Note: See TracBrowser for help on using the repository browser.