New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zpshde.F90 in NEMO/branches/2021/dev_r14273_HPC-02_Daley_Tiling/src/OCE/TRA – NEMO

source: NEMO/branches/2021/dev_r14273_HPC-02_Daley_Tiling/src/OCE/TRA/zpshde.F90 @ 14680

Last change on this file since 14680 was 14680, checked in by hadcv, 3 years ago

#2600: Merge in dev_r14393_HPC-03_Mele_Comm_Cleanup [14667]
  • Property svn:keywords set to Id
File size: 28.0 KB
Line 
1MODULE zpshde
2   !!======================================================================
3   !!                       ***  MODULE zpshde   ***
4   !! z-coordinate + partial step : Horizontal Derivative at ocean bottom level
5   !!======================================================================
6   !! History :  OPA  !  2002-04  (A. Bozec)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec E. Durand)  Optimization and Free form
8   !!             -   !  2004-03  (C. Ethe)  adapted for passive tracers
9   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
10   !!            3.6  !  2014-11  (P. Mathiot) Add zps_hde_isf (needed to open a cavity)
11   !!======================================================================
12
13   !!----------------------------------------------------------------------
14   !!   zps_hde      :  Horizontal DErivative of T, S and rd at the last
15   !!                   ocean level (Z-coord. with Partial Steps)
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean: dynamics and tracers variables
18   USE dom_oce         ! domain: ocean variables
19   USE domutl, ONLY : is_tile
20   USE phycst          ! physical constants
21   USE eosbn2          ! ocean equation of state
22   USE in_out_manager  ! I/O manager
23   USE lbclnk          ! lateral boundary conditions (or mpp link)
24   USE lib_mpp         ! MPP library
25   USE timing          ! Timing
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   zps_hde     ! routine called by step.F90
31   PUBLIC   zps_hde_isf ! routine called by step.F90
32
33   !! * Substitutions
34#  include "do_loop_substitute.h90"
35#  include "domzgr_substitute.h90"
36   !!----------------------------------------------------------------------
37   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
38   !! $Id$
39   !! Software governed by the CeCILL license (see ./LICENSE)
40   !!----------------------------------------------------------------------
41CONTAINS
42
43   SUBROUTINE zps_hde( kt, Kmm, kjpt, pta, pgtu, pgtv,  &
44      &                               prd, pgru, pgrv )
45      !!
46      INTEGER                     , INTENT(in   )           ::  kt          ! ocean time-step index
47      INTEGER                     , INTENT(in   )           ::  Kmm         ! ocean time level index
48      INTEGER                     , INTENT(in   )           ::  kjpt        ! number of tracers
49      REAL(wp), DIMENSION(:,:,:,:), INTENT(in   )           ::  pta         ! 4D tracers fields
50      REAL(wp), DIMENSION(:,:,:)  , INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
51      REAL(wp), DIMENSION(:,:,:)  , INTENT(in   ), OPTIONAL ::  prd         ! 3D density anomaly fields
52      REAL(wp), DIMENSION(:,:)    , INTENT(  out), OPTIONAL ::  pgru, pgrv  ! hor. grad of prd at u- & v-pts (bottom)
53      !
54      INTEGER :: itrd, itgr
55      !!
56      IF( PRESENT(prd)  ) THEN ; itrd = is_tile(prd)  ; ELSE ; itrd = 0 ; ENDIF
57      IF( PRESENT(pgru) ) THEN ; itgr = is_tile(pgru) ; ELSE ; itgr = 0 ; ENDIF
58
59      CALL zps_hde_t( kt, Kmm, kjpt, pta, is_tile(pta), pgtu, pgtv, is_tile(pgtu), &
60         &                           prd, itrd,         pgru, pgrv, itgr )
61   END SUBROUTINE zps_hde
62
63
64   SUBROUTINE zps_hde_t( kt, Kmm, kjpt, pta, ktta, pgtu, pgtv, ktgt,   &
65      &                                 prd, ktrd, pgru, pgrv, ktgr )
66      !!----------------------------------------------------------------------
67      !!                     ***  ROUTINE zps_hde  ***
68      !!
69      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
70      !!      at u- and v-points with a linear interpolation for z-coordinate
71      !!      with partial steps.
72      !!
73      !! ** Method  :   In z-coord with partial steps, scale factors on last
74      !!      levels are different for each grid point, so that T, S and rd
75      !!      points are not at the same depth as in z-coord. To have horizontal
76      !!      gradients again, we interpolate T and S at the good depth :
77      !!      Linear interpolation of T, S
78      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
79      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
80      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
81      !!         This formulation computes the two cases:
82      !!                 CASE 1                   CASE 2
83      !!         k-1  ___ ___________   k-1   ___ ___________
84      !!                    Ti  T~                  T~  Ti+1
85      !!                  _____                        _____
86      !!         k        |   |Ti+1     k           Ti |   |
87      !!                  |   |____                ____|   |
88      !!              ___ |   |   |           ___  |   |   |
89      !!
90      !!      case 1->   e3w(i+1,:,:,Kmm) >= e3w(i,:,:,Kmm) ( and e3w(:,j+1,:,Kmm) >= e3w(:,j,:,Kmm) ) then
91      !!          t~ = t(i+1,j  ,k) + (e3w(i+1,j,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Ti+1)/e3w(i+1,j,k,Kmm)
92      !!        ( t~ = t(i  ,j+1,k) + (e3w(i,j+1,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Tj+1)/e3w(i,j+1,k,Kmm)  )
93      !!          or
94      !!      case 2->   e3w(i+1,:,:,Kmm) <= e3w(i,:,:,Kmm) ( and e3w(:,j+1,:,Kmm) <= e3w(:,j,:,Kmm) ) then
95      !!          t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i+1,j,k,Kmm)) * dk(Ti)/e3w(i,j,k,Kmm)
96      !!        ( t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i,j+1,k,Kmm)) * dk(Tj)/e3w(i,j,k,Kmm) )
97      !!          Idem for di(s) and dj(s)
98      !!
99      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
100      !!      depth zh from interpolated T and S for the different formulations
101      !!      of the equation of state (eos).
102      !!      Gradient formulation for rho :
103      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
104      !!
105      !! ** Action  : compute for top interfaces
106      !!              - pgtu, pgtv: horizontal gradient of tracer at u- & v-points
107      !!              - pgru, pgrv: horizontal gradient of rho (if present) at u- & v-points
108      !!----------------------------------------------------------------------
109      INTEGER                                , INTENT(in   )           ::  kt          ! ocean time-step index
110      INTEGER                                , INTENT(in   )           ::  Kmm         ! ocean time level index
111      INTEGER                                , INTENT(in   )           ::  kjpt        ! number of tracers
112      INTEGER                                , INTENT(in   )           ::  ktta, ktgt, ktrd, ktgr
113      REAL(wp), DIMENSION(A2D_T(ktta),JPK,KJPT), INTENT(in   )           ::  pta         ! 4D tracers fields
114      REAL(wp), DIMENSION(A2D_T(ktgt)    ,KJPT), INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
115      REAL(wp), DIMENSION(A2D_T(ktrd),JPK     ), INTENT(in   ), OPTIONAL ::  prd         ! 3D density anomaly fields
116      REAL(wp), DIMENSION(A2D_T(ktgr)         ), INTENT(  out), OPTIONAL ::  pgru, pgrv  ! hor. grad of prd at u- & v-pts (bottom)
117      !
118      INTEGER  ::   ji, jj, jn                  ! Dummy loop indices
119      INTEGER  ::   iku, ikv, ikum1, ikvm1      ! partial step level (ocean bottom level) at u- and v-points
120      REAL(wp) ::   ze3wu, ze3wv, zmaxu, zmaxv  ! local scalars
121      REAL(wp), DIMENSION(A2D(nn_hls))      ::   zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
122      REAL(wp), DIMENSION(A2D(nn_hls),kjpt) ::   zti, ztj             !
123      !!----------------------------------------------------------------------
124      !
125      IF( ln_timing )   CALL timing_start( 'zps_hde')
126      !
127      pgtu(:,:,:) = 0._wp   ;   zti (:,:,:) = 0._wp   ;   zhi (:,:) = 0._wp
128      pgtv(:,:,:) = 0._wp   ;   ztj (:,:,:) = 0._wp   ;   zhj (:,:) = 0._wp
129      !
130      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
131         !
132         ! NOTE: [tiling] increase lower bounds for tra_ldf_blp* calculation
133         DO_2D( nn_hls, nn_hls-1, nn_hls, nn_hls-1 )              ! Gradient of density at the last level
134            iku = mbku(ji,jj)   ;   ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
135            ikv = mbkv(ji,jj)   ;   ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
136!!gm BUG ? when applied to before fields, e3w(:,:,k,Kbb) should be used....
137            ze3wu = e3w(ji+1,jj  ,iku,Kmm) - e3w(ji,jj,iku,Kmm)
138            ze3wv = e3w(ji  ,jj+1,ikv,Kmm) - e3w(ji,jj,ikv,Kmm)
139            !
140            ! i- direction
141            IF( ze3wu >= 0._wp ) THEN      ! case 1
142               zmaxu =  ze3wu / e3w(ji+1,jj,iku,Kmm)
143               ! interpolated values of tracers
144               zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
145               ! gradient of  tracers
146               pgtu(ji,jj,jn) = umask(ji,jj,1) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
147            ELSE                           ! case 2
148               zmaxu = -ze3wu / e3w(ji,jj,iku,Kmm)
149               ! interpolated values of tracers
150               zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
151               ! gradient of tracers
152               pgtu(ji,jj,jn) = umask(ji,jj,1) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
153            ENDIF
154            !
155            ! j- direction
156            IF( ze3wv >= 0._wp ) THEN      ! case 1
157               zmaxv =  ze3wv / e3w(ji,jj+1,ikv,Kmm)
158               ! interpolated values of tracers
159               ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
160               ! gradient of tracers
161               pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
162            ELSE                           ! case 2
163               zmaxv =  -ze3wv / e3w(ji,jj,ikv,Kmm)
164               ! interpolated values of tracers
165               ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
166               ! gradient of tracers
167               pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
168            ENDIF
169         END_2D
170      END DO
171      !
172      IF (nn_hls.EQ.1) CALL lbc_lnk( 'zpshde', pgtu(:,:,:), 'U', -1.0_wp , pgtv(:,:,:), 'V', -1.0_wp )   ! Lateral boundary cond.
173      !
174      IF( PRESENT( prd ) ) THEN    !==  horizontal derivative of density anomalies (rd)  ==!    (optional part)
175         pgru(:,:) = 0._wp
176         pgrv(:,:) = 0._wp                ! depth of the partial step level
177         DO_2D( nn_hls, nn_hls-1, nn_hls, nn_hls-1 )
178            iku = mbku(ji,jj)
179            ikv = mbkv(ji,jj)
180            ze3wu  = e3w(ji+1,jj  ,iku,Kmm) - e3w(ji,jj,iku,Kmm)
181            ze3wv  = e3w(ji  ,jj+1,ikv,Kmm) - e3w(ji,jj,ikv,Kmm)
182            IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept(ji  ,jj,iku,Kmm)     ! i-direction: case 1
183            ELSE                        ;   zhi(ji,jj) = gdept(ji+1,jj,iku,Kmm)     ! -     -      case 2
184            ENDIF
185            IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept(ji,jj  ,ikv,Kmm)     ! j-direction: case 1
186            ELSE                        ;   zhj(ji,jj) = gdept(ji,jj+1,ikv,Kmm)     ! -     -      case 2
187            ENDIF
188         END_2D
189         !
190         CALL eos( zti, zhi, zri )        ! interpolated density from zti, ztj
191         CALL eos( ztj, zhj, zrj )        ! at the partial step depth output in  zri, zrj
192         !
193         DO_2D( nn_hls, nn_hls-1, nn_hls, nn_hls-1 )              ! Gradient of density at the last level
194            iku = mbku(ji,jj)
195            ikv = mbkv(ji,jj)
196            ze3wu  = e3w(ji+1,jj  ,iku,Kmm) - e3w(ji,jj,iku,Kmm)
197            ze3wv  = e3w(ji  ,jj+1,ikv,Kmm) - e3w(ji,jj,ikv,Kmm)
198            IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = umask(ji,jj,1) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
199            ELSE                        ;   pgru(ji,jj) = umask(ji,jj,1) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
200            ENDIF
201            IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
202            ELSE                        ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
203            ENDIF
204         END_2D
205         IF (nn_hls.EQ.1) CALL lbc_lnk( 'zpshde', pgru , 'U', -1.0_wp , pgrv , 'V', -1.0_wp )   ! Lateral boundary conditions
206         !
207      END IF
208      !
209      IF( ln_timing )   CALL timing_stop( 'zps_hde')
210      !
211   END SUBROUTINE zps_hde_t
212
213
214   SUBROUTINE zps_hde_isf( kt, Kmm, kjpt, pta, pgtu, pgtv, pgtui, pgtvi,  &
215      &                                   prd, pgru, pgrv, pgrui, pgrvi )
216      !!
217      INTEGER                     , INTENT(in   )           ::  kt           ! ocean time-step index
218      INTEGER                     , INTENT(in   )           ::  Kmm          ! ocean time level index
219      INTEGER                     , INTENT(in   )           ::  kjpt         ! number of tracers
220      REAL(wp), DIMENSION(:,:,:,:), INTENT(in   )           ::  pta          ! 4D tracers fields
221      REAL(wp), DIMENSION(:,:,:)  , INTENT(  out)           ::  pgtu, pgtv   ! hor. grad. of ptra at u- & v-pts
222      REAL(wp), DIMENSION(:,:,:)  , INTENT(  out)           ::  pgtui, pgtvi ! hor. grad. of stra at u- & v-pts (ISF)
223      REAL(wp), DIMENSION(:,:,:)  , INTENT(in   ), OPTIONAL ::  prd          ! 3D density anomaly fields
224      REAL(wp), DIMENSION(:,:)    , INTENT(  out), OPTIONAL ::  pgru, pgrv   ! hor. grad of prd at u- & v-pts (bottom)
225      REAL(wp), DIMENSION(:,:)    , INTENT(  out), OPTIONAL ::  pgrui, pgrvi ! hor. grad of prd at u- & v-pts (top)
226      !
227      INTEGER :: itrd, itgr, itgri
228      !!
229      IF( PRESENT(prd)   ) THEN ; itrd  = is_tile(prd)   ; ELSE ; itrd  = 0 ; ENDIF
230      IF( PRESENT(pgru)  ) THEN ; itgr  = is_tile(pgru)  ; ELSE ; itgr  = 0 ; ENDIF
231      IF( PRESENT(pgrui) ) THEN ; itgri = is_tile(pgrui) ; ELSE ; itgri = 0 ; ENDIF
232
233      CALL zps_hde_isf_t( kt, Kmm, kjpt, pta, is_tile(pta), pgtu, pgtv, is_tile(pgtu), pgtui, pgtvi, is_tile(pgtui),  &
234      &                                  prd, itrd,         pgru, pgrv, itgr,          pgrui, pgrvi, itgri )
235   END SUBROUTINE zps_hde_isf
236
237
238   SUBROUTINE zps_hde_isf_t( kt, Kmm, kjpt, pta, ktta, pgtu, pgtv, ktgt, pgtui, pgtvi, ktgti,  &
239      &                                     prd, ktrd, pgru, pgrv, ktgr, pgrui, pgrvi, ktgri )
240      !!----------------------------------------------------------------------
241      !!                     ***  ROUTINE zps_hde_isf  ***
242      !!
243      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
244      !!      at u- and v-points with a linear interpolation for z-coordinate
245      !!      with partial steps for top (ice shelf) and bottom.
246      !!
247      !! ** Method  :   In z-coord with partial steps, scale factors on last
248      !!      levels are different for each grid point, so that T, S and rd
249      !!      points are not at the same depth as in z-coord. To have horizontal
250      !!      gradients again, we interpolate T and S at the good depth :
251      !!      For the bottom case:
252      !!      Linear interpolation of T, S
253      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
254      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
255      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
256      !!         This formulation computes the two cases:
257      !!                 CASE 1                   CASE 2
258      !!         k-1  ___ ___________   k-1   ___ ___________
259      !!                    Ti  T~                  T~  Ti+1
260      !!                  _____                        _____
261      !!         k        |   |Ti+1     k           Ti |   |
262      !!                  |   |____                ____|   |
263      !!              ___ |   |   |           ___  |   |   |
264      !!
265      !!      case 1->   e3w(i+1,j,k,Kmm) >= e3w(i,j,k,Kmm) ( and e3w(i,j+1,k,Kmm) >= e3w(i,j,k,Kmm) ) then
266      !!          t~ = t(i+1,j  ,k) + (e3w(i+1,j  ,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Ti+1)/e3w(i+1,j  ,k,Kmm)
267      !!        ( t~ = t(i  ,j+1,k) + (e3w(i  ,j+1,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Tj+1)/e3w(i  ,j+1,k,Kmm)  )
268      !!          or
269      !!      case 2->   e3w(i+1,j,k,Kmm) <= e3w(i,j,k,Kmm) ( and e3w(i,j+1,k,Kmm) <= e3w(i,j,k,Kmm) ) then
270      !!          t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i+1,j  ,k,Kmm)) * dk(Ti)/e3w(i,j,k,Kmm)
271      !!        ( t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i  ,j+1,k,Kmm)) * dk(Tj)/e3w(i,j,k,Kmm) )
272      !!          Idem for di(s) and dj(s)
273      !!
274      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
275      !!      depth zh from interpolated T and S for the different formulations
276      !!      of the equation of state (eos).
277      !!      Gradient formulation for rho :
278      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
279      !!
280      !!      For the top case (ice shelf): As for the bottom case but upside down
281      !!
282      !! ** Action  : compute for top and bottom interfaces
283      !!              - pgtu, pgtv, pgtui, pgtvi: horizontal gradient of tracer at u- & v-points
284      !!              - pgru, pgrv, pgrui, pgtvi: horizontal gradient of rho (if present) at u- & v-points
285      !!----------------------------------------------------------------------
286      INTEGER                                , INTENT(in   )           ::  kt           ! ocean time-step index
287      INTEGER                                , INTENT(in   )           ::  Kmm          ! ocean time level index
288      INTEGER                                , INTENT(in   )           ::  kjpt         ! number of tracers
289      INTEGER                                , INTENT(in   )           ::  ktta, ktgt, ktgti, ktrd, ktgr, ktgri
290      REAL(wp), DIMENSION(A2D_T(ktta),JPK,KJPT), INTENT(in   )           ::  pta          ! 4D tracers fields
291      REAL(wp), DIMENSION(A2D_T(ktgt)    ,KJPT), INTENT(  out)           ::  pgtu, pgtv   ! hor. grad. of ptra at u- & v-pts
292      REAL(wp), DIMENSION(A2D_T(ktgti)   ,KJPT), INTENT(  out)           ::  pgtui, pgtvi ! hor. grad. of stra at u- & v-pts (ISF)
293      REAL(wp), DIMENSION(A2D_T(ktrd),JPK     ), INTENT(in   ), OPTIONAL ::  prd          ! 3D density anomaly fields
294      REAL(wp), DIMENSION(A2D_T(ktgr)         ), INTENT(  out), OPTIONAL ::  pgru, pgrv   ! hor. grad of prd at u- & v-pts (bottom)
295      REAL(wp), DIMENSION(A2D_T(ktgri)        ), INTENT(  out), OPTIONAL ::  pgrui, pgrvi ! hor. grad of prd at u- & v-pts (top)
296      !
297      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
298      INTEGER  ::   iku, ikv, ikum1, ikvm1,ikup1, ikvp1   ! partial step level (ocean bottom level) at u- and v-points
299      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv             ! temporary scalars
300      REAL(wp), DIMENSION(A2D(nn_hls))      ::  zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
301      REAL(wp), DIMENSION(A2D(nn_hls),kjpt) ::  zti, ztj             !
302      !!----------------------------------------------------------------------
303      !
304      IF( ln_timing )   CALL timing_start( 'zps_hde_isf')
305      !
306      pgtu (:,:,:) = 0._wp   ;   pgtv (:,:,:) =0._wp
307      pgtui(:,:,:) = 0._wp   ;   pgtvi(:,:,:) =0._wp
308      zti  (:,:,:) = 0._wp   ;   ztj  (:,:,:) =0._wp
309      zhi  (:,:  ) = 0._wp   ;   zhj  (:,:  ) =0._wp
310      !
311      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
312         !
313         ! NOTE: [tiling] increase lower bounds for tra_ldf_blp* calculation
314         DO_2D( nn_hls, nn_hls-1, nn_hls, nn_hls-1 )
315
316            iku = mbku(ji,jj); ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
317            ikv = mbkv(ji,jj); ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
318            ze3wu = gdept(ji+1,jj,iku,Kmm) - gdept(ji,jj,iku,Kmm)
319            ze3wv = gdept(ji,jj+1,ikv,Kmm) - gdept(ji,jj,ikv,Kmm)
320            !
321            ! i- direction
322            IF( ze3wu >= 0._wp ) THEN      ! case 1
323               zmaxu =  ze3wu / e3w(ji+1,jj,iku,Kmm)
324               ! interpolated values of tracers
325               zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
326               ! gradient of  tracers
327               pgtu(ji,jj,jn) = ssumask(ji,jj) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
328            ELSE                           ! case 2
329               zmaxu = -ze3wu / e3w(ji,jj,iku,Kmm)
330               ! interpolated values of tracers
331               zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
332               ! gradient of tracers
333               pgtu(ji,jj,jn) = ssumask(ji,jj) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
334            ENDIF
335            !
336            ! j- direction
337            IF( ze3wv >= 0._wp ) THEN      ! case 1
338               zmaxv =  ze3wv / e3w(ji,jj+1,ikv,Kmm)
339               ! interpolated values of tracers
340               ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
341               ! gradient of tracers
342               pgtv(ji,jj,jn) = ssvmask(ji,jj) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
343            ELSE                           ! case 2
344               zmaxv =  -ze3wv / e3w(ji,jj,ikv,Kmm)
345               ! interpolated values of tracers
346               ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
347               ! gradient of tracers
348               pgtv(ji,jj,jn) = ssvmask(ji,jj) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
349            ENDIF
350
351         END_2D
352      END DO
353      !
354      IF (nn_hls.EQ.1) CALL lbc_lnk( 'zpshde', pgtu(:,:,:), 'U', -1.0_wp , pgtv(:,:,:), 'V', -1.0_wp )   ! Lateral boundary cond.
355
356      ! horizontal derivative of density anomalies (rd)
357      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
358         pgru(:,:)=0.0_wp   ; pgrv(:,:)=0.0_wp ;
359         !
360         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
361
362            iku = mbku(ji,jj)
363            ikv = mbkv(ji,jj)
364            ze3wu = gdept(ji+1,jj,iku,Kmm) - gdept(ji,jj,iku,Kmm)
365            ze3wv = gdept(ji,jj+1,ikv,Kmm) - gdept(ji,jj,ikv,Kmm)
366            !
367            IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept(ji  ,jj,iku,Kmm)    ! i-direction: case 1
368            ELSE                        ;   zhi(ji,jj) = gdept(ji+1,jj,iku,Kmm)    ! -     -      case 2
369            ENDIF
370            IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept(ji,jj  ,ikv,Kmm)    ! j-direction: case 1
371            ELSE                        ;   zhj(ji,jj) = gdept(ji,jj+1,ikv,Kmm)    ! -     -      case 2
372            ENDIF
373
374         END_2D
375
376         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
377         ! step and store it in  zri, zrj for each  case
378         CALL eos( zti, zhi, zri )
379         CALL eos( ztj, zhj, zrj )
380
381         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
382            iku = mbku(ji,jj)
383            ikv = mbkv(ji,jj)
384            ze3wu = gdept(ji+1,jj,iku,Kmm) - gdept(ji,jj,iku,Kmm)
385            ze3wv = gdept(ji,jj+1,ikv,Kmm) - gdept(ji,jj,ikv,Kmm)
386
387            IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = ssumask(ji,jj) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
388            ELSE                        ;   pgru(ji,jj) = ssumask(ji,jj) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
389            ENDIF
390            IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = ssvmask(ji,jj) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
391            ELSE                        ;   pgrv(ji,jj) = ssvmask(ji,jj) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
392            ENDIF
393
394         END_2D
395
396         IF (nn_hls.EQ.1) CALL lbc_lnk( 'zpshde', pgru , 'U', -1.0_wp , pgrv , 'V', -1.0_wp )   ! Lateral boundary conditions
397         !
398      END IF
399      !
400      !     !==  (ISH)  compute grui and gruvi  ==!
401      !
402      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!            !
403         ! NOTE: [tiling] increase lower bounds for tra_ldf_blp* calculation
404         DO_2D( nn_hls, nn_hls-1, nn_hls, nn_hls-1 )
405            iku = miku(ji,jj); ikup1 = miku(ji,jj) + 1
406            ikv = mikv(ji,jj); ikvp1 = mikv(ji,jj) + 1
407            !
408            ! (ISF) case partial step top and bottom in adjacent cell in vertical
409            ! cannot used e3w because if 2 cell water column, we have ps at top and bottom
410            ! in this case e3w(i,j,k,Kmm) - e3w(i,j+1,k,Kmm) is not the distance between Tj~ and Tj
411            ! the only common depth between cells (i,j) and (i,j+1) is gdepw_0
412            ze3wu  =  gdept(ji,jj,iku,Kmm) - gdept(ji+1,jj,iku,Kmm)
413            ze3wv  =  gdept(ji,jj,ikv,Kmm) - gdept(ji,jj+1,ikv,Kmm)
414
415            ! i- direction
416            IF( ze3wu >= 0._wp ) THEN      ! case 1
417               zmaxu = ze3wu / e3w(ji+1,jj,ikup1,Kmm)
418               ! interpolated values of tracers
419               zti(ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikup1,jn) - pta(ji+1,jj,iku,jn) )
420               ! gradient of tracers
421               pgtui(ji,jj,jn) = ssumask(ji,jj) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
422            ELSE                           ! case 2
423               zmaxu = - ze3wu / e3w(ji,jj,ikup1,Kmm)
424               ! interpolated values of tracers
425               zti(ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikup1,jn) - pta(ji,jj,iku,jn) )
426               ! gradient of  tracers
427               pgtui(ji,jj,jn) = ssumask(ji,jj) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
428            ENDIF
429            !
430            ! j- direction
431            IF( ze3wv >= 0._wp ) THEN      ! case 1
432               zmaxv =  ze3wv / e3w(ji,jj+1,ikvp1,Kmm)
433               ! interpolated values of tracers
434               ztj(ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvp1,jn) - pta(ji,jj+1,ikv,jn) )
435               ! gradient of tracers
436               pgtvi(ji,jj,jn) = ssvmask(ji,jj) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
437            ELSE                           ! case 2
438               zmaxv =  - ze3wv / e3w(ji,jj,ikvp1,Kmm)
439               ! interpolated values of tracers
440               ztj(ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvp1,jn) - pta(ji,jj,ikv,jn) )
441               ! gradient of tracers
442               pgtvi(ji,jj,jn) = ssvmask(ji,jj) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
443            ENDIF
444
445         END_2D
446         !
447      END DO
448      IF (nn_hls.EQ.1) CALL lbc_lnk( 'zpshde', pgtui(:,:,:), 'U', -1.0_wp , pgtvi(:,:,:), 'V', -1.0_wp )   ! Lateral boundary cond.
449
450      IF( PRESENT( prd ) ) THEN    !==  horizontal derivative of density anomalies (rd)  ==!    (optional part)
451         !
452         pgrui(:,:)  =0.0_wp; pgrvi(:,:)  =0.0_wp;
453         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
454
455            iku = miku(ji,jj)
456            ikv = mikv(ji,jj)
457            ze3wu  =  gdept(ji,jj,iku,Kmm) - gdept(ji+1,jj,iku,Kmm)
458            ze3wv  =  gdept(ji,jj,ikv,Kmm) - gdept(ji,jj+1,ikv,Kmm)
459            !
460            IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept(ji  ,jj,iku,Kmm)    ! i-direction: case 1
461            ELSE                        ;   zhi(ji,jj) = gdept(ji+1,jj,iku,Kmm)    ! -     -      case 2
462            ENDIF
463
464            IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept(ji,jj  ,ikv,Kmm)    ! j-direction: case 1
465            ELSE                        ;   zhj(ji,jj) = gdept(ji,jj+1,ikv,Kmm)    ! -     -      case 2
466            ENDIF
467
468         END_2D
469         !
470         CALL eos( zti, zhi, zri )        ! interpolated density from zti, ztj
471         CALL eos( ztj, zhj, zrj )        ! at the partial step depth output in  zri, zrj
472         !
473         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
474            iku = miku(ji,jj)
475            ikv = mikv(ji,jj)
476            ze3wu  =  gdept(ji,jj,iku,Kmm) - gdept(ji+1,jj,iku,Kmm)
477            ze3wv  =  gdept(ji,jj,ikv,Kmm) - gdept(ji,jj+1,ikv,Kmm)
478
479            IF( ze3wu >= 0._wp ) THEN ; pgrui(ji,jj) = ssumask(ji,jj) * ( zri(ji  ,jj      ) - prd(ji,jj,iku) ) ! i: 1
480            ELSE                      ; pgrui(ji,jj) = ssumask(ji,jj) * ( prd(ji+1,jj  ,iku) - zri(ji,jj    ) ) ! i: 2
481            ENDIF
482            IF( ze3wv >= 0._wp ) THEN ; pgrvi(ji,jj) = ssvmask(ji,jj) * ( zrj(ji  ,jj      ) - prd(ji,jj,ikv) ) ! j: 1
483            ELSE                      ; pgrvi(ji,jj) = ssvmask(ji,jj) * ( prd(ji  ,jj+1,ikv) - zrj(ji,jj    ) ) ! j: 2
484            ENDIF
485
486         END_2D
487         IF (nn_hls.EQ.1) CALL lbc_lnk( 'zpshde', pgrui, 'U', -1.0_wp , pgrvi, 'V', -1.0_wp )   ! Lateral boundary conditions
488         !
489      END IF
490      !
491      IF( ln_timing )   CALL timing_stop( 'zps_hde_isf')
492      !
493   END SUBROUTINE zps_hde_isf_t
494
495   !!======================================================================
496END MODULE zpshde
Note: See TracBrowser for help on using the repository browser.