New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trdpen.F90 in NEMO/branches/2021/dev_r14116_HPC-10_mcastril_Mixed_Precision_implementation/src/OCE/TRD – NEMO

source: NEMO/branches/2021/dev_r14116_HPC-10_mcastril_Mixed_Precision_implementation/src/OCE/TRD/trdpen.F90 @ 15540

Last change on this file since 15540 was 15540, checked in by sparonuz, 3 years ago

Mixed precision version, tested up to 30 years on ORCA2.
  • Property svn:keywords set to Id
File size: 7.4 KB
Line 
1MODULE trdpen
2   !!======================================================================
3   !!                       ***  MODULE  trdpen  ***
4   !! Ocean diagnostics:  Potential Energy trends
5   !!=====================================================================
6   !! History :  3.5  !  2012-02  (G. Madec) original code
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   trd_pen       : compute and output Potential Energy trends from T & S trends
11   !!   trd_pen_init  : initialisation of PE trends
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers variables
14   USE dom_oce        ! ocean domain
15   USE sbc_oce        ! surface boundary condition: ocean
16   USE zdf_oce        ! ocean vertical physics
17   USE trd_oce        ! trends: ocean variables
18   USE eosbn2         ! equation of state and related derivatives
19   USE ldftra         ! lateral diffusion: eddy diffusivity & EIV coeff.
20   USE zdfddm         ! vertical physics: double diffusion
21   USE phycst         ! physical constants
22   !
23   USE in_out_manager ! I/O manager
24   USE iom            ! I/O manager library
25   USE lib_mpp        ! MPP library
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   trd_pen        ! called by all trdtra module
31   PUBLIC   trd_pen_init   ! called by all nemogcm module
32
33   INTEGER ::   nkstp   ! current time step
34
35   REAL(dp), ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) ::   rab_pe   ! partial derivatives of PE anomaly with respect to T and S
36
37   !! * Substitutions
38#  include "domzgr_substitute.h90"
39#  include "single_precision_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
42   !! $Id$
43   !! Software governed by the CeCILL license (see ./LICENSE)
44   !!----------------------------------------------------------------------
45
46CONTAINS
47
48   INTEGER FUNCTION trd_pen_alloc()
49      !!---------------------------------------------------------------------
50      !!                  ***  FUNCTION trd_tra_alloc  ***
51      !!---------------------------------------------------------------------
52      ALLOCATE( rab_pe(jpi,jpj,jpk,jpts) , STAT= trd_pen_alloc )
53      !
54      CALL mpp_sum ( 'trdpen', trd_pen_alloc )
55      IF( trd_pen_alloc /= 0 )   CALL ctl_stop( 'STOP',  'trd_pen_alloc: failed to allocate arrays'  )
56   END FUNCTION trd_pen_alloc
57
58
59   SUBROUTINE trd_pen( ptrdx, ptrdy, ktrd, kt, pdt, Kmm )
60      !!---------------------------------------------------------------------
61      !!                  ***  ROUTINE trd_tra_mng  ***
62      !!
63      !! ** Purpose :   Dispatch all trends computation, e.g. 3D output, integral
64      !!                constraints, barotropic vorticity, kinetic enrgy,
65      !!                potential energy, and/or mixed layer budget.
66      !!----------------------------------------------------------------------
67      REAL(dp), DIMENSION(:,:,:), INTENT(in) ::   ptrdx, ptrdy   ! Temperature & Salinity trends
68      INTEGER                   , INTENT(in) ::   ktrd           ! tracer trend index
69      INTEGER                   , INTENT(in) ::   kt             ! time step index
70      INTEGER                   , INTENT(in) ::   Kmm            ! time level index
71      REAL(dp)                  , INTENT(in) ::   pdt            ! time step [s]
72      !
73      INTEGER ::   jk                                            ! dummy loop indices
74      REAL(dp), ALLOCATABLE, DIMENSION(:,:)      ::   z2d            ! 2D workspace
75      REAL(dp), DIMENSION(jpi,jpj,jpk)           ::   zpe            ! 3D workspace
76      !!----------------------------------------------------------------------
77      !
78      zpe(:,:,:) = 0._wp
79      !
80      IF( kt /= nkstp ) THEN     ! full eos: set partial derivatives at the 1st call of kt time step
81         nkstp = kt
82         CALL eos_pen( ts(:,:,:,:,Kmm), rab_pe, zpe, Kmm )
83         CALL iom_put( "alphaPE", rab_pe(:,:,:,jp_tem) )
84         CALL iom_put( "betaPE" , rab_pe(:,:,:,jp_sal) )
85         CALL iom_put( "PEanom" , zpe )
86      ENDIF
87      !
88      zpe(:,:,jpk) = 0._wp
89      DO jk = 1, jpkm1
90         zpe(:,:,jk) = ( - ( rab_n(:,:,jk,jp_tem) + rab_pe(:,:,jk,jp_tem) ) * ptrdx(:,:,jk)   &
91            &            + ( rab_n(:,:,jk,jp_sal) + rab_pe(:,:,jk,jp_sal) ) * ptrdy(:,:,jk)  )
92      END DO
93
94      SELECT CASE ( ktrd )
95      CASE ( jptra_xad  )   ;   CALL iom_put( "petrd_xad", zpe )   ! zonal    advection
96      CASE ( jptra_yad  )   ;   CALL iom_put( "petrd_yad", zpe )   ! merid.   advection
97      CASE ( jptra_zad  )   ;   CALL iom_put( "petrd_zad", zpe )   ! vertical advection
98                                IF( ln_linssh ) THEN                   ! cst volume : adv flux through z=0 surface
99                                   ALLOCATE( z2d(jpi,jpj) )
100                                   z2d(:,:) = ww(:,:,1) * ( &
101                                     &   - ( rab_n(:,:,1,jp_tem) + rab_pe(:,:,1,jp_tem) ) * ts(:,:,1,jp_tem,Kmm)    &
102                                     &   + ( rab_n(:,:,1,jp_sal) + rab_pe(:,:,1,jp_sal) ) * ts(:,:,1,jp_sal,Kmm)    &
103                                     & ) / e3t(:,:,1,Kmm)
104                                   CALL iom_put( "petrd_sad" , z2d )
105                                   DEALLOCATE( z2d )
106                                ENDIF
107      CASE ( jptra_ldf  )   ;   CALL iom_put( "petrd_ldf" , zpe )   ! lateral  diffusion
108      CASE ( jptra_zdf  )   ;   CALL iom_put( "petrd_zdf" , zpe )   ! lateral  diffusion (K_z)
109      CASE ( jptra_zdfp )   ;   CALL iom_put( "petrd_zdfp", zpe )   ! vertical diffusion (K_z)
110      CASE ( jptra_dmp  )   ;   CALL iom_put( "petrd_dmp" , zpe )   ! internal 3D restoring (tradmp)
111      CASE ( jptra_bbl  )   ;   CALL iom_put( "petrd_bbl" , zpe )   ! bottom boundary layer
112      CASE ( jptra_npc  )   ;   CALL iom_put( "petrd_npc" , zpe )   ! non penetr convect adjustment
113      CASE ( jptra_nsr  )   ;   CALL iom_put( "petrd_nsr" , zpe )   ! surface forcing + runoff (ln_rnf=T)
114      CASE ( jptra_qsr  )   ;   CALL iom_put( "petrd_qsr" , zpe )   ! air-sea : penetrative sol radiat
115      CASE ( jptra_bbc  )   ;   CALL iom_put( "petrd_bbc" , zpe )   ! bottom bound cond (geoth flux)
116      CASE ( jptra_atf  )   ;   CALL iom_put( "petrd_atf" , zpe )   ! asselin time filter (last trend)
117         !
118      END SELECT
119      !
120      !
121   END SUBROUTINE trd_pen
122
123
124   SUBROUTINE trd_pen_init
125      !!---------------------------------------------------------------------
126      !!                  ***  ROUTINE trd_pen_init  ***
127      !!
128      !! ** Purpose :   initialisation of 3D Kinetic Energy trend diagnostic
129      !!----------------------------------------------------------------------
130      INTEGER  ::   ji, jj, jk   ! dummy loop indices
131      !!----------------------------------------------------------------------
132      !
133      IF(lwp) THEN
134         WRITE(numout,*)
135         WRITE(numout,*) 'trd_pen_init : 3D Potential ENergy trends'
136         WRITE(numout,*) '~~~~~~~~~~~~~'
137      ENDIF
138      !                           ! allocate box volume arrays
139      IF ( trd_pen_alloc() /= 0 )   CALL ctl_stop('trd_pen_alloc: failed to allocate arrays')
140      !
141      rab_pe(:,:,:,:) = 0._wp
142      !
143      IF( .NOT.ln_linssh )   CALL ctl_stop('trd_pen_init : PE trends not coded for variable volume')
144      !
145      nkstp     = nit000 - 1
146      !
147   END SUBROUTINE trd_pen_init
148
149   !!======================================================================
150END MODULE trdpen
Note: See TracBrowser for help on using the repository browser.