New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcrnf.F90 in NEMO/branches/2021/dev_r14273_HPC-02_Daley_Tiling/src/OCE/SBC – NEMO

source: NEMO/branches/2021/dev_r14273_HPC-02_Daley_Tiling/src/OCE/SBC/sbcrnf.F90 @ 14680

Last change on this file since 14680 was 14680, checked in by hadcv, 3 years ago

#2600: Merge in dev_r14393_HPC-03_Mele_Comm_Cleanup [14667]
  • Property svn:keywords set to Id
File size: 30.5 KB
Line 
1MODULE sbcrnf
2   !!======================================================================
3   !!                       ***  MODULE  sbcrnf  ***
4   !! Ocean forcing:  river runoff
5   !!=====================================================================
6   !! History :  OPA  ! 2000-11  (R. Hordoir, E. Durand)  NetCDF FORMAT
7   !!   NEMO     1.0  ! 2002-09  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-07  (G. Madec)  Surface module
9   !!            3.2  ! 2009-04  (B. Lemaire)  Introduce iom_put
10   !!            3.3  ! 2010-10  (R. Furner, G. Madec) runoff distributed over ocean levels
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_rnf       : monthly runoffs read in a NetCDF file
15   !!   sbc_rnf_init  : runoffs initialisation
16   !!   rnf_mouth     : set river mouth mask
17   !!----------------------------------------------------------------------
18   USE dom_oce        ! ocean space and time domain
19   USE phycst         ! physical constants
20   USE sbc_oce        ! surface boundary condition variables
21   USE eosbn2         ! Equation Of State
22   USE closea, ONLY: l_clo_rnf, clo_rnf ! closed seas
23   !
24   USE in_out_manager ! I/O manager
25   USE fldread        ! read input field at current time step
26   USE iom            ! I/O module
27   USE lib_mpp        ! MPP library
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   sbc_rnf       ! called in sbcmod module
33   PUBLIC   sbc_rnf_div   ! called in divhor module
34   PUBLIC   sbc_rnf_alloc ! called in sbcmod module
35   PUBLIC   sbc_rnf_init  ! called in sbcmod module
36
37   !                                                !!* namsbc_rnf namelist *
38   CHARACTER(len=100)         ::   cn_dir            !: Root directory for location of rnf files
39   LOGICAL           , PUBLIC ::   ln_rnf_depth      !: depth       river runoffs attribute specified in a file
40   LOGICAL                    ::      ln_rnf_depth_ini  !: depth       river runoffs  computed at the initialisation
41   REAL(wp)                   ::      rn_rnf_max        !: maximum value of the runoff climatologie (ln_rnf_depth_ini =T)
42   REAL(wp)                   ::      rn_dep_max        !: depth over which runoffs is spread       (ln_rnf_depth_ini =T)
43   INTEGER                    ::      nn_rnf_depth_file !: create (=1) a runoff depth file or not (=0)
44   LOGICAL           , PUBLIC ::   ln_rnf_icb        !: iceberg flux is specified in a file
45   LOGICAL                    ::   ln_rnf_tem        !: temperature river runoffs attribute specified in a file
46   LOGICAL           , PUBLIC ::   ln_rnf_sal        !: salinity    river runoffs attribute specified in a file
47   TYPE(FLD_N)       , PUBLIC ::   sn_rnf            !: information about the runoff file to be read
48   TYPE(FLD_N)                ::   sn_cnf            !: information about the runoff mouth file to be read
49   TYPE(FLD_N)                ::   sn_i_rnf        !: information about the iceberg flux file to be read
50   TYPE(FLD_N)                ::   sn_s_rnf          !: information about the salinities of runoff file to be read
51   TYPE(FLD_N)                ::   sn_t_rnf          !: information about the temperatures of runoff file to be read
52   TYPE(FLD_N)                ::   sn_dep_rnf        !: information about the depth which river inflow affects
53   LOGICAL           , PUBLIC ::   ln_rnf_mouth      !: specific treatment in mouths vicinity
54   REAL(wp)                   ::   rn_hrnf           !: runoffs, depth over which enhanced vertical mixing is used
55   REAL(wp)          , PUBLIC ::   rn_avt_rnf        !: runoffs, value of the additional vertical mixing coef. [m2/s]
56   REAL(wp)          , PUBLIC ::   rn_rfact          !: multiplicative factor for runoff
57
58   LOGICAL , PUBLIC ::   l_rnfcpl = .false.   !: runoffs recieved from oasis
59   INTEGER , PUBLIC ::   nkrnf = 0            !: nb of levels over which Kz is increased at river mouths
60
61   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rnfmsk              !: river mouth mask (hori.)
62   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:)     ::   rnfmsk_z            !: river mouth mask (vert.)
63   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   h_rnf               !: depth of runoff in m
64   INTEGER,  PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   nk_rnf              !: depth of runoff in model levels
65   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   rnf_tsc_b, rnf_tsc  !: before and now T & S runoff contents   [K.m/s & PSU.m/s]
66
67   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_rnf       ! structure: river runoff (file information, fields read)
68   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_i_rnf     ! structure: iceberg flux (file information, fields read)
69   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_s_rnf     ! structure: river runoff salinity (file information, fields read)
70   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_t_rnf     ! structure: river runoff temperature (file information, fields read)
71
72   !! * Substitutions
73#  include "do_loop_substitute.h90"
74#  include "domzgr_substitute.h90"
75   !!----------------------------------------------------------------------
76   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
77   !! $Id$
78   !! Software governed by the CeCILL license (see ./LICENSE)
79   !!----------------------------------------------------------------------
80CONTAINS
81
82   INTEGER FUNCTION sbc_rnf_alloc()
83      !!----------------------------------------------------------------------
84      !!                ***  ROUTINE sbc_rnf_alloc  ***
85      !!----------------------------------------------------------------------
86      ALLOCATE( rnfmsk(jpi,jpj)         , rnfmsk_z(jpk)          ,     &
87         &      h_rnf (jpi,jpj)         , nk_rnf  (jpi,jpj)      ,     &
88         &      rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
89         !
90      CALL mpp_sum ( 'sbcrnf', sbc_rnf_alloc )
91      IF( sbc_rnf_alloc > 0 )   CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
92   END FUNCTION sbc_rnf_alloc
93
94
95   SUBROUTINE sbc_rnf( kt )
96      !!----------------------------------------------------------------------
97      !!                  ***  ROUTINE sbc_rnf  ***
98      !!
99      !! ** Purpose :   Introduce a climatological run off forcing
100      !!
101      !! ** Method  :   Set each river mouth with a monthly climatology
102      !!                provided from different data.
103      !!                CAUTION : upward water flux, runoff forced to be < 0
104      !!
105      !! ** Action  :   runoff updated runoff field at time-step kt
106      !!----------------------------------------------------------------------
107      INTEGER, INTENT(in) ::   kt          ! ocean time step
108      !
109      INTEGER  ::   ji, jj    ! dummy loop indices
110      INTEGER  ::   z_err = 0 ! dummy integer for error handling
111      !!----------------------------------------------------------------------
112      REAL(wp), DIMENSION(jpi,jpj) ::   ztfrz   ! freezing point used for temperature correction
113      !
114      !
115      !                                            !-------------------!
116      !                                            !   Update runoff   !
117      !                                            !-------------------!
118      !
119      !
120      IF( .NOT. l_rnfcpl )  THEN
121                            CALL fld_read ( kt, nn_fsbc, sf_rnf   )    ! Read Runoffs data and provide it at kt ( runoffs + iceberg )
122         IF( ln_rnf_icb )   CALL fld_read ( kt, nn_fsbc, sf_i_rnf )    ! idem for iceberg flux if required
123      ENDIF
124      IF(   ln_rnf_tem   )   CALL fld_read ( kt, nn_fsbc, sf_t_rnf )    ! idem for runoffs temperature if required
125      IF(   ln_rnf_sal   )   CALL fld_read ( kt, nn_fsbc, sf_s_rnf )    ! idem for runoffs salinity    if required
126      !
127      IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
128         !
129         IF( .NOT. l_rnfcpl ) THEN
130             rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) * tmask(:,:,1)  ! updated runoff value at time step kt
131             IF( ln_rnf_icb ) THEN
132                fwficb(:,:) = rn_rfact * ( sf_i_rnf(1)%fnow(:,:,1) ) * tmask(:,:,1)  ! updated runoff value at time step kt
133                CALL iom_put( 'iceberg_cea'  , fwficb(:,:)  )         ! output iceberg flux
134                CALL iom_put( 'hflx_icb_cea' , fwficb(:,:) * rLfus )   ! output Heat Flux into Sea Water due to Iceberg Thermodynamics -->
135             ENDIF
136         ENDIF
137         !
138         !                                                           ! set temperature & salinity content of runoffs
139         IF( ln_rnf_tem ) THEN                                       ! use runoffs temperature data
140            rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rho0
141            CALL eos_fzp( sss_m(:,:), ztfrz(:,:) )
142            WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp )             ! if missing data value use SST as runoffs temperature
143               rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rho0
144            END WHERE
145         ELSE                                                        ! use SST as runoffs temperature
146            !CEOD River is fresh water so must at least be 0 unless we consider ice
147            rnf_tsc(:,:,jp_tem) = MAX( sst_m(:,:), 0.0_wp ) * rnf(:,:) * r1_rho0
148         ENDIF
149         !                                                           ! use runoffs salinity data
150         IF( ln_rnf_sal )   rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rho0
151         !                                                           ! else use S=0 for runoffs (done one for all in the init)
152                                         CALL iom_put( 'runoffs'     , rnf(:,:)                         )   ! output runoff mass flux
153         IF( iom_use('hflx_rnf_cea') )   CALL iom_put( 'hflx_rnf_cea', rnf_tsc(:,:,jp_tem) * rho0 * rcp )   ! output runoff sensible heat (W/m2)
154      ENDIF
155      !
156      !                                                ! ---------------------------------------- !
157      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
158         !                                             ! ---------------------------------------- !
159         IF( ln_rstart .AND. .NOT.l_1st_euler ) THEN         !* Restart: read in restart file
160            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields red in the restart file', lrxios
161            CALL iom_get( numror, jpdom_auto, 'rnf_b'   , rnf_b                 )   ! before runoff
162            CALL iom_get( numror, jpdom_auto, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) )   ! before heat content of runoff
163            CALL iom_get( numror, jpdom_auto, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) )   ! before salinity content of runoff
164         ELSE                                                !* no restart: set from nit000 values
165            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields set to nit000'
166            rnf_b    (:,:  ) = rnf    (:,:  )
167            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
168         ENDIF
169      ENDIF
170      !                                                ! ---------------------------------------- !
171      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
172         !                                             ! ---------------------------------------- !
173         IF(lwp) WRITE(numout,*)
174         IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ',   &
175            &                    'at it= ', kt,' date= ', ndastp
176         IF(lwp) WRITE(numout,*) '~~~~'
177         CALL iom_rstput( kt, nitrst, numrow, 'rnf_b'   , rnf                 )
178         CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
179         CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
180      ENDIF
181      !
182   END SUBROUTINE sbc_rnf
183
184
185   SUBROUTINE sbc_rnf_div( phdivn, Kmm )
186      !!----------------------------------------------------------------------
187      !!                  ***  ROUTINE sbc_rnf  ***
188      !!
189      !! ** Purpose :   update the horizontal divergence with the runoff inflow
190      !!
191      !! ** Method  :
192      !!                CAUTION : rnf is positive (inflow) decreasing the
193      !!                          divergence and expressed in m/s
194      !!
195      !! ** Action  :   phdivn   decreased by the runoff inflow
196      !!----------------------------------------------------------------------
197      INTEGER                   , INTENT(in   ) ::   Kmm      ! ocean time level index
198      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   phdivn   ! horizontal divergence
199      !!
200      INTEGER  ::   ji, jj, jk   ! dummy loop indices
201      REAL(wp) ::   zfact     ! local scalar
202      !!----------------------------------------------------------------------
203      !
204      zfact = 0.5_wp
205      !
206      IF( ln_rnf_depth .OR. ln_rnf_depth_ini ) THEN      !==   runoff distributed over several levels   ==!
207         IF( ln_linssh ) THEN    !* constant volume case : just apply the runoff input flow
208            ! [comm_cleanup] ! DO_2D( 1, 1, 1, 1 )
209            DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
210               DO jk = 1, nk_rnf(ji,jj)
211                  phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rho0 / h_rnf(ji,jj)
212               END DO
213            END_2D
214         ELSE                    !* variable volume case
215            ! [comm_cleanup] ! DO_2D( 1, 1, 1, 1 )              ! update the depth over which runoffs are distributed
216            DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )              ! update the depth over which runoffs are distributed
217               h_rnf(ji,jj) = 0._wp
218               DO jk = 1, nk_rnf(ji,jj)                             ! recalculates h_rnf to be the depth in metres
219                  h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)   ! to the bottom of the relevant grid box
220               END DO
221               !                          ! apply the runoff input flow
222               DO jk = 1, nk_rnf(ji,jj)
223                  phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rho0 / h_rnf(ji,jj)
224               END DO
225            END_2D
226         ENDIF
227      ELSE                       !==   runoff put only at the surface   ==!
228         h_rnf (:,:)   = e3t (:,:,1,Kmm)        ! update h_rnf to be depth of top box
229         phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rho0 / e3t(:,:,1,Kmm)
230      ENDIF
231      !
232   END SUBROUTINE sbc_rnf_div
233
234
235   SUBROUTINE sbc_rnf_init( Kmm )
236      !!----------------------------------------------------------------------
237      !!                  ***  ROUTINE sbc_rnf_init  ***
238      !!
239      !! ** Purpose :   Initialisation of the runoffs if (ln_rnf=T)
240      !!
241      !! ** Method  : - read the runoff namsbc_rnf namelist
242      !!
243      !! ** Action  : - read parameters
244      !!----------------------------------------------------------------------
245      INTEGER, INTENT(in) :: Kmm           ! ocean time level index
246      CHARACTER(len=32) ::   rn_dep_file   ! runoff file name
247      INTEGER           ::   ji, jj, jk, jm    ! dummy loop indices
248      INTEGER           ::   ierror, inum  ! temporary integer
249      INTEGER           ::   ios           ! Local integer output status for namelist read
250      INTEGER           ::   nbrec         ! temporary integer
251      REAL(wp)          ::   zacoef
252      REAL(wp), DIMENSION(jpi,jpj,2) :: zrnfcl
253      !!
254      NAMELIST/namsbc_rnf/ cn_dir            , ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, ln_rnf_icb,   &
255         &                 sn_rnf, sn_cnf    , sn_i_rnf, sn_s_rnf    , sn_t_rnf  , sn_dep_rnf,   &
256         &                 ln_rnf_mouth      , rn_hrnf     , rn_avt_rnf, rn_rfact,     &
257         &                 ln_rnf_depth_ini  , rn_dep_max  , rn_rnf_max, nn_rnf_depth_file
258      !!----------------------------------------------------------------------
259      !
260      !                                         !==  allocate runoff arrays
261      IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
262      !
263      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
264         ln_rnf_mouth  = .FALSE.                   ! default definition needed for example by sbc_ssr or by tra_adv_muscl
265         nkrnf         = 0
266         rnf     (:,:) = 0.0_wp
267         rnf_b   (:,:) = 0.0_wp
268         rnfmsk  (:,:) = 0.0_wp
269         rnfmsk_z(:)   = 0.0_wp
270         RETURN
271      ENDIF
272      !
273      !                                   ! ============
274      !                                   !   Namelist
275      !                                   ! ============
276      !
277      READ  ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
278901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist' )
279
280      READ  ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
281902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist' )
282      IF(lwm) WRITE ( numond, namsbc_rnf )
283      !
284      !                                         ! Control print
285      IF(lwp) THEN
286         WRITE(numout,*)
287         WRITE(numout,*) 'sbc_rnf_init : runoff '
288         WRITE(numout,*) '~~~~~~~~~~~~ '
289         WRITE(numout,*) '   Namelist namsbc_rnf'
290         WRITE(numout,*) '      specific river mouths treatment            ln_rnf_mouth = ', ln_rnf_mouth
291         WRITE(numout,*) '      river mouth additional Kz                  rn_avt_rnf   = ', rn_avt_rnf
292         WRITE(numout,*) '      depth of river mouth additional mixing     rn_hrnf      = ', rn_hrnf
293         WRITE(numout,*) '      multiplicative factor for runoff           rn_rfact     = ', rn_rfact
294      ENDIF
295      !                                   ! ==================
296      !                                   !   Type of runoff
297      !                                   ! ==================
298      !
299      IF( .NOT. l_rnfcpl ) THEN
300         ALLOCATE( sf_rnf(1), STAT=ierror )         ! Create sf_rnf structure (runoff inflow)
301         IF(lwp) WRITE(numout,*)
302         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs inflow read in a file'
303         IF( ierror > 0 ) THEN
304            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_rnf structure' )   ;   RETURN
305         ENDIF
306         ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1)   )
307         IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
308         CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf', no_print )
309         !
310         IF( ln_rnf_icb ) THEN                      ! Create (if required) sf_i_rnf structure
311            IF(lwp) WRITE(numout,*)
312            IF(lwp) WRITE(numout,*) '          iceberg flux read in a file'
313            ALLOCATE( sf_i_rnf(1), STAT=ierror  )
314            IF( ierror > 0 ) THEN
315               CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_i_rnf structure' )   ;   RETURN
316            ENDIF
317            ALLOCATE( sf_i_rnf(1)%fnow(jpi,jpj,1)   )
318            IF( sn_i_rnf%ln_tint ) ALLOCATE( sf_i_rnf(1)%fdta(jpi,jpj,1,2) )
319            CALL fld_fill (sf_i_rnf, (/ sn_i_rnf /), cn_dir, 'sbc_rnf_init', 'read iceberg flux data', 'namsbc_rnf' )
320         ELSE
321            fwficb(:,:) = 0._wp
322         ENDIF
323
324      ENDIF
325      !
326      IF( ln_rnf_tem ) THEN                      ! Create (if required) sf_t_rnf structure
327         IF(lwp) WRITE(numout,*)
328         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs temperatures read in a file'
329         ALLOCATE( sf_t_rnf(1), STAT=ierror  )
330         IF( ierror > 0 ) THEN
331            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' )   ;   RETURN
332         ENDIF
333         ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1)   )
334         IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
335         CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf', no_print )
336      ENDIF
337      !
338      IF( ln_rnf_sal  ) THEN                     ! Create (if required) sf_s_rnf and sf_t_rnf structures
339         IF(lwp) WRITE(numout,*)
340         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs salinities read in a file'
341         ALLOCATE( sf_s_rnf(1), STAT=ierror  )
342         IF( ierror > 0 ) THEN
343            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' )   ;   RETURN
344         ENDIF
345         ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1)   )
346         IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
347         CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf', no_print )
348      ENDIF
349      !
350      IF( ln_rnf_depth ) THEN                    ! depth of runoffs set from a file
351         IF(lwp) WRITE(numout,*)
352         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs depth read in a file'
353         rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
354         IF( .NOT. sn_dep_rnf%ln_clim ) THEN   ;   WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear    ! add year
355            IF( sn_dep_rnf%clftyp == 'monthly' )   WRITE(rn_dep_file, '(a,"m",i2)'  ) TRIM( rn_dep_file ), nmonth   ! add month
356         ENDIF
357         CALL iom_open ( rn_dep_file, inum )                             ! open file
358         CALL iom_get  ( inum, jpdom_global, sn_dep_rnf%clvar, h_rnf )   ! read the river mouth array
359         CALL iom_close( inum )                                          ! close file
360         !
361         nk_rnf(:,:) = 0                               ! set the number of level over which river runoffs are applied
362         ! [comm_cleanup] ! DO_2D( 1, 1, 1, 1 )
363         DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
364            IF( h_rnf(ji,jj) > 0._wp ) THEN
365               jk = 2
366               DO WHILE ( jk < mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
367               END DO
368               nk_rnf(ji,jj) = jk
369            ELSEIF( h_rnf(ji,jj) == -1._wp   ) THEN   ;  nk_rnf(ji,jj) = 1
370            ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN   ;  nk_rnf(ji,jj) = mbkt(ji,jj)
371            ELSE
372               CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999'  )
373               WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
374            ENDIF
375         END_2D
376         ! [comm_cleanup] ! DO_2D( 1, 1, 1, 1 )                           ! set the associated depth
377         DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )                           ! set the associated depth
378            h_rnf(ji,jj) = 0._wp
379            DO jk = 1, nk_rnf(ji,jj)
380               h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)
381            END DO
382         END_2D
383         !
384      ELSE IF( ln_rnf_depth_ini ) THEN           ! runoffs applied at the surface
385         !
386         IF(lwp) WRITE(numout,*)
387         IF(lwp) WRITE(numout,*) '   ==>>>   depth of runoff computed once from max value of runoff'
388         IF(lwp) WRITE(numout,*) '        max value of the runoff climatologie (over global domain) rn_rnf_max = ', rn_rnf_max
389         IF(lwp) WRITE(numout,*) '        depth over which runoffs is spread                        rn_dep_max = ', rn_dep_max
390         IF(lwp) WRITE(numout,*) '        create (=1) a runoff depth file or not (=0)      nn_rnf_depth_file  = ', nn_rnf_depth_file
391
392         CALL iom_open( TRIM( sn_rnf%clname ), inum )    !  open runoff file
393         nbrec = iom_getszuld( inum )
394         zrnfcl(:,:,1) = 0._wp                                                            ! init the max to 0. in 1
395         DO jm = 1, nbrec
396            CALL iom_get( inum, jpdom_global, TRIM( sn_rnf%clvar ), zrnfcl(:,:,2), jm )   ! read the value in 2
397            zrnfcl(:,:,1) = MAXVAL( zrnfcl(:,:,:), DIM=3 )                                ! store the maximum value in time in 1
398         END DO
399         CALL iom_close( inum )
400         !
401         h_rnf(:,:) = 1.
402         !
403         zacoef = rn_dep_max / rn_rnf_max            ! coef of linear relation between runoff and its depth (150m for max of runoff)
404         !
405         WHERE( zrnfcl(:,:,1) > 0._wp )  h_rnf(:,:) = zacoef * zrnfcl(:,:,1)   ! compute depth for all runoffs
406         !
407         ! [comm_cleanup] ! DO_2D( 1, 1, 1, 1 )                ! take in account min depth of ocean rn_hmin
408         DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )                ! take in account min depth of ocean rn_hmin
409            IF( zrnfcl(ji,jj,1) > 0._wp ) THEN
410               jk = mbkt(ji,jj)
411               h_rnf(ji,jj) = MIN( h_rnf(ji,jj), gdept_0(ji,jj,jk ) )
412            ENDIF
413         END_2D
414         !
415         nk_rnf(:,:) = 0                       ! number of levels on which runoffs are distributed
416         ! [comm_cleanup] ! DO_2D( 1, 1, 1, 1 )
417         DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
418            IF( zrnfcl(ji,jj,1) > 0._wp ) THEN
419               jk = 2
420               DO WHILE ( jk < mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
421               END DO
422               nk_rnf(ji,jj) = jk
423            ELSE
424               nk_rnf(ji,jj) = 1
425            ENDIF
426         END_2D
427         !
428         ! [comm_cleanup] ! DO_2D( 1, 1, 1, 1 )                          ! set the associated depth
429         DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )                          ! set the associated depth
430            h_rnf(ji,jj) = 0._wp
431            DO jk = 1, nk_rnf(ji,jj)
432               h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)
433            END DO
434         END_2D
435         !
436         IF( nn_rnf_depth_file == 1 ) THEN      !  save  output nb levels for runoff
437            IF(lwp) WRITE(numout,*) '   ==>>>   create runoff depht file'
438            CALL iom_open  ( TRIM( sn_dep_rnf%clname ), inum, ldwrt = .TRUE. )
439            CALL iom_rstput( 0, 0, inum, 'rodepth', h_rnf )
440            CALL iom_close ( inum )
441         ENDIF
442      ELSE                                       ! runoffs applied at the surface
443         nk_rnf(:,:) = 1
444         h_rnf (:,:) = e3t(:,:,1,Kmm)
445      ENDIF
446      !
447      rnf(:,:) =  0._wp                         ! runoff initialisation
448      rnf_tsc(:,:,:) = 0._wp                    ! runoffs temperature & salinty contents initilisation
449      !
450      !                                   ! ========================
451      !                                   !   River mouth vicinity
452      !                                   ! ========================
453      !
454      IF( ln_rnf_mouth ) THEN                   ! Specific treatment in vicinity of river mouths :
455         !                                      !    - Increase Kz in surface layers ( rn_hrnf > 0 )
456         !                                      !    - set to zero SSS damping (ln_ssr=T)
457         !                                      !    - mixed upstream-centered (ln_traadv_cen2=T)
458         !
459         IF( ln_rnf_depth )   CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already',   &
460            &                                              'be spread through depth by ln_rnf_depth'               )
461         !
462         nkrnf = 0                                  ! Number of level over which Kz increase
463         IF( rn_hrnf > 0._wp ) THEN
464            nkrnf = 2
465            DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf )   ;   nkrnf = nkrnf + 1
466            END DO
467            IF( ln_sco )   CALL ctl_warn( 'sbc_rnf_init: number of levels over which Kz is increased is computed for zco...' )
468         ENDIF
469         IF(lwp) WRITE(numout,*)
470         IF(lwp) WRITE(numout,*) '   ==>>>   Specific treatment used in vicinity of river mouths :'
471         IF(lwp) WRITE(numout,*) '             - Increase Kz in surface layers (if rn_hrnf > 0 )'
472         IF(lwp) WRITE(numout,*) '               by ', rn_avt_rnf,' m2/s  over ', nkrnf, ' w-levels'
473         IF(lwp) WRITE(numout,*) '             - set to zero SSS damping       (if ln_ssr=T)'
474         IF(lwp) WRITE(numout,*) '             - mixed upstream-centered       (if ln_traadv_cen2=T)'
475         !
476         CALL rnf_mouth                             ! set river mouth mask
477         !
478      ELSE                                      ! No treatment at river mouths
479         IF(lwp) WRITE(numout,*)
480         IF(lwp) WRITE(numout,*) '   ==>>>   No specific treatment at river mouths'
481         rnfmsk  (:,:) = 0._wp
482         rnfmsk_z(:)   = 0._wp
483         nkrnf = 0
484      ENDIF
485      !
486   END SUBROUTINE sbc_rnf_init
487
488
489   SUBROUTINE rnf_mouth
490      !!----------------------------------------------------------------------
491      !!                  ***  ROUTINE rnf_mouth  ***
492      !!
493      !! ** Purpose :   define the river mouths mask
494      !!
495      !! ** Method  :   read the river mouth mask (=0/1) in the river runoff
496      !!                climatological file. Defined a given vertical structure.
497      !!                CAUTION, the vertical structure is hard coded on the
498      !!                first 5 levels.
499      !!                This fields can be used to:
500      !!                 - set an upstream advection scheme
501      !!                   (ln_rnf_mouth=T and ln_traadv_cen2=T)
502      !!                 - increase vertical on the top nn_krnf vertical levels
503      !!                   at river runoff input grid point (nn_krnf>=2, see step.F90)
504      !!                 - set to zero SSS restoring flux at river mouth grid points
505      !!
506      !! ** Action  :   rnfmsk   set to 1 at river runoff input, 0 elsewhere
507      !!                rnfmsk_z vertical structure
508      !!----------------------------------------------------------------------
509      INTEGER            ::   inum        ! temporary integers
510      CHARACTER(len=140) ::   cl_rnfile   ! runoff file name
511      !!----------------------------------------------------------------------
512      !
513      IF(lwp) WRITE(numout,*)
514      IF(lwp) WRITE(numout,*) '   rnf_mouth : river mouth mask'
515      IF(lwp) WRITE(numout,*) '   ~~~~~~~~~ '
516      !
517      cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
518      IF( .NOT. sn_cnf%ln_clim ) THEN   ;   WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear    ! add year
519         IF( sn_cnf%clftyp == 'monthly' )   WRITE(cl_rnfile, '(a,"m",i2)'  ) TRIM( cl_rnfile ), nmonth   ! add month
520      ENDIF
521      !
522      ! horizontal mask (read in NetCDF file)
523      CALL iom_open ( cl_rnfile, inum )                             ! open file
524      CALL iom_get  ( inum, jpdom_global, sn_cnf%clvar, rnfmsk )    ! read the river mouth array
525      CALL iom_close( inum )                                        ! close file
526      !
527      IF( l_clo_rnf )   CALL clo_rnf( rnfmsk )   ! closed sea inflow set as river mouth
528      !
529      rnfmsk_z(:)   = 0._wp                                       ! vertical structure
530      rnfmsk_z(1)   = 1.0
531      rnfmsk_z(2)   = 1.0                                         ! **********
532      rnfmsk_z(3)   = 0.5                                         ! HARD CODED on the 5 first levels
533      rnfmsk_z(4)   = 0.25                                        ! **********
534      rnfmsk_z(5)   = 0.125
535      !
536   END SUBROUTINE rnf_mouth
537
538   !!======================================================================
539END MODULE sbcrnf
Note: See TracBrowser for help on using the repository browser.