New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynzdf.F90 in NEMO/branches/2021/dev_r14318_RK3_stage1/src/OCE/DYN – NEMO

source: NEMO/branches/2021/dev_r14318_RK3_stage1/src/OCE/DYN/dynzdf.F90 @ 14618

Last change on this file since 14618 was 14547, checked in by techene, 3 years ago

#2605 RK3 time-stepping on OCE only (run on GYRE_PISCES without key_top)
  • Property svn:keywords set to Id
File size: 25.2 KB
Line 
1MODULE dynzdf
2   !!==============================================================================
3   !!                 ***  MODULE  dynzdf  ***
4   !! Ocean dynamics :  vertical component of the momentum mixing trend
5   !!==============================================================================
6   !! History :  1.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
8   !!            4.0  !  2017-06  (G. Madec) remove the explicit time-stepping option + avm at t-point
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   dyn_zdf       : compute the after velocity through implicit calculation of vertical mixing
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE phycst         ! physical constants
16   USE dom_oce        ! ocean space and time domain variables
17   USE sbc_oce        ! surface boundary condition: ocean
18   USE zdf_oce        ! ocean vertical physics variables
19   USE zdfdrg         ! vertical physics: top/bottom drag coef.
20   USE dynadv    ,ONLY: ln_dynadv_vec    ! dynamics: advection form
21   USE dynldf_iso,ONLY: akzu, akzv       ! dynamics: vertical component of rotated lateral mixing
22   USE ldfdyn         ! lateral diffusion: eddy viscosity coef. and type of operator
23   USE trd_oce        ! trends: ocean variables
24   USE trddyn         ! trend manager: dynamics
25   !
26   USE in_out_manager ! I/O manager
27   USE lib_mpp        ! MPP library
28   USE prtctl         ! Print control
29   USE timing         ! Timing
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   dyn_zdf   !  routine called by step.F90
35
36   REAL(wp) ::  r_vvl     ! non-linear free surface indicator: =0 if ln_linssh=T, =1 otherwise
37
38   !! * Substitutions
39#  include "do_loop_substitute.h90"
40#  include "domzgr_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
43   !! $Id$
44   !! Software governed by the CeCILL license (see ./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47   
48   SUBROUTINE dyn_zdf( kt, Kbb, Kmm, Krhs, puu, pvv, Kaa )
49      !!----------------------------------------------------------------------
50      !!                  ***  ROUTINE dyn_zdf  ***
51      !!
52      !! ** Purpose :   compute the trend due to the vert. momentum diffusion
53      !!              together with the Leap-Frog time stepping using an
54      !!              implicit scheme.
55      !!
56      !! ** Method  :  - Leap-Frog time stepping on all trends but the vertical mixing
57      !!         u(after) =         u(before) + 2*dt *       u(rhs)                vector form or linear free surf.
58      !!         u(after) = ( e3u_b*u(before) + 2*dt * e3u_n*u(rhs) ) / e3u_after   otherwise
59      !!               - update the after velocity with the implicit vertical mixing.
60      !!      This requires to solver the following system:
61      !!         u(after) = u(after) + 1/e3u_after  dk+1[ mi(avm) / e3uw_after dk[ua] ]
62      !!      with the following surface/top/bottom boundary condition:
63      !!      surface: wind stress input (averaged over kt-1/2 & kt+1/2)
64      !!      top & bottom : top stress (iceshelf-ocean) & bottom stress (cf zdfdrg.F90)
65      !!
66      !! ** Action :   (puu(:,:,:,Kaa),pvv(:,:,:,Kaa))   after velocity
67      !!---------------------------------------------------------------------
68      INTEGER                             , INTENT( in )  ::  kt                  ! ocean time-step index
69      INTEGER                             , INTENT( in )  ::  Kbb, Kmm, Krhs, Kaa ! ocean time level indices
70      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv            ! ocean velocities and RHS of momentum equation
71      !
72      INTEGER  ::   ji, jj, jk           ! dummy loop indices
73      INTEGER  ::   iku, ikv             ! local integers
74      REAL(wp) ::   zzwi, ze3ua, zDt_2   ! local scalars
75      REAL(wp) ::   zzws, ze3va          !   -      -
76      REAL(wp) ::   z1_e3ua, z1_e3va     !   -      -
77      REAL(wp) ::   zWu , zWv            !   -      -
78      REAL(wp) ::   zWui, zWvi           !   -      -
79      REAL(wp) ::   zWus, zWvs           !   -      -
80      REAL(wp), DIMENSION(jpi,jpj,jpk)        ::  zwi, zwd, zws   ! 3D workspace
81      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdu, ztrdv   !  -      -
82      !!---------------------------------------------------------------------
83      !
84      IF( ln_timing )   CALL timing_start('dyn_zdf')
85      !
86      IF( kt == nit000 ) THEN       !* initialization
87         IF(lwp) WRITE(numout,*)
88         IF(lwp) WRITE(numout,*) 'dyn_zdf_imp : vertical momentum diffusion implicit operator'
89         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
90         !
91         If( ln_linssh ) THEN   ;    r_vvl = 0._wp    ! non-linear free surface indicator
92         ELSE                   ;    r_vvl = 1._wp
93         ENDIF
94      ENDIF
95      !
96      zDt_2 = rDt * 0.5_wp
97      !
98      !                             !* explicit top/bottom drag case
99      IF( .NOT.ln_drgimp )   CALL zdf_drg_exp( kt, Kmm, puu(:,:,:,Kbb), pvv(:,:,:,Kbb), puu(:,:,:,Krhs), pvv(:,:,:,Krhs) )  ! add top/bottom friction trend to (puu(Kaa),pvv(Kaa))
100      !
101      !
102      IF( l_trddyn )   THEN         !* temporary save of ta and sa trends
103         ALLOCATE( ztrdu(jpi,jpj,jpk), ztrdv(jpi,jpj,jpk) ) 
104         ztrdu(:,:,:) = puu(:,:,:,Krhs)
105         ztrdv(:,:,:) = pvv(:,:,:,Krhs)
106      ENDIF
107      !
108      !              !==  RHS: Leap-Frog time stepping on all trends but the vertical mixing  ==!   (put in puu(:,:,:,Kaa),pvv(:,:,:,Kaa))
109      !
110      !                    ! time stepping except vertical diffusion
111      IF( ln_dynadv_vec .OR. ln_linssh ) THEN   ! applied on velocity
112         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
113            puu(ji,jj,jk,Kaa) = ( puu(ji,jj,jk,Kbb) + rDt * puu(ji,jj,jk,Krhs) ) * umask(ji,jj,jk)
114            pvv(ji,jj,jk,Kaa) = ( pvv(ji,jj,jk,Kbb) + rDt * pvv(ji,jj,jk,Krhs) ) * vmask(ji,jj,jk)
115         END_3D
116      ELSE                                      ! applied on thickness weighted velocity
117         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
118            puu(ji,jj,jk,Kaa) = (         e3u(ji,jj,jk,Kbb) * puu(ji,jj,jk,Kbb )  &
119               &                  + rDt * e3u(ji,jj,jk,Kmm) * puu(ji,jj,jk,Krhs)  ) &
120               &                        / e3u(ji,jj,jk,Kaa) * umask(ji,jj,jk)
121            pvv(ji,jj,jk,Kaa) = (         e3v(ji,jj,jk,Kbb) * pvv(ji,jj,jk,Kbb )  &
122               &                  + rDt * e3v(ji,jj,jk,Kmm) * pvv(ji,jj,jk,Krhs)  ) &
123               &                        / e3v(ji,jj,jk,Kaa) * vmask(ji,jj,jk)
124         END_3D
125      ENDIF
126      !                    ! add top/bottom friction
127      !     With split-explicit free surface, barotropic stress is treated explicitly Update velocities at the bottom.
128      !     J. Chanut: The bottom stress is computed considering after barotropic velocities, which does
129      !                not lead to the effective stress seen over the whole barotropic loop.
130      !     G. Madec : in linear free surface, e3u(:,:,:,Kaa) = e3u(:,:,:,Kmm) = e3u_0, so systematic use of e3u(:,:,:,Kaa)
131      IF( ln_drgimp .AND. ln_dynspg_ts ) THEN
132         DO_3D( 0, 0, 0, 0, 1, jpkm1 )      ! remove barotropic velocities
133            puu(ji,jj,jk,Kaa) = ( puu(ji,jj,jk,Kaa) - uu_b(ji,jj,Kaa) ) * umask(ji,jj,jk)
134            pvv(ji,jj,jk,Kaa) = ( pvv(ji,jj,jk,Kaa) - vv_b(ji,jj,Kaa) ) * vmask(ji,jj,jk)
135         END_3D
136         DO_2D( 0, 0, 0, 0 )      ! Add bottom/top stress due to barotropic component only
137            iku = mbku(ji,jj)         ! ocean bottom level at u- and v-points
138            ikv = mbkv(ji,jj)         ! (deepest ocean u- and v-points)
139            ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,iku,Kmm)    &
140               &             + r_vvl   * e3u(ji,jj,iku,Kaa)
141            ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,ikv,Kmm)    &
142               &             + r_vvl   * e3v(ji,jj,ikv,Kaa)
143            puu(ji,jj,iku,Kaa) = puu(ji,jj,iku,Kaa) + zDt_2 *( rCdU_bot(ji+1,jj)+rCdU_bot(ji,jj) ) * uu_b(ji,jj,Kaa) / ze3ua
144            pvv(ji,jj,ikv,Kaa) = pvv(ji,jj,ikv,Kaa) + zDt_2 *( rCdU_bot(ji,jj+1)+rCdU_bot(ji,jj) ) * vv_b(ji,jj,Kaa) / ze3va
145         END_2D
146         IF( ln_isfcav.OR.ln_drgice_imp ) THEN    ! Ocean cavities (ISF)
147            DO_2D( 0, 0, 0, 0 )
148               iku = miku(ji,jj)         ! top ocean level at u- and v-points
149               ikv = mikv(ji,jj)         ! (first wet ocean u- and v-points)
150               ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,iku,Kmm)    &
151                  &             + r_vvl   * e3u(ji,jj,iku,Kaa)
152               ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,ikv,Kmm)    &
153                  &             + r_vvl   * e3v(ji,jj,ikv,Kaa)
154               puu(ji,jj,iku,Kaa) = puu(ji,jj,iku,Kaa) + zDt_2 *( rCdU_top(ji+1,jj)+rCdU_top(ji,jj) ) * uu_b(ji,jj,Kaa) / ze3ua
155               pvv(ji,jj,ikv,Kaa) = pvv(ji,jj,ikv,Kaa) + zDt_2 *( rCdU_top(ji,jj+1)+rCdU_top(ji,jj) ) * vv_b(ji,jj,Kaa) / ze3va
156            END_2D
157         END IF
158      ENDIF
159      !
160      !              !==  Vertical diffusion on u  ==!
161      !
162      !                    !* Matrix construction
163      IF( ln_zad_Aimp ) THEN   !!
164         SELECT CASE( nldf_dyn )
165         CASE( np_lap_i )           ! rotated lateral mixing: add its vertical mixing (akzu)
166            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
167               ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,jk,Kmm)    &
168                  &             + r_vvl   * e3u(ji,jj,jk,Kaa)   ! after scale factor at U-point
169               zzwi = - zDt_2 * ( avm(ji+1,jj,jk  ) + avm(ji,jj,jk  ) + akzu(ji,jj,jk  ) )   &
170                  &         / ( ze3ua * e3uw(ji,jj,jk  ,Kmm) ) * wumask(ji,jj,jk  )
171               zzws = - zDt_2 * ( avm(ji+1,jj,jk+1) + avm(ji,jj,jk+1) + akzu(ji,jj,jk+1) )   &
172                  &         / ( ze3ua * e3uw(ji,jj,jk+1,Kmm) ) * wumask(ji,jj,jk+1)
173               zWui = ( wi(ji,jj,jk  ) + wi(ji+1,jj,jk  ) ) / ze3ua
174               zWus = ( wi(ji,jj,jk+1) + wi(ji+1,jj,jk+1) ) / ze3ua
175               zwi(ji,jj,jk) = zzwi + zDt_2 * MIN( zWui, 0._wp ) 
176               zws(ji,jj,jk) = zzws - zDt_2 * MAX( zWus, 0._wp )
177               zwd(ji,jj,jk) = 1._wp - zzwi - zzws + zDt_2 * ( MAX( zWui, 0._wp ) - MIN( zWus, 0._wp ) )
178            END_3D
179         CASE DEFAULT               ! iso-level lateral mixing
180            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
181               ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,jk,Kmm)    &    ! after scale factor at U-point
182                  &             + r_vvl   * e3u(ji,jj,jk,Kaa)
183               zzwi = - zDt_2 * ( avm(ji+1,jj,jk  ) + avm(ji,jj,jk  ) )   &
184                  &         / ( ze3ua * e3uw(ji,jj,jk  ,Kmm) ) * wumask(ji,jj,jk  )
185               zzws = - zDt_2 * ( avm(ji+1,jj,jk+1) + avm(ji,jj,jk+1) )   &
186                  &         / ( ze3ua * e3uw(ji,jj,jk+1,Kmm) ) * wumask(ji,jj,jk+1)
187               zWui = ( wi(ji,jj,jk  ) + wi(ji+1,jj,jk  ) ) / ze3ua
188               zWus = ( wi(ji,jj,jk+1) + wi(ji+1,jj,jk+1) ) / ze3ua
189               zwi(ji,jj,jk) = zzwi + zDt_2 * MIN( zWui, 0._wp )
190               zws(ji,jj,jk) = zzws - zDt_2 * MAX( zWus, 0._wp )
191               zwd(ji,jj,jk) = 1._wp - zzwi - zzws + zDt_2 * ( MAX( zWui, 0._wp ) - MIN( zWus, 0._wp ) )
192            END_3D
193         END SELECT
194         DO_2D( 0, 0, 0, 0 )     !* Surface boundary conditions
195            zwi(ji,jj,1) = 0._wp
196            ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,1,Kmm)    &
197               &             + r_vvl   * e3u(ji,jj,1,Kaa)
198            zzws = - zDt_2 * ( avm(ji+1,jj,2) + avm(ji  ,jj,2) )   &
199               &         / ( ze3ua * e3uw(ji,jj,2,Kmm) ) * wumask(ji,jj,2)
200            zWus = ( wi(ji  ,jj,2) +  wi(ji+1,jj,2) ) / ze3ua
201            zws(ji,jj,1 ) = zzws - zDt_2 * MAX( zWus, 0._wp )
202            zwd(ji,jj,1 ) = 1._wp - zzws - zDt_2 * ( MIN( zWus, 0._wp ) )
203         END_2D
204      ELSE
205         SELECT CASE( nldf_dyn )
206         CASE( np_lap_i )           ! rotated lateral mixing: add its vertical mixing (akzu)
207            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
208               ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,jk,Kmm)    &
209                  &             + r_vvl   * e3u(ji,jj,jk,Kaa)   ! after scale factor at U-point
210               zzwi = - zDt_2 * ( avm(ji+1,jj,jk  ) + avm(ji,jj,jk  ) + akzu(ji,jj,jk  ) )   &
211                  &         / ( ze3ua * e3uw(ji,jj,jk  ,Kmm) ) * wumask(ji,jj,jk  )
212               zzws = - zDt_2 * ( avm(ji+1,jj,jk+1) + avm(ji,jj,jk+1) + akzu(ji,jj,jk+1) )   &
213                  &         / ( ze3ua * e3uw(ji,jj,jk+1,Kmm) ) * wumask(ji,jj,jk+1)
214               zwi(ji,jj,jk) = zzwi
215               zws(ji,jj,jk) = zzws
216               zwd(ji,jj,jk) = 1._wp - zzwi - zzws
217            END_3D
218         CASE DEFAULT               ! iso-level lateral mixing
219            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
220               ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,jk,Kmm)    &
221                  &             + r_vvl   * e3u(ji,jj,jk,Kaa)   ! after scale factor at U-point
222               zzwi = - zDt_2 * ( avm(ji+1,jj,jk  ) + avm(ji,jj,jk  ) )    &
223                  &         / ( ze3ua * e3uw(ji,jj,jk  ,Kmm) ) * wumask(ji,jj,jk  )
224               zzws = - zDt_2 * ( avm(ji+1,jj,jk+1) + avm(ji,jj,jk+1) )    &
225                  &         / ( ze3ua * e3uw(ji,jj,jk+1,Kmm) ) * wumask(ji,jj,jk+1)
226               zwi(ji,jj,jk) = zzwi
227               zws(ji,jj,jk) = zzws
228               zwd(ji,jj,jk) = 1._wp - zzwi - zzws
229            END_3D
230         END SELECT
231         DO_2D( 0, 0, 0, 0 )     !* Surface boundary conditions
232            zwi(ji,jj,1) = 0._wp
233            zwd(ji,jj,1) = 1._wp - zws(ji,jj,1)
234         END_2D
235      ENDIF
236      !
237      !
238      !              !==  Apply semi-implicit bottom friction  ==!
239      !
240      !     Only needed for semi-implicit bottom friction setup. The explicit
241      !     bottom friction has been included in "u(v)a" which act as the R.H.S
242      !     column vector of the tri-diagonal matrix equation
243      !
244      IF ( ln_drgimp ) THEN      ! implicit bottom friction
245         DO_2D( 0, 0, 0, 0 )
246            iku = mbku(ji,jj)       ! ocean bottom level at u- and v-points
247            ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,iku,Kmm)    &
248               &             + r_vvl   * e3u(ji,jj,iku,Kaa)   ! after scale factor at T-point
249            zwd(ji,jj,iku) = zwd(ji,jj,iku) - zDt_2 *( rCdU_bot(ji+1,jj)+rCdU_bot(ji,jj) ) / ze3ua
250         END_2D
251         IF ( ln_isfcav.OR.ln_drgice_imp ) THEN   ! top friction (always implicit)
252            DO_2D( 0, 0, 0, 0 )
253               !!gm   top Cd is masked (=0 outside cavities) no need of test on mik>=2  ==>> it has been suppressed
254               iku = miku(ji,jj)       ! ocean top level at u- and v-points
255               ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,iku,Kmm)    &
256                  &             + r_vvl   * e3u(ji,jj,iku,Kaa)   ! after scale factor at T-point
257               zwd(ji,jj,iku) = zwd(ji,jj,iku) - zDt_2 *( rCdU_top(ji+1,jj)+rCdU_top(ji,jj) ) / ze3ua
258            END_2D
259         END IF
260      ENDIF
261      !
262      ! Matrix inversion starting from the first level
263      !-----------------------------------------------------------------------
264      !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
265      !
266      !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
267      !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
268      !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
269      !        (        ...               )( ...  ) ( ...  )
270      !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
271      !
272      !   m is decomposed in the product of an upper and a lower triangular matrix
273      !   The 3 diagonal terms are in 2d arrays: zwd, zws, zwi
274      !   The solution (the after velocity) is in puu(:,:,:,Kaa)
275      !-----------------------------------------------------------------------
276      !
277      DO_3D( 0, 0, 0, 0, 2, jpkm1 )   !==  First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1   (increasing k)  ==
278         zwd(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwd(ji,jj,jk-1)
279      END_3D
280      !
281      DO_2D( 0, 0, 0, 0 )             !==  second recurrence:    SOLk = RHSk - Lk / Dk-1  Lk-1  ==!
282         ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,1,Kmm)    &
283            &             + r_vvl   * e3u(ji,jj,1,Kaa) 
284         puu(ji,jj,1,Kaa) = puu(ji,jj,1,Kaa) + zDt_2 * ( utau_b(ji,jj) + utau(ji,jj) )   &
285            &                                      / ( ze3ua * rho0 ) * umask(ji,jj,1) 
286      END_2D
287      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
288         puu(ji,jj,jk,Kaa) = puu(ji,jj,jk,Kaa) - zwi(ji,jj,jk) / zwd(ji,jj,jk-1) * puu(ji,jj,jk-1,Kaa)
289      END_3D
290      !
291      DO_2D( 0, 0, 0, 0 )             !==  thrid recurrence : SOLk = ( Lk - Uk * Ek+1 ) / Dk  ==!
292         puu(ji,jj,jpkm1,Kaa) = puu(ji,jj,jpkm1,Kaa) / zwd(ji,jj,jpkm1)
293      END_2D
294      DO_3DS( 0, 0, 0, 0, jpk-2, 1, -1 )
295         puu(ji,jj,jk,Kaa) = ( puu(ji,jj,jk,Kaa) - zws(ji,jj,jk) * puu(ji,jj,jk+1,Kaa) ) / zwd(ji,jj,jk)
296      END_3D
297      !
298      !              !==  Vertical diffusion on v  ==!
299      !
300      !                       !* Matrix construction
301      IF( ln_zad_Aimp ) THEN   !!
302         SELECT CASE( nldf_dyn )
303         CASE( np_lap_i )           ! rotated lateral mixing: add its vertical mixing (akzv)
304            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
305               ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,jk,Kmm)    &
306                  &             + r_vvl   * e3v(ji,jj,jk,Kaa)   ! after scale factor at V-point
307               zzwi = - zDt_2 * ( avm(ji,jj+1,jk  ) + avm(ji,jj,jk  ) + akzv(ji,jj,jk  ) )   &
308                  &         / ( ze3va * e3vw(ji,jj,jk  ,Kmm) ) * wvmask(ji,jj,jk  )
309               zzws = - zDt_2 * ( avm(ji,jj+1,jk+1) + avm(ji,jj,jk+1) + akzv(ji,jj,jk+1) )   &
310                  &         / ( ze3va * e3vw(ji,jj,jk+1,Kmm) ) * wvmask(ji,jj,jk+1)
311               zWvi = ( wi(ji,jj,jk  ) + wi(ji,jj+1,jk  ) ) / ze3va
312               zWvs = ( wi(ji,jj,jk+1) + wi(ji,jj+1,jk+1) ) / ze3va
313               zwi(ji,jj,jk) = zzwi + zDt_2 * MIN( zWvi, 0._wp )
314               zws(ji,jj,jk) = zzws - zDt_2 * MAX( zWvs, 0._wp )
315               zwd(ji,jj,jk) = 1._wp - zzwi - zzws - zDt_2 * ( - MAX( zWvi, 0._wp ) + MIN( zWvs, 0._wp ) )
316            END_3D
317         CASE DEFAULT               ! iso-level lateral mixing
318            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
319               ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,jk,Kmm)    &
320                  &             + r_vvl   * e3v(ji,jj,jk,Kaa)   ! after scale factor at V-point
321               zzwi = - zDt_2 * ( avm(ji,jj+1,jk  ) + avm(ji,jj,jk  ) )    &
322                  &         / ( ze3va * e3vw(ji,jj,jk  ,Kmm) ) * wvmask(ji,jj,jk  )
323               zzws = - zDt_2 * ( avm(ji,jj+1,jk+1) + avm(ji,jj,jk+1) )    &
324                  &         / ( ze3va * e3vw(ji,jj,jk+1,Kmm) ) * wvmask(ji,jj,jk+1)
325               zWvi = ( wi(ji,jj,jk  ) + wi(ji,jj+1,jk  ) ) / ze3va
326               zWvs = ( wi(ji,jj,jk+1) + wi(ji,jj+1,jk+1) ) / ze3va
327               zwi(ji,jj,jk) = zzwi  + zDt_2 * MIN( zWvi, 0._wp )
328               zws(ji,jj,jk) = zzws  - zDt_2 * MAX( zWvs, 0._wp )
329               zwd(ji,jj,jk) = 1._wp - zzwi - zzws - zDt_2 * ( - MAX( zWvi, 0._wp ) + MIN( zWvs, 0._wp ) )
330            END_3D
331         END SELECT
332         DO_2D( 0, 0, 0, 0 )   !* Surface boundary conditions
333            zwi(ji,jj,1) = 0._wp
334            ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,1,Kmm)    &
335               &             + r_vvl   * e3v(ji,jj,1,Kaa)
336            zzws = - zDt_2 * ( avm(ji,jj+1,2) + avm(ji,jj,2) )    &
337               &         / ( ze3va * e3vw(ji,jj,2,Kmm) ) * wvmask(ji,jj,2)
338            zWvs = ( wi(ji,jj  ,2) +  wi(ji,jj+1,2) ) / ze3va
339            zws(ji,jj,1 ) = zzws - zDt_2 * MAX( zWvs, 0._wp )
340            zwd(ji,jj,1 ) = 1._wp - zzws - zDt_2 * ( MIN( zWvs, 0._wp ) )
341         END_2D
342      ELSE
343         SELECT CASE( nldf_dyn )
344         CASE( np_lap_i )           ! rotated lateral mixing: add its vertical mixing (akzu)
345            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
346               ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,jk,Kmm)    &
347                  &             + r_vvl   * e3v(ji,jj,jk,Kaa)   ! after scale factor at V-point
348               zzwi = - zDt_2 * ( avm(ji,jj+1,jk  ) + avm(ji,jj,jk  ) + akzv(ji,jj,jk  ) )   &
349                  &         / ( ze3va * e3vw(ji,jj,jk  ,Kmm) ) * wvmask(ji,jj,jk  )
350               zzws = - zDt_2 * ( avm(ji,jj+1,jk+1) + avm(ji,jj,jk+1) + akzv(ji,jj,jk+1) )   &
351                  &         / ( ze3va * e3vw(ji,jj,jk+1,Kmm) ) * wvmask(ji,jj,jk+1)
352               zwi(ji,jj,jk) = zzwi
353               zws(ji,jj,jk) = zzws
354               zwd(ji,jj,jk) = 1._wp - zzwi - zzws
355            END_3D
356         CASE DEFAULT               ! iso-level lateral mixing
357            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
358               ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,jk,Kmm)    &
359                  &             + r_vvl   * e3v(ji,jj,jk,Kaa)   ! after scale factor at V-point
360               zzwi = - zDt_2 * ( avm(ji,jj+1,jk  ) + avm(ji,jj,jk  ) )    &
361                  &         / ( ze3va * e3vw(ji,jj,jk  ,Kmm) ) * wvmask(ji,jj,jk  )
362               zzws = - zDt_2 * ( avm(ji,jj+1,jk+1) + avm(ji,jj,jk+1) )    &
363                  &         / ( ze3va * e3vw(ji,jj,jk+1,Kmm) ) * wvmask(ji,jj,jk+1)
364               zwi(ji,jj,jk) = zzwi
365               zws(ji,jj,jk) = zzws
366               zwd(ji,jj,jk) = 1._wp - zzwi - zzws
367            END_3D
368         END SELECT
369         DO_2D( 0, 0, 0, 0 )        !* Surface boundary conditions
370            zwi(ji,jj,1) = 0._wp
371            zwd(ji,jj,1) = 1._wp - zws(ji,jj,1)
372         END_2D
373      ENDIF
374      !
375      !              !==  Apply semi-implicit top/bottom friction  ==!
376      !
377      !     Only needed for semi-implicit bottom friction setup. The explicit
378      !     bottom friction has been included in "u(v)a" which act as the R.H.S
379      !     column vector of the tri-diagonal matrix equation
380      !
381      IF( ln_drgimp ) THEN
382         DO_2D( 0, 0, 0, 0 )
383            ikv = mbkv(ji,jj)       ! (deepest ocean u- and v-points)
384            ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,ikv,Kmm)    &
385               &             + r_vvl   * e3v(ji,jj,ikv,Kaa)   ! after scale factor at T-point
386            zwd(ji,jj,ikv) = zwd(ji,jj,ikv) - zDt_2*( rCdU_bot(ji,jj+1)+rCdU_bot(ji,jj) ) / ze3va           
387         END_2D
388         IF ( ln_isfcav.OR.ln_drgice_imp ) THEN
389            DO_2D( 0, 0, 0, 0 )
390               ikv = mikv(ji,jj)       ! (first wet ocean u- and v-points)
391               ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,ikv,Kmm)    &
392                  &             + r_vvl   * e3v(ji,jj,ikv,Kaa)   ! after scale factor at T-point
393               zwd(ji,jj,ikv) = zwd(ji,jj,ikv) - zDt_2*( rCdU_top(ji,jj+1)+rCdU_top(ji,jj) ) / ze3va
394            END_2D
395         ENDIF
396      ENDIF
397
398      ! Matrix inversion
399      !-----------------------------------------------------------------------
400      !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
401      !
402      !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
403      !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
404      !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
405      !        (        ...               )( ...  ) ( ...  )
406      !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
407      !
408      !   m is decomposed in the product of an upper and lower triangular matrix
409      !   The 3 diagonal terms are in 2d arrays: zwd, zws, zwi
410      !   The solution (after velocity) is in 2d array va
411      !-----------------------------------------------------------------------
412      !
413      DO_3D( 0, 0, 0, 0, 2, jpkm1 )   !==  First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1   (increasing k)  ==
414         zwd(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwd(ji,jj,jk-1)
415      END_3D
416      !
417      DO_2D( 0, 0, 0, 0 )             !==  second recurrence:    SOLk = RHSk - Lk / Dk-1  Lk-1  ==!
418         ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,1,Kmm)    &
419            &             + r_vvl   * e3v(ji,jj,1,Kaa) 
420         pvv(ji,jj,1,Kaa) = pvv(ji,jj,1,Kaa) + zDt_2*( vtau_b(ji,jj) + vtau(ji,jj) )   &
421            &                                      / ( ze3va * rho0 ) * vmask(ji,jj,1) 
422      END_2D
423      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
424         pvv(ji,jj,jk,Kaa) = pvv(ji,jj,jk,Kaa) - zwi(ji,jj,jk) / zwd(ji,jj,jk-1) * pvv(ji,jj,jk-1,Kaa)
425      END_3D
426      !
427      DO_2D( 0, 0, 0, 0 )             !==  third recurrence : SOLk = ( Lk - Uk * SOLk+1 ) / Dk  ==!
428         pvv(ji,jj,jpkm1,Kaa) = pvv(ji,jj,jpkm1,Kaa) / zwd(ji,jj,jpkm1)
429      END_2D
430      DO_3DS( 0, 0, 0, 0, jpk-2, 1, -1 )
431         pvv(ji,jj,jk,Kaa) = ( pvv(ji,jj,jk,Kaa) - zws(ji,jj,jk) * pvv(ji,jj,jk+1,Kaa) ) / zwd(ji,jj,jk)
432      END_3D
433      !
434      IF( l_trddyn )   THEN                      ! save the vertical diffusive trends for further diagnostics
435         ztrdu(:,:,:) = ( puu(:,:,:,Kaa) - puu(:,:,:,Kbb) )*r1_Dt - ztrdu(:,:,:)
436         ztrdv(:,:,:) = ( pvv(:,:,:,Kaa) - pvv(:,:,:,Kbb) )*r1_Dt - ztrdv(:,:,:)
437         CALL trd_dyn( ztrdu, ztrdv, jpdyn_zdf, kt, Kmm )
438         DEALLOCATE( ztrdu, ztrdv ) 
439      ENDIF
440      !                                          ! print mean trends (used for debugging)
441      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=puu(:,:,:,Kaa), clinfo1=' zdf  - Ua: ', mask1=umask,               &
442         &                                  tab3d_2=pvv(:,:,:,Kaa), clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
443         !
444      IF( ln_timing )   CALL timing_stop('dyn_zdf')
445      !
446   END SUBROUTINE dyn_zdf
447
448   !!==============================================================================
449END MODULE dynzdf
Note: See TracBrowser for help on using the repository browser.