| 1 | MODULE p4zrem |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE p4zrem *** |
|---|
| 4 | !! TOP : PISCES Compute remineralization/dissolution of organic compounds |
|---|
| 5 | !!========================================================================= |
|---|
| 6 | !! History : 1.0 ! 2004 (O. Aumont) Original code |
|---|
| 7 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
|---|
| 8 | !! 3.4 ! 2011-06 (O. Aumont, C. Ethe) Quota model for iron |
|---|
| 9 | !!---------------------------------------------------------------------- |
|---|
| 10 | !! p4z_rem : Compute remineralization/dissolution of organic compounds |
|---|
| 11 | !! p4z_rem_init : Initialisation of parameters for remineralisation |
|---|
| 12 | !! p4z_rem_alloc : Allocate remineralisation variables |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | USE oce_trc ! shared variables between ocean and passive tracers |
|---|
| 15 | USE trc ! passive tracers common variables |
|---|
| 16 | USE sms_pisces ! PISCES Source Minus Sink variables |
|---|
| 17 | USE p4zche ! chemical model |
|---|
| 18 | USE p4zprod ! Growth rate of the 2 phyto groups |
|---|
| 19 | USE p4zlim |
|---|
| 20 | USE prtctl ! print control for debugging |
|---|
| 21 | USE iom ! I/O manager |
|---|
| 22 | |
|---|
| 23 | |
|---|
| 24 | IMPLICIT NONE |
|---|
| 25 | PRIVATE |
|---|
| 26 | |
|---|
| 27 | PUBLIC p4z_rem ! called in p4zbio.F90 |
|---|
| 28 | PUBLIC p4z_rem_init ! called in trcsms_pisces.F90 |
|---|
| 29 | PUBLIC p4z_rem_alloc |
|---|
| 30 | |
|---|
| 31 | REAL(wp), PUBLIC :: xremikc !: remineralisation rate of DOC |
|---|
| 32 | REAL(wp), PUBLIC :: xremikn !: remineralisation rate of DON |
|---|
| 33 | REAL(wp), PUBLIC :: xremikp !: remineralisation rate of DOP |
|---|
| 34 | REAL(wp), PUBLIC :: xremik !: remineralisation rate of POC |
|---|
| 35 | REAL(wp), PUBLIC :: nitrif !: NH4 nitrification rate |
|---|
| 36 | REAL(wp), PUBLIC :: xsirem !: remineralisation rate of POC |
|---|
| 37 | REAL(wp), PUBLIC :: xsiremlab !: fast remineralisation rate of POC |
|---|
| 38 | REAL(wp), PUBLIC :: xsilab !: fraction of labile biogenic silica |
|---|
| 39 | REAL(wp), PUBLIC :: feratb !: Fe/C quota in bacteria |
|---|
| 40 | REAL(wp), PUBLIC :: xkferb !: Half-saturation constant for bacteria Fe/C |
|---|
| 41 | |
|---|
| 42 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: denitr !: denitrification array |
|---|
| 43 | |
|---|
| 44 | !! * Substitutions |
|---|
| 45 | # include "do_loop_substitute.h90" |
|---|
| 46 | # include "domzgr_substitute.h90" |
|---|
| 47 | # include "single_precision_substitute.h90" |
|---|
| 48 | !!---------------------------------------------------------------------- |
|---|
| 49 | !! NEMO/TOP 4.0 , NEMO Consortium (2018) |
|---|
| 50 | !! $Id$ |
|---|
| 51 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 52 | !!---------------------------------------------------------------------- |
|---|
| 53 | CONTAINS |
|---|
| 54 | |
|---|
| 55 | SUBROUTINE p4z_rem( kt, knt, Kbb, Kmm, Krhs ) |
|---|
| 56 | !!--------------------------------------------------------------------- |
|---|
| 57 | !! *** ROUTINE p4z_rem *** |
|---|
| 58 | !! |
|---|
| 59 | !! ** Purpose : Compute remineralization/scavenging of organic compounds |
|---|
| 60 | !! |
|---|
| 61 | !! ** Method : - ??? |
|---|
| 62 | !!--------------------------------------------------------------------- |
|---|
| 63 | INTEGER, INTENT(in) :: kt, knt ! ocean time step |
|---|
| 64 | INTEGER, INTENT(in) :: Kbb, Kmm, Krhs ! time level indices |
|---|
| 65 | ! |
|---|
| 66 | INTEGER :: ji, jj, jk |
|---|
| 67 | REAL(wp) :: zremik, zremikc, zremikn, zremikp, zsiremin, zfact |
|---|
| 68 | REAL(wp) :: zsatur, zsatur2, znusil, znusil2, zdep, zdepmin, zfactdep |
|---|
| 69 | REAL(wp) :: zbactfer, zolimit, zonitr, zrfact2 |
|---|
| 70 | REAL(wp) :: zammonic, zoxyremc, zoxyremn, zoxyremp |
|---|
| 71 | REAL(wp) :: zosil, ztem, zdenitnh4, zolimic, zolimin, zolimip, zdenitrn, zdenitrp |
|---|
| 72 | CHARACTER (len=25) :: charout |
|---|
| 73 | REAL(wp), DIMENSION(jpi,jpj ) :: ztempbac |
|---|
| 74 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdepbac, zolimi, zdepprod, zfacsi, zfacsib, zdepeff, zfebact |
|---|
| 75 | !!--------------------------------------------------------------------- |
|---|
| 76 | ! |
|---|
| 77 | IF( ln_timing ) CALL timing_start('p4z_rem') |
|---|
| 78 | ! |
|---|
| 79 | ! Initialisation of arrys |
|---|
| 80 | zdepprod(:,:,:) = 1._wp |
|---|
| 81 | zdepeff (:,:,:) = 0.3_wp |
|---|
| 82 | ztempbac(:,:) = 0._wp |
|---|
| 83 | zfacsib(:,:,:) = xsilab / ( 1.0 - xsilab ) |
|---|
| 84 | zfebact(:,:,:) = 0._wp |
|---|
| 85 | zfacsi(:,:,:) = xsilab |
|---|
| 86 | |
|---|
| 87 | ! Computation of the mean phytoplankton concentration as |
|---|
| 88 | ! a crude estimate of the bacterial biomass |
|---|
| 89 | ! this parameterization has been deduced from a model version |
|---|
| 90 | ! that was modeling explicitely bacteria |
|---|
| 91 | ! ------------------------------------------------------- |
|---|
| 92 | DO_3D( 1, 1, 1, 1, 1, jpkm1 ) |
|---|
| 93 | zdep = MAX( hmld(ji,jj), heup(ji,jj) ) |
|---|
| 94 | IF( gdept(ji,jj,jk,Kmm) < zdep ) THEN |
|---|
| 95 | zdepbac(ji,jj,jk) = MIN( 0.7 * ( tr(ji,jj,jk,jpzoo,Kbb) + 2.* tr(ji,jj,jk,jpmes,Kbb) ), 4.e-6 ) |
|---|
| 96 | ztempbac(ji,jj) = zdepbac(ji,jj,jk) |
|---|
| 97 | ELSE |
|---|
| 98 | zdepmin = MIN( 1., zdep / gdept(ji,jj,jk,Kmm) ) |
|---|
| 99 | zdepbac (ji,jj,jk) = zdepmin**0.683 * ztempbac(ji,jj) |
|---|
| 100 | zdepprod(ji,jj,jk) = zdepmin**0.273 |
|---|
| 101 | zdepeff (ji,jj,jk) = zdepeff(ji,jj,jk) * zdepmin**0.3 |
|---|
| 102 | ENDIF |
|---|
| 103 | END_3D |
|---|
| 104 | |
|---|
| 105 | IF( ln_p4z ) THEN |
|---|
| 106 | DO_3D( 1, 1, 1, 1, 1, jpkm1 ) |
|---|
| 107 | ! DOC ammonification. Depends on depth, phytoplankton biomass |
|---|
| 108 | ! and a limitation term which is supposed to be a parameterization of the bacterial activity. |
|---|
| 109 | zremik = xremik * xstep / 1.e-6 * xlimbac(ji,jj,jk) * zdepbac(ji,jj,jk) |
|---|
| 110 | zremik = MAX( zremik, 2.74e-4 * xstep ) |
|---|
| 111 | ! Ammonification in oxic waters with oxygen consumption |
|---|
| 112 | ! ----------------------------------------------------- |
|---|
| 113 | zolimit = zremik * ( 1.- nitrfac(ji,jj,jk) ) * tr(ji,jj,jk,jpdoc,Kbb) |
|---|
| 114 | zolimi(ji,jj,jk) = MIN( ( tr(ji,jj,jk,jpoxy,Kbb) - rtrn ) / o2ut, zolimit ) |
|---|
| 115 | ! Ammonification in suboxic waters with denitrification |
|---|
| 116 | ! ------------------------------------------------------- |
|---|
| 117 | zammonic = zremik * nitrfac(ji,jj,jk) * tr(ji,jj,jk,jpdoc,Kbb) |
|---|
| 118 | denitr(ji,jj,jk) = zammonic * ( 1. - nitrfac2(ji,jj,jk) ) |
|---|
| 119 | denitr(ji,jj,jk) = MIN( ( tr(ji,jj,jk,jpno3,Kbb) - rtrn ) / rdenit, denitr(ji,jj,jk) ) |
|---|
| 120 | zoxyremc = zammonic - denitr(ji,jj,jk) |
|---|
| 121 | ! |
|---|
| 122 | zolimi (ji,jj,jk) = MAX( 0.e0, zolimi (ji,jj,jk) ) |
|---|
| 123 | denitr (ji,jj,jk) = MAX( 0.e0, denitr (ji,jj,jk) ) |
|---|
| 124 | zoxyremc = MAX( 0.e0, zoxyremc ) |
|---|
| 125 | |
|---|
| 126 | ! |
|---|
| 127 | tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyremc |
|---|
| 128 | tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyremc |
|---|
| 129 | tr(ji,jj,jk,jpno3,Krhs) = tr(ji,jj,jk,jpno3,Krhs) - denitr (ji,jj,jk) * rdenit |
|---|
| 130 | tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) - zolimi (ji,jj,jk) - denitr(ji,jj,jk) - zoxyremc |
|---|
| 131 | tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) - zolimi (ji,jj,jk) * o2ut |
|---|
| 132 | tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyremc |
|---|
| 133 | tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * ( zolimi(ji,jj,jk) + zoxyremc & |
|---|
| 134 | & + ( rdenit + 1.) * denitr(ji,jj,jk) ) |
|---|
| 135 | END_3D |
|---|
| 136 | ELSE |
|---|
| 137 | DO_3D( 1, 1, 1, 1, 1, jpkm1 ) |
|---|
| 138 | ! DOC ammonification. Depends on depth, phytoplankton biomass |
|---|
| 139 | ! and a limitation term which is supposed to be a parameterization of the bacterial activity. |
|---|
| 140 | ! ----------------------------------------------------------------- |
|---|
| 141 | zremik = xstep / 1.e-6 * MAX(0.01, xlimbac(ji,jj,jk)) * zdepbac(ji,jj,jk) |
|---|
| 142 | zremik = MAX( zremik, 2.74e-4 * xstep / xremikc ) |
|---|
| 143 | |
|---|
| 144 | zremikc = xremikc * zremik |
|---|
| 145 | zremikn = xremikn / xremikc |
|---|
| 146 | zremikp = xremikp / xremikc |
|---|
| 147 | |
|---|
| 148 | ! Ammonification in oxic waters with oxygen consumption |
|---|
| 149 | ! ----------------------------------------------------- |
|---|
| 150 | zolimit = zremikc * ( 1.- nitrfac(ji,jj,jk) ) * tr(ji,jj,jk,jpdoc,Kbb) |
|---|
| 151 | zolimic = MAX( 0.e0, MIN( ( tr(ji,jj,jk,jpoxy,Kbb) - rtrn ) / o2ut, zolimit ) ) |
|---|
| 152 | zolimi(ji,jj,jk) = zolimic |
|---|
| 153 | zolimin = zremikn * zolimic * tr(ji,jj,jk,jpdon,Kbb) / ( tr(ji,jj,jk,jpdoc,Kbb) + rtrn ) |
|---|
| 154 | zolimip = zremikp * zolimic * tr(ji,jj,jk,jpdop,Kbb) / ( tr(ji,jj,jk,jpdoc,Kbb) + rtrn ) |
|---|
| 155 | |
|---|
| 156 | ! Ammonification in suboxic waters with denitrification |
|---|
| 157 | ! ------------------------------------------------------- |
|---|
| 158 | zammonic = zremikc * nitrfac(ji,jj,jk) * tr(ji,jj,jk,jpdoc,Kbb) |
|---|
| 159 | denitr(ji,jj,jk) = zammonic * ( 1. - nitrfac2(ji,jj,jk) ) |
|---|
| 160 | denitr(ji,jj,jk) = MAX(0., MIN( ( tr(ji,jj,jk,jpno3,Kbb) - rtrn ) / rdenit, denitr(ji,jj,jk) ) ) |
|---|
| 161 | zoxyremc = MAX(0., zammonic - denitr(ji,jj,jk)) |
|---|
| 162 | zdenitrn = zremikn * denitr(ji,jj,jk) * tr(ji,jj,jk,jpdon,Kbb) / ( tr(ji,jj,jk,jpdoc,Kbb) + rtrn ) |
|---|
| 163 | zdenitrp = zremikp * denitr(ji,jj,jk) * tr(ji,jj,jk,jpdop,Kbb) / ( tr(ji,jj,jk,jpdoc,Kbb) + rtrn ) |
|---|
| 164 | zoxyremn = zremikn * zoxyremc * tr(ji,jj,jk,jpdon,Kbb) / ( tr(ji,jj,jk,jpdoc,Kbb) + rtrn ) |
|---|
| 165 | zoxyremp = zremikp * zoxyremc * tr(ji,jj,jk,jpdop,Kbb) / ( tr(ji,jj,jk,jpdoc,Kbb) + rtrn ) |
|---|
| 166 | |
|---|
| 167 | tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) + zolimip + zdenitrp + zoxyremp |
|---|
| 168 | tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) + zolimin + zdenitrn + zoxyremn |
|---|
| 169 | tr(ji,jj,jk,jpno3,Krhs) = tr(ji,jj,jk,jpno3,Krhs) - denitr(ji,jj,jk) * rdenit |
|---|
| 170 | tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) - zolimic - denitr(ji,jj,jk) - zoxyremc |
|---|
| 171 | tr(ji,jj,jk,jpdon,Krhs) = tr(ji,jj,jk,jpdon,Krhs) - zolimin - zdenitrn - zoxyremn |
|---|
| 172 | tr(ji,jj,jk,jpdop,Krhs) = tr(ji,jj,jk,jpdop,Krhs) - zolimip - zdenitrp - zoxyremp |
|---|
| 173 | tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) - zolimic * o2ut |
|---|
| 174 | tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) + zolimic + denitr(ji,jj,jk) + zoxyremc |
|---|
| 175 | tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * ( zolimin + zoxyremn + ( rdenit + 1.) * zdenitrn ) |
|---|
| 176 | END_3D |
|---|
| 177 | ! |
|---|
| 178 | ENDIF |
|---|
| 179 | |
|---|
| 180 | |
|---|
| 181 | DO_3D( 1, 1, 1, 1, 1, jpkm1 ) |
|---|
| 182 | ! NH4 nitrification to NO3. Ceased for oxygen concentrations |
|---|
| 183 | ! below 2 umol/L. Inhibited at strong light |
|---|
| 184 | ! ---------------------------------------------------------- |
|---|
| 185 | zonitr = nitrif * xstep * tr(ji,jj,jk,jpnh4,Kbb) * ( 1.- nitrfac(ji,jj,jk) ) & |
|---|
| 186 | & / ( 1.+ emoy(ji,jj,jk) ) * ( 1. + fr_i(ji,jj) * emoy(ji,jj,jk) ) |
|---|
| 187 | zdenitnh4 = nitrif * xstep * tr(ji,jj,jk,jpnh4,Kbb) * nitrfac(ji,jj,jk) |
|---|
| 188 | zdenitnh4 = MIN( ( tr(ji,jj,jk,jpno3,Kbb) - rtrn ) / rdenita, zdenitnh4 ) |
|---|
| 189 | ! Update of the tracers trends |
|---|
| 190 | ! ---------------------------- |
|---|
| 191 | tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) - zonitr - zdenitnh4 |
|---|
| 192 | tr(ji,jj,jk,jpno3,Krhs) = tr(ji,jj,jk,jpno3,Krhs) + zonitr - rdenita * zdenitnh4 |
|---|
| 193 | tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) - o2nit * zonitr |
|---|
| 194 | tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) - 2 * rno3 * zonitr + rno3 * ( rdenita - 1. ) * zdenitnh4 |
|---|
| 195 | END_3D |
|---|
| 196 | |
|---|
| 197 | IF(sn_cfctl%l_prttrc) THEN ! print mean trends (used for debugging) |
|---|
| 198 | WRITE(charout, FMT="('rem1')") |
|---|
| 199 | CALL prt_ctl_info( charout, cdcomp = 'top' ) |
|---|
| 200 | CALL prt_ctl(tab4d_1=CASTDP(tr(:,:,:,:,Krhs)), mask1=tmask, clinfo=ctrcnm) |
|---|
| 201 | ENDIF |
|---|
| 202 | |
|---|
| 203 | DO_3D( 1, 1, 1, 1, 1, jpkm1 ) |
|---|
| 204 | |
|---|
| 205 | ! Bacterial uptake of iron. No iron is available in DOC. So |
|---|
| 206 | ! Bacteries are obliged to take up iron from the water. Some |
|---|
| 207 | ! studies (especially at Papa) have shown this uptake to be significant |
|---|
| 208 | ! ---------------------------------------------------------- |
|---|
| 209 | zbactfer = feratb * rfact2 * 0.6_wp / rday * tgfunc(ji,jj,jk) * xlimbacl(ji,jj,jk) & |
|---|
| 210 | & * tr(ji,jj,jk,jpfer,Kbb) / ( xkferb + tr(ji,jj,jk,jpfer,Kbb) ) & |
|---|
| 211 | & * zdepprod(ji,jj,jk) * zdepeff(ji,jj,jk) * zdepbac(ji,jj,jk) |
|---|
| 212 | tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) - zbactfer*0.33 |
|---|
| 213 | tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) + zbactfer*0.25 |
|---|
| 214 | tr(ji,jj,jk,jpbfe,Krhs) = tr(ji,jj,jk,jpbfe,Krhs) + zbactfer*0.08 |
|---|
| 215 | zfebact(ji,jj,jk) = zbactfer * 0.33 |
|---|
| 216 | blim(ji,jj,jk) = xlimbacl(ji,jj,jk) * zdepbac(ji,jj,jk) / 1.e-6 * zdepprod(ji,jj,jk) |
|---|
| 217 | END_3D |
|---|
| 218 | |
|---|
| 219 | IF(sn_cfctl%l_prttrc) THEN ! print mean trends (used for debugging) |
|---|
| 220 | WRITE(charout, FMT="('rem2')") |
|---|
| 221 | CALL prt_ctl_info( charout, cdcomp = 'top' ) |
|---|
| 222 | CALL prt_ctl(tab4d_1=CASTDP(tr(:,:,:,:,Krhs)), mask1=tmask, clinfo=ctrcnm) |
|---|
| 223 | ENDIF |
|---|
| 224 | |
|---|
| 225 | ! Initialization of the array which contains the labile fraction |
|---|
| 226 | ! of bSi. Set to a constant in the upper ocean |
|---|
| 227 | ! --------------------------------------------------------------- |
|---|
| 228 | |
|---|
| 229 | DO_3D( 1, 1, 1, 1, 1, jpkm1 ) |
|---|
| 230 | zdep = MAX( hmld(ji,jj), heup_01(ji,jj) ) |
|---|
| 231 | zsatur = MAX( rtrn, ( sio3eq(ji,jj,jk) - tr(ji,jj,jk,jpsil,Kbb) ) / ( sio3eq(ji,jj,jk) + rtrn ) ) |
|---|
| 232 | zsatur2 = ( 1. + ts(ji,jj,jk,jp_tem,Kmm) / 400.)**37 |
|---|
| 233 | znusil = 0.225 * ( 1. + ts(ji,jj,jk,jp_tem,Kmm) / 15.) * zsatur + 0.775 * zsatur2 * zsatur**9.25 |
|---|
| 234 | ! Remineralization rate of BSi depedant on T and saturation |
|---|
| 235 | ! --------------------------------------------------------- |
|---|
| 236 | IF ( gdept(ji,jj,jk,Kmm) > zdep ) THEN |
|---|
| 237 | zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk-1) * EXP( -0.5 * ( xsiremlab - xsirem ) & |
|---|
| 238 | & * znusil * e3t(ji,jj,jk,Kmm) / wsbio4(ji,jj,jk) ) |
|---|
| 239 | zfacsi(ji,jj,jk) = zfacsib(ji,jj,jk) / ( 1.0 + zfacsib(ji,jj,jk) ) |
|---|
| 240 | zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk) * EXP( -0.5 * ( xsiremlab - xsirem ) & |
|---|
| 241 | & * znusil * e3t(ji,jj,jk,Kmm) / wsbio4(ji,jj,jk) ) |
|---|
| 242 | ENDIF |
|---|
| 243 | zsiremin = ( xsiremlab * zfacsi(ji,jj,jk) + xsirem * ( 1. - zfacsi(ji,jj,jk) ) ) * xstep * znusil |
|---|
| 244 | zosil = zsiremin * tr(ji,jj,jk,jpgsi,Kbb) |
|---|
| 245 | ! |
|---|
| 246 | tr(ji,jj,jk,jpgsi,Krhs) = tr(ji,jj,jk,jpgsi,Krhs) - zosil |
|---|
| 247 | tr(ji,jj,jk,jpsil,Krhs) = tr(ji,jj,jk,jpsil,Krhs) + zosil |
|---|
| 248 | END_3D |
|---|
| 249 | |
|---|
| 250 | IF(sn_cfctl%l_prttrc) THEN ! print mean trends (used for debugging) |
|---|
| 251 | WRITE(charout, FMT="('rem3')") |
|---|
| 252 | CALL prt_ctl_info( charout, cdcomp = 'top' ) |
|---|
| 253 | CALL prt_ctl(tab4d_1=CASTDP(tr(:,:,:,:,Krhs)), mask1=tmask, clinfo=ctrcnm) |
|---|
| 254 | ENDIF |
|---|
| 255 | |
|---|
| 256 | IF( knt == nrdttrc ) THEN |
|---|
| 257 | zrfact2 = 1.e+3 * rfact2r ! conversion from mol/l/kt to mol/m3/s |
|---|
| 258 | ! |
|---|
| 259 | IF( iom_use( "REMIN" ) ) THEN ! Remineralisation rate |
|---|
| 260 | zolimi(:,:,jpk) = 0. ; CALL iom_put( "REMIN" , zolimi(:,:,:) * tmask(:,:,:) * zrfact2 ) |
|---|
| 261 | ENDIF |
|---|
| 262 | CALL iom_put( "DENIT" , denitr(:,:,:) * rdenit * rno3 * tmask(:,:,:) * zrfact2 ) ! Denitrification |
|---|
| 263 | IF( iom_use( "BACT" ) ) THEN ! Bacterial biomass |
|---|
| 264 | zdepbac(:,:,jpk) = 0. ; CALL iom_put( "BACT", zdepbac(:,:,:) * 1.E6 * tmask(:,:,:) ) |
|---|
| 265 | ENDIF |
|---|
| 266 | CALL iom_put( "FEBACT" , zfebact(:,:,:) * 1E9 * tmask(:,:,:) * zrfact2 ) |
|---|
| 267 | ENDIF |
|---|
| 268 | ! |
|---|
| 269 | IF( ln_timing ) CALL timing_stop('p4z_rem') |
|---|
| 270 | ! |
|---|
| 271 | END SUBROUTINE p4z_rem |
|---|
| 272 | |
|---|
| 273 | |
|---|
| 274 | SUBROUTINE p4z_rem_init |
|---|
| 275 | !!---------------------------------------------------------------------- |
|---|
| 276 | !! *** ROUTINE p4z_rem_init *** |
|---|
| 277 | !! |
|---|
| 278 | !! ** Purpose : Initialization of remineralization parameters |
|---|
| 279 | !! |
|---|
| 280 | !! ** Method : Read the nampisrem namelist and check the parameters |
|---|
| 281 | !! called at the first timestep |
|---|
| 282 | !! |
|---|
| 283 | !! ** input : Namelist nampisrem |
|---|
| 284 | !! |
|---|
| 285 | !!---------------------------------------------------------------------- |
|---|
| 286 | NAMELIST/nampisrem/ xremik, nitrif, xsirem, xsiremlab, xsilab, feratb, xkferb, & |
|---|
| 287 | & xremikc, xremikn, xremikp |
|---|
| 288 | INTEGER :: ios ! Local integer output status for namelist read |
|---|
| 289 | !!---------------------------------------------------------------------- |
|---|
| 290 | ! |
|---|
| 291 | IF(lwp) THEN |
|---|
| 292 | WRITE(numout,*) |
|---|
| 293 | WRITE(numout,*) 'p4z_rem_init : Initialization of remineralization parameters' |
|---|
| 294 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 295 | ENDIF |
|---|
| 296 | ! |
|---|
| 297 | READ ( numnatp_ref, nampisrem, IOSTAT = ios, ERR = 901) |
|---|
| 298 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in reference namelist' ) |
|---|
| 299 | READ ( numnatp_cfg, nampisrem, IOSTAT = ios, ERR = 902 ) |
|---|
| 300 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'nampisrem in configuration namelist' ) |
|---|
| 301 | IF(lwm) WRITE( numonp, nampisrem ) |
|---|
| 302 | |
|---|
| 303 | IF(lwp) THEN ! control print |
|---|
| 304 | WRITE(numout,*) ' Namelist parameters for remineralization, nampisrem' |
|---|
| 305 | IF( ln_p4z ) THEN |
|---|
| 306 | WRITE(numout,*) ' remineralization rate of DOC xremik =', xremik |
|---|
| 307 | ELSE |
|---|
| 308 | WRITE(numout,*) ' remineralization rate of DOC xremikc =', xremikc |
|---|
| 309 | WRITE(numout,*) ' remineralization rate of DON xremikn =', xremikn |
|---|
| 310 | WRITE(numout,*) ' remineralization rate of DOP xremikp =', xremikp |
|---|
| 311 | ENDIF |
|---|
| 312 | WRITE(numout,*) ' remineralization rate of Si xsirem =', xsirem |
|---|
| 313 | WRITE(numout,*) ' fast remineralization rate of Si xsiremlab =', xsiremlab |
|---|
| 314 | WRITE(numout,*) ' fraction of labile biogenic silica xsilab =', xsilab |
|---|
| 315 | WRITE(numout,*) ' NH4 nitrification rate nitrif =', nitrif |
|---|
| 316 | WRITE(numout,*) ' Bacterial Fe/C ratio feratb =', feratb |
|---|
| 317 | WRITE(numout,*) ' Half-saturation constant for bact. Fe/C xkferb =', xkferb |
|---|
| 318 | ENDIF |
|---|
| 319 | ! |
|---|
| 320 | denitr(:,:,:) = 0._wp |
|---|
| 321 | ! |
|---|
| 322 | END SUBROUTINE p4z_rem_init |
|---|
| 323 | |
|---|
| 324 | |
|---|
| 325 | INTEGER FUNCTION p4z_rem_alloc() |
|---|
| 326 | !!---------------------------------------------------------------------- |
|---|
| 327 | !! *** ROUTINE p4z_rem_alloc *** |
|---|
| 328 | !!---------------------------------------------------------------------- |
|---|
| 329 | ALLOCATE( denitr(jpi,jpj,jpk), STAT=p4z_rem_alloc ) |
|---|
| 330 | ! |
|---|
| 331 | IF( p4z_rem_alloc /= 0 ) CALL ctl_stop( 'STOP', 'p4z_rem_alloc: failed to allocate arrays' ) |
|---|
| 332 | ! |
|---|
| 333 | END FUNCTION p4z_rem_alloc |
|---|
| 334 | |
|---|
| 335 | !!====================================================================== |
|---|
| 336 | END MODULE p4zrem |
|---|
