New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

dynhpg.F90 in NEMO/branches/2021/dev_r14273_HPC-02_Daley_Tiling/src/OCE/DYN – NEMO

Context Navigation

source: NEMO/branches/2021/dev_r14273_HPC-02_Daley_Tiling/src/OCE/DYN/dynhpg.F90 @ 14787

Last change on this file since 14787 was 14787, checked in by hadcv, 3 years ago
#2600: Clean up part 2- remove/modify comments & remove bug fixes to be committed separately
Property svn:keywords set to `Id`
File size: 76.2 KB

Line
1	MODULE dynhpg
2	!!======================================================================
3	!! * MODULE dynhpg *
4	!! Ocean dynamics: hydrostatic pressure gradient trend
5	!!======================================================================
6	!! History : OPA ! 1987-09 (P. Andrich, M.-A. Foujols) hpg_zco: Original code
7	!! 5.0 ! 1991-11 (G. Madec)
8	!! 7.0 ! 1996-01 (G. Madec) hpg_sco: Original code for s-coordinates
9	!! 8.0 ! 1997-05 (G. Madec) split dynber into dynkeg and dynhpg
10	!! 8.5 ! 2002-07 (G. Madec) F90: Free form and module
11	!! 8.5 ! 2002-08 (A. Bozec) hpg_zps: Original code
12	!! NEMO 1.0 ! 2005-10 (A. Beckmann, B.W. An) various s-coordinate options
13	!! ! Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14	!! - ! 2005-11 (G. Madec) style & small optimisation
15	!! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
16	!! 3.4 ! 2011-11 (H. Liu) hpg_prj: Original code for s-coordinates
17	!! ! (A. Coward) suppression of hel, wdj and rot options
18	!! 3.6 ! 2014-11 (P. Mathiot) hpg_isf: original code for ice shelf cavity
19	!! 4.2 ! 2020-12 (M. Bell, A. Young) hpg_djc: revised djc scheme
20	!!----------------------------------------------------------------------
21
22	!!----------------------------------------------------------------------
23	!! dyn_hpg : update the momentum trend with the now horizontal
24	!! gradient of the hydrostatic pressure
25	!! dyn_hpg_init : initialisation and control of options
26	!! hpg_zco : z-coordinate scheme
27	!! hpg_zps : z-coordinate plus partial steps (interpolation)
28	!! hpg_sco : s-coordinate (standard jacobian formulation)
29	!! hpg_isf : s-coordinate (sco formulation) adapted to ice shelf
30	!! hpg_djc : s-coordinate (Density Jacobian with Cubic polynomial)
31	!! hpg_prj : s-coordinate (Pressure Jacobian with Cubic polynomial)
32	!!----------------------------------------------------------------------
33	USE oce ! ocean dynamics and tracers
34	USE isf_oce , ONLY : risfload ! ice shelf (risfload variable)
35	USE isfload , ONLY : isf_load ! ice shelf (isf_load routine )
36	USE sbc_oce ! surface variable (only for the flag with ice shelf)
37	USE dom_oce ! ocean space and time domain
38	USE wet_dry ! wetting and drying
39	USE phycst ! physical constants
40	USE trd_oce ! trends: ocean variables
41	USE trddyn ! trend manager: dynamics
42	USE zpshde ! partial step: hor. derivative (zps_hde routine)
43	!
44	USE in_out_manager ! I/O manager
45	USE prtctl ! Print control
46	USE lbclnk ! lateral boundary condition
47	USE lib_mpp ! MPP library
48	USE eosbn2 ! compute density
49	USE timing ! Timing
50	USE iom
51
52	IMPLICIT NONE
53	PRIVATE
54
55	PUBLIC dyn_hpg ! routine called by step module
56	PUBLIC dyn_hpg_init ! routine called by opa module
57
58	! !!* Namelist namdyn_hpg : hydrostatic pressure gradient
59	LOGICAL, PUBLIC :: ln_hpg_zco !: z-coordinate - full steps
60	LOGICAL, PUBLIC :: ln_hpg_zps !: z-coordinate - partial steps (interpolation)
61	LOGICAL, PUBLIC :: ln_hpg_sco !: s-coordinate (standard jacobian formulation)
62	LOGICAL, PUBLIC :: ln_hpg_djc !: s-coordinate (Density Jacobian with Cubic polynomial)
63	LOGICAL, PUBLIC :: ln_hpg_prj !: s-coordinate (Pressure Jacobian scheme)
64	LOGICAL, PUBLIC :: ln_hpg_isf !: s-coordinate similar to sco modify for isf
65
66	! !! Flag to control the type of hydrostatic pressure gradient
67	INTEGER, PARAMETER :: np_ERROR =-10 ! error in specification of lateral diffusion
68	INTEGER, PARAMETER :: np_zco = 0 ! z-coordinate - full steps
69	INTEGER, PARAMETER :: np_zps = 1 ! z-coordinate - partial steps (interpolation)
70	INTEGER, PARAMETER :: np_sco = 2 ! s-coordinate (standard jacobian formulation)
71	INTEGER, PARAMETER :: np_djc = 3 ! s-coordinate (Density Jacobian with Cubic polynomial)
72	INTEGER, PARAMETER :: np_prj = 4 ! s-coordinate (Pressure Jacobian scheme)
73	INTEGER, PARAMETER :: np_isf = 5 ! s-coordinate similar to sco modify for isf
74	!
75	INTEGER, PUBLIC :: nhpg !: type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
76	!
77	LOGICAL :: ln_hpg_djc_vnh, ln_hpg_djc_vnv ! flag to specify hpg_djc boundary condition type
78	REAL(wp), PUBLIC :: aco_bc_hor, bco_bc_hor, aco_bc_vrt, bco_bc_vrt !: coefficients for hpg_djc hor and vert boundary conditions
79
80	!! * Substitutions
81	# include "do_loop_substitute.h90"
82	# include "domzgr_substitute.h90"
83
84	!!----------------------------------------------------------------------
85	!! NEMO/OCE 4.0 , NEMO Consortium (2018)
86	!! $Id$
87	!! Software governed by the CeCILL license (see ./LICENSE)
88	!!----------------------------------------------------------------------
89	CONTAINS
90
91	SUBROUTINE dyn_hpg( kt, Kmm, puu, pvv, Krhs )
92	!!---------------------------------------------------------------------
93	!! * ROUTINE dyn_hpg *
94	!!
95	!! ** Method : Call the hydrostatic pressure gradient routine
96	!! using the scheme defined in the namelist
97	!!
98	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
99	!! - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
100	!!----------------------------------------------------------------------
101	INTEGER , INTENT( in ) :: kt ! ocean time-step index
102	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
103	REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
104	!
105	REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: ztrdu, ztrdv
106	!!----------------------------------------------------------------------
107	!
108	IF( ln_timing ) CALL timing_start('dyn_hpg')
109	!
110	IF( l_trddyn ) THEN ! Temporary saving of puu(:,:,:,Krhs) and pvv(:,:,:,Krhs) trends (l_trddyn)
111	ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
112	ztrdu(:,:,:) = puu(:,:,:,Krhs)
113	ztrdv(:,:,:) = pvv(:,:,:,Krhs)
114	ENDIF
115	!
116	SELECT CASE ( nhpg ) ! Hydrostatic pressure gradient computation
117	CASE ( np_zco ) ; CALL hpg_zco ( kt, Kmm, puu, pvv, Krhs ) ! z-coordinate
118	CASE ( np_zps ) ; CALL hpg_zps ( kt, Kmm, puu, pvv, Krhs ) ! z-coordinate plus partial steps (interpolation)
119	CASE ( np_sco ) ; CALL hpg_sco ( kt, Kmm, puu, pvv, Krhs ) ! s-coordinate (standard jacobian formulation)
120	CASE ( np_djc )
121	! [ comm_cleanup ] : it should not be needed but the removal/shift of this lbc_lnk results in a seg_fault error
122	! TODO: [tiling] to check if still needed
123	!#if defined key_qco
124	! IF (nn_hls==2) CALL lbc_lnk( 'dynhpg', r3t(:,:,Kmm), 'T', 1.)
125	!#endif
126	CALL hpg_djc ( kt, Kmm, puu, pvv, Krhs ) ! s-coordinate (Density Jacobian with Cubic polynomial)
127	CASE ( np_prj ) ; CALL hpg_prj ( kt, Kmm, puu, pvv, Krhs ) ! s-coordinate (Pressure Jacobian scheme)
128	CASE ( np_isf ) ; CALL hpg_isf ( kt, Kmm, puu, pvv, Krhs ) ! s-coordinate similar to sco modify for ice shelf
129	END SELECT
130	!
131	IF( l_trddyn ) THEN ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
132	ztrdu(:,:,:) = puu(:,:,:,Krhs) - ztrdu(:,:,:)
133	ztrdv(:,:,:) = pvv(:,:,:,Krhs) - ztrdv(:,:,:)
134	CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt, Kmm )
135	DEALLOCATE( ztrdu , ztrdv )
136	ENDIF
137	!
138	IF(sn_cfctl%l_prtctl) CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' hpg - Ua: ', mask1=umask, &
139	& tab3d_2=pvv(:,:,:,Krhs), clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' )
140	!
141	IF( ln_timing ) CALL timing_stop('dyn_hpg')
142	!
143	END SUBROUTINE dyn_hpg
144
145
146	SUBROUTINE dyn_hpg_init( Kmm )
147	!!----------------------------------------------------------------------
148	!! * ROUTINE dyn_hpg_init *
149	!!
150	!! ** Purpose : initializations for the hydrostatic pressure gradient
151	!! computation and consistency control
152	!!
153	!! ** Action : Read the namelist namdyn_hpg and check the consistency
154	!! with the type of vertical coordinate used (zco, zps, sco)
155	!!----------------------------------------------------------------------
156	INTEGER, INTENT( in ) :: Kmm ! ocean time level index
157	!
158	INTEGER :: ioptio = 0 ! temporary integer
159	INTEGER :: ios ! Local integer output status for namelist read
160	!!
161	INTEGER :: ji, jj, jk, ikt ! dummy loop indices ISF
162	REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zts_top, zrhd ! hypothesys on isf density
163	REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: zrhdtop_isf ! density at bottom of ISF
164	REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: ziceload ! density at bottom of ISF
165	!!
166	NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco, &
167	& ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, &
168	& ln_hpg_djc_vnh, ln_hpg_djc_vnv
169	!!----------------------------------------------------------------------
170	!
171	READ ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
172	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist' )
173	!
174	READ ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
175	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist' )
176	IF(lwm) WRITE ( numond, namdyn_hpg )
177	!
178	IF(lwp) THEN ! Control print
179	WRITE(numout,*)
180	WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
181	WRITE(numout,*) '~~~~~~~~~~~~'
182	WRITE(numout,*) ' Namelist namdyn_hpg : choice of hpg scheme'
183	WRITE(numout,*) ' z-coord. - full steps ln_hpg_zco = ', ln_hpg_zco
184	WRITE(numout,*) ' z-coord. - partial steps (interpolation) ln_hpg_zps = ', ln_hpg_zps
185	WRITE(numout,*) ' s-coord. (standard jacobian formulation) ln_hpg_sco = ', ln_hpg_sco
186	WRITE(numout,*) ' s-coord. (standard jacobian formulation) for isf ln_hpg_isf = ', ln_hpg_isf
187	WRITE(numout,*) ' s-coord. (Density Jacobian: Cubic polynomial) ln_hpg_djc = ', ln_hpg_djc
188	WRITE(numout,*) ' s-coord. (Pressure Jacobian: Cubic polynomial) ln_hpg_prj = ', ln_hpg_prj
189	ENDIF
190	!
191	IF( .NOT.ln_linssh .AND. (ln_hpg_zco.OR.ln_hpg_zps) ) &
192	& CALL ctl_stop( 'dyn_hpg_init : non-linear free surface incompatible with hpg_zco or hpg_zps' )
193	!
194	IF( (.NOT.ln_hpg_isf .AND. ln_isfcav) .OR. (ln_hpg_isf .AND. .NOT.ln_isfcav) ) &
195	& CALL ctl_stop( 'dyn_hpg_init : ln_hpg_isf=T requires ln_isfcav=T and vice versa' )
196	!
197	#if defined key_qco
198	IF( ln_hpg_isf ) THEN
199	CALL ctl_stop( 'dyn_hpg_init : key_qco and ln_hpg_isf not yet compatible' )
200	ENDIF
201	#endif
202	!
203	! ! Set nhpg from ln_hpg_... flags & consistency check
204	nhpg = np_ERROR
205	ioptio = 0
206	IF( ln_hpg_zco ) THEN ; nhpg = np_zco ; ioptio = ioptio +1 ; ENDIF
207	IF( ln_hpg_zps ) THEN ; nhpg = np_zps ; ioptio = ioptio +1 ; ENDIF
208	IF( ln_hpg_sco ) THEN ; nhpg = np_sco ; ioptio = ioptio +1 ; ENDIF
209	IF( ln_hpg_djc ) THEN ; nhpg = np_djc ; ioptio = ioptio +1 ; ENDIF
210	IF( ln_hpg_prj ) THEN ; nhpg = np_prj ; ioptio = ioptio +1 ; ENDIF
211	IF( ln_hpg_isf ) THEN ; nhpg = np_isf ; ioptio = ioptio +1 ; ENDIF
212	!
213	IF( ioptio /= 1 ) CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
214	!
215	IF(lwp) THEN
216	WRITE(numout,*)
217	SELECT CASE( nhpg )
218	CASE( np_zco ) ; WRITE(numout,*) ' ==>>> z-coord. - full steps '
219	CASE( np_zps ) ; WRITE(numout,*) ' ==>>> z-coord. - partial steps (interpolation)'
220	CASE( np_sco ) ; WRITE(numout,*) ' ==>>> s-coord. (standard jacobian formulation)'
221	CASE( np_djc ) ; WRITE(numout,*) ' ==>>> s-coord. (Density Jacobian: Cubic polynomial)'
222	CASE( np_prj ) ; WRITE(numout,*) ' ==>>> s-coord. (Pressure Jacobian: Cubic polynomial)'
223	CASE( np_isf ) ; WRITE(numout,*) ' ==>>> s-coord. (standard jacobian formulation) for isf'
224	END SELECT
225	WRITE(numout,*)
226	ENDIF
227	!
228	IF ( ln_hpg_djc ) THEN
229	IF (ln_hpg_djc_vnh) THEN ! Von Neumann boundary condition
230	IF(lwp) WRITE(numout,*) ' horizontal bc: von Neumann '
231	aco_bc_hor = 6.0_wp/5.0_wp
232	bco_bc_hor = 7.0_wp/15.0_wp
233	ELSE ! Linear extrapolation
234	IF(lwp) WRITE(numout,*) ' horizontal bc: linear extrapolation'
235	aco_bc_hor = 3.0_wp/2.0_wp
236	bco_bc_hor = 1.0_wp/2.0_wp
237	END IF
238	IF (ln_hpg_djc_vnv) THEN ! Von Neumann boundary condition
239	IF(lwp) WRITE(numout,*) ' vertical bc: von Neumann '
240	aco_bc_vrt = 6.0_wp/5.0_wp
241	bco_bc_vrt = 7.0_wp/15.0_wp
242	ELSE ! Linear extrapolation
243	IF(lwp) WRITE(numout,*) ' vertical bc: linear extrapolation'
244	aco_bc_vrt = 3.0_wp/2.0_wp
245	bco_bc_vrt = 1.0_wp/2.0_wp
246	END IF
247	END IF
248	!
249	END SUBROUTINE dyn_hpg_init
250
251
252	SUBROUTINE hpg_zco( kt, Kmm, puu, pvv, Krhs )
253	!!---------------------------------------------------------------------
254	!! * ROUTINE hpg_zco *
255	!!
256	!! ** Method : z-coordinate case, levels are horizontal surfaces.
257	!! The now hydrostatic pressure gradient at a given level, jk,
258	!! is computed by taking the vertical integral of the in-situ
259	!! density gradient along the model level from the suface to that
260	!! level: zhpi = grav .....
261	!! zhpj = grav .....
262	!! add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
263	!! puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
264	!! pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
265	!!
266	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
267	!!----------------------------------------------------------------------
268	INTEGER , INTENT( in ) :: kt ! ocean time-step index
269	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
270	REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
271	!
272	INTEGER :: ji, jj, jk ! dummy loop indices
273	REAL(wp) :: zcoef0, zcoef1 ! temporary scalars
274	REAL(wp), DIMENSION(A2D(nn_hls)) :: zhpi, zhpj
275	!!----------------------------------------------------------------------
276	!
277	IF( .NOT. l_istiled .OR. ntile == 1 ) THEN ! Do only on the first tile
278	IF( kt == nit000 ) THEN
279	IF(lwp) WRITE(numout,*)
280	IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
281	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate case '
282	ENDIF
283	ENDIF
284	!
285	zcoef0 = - grav * 0.5_wp ! Local constant initialization
286	!
287	DO_2D( 0, 0, 0, 0 ) ! Surface value
288	zcoef1 = zcoef0 * e3w(ji,jj,1,Kmm)
289	! ! hydrostatic pressure gradient
290	zhpi(ji,jj) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
291	zhpj(ji,jj) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
292	! ! add to the general momentum trend
293	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj)
294	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj)
295	END_2D
296	!
297	DO_3D( 0, 0, 0, 0, 2, jpkm1 ) ! interior value (2=<jk=<jpkm1)
298	zcoef1 = zcoef0 * e3w(ji,jj,jk,Kmm)
299	! ! hydrostatic pressure gradient
300	zhpi(ji,jj) = zhpi(ji,jj) + zcoef1 * ( ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) ) &
301	& - ( rhd(ji ,jj,jk)+rhd(ji ,jj,jk-1) ) ) * r1_e1u(ji,jj)
302
303	zhpj(ji,jj) = zhpj(ji,jj) + zcoef1 * ( ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) ) &
304	& - ( rhd(ji,jj, jk)+rhd(ji,jj ,jk-1) ) ) * r1_e2v(ji,jj)
305	! ! add to the general momentum trend
306	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj)
307	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj)
308	END_3D
309	!
310	END SUBROUTINE hpg_zco
311
312
313	SUBROUTINE hpg_zps( kt, Kmm, puu, pvv, Krhs )
314	!!---------------------------------------------------------------------
315	!! * ROUTINE hpg_zps *
316	!!
317	!! ** Method : z-coordinate plus partial steps case. blahblah...
318	!!
319	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
320	!!----------------------------------------------------------------------
321	INTEGER , INTENT( in ) :: kt ! ocean time-step index
322	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
323	REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
324	!!
325	INTEGER :: ji, jj, jk ! dummy loop indices
326	INTEGER :: iku, ikv ! temporary integers
327	REAL(wp) :: zcoef0, zcoef1, zcoef2, zcoef3 ! temporary scalars
328	REAL(wp), DIMENSION(A2D(nn_hls),jpk ) :: zhpi, zhpj
329	REAL(wp), DIMENSION(A2D(nn_hls),jpts) :: zgtsu, zgtsv
330	REAL(wp), DIMENSION(A2D(nn_hls) ) :: zgru, zgrv
331	!!----------------------------------------------------------------------
332	!
333	IF( .NOT. l_istiled .OR. ntile == 1 ) THEN ! Do only on the first tile
334	IF( kt == nit000 ) THEN
335	IF(lwp) WRITE(numout,*)
336	IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
337	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate with partial steps - vector optimization'
338	ENDIF
339	ENDIF
340
341	! Partial steps: Compute NOW horizontal gradient of t, s, rd at the last ocean level
342	CALL zps_hde( kt, Kmm, jpts, ts(:,:,:,:,Kmm), zgtsu, zgtsv, rhd, zgru , zgrv )
343
344	! Local constant initialization
345	zcoef0 = - grav * 0.5_wp
346
347	! Surface value (also valid in partial step case)
348	DO_2D( 0, 0, 0, 0 )
349	zcoef1 = zcoef0 * e3w(ji,jj,1,Kmm)
350	! hydrostatic pressure gradient
351	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
352	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
353	! add to the general momentum trend
354	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
355	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
356	END_2D
357
358	! interior value (2=<jk=<jpkm1)
359	DO_3D( 0, 0, 0, 0, 2, jpkm1 )
360	zcoef1 = zcoef0 * e3w(ji,jj,jk,Kmm)
361	! hydrostatic pressure gradient
362	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
363	& + zcoef1 * ( ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) &
364	& - ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) ) ) * r1_e1u(ji,jj)
365
366	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
367	& + zcoef1 * ( ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) &
368	& - ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) ) ) * r1_e2v(ji,jj)
369	! add to the general momentum trend
370	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
371	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
372	END_3D
373
374	! partial steps correction at the last level (use zgru & zgrv computed in zpshde.F90)
375	DO_2D( 0, 0, 0, 0 )
376	iku = mbku(ji,jj)
377	ikv = mbkv(ji,jj)
378	zcoef2 = zcoef0 * MIN( e3w(ji,jj,iku,Kmm), e3w(ji+1,jj ,iku,Kmm) )
379	zcoef3 = zcoef0 * MIN( e3w(ji,jj,ikv,Kmm), e3w(ji ,jj+1,ikv,Kmm) )
380	IF( iku > 1 ) THEN ! on i-direction (level 2 or more)
381	puu (ji,jj,iku,Krhs) = puu(ji,jj,iku,Krhs) - zhpi(ji,jj,iku) ! subtract old value
382	zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1) & ! compute the new one
383	& + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + zgru(ji,jj) ) * r1_e1u(ji,jj)
384	puu (ji,jj,iku,Krhs) = puu(ji,jj,iku,Krhs) + zhpi(ji,jj,iku) ! add the new one to the general momentum trend
385	ENDIF
386	IF( ikv > 1 ) THEN ! on j-direction (level 2 or more)
387	pvv (ji,jj,ikv,Krhs) = pvv(ji,jj,ikv,Krhs) - zhpj(ji,jj,ikv) ! subtract old value
388	zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1) & ! compute the new one
389	& + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + zgrv(ji,jj) ) * r1_e2v(ji,jj)
390	pvv (ji,jj,ikv,Krhs) = pvv(ji,jj,ikv,Krhs) + zhpj(ji,jj,ikv) ! add the new one to the general momentum trend
391	ENDIF
392	END_2D
393	!
394	END SUBROUTINE hpg_zps
395
396
397	SUBROUTINE hpg_sco( kt, Kmm, puu, pvv, Krhs )
398	!!---------------------------------------------------------------------
399	!! * ROUTINE hpg_sco *
400	!!
401	!! ** Method : s-coordinate case. Jacobian scheme.
402	!! The now hydrostatic pressure gradient at a given level, jk,
403	!! is computed by taking the vertical integral of the in-situ
404	!! density gradient along the model level from the suface to that
405	!! level. s-coordinates (ln_sco): a corrective term is added
406	!! to the horizontal pressure gradient :
407	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
408	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
409	!! add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
410	!! puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
411	!! pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
412	!!
413	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
414	!!----------------------------------------------------------------------
415	INTEGER , INTENT( in ) :: kt ! ocean time-step index
416	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
417	REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
418	!!
419	INTEGER :: ji, jj, jk, jii, jjj ! dummy loop indices
420	REAL(wp) :: zcoef0, zuap, zvap, ztmp ! local scalars
421	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
422	REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zhpi, zhpj
423	REAL(wp), DIMENSION(:,:), ALLOCATABLE :: zcpx, zcpy !W/D pressure filter
424	!!----------------------------------------------------------------------
425	!
426	IF( ln_wd_il ) ALLOCATE(zcpx(A2D(nn_hls)), zcpy(A2D(nn_hls)))
427	!
428	IF( .NOT. l_istiled .OR. ntile == 1 ) THEN ! Do only on the first tile
429	IF( kt == nit000 ) THEN
430	IF(lwp) WRITE(numout,*)
431	IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
432	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, OCE original scheme used'
433	ENDIF
434	ENDIF
435	!
436	zcoef0 = - grav * 0.5_wp
437	!
438	IF( ln_wd_il ) THEN
439	DO_2D( 0, 0, 0, 0 )
440	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
441	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) .AND. &
442	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) ) &
443	& > rn_wdmin1 + rn_wdmin2
444	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. ( &
445	& MAX( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
446	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
447
448	IF(ll_tmp1) THEN
449	zcpx(ji,jj) = 1.0_wp
450	ELSE IF(ll_tmp2) THEN
451	! no worries about ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm) = 0, it won't happen ! here
452	zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
453	& / (ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm)) )
454	ELSE
455	zcpx(ji,jj) = 0._wp
456	END IF
457
458	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
459	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) .AND. &
460	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) ) &
461	& > rn_wdmin1 + rn_wdmin2
462	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. ( &
463	& MAX( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
464	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
465
466	IF(ll_tmp1) THEN
467	zcpy(ji,jj) = 1.0_wp
468	ELSE IF(ll_tmp2) THEN
469	! no worries about ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm) = 0, it won't happen ! here
470	zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
471	& / (ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm)) )
472	ELSE
473	zcpy(ji,jj) = 0._wp
474	END IF
475	END_2D
476	END IF
477	!
478	DO_2D( 0, 0, 0, 0 ) ! Surface value
479	! ! hydrostatic pressure gradient along s-surfaces
480	zhpi(ji,jj,1) = zcoef0 * r1_e1u(ji,jj) &
481	& * ( e3w(ji+1,jj ,1,Kmm) * rhd(ji+1,jj ,1) &
482	& - e3w(ji ,jj ,1,Kmm) * rhd(ji ,jj ,1) )
483	zhpj(ji,jj,1) = zcoef0 * r1_e2v(ji,jj) &
484	& * ( e3w(ji ,jj+1,1,Kmm) * rhd(ji ,jj+1,1) &
485	& - e3w(ji ,jj ,1,Kmm) * rhd(ji ,jj ,1) )
486	! ! s-coordinate pressure gradient correction
487	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) ) &
488	& * ( gde3w(ji+1,jj,1) - gde3w(ji,jj,1) ) * r1_e1u(ji,jj)
489	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) ) &
490	& * ( gde3w(ji,jj+1,1) - gde3w(ji,jj,1) ) * r1_e2v(ji,jj)
491	!
492	IF( ln_wd_il ) THEN
493	zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
494	zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj)
495	zuap = zuap * zcpx(ji,jj)
496	zvap = zvap * zcpy(ji,jj)
497	ENDIF
498	! ! add to the general momentum trend
499	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1) + zuap
500	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1) + zvap
501	END_2D
502	!
503	DO_3D( 0, 0, 0, 0, 2, jpkm1 ) ! interior value (2=<jk=<jpkm1)
504	! ! hydrostatic pressure gradient along s-surfaces
505	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj) &
506	& * ( e3w(ji+1,jj,jk,Kmm) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) &
507	& - e3w(ji ,jj,jk,Kmm) * ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) ) )
508	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj) &
509	& * ( e3w(ji,jj+1,jk,Kmm) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) &
510	& - e3w(ji,jj ,jk,Kmm) * ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) ) )
511	! ! s-coordinate pressure gradient correction
512	zuap = -zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) ) &
513	& * ( gde3w(ji+1,jj ,jk) - gde3w(ji,jj,jk) ) * r1_e1u(ji,jj)
514	zvap = -zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) ) &
515	& * ( gde3w(ji ,jj+1,jk) - gde3w(ji,jj,jk) ) * r1_e2v(ji,jj)
516	!
517	IF( ln_wd_il ) THEN
518	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
519	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj)
520	zuap = zuap * zcpx(ji,jj)
521	zvap = zvap * zcpy(ji,jj)
522	ENDIF
523	!
524	! add to the general momentum trend
525	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk) + zuap
526	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk) + zvap
527	END_3D
528	!
529	IF( ln_wd_il ) DEALLOCATE( zcpx , zcpy )
530	!
531	END SUBROUTINE hpg_sco
532
533
534	SUBROUTINE hpg_isf( kt, Kmm, puu, pvv, Krhs )
535	!!---------------------------------------------------------------------
536	!! * ROUTINE hpg_isf *
537	!!
538	!! ** Method : s-coordinate case. Jacobian scheme.
539	!! The now hydrostatic pressure gradient at a given level, jk,
540	!! is computed by taking the vertical integral of the in-situ
541	!! density gradient along the model level from the suface to that
542	!! level. s-coordinates (ln_sco): a corrective term is added
543	!! to the horizontal pressure gradient :
544	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
545	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
546	!! add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
547	!! puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
548	!! pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
549	!! iceload is added
550	!!
551	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
552	!!----------------------------------------------------------------------
553	INTEGER , INTENT( in ) :: kt ! ocean time-step index
554	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
555	REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
556	!!
557	INTEGER :: ji, jj, jk ! dummy loop indices
558	INTEGER :: ikt , ikti1, iktj1 ! local integer
559	REAL(wp) :: ze3w, ze3wi1, ze3wj1 ! local scalars
560	REAL(wp) :: zcoef0, zuap, zvap ! - -
561	REAL(wp), DIMENSION(A2D(nn_hls),jpk ) :: zhpi, zhpj
562	REAL(wp), DIMENSION(A2D(nn_hls),jpts) :: zts_top
563	REAL(wp), DIMENSION(A2D(nn_hls)) :: zrhdtop_oce
564	!!----------------------------------------------------------------------
565	!
566	zcoef0 = - grav * 0.5_wp ! Local constant initialization
567	!
568	! ! iniitialised to 0. zhpi zhpi
569	zhpi(:,:,:) = 0._wp ; zhpj(:,:,:) = 0._wp
570
571	! compute rhd at the ice/oce interface (ocean side)
572	! usefull to reduce residual current in the test case ISOMIP with no melting
573	DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
574	ikt = mikt(ji,jj)
575	zts_top(ji,jj,1) = ts(ji,jj,ikt,1,Kmm)
576	zts_top(ji,jj,2) = ts(ji,jj,ikt,2,Kmm)
577	END_2D
578	CALL eos( zts_top, risfdep, zrhdtop_oce )
579
580	! !===========================!
581	! !===== surface value =====!
582	! !===========================!
583	DO_2D( 0, 0, 0, 0 )
584	ikt = mikt(ji ,jj ) ; ze3w = e3w(ji ,jj ,ikt ,Kmm)
585	ikti1 = mikt(ji+1,jj ) ; ze3wi1 = e3w(ji+1,jj ,ikti1,Kmm)
586	iktj1 = mikt(ji ,jj+1) ; ze3wj1 = e3w(ji ,jj+1,iktj1,Kmm)
587	! ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
588	! ! we assume ISF is in isostatic equilibrium
589	zhpi(ji,jj,1) = zcoef0 * r1_e1u(ji,jj) * ( risfload(ji+1,jj) - risfload(ji,jj) &
590	& + 0.5_wp * ( ze3wi1 * ( rhd(ji+1,jj,ikti1) + zrhdtop_oce(ji+1,jj) ) &
591	& - ze3w * ( rhd(ji ,jj,ikt ) + zrhdtop_oce(ji ,jj) ) ) )
592	zhpj(ji,jj,1) = zcoef0 * r1_e2v(ji,jj) * ( risfload(ji,jj+1) - risfload(ji,jj) &
593	& + 0.5_wp * ( ze3wj1 * ( rhd(ji,jj+1,iktj1) + zrhdtop_oce(ji,jj+1) ) &
594	& - ze3w * ( rhd(ji,jj ,ikt ) + zrhdtop_oce(ji,jj ) ) ) )
595	! ! s-coordinate pressure gradient correction (=0 if z coordinate)
596	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) ) &
597	& * ( gde3w(ji+1,jj,1) - gde3w(ji,jj,1) ) * r1_e1u(ji,jj)
598	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) ) &
599	& * ( gde3w(ji,jj+1,1) - gde3w(ji,jj,1) ) * r1_e2v(ji,jj)
600	! ! add to the general momentum trend
601	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
602	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
603	END_2D
604	!
605	! !=============================!
606	! !===== interior values =====!
607	! !=============================!
608	DO_3D( 0, 0, 0, 0, 2, jpkm1 )
609	ze3w = e3w(ji ,jj ,jk,Kmm)
610	ze3wi1 = e3w(ji+1,jj ,jk,Kmm)
611	ze3wj1 = e3w(ji ,jj+1,jk,Kmm)
612	! ! hydrostatic pressure gradient along s-surfaces
613	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj) &
614	& * ( ze3wi1 * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) * wmask(ji+1,jj,jk) &
615	& - ze3w * ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) ) * wmask(ji ,jj,jk) )
616	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj) &
617	& * ( ze3wj1 * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) * wmask(ji,jj+1,jk) &
618	& - ze3w * ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) ) * wmask(ji,jj ,jk) )
619	! ! s-coordinate pressure gradient correction
620	zuap = -zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) ) &
621	& * ( gde3w(ji+1,jj ,jk) - gde3w(ji,jj,jk) ) / e1u(ji,jj)
622	zvap = -zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) ) &
623	& * ( gde3w(ji ,jj+1,jk) - gde3w(ji,jj,jk) ) / e2v(ji,jj)
624	! ! add to the general momentum trend
625	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
626	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
627	END_3D
628	!
629	END SUBROUTINE hpg_isf
630
631
632	SUBROUTINE hpg_djc( kt, Kmm, puu, pvv, Krhs )
633	!!---------------------------------------------------------------------
634	!! * ROUTINE hpg_djc *
635	!!
636	!! ** Method : Density Jacobian with Cubic polynomial scheme
637	!!
638	!! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
639	!!----------------------------------------------------------------------
640	INTEGER , INTENT( in ) :: kt ! ocean time-step index
641	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
642	REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
643	!!
644	INTEGER :: ji, jj, jk ! dummy loop indices
645	INTEGER :: iktb, iktt ! jk indices at tracer points for top and bottom points
646	REAL(wp) :: zcoef0, zep, cffw ! temporary scalars
647	REAL(wp) :: z_grav_10, z1_12, z1_cff
648	REAL(wp) :: cffu, cffx ! " "
649	REAL(wp) :: cffv, cffy ! " "
650	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
651	REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zhpi, zhpj
652
653	REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zdzx, zdzy, zdzz ! Primitive grid differences ('delta_xyz')
654	REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zdz_i, zdz_j, zdz_k ! Harmonic average of primitive grid differences ('d_xyz')
655	REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zdrhox, zdrhoy, zdrhoz ! Primitive rho differences ('delta_rho')
656	REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zdrho_i, zdrho_j, zdrho_k ! Harmonic average of primitive rho differences ('d_rho')
657	REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: z_rho_i, z_rho_j, z_rho_k ! Face intergrals
658	REAL(wp), DIMENSION(A2D(nn_hls)) :: zz_dz_i, zz_dz_j, zz_drho_i, zz_drho_j ! temporary arrays
659	REAL(wp), DIMENSION(:,:), ALLOCATABLE :: zcpx, zcpy !W/D pressure filter
660	!!----------------------------------------------------------------------
661	!
662	IF( ln_wd_il ) THEN
663	ALLOCATE( zcpx(A2D(nn_hls)) , zcpy(A2D(nn_hls)) )
664	DO_2D( 0, 0, 0, 0 )
665	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
666	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) .AND. &
667	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) ) &
668	& > rn_wdmin1 + rn_wdmin2
669	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. ( &
670	& MAX( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
671	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
672	IF(ll_tmp1) THEN
673	zcpx(ji,jj) = 1.0_wp
674	ELSE IF(ll_tmp2) THEN
675	! no worries about ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm) = 0, it won't happen ! here
676	zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
677	& / (ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm)) )
678	ELSE
679	zcpx(ji,jj) = 0._wp
680	END IF
681
682	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
683	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) .AND. &
684	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) ) &
685	& > rn_wdmin1 + rn_wdmin2
686	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. ( &
687	& MAX( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
688	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
689
690	IF(ll_tmp1) THEN
691	zcpy(ji,jj) = 1.0_wp
692	ELSE IF(ll_tmp2) THEN
693	! no worries about ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm) = 0, it won't happen ! here
694	zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
695	& / (ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm)) )
696	ELSE
697	zcpy(ji,jj) = 0._wp
698	END IF
699	END_2D
700	END IF
701
702	IF( .NOT. l_istiled .OR. ntile == 1 ) THEN ! Do only on the first tile
703	IF( kt == nit000 ) THEN
704	IF(lwp) WRITE(numout,*)
705	IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
706	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, density Jacobian with cubic polynomial scheme'
707	ENDIF
708	ENDIF
709
710	! Local constant initialization
711	zcoef0 = - grav * 0.5_wp
712	z_grav_10 = grav / 10._wp
713	z1_12 = 1.0_wp / 12._wp
714
715	!----------------------------------------------------------------------------------------
716	! 1. compute and store elementary vertical differences in provisional arrays
717	!----------------------------------------------------------------------------------------
718
719	!!bug gm Not a true bug, but... zdzz=e3w for zdzx, zdzy verify what it is really
720
721	DO_3D( 1, 1, 1, 1, 2, jpkm1 )
722	zdrhoz(ji,jj,jk) = rhd (ji ,jj ,jk) - rhd (ji,jj,jk-1)
723	zdzz (ji,jj,jk) = - gde3w(ji ,jj ,jk) + gde3w(ji,jj,jk-1)
724	END_3D
725
726	!-------------------------------------------------------------------------
727	! 2. compute harmonic averages for vertical differences using eq. 5.18
728	!-------------------------------------------------------------------------
729	zep = 1.e-15
730
731	!! mb zdrho_k, zdz_k, zdrho_i, zdz_i, zdrho_j, zdz_j re-centred about the point (ji,jj,jk)
732	zdrho_k(:,:,:) = 0._wp
733	zdz_k (:,:,:) = 0._wp
734
735	DO_3D( 1, 1, 1, 1, 2, jpk-2 )
736	cffw = MAX( 2._wp * zdrhoz(ji,jj,jk) * zdrhoz(ji,jj,jk+1), 0._wp )
737	z1_cff = zdrhoz(ji,jj,jk) + zdrhoz(ji,jj,jk+1)
738	zdrho_k(ji,jj,jk) = cffw / SIGN( MAX( ABS(z1_cff), zep ), z1_cff )
739	zdz_k(ji,jj,jk) = 2._wp * zdzz(ji,jj,jk) * zdzz(ji,jj,jk+1) &
740	& / ( zdzz(ji,jj,jk) + zdzz(ji,jj,jk+1) )
741	END_3D
742
743	!----------------------------------------------------------------------------------
744	! 3. apply boundary conditions at top and bottom using 5.36-5.37
745	!----------------------------------------------------------------------------------
746
747	! mb for sea-ice shelves we will need to re-write this upper boundary condition in the same form as the lower boundary condition
748	DO_2D( 1, 1, 1, 1 )
749	zdrho_k(ji,jj,1) = aco_bc_vrt * ( rhd (ji,jj,2) - rhd (ji,jj,1) ) - bco_bc_vrt * zdrho_k(ji,jj,2)
750	zdz_k (ji,jj,1) = aco_bc_vrt * (-gde3w(ji,jj,2) + gde3w(ji,jj,1) ) - bco_bc_vrt * zdz_k (ji,jj,2)
751	END_2D
752
753	DO_2D( 1, 1, 1, 1 )
754	IF ( mbkt(ji,jj)>1 ) THEN
755	iktb = mbkt(ji,jj)
756	zdrho_k(ji,jj,iktb) = aco_bc_vrt * ( rhd(ji,jj,iktb) - rhd(ji,jj,iktb-1) ) - bco_bc_vrt * zdrho_k(ji,jj,iktb-1)
757	zdz_k (ji,jj,iktb) = aco_bc_vrt * (-gde3w(ji,jj,iktb) + gde3w(ji,jj,iktb-1) ) - bco_bc_vrt * zdz_k (ji,jj,iktb-1)
758	END IF
759	END_2D
760
761	!--------------------------------------------------------------
762	! 4. Compute side face integrals
763	!-------------------------------------------------------------
764
765	!! ssh replaces e3w_n ; gde3w is a depth; the formulae involve heights
766	!! rho_k stores grav * FX / rho_0
767
768	!--------------------------------------------------------------
769	! 4. a) Upper half of top-most grid box, compute and store
770	!-------------------------------------------------------------
771	! *** AY note: ssh(ji,jj,Kmm) + gde3w(ji,jj,1) = e3w(ji,jj,1,Kmm)
772	DO_2D( 0, 1, 0, 1)
773	z_rho_k(ji,jj,1) = grav * ( ssh(ji,jj,Kmm) + gde3w(ji,jj,1) ) &
774	& * ( rhd(ji,jj,1) &
775	& + 0.5_wp * ( rhd (ji,jj,2) - rhd (ji,jj,1) ) &
776	& * ( ssh (ji,jj,Kmm) + gde3w(ji,jj,1) ) &
777	& / ( - gde3w(ji,jj,2) + gde3w(ji,jj,1) ) )
778	END_2D
779
780	!--------------------------------------------------------------
781	! 4. b) Interior faces, compute and store
782	!-------------------------------------------------------------
783
784	DO_3D( 0, 1, 0, 1, 2, jpkm1 )
785	z_rho_k(ji,jj,jk) = zcoef0 * ( rhd (ji,jj,jk) + rhd (ji,jj,jk-1) ) &
786	& * ( - gde3w(ji,jj,jk) + gde3w(ji,jj,jk-1) ) &
787	& + z_grav_10 * ( &
788	& ( zdrho_k (ji,jj,jk) - zdrho_k (ji,jj,jk-1) ) &
789	& * ( - gde3w(ji,jj,jk) + gde3w(ji,jj,jk-1) - z1_12 * ( zdz_k (ji,jj,jk) + zdz_k (ji,jj,jk-1) ) ) &
790	& - ( zdz_k (ji,jj,jk) - zdz_k (ji,jj,jk-1) ) &
791	& * ( rhd (ji,jj,jk) - rhd (ji,jj,jk-1) - z1_12 * ( zdrho_k(ji,jj,jk) + zdrho_k(ji,jj,jk-1) ) ) &
792	& )
793	END_3D
794
795	!----------------------------------------------------------------------------------------
796	! 5. compute and store elementary horizontal differences in provisional arrays
797	!----------------------------------------------------------------------------------------
798	zdrhox(:,:,:) = 0._wp
799	zdzx (:,:,:) = 0._wp
800	zdrhoy(:,:,:) = 0._wp
801	zdzy (:,:,:) = 0._wp
802
803	DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )
804	zdrhox(ji,jj,jk) = rhd (ji+1,jj ,jk) - rhd (ji ,jj ,jk)
805	zdzx (ji,jj,jk) = gde3w(ji ,jj ,jk) - gde3w(ji+1,jj ,jk)
806	zdrhoy(ji,jj,jk) = rhd (ji ,jj+1,jk) - rhd (ji ,jj ,jk)
807	zdzy (ji,jj,jk) = gde3w(ji ,jj ,jk) - gde3w(ji ,jj+1,jk)
808	END_3D
809
810	IF( nn_hls == 1 ) CALL lbc_lnk( 'dynhpg', zdrhox, 'U', -1._wp, zdzx, 'U', -1._wp, zdrhoy, 'V', -1._wp, zdzy, 'V', -1._wp )
811
812	!-------------------------------------------------------------------------
813	! 6. compute harmonic averages using eq. 5.18
814	!-------------------------------------------------------------------------
815
816	DO_3D( 0, 1, 0, 1, 1, jpkm1 )
817	cffu = MAX( 2._wp * zdrhox(ji-1,jj,jk) * zdrhox(ji,jj,jk), 0._wp )
818	z1_cff = zdrhox(ji-1,jj,jk) + zdrhox(ji,jj,jk)
819	zdrho_i(ji,jj,jk) = cffu / SIGN( MAX( ABS(z1_cff), zep ), z1_cff )
820
821	cffx = MAX( 2._wp * zdzx(ji-1,jj,jk) * zdzx(ji,jj,jk), 0._wp )
822	z1_cff = zdzx(ji-1,jj,jk) + zdzx(ji,jj,jk)
823	zdz_i(ji,jj,jk) = cffx / SIGN( MAX( ABS(z1_cff), zep ), z1_cff )
824
825	cffv = MAX( 2._wp * zdrhoy(ji,jj-1,jk) * zdrhoy(ji,jj,jk), 0._wp )
826	z1_cff = zdrhoy(ji,jj-1,jk) + zdrhoy(ji,jj,jk)
827	zdrho_j(ji,jj,jk) = cffv / SIGN( MAX( ABS(z1_cff), zep ), z1_cff )
828
829	cffy = MAX( 2._wp * zdzy(ji,jj-1,jk) * zdzy(ji,jj,jk), 0._wp )
830	z1_cff = zdzy(ji,jj-1,jk) + zdzy(ji,jj,jk)
831	zdz_j(ji,jj,jk) = cffy / SIGN( MAX( ABS(z1_cff), zep ), z1_cff )
832	END_3D
833
834	!!! Note that zdzx, zdzy, zdzz, zdrhox, zdrhoy and zdrhoz should NOT be used beyond this point
835
836	!----------------------------------------------------------------------------------
837	! 6B. apply boundary conditions at side boundaries using 5.36-5.37
838	!----------------------------------------------------------------------------------
839
840	DO jk = 1, jpkm1
841	zz_drho_i(:,:) = zdrho_i(:,:,jk)
842	zz_dz_i (:,:) = zdz_i (:,:,jk)
843	zz_drho_j(:,:) = zdrho_j(:,:,jk)
844	zz_dz_j (:,:) = zdz_j (:,:,jk)
845	! Walls coming from left: should check from 2 to jpi-1 (and jpj=2-jpj)
846	DO_2D( 0, 0, 0, 1 )
847	IF ( umask(ji,jj,jk) > 0.5_wp .AND. umask(ji-1,jj,jk) < 0.5_wp .AND. umask(ji+1,jj,jk) > 0.5_wp) THEN
848	zz_drho_i(ji,jj) = aco_bc_hor * ( rhd (ji+1,jj,jk) - rhd (ji,jj,jk) ) - bco_bc_hor * zdrho_i(ji+1,jj,jk)
849	zz_dz_i (ji,jj) = aco_bc_hor * (-gde3w(ji+1,jj,jk) + gde3w(ji,jj,jk) ) - bco_bc_hor * zdz_i (ji+1,jj,jk)
850	END IF
851	END_2D
852	! Walls coming from right: should check from 3 to jpi (and jpj=2-jpj)
853	DO_2D( -1, 1, 0, 1 )
854	IF ( umask(ji,jj,jk) < 0.5_wp .AND. umask(ji-1,jj,jk) > 0.5_wp .AND. umask(ji-2,jj,jk) > 0.5_wp) THEN
855	zz_drho_i(ji,jj) = aco_bc_hor * ( rhd (ji,jj,jk) - rhd (ji-1,jj,jk) ) - bco_bc_hor * zdrho_i(ji-1,jj,jk)
856	zz_dz_i (ji,jj) = aco_bc_hor * (-gde3w(ji,jj,jk) + gde3w(ji-1,jj,jk) ) - bco_bc_hor * zdz_i (ji-1,jj,jk)
857	END IF
858	END_2D
859	! Walls coming from left: should check from 2 to jpj-1 (and jpi=2-jpi)
860	DO_2D( 0, 1, 0, 0 )
861	IF ( vmask(ji,jj,jk) > 0.5_wp .AND. vmask(ji,jj-1,jk) < 0.5_wp .AND. vmask(ji,jj+1,jk) > 0.5_wp) THEN
862	zz_drho_j(ji,jj) = aco_bc_hor * ( rhd (ji,jj+1,jk) - rhd (ji,jj,jk) ) - bco_bc_hor * zdrho_j(ji,jj+1,jk)
863	zz_dz_j (ji,jj) = aco_bc_hor * (-gde3w(ji,jj+1,jk) + gde3w(ji,jj,jk) ) - bco_bc_hor * zdz_j (ji,jj+1,jk)
864	END IF
865	END_2D
866	! Walls coming from right: should check from 3 to jpj (and jpi=2-jpi)
867	DO_2D( 0, 1, -1, 1 )
868	IF ( vmask(ji,jj,jk) < 0.5_wp .AND. vmask(ji,jj-1,jk) > 0.5_wp .AND. vmask(ji,jj-2,jk) > 0.5_wp) THEN
869	zz_drho_j(ji,jj) = aco_bc_hor * ( rhd (ji,jj,jk) - rhd (ji,jj-1,jk) ) - bco_bc_hor * zdrho_j(ji,jj-1,jk)
870	zz_dz_j (ji,jj) = aco_bc_hor * (-gde3w(ji,jj,jk) + gde3w(ji,jj-1,jk) ) - bco_bc_hor * zdz_j (ji,jj-1,jk)
871	END IF
872	END_2D
873	zdrho_i(:,:,jk) = zz_drho_i(:,:)
874	zdz_i (:,:,jk) = zz_dz_i (:,:)
875	zdrho_j(:,:,jk) = zz_drho_j(:,:)
876	zdz_j (:,:,jk) = zz_dz_j (:,:)
877	END DO
878
879	!--------------------------------------------------------------
880	! 7. Calculate integrals on side faces
881	!-------------------------------------------------------------
882
883	DO_3D( 0, 0, 0, 0, 1, jpkm1 )
884	! two -ve signs cancel in next two lines (within zcoef0 and because gde3w is a depth not a height)
885	z_rho_i(ji,jj,jk) = zcoef0 * ( rhd (ji+1,jj,jk) + rhd (ji,jj,jk) ) &
886	& * ( gde3w(ji+1,jj,jk) - gde3w(ji,jj,jk) )
887	IF ( umask(ji-1, jj, jk) > 0.5 .OR. umask(ji+1, jj, jk) > 0.5 ) THEN
888	z_rho_i(ji,jj,jk) = z_rho_i(ji,jj,jk) - z_grav_10 * ( &
889	& ( zdrho_i (ji+1,jj,jk) - zdrho_i (ji,jj,jk) ) &
890	& * ( - gde3w(ji+1,jj,jk) + gde3w(ji,jj,jk) - z1_12 * ( zdz_i (ji+1,jj,jk) + zdz_i (ji,jj,jk) ) ) &
891	& - ( zdz_i (ji+1,jj,jk) - zdz_i (ji,jj,jk) ) &
892	& * ( rhd (ji+1,jj,jk) - rhd (ji,jj,jk) - z1_12 * ( zdrho_i(ji+1,jj,jk) + zdrho_i(ji,jj,jk) ) ) &
893	& )
894	END IF
895
896	z_rho_j(ji,jj,jk) = zcoef0 * ( rhd (ji,jj+1,jk) + rhd (ji,jj,jk) ) &
897	& * ( gde3w(ji,jj+1,jk) - gde3w(ji,jj,jk) )
898	IF ( vmask(ji, jj-1, jk) > 0.5 .OR. vmask(ji, jj+1, jk) > 0.5 ) THEN
899	z_rho_j(ji,jj,jk) = z_rho_j(ji,jj,jk) - z_grav_10 * ( &
900	& ( zdrho_j (ji,jj+1,jk) - zdrho_j (ji,jj,jk) ) &
901	& * ( - gde3w(ji,jj+1,jk) + gde3w(ji,jj,jk) - z1_12 * ( zdz_j (ji,jj+1,jk) + zdz_j (ji,jj,jk) ) ) &
902	& - ( zdz_j (ji,jj+1,jk) - zdz_j (ji,jj,jk) ) &
903	& * ( rhd (ji,jj+1,jk) - rhd (ji,jj,jk) - z1_12 * ( zdrho_j(ji,jj+1,jk) + zdrho_j(ji,jj,jk) ) ) &
904	& )
905	END IF
906	END_3D
907
908	!--------------------------------------------------------------
909	! 8. Integrate in the vertical
910	!-------------------------------------------------------------
911	!
912	! ---------------
913	! Surface value
914	! ---------------
915	DO_2D( 0, 0, 0, 0 )
916	zhpi(ji,jj,1) = ( z_rho_k(ji,jj,1) - z_rho_k(ji+1,jj ,1) - z_rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
917	zhpj(ji,jj,1) = ( z_rho_k(ji,jj,1) - z_rho_k(ji ,jj+1,1) - z_rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
918	IF( ln_wd_il ) THEN
919	zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
920	zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj)
921	ENDIF
922	! add to the general momentum trend
923	puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
924	pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
925	END_2D
926
927	! ----------------
928	! interior value (2=<jk=<jpkm1)
929	! ----------------
930	DO_3D( 0, 0, 0, 0, 2, jpkm1 )
931	! hydrostatic pressure gradient along s-surfaces
932	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
933	& + ( ( z_rho_k(ji,jj,jk) - z_rho_k(ji+1,jj,jk ) ) &
934	& - ( z_rho_i(ji,jj,jk) - z_rho_i(ji ,jj,jk-1) ) ) * r1_e1u(ji,jj)
935	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
936	& + ( ( z_rho_k(ji,jj,jk) - z_rho_k(ji,jj+1,jk ) ) &
937	& -( z_rho_j(ji,jj,jk) - z_rho_j(ji,jj ,jk-1) ) ) * r1_e2v(ji,jj)
938	IF( ln_wd_il ) THEN
939	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
940	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj)
941	ENDIF
942	! add to the general momentum trend
943	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
944	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
945	END_3D
946	!
947	IF( ln_wd_il ) DEALLOCATE( zcpx, zcpy )
948	!
949	END SUBROUTINE hpg_djc
950
951
952	SUBROUTINE hpg_prj( kt, Kmm, puu, pvv, Krhs )
953	!!---------------------------------------------------------------------
954	!! * ROUTINE hpg_prj *
955	!!
956	!! ** Method : s-coordinate case.
957	!! A Pressure-Jacobian horizontal pressure gradient method
958	!! based on the constrained cubic-spline interpolation for
959	!! all vertical coordinate systems
960	!!
961	!! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
962	!!----------------------------------------------------------------------
963	INTEGER, PARAMETER :: polynomial_type = 1 ! 1: cubic spline, 2: linear
964	INTEGER , INTENT( in ) :: kt ! ocean time-step index
965	INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices
966	REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation
967	!!
968	INTEGER :: ji, jj, jk, jkk ! dummy loop indices
969	REAL(wp) :: zcoef0, znad ! local scalars
970	!
971	!! The local variables for the correction term
972	INTEGER :: jk1, jis, jid, jjs, jjd
973	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
974	REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
975	REAL(wp) :: zrhdt1
976	REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
977	REAL(wp), DIMENSION(A2D(nn_hls)) :: zpgu, zpgv ! 2D workspace
978	REAL(wp), DIMENSION(A2D(nn_hls)) :: zsshu_n, zsshv_n
979	REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zdept, zrhh
980	REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
981	REAL(wp), DIMENSION(:,:), ALLOCATABLE :: zcpx, zcpy !W/D pressure filter
982	!!----------------------------------------------------------------------
983	!
984	IF( .NOT. l_istiled .OR. ntile == 1 ) THEN ! Do only on the first tile
985	IF( kt == nit000 ) THEN
986	IF(lwp) WRITE(numout,*)
987	IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
988	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, cubic spline pressure Jacobian'
989	ENDIF
990	ENDIF
991
992	! Local constant initialization
993	zcoef0 = - grav
994	znad = 1._wp
995	IF( ln_linssh ) znad = 1._wp
996	!
997	! ---------------
998	! Surface pressure gradient to be removed
999	! ---------------
1000	DO_2D( 0, 0, 0, 0 )
1001	zpgu(ji,jj) = - grav * ( ssh(ji+1,jj,Kmm) - ssh(ji,jj,Kmm) ) * r1_e1u(ji,jj)
1002	zpgv(ji,jj) = - grav * ( ssh(ji,jj+1,Kmm) - ssh(ji,jj,Kmm) ) * r1_e2v(ji,jj)
1003	END_2D
1004	!
1005	IF( ln_wd_il ) THEN
1006	ALLOCATE( zcpx(A2D(nn_hls)) , zcpy(A2D(nn_hls)) )
1007	DO_2D( 0, 0, 0, 0 )
1008	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
1009	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) .AND. &
1010	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) ) > &
1011	& rn_wdmin1 + rn_wdmin2
1012	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. &
1013	& ( MAX( ssh(ji,jj,Kmm) , ssh(ji+1,jj,Kmm) ) > &
1014	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
1015
1016	IF(ll_tmp1) THEN
1017	zcpx(ji,jj) = 1.0_wp
1018	ELSE IF(ll_tmp2) THEN
1019	! no worries about ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm) = 0, it won't happen ! here
1020	zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
1021	& / (ssh(ji+1,jj,Kmm) - ssh(ji ,jj,Kmm)) )
1022	zcpx(ji,jj) = MAX(MIN( zcpx(ji,jj) , 1.0_wp),0.0_wp)
1023	ELSE
1024	zcpx(ji,jj) = 0._wp
1025	END IF
1026
1027	ll_tmp1 = MIN( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
1028	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) .AND. &
1029	& MAX( ssh(ji,jj,Kmm) + ht_0(ji,jj), ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) ) > &
1030	& rn_wdmin1 + rn_wdmin2
1031	ll_tmp2 = ( ABS( ssh(ji,jj,Kmm) - ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. &
1032	& ( MAX( ssh(ji,jj,Kmm) , ssh(ji,jj+1,Kmm) ) > &
1033	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
1034
1035	IF(ll_tmp1) THEN
1036	zcpy(ji,jj) = 1.0_wp
1037	ELSE IF(ll_tmp2) THEN
1038	! no worries about ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm) = 0, it won't happen ! here
1039	zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
1040	& / (ssh(ji,jj+1,Kmm) - ssh(ji,jj ,Kmm)) )
1041	zcpy(ji,jj) = MAX(MIN( zcpy(ji,jj) , 1.0_wp),0.0_wp)
1042	ELSE
1043	zcpy(ji,jj) = 0._wp
1044	ENDIF
1045	END_2D
1046	ENDIF
1047
1048	! Clean 3-D work arrays
1049	zhpi(:,:,:) = 0._wp
1050	zrhh(:,:,:) = rhd(A2D(nn_hls),:)
1051
1052	! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1053	DO_2D( 1, 1, 1, 1 )
1054	jk = mbkt(ji,jj)
1055	IF( jk <= 1 ) THEN ; zrhh(ji,jj, : ) = 0._wp
1056	ELSEIF( jk == 2 ) THEN ; zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
1057	ELSEIF( jk < jpkm1 ) THEN
1058	DO jkk = jk+1, jpk
1059	zrhh(ji,jj,jkk) = interp1(gde3w(ji,jj,jkk ), gde3w(ji,jj,jkk-1), &
1060	& gde3w(ji,jj,jkk-2), zrhh (ji,jj,jkk-1), zrhh(ji,jj,jkk-2))
1061	END DO
1062	ENDIF
1063	END_2D
1064
1065	! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1066	DO_2D( 1, 1, 1, 1 )
1067	zdept(ji,jj,1) = 0.5_wp * e3w(ji,jj,1,Kmm) - ssh(ji,jj,Kmm)
1068	END_2D
1069
1070	DO_3D( 1, 1, 1, 1, 2, jpk )
1071	zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w(ji,jj,jk,Kmm)
1072	END_3D
1073
1074	fsp(:,:,:) = zrhh (:,:,:)
1075	xsp(:,:,:) = zdept(:,:,:)
1076
1077	! Construct the vertical density profile with the
1078	! constrained cubic spline interpolation
1079	! rho(z) = asp + bspz + cspz^2 + dsp*z^3
1080	CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1081
1082	! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1083	DO_2D( 0, 1, 0, 1 )
1084	zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1), &
1085	& csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w(ji,jj,1,Kmm)
1086
1087	! assuming linear profile across the top half surface layer
1088	zhpi(ji,jj,1) = 0.5_wp * e3w(ji,jj,1,Kmm) * zrhdt1
1089	END_2D
1090
1091	! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1092	DO_3D( 0, 1, 0, 1, 2, jpkm1 )
1093	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + &
1094	& integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk), &
1095	& asp (ji,jj,jk-1), bsp (ji,jj,jk-1), &
1096	& csp (ji,jj,jk-1), dsp (ji,jj,jk-1) )
1097	END_3D
1098
1099	! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1100
1101	! Prepare zsshu_n and zsshv_n
1102	DO_2D( 0, 0, 0, 0 )
1103	!!gm BUG ? if it is ssh at u- & v-point then it should be:
1104	! zsshu_n(ji,jj) = (e1e2t(ji,jj) * ssh(ji,jj,Kmm) + e1e2t(ji+1,jj) * ssh(ji+1,jj,Kmm)) * &
1105	! & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1106	! zsshv_n(ji,jj) = (e1e2t(ji,jj) * ssh(ji,jj,Kmm) + e1e2t(ji,jj+1) * ssh(ji,jj+1,Kmm)) * &
1107	! & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1108	!!gm not this:
1109	zsshu_n(ji,jj) = (e1e2u(ji,jj) * ssh(ji,jj,Kmm) + e1e2u(ji+1, jj) * ssh(ji+1,jj,Kmm)) * &
1110	& r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1111	zsshv_n(ji,jj) = (e1e2v(ji,jj) * ssh(ji,jj,Kmm) + e1e2v(ji+1, jj) * ssh(ji,jj+1,Kmm)) * &
1112	& r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1113	END_2D
1114
1115	DO_2D( 0, 0, 0, 0 )
1116	zu(ji,jj,1) = - ( e3u(ji,jj,1,Kmm) - zsshu_n(ji,jj) )
1117	zv(ji,jj,1) = - ( e3v(ji,jj,1,Kmm) - zsshv_n(ji,jj) )
1118	END_2D
1119
1120	DO_3D( 0, 0, 0, 0, 2, jpkm1 )
1121	zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u(ji,jj,jk,Kmm)
1122	zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v(ji,jj,jk,Kmm)
1123	END_3D
1124
1125	DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1126	zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u(ji,jj,jk,Kmm)
1127	zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v(ji,jj,jk,Kmm)
1128	END_3D
1129
1130	DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1131	zu(ji,jj,jk) = MIN( zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) ) )
1132	zu(ji,jj,jk) = MAX( zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) ) )
1133	zv(ji,jj,jk) = MIN( zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) ) )
1134	zv(ji,jj,jk) = MAX( zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) ) )
1135	END_3D
1136
1137
1138	DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1139	zpwes = 0._wp; zpwed = 0._wp
1140	zpnss = 0._wp; zpnsd = 0._wp
1141	zuijk = zu(ji,jj,jk)
1142	zvijk = zv(ji,jj,jk)
1143
1144	!!!!! for u equation
1145	IF( jk <= mbku(ji,jj) ) THEN
1146	IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1147	jis = ji + 1; jid = ji
1148	ELSE
1149	jis = ji; jid = ji +1
1150	ENDIF
1151
1152	! integrate the pressure on the shallow side
1153	jk1 = jk
1154	DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1155	IF( jk1 == mbku(ji,jj) ) THEN
1156	zuijk = -zdept(jis,jj,jk1)
1157	EXIT
1158	ENDIF
1159	zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1160	zpwes = zpwes + &
1161	integ_spline(zdept(jis,jj,jk1), zdeps, &
1162	asp(jis,jj,jk1), bsp(jis,jj,jk1), &
1163	csp(jis,jj,jk1), dsp(jis,jj,jk1))
1164	jk1 = jk1 + 1
1165	END DO
1166
1167	! integrate the pressure on the deep side
1168	jk1 = jk
1169	DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1170	IF( jk1 == 1 ) THEN
1171	zdeps = zdept(jid,jj,1) + MIN(zuijk, ssh(jid,jj,Kmm)*znad)
1172	zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1173	bsp(jid,jj,1) , csp(jid,jj,1), &
1174	dsp(jid,jj,1)) * zdeps
1175	zpwed = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1176	EXIT
1177	ENDIF
1178	zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1179	zpwed = zpwed + &
1180	integ_spline(zdeps, zdept(jid,jj,jk1), &
1181	asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1), &
1182	csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1183	jk1 = jk1 - 1
1184	END DO
1185
1186	! update the momentum trends in u direction
1187	zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1188	IF( .NOT.ln_linssh ) THEN
1189	zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1190	& ( REAL(jis-jid, wp) * (zpwes + zpwed) + (ssh(ji+1,jj,Kmm)-ssh(ji,jj,Kmm)) )
1191	ELSE
1192	zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1193	ENDIF
1194	IF( ln_wd_il ) THEN
1195	zdpdx1 = zdpdx1 * zcpx(ji,jj) * wdrampu(ji,jj)
1196	zdpdx2 = zdpdx2 * zcpx(ji,jj) * wdrampu(ji,jj)
1197	ENDIF
1198	puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + (zdpdx1 + zdpdx2 - zpgu(ji,jj)) * umask(ji,jj,jk)
1199	ENDIF
1200
1201	!!!!! for v equation
1202	IF( jk <= mbkv(ji,jj) ) THEN
1203	IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1204	jjs = jj + 1; jjd = jj
1205	ELSE
1206	jjs = jj ; jjd = jj + 1
1207	ENDIF
1208
1209	! integrate the pressure on the shallow side
1210	jk1 = jk
1211	DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1212	IF( jk1 == mbkv(ji,jj) ) THEN
1213	zvijk = -zdept(ji,jjs,jk1)
1214	EXIT
1215	ENDIF
1216	zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1217	zpnss = zpnss + &
1218	integ_spline(zdept(ji,jjs,jk1), zdeps, &
1219	asp(ji,jjs,jk1), bsp(ji,jjs,jk1), &
1220	csp(ji,jjs,jk1), dsp(ji,jjs,jk1) )
1221	jk1 = jk1 + 1
1222	END DO
1223
1224	! integrate the pressure on the deep side
1225	jk1 = jk
1226	DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1227	IF( jk1 == 1 ) THEN
1228	zdeps = zdept(ji,jjd,1) + MIN(zvijk, ssh(ji,jjd,Kmm)*znad)
1229	zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1230	bsp(ji,jjd,1) , csp(ji,jjd,1), &
1231	dsp(ji,jjd,1) ) * zdeps
1232	zpnsd = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1233	EXIT
1234	ENDIF
1235	zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1236	zpnsd = zpnsd + &
1237	integ_spline(zdeps, zdept(ji,jjd,jk1), &
1238	asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1239	csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1240	jk1 = jk1 - 1
1241	END DO
1242
1243	! update the momentum trends in v direction
1244	zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1245	IF( .NOT.ln_linssh ) THEN
1246	zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1247	( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (ssh(ji,jj+1,Kmm)-ssh(ji,jj,Kmm)) )
1248	ELSE
1249	zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1250	ENDIF
1251	IF( ln_wd_il ) THEN
1252	zdpdy1 = zdpdy1 * zcpy(ji,jj) * wdrampv(ji,jj)
1253	zdpdy2 = zdpdy2 * zcpy(ji,jj) * wdrampv(ji,jj)
1254	ENDIF
1255
1256	pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + (zdpdy1 + zdpdy2 - zpgv(ji,jj)) * vmask(ji,jj,jk)
1257	ENDIF
1258	!
1259	END_3D
1260	!
1261	IF( ln_wd_il ) DEALLOCATE( zcpx, zcpy )
1262	!
1263	END SUBROUTINE hpg_prj
1264
1265
1266	SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1267	!!----------------------------------------------------------------------
1268	!! * ROUTINE cspline *
1269	!!
1270	!! ** Purpose : constrained cubic spline interpolation
1271	!!
1272	!! ** Method : f(x) = asp + bspx + cspx^2 + dsp*x^3
1273	!!
1274	!! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1275	!!----------------------------------------------------------------------
1276	REAL(wp), DIMENSION(A2D(nn_hls),jpk), INTENT(in ) :: fsp, xsp ! value and coordinate
1277	REAL(wp), DIMENSION(A2D(nn_hls),jpk), INTENT( out) :: asp, bsp, csp, dsp ! coefficients of the interpoated function
1278	INTEGER , INTENT(in ) :: polynomial_type ! 1: cubic spline ; 2: Linear
1279	!
1280	INTEGER :: ji, jj, jk ! dummy loop indices
1281	REAL(wp) :: zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1282	REAL(wp) :: zdxtmp1, zdxtmp2, zalpha
1283	REAL(wp) :: zdf(jpk)
1284	!!----------------------------------------------------------------------
1285	!
1286	IF (polynomial_type == 1) THEN ! Constrained Cubic Spline
1287	DO_2D( 1, 1, 1, 1 )
1288	!!Fritsch&Butland's method, 1984 (preferred, but more computation)
1289	! DO jk = 2, jpkm1-1
1290	! zdxtmp1 = xsp(ji,jj,jk) - xsp(ji,jj,jk-1)
1291	! zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1292	! zdf1 = ( fsp(ji,jj,jk) - fsp(ji,jj,jk-1) ) / zdxtmp1
1293	! zdf2 = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp2
1294	!
1295	! zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1296	!
1297	! IF(zdf1 * zdf2 <= 0._wp) THEN
1298	! zdf(jk) = 0._wp
1299	! ELSE
1300	! zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1301	! ENDIF
1302	! END DO
1303
1304	!!Simply geometric average
1305	DO jk = 2, jpk-2
1306	zdf1 = (fsp(ji,jj,jk ) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk ) - xsp(ji,jj,jk-1))
1307	zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk )) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk ))
1308
1309	IF(zdf1 * zdf2 <= 0._wp) THEN
1310	zdf(jk) = 0._wp
1311	ELSE
1312	zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1313	ENDIF
1314	END DO
1315
1316	zdf(1) = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1317	& ( xsp(ji,jj,2) - xsp(ji,jj,1) ) - 0.5_wp * zdf(2)
1318	zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1319	& ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpk - 2)
1320
1321	DO jk = 1, jpk-2
1322	zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1323	ztmp1 = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1324	ztmp2 = 6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1325	zddf1 = -2._wp * ztmp1 + ztmp2
1326	ztmp1 = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1327	zddf2 = 2._wp * ztmp1 - ztmp2
1328
1329	dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1330	csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1331	bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1332	& csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1333	& dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1334	& xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1335	asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1336	& (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1337	& dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1338	END DO
1339	END_2D
1340
1341	ELSEIF ( polynomial_type == 2 ) THEN ! Linear
1342	DO_3D( 1, 1, 1, 1, 1, jpk-2 )
1343	zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1344	ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1345
1346	dsp(ji,jj,jk) = 0._wp
1347	csp(ji,jj,jk) = 0._wp
1348	bsp(ji,jj,jk) = ztmp1 / zdxtmp
1349	asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1350	END_3D
1351	!
1352	ELSE
1353	CALL ctl_stop( 'invalid polynomial type in cspline' )
1354	ENDIF
1355	!
1356	END SUBROUTINE cspline
1357
1358
1359	FUNCTION interp1(x, xl, xr, fl, fr) RESULT(f)
1360	!!----------------------------------------------------------------------
1361	!! * ROUTINE interp1 *
1362	!!
1363	!! ** Purpose : 1-d linear interpolation
1364	!!
1365	!! ** Method : interpolation is straight forward
1366	!! extrapolation is also permitted (no value limit)
1367	!!----------------------------------------------------------------------
1368	REAL(wp), INTENT(in) :: x, xl, xr, fl, fr
1369	REAL(wp) :: f ! result of the interpolation (extrapolation)
1370	REAL(wp) :: zdeltx
1371	!!----------------------------------------------------------------------
1372	!
1373	zdeltx = xr - xl
1374	IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1375	f = 0.5_wp * (fl + fr)
1376	ELSE
1377	f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1378	ENDIF
1379	!
1380	END FUNCTION interp1
1381
1382
1383	FUNCTION interp2( x, a, b, c, d ) RESULT(f)
1384	!!----------------------------------------------------------------------
1385	!! * ROUTINE interp1 *
1386	!!
1387	!! ** Purpose : 1-d constrained cubic spline interpolation
1388	!!
1389	!! ** Method : cubic spline interpolation
1390	!!
1391	!!----------------------------------------------------------------------
1392	REAL(wp), INTENT(in) :: x, a, b, c, d
1393	REAL(wp) :: f ! value from the interpolation
1394	!!----------------------------------------------------------------------
1395	!
1396	f = a + x* ( b + x * ( c + d * x ) )
1397	!
1398	END FUNCTION interp2
1399
1400
1401	FUNCTION interp3( x, a, b, c, d ) RESULT(f)
1402	!!----------------------------------------------------------------------
1403	!! * ROUTINE interp1 *
1404	!!
1405	!! ** Purpose : Calculate the first order of derivative of
1406	!! a cubic spline function y=a+bx+cx^2+d*x^3
1407	!!
1408	!! ** Method : f=dy/dx=b+2cx+3dx^2
1409	!!
1410	!!----------------------------------------------------------------------
1411	REAL(wp), INTENT(in) :: x, a, b, c, d
1412	REAL(wp) :: f ! value from the interpolation
1413	!!----------------------------------------------------------------------
1414	!
1415	f = b + x * ( 2._wp * c + 3._wp * d * x)
1416	!
1417	END FUNCTION interp3
1418
1419
1420	FUNCTION integ_spline( xl, xr, a, b, c, d ) RESULT(f)
1421	!!----------------------------------------------------------------------
1422	!! * ROUTINE interp1 *
1423	!!
1424	!! ** Purpose : 1-d constrained cubic spline integration
1425	!!
1426	!! ** Method : integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1427	!!
1428	!!----------------------------------------------------------------------
1429	REAL(wp), INTENT(in) :: xl, xr, a, b, c, d
1430	REAL(wp) :: za1, za2, za3
1431	REAL(wp) :: f ! integration result
1432	!!----------------------------------------------------------------------
1433	!
1434	za1 = 0.5_wp * b
1435	za2 = c / 3.0_wp
1436	za3 = 0.25_wp * d
1437	!
1438	f = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1439	& xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1440	!
1441	END FUNCTION integ_spline
1442
1443	!!======================================================================
1444	END MODULE dynhpg

Note: See TracBrowser for help on using the repository browser.

Download in other formats: