New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trasbc.F90 in NEMO/branches/2021/dev_r14116_HPC-10_mcastril_Mixed_Precision_implementation/src/OCE/TRA – NEMO

source: NEMO/branches/2021/dev_r14116_HPC-10_mcastril_Mixed_Precision_implementation/src/OCE/TRA/trasbc.F90 @ 15540

Last change on this file since 15540 was 15540, checked in by sparonuz, 3 years ago

Mixed precision version, tested up to 30 years on ORCA2.
  • Property svn:keywords set to Id
File size: 11.5 KB
Line 
1MODULE trasbc
2   !!==============================================================================
3   !!                       ***  MODULE  trasbc  ***
4   !! Ocean active tracers:  surface boundary condition
5   !!==============================================================================
6   !! History :  OPA  !  1998-10  (G. Madec, G. Roullet, M. Imbard)  Original code
7   !!            8.2  !  2001-02  (D. Ludicone)  sea ice and free surface
8   !!  NEMO      1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
10   !!             -   !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!            3.6  !  2014-11  (P. Mathiot) isf melting forcing
12   !!            4.1  !  2019-09  (P. Mathiot) isf moved in traisf
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   tra_sbc       : update the tracer trend at ocean surface
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE sbc_oce        ! surface boundary condition: ocean
20   USE dom_oce        ! ocean space domain variables
21   USE phycst         ! physical constant
22   USE eosbn2         ! Equation Of State
23   USE sbcmod         ! ln_rnf
24   USE sbcrnf         ! River runoff
25   USE traqsr         ! solar radiation penetration
26   USE trd_oce        ! trends: ocean variables
27   USE trdtra         ! trends manager: tracers
28#if defined key_asminc
29   USE asminc         ! Assimilation increment
30#endif
31   !
32   USE in_out_manager ! I/O manager
33   USE prtctl         ! Print control
34   USE iom            ! xIOS server
35   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
36   USE timing         ! Timing
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC   tra_sbc   ! routine called by step.F90
42
43   !! * Substitutions
44#  include "do_loop_substitute.h90"
45#  include "domzgr_substitute.h90"
46#  include "single_precision_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
49   !! $Id$
50   !! Software governed by the CeCILL license (see ./LICENSE)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE tra_sbc ( kt, Kmm, pts, Krhs )
55      !!----------------------------------------------------------------------
56      !!                  ***  ROUTINE tra_sbc  ***
57      !!
58      !! ** Purpose :   Compute the tracer surface boundary condition trend of
59      !!      (flux through the interface, concentration/dilution effect)
60      !!      and add it to the general trend of tracer equations.
61      !!
62      !! ** Method :   The (air+ice)-sea flux has two components:
63      !!      (1) Fext, external forcing (i.e. flux through the (air+ice)-sea interface);
64      !!      (2) Fwe , tracer carried with the water that is exchanged with air+ice.
65      !!               The input forcing fields (emp, rnf, sfx) contain Fext+Fwe,
66      !!             they are simply added to the tracer trend (ts(Krhs)).
67      !!               In linear free surface case (ln_linssh=T), the volume of the
68      !!             ocean does not change with the water exchanges at the (air+ice)-sea
69      !!             interface. Therefore another term has to be added, to mimic the
70      !!             concentration/dilution effect associated with water exchanges.
71      !!
72      !! ** Action  : - Update ts(Krhs) with the surface boundary condition trend
73      !!              - send trends to trdtra module for further diagnostics(l_trdtra=T)
74      !!----------------------------------------------------------------------
75      INTEGER,                                   INTENT(in   ) :: kt         ! ocean time-step index
76      INTEGER,                                   INTENT(in   ) :: Kmm, Krhs  ! time level indices
77      REAL(dp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts        ! active tracers and RHS of tracer equation
78      !
79      INTEGER  ::   ji, jj, jk, jn               ! dummy loop indices
80      INTEGER  ::   ikt, ikb                     ! local integers
81      REAL(wp)  :: zfact, zdep! local scalar
82      REAL(dp)  :: z1_e3t, ztim! local scalar
83      REAL(dp), ALLOCATABLE, DIMENSION(:,:,:) ::  ztrdt, ztrds
84      !!----------------------------------------------------------------------
85      !
86      IF( ln_timing )   CALL timing_start('tra_sbc')
87      !
88      IF( .NOT. l_istiled .OR. ntile == 1 )  THEN                       ! Do only on the first tile
89         IF( kt == nit000 ) THEN
90            IF(lwp) WRITE(numout,*)
91            IF(lwp) WRITE(numout,*) 'tra_sbc : TRAcer Surface Boundary Condition'
92            IF(lwp) WRITE(numout,*) '~~~~~~~ '
93         ENDIF
94      ENDIF
95      !
96      IF( l_trdtra ) THEN                    !* Save ta and sa trends
97         ALLOCATE( ztrdt(jpi,jpj,jpk), ztrds(jpi,jpj,jpk) )
98         ztrdt(:,:,:) = pts(:,:,:,jp_tem,Krhs)
99         ztrds(:,:,:) = pts(:,:,:,jp_sal,Krhs)
100      ENDIF
101      !
102!!gm  This should be moved into sbcmod.F90 module ? (especially now that ln_traqsr is read in namsbc namelist)
103      IF( .NOT.ln_traqsr ) THEN     ! no solar radiation penetration
104         DO_2D_OVR( nn_hls, nn_hls, nn_hls, nn_hls )
105            qns(ji,jj) = qns(ji,jj) + qsr(ji,jj)      ! total heat flux in qns
106            qsr(ji,jj) = 0._wp                        ! qsr set to zero
107         END_2D
108      ENDIF
109
110      !----------------------------------------
111      !        EMP, SFX and QNS effects
112      !----------------------------------------
113      !                             !==  Set before sbc tracer content fields  ==!
114      IF( kt == nit000 ) THEN             !* 1st time-step
115         IF( ln_rstart .AND. .NOT.l_1st_euler ) THEN      ! Restart: read in restart file
116            zfact = 0.5_wp
117            IF( .NOT. l_istiled .OR. ntile == 1 )  THEN                       ! Do only on the first tile
118               IF(lwp) WRITE(numout,*) '          nit000-1 sbc tracer content field read in the restart file'
119               sbc_tsc(:,:,:) = 0._wp
120               CALL iom_get( numror, jpdom_auto, 'sbc_hc_b', sbc_tsc_b(:,:,jp_tem) )   ! before heat content sbc trend
121               CALL iom_get( numror, jpdom_auto, 'sbc_sc_b', sbc_tsc_b(:,:,jp_sal) )   ! before salt content sbc trend
122            ENDIF
123         ELSE                                             ! No restart or restart not found: Euler forward time stepping
124            zfact = 1._wp
125            DO_2D_OVR( nn_hls, nn_hls, nn_hls, nn_hls )
126               sbc_tsc(ji,jj,:) = 0._wp
127               sbc_tsc_b(ji,jj,:) = 0._wp
128            END_2D
129         ENDIF
130      ELSE                                !* other time-steps: swap of forcing fields
131         zfact = 0.5_wp
132         DO_2D_OVR( nn_hls, nn_hls, nn_hls, nn_hls )
133            sbc_tsc_b(ji,jj,:) = sbc_tsc(ji,jj,:)
134         END_2D
135      ENDIF
136      !                             !==  Now sbc tracer content fields  ==!
137      DO_2D_OVR( nn_hls, nn_hls, nn_hls, nn_hls )
138         sbc_tsc(ji,jj,jp_tem) = r1_rho0_rcp * qns(ji,jj)   ! non solar heat flux
139         sbc_tsc(ji,jj,jp_sal) = r1_rho0     * sfx(ji,jj)   ! salt flux due to freezing/melting
140      END_2D
141      IF( ln_linssh ) THEN                !* linear free surface
142         DO_2D_OVR( nn_hls, nn_hls, nn_hls, nn_hls )                    !==>> add concentration/dilution effect due to constant volume cell
143            sbc_tsc(ji,jj,jp_tem) = sbc_tsc(ji,jj,jp_tem) + r1_rho0 * emp(ji,jj) * pts(ji,jj,1,jp_tem,Kmm)
144            sbc_tsc(ji,jj,jp_sal) = sbc_tsc(ji,jj,jp_sal) + r1_rho0 * emp(ji,jj) * pts(ji,jj,1,jp_sal,Kmm)
145         END_2D                                 !==>> output c./d. term
146         IF( iom_use('emp_x_sst') )   CALL iom_put( "emp_x_sst", emp (:,:) * pts(:,:,1,jp_tem,Kmm) )
147         IF( iom_use('emp_x_sss') )   CALL iom_put( "emp_x_sss", emp (:,:) * pts(:,:,1,jp_sal,Kmm) )
148      ENDIF
149      !
150      DO jn = 1, jpts               !==  update tracer trend  ==!
151         DO_2D( 0, 0, 0, 0 )
152            pts(ji,jj,1,jn,Krhs) = pts(ji,jj,1,jn,Krhs) + zfact * ( sbc_tsc_b(ji,jj,jn) + sbc_tsc(ji,jj,jn) )    &
153               &                                                / e3t(ji,jj,1,Kmm)
154         END_2D
155      END DO
156      !
157      IF( .NOT. l_istiled .OR. ntile == nijtile )  THEN                ! Do only on the last tile
158         IF( lrst_oce ) THEN           !==  write sbc_tsc in the ocean restart file  ==!
159            CALL iom_rstput( kt, nitrst, numrow, 'sbc_hc_b', sbc_tsc(:,:,jp_tem) )
160            CALL iom_rstput( kt, nitrst, numrow, 'sbc_sc_b', sbc_tsc(:,:,jp_sal) )
161         ENDIF
162      ENDIF
163      !
164      !----------------------------------------
165      !        River Runoff effects
166      !----------------------------------------
167      !
168      IF( ln_rnf ) THEN         ! input of heat and salt due to river runoff
169         zfact = 0.5_wp
170         DO_2D( 0, 0, 0, 0 )
171            IF( rnf(ji,jj) /= 0._wp ) THEN
172               zdep = zfact / h_rnf(ji,jj)
173               DO jk = 1, nk_rnf(ji,jj)
174                                     pts(ji,jj,jk,jp_tem,Krhs) = pts(ji,jj,jk,jp_tem,Krhs)                                  &
175                                        &                      +  ( rnf_tsc_b(ji,jj,jp_tem) + rnf_tsc(ji,jj,jp_tem) ) * zdep
176                  IF( ln_rnf_sal )   pts(ji,jj,jk,jp_sal,Krhs) = pts(ji,jj,jk,jp_sal,Krhs)                                  &
177                                        &                      +  ( rnf_tsc_b(ji,jj,jp_sal) + rnf_tsc(ji,jj,jp_sal) ) * zdep
178               END DO
179            ENDIF
180         END_2D
181      ENDIF
182
183      IF( iom_use('rnf_x_sst') )   CALL iom_put( "rnf_x_sst", rnf*pts(:,:,1,jp_tem,Kmm) )   ! runoff term on sst
184      IF( iom_use('rnf_x_sss') )   CALL iom_put( "rnf_x_sss", rnf*pts(:,:,1,jp_sal,Kmm) )   ! runoff term on sss
185
186#if defined key_asminc
187      !
188      !----------------------------------------
189      !        Assmilation effects
190      !----------------------------------------
191      !
192      IF( ln_sshinc ) THEN         ! input of heat and salt due to assimilation
193          !
194         IF( ln_linssh ) THEN
195            DO_2D( 0, 0, 0, 0 )
196               ztim = ssh_iau(ji,jj) / e3t(ji,jj,1,Kmm)
197               pts(ji,jj,1,jp_tem,Krhs) = pts(ji,jj,1,jp_tem,Krhs) + pts(ji,jj,1,jp_tem,Kmm) * ztim
198               pts(ji,jj,1,jp_sal,Krhs) = pts(ji,jj,1,jp_sal,Krhs) + pts(ji,jj,1,jp_sal,Kmm) * ztim
199            END_2D
200         ELSE
201            DO_2D( 0, 0, 0, 0 )
202               ztim = ssh_iau(ji,jj) / ( ht(ji,jj) + 1. - ssmask(ji, jj) )
203               pts(ji,jj,:,jp_tem,Krhs) = pts(ji,jj,:,jp_tem,Krhs) + pts(ji,jj,:,jp_tem,Kmm) * ztim
204               pts(ji,jj,:,jp_sal,Krhs) = pts(ji,jj,:,jp_sal,Krhs) + pts(ji,jj,:,jp_sal,Kmm) * ztim
205            END_2D
206         ENDIF
207         !
208      ENDIF
209      !
210#endif
211      !
212      IF( l_trdtra )   THEN                      ! save the horizontal diffusive trends for further diagnostics
213         ztrdt(:,:,:) = pts(:,:,:,jp_tem,Krhs) - ztrdt(:,:,:)
214         ztrds(:,:,:) = pts(:,:,:,jp_sal,Krhs) - ztrds(:,:,:)
215         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_nsr, ztrdt )
216         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_nsr, ztrds )
217         DEALLOCATE( ztrdt , ztrds )
218      ENDIF
219      !
220      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Krhs), clinfo1=' sbc  - Ta: ', mask1=tmask,   &
221         &                                  tab3d_2=pts(:,:,:,jp_sal,Krhs), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
222      !
223      IF( ln_timing )   CALL timing_stop('tra_sbc')
224      !
225   END SUBROUTINE tra_sbc
226
227   !!======================================================================
228END MODULE trasbc
Note: See TracBrowser for help on using the repository browser.