New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv.F90 in NEMO/branches/2021/dev_r14318_RK3_stage1/src/OCE/TRA – NEMO

source: NEMO/branches/2021/dev_r14318_RK3_stage1/src/OCE/TRA/traadv.F90 @ 15193

Last change on this file since 15193 was 15193, checked in by techene, 3 years ago

#2715 comments and cosmetics
  • Property svn:keywords set to Id
File size: 20.2 KB
Line 
1MODULE traadv
2   !!==============================================================================
3   !!                       ***  MODULE  traadv  ***
4   !! Ocean active tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-09  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!            3.6  !  2011-06  (G. Madec)  Addition of Mixed Layer Eddy parameterisation
9   !!            3.7  !  2014-05  (G. Madec)  Add 2nd/4th order cases for CEN and FCT schemes
10   !!             -   !  2014-12  (G. Madec) suppression of cross land advection option
11   !!            3.6  !  2015-06  (E. Clementi) Addition of Stokes drift in case of wave coupling
12   !!            4.5  !  2021-04  (G. Madec, S. Techene) add advective velocities as optional arguments
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   tra_adv       : compute ocean tracer advection trend
17   !!   tra_adv_init  : control the different options of advection scheme
18   !!----------------------------------------------------------------------
19   USE oce            ! ocean dynamics and active tracers
20   USE dom_oce        ! ocean space and time domain
21   ! TEMP: [tiling] This change not necessary after extended haloes development
22   USE domtile
23   USE domvvl         ! variable vertical scale factors
24   USE sbcwave        ! wave module
25   USE sbc_oce        ! surface boundary condition: ocean
26   USE traadv_cen     ! centered scheme            (tra_adv_cen  routine)
27   USE traadv_fct     ! FCT      scheme            (tra_adv_fct  routine)
28   USE traadv_fct_lf  ! FCT      scheme            (tra_adv_fct  routine - loop fusion version)
29   USE traadv_mus     ! MUSCL    scheme            (tra_adv_mus  routine)
30   USE traadv_mus_lf  ! MUSCL    scheme            (tra_adv_mus  routine - loop fusion version)
31   USE traadv_ubs     ! UBS      scheme            (tra_adv_ubs  routine)
32   USE traadv_qck     ! QUICKEST scheme            (tra_adv_qck  routine)
33   USE tramle         ! Mixed Layer Eddy transport (tra_mle_trp  routine)
34   USE ldftra         ! Eddy Induced transport     (ldf_eiv_trp  routine)
35   USE ldfslp         ! Lateral diffusion: slopes of neutral surfaces
36   USE trd_oce        ! trends: ocean variables
37   USE trdtra         ! trends manager: tracers
38   USE diaptr         ! Poleward heat transport
39   !
40   USE in_out_manager ! I/O manager
41   USE iom            ! I/O module
42   USE prtctl         ! Print control
43   USE lib_mpp        ! MPP library
44   USE timing         ! Timing
45
46   IMPLICIT NONE
47   PRIVATE
48
49   PUBLIC   tra_adv        ! called by step.F90, stpmlf.F90 and stprk3_stg.F90
50   PUBLIC   tra_adv_init   ! called by nemogcm.F90
51
52   !                            !!* Namelist namtra_adv *
53   LOGICAL ::   ln_traadv_OFF    ! no advection on T and S
54   LOGICAL ::   ln_traadv_cen    ! centered scheme flag
55   INTEGER ::      nn_cen_h, nn_cen_v   ! =2/4 : horizontal and vertical choices of the order of CEN scheme
56   LOGICAL ::   ln_traadv_fct    ! FCT scheme flag
57   INTEGER ::      nn_fct_h, nn_fct_v   ! =2/4 : horizontal and vertical choices of the order of FCT scheme
58   LOGICAL ::   ln_traadv_mus    ! MUSCL scheme flag
59   LOGICAL ::      ln_mus_ups           ! use upstream scheme in vivcinity of river mouths
60   LOGICAL ::   ln_traadv_ubs    ! UBS scheme flag
61   INTEGER ::      nn_ubs_v             ! =2/4 : vertical choice of the order of UBS scheme
62   LOGICAL ::   ln_traadv_qck    ! QUICKEST scheme flag
63
64   INTEGER ::   nadv             ! choice of the type of advection scheme
65   !                             ! associated indices:
66   INTEGER, PARAMETER ::   np_NO_adv  = 0   ! no T-S advection
67   INTEGER, PARAMETER ::   np_CEN     = 1   ! 2nd/4th order centered scheme
68   INTEGER, PARAMETER ::   np_FCT     = 2   ! 2nd/4th order Flux Corrected Transport scheme
69   INTEGER, PARAMETER ::   np_MUS     = 3   ! MUSCL scheme
70   INTEGER, PARAMETER ::   np_UBS     = 4   ! 3rd order Upstream Biased Scheme
71   INTEGER, PARAMETER ::   np_QCK     = 5   ! QUICK scheme
72
73   !! * Substitutions
74#  include "do_loop_substitute.h90"
75#  include "domzgr_substitute.h90"
76   !!----------------------------------------------------------------------
77   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
78   !! $Id$
79   !! Software governed by the CeCILL license (see ./LICENSE)
80   !!----------------------------------------------------------------------
81CONTAINS
82
83   SUBROUTINE tra_adv( kt, Kbb, Kmm, pts, Krhs, pau, pav, paw )
84      !!----------------------------------------------------------------------
85      !!                  ***  ROUTINE tra_adv  ***
86      !!
87      !! ** Purpose :   compute the ocean tracer advection trend.
88      !!
89      !! ** Method  : - Update ts(Krhs) with the advective trend following nadv
90      !!----------------------------------------------------------------------
91      INTEGER                                     , INTENT(in   ) ::   kt             ! ocean time-step index
92      INTEGER                                     , INTENT(in   ) ::   Kbb, Kmm, Krhs ! time level indices
93      REAL(wp), DIMENSION(:,:,:), OPTIONAL, TARGET, INTENT(in   ) ::   pau, pav, paw  ! advective velocity
94      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt)   , INTENT(inout) ::   pts            ! active tracers and RHS of tracer equation
95      !
96      INTEGER ::   ji, jj, jk   ! dummy loop index
97      REAL(wp), DIMENSION(:,:,:), POINTER ::   zptu, zptv, zptw
98      ! TEMP: [tiling] This change not necessary and can be A2D(nn_hls) if using XIOS (subdomain support)
99      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   zuu, zvv, zww   ! 3D workspace
100      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE       ::   ztrdt, ztrds
101      ! TEMP: [tiling] This change not necessary after extra haloes development
102      LOGICAL ::   lskip
103      !!----------------------------------------------------------------------
104      !
105      IF( ln_timing )   CALL timing_start('tra_adv')
106      !
107      lskip = .FALSE.
108
109      ! TEMP: [tiling] These changes not necessary if using XIOS (subdomain support)
110      IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
111         ALLOCATE( zuu(jpi,jpj,jpk), zvv(jpi,jpj,jpk), zww(jpi,jpj,jpk) )
112      ENDIF
113
114      ! TEMP: [tiling] These changes not necessary after extra haloes development (lbc_lnk removed from tra_adv_*) and if XIOS has subdomain support (ldf_eiv_dia)
115      IF( nadv /= np_CEN .OR. (nadv == np_CEN .AND. nn_cen_h == 4) .OR. ln_ldfeiv_dia )  THEN
116         IF( ln_tile ) THEN
117            IF( ntile == 1 ) THEN
118               CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 )
119            ELSE
120               lskip = .TRUE.
121            ENDIF
122         ENDIF
123      ENDIF
124      !
125      IF( .NOT. lskip ) THEN
126         !                                         !==  effective advective transport  ==!
127         !
128         IF( PRESENT( pau ) ) THEN     ! RK3: advective velocity (pau,pav,paw) /= advected velocity (uu,vv,ww)
129            zptu => pau(:,:,:)
130            zptv => pav(:,:,:)
131            zptw => paw(:,:,:)
132         ELSE                          ! MLF: advective velocity = (uu,vv,ww)
133            zptu => uu(:,:,:,Kmm)
134            zptv => vv(:,:,:,Kmm)
135            zptw => ww(:,:,:    )
136         ENDIF
137         !
138         IF( ln_wave .AND. ln_sdw )  THEN
139            DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
140               zuu(ji,jj,jk) = e2u  (ji,jj) * e3u(ji,jj,jk,Kmm) * ( zptu(ji,jj,jk) + usd(ji,jj,jk) )
141               zvv(ji,jj,jk) = e1v  (ji,jj) * e3v(ji,jj,jk,Kmm) * ( zptv(ji,jj,jk) + vsd(ji,jj,jk) )
142               zww(ji,jj,jk) = e1e2t(ji,jj)                     * ( zptw(ji,jj,jk) + wsd(ji,jj,jk) )
143            END_3D
144         ELSE
145            DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
146               zuu(ji,jj,jk) = e2u  (ji,jj) * e3u(ji,jj,jk,Kmm) * zptu(ji,jj,jk)               ! eulerian transport only
147               zvv(ji,jj,jk) = e1v  (ji,jj) * e3v(ji,jj,jk,Kmm) * zptv(ji,jj,jk)
148               zww(ji,jj,jk) = e1e2t(ji,jj)                     * zptw(ji,jj,jk)
149            END_3D
150         ENDIF
151         !
152         IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN                                ! add z-tilde and/or vvl corrections
153            DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
154               zuu(ji,jj,jk) = zuu(ji,jj,jk) + un_td(ji,jj,jk)
155               zvv(ji,jj,jk) = zvv(ji,jj,jk) + vn_td(ji,jj,jk)
156            END_3D
157         ENDIF
158         !
159!!st the do loop below should be useless ==>> to be checked
160         DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
161            zuu(ji,jj,jpk) = 0._wp                                                      ! no transport trough the bottom
162            zvv(ji,jj,jpk) = 0._wp
163            zww(ji,jj,jpk) = 0._wp
164         END_2D
165         !
166         ! TEMP: [tiling] These changes not necessary if using XIOS (subdomain support)
167         IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad )   &
168            &              CALL ldf_eiv_trp( kt, nit000, zuu(A2D(nn_hls),:), zvv(A2D(nn_hls),:), zww(A2D(nn_hls),:), &
169            &                                'TRA', Kmm, Krhs )   ! add the eiv transport (if necessary)
170         !
171         IF( ln_mle    )   CALL tra_mle_trp( kt, nit000, zuu(A2D(nn_hls),:), zvv(A2D(nn_hls),:), zww(A2D(nn_hls),:), &
172            &                                'TRA', Kmm       )   ! add the mle transport (if necessary)
173         !
174         ! TEMP: [tiling] This change not necessary if using XIOS (subdomain support)
175         IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only on the last tile
176            CALL iom_put( "uocetr_eff", zuu )                                        ! output effective transport
177            CALL iom_put( "vocetr_eff", zvv )
178            CALL iom_put( "wocetr_eff", zww )
179         ENDIF
180         !
181   !!gm ???
182         ! TEMP: [tiling] This change not necessary if using XIOS (subdomain support)
183         CALL dia_ptr( kt, Kmm, zvv(A2D(nn_hls),:) )                                    ! diagnose the effective MSF
184   !!gm ???
185         !
186
187         IF( l_trdtra )   THEN                    !* Save ta and sa trends
188            ALLOCATE( ztrdt(jpi,jpj,jpk), ztrds(jpi,jpj,jpk) )
189            ztrdt(:,:,:) = pts(:,:,:,jp_tem,Krhs)
190            ztrds(:,:,:) = pts(:,:,:,jp_sal,Krhs)
191         ENDIF
192         !
193         SELECT CASE ( nadv )                      !==  compute advection trend and add it to general trend  ==!
194         !
195         CASE ( np_CEN )                                 ! Centered scheme : 2nd / 4th order
196            IF( nn_hls == 2 ) CALL lbc_lnk( 'traadv', pts(:,:,:,:,Kmm), 'T', 1._wp )
197            CALL tra_adv_cen    ( kt, nit000, 'TRA',         zuu, zvv, zww, Kmm, pts, jpts, Krhs, nn_cen_h, nn_cen_v )
198         CASE ( np_FCT )                                 ! FCT scheme      : 2nd / 4th order
199            IF( nn_hls == 2 ) THEN
200               CALL lbc_lnk_multi( 'traadv', pts(:,:,:,:,Kbb), 'T', 1._wp, pts(:,:,:,:,Kmm), 'T', 1._wp)
201               CALL lbc_lnk_multi( 'traadv', zuu(:,:,:), 'U', -1._wp, zvv(:,:,:), 'V', -1._wp, zww(:,:,:), 'W', 1._wp)
202#if defined key_loop_fusion
203               CALL tra_adv_fct_lf ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, nn_fct_h, nn_fct_v )
204#else
205               CALL tra_adv_fct    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, nn_fct_h, nn_fct_v )
206#endif
207            ELSE
208               CALL tra_adv_fct    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, nn_fct_h, nn_fct_v )
209            END IF
210         CASE ( np_MUS )                                 ! MUSCL
211            IF( nn_hls == 2 ) THEN
212                CALL lbc_lnk( 'traadv', pts(:,:,:,:,Kbb), 'T', 1._wp)
213#if defined key_loop_fusion
214                CALL tra_adv_mus_lf ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, ln_mus_ups )
215#else
216                CALL tra_adv_mus    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, ln_mus_ups )
217#endif
218            ELSE
219                CALL tra_adv_mus    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, ln_mus_ups )
220            END IF
221         CASE ( np_UBS )                                 ! UBS
222            IF( nn_hls == 2)   CALL lbc_lnk( 'traadv', pts(:,:,:,:,Kbb), 'T', 1._wp)
223            CALL tra_adv_ubs    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, nn_ubs_v   )
224         CASE ( np_QCK )                                 ! QUICKEST
225            IF( nn_hls == 2 ) THEN
226               CALL lbc_lnk_multi( 'traadv', zuu(:,:,:), 'U', -1._wp, zvv(:,:,:), 'V', -1._wp)
227               CALL lbc_lnk( 'traadv', pts(:,:,:,:,Kbb), 'T', 1._wp)
228            END IF
229            CALL tra_adv_qck    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs )
230         !
231         END SELECT
232         !
233         IF( l_trdtra )   THEN                      ! save the advective trends for further diagnostics
234            DO jk = 1, jpkm1
235               ztrdt(:,:,jk) = pts(:,:,jk,jp_tem,Krhs) - ztrdt(:,:,jk)
236               ztrds(:,:,jk) = pts(:,:,jk,jp_sal,Krhs) - ztrds(:,:,jk)
237            END DO
238            CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_totad, ztrdt )
239            CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_totad, ztrds )
240            DEALLOCATE( ztrdt, ztrds )
241         ENDIF
242
243         ! TEMP: [tiling] This change not necessary after extra haloes development (lbc_lnk removed from tra_adv_*) and if XIOS has subdomain support (ldf_eiv_dia)
244         IF( ln_tile .AND. ntile == 0 ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 1 )
245
246      ENDIF
247      !                                              ! print mean trends (used for debugging)
248      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Krhs), clinfo1=' adv  - Ta: ', mask1=tmask, &
249         &                                  tab3d_2=pts(:,:,:,jp_sal,Krhs), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
250
251      ! TEMP: [tiling] This change not necessary if using XIOS (subdomain support)
252      IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only for the full domain
253         DEALLOCATE( zuu, zvv, zww )
254      ENDIF
255      !
256      IF( ln_timing )   CALL timing_stop( 'tra_adv' )
257      !
258   END SUBROUTINE tra_adv
259
260
261   SUBROUTINE tra_adv_init
262      !!---------------------------------------------------------------------
263      !!                  ***  ROUTINE tra_adv_init  ***
264      !!
265      !! ** Purpose :   Control the consistency between namelist options for
266      !!              tracer advection schemes and set nadv
267      !!----------------------------------------------------------------------
268      INTEGER ::   ioptio, ios   ! Local integers
269      !
270      NAMELIST/namtra_adv/ ln_traadv_OFF,                        &   ! No advection
271         &                 ln_traadv_cen , nn_cen_h, nn_cen_v,   &   ! CEN
272         &                 ln_traadv_fct , nn_fct_h, nn_fct_v,   &   ! FCT
273         &                 ln_traadv_mus , ln_mus_ups,           &   ! MUSCL
274         &                 ln_traadv_ubs ,           nn_ubs_v,   &   ! UBS
275         &                 ln_traadv_qck                             ! QCK
276      !!----------------------------------------------------------------------
277      !
278      !                                !==  Namelist  ==!
279      READ  ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
280901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtra_adv in reference namelist' )
281      !
282      READ  ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
283902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtra_adv in configuration namelist' )
284      IF(lwm) WRITE( numond, namtra_adv )
285      !
286      IF(lwp) THEN                           ! Namelist print
287         WRITE(numout,*)
288         WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
289         WRITE(numout,*) '~~~~~~~~~~~~'
290         WRITE(numout,*) '   Namelist namtra_adv : chose a advection scheme for tracers'
291         WRITE(numout,*) '      No advection on T & S                     ln_traadv_OFF = ', ln_traadv_OFF
292         WRITE(numout,*) '      centered scheme                           ln_traadv_cen = ', ln_traadv_cen
293         WRITE(numout,*) '            horizontal 2nd/4th order               nn_cen_h   = ', nn_cen_h
294         WRITE(numout,*) '            vertical   2nd/4th order               nn_cen_v   = ', nn_cen_v
295         WRITE(numout,*) '      Flux Corrected Transport scheme           ln_traadv_fct = ', ln_traadv_fct
296         WRITE(numout,*) '            horizontal 2nd/4th order               nn_fct_h   = ', nn_fct_h
297         WRITE(numout,*) '            vertical   2nd/4th order               nn_fct_v   = ', nn_fct_v
298         WRITE(numout,*) '      MUSCL scheme                              ln_traadv_mus = ', ln_traadv_mus
299         WRITE(numout,*) '            + upstream scheme near river mouths    ln_mus_ups = ', ln_mus_ups
300         WRITE(numout,*) '      UBS scheme                                ln_traadv_ubs = ', ln_traadv_ubs
301         WRITE(numout,*) '            vertical   2nd/4th order               nn_ubs_v   = ', nn_ubs_v
302         WRITE(numout,*) '      QUICKEST scheme                           ln_traadv_qck = ', ln_traadv_qck
303      ENDIF
304      !
305      !                                !==  Parameter control & set nadv ==!
306      ioptio = 0
307      IF( ln_traadv_OFF ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_NO_adv   ;   ENDIF
308      IF( ln_traadv_cen ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_CEN      ;   ENDIF
309      IF( ln_traadv_fct ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_FCT      ;   ENDIF
310      IF( ln_traadv_mus ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_MUS      ;   ENDIF
311      IF( ln_traadv_ubs ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_UBS      ;   ENDIF
312      IF( ln_traadv_qck ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_QCK      ;   ENDIF
313      !
314      IF( ioptio /= 1 )   CALL ctl_stop( 'tra_adv_init: Choose ONE advection option in namelist namtra_adv' )
315      !
316      IF( ln_traadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 )   &          ! Centered
317                        .AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 )   ) THEN
318        CALL ctl_stop( 'tra_adv_init: CEN scheme, choose 2nd or 4th order' )
319      ENDIF
320      IF( ln_traadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 )   &          ! FCT
321                        .AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 )   ) THEN
322        CALL ctl_stop( 'tra_adv_init: FCT scheme, choose 2nd or 4th order' )
323      ENDIF
324      IF( ln_traadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 )   ) THEN     ! UBS
325        CALL ctl_stop( 'tra_adv_init: UBS scheme, choose 2nd or 4th order' )
326      ENDIF
327      IF( ln_traadv_ubs .AND. nn_ubs_v == 4 ) THEN
328         CALL ctl_warn( 'tra_adv_init: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
329      ENDIF
330      IF( ln_isfcav ) THEN                                                       ! ice-shelf cavities
331         IF(  ln_traadv_cen .AND. nn_cen_v == 4    .OR.   &                            ! NO 4th order with ISF
332            & ln_traadv_fct .AND. nn_fct_v == 4   )   CALL ctl_stop( 'tra_adv_init: 4th order COMPACT scheme not allowed with ISF' )
333      ENDIF
334      !
335      !                                !==  Print the choice  ==!
336      IF(lwp) THEN
337         WRITE(numout,*)
338         SELECT CASE ( nadv )
339         CASE( np_NO_adv  )   ;   WRITE(numout,*) '   ==>>>   NO T-S advection'
340         CASE( np_CEN     )   ;   WRITE(numout,*) '   ==>>>   CEN      scheme is used. Horizontal order: ', nn_cen_h,   &
341            &                                                                        ' Vertical   order: ', nn_cen_v
342         CASE( np_FCT     )   ;   WRITE(numout,*) '   ==>>>   FCT      scheme is used. Horizontal order: ', nn_fct_h,   &
343            &                                                                        ' Vertical   order: ', nn_fct_v
344         CASE( np_MUS     )   ;   WRITE(numout,*) '   ==>>>   MUSCL    scheme is used'
345         CASE( np_UBS     )   ;   WRITE(numout,*) '   ==>>>   UBS      scheme is used'
346         CASE( np_QCK     )   ;   WRITE(numout,*) '   ==>>>   QUICKEST scheme is used'
347         END SELECT
348      ENDIF
349      !
350      CALL tra_mle_init            !== initialisation of the Mixed Layer Eddy parametrisation (MLE)  ==!
351      !
352   END SUBROUTINE tra_adv_init
353
354  !!======================================================================
355END MODULE traadv
Note: See TracBrowser for help on using the repository browser.