| 1 | MODULE p4zmeso |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE p4zmeso *** |
|---|
| 4 | !! TOP : PISCES Compute the sources/sinks for mesozooplankton |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 1.0 ! 2002 (O. Aumont) Original code |
|---|
| 7 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
|---|
| 8 | !! 3.4 ! 2011-06 (O. Aumont, C. Ethe) Quota model for iron |
|---|
| 9 | !!---------------------------------------------------------------------- |
|---|
| 10 | !! p4z_meso : Compute the sources/sinks for mesozooplankton |
|---|
| 11 | !! p4z_meso_init : Initialization of the parameters for mesozooplankton |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | USE oce_trc ! shared variables between ocean and passive tracers |
|---|
| 14 | USE trc ! passive tracers common variables |
|---|
| 15 | USE sms_pisces ! PISCES Source Minus Sink variables |
|---|
| 16 | USE p4zprod ! production |
|---|
| 17 | USE prtctl ! print control for debugging |
|---|
| 18 | USE iom ! I/O manager |
|---|
| 19 | |
|---|
| 20 | IMPLICIT NONE |
|---|
| 21 | PRIVATE |
|---|
| 22 | |
|---|
| 23 | PUBLIC p4z_meso ! called in p4zbio.F90 |
|---|
| 24 | PUBLIC p4z_meso_init ! called in trcsms_pisces.F90 |
|---|
| 25 | |
|---|
| 26 | REAL(wp), PUBLIC :: part2 !: part of calcite not dissolved in mesozoo guts |
|---|
| 27 | REAL(wp), PUBLIC :: xpref2d !: mesozoo preference for diatoms |
|---|
| 28 | REAL(wp), PUBLIC :: xpref2n !: mesozoo preference for nanophyto |
|---|
| 29 | REAL(wp), PUBLIC :: xpref2z !: mesozoo preference for microzooplankton |
|---|
| 30 | REAL(wp), PUBLIC :: xpref2c !: mesozoo preference for POC |
|---|
| 31 | REAL(wp), PUBLIC :: xthresh2zoo !: zoo feeding threshold for mesozooplankton |
|---|
| 32 | REAL(wp), PUBLIC :: xthresh2dia !: diatoms feeding threshold for mesozooplankton |
|---|
| 33 | REAL(wp), PUBLIC :: xthresh2phy !: nanophyto feeding threshold for mesozooplankton |
|---|
| 34 | REAL(wp), PUBLIC :: xthresh2poc !: poc feeding threshold for mesozooplankton |
|---|
| 35 | REAL(wp), PUBLIC :: xthresh2 !: feeding threshold for mesozooplankton |
|---|
| 36 | REAL(wp), PUBLIC :: resrat2 !: exsudation rate of mesozooplankton |
|---|
| 37 | REAL(wp), PUBLIC :: mzrat2 !: microzooplankton mortality rate |
|---|
| 38 | REAL(wp), PUBLIC :: grazrat2 !: maximal mesozoo grazing rate |
|---|
| 39 | REAL(wp), PUBLIC :: xkgraz2 !: non assimilated fraction of P by mesozoo |
|---|
| 40 | REAL(wp), PUBLIC :: unass2 !: Efficicency of mesozoo growth |
|---|
| 41 | REAL(wp), PUBLIC :: sigma2 !: Fraction of mesozoo excretion as DOM |
|---|
| 42 | REAL(wp), PUBLIC :: epsher2 !: growth efficiency |
|---|
| 43 | REAL(wp), PUBLIC :: epsher2min !: minimum growth efficiency at high food for grazing 2 |
|---|
| 44 | REAL(wp), PUBLIC :: grazflux !: mesozoo flux feeding rate |
|---|
| 45 | |
|---|
| 46 | !! * Substitutions |
|---|
| 47 | # include "do_loop_substitute.h90" |
|---|
| 48 | # include "single_precision_substitute.h90" |
|---|
| 49 | !!---------------------------------------------------------------------- |
|---|
| 50 | !! NEMO/TOP 4.0 , NEMO Consortium (2018) |
|---|
| 51 | !! $Id$ |
|---|
| 52 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 53 | !!---------------------------------------------------------------------- |
|---|
| 54 | CONTAINS |
|---|
| 55 | |
|---|
| 56 | SUBROUTINE p4z_meso( kt, knt, Kbb, Krhs ) |
|---|
| 57 | !!--------------------------------------------------------------------- |
|---|
| 58 | !! *** ROUTINE p4z_meso *** |
|---|
| 59 | !! |
|---|
| 60 | !! ** Purpose : Compute the sources/sinks for mesozooplankton |
|---|
| 61 | !! |
|---|
| 62 | !! ** Method : - ??? |
|---|
| 63 | !!--------------------------------------------------------------------- |
|---|
| 64 | INTEGER, INTENT(in) :: kt, knt ! ocean time step and ??? |
|---|
| 65 | INTEGER, INTENT(in) :: Kbb, Krhs ! time level indices |
|---|
| 66 | ! |
|---|
| 67 | INTEGER :: ji, jj, jk |
|---|
| 68 | REAL(wp) :: zcompadi, zcompaph, zcompapoc, zcompaz, zcompam |
|---|
| 69 | REAL(wp) :: zgraze2 , zdenom, zdenom2 |
|---|
| 70 | REAL(wp) :: zfact , zfood, zfoodlim, zproport, zbeta |
|---|
| 71 | REAL(wp) :: zmortzgoc, zfrac, zfracfe, zratio, zratio2, zfracal, zgrazcal |
|---|
| 72 | REAL(wp) :: zepsherf, zepshert, zepsherv, zepsherq |
|---|
| 73 | REAL(wp) :: zgrarsig, zgraztotc, zgraztotn, zgraztotf |
|---|
| 74 | REAL(wp) :: zgrarem2, zgrafer2, zgrapoc2, zprcaca, zmortz, zgrasrat, zgrasratn |
|---|
| 75 | REAL(wp) :: zrespz, ztortz, zgrazd, zgrazz, zgrazpof |
|---|
| 76 | REAL(wp) :: zgrazn, zgrazpoc, zgraznf, zgrazf |
|---|
| 77 | REAL(wp) :: zgrazfffp, zgrazfffg, zgrazffep, zgrazffeg |
|---|
| 78 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazing2, zfezoo2, zz2ligprod |
|---|
| 79 | CHARACTER (len=25) :: charout |
|---|
| 80 | !!--------------------------------------------------------------------- |
|---|
| 81 | ! |
|---|
| 82 | IF( ln_timing ) CALL timing_start('p4z_meso') |
|---|
| 83 | ! |
|---|
| 84 | DO_3D( 1, 1, 1, 1, 1, jpkm1 ) |
|---|
| 85 | zcompam = MAX( ( tr(ji,jj,jk,jpmes,Kbb) - 1.e-9 ), 0.e0 ) |
|---|
| 86 | zfact = xstep * tgfunc2(ji,jj,jk) * zcompam |
|---|
| 87 | |
|---|
| 88 | ! Respiration rates of both zooplankton |
|---|
| 89 | ! ------------------------------------- |
|---|
| 90 | zrespz = resrat2 * zfact * ( tr(ji,jj,jk,jpmes,Kbb) / ( xkmort + tr(ji,jj,jk,jpmes,Kbb) ) & |
|---|
| 91 | & + 3. * nitrfac(ji,jj,jk) ) |
|---|
| 92 | |
|---|
| 93 | ! Zooplankton mortality. A square function has been selected with |
|---|
| 94 | ! no real reason except that it seems to be more stable and may mimic predation |
|---|
| 95 | ! --------------------------------------------------------------- |
|---|
| 96 | ztortz = mzrat2 * 1.e6 * zfact * tr(ji,jj,jk,jpmes,Kbb) * (1. - nitrfac(ji,jj,jk) ) |
|---|
| 97 | ! |
|---|
| 98 | zcompadi = MAX( ( tr(ji,jj,jk,jpdia,Kbb) - xthresh2dia ), 0.e0 ) |
|---|
| 99 | zcompaz = MAX( ( tr(ji,jj,jk,jpzoo,Kbb) - xthresh2zoo ), 0.e0 ) |
|---|
| 100 | zcompapoc = MAX( ( tr(ji,jj,jk,jppoc,Kbb) - xthresh2poc ), 0.e0 ) |
|---|
| 101 | ! Size effect of nanophytoplankton on grazing : the smaller it is, the less prone |
|---|
| 102 | ! it is to predation by mesozooplankton |
|---|
| 103 | ! ------------------------------------------------------------------------------- |
|---|
| 104 | zcompaph = MAX( ( tr(ji,jj,jk,jpphy,Kbb) - xthresh2phy ), 0.e0 ) & |
|---|
| 105 | & * MIN(1., MAX( 0., ( quotan(ji,jj,jk) - 0.2) / 0.3 ) ) |
|---|
| 106 | |
|---|
| 107 | ! Mesozooplankton grazing |
|---|
| 108 | ! ------------------------ |
|---|
| 109 | zfood = xpref2d * zcompadi + xpref2z * zcompaz + xpref2n * zcompaph + xpref2c * zcompapoc |
|---|
| 110 | zfoodlim = MAX( 0., zfood - MIN( 0.5 * zfood, xthresh2 ) ) |
|---|
| 111 | zdenom = zfoodlim / ( xkgraz2 + zfoodlim ) |
|---|
| 112 | zdenom2 = zdenom / ( zfood + rtrn ) |
|---|
| 113 | zgraze2 = grazrat2 * xstep * tgfunc2(ji,jj,jk) * tr(ji,jj,jk,jpmes,Kbb) * (1. - nitrfac(ji,jj,jk)) |
|---|
| 114 | |
|---|
| 115 | zgrazd = zgraze2 * xpref2d * zcompadi * zdenom2 |
|---|
| 116 | zgrazz = zgraze2 * xpref2z * zcompaz * zdenom2 |
|---|
| 117 | zgrazn = zgraze2 * xpref2n * zcompaph * zdenom2 |
|---|
| 118 | zgrazpoc = zgraze2 * xpref2c * zcompapoc * zdenom2 |
|---|
| 119 | |
|---|
| 120 | zgraznf = zgrazn * tr(ji,jj,jk,jpnfe,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) + rtrn) |
|---|
| 121 | zgrazf = zgrazd * tr(ji,jj,jk,jpdfe,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn) |
|---|
| 122 | zgrazpof = zgrazpoc * tr(ji,jj,jk,jpsfe,Kbb) / ( tr(ji,jj,jk,jppoc,Kbb) + rtrn) |
|---|
| 123 | |
|---|
| 124 | ! Mesozooplankton flux feeding on GOC |
|---|
| 125 | ! ---------------------------------- |
|---|
| 126 | zgrazffeg = grazflux * xstep * wsbio4(ji,jj,jk) & |
|---|
| 127 | & * tgfunc2(ji,jj,jk) * tr(ji,jj,jk,jpgoc,Kbb) * tr(ji,jj,jk,jpmes,Kbb) & |
|---|
| 128 | & * (1. - nitrfac(ji,jj,jk)) |
|---|
| 129 | zgrazfffg = zgrazffeg * tr(ji,jj,jk,jpbfe,Kbb) / (tr(ji,jj,jk,jpgoc,Kbb) + rtrn) |
|---|
| 130 | zgrazffep = grazflux * xstep * wsbio3(ji,jj,jk) & |
|---|
| 131 | & * tgfunc2(ji,jj,jk) * tr(ji,jj,jk,jppoc,Kbb) * tr(ji,jj,jk,jpmes,Kbb) & |
|---|
| 132 | & * (1. - nitrfac(ji,jj,jk)) |
|---|
| 133 | zgrazfffp = zgrazffep * tr(ji,jj,jk,jpsfe,Kbb) / (tr(ji,jj,jk,jppoc,Kbb) + rtrn) |
|---|
| 134 | ! |
|---|
| 135 | zgraztotc = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg |
|---|
| 136 | ! Compute the proportion of filter feeders |
|---|
| 137 | zproport = (zgrazffep + zgrazffeg)/(rtrn + zgraztotc) |
|---|
| 138 | ! Compute fractionation of aggregates. It is assumed that |
|---|
| 139 | ! diatoms based aggregates are more prone to fractionation |
|---|
| 140 | ! since they are more porous (marine snow instead of fecal pellets) |
|---|
| 141 | zratio = tr(ji,jj,jk,jpgsi,Kbb) / ( tr(ji,jj,jk,jpgoc,Kbb) + rtrn ) |
|---|
| 142 | zratio2 = zratio * zratio |
|---|
| 143 | zfrac = zproport * grazflux * xstep * wsbio4(ji,jj,jk) & |
|---|
| 144 | & * tr(ji,jj,jk,jpgoc,Kbb) * tr(ji,jj,jk,jpmes,Kbb) & |
|---|
| 145 | & * ( 0.2 + 3.8 * zratio2 / ( 1.**2 + zratio2 ) ) |
|---|
| 146 | zfracfe = zfrac * tr(ji,jj,jk,jpbfe,Kbb) / (tr(ji,jj,jk,jpgoc,Kbb) + rtrn) |
|---|
| 147 | |
|---|
| 148 | zgrazffep = zproport * zgrazffep |
|---|
| 149 | zgrazffeg = zproport * zgrazffeg |
|---|
| 150 | zgrazfffp = zproport * zgrazfffp |
|---|
| 151 | zgrazfffg = zproport * zgrazfffg |
|---|
| 152 | zgraztotc = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg |
|---|
| 153 | zgraztotn = zgrazd * quotad(ji,jj,jk) + zgrazz + zgrazn * quotan(ji,jj,jk) & |
|---|
| 154 | & + zgrazpoc + zgrazffep + zgrazffeg |
|---|
| 155 | zgraztotf = zgrazf + zgraznf + zgrazz * ferat3 + zgrazpof + zgrazfffp + zgrazfffg |
|---|
| 156 | |
|---|
| 157 | ! Total grazing ( grazing by microzoo is already computed in p4zmicro ) |
|---|
| 158 | zgrazing2(ji,jj,jk) = zgraztotc |
|---|
| 159 | |
|---|
| 160 | ! Mesozooplankton efficiency. |
|---|
| 161 | ! We adopt a formulation proposed by Mitra et al. (2007) |
|---|
| 162 | ! The gross growth efficiency is controled by the most limiting nutrient. |
|---|
| 163 | ! Growth is also further decreased when the food quality is poor. This is currently |
|---|
| 164 | ! hard coded : it can be decreased by up to 50% (zepsherq) |
|---|
| 165 | ! GGE can also be decreased when food quantity is high, zepsherf (Montagnes and |
|---|
| 166 | ! Fulton, 2012) |
|---|
| 167 | ! ----------------------------------------------------------------------------------- |
|---|
| 168 | zgrasrat = ( zgraztotf + rtrn )/ ( zgraztotc + rtrn ) |
|---|
| 169 | zgrasratn = ( zgraztotn + rtrn )/ ( zgraztotc + rtrn ) |
|---|
| 170 | zepshert = MIN( 1., zgrasratn, zgrasrat / ferat3) |
|---|
| 171 | zbeta = MAX(0., (epsher2 - epsher2min) ) |
|---|
| 172 | zepsherf = epsher2min + zbeta / ( 1.0 + 0.04E6 * 12. * zfood * zbeta ) |
|---|
| 173 | zepsherq = 0.5 + (1.0 - 0.5) * zepshert * ( 1.0 + 1.0 ) / ( zepshert + 1.0 ) |
|---|
| 174 | zepsherv = zepsherf * zepshert * zepsherq |
|---|
| 175 | |
|---|
| 176 | zgrarem2 = zgraztotc * ( 1. - zepsherv - unass2 ) & |
|---|
| 177 | & + ( 1. - epsher2 - unass2 ) / ( 1. - epsher2 ) * ztortz |
|---|
| 178 | zgrafer2 = zgraztotc * MAX( 0. , ( 1. - unass2 ) * zgrasrat - ferat3 * zepsherv ) & |
|---|
| 179 | & + ferat3 * ( ( 1. - epsher2 - unass2 ) /( 1. - epsher2 ) * ztortz ) |
|---|
| 180 | zgrapoc2 = zgraztotc * unass2 |
|---|
| 181 | |
|---|
| 182 | |
|---|
| 183 | ! Update the arrays TRA which contain the biological sources and sinks |
|---|
| 184 | zgrarsig = zgrarem2 * sigma2 |
|---|
| 185 | tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) + zgrarsig |
|---|
| 186 | tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) + zgrarsig |
|---|
| 187 | tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) + zgrarem2 - zgrarsig |
|---|
| 188 | ! |
|---|
| 189 | IF( ln_ligand ) THEN |
|---|
| 190 | tr(ji,jj,jk,jplgw,Krhs) = tr(ji,jj,jk,jplgw,Krhs) + (zgrarem2 - zgrarsig) * ldocz |
|---|
| 191 | zz2ligprod(ji,jj,jk) = (zgrarem2 - zgrarsig) * ldocz |
|---|
| 192 | ENDIF |
|---|
| 193 | ! |
|---|
| 194 | tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) - o2ut * zgrarsig |
|---|
| 195 | tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) + zgrafer2 |
|---|
| 196 | zfezoo2(ji,jj,jk) = zgrafer2 |
|---|
| 197 | tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) + zgrarsig |
|---|
| 198 | tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * zgrarsig |
|---|
| 199 | |
|---|
| 200 | zmortz = ztortz + zrespz |
|---|
| 201 | zmortzgoc = unass2 / ( 1. - epsher2 ) * ztortz + zrespz |
|---|
| 202 | tr(ji,jj,jk,jpmes,Krhs) = tr(ji,jj,jk,jpmes,Krhs) - zmortz + zepsherv * zgraztotc |
|---|
| 203 | tr(ji,jj,jk,jpdia,Krhs) = tr(ji,jj,jk,jpdia,Krhs) - zgrazd |
|---|
| 204 | tr(ji,jj,jk,jpzoo,Krhs) = tr(ji,jj,jk,jpzoo,Krhs) - zgrazz |
|---|
| 205 | tr(ji,jj,jk,jpphy,Krhs) = tr(ji,jj,jk,jpphy,Krhs) - zgrazn |
|---|
| 206 | tr(ji,jj,jk,jpnch,Krhs) = tr(ji,jj,jk,jpnch,Krhs) - zgrazn * tr(ji,jj,jk,jpnch,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) + rtrn ) |
|---|
| 207 | tr(ji,jj,jk,jpdch,Krhs) = tr(ji,jj,jk,jpdch,Krhs) - zgrazd * tr(ji,jj,jk,jpdch,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn ) |
|---|
| 208 | tr(ji,jj,jk,jpdsi,Krhs) = tr(ji,jj,jk,jpdsi,Krhs) - zgrazd * tr(ji,jj,jk,jpdsi,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn ) |
|---|
| 209 | tr(ji,jj,jk,jpgsi,Krhs) = tr(ji,jj,jk,jpgsi,Krhs) + zgrazd * tr(ji,jj,jk,jpdsi,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn ) |
|---|
| 210 | tr(ji,jj,jk,jpnfe,Krhs) = tr(ji,jj,jk,jpnfe,Krhs) - zgraznf |
|---|
| 211 | tr(ji,jj,jk,jpdfe,Krhs) = tr(ji,jj,jk,jpdfe,Krhs) - zgrazf |
|---|
| 212 | |
|---|
| 213 | tr(ji,jj,jk,jppoc,Krhs) = tr(ji,jj,jk,jppoc,Krhs) - zgrazpoc - zgrazffep + zfrac |
|---|
| 214 | prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zfrac |
|---|
| 215 | conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazpoc - zgrazffep |
|---|
| 216 | tr(ji,jj,jk,jpgoc,Krhs) = tr(ji,jj,jk,jpgoc,Krhs) + zmortzgoc - zgrazffeg + zgrapoc2 - zfrac |
|---|
| 217 | prodgoc(ji,jj,jk) = prodgoc(ji,jj,jk) + zmortzgoc + zgrapoc2 |
|---|
| 218 | consgoc(ji,jj,jk) = consgoc(ji,jj,jk) - zgrazffeg - zfrac |
|---|
| 219 | tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) - zgrazpof - zgrazfffp + zfracfe |
|---|
| 220 | tr(ji,jj,jk,jpbfe,Krhs) = tr(ji,jj,jk,jpbfe,Krhs) + ferat3 * zmortzgoc - zgrazfffg & |
|---|
| 221 | & + zgraztotf * unass2 - zfracfe |
|---|
| 222 | zfracal = tr(ji,jj,jk,jpcal,Kbb) / (tr(ji,jj,jk,jppoc,Kbb) + tr(ji,jj,jk,jpgoc,Kbb) + rtrn ) |
|---|
| 223 | zgrazcal = (zgrazffeg + zgrazpoc) * (1. - part2) * zfracal |
|---|
| 224 | ! calcite production |
|---|
| 225 | zprcaca = xfracal(ji,jj,jk) * zgrazn |
|---|
| 226 | prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo) |
|---|
| 227 | ! |
|---|
| 228 | zprcaca = part2 * zprcaca |
|---|
| 229 | tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) + zgrazcal - zprcaca |
|---|
| 230 | tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) - 2. * ( zgrazcal + zprcaca ) |
|---|
| 231 | tr(ji,jj,jk,jpcal,Krhs) = tr(ji,jj,jk,jpcal,Krhs) - zgrazcal + zprcaca |
|---|
| 232 | END_3D |
|---|
| 233 | ! |
|---|
| 234 | IF( lk_iomput .AND. knt == nrdttrc ) THEN |
|---|
| 235 | CALL iom_put( "PCAL" , prodcal(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:) ) ! Calcite production |
|---|
| 236 | IF( iom_use("GRAZ2") ) THEN ! Total grazing of phyto by zooplankton |
|---|
| 237 | zgrazing2(:,:,jpk) = 0._wp ; CALL iom_put( "GRAZ2" , zgrazing2(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:) ) |
|---|
| 238 | ENDIF |
|---|
| 239 | IF( iom_use("FEZOO2") ) THEN |
|---|
| 240 | zfezoo2 (:,:,jpk) = 0._wp ; CALL iom_put( "FEZOO2", zfezoo2(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:) ) |
|---|
| 241 | ENDIF |
|---|
| 242 | IF( ln_ligand ) THEN |
|---|
| 243 | zz2ligprod(:,:,jpk) = 0._wp ; CALL iom_put( "LPRODZ2", zz2ligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:) ) |
|---|
| 244 | ENDIF |
|---|
| 245 | ENDIF |
|---|
| 246 | ! |
|---|
| 247 | IF(sn_cfctl%l_prttrc) THEN ! print mean trends (used for debugging) |
|---|
| 248 | WRITE(charout, FMT="('meso')") |
|---|
| 249 | CALL prt_ctl_info( charout, cdcomp = 'top' ) |
|---|
| 250 | CALL prt_ctl(tab4d_1=CASTDP(tr(:,:,:,:,Krhs)), mask1=tmask, clinfo=ctrcnm) |
|---|
| 251 | ENDIF |
|---|
| 252 | ! |
|---|
| 253 | IF( ln_timing ) CALL timing_stop('p4z_meso') |
|---|
| 254 | ! |
|---|
| 255 | END SUBROUTINE p4z_meso |
|---|
| 256 | |
|---|
| 257 | |
|---|
| 258 | SUBROUTINE p4z_meso_init |
|---|
| 259 | !!---------------------------------------------------------------------- |
|---|
| 260 | !! *** ROUTINE p4z_meso_init *** |
|---|
| 261 | !! |
|---|
| 262 | !! ** Purpose : Initialization of mesozooplankton parameters |
|---|
| 263 | !! |
|---|
| 264 | !! ** Method : Read the nampismes namelist and check the parameters |
|---|
| 265 | !! called at the first timestep (nittrc000) |
|---|
| 266 | !! |
|---|
| 267 | !! ** input : Namelist nampismes |
|---|
| 268 | !!---------------------------------------------------------------------- |
|---|
| 269 | INTEGER :: ios ! Local integer |
|---|
| 270 | ! |
|---|
| 271 | NAMELIST/namp4zmes/ part2, grazrat2, resrat2, mzrat2, xpref2n, xpref2d, xpref2z, & |
|---|
| 272 | & xpref2c, xthresh2dia, xthresh2phy, xthresh2zoo, xthresh2poc, & |
|---|
| 273 | & xthresh2, xkgraz2, epsher2, epsher2min, sigma2, unass2, grazflux |
|---|
| 274 | !!---------------------------------------------------------------------- |
|---|
| 275 | ! |
|---|
| 276 | IF(lwp) THEN |
|---|
| 277 | WRITE(numout,*) |
|---|
| 278 | WRITE(numout,*) 'p4z_meso_init : Initialization of mesozooplankton parameters' |
|---|
| 279 | WRITE(numout,*) '~~~~~~~~~~~~~' |
|---|
| 280 | ENDIF |
|---|
| 281 | ! |
|---|
| 282 | READ ( numnatp_ref, namp4zmes, IOSTAT = ios, ERR = 901) |
|---|
| 283 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zmes in reference namelist' ) |
|---|
| 284 | READ ( numnatp_cfg, namp4zmes, IOSTAT = ios, ERR = 902 ) |
|---|
| 285 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namp4zmes in configuration namelist' ) |
|---|
| 286 | IF(lwm) WRITE( numonp, namp4zmes ) |
|---|
| 287 | ! |
|---|
| 288 | IF(lwp) THEN ! control print |
|---|
| 289 | WRITE(numout,*) ' Namelist : namp4zmes' |
|---|
| 290 | WRITE(numout,*) ' part of calcite not dissolved in mesozoo guts part2 =', part2 |
|---|
| 291 | WRITE(numout,*) ' mesozoo preference for phyto xpref2n =', xpref2n |
|---|
| 292 | WRITE(numout,*) ' mesozoo preference for diatoms xpref2d =', xpref2d |
|---|
| 293 | WRITE(numout,*) ' mesozoo preference for zoo xpref2z =', xpref2z |
|---|
| 294 | WRITE(numout,*) ' mesozoo preference for poc xpref2c =', xpref2c |
|---|
| 295 | WRITE(numout,*) ' microzoo feeding threshold for mesozoo xthresh2zoo =', xthresh2zoo |
|---|
| 296 | WRITE(numout,*) ' diatoms feeding threshold for mesozoo xthresh2dia =', xthresh2dia |
|---|
| 297 | WRITE(numout,*) ' nanophyto feeding threshold for mesozoo xthresh2phy =', xthresh2phy |
|---|
| 298 | WRITE(numout,*) ' poc feeding threshold for mesozoo xthresh2poc =', xthresh2poc |
|---|
| 299 | WRITE(numout,*) ' feeding threshold for mesozooplankton xthresh2 =', xthresh2 |
|---|
| 300 | WRITE(numout,*) ' exsudation rate of mesozooplankton resrat2 =', resrat2 |
|---|
| 301 | WRITE(numout,*) ' mesozooplankton mortality rate mzrat2 =', mzrat2 |
|---|
| 302 | WRITE(numout,*) ' maximal mesozoo grazing rate grazrat2 =', grazrat2 |
|---|
| 303 | WRITE(numout,*) ' mesozoo flux feeding rate grazflux =', grazflux |
|---|
| 304 | WRITE(numout,*) ' non assimilated fraction of P by mesozoo unass2 =', unass2 |
|---|
| 305 | WRITE(numout,*) ' Efficiency of Mesozoo growth epsher2 =', epsher2 |
|---|
| 306 | WRITE(numout,*) ' Minimum Efficiency of Mesozoo growth epsher2min =', epsher2min |
|---|
| 307 | WRITE(numout,*) ' Fraction of mesozoo excretion as DOM sigma2 =', sigma2 |
|---|
| 308 | WRITE(numout,*) ' half sturation constant for grazing 2 xkgraz2 =', xkgraz2 |
|---|
| 309 | ENDIF |
|---|
| 310 | ! |
|---|
| 311 | END SUBROUTINE p4z_meso_init |
|---|
| 312 | |
|---|
| 313 | !!====================================================================== |
|---|
| 314 | END MODULE p4zmeso |
|---|
