New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv.F90 in NEMO/branches/2021/dev_r14318_RK3_stage1/src/OCE/TRA – NEMO

source: NEMO/branches/2021/dev_r14318_RK3_stage1/src/OCE/TRA/traadv.F90 @ 15514

Last change on this file since 15514 was 15514, checked in by techene, 3 years ago

#2605 #2715 debug
  • Property svn:keywords set to Id
File size: 20.3 KB
Line 
1MODULE traadv
2   !!==============================================================================
3   !!                       ***  MODULE  traadv  ***
4   !! Ocean active tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-09  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!            3.6  !  2011-06  (G. Madec)  Addition of Mixed Layer Eddy parameterisation
9   !!            3.7  !  2014-05  (G. Madec)  Add 2nd/4th order cases for CEN and FCT schemes
10   !!             -   !  2014-12  (G. Madec) suppression of cross land advection option
11   !!            3.6  !  2015-06  (E. Clementi) Addition of Stokes drift in case of wave coupling
12   !!            4.5  !  2021-04  (G. Madec, S. Techene) add advective velocities as optional arguments
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   tra_adv       : compute ocean tracer advection trend
17   !!   tra_adv_init  : control the different options of advection scheme
18   !!----------------------------------------------------------------------
19   USE oce            ! ocean dynamics and active tracers
20   USE dom_oce        ! ocean space and time domain
21   ! TEMP: [tiling] This change not necessary after extended haloes development
22   USE domtile
23   USE domvvl         ! variable vertical scale factors
24   USE sbcwave        ! wave module
25   USE sbc_oce        ! surface boundary condition: ocean
26   USE traadv_cen     ! centered scheme            (tra_adv_cen  routine)
27   USE traadv_fct     ! FCT      scheme            (tra_adv_fct  routine)
28   USE traadv_fct_lf  ! FCT      scheme            (tra_adv_fct  routine - loop fusion version)
29   USE traadv_mus     ! MUSCL    scheme            (tra_adv_mus  routine)
30   USE traadv_mus_lf  ! MUSCL    scheme            (tra_adv_mus  routine - loop fusion version)
31   USE traadv_ubs     ! UBS      scheme            (tra_adv_ubs  routine)
32   USE traadv_qck     ! QUICKEST scheme            (tra_adv_qck  routine)
33   USE tramle         ! Mixed Layer Eddy transport (tra_mle_trp  routine)
34   USE ldftra         ! Eddy Induced transport     (ldf_eiv_trp  routine)
35   USE ldfslp         ! Lateral diffusion: slopes of neutral surfaces
36   USE trd_oce        ! trends: ocean variables
37   USE trdtra         ! trends manager: tracers
38   USE diaptr         ! Poleward heat transport
39   !
40   USE in_out_manager ! I/O manager
41   USE iom            ! I/O module
42   USE prtctl         ! Print control
43   USE lib_mpp        ! MPP library
44   USE timing         ! Timing
45
46   IMPLICIT NONE
47   PRIVATE
48
49   PUBLIC   tra_adv        ! called by step.F90, stpmlf.F90 and stprk3_stg.F90
50   PUBLIC   tra_adv_init   ! called by nemogcm.F90
51
52   !                            !!* Namelist namtra_adv *
53   LOGICAL ::   ln_traadv_OFF    ! no advection on T and S
54   LOGICAL ::   ln_traadv_cen    ! centered scheme flag
55   INTEGER ::      nn_cen_h, nn_cen_v   ! =2/4 : horizontal and vertical choices of the order of CEN scheme
56   LOGICAL ::   ln_traadv_fct    ! FCT scheme flag
57   INTEGER ::      nn_fct_h, nn_fct_v   ! =2/4 : horizontal and vertical choices of the order of FCT scheme
58   LOGICAL ::   ln_traadv_mus    ! MUSCL scheme flag
59   LOGICAL ::      ln_mus_ups           ! use upstream scheme in vivcinity of river mouths
60   LOGICAL ::   ln_traadv_ubs    ! UBS scheme flag
61   INTEGER ::      nn_ubs_v             ! =2/4 : vertical choice of the order of UBS scheme
62   LOGICAL ::   ln_traadv_qck    ! QUICKEST scheme flag
63
64   INTEGER ::   nadv             ! choice of the type of advection scheme
65   !                             ! associated indices:
66   INTEGER, PARAMETER ::   np_NO_adv  = 0   ! no T-S advection
67   INTEGER, PARAMETER ::   np_CEN     = 1   ! 2nd/4th order centered scheme
68   INTEGER, PARAMETER ::   np_FCT     = 2   ! 2nd/4th order Flux Corrected Transport scheme
69   INTEGER, PARAMETER ::   np_MUS     = 3   ! MUSCL scheme
70   INTEGER, PARAMETER ::   np_UBS     = 4   ! 3rd order Upstream Biased Scheme
71   INTEGER, PARAMETER ::   np_QCK     = 5   ! QUICK scheme
72
73   !! * Substitutions
74#  include "do_loop_substitute.h90"
75#  include "domzgr_substitute.h90"
76   !!----------------------------------------------------------------------
77   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
78   !! $Id$
79   !! Software governed by the CeCILL license (see ./LICENSE)
80   !!----------------------------------------------------------------------
81CONTAINS
82
83   SUBROUTINE tra_adv( kt, Kbb, Kmm, pts, Krhs, pau, pav, paw )
84      !!----------------------------------------------------------------------
85      !!                  ***  ROUTINE tra_adv  ***
86      !!
87      !! ** Purpose :   compute the ocean tracer advection trend.
88      !!
89      !! ** Method  : - Update ts(Krhs) with the advective trend following nadv
90      !!----------------------------------------------------------------------
91      INTEGER                                     , INTENT(in   ) ::   kt             ! ocean time-step index
92      INTEGER                                     , INTENT(in   ) ::   Kbb, Kmm, Krhs ! time level indices
93      REAL(wp), DIMENSION(:,:,:), OPTIONAL, TARGET, INTENT(in   ) ::   pau, pav, paw  ! advective velocity
94      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt)   , INTENT(inout) ::   pts            ! active tracers and RHS of tracer equation
95      !
96      INTEGER ::   ji, jj, jk   ! dummy loop index
97      REAL(wp), DIMENSION(:,:,:), POINTER ::   zptu, zptv, zptw
98      ! TEMP: [tiling] This change not necessary and can be A2D(nn_hls) if using XIOS (subdomain support)
99      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   zuu, zvv, zww   ! 3D workspace
100      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE       ::   ztrdt, ztrds
101      ! TEMP: [tiling] This change not necessary after extra haloes development
102      LOGICAL ::   lskip
103      !!----------------------------------------------------------------------
104      !
105      IF( ln_timing )   CALL timing_start('tra_adv')
106      !
107      lskip = .FALSE.
108
109      ! TEMP: [tiling] These changes not necessary if using XIOS (subdomain support)
110      IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
111         ALLOCATE( zuu(jpi,jpj,jpk), zvv(jpi,jpj,jpk), zww(jpi,jpj,jpk) )
112      ENDIF
113
114      ! TEMP: [tiling] These changes not necessary after extra haloes development (lbc_lnk removed from tra_adv_*) and if XIOS has subdomain support (ldf_eiv_dia)
115      IF( nadv /= np_CEN .OR. (nadv == np_CEN .AND. nn_cen_h == 4) .OR. ln_ldfeiv_dia )  THEN
116         IF( ln_tile ) THEN
117            IF( ntile == 1 ) THEN
118               CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 )
119            ELSE
120               lskip = .TRUE.
121            ENDIF
122         ENDIF
123      ENDIF
124      !
125      IF( .NOT. lskip ) THEN
126         !                                         !==  effective advective transport  ==!
127         !
128         IF( PRESENT( pau ) ) THEN     ! RK3: advective velocity (pau,pav,paw) /= advected velocity (uu,vv,ww)
129            zptu => pau(:,:,:)
130            zptv => pav(:,:,:)
131            zptw => paw(:,:,:)
132         ELSE                          ! MLF: advective velocity = (uu,vv,ww)
133            zptu => uu(:,:,:,Kmm)
134            zptv => vv(:,:,:,Kmm)
135            zptw => ww(:,:,:    )
136         ENDIF
137         !
138         IF( ln_wave .AND. ln_sdw )  THEN
139            DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
140               zuu(ji,jj,jk) = e2u  (ji,jj) * e3u(ji,jj,jk,Kmm) * ( zptu(ji,jj,jk) + usd(ji,jj,jk) )
141               zvv(ji,jj,jk) = e1v  (ji,jj) * e3v(ji,jj,jk,Kmm) * ( zptv(ji,jj,jk) + vsd(ji,jj,jk) )
142               zww(ji,jj,jk) = e1e2t(ji,jj)                     * ( zptw(ji,jj,jk) + wsd(ji,jj,jk) )
143            END_3D
144         ELSE
145            DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
146               zuu(ji,jj,jk) = e2u  (ji,jj) * e3u(ji,jj,jk,Kmm) * zptu(ji,jj,jk)               ! eulerian transport only
147               zvv(ji,jj,jk) = e1v  (ji,jj) * e3v(ji,jj,jk,Kmm) * zptv(ji,jj,jk)
148               zww(ji,jj,jk) = e1e2t(ji,jj)                     * zptw(ji,jj,jk)
149            END_3D
150         ENDIF
151         !
152         IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN                                ! add z-tilde and/or vvl corrections
153            DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
154               zuu(ji,jj,jk) = zuu(ji,jj,jk) + un_td(ji,jj,jk)
155               zvv(ji,jj,jk) = zvv(ji,jj,jk) + vn_td(ji,jj,jk)
156            END_3D
157         ENDIF
158         !
159!!st the do loop below should be useless ==>> to be checked
160         DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
161            zuu(ji,jj,jpk) = 0._wp                                                      ! no transport trough the bottom
162            zvv(ji,jj,jpk) = 0._wp
163            zww(ji,jj,jpk) = 0._wp
164         END_2D
165         !
166         ! TEMP: [tiling] These changes not necessary if using XIOS (subdomain support)
167         IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad )   &
168            &              CALL ldf_eiv_trp( kt, nit000, zuu(A2D(nn_hls),:), zvv(A2D(nn_hls),:), zww(A2D(nn_hls),:), &
169            &                                'TRA', Kmm, Krhs )   ! add the eiv transport (if necessary)
170         !
171         IF( ln_mle    )   CALL tra_mle_trp( kt, nit000, zuu(A2D(nn_hls),:), zvv(A2D(nn_hls),:), zww(A2D(nn_hls),:), &
172            &                                'TRA', Kmm       )   ! add the mle transport (if necessary)
173         !
174         ! TEMP: [tiling] This change not necessary if using XIOS (subdomain support)
175         IF( l_iom ) THEN
176            IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only on the last tile
177               CALL iom_put( "uocetr_eff", zuu )                                        ! output effective transport
178               CALL iom_put( "vocetr_eff", zvv )
179               CALL iom_put( "wocetr_eff", zww )
180            ENDIF
181         ENDIF
182         !
183   !!gm ???
184         ! TEMP: [tiling] This change not necessary if using XIOS (subdomain support)
185         IF( l_diaptr ) CALL dia_ptr( kt, Kmm, zvv(A2D(nn_hls),:) )                                    ! diagnose the effective MSF
186   !!gm ???
187         !
188
189         IF( l_trdtra )   THEN                    !* Save ta and sa trends
190            ALLOCATE( ztrdt(jpi,jpj,jpk), ztrds(jpi,jpj,jpk) )
191            ztrdt(:,:,:) = pts(:,:,:,jp_tem,Krhs)
192            ztrds(:,:,:) = pts(:,:,:,jp_sal,Krhs)
193         ENDIF
194         !
195         SELECT CASE ( nadv )                      !==  compute advection trend and add it to general trend  ==!
196         !
197         CASE ( np_CEN )                                 ! Centered scheme : 2nd / 4th order
198            IF( nn_hls == 2 ) CALL lbc_lnk( 'traadv', pts(:,:,:,:,Kmm), 'T', 1._wp )
199            CALL tra_adv_cen    ( kt, nit000, 'TRA',         zuu, zvv, zww, Kmm, pts, jpts, Krhs, nn_cen_h, nn_cen_v )
200         CASE ( np_FCT )                                 ! FCT scheme      : 2nd / 4th order
201            IF( nn_hls == 2 ) THEN
202               CALL lbc_lnk_multi( 'traadv', pts(:,:,:,:,Kbb), 'T', 1._wp, pts(:,:,:,:,Kmm), 'T', 1._wp)
203               CALL lbc_lnk_multi( 'traadv', zuu(:,:,:), 'U', -1._wp, zvv(:,:,:), 'V', -1._wp, zww(:,:,:), 'W', 1._wp)
204#if defined key_loop_fusion
205               CALL tra_adv_fct_lf ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, nn_fct_h, nn_fct_v )
206#else
207               CALL tra_adv_fct    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, nn_fct_h, nn_fct_v )
208#endif
209            ELSE
210               CALL tra_adv_fct    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, nn_fct_h, nn_fct_v )
211            END IF
212         CASE ( np_MUS )                                 ! MUSCL
213            IF( nn_hls == 2 ) THEN
214                CALL lbc_lnk( 'traadv', pts(:,:,:,:,Kbb), 'T', 1._wp)
215#if defined key_loop_fusion
216                CALL tra_adv_mus_lf ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, ln_mus_ups )
217#else
218                CALL tra_adv_mus    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, ln_mus_ups )
219#endif
220            ELSE
221                CALL tra_adv_mus    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, ln_mus_ups )
222            END IF
223         CASE ( np_UBS )                                 ! UBS
224            IF( nn_hls == 2)   CALL lbc_lnk( 'traadv', pts(:,:,:,:,Kbb), 'T', 1._wp)
225            CALL tra_adv_ubs    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, nn_ubs_v   )
226         CASE ( np_QCK )                                 ! QUICKEST
227            IF( nn_hls == 2 ) THEN
228               CALL lbc_lnk_multi( 'traadv', zuu(:,:,:), 'U', -1._wp, zvv(:,:,:), 'V', -1._wp)
229               CALL lbc_lnk( 'traadv', pts(:,:,:,:,Kbb), 'T', 1._wp)
230            END IF
231            CALL tra_adv_qck    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs )
232         !
233         END SELECT
234         !
235         IF( l_trdtra )   THEN                      ! save the advective trends for further diagnostics
236            DO jk = 1, jpkm1
237               ztrdt(:,:,jk) = pts(:,:,jk,jp_tem,Krhs) - ztrdt(:,:,jk)
238               ztrds(:,:,jk) = pts(:,:,jk,jp_sal,Krhs) - ztrds(:,:,jk)
239            END DO
240            CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_totad, ztrdt )
241            CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_totad, ztrds )
242            DEALLOCATE( ztrdt, ztrds )
243         ENDIF
244
245         ! TEMP: [tiling] This change not necessary after extra haloes development (lbc_lnk removed from tra_adv_*) and if XIOS has subdomain support (ldf_eiv_dia)
246         IF( ln_tile .AND. ntile == 0 ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 1 )
247
248      ENDIF
249      !                                              ! print mean trends (used for debugging)
250      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Krhs), clinfo1=' adv  - Ta: ', mask1=tmask, &
251         &                                  tab3d_2=pts(:,:,:,jp_sal,Krhs), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
252
253      ! TEMP: [tiling] This change not necessary if using XIOS (subdomain support)
254      IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only for the full domain
255         DEALLOCATE( zuu, zvv, zww )
256      ENDIF
257      !
258      IF( ln_timing )   CALL timing_stop( 'tra_adv' )
259      !
260   END SUBROUTINE tra_adv
261
262
263   SUBROUTINE tra_adv_init
264      !!---------------------------------------------------------------------
265      !!                  ***  ROUTINE tra_adv_init  ***
266      !!
267      !! ** Purpose :   Control the consistency between namelist options for
268      !!              tracer advection schemes and set nadv
269      !!----------------------------------------------------------------------
270      INTEGER ::   ioptio, ios   ! Local integers
271      !
272      NAMELIST/namtra_adv/ ln_traadv_OFF,                        &   ! No advection
273         &                 ln_traadv_cen , nn_cen_h, nn_cen_v,   &   ! CEN
274         &                 ln_traadv_fct , nn_fct_h, nn_fct_v,   &   ! FCT
275         &                 ln_traadv_mus , ln_mus_ups,           &   ! MUSCL
276         &                 ln_traadv_ubs ,           nn_ubs_v,   &   ! UBS
277         &                 ln_traadv_qck                             ! QCK
278      !!----------------------------------------------------------------------
279      !
280      !                                !==  Namelist  ==!
281      READ  ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
282901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtra_adv in reference namelist' )
283      !
284      READ  ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
285902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtra_adv in configuration namelist' )
286      IF(lwm) WRITE( numond, namtra_adv )
287      !
288      IF(lwp) THEN                           ! Namelist print
289         WRITE(numout,*)
290         WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
291         WRITE(numout,*) '~~~~~~~~~~~~'
292         WRITE(numout,*) '   Namelist namtra_adv : chose a advection scheme for tracers'
293         WRITE(numout,*) '      No advection on T & S                     ln_traadv_OFF = ', ln_traadv_OFF
294         WRITE(numout,*) '      centered scheme                           ln_traadv_cen = ', ln_traadv_cen
295         WRITE(numout,*) '            horizontal 2nd/4th order               nn_cen_h   = ', nn_cen_h
296         WRITE(numout,*) '            vertical   2nd/4th order               nn_cen_v   = ', nn_cen_v
297         WRITE(numout,*) '      Flux Corrected Transport scheme           ln_traadv_fct = ', ln_traadv_fct
298         WRITE(numout,*) '            horizontal 2nd/4th order               nn_fct_h   = ', nn_fct_h
299         WRITE(numout,*) '            vertical   2nd/4th order               nn_fct_v   = ', nn_fct_v
300         WRITE(numout,*) '      MUSCL scheme                              ln_traadv_mus = ', ln_traadv_mus
301         WRITE(numout,*) '            + upstream scheme near river mouths    ln_mus_ups = ', ln_mus_ups
302         WRITE(numout,*) '      UBS scheme                                ln_traadv_ubs = ', ln_traadv_ubs
303         WRITE(numout,*) '            vertical   2nd/4th order               nn_ubs_v   = ', nn_ubs_v
304         WRITE(numout,*) '      QUICKEST scheme                           ln_traadv_qck = ', ln_traadv_qck
305      ENDIF
306      !
307      !                                !==  Parameter control & set nadv ==!
308      ioptio = 0
309      IF( ln_traadv_OFF ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_NO_adv   ;   ENDIF
310      IF( ln_traadv_cen ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_CEN      ;   ENDIF
311      IF( ln_traadv_fct ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_FCT      ;   ENDIF
312      IF( ln_traadv_mus ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_MUS      ;   ENDIF
313      IF( ln_traadv_ubs ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_UBS      ;   ENDIF
314      IF( ln_traadv_qck ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_QCK      ;   ENDIF
315      !
316      IF( ioptio /= 1 )   CALL ctl_stop( 'tra_adv_init: Choose ONE advection option in namelist namtra_adv' )
317      !
318      IF( ln_traadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 )   &          ! Centered
319                        .AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 )   ) THEN
320        CALL ctl_stop( 'tra_adv_init: CEN scheme, choose 2nd or 4th order' )
321      ENDIF
322      IF( ln_traadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 )   &          ! FCT
323                        .AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 )   ) THEN
324        CALL ctl_stop( 'tra_adv_init: FCT scheme, choose 2nd or 4th order' )
325      ENDIF
326      IF( ln_traadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 )   ) THEN     ! UBS
327        CALL ctl_stop( 'tra_adv_init: UBS scheme, choose 2nd or 4th order' )
328      ENDIF
329      IF( ln_traadv_ubs .AND. nn_ubs_v == 4 ) THEN
330         CALL ctl_warn( 'tra_adv_init: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
331      ENDIF
332      IF( ln_isfcav ) THEN                                                       ! ice-shelf cavities
333         IF(  ln_traadv_cen .AND. nn_cen_v == 4    .OR.   &                            ! NO 4th order with ISF
334            & ln_traadv_fct .AND. nn_fct_v == 4   )   CALL ctl_stop( 'tra_adv_init: 4th order COMPACT scheme not allowed with ISF' )
335      ENDIF
336      !
337      !                                !==  Print the choice  ==!
338      IF(lwp) THEN
339         WRITE(numout,*)
340         SELECT CASE ( nadv )
341         CASE( np_NO_adv  )   ;   WRITE(numout,*) '   ==>>>   NO T-S advection'
342         CASE( np_CEN     )   ;   WRITE(numout,*) '   ==>>>   CEN      scheme is used. Horizontal order: ', nn_cen_h,   &
343            &                                                                        ' Vertical   order: ', nn_cen_v
344         CASE( np_FCT     )   ;   WRITE(numout,*) '   ==>>>   FCT      scheme is used. Horizontal order: ', nn_fct_h,   &
345            &                                                                        ' Vertical   order: ', nn_fct_v
346         CASE( np_MUS     )   ;   WRITE(numout,*) '   ==>>>   MUSCL    scheme is used'
347         CASE( np_UBS     )   ;   WRITE(numout,*) '   ==>>>   UBS      scheme is used'
348         CASE( np_QCK     )   ;   WRITE(numout,*) '   ==>>>   QUICKEST scheme is used'
349         END SELECT
350      ENDIF
351      !
352      CALL tra_mle_init            !== initialisation of the Mixed Layer Eddy parametrisation (MLE)  ==!
353      !
354   END SUBROUTINE tra_adv_init
355
356  !!======================================================================
357END MODULE traadv
Note: See TracBrowser for help on using the repository browser.