New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynldf_lap_blp.F90 in NEMO/branches/2021/dev_r14273_HPC-02_Daley_Tiling/src/OCE/DYN – NEMO

source: NEMO/branches/2021/dev_r14273_HPC-02_Daley_Tiling/src/OCE/DYN/dynldf_lap_blp.F90 @ 14751

Last change on this file since 14751 was 14751, checked in by hadcv, 3 years ago

#2600: Tiling for DYN
  • Property svn:keywords set to Id
File size: 13.1 KB
Line 
1MODULE dynldf_lap_blp
2   !!======================================================================
3   !!                   ***  MODULE  dynldf_lap_blp  ***
4   !! Ocean dynamics:  lateral viscosity trend (laplacian and bilaplacian)
5   !!======================================================================
6   !! History : 3.7  ! 2014-01  (G. Madec, S. Masson)  Original code, re-entrant laplacian
7   !!           4.0  ! 2020-04  (A. Nasser, G. Madec)  Add symmetric mixing tensor
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   dyn_ldf_lap   : update the momentum trend with the lateral viscosity using an iso-level   laplacian operator
12   !!   dyn_ldf_blp   : update the momentum trend with the lateral viscosity using an iso-level bilaplacian operator
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers
15   USE dom_oce        ! ocean space and time domain
16   USE domutl, ONLY : is_tile
17   USE ldfdyn         ! lateral diffusion: eddy viscosity coef.
18   USE ldfslp         ! iso-neutral slopes
19   USE zdf_oce        ! ocean vertical physics
20   !
21   USE in_out_manager ! I/O manager
22   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
23   USE lib_mpp
24   
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC dyn_ldf_lap  ! called by dynldf.F90
29   PUBLIC dyn_ldf_blp  ! called by dynldf.F90
30
31   !! * Substitutions
32#  include "do_loop_substitute.h90"
33#  include "domzgr_substitute.h90"
34   !!----------------------------------------------------------------------
35   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
36   !! $Id$
37   !! Software governed by the CeCILL license (see ./LICENSE)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   SUBROUTINE dyn_ldf_lap( kt, Kbb, Kmm, pu, pv, pu_rhs, pv_rhs, kpass )
42      !!
43      INTEGER                   , INTENT(in   ) ::   kt               ! ocean time-step index
44      INTEGER                   , INTENT(in   ) ::   Kbb, Kmm         ! ocean time level indices
45      INTEGER                   , INTENT(in   ) ::   kpass            ! =1/2 first or second passage
46      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pu, pv           ! before velocity  [m/s]
47      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pu_rhs, pv_rhs   ! velocity trend   [m/s2]
48      !!
49      CALL dyn_ldf_lap_t( kt, Kbb, Kmm, pu, pv, is_tile(pu), pu_rhs, pv_rhs, is_tile(pu_rhs), kpass )
50   END SUBROUTINE dyn_ldf_lap
51
52
53   SUBROUTINE dyn_ldf_lap_t( kt, Kbb, Kmm, pu, pv, ktuv, pu_rhs, pv_rhs, ktuv_rhs, kpass )
54      !!----------------------------------------------------------------------
55      !!                     ***  ROUTINE dyn_ldf_lap  ***
56      !!                       
57      !! ** Purpose :   Compute the before horizontal momentum diffusive
58      !!      trend and add it to the general trend of momentum equation.
59      !!
60      !! ** Method  :   The Laplacian operator apply on horizontal velocity is
61      !!      writen as :   grad_h( ahmt div_h(U )) - curl_h( ahmf curl_z(U) )
62      !!
63      !! ** Action : - pu_rhs, pv_rhs increased by the harmonic operator applied on pu, pv.
64      !!
65      !! Reference : S.Griffies, R.Hallberg 2000 Mon.Wea.Rev., DOI:/
66      !!----------------------------------------------------------------------
67      INTEGER                                 , INTENT(in   ) ::   kt               ! ocean time-step index
68      INTEGER                                 , INTENT(in   ) ::   Kbb, Kmm         ! ocean time level indices
69      INTEGER                                 , INTENT(in   ) ::   kpass            ! =1/2 first or second passage
70      INTEGER                                 , INTENT(in   ) ::   ktuv, ktuv_rhs
71      REAL(wp), DIMENSION(A2D_T(ktuv)    ,JPK), INTENT(in   ) ::   pu, pv           ! before velocity  [m/s]
72      REAL(wp), DIMENSION(A2D_T(ktuv_rhs),JPK), INTENT(inout) ::   pu_rhs, pv_rhs   ! velocity trend   [m/s2]
73      !
74      INTEGER  ::   ji, jj, jk   ! dummy loop indices
75      INTEGER  ::   iij
76      REAL(wp) ::   zsign        ! local scalars
77      REAL(wp) ::   zua, zva     ! local scalars
78      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   zcur, zdiv
79      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   zten, zshe   ! tension (diagonal) and shearing (anti-diagonal) terms
80      !!----------------------------------------------------------------------
81      !
82      IF( .NOT. l_istiled .OR. ntile == 1 )  THEN                       ! Do only on the first tile
83         IF( kt == nit000 .AND. lwp ) THEN
84            WRITE(numout,*)
85            WRITE(numout,*) 'dyn_ldf : iso-level harmonic (laplacian) operator, pass=', kpass
86            WRITE(numout,*) '~~~~~~~ '
87         ENDIF
88      ENDIF
89      !
90      ! Define pu_rhs/pv_rhs halo points for multi-point haloes in bilaplacian case
91      IF( nldf_dyn == np_blp .AND. kpass == 1 ) THEN ; iij = nn_hls
92      ELSE                                           ; iij = 1
93      ENDIF
94      !
95      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign
96      ELSE                    ;   zsign = -1._wp      !  (eddy viscosity coef. >0)
97      ENDIF
98      !
99      SELECT CASE( nn_dynldf_typ ) 
100      !             
101      CASE ( np_typ_rot )       !==  Vorticity-Divergence operator  ==!
102         !
103         ALLOCATE( zcur(A2D(nn_hls)) , zdiv(A2D(nn_hls)) )
104         !
105         DO jk = 1, jpkm1                                 ! Horizontal slab
106            !
107            ! [comm_cleanup] ! DO_2D( 0, 1, 0, 1 )
108            DO_2D( iij-1, iij, iij-1, iij )
109               !                                      ! ahm * e3 * curl  (computed from 1 to jpim1/jpjm1)
110               zcur(ji-1,jj-1) = ahmf(ji-1,jj-1,jk) * e3f(ji-1,jj-1,jk) * r1_e1e2f(ji-1,jj-1)       &   ! ahmf already * by fmask
111                  &     * (  e2v(ji  ,jj-1) * pv(ji  ,jj-1,jk) - e2v(ji-1,jj-1) * pv(ji-1,jj-1,jk)  &
112                  &        - e1u(ji-1,jj  ) * pu(ji-1,jj  ,jk) + e1u(ji-1,jj-1) * pu(ji-1,jj-1,jk)  )
113               !                                      ! ahm * div        (computed from 2 to jpi/jpj)
114               zdiv(ji,jj)     = ahmt(ji,jj,jk) * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kbb)               &   ! ahmt already * by tmask
115                  &     * (  e2u(ji,jj)*e3u(ji,jj,jk,Kbb) * pu(ji,jj,jk) - e2u(ji-1,jj)*e3u(ji-1,jj,jk,Kbb) * pu(ji-1,jj,jk)  &
116                  &        + e1v(ji,jj)*e3v(ji,jj,jk,Kbb) * pv(ji,jj,jk) - e1v(ji,jj-1)*e3v(ji,jj-1,jk,Kbb) * pv(ji,jj-1,jk)  )
117            END_2D
118            !
119            ! [comm_cleanup] ! DO_2D( 0, 0, 0, 0 )                       ! - curl( curl) + grad( div )
120            DO_2D( iij-1, iij-1, iij-1, iij-1 )   ! - curl( curl) + grad( div )
121               pu_rhs(ji,jj,jk) = pu_rhs(ji,jj,jk) + zsign * umask(ji,jj,jk) * (    &    ! * by umask is mandatory for dyn_ldf_blp use
122                  &              - ( zcur(ji  ,jj) - zcur(ji,jj-1) ) * r1_e2u(ji,jj) / e3u(ji,jj,jk,Kmm)   &
123                  &              + ( zdiv(ji+1,jj) - zdiv(ji,jj  ) ) * r1_e1u(ji,jj)                      )
124               !
125               pv_rhs(ji,jj,jk) = pv_rhs(ji,jj,jk) + zsign * vmask(ji,jj,jk) * (    &    ! * by vmask is mandatory for dyn_ldf_blp use
126                  &                ( zcur(ji,jj  ) - zcur(ji-1,jj) ) * r1_e1v(ji,jj) / e3v(ji,jj,jk,Kmm)   &
127                  &              + ( zdiv(ji,jj+1) - zdiv(ji  ,jj) ) * r1_e2v(ji,jj)                      )
128            END_2D
129            !
130         END DO                                           !   End of slab
131         !
132         DEALLOCATE( zcur , zdiv )
133         !
134      CASE ( np_typ_sym )       !==  Symmetric operator  ==!
135         !
136         ALLOCATE( zten(A2D(nn_hls)) , zshe(A2D(nn_hls)) )
137         !
138         DO jk = 1, jpkm1                                 ! Horizontal slab
139            !
140            ! [comm_cleanup] ! DO_2D( 0, 1, 0, 1 )
141            DO_2D( iij-1, iij, iij-1, iij )
142               !                                      ! shearing stress component (F-point)   NB : ahmf has already been multiplied by fmask
143               zshe(ji-1,jj-1) = ahmf(ji-1,jj-1,jk)                                                              &
144                  &     * (    e1f(ji-1,jj-1)    * r1_e2f(ji-1,jj-1)                                             &
145                  &         * ( pu(ji-1,jj  ,jk) * r1_e1u(ji-1,jj  )  - pu(ji-1,jj-1,jk) * r1_e1u(ji-1,jj-1) )   &
146                  &         +  e2f(ji-1,jj-1)    * r1_e1f(ji-1,jj-1)                                             &
147                  &         * ( pv(ji  ,jj-1,jk) * r1_e2v(ji  ,jj-1)  - pv(ji-1,jj-1,jk) * r1_e2v(ji-1,jj-1) )   ) 
148               !                                      ! tension stress component (T-point)   NB : ahmt has already been multiplied by tmask
149               zten(ji,jj)    = ahmt(ji,jj,jk)                                                       &
150                  &     * (    e2t(ji,jj)    * r1_e1t(ji,jj)                                         &
151                  &         * ( pu(ji,jj,jk) * r1_e2u(ji,jj)  - pu(ji-1,jj,jk) * r1_e2u(ji-1,jj) )   &
152                  &         -  e1t(ji,jj)    * r1_e2t(ji,jj)                                         &
153                  &         * ( pv(ji,jj,jk) * r1_e1v(ji,jj)  - pv(ji,jj-1,jk) * r1_e1v(ji,jj-1) )   )   
154            END_2D
155            !
156            ! [comm_cleanup] ! DO_2D( 0, 0, 0, 0 )
157            DO_2D( iij-1, iij-1, iij-1, iij-1 )
158               pu_rhs(ji,jj,jk) = pu_rhs(ji,jj,jk) + zsign * r1_e1e2u(ji,jj) / e3u(ji,jj,jk,Kmm)                               &
159                  &    * (   (   zten(ji+1,jj  ) * e2t(ji+1,jj  )*e2t(ji+1,jj  ) * e3t(ji+1,jj  ,jk,Kmm)                       &
160                  &            - zten(ji  ,jj  ) * e2t(ji  ,jj  )*e2t(ji  ,jj  ) * e3t(ji  ,jj  ,jk,Kmm) ) * r1_e2u(ji,jj)     &                                                   
161                  &        + (   zshe(ji  ,jj  ) * e1f(ji  ,jj  )*e1f(ji  ,jj  ) * e3f(ji  ,jj  ,jk)                           &
162                  &            - zshe(ji  ,jj-1) * e1f(ji  ,jj-1)*e1f(ji  ,jj-1) * e3f(ji  ,jj-1,jk)     ) * r1_e1u(ji,jj) )   
163               !
164               pv_rhs(ji,jj,jk) = pv_rhs(ji,jj,jk) + zsign * r1_e1e2v(ji,jj) / e3v(ji,jj,jk,Kmm)                               &
165                  &    * (   (   zshe(ji  ,jj  ) * e2f(ji  ,jj  )*e2f(ji  ,jj  ) * e3f(ji  ,jj  ,jk)                           &
166                  &            - zshe(ji-1,jj  ) * e2f(ji-1,jj  )*e2f(ji-1,jj  ) * e3f(ji-1,jj  ,jk)     ) * r1_e2v(ji,jj)     &
167                  &        - (   zten(ji  ,jj+1) * e1t(ji  ,jj+1)*e1t(ji  ,jj+1) * e3t(ji  ,jj+1,jk,Kmm)                       &
168                  &            - zten(ji  ,jj  ) * e1t(ji  ,jj  )*e1t(ji  ,jj  ) * e3t(ji  ,jj  ,jk,Kmm) ) * r1_e1v(ji,jj) )
169               !
170            END_2D
171            !
172         END DO
173         !
174         DEALLOCATE( zten , zshe )
175         !
176      END SELECT
177      !
178   END SUBROUTINE dyn_ldf_lap_t
179
180
181   SUBROUTINE dyn_ldf_blp( kt, Kbb, Kmm, pu, pv, pu_rhs, pv_rhs )
182      !!----------------------------------------------------------------------
183      !!                 ***  ROUTINE dyn_ldf_blp  ***
184      !!                   
185      !! ** Purpose :   Compute the before lateral momentum viscous trend
186      !!              and add it to the general trend of momentum equation.
187      !!
188      !! ** Method  :   The lateral viscous trends is provided by a bilaplacian
189      !!      operator applied to before field (forward in time).
190      !!      It is computed by two successive calls to dyn_ldf_lap routine
191      !!
192      !! ** Action :   pt(:,:,:,:,Krhs)   updated with the before rotated bilaplacian diffusion
193      !!----------------------------------------------------------------------
194      INTEGER                         , INTENT(in   ) ::   kt         ! ocean time-step index
195      INTEGER                         , INTENT(in   ) ::   Kbb, Kmm   ! ocean time level indices
196      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pu, pv     ! before velocity fields
197      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pu_rhs, pv_rhs   ! momentum trend
198      !
199      REAL(wp), DIMENSION(A2D(nn_hls),jpk) ::   zulap, zvlap   ! laplacian at u- and v-point
200      !!----------------------------------------------------------------------
201      !
202      IF( .NOT. l_istiled .OR. ntile == 1 )  THEN                       ! Do only on the first tile
203         IF( kt == nit000 )  THEN
204            IF(lwp) WRITE(numout,*)
205            IF(lwp) WRITE(numout,*) 'dyn_ldf_blp : bilaplacian operator momentum '
206            IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
207         ENDIF
208      ENDIF
209      !
210      zulap(:,:,:) = 0._wp
211      zvlap(:,:,:) = 0._wp
212      !
213      CALL dyn_ldf_lap( kt, Kbb, Kmm, pu, pv, zulap, zvlap, 1 )   ! rotated laplacian applied to pt (output in zlap,Kbb)
214      !
215      IF (nn_hls.eq.1) CALL lbc_lnk( 'dynldf_lap_blp', zulap, 'U', -1.0_wp, zvlap, 'V', -1.0_wp )             ! Lateral boundary conditions
216      !
217      CALL dyn_ldf_lap( kt, Kbb, Kmm, zulap, zvlap, pu_rhs, pv_rhs, 2 )   ! rotated laplacian applied to zlap (output in pt(:,:,:,:,Krhs))
218      !
219   END SUBROUTINE dyn_ldf_blp
220
221   !!======================================================================
222END MODULE dynldf_lap_blp
Note: See TracBrowser for help on using the repository browser.