New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trasbc.F90 in NEMO/branches/2021/dev_r14318_RK3_stage1/src/OCE/TRA – NEMO

source: NEMO/branches/2021/dev_r14318_RK3_stage1/src/OCE/TRA/trasbc.F90 @ 14784

Last change on this file since 14784 was 14784, checked in by techene, 3 years ago

#2605 : enable diahsb and fix rnf forcing accordingly
  • Property svn:keywords set to Id
File size: 12.8 KB
Line 
1MODULE trasbc
2   !!==============================================================================
3   !!                       ***  MODULE  trasbc  ***
4   !! Ocean active tracers:  surface boundary condition
5   !!==============================================================================
6   !! History :  OPA  !  1998-10  (G. Madec, G. Roullet, M. Imbard)  Original code
7   !!            8.2  !  2001-02  (D. Ludicone)  sea ice and free surface
8   !!  NEMO      1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
10   !!             -   !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!            3.6  !  2014-11  (P. Mathiot) isf melting forcing
12   !!            4.1  !  2019-09  (P. Mathiot) isf moved in traisf
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   tra_sbc       : update the tracer trend at ocean surface
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE sbc_oce        ! surface boundary condition: ocean
20   USE dom_oce        ! ocean space domain variables
21   USE phycst         ! physical constant
22   USE eosbn2         ! Equation Of State
23   USE sbcmod         ! ln_rnf
24   USE sbcrnf         ! River runoff
25   USE traqsr         ! solar radiation penetration
26   USE trd_oce        ! trends: ocean variables
27   USE trdtra         ! trends manager: tracers
28#if defined key_asminc
29   USE asminc         ! Assimilation increment
30#endif
31   !
32   USE in_out_manager ! I/O manager
33   USE prtctl         ! Print control
34   USE iom            ! xIOS server
35   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
36   USE timing         ! Timing
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC   tra_sbc   ! routine called by step.F90
42
43   !! * Substitutions
44#  include "do_loop_substitute.h90"
45#  include "domzgr_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
48   !! $Id$
49   !! Software governed by the CeCILL license (see ./LICENSE)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE tra_sbc ( kt, Kmm, pts, Krhs, kstg )
54      !!----------------------------------------------------------------------
55      !!                  ***  ROUTINE tra_sbc  ***
56      !!
57      !! ** Purpose :   Compute the tracer surface boundary condition trend of
58      !!      (flux through the interface, concentration/dilution effect)
59      !!      and add it to the general trend of tracer equations.
60      !!
61      !! ** Method :   The (air+ice)-sea flux has two components:
62      !!      (1) Fext, external forcing (i.e. flux through the (air+ice)-sea interface);
63      !!      (2) Fwe , tracer carried with the water that is exchanged with air+ice.
64      !!               The input forcing fields (emp, rnf, sfx) contain Fext+Fwe,
65      !!             they are simply added to the tracer trend (ts(Krhs)).
66      !!               In linear free surface case (ln_linssh=T), the volume of the
67      !!             ocean does not change with the water exchanges at the (air+ice)-sea
68      !!             interface. Therefore another term has to be added, to mimic the
69      !!             concentration/dilution effect associated with water exchanges.
70      !!
71      !! ** Action  : - Update ts(Krhs) with the surface boundary condition trend
72      !!              - send trends to trdtra module for further diagnostics(l_trdtra=T)
73      !!----------------------------------------------------------------------
74      INTEGER,                                   INTENT(in   ) ::   kt, Kmm, Krhs   ! ocean time-step and time-level indices
75      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) ::   pts             ! active tracers and RHS of tracer Eq.
76      INTEGER , OPTIONAL                       , INTENT(in   ) ::   kstg            ! RK3 stage index
77      !
78      INTEGER  ::   ji, jj, jk, jn               ! dummy loop indices
79      INTEGER  ::   istg_1, istg_3               ! local integers
80      INTEGER  ::   ikt, ikb, isi, iei, isj, iej !   -       -
81      REAL(wp) ::   zfact, z1_e3t, zdep, ztim    ! local scalar
82      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  ztrdt, ztrds
83      !!----------------------------------------------------------------------
84      !
85      IF( ln_timing )   CALL timing_start('tra_sbc')
86      !
87      IF( PRESENT( kstg ) ) THEN      ! RK3 : a few things have to be done at only a specific stage
88         istg_1 = kstg   ;   istg_3 = kstg
89      ELSE                            ! MLF : only one call by time step
90         istg_1 =   1    ;   istg_3 =   3
91      ENDIF
92      !
93      IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
94         IF( kt == nit000 ) THEN
95            IF(lwp) WRITE(numout,*)
96            IF(lwp) WRITE(numout,*) 'tra_sbc : TRAcer Surface Boundary Condition'
97            IF(lwp) WRITE(numout,*) '~~~~~~~ '
98         ENDIF
99      ENDIF
100      !
101      IF( l_trdtra ) THEN                    !* Save ta and sa trends
102         ALLOCATE( ztrdt(jpi,jpj,jpk), ztrds(jpi,jpj,jpk) )
103         ztrdt(:,:,:) = pts(:,:,:,jp_tem,Krhs)
104         ztrds(:,:,:) = pts(:,:,:,jp_sal,Krhs)
105      ENDIF
106      !
107      IF( ntsi == Nis0 ) THEN ; isi = nn_hls ; ELSE ; isi = 0 ; ENDIF    ! Avoid double-counting when using tiling
108      IF( ntsj == Njs0 ) THEN ; isj = nn_hls ; ELSE ; isj = 0 ; ENDIF
109      IF( ntei == Nie0 ) THEN ; iei = nn_hls ; ELSE ; iei = 0 ; ENDIF
110      IF( ntej == Nje0 ) THEN ; iej = nn_hls ; ELSE ; iej = 0 ; ENDIF
111
112!!gm  This should be moved into sbcmod.F90 module ? (especially now that ln_traqsr is read in namsbc namelist)
113      IF( .NOT.ln_traqsr .AND. istg_1 == 1 ) THEN     ! no solar radiation penetration (RK3: only at stage 1)
114         DO_2D( isi, iei, isj, iej )
115            qns(ji,jj) = qns(ji,jj) + qsr(ji,jj)         ! total heat flux in qns
116            qsr(ji,jj) = 0._wp                           ! qsr set to zero
117         END_2D
118      ENDIF
119
120      !----------------------------------------
121      !        EMP, SFX and QNS effects
122      !----------------------------------------
123      !                             !==  Set before sbc tracer content fields  ==!
124      IF( kt == nit000 .AND. istg_1 == 1 ) THEN             !* 1st time-step
125         IF( ln_rstart .AND. .NOT.l_1st_euler ) THEN      ! Restart: read in restart file
126            zfact = 0.5_wp
127            IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
128               IF(lwp) WRITE(numout,*) '          nit000-1 sbc tracer content field read in the restart file'
129               sbc_tsc(:,:,:) = 0._wp
130               CALL iom_get( numror, jpdom_auto, 'sbc_hc_b', sbc_tsc_b(:,:,jp_tem) )   ! before heat content sbc trend
131               CALL iom_get( numror, jpdom_auto, 'sbc_sc_b', sbc_tsc_b(:,:,jp_sal) )   ! before salt content sbc trend
132            ENDIF
133         ELSE                                             ! No restart or restart not found: Euler forward time stepping
134            zfact = 1._wp
135            DO_2D( isi, iei, isj, iej )
136               sbc_tsc(ji,jj,:) = 0._wp
137               sbc_tsc_b(ji,jj,:) = 0._wp
138            END_2D
139         ENDIF
140      ELSEIF( istg_3 == 3 ) THEN          !* other time-steps: swap of forcing fields (RK3: only at stage 3)
141         zfact = 0.5_wp
142         DO_2D( isi, iei, isj, iej )
143            sbc_tsc_b(ji,jj,:) = sbc_tsc(ji,jj,:)
144         END_2D
145      ENDIF
146      !                             !==  Now sbc tracer content fields  ==!
147      DO_2D( isi, iei, isj, iej )
148         sbc_tsc(ji,jj,jp_tem) = r1_rho0_rcp * qns(ji,jj)   ! non solar heat flux
149         sbc_tsc(ji,jj,jp_sal) = r1_rho0     * sfx(ji,jj)   ! salt flux due to freezing/melting
150      END_2D
151      IF( ln_linssh ) THEN                !* linear free surface
152         DO_2D( isi, iei, isj, iej )                    !==>> add concentration/dilution effect due to constant volume cell
153            sbc_tsc(ji,jj,jp_tem) = sbc_tsc(ji,jj,jp_tem) + r1_rho0 * emp(ji,jj) * pts(ji,jj,1,jp_tem,Kmm)
154            sbc_tsc(ji,jj,jp_sal) = sbc_tsc(ji,jj,jp_sal) + r1_rho0 * emp(ji,jj) * pts(ji,jj,1,jp_sal,Kmm)
155         END_2D                                 !==>> output c./d. term
156         IF( ntile == 0 .OR. ntile == nijtile )  THEN             ! Do only on the last tile
157            IF( iom_use('emp_x_sst') )   CALL iom_put( "emp_x_sst", emp (:,:) * pts(:,:,1,jp_tem,Kmm) )
158            IF( iom_use('emp_x_sss') )   CALL iom_put( "emp_x_sss", emp (:,:) * pts(:,:,1,jp_sal,Kmm) )
159         ENDIF
160      ENDIF
161      !
162      DO jn = 1, jpts               !==  update tracer trend  ==!
163         DO_2D( 0, 0, 0, 0 )
164            pts(ji,jj,1,jn,Krhs) = pts(ji,jj,1,jn,Krhs) + zfact * ( sbc_tsc_b(ji,jj,jn) + sbc_tsc(ji,jj,jn) )    &
165               &                                                / e3t(ji,jj,1,Kmm)
166         END_2D
167      END DO
168      !
169      IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only on the last tile
170         IF( lrst_oce ) THEN           !==  write sbc_tsc in the ocean restart file  ==!
171            CALL iom_rstput( kt, nitrst, numrow, 'sbc_hc_b', sbc_tsc(:,:,jp_tem) )
172            CALL iom_rstput( kt, nitrst, numrow, 'sbc_sc_b', sbc_tsc(:,:,jp_sal) )
173         ENDIF
174      ENDIF
175      !
176      !----------------------------------------
177      !        River Runoff effects
178      !----------------------------------------
179      !
180      IF( ln_rnf ) THEN         ! input of heat and salt due to river runoff
181         zfact = 0.5_wp
182         DO_2D( 0, 0, 0, 0 )
183            IF( rnf(ji,jj) /= 0._wp ) THEN
184!!st - Jerome               zdep = zfact / h_rnf(ji,jj)
185#if defined key_RK3
186               zdep = 1._wp / h_rnf(ji,jj)
187               DO jk = 1, nk_rnf(ji,jj)
188                                     pts(ji,jj,jk,jp_tem,Krhs) = pts(ji,jj,jk,jp_tem,Krhs)  + rnf_tsc(ji,jj,jp_tem) * zdep
189                  IF( ln_rnf_sal )   pts(ji,jj,jk,jp_sal,Krhs) = pts(ji,jj,jk,jp_sal,Krhs)  + rnf_tsc(ji,jj,jp_sal) * zdep
190               END DO
191
192#else
193               zdep = zfact / h_rnf(ji,jj)
194               DO jk = 1, nk_rnf(ji,jj)
195                                     pts(ji,jj,jk,jp_tem,Krhs) = pts(ji,jj,jk,jp_tem,Krhs)                                  &
196                                        &                      +  ( rnf_tsc_b(ji,jj,jp_tem) + rnf_tsc(ji,jj,jp_tem) ) * zdep
197                  IF( ln_rnf_sal )   pts(ji,jj,jk,jp_sal,Krhs) = pts(ji,jj,jk,jp_sal,Krhs)                                  &
198                                        &                      +  ( rnf_tsc_b(ji,jj,jp_sal) + rnf_tsc(ji,jj,jp_sal) ) * zdep
199               END DO
200#endif
201!!st
202            ENDIF
203         END_2D
204      ENDIF
205
206      IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only on the last tile
207         IF( iom_use('rnf_x_sst') )   CALL iom_put( "rnf_x_sst", rnf*pts(:,:,1,jp_tem,Kmm) )   ! runoff term on sst
208         IF( iom_use('rnf_x_sss') )   CALL iom_put( "rnf_x_sss", rnf*pts(:,:,1,jp_sal,Kmm) )   ! runoff term on sss
209      ENDIF
210
211#if defined key_asminc
212      !
213      !----------------------------------------
214      !        Assmilation effects
215      !----------------------------------------
216      !
217      IF( ln_sshinc ) THEN         ! input of heat and salt due to assimilation
218          !
219         IF( ln_linssh ) THEN
220            DO_2D( 0, 0, 0, 0 )
221               ztim = ssh_iau(ji,jj) / e3t(ji,jj,1,Kmm)
222               pts(ji,jj,1,jp_tem,Krhs) = pts(ji,jj,1,jp_tem,Krhs) + pts(ji,jj,1,jp_tem,Kmm) * ztim
223               pts(ji,jj,1,jp_sal,Krhs) = pts(ji,jj,1,jp_sal,Krhs) + pts(ji,jj,1,jp_sal,Kmm) * ztim
224            END_2D
225         ELSE
226            DO_2D( 0, 0, 0, 0 )
227               ztim = ssh_iau(ji,jj) / ( ht(ji,jj) + 1. - ssmask(ji, jj) )
228               pts(ji,jj,:,jp_tem,Krhs) = pts(ji,jj,:,jp_tem,Krhs) + pts(ji,jj,:,jp_tem,Kmm) * ztim
229               pts(ji,jj,:,jp_sal,Krhs) = pts(ji,jj,:,jp_sal,Krhs) + pts(ji,jj,:,jp_sal,Kmm) * ztim
230            END_2D
231         ENDIF
232         !
233      ENDIF
234      !
235#endif
236      !
237      IF( l_trdtra )   THEN                      ! save the horizontal diffusive trends for further diagnostics
238         ztrdt(:,:,:) = pts(:,:,:,jp_tem,Krhs) - ztrdt(:,:,:)
239         ztrds(:,:,:) = pts(:,:,:,jp_sal,Krhs) - ztrds(:,:,:)
240         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_nsr, ztrdt )
241         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_nsr, ztrds )
242         DEALLOCATE( ztrdt , ztrds )
243      ENDIF
244      !
245      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Krhs), clinfo1=' sbc  - Ta: ', mask1=tmask,   &
246         &                                  tab3d_2=pts(:,:,:,jp_sal,Krhs), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
247      !
248      IF( ln_timing )   CALL timing_stop('tra_sbc')
249      !
250   END SUBROUTINE tra_sbc
251
252   !!======================================================================
253END MODULE trasbc
Note: See TracBrowser for help on using the repository browser.