New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcadv.F90 in NEMO/branches/2021/dev_r14318_RK3_stage1/src/TOP/TRP – NEMO

source: NEMO/branches/2021/dev_r14318_RK3_stage1/src/TOP/TRP/trcadv.F90 @ 15574

Last change on this file since 15574 was 15574, checked in by techene, 3 years ago

#2605 #2715 trunk merged into dev_r14318_RK3_stage1
  • Property svn:keywords set to Id
File size: 15.6 KB
Line 
1MODULE trcadv
2   !!==============================================================================
3   !!                       ***  MODULE  trcadv  ***
4   !! Ocean passive tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.0  !  2010-06  (C. Ethe)   Adapted to passive tracers
8   !!            3.7  !  2014-05  (G. Madec, C. Ethe)  Add 2nd/4th order cases for CEN and FCT schemes
9   !!            4.0  !  2017-09  (G. Madec)  remove vertical time-splitting option
10   !!            4.5  !  2021-08  (G. Madec, S. Techene) add advective velocities as optional arguments
11   !!----------------------------------------------------------------------
12#if defined key_top
13   !!----------------------------------------------------------------------
14   !!   'key_top'                                                TOP models
15   !!----------------------------------------------------------------------
16   !!   trc_adv       : compute ocean tracer advection trend
17   !!   trc_adv_ini   : control the different options of advection scheme
18   !!----------------------------------------------------------------------
19   USE par_trc        ! need jptra, number of passive tracers
20   USE oce_trc        ! ocean dynamics and active tracers
21   USE trc            ! ocean passive tracers variables
22   USE sbcwave        ! wave module
23   USE sbc_oce        ! surface boundary condition: ocean
24   USE traadv_cen     ! centered scheme           (tra_adv_cen  routine)
25   USE traadv_fct     ! FCT      scheme           (tra_adv_fct  routine)
26   USE traadv_mus     ! MUSCL    scheme           (tra_adv_mus  routine)
27   USE traadv_ubs     ! UBS      scheme           (tra_adv_ubs  routine)
28   USE traadv_qck     ! QUICKEST scheme           (tra_adv_qck  routine)
29   USE tramle         ! ML eddy induced transport (tra_adv_mle  routine)
30   USE ldftra         ! lateral diffusion: eddy diffusivity & EIV coeff.
31   USE ldfslp         ! Lateral diffusion: slopes of neutral surfaces
32   !
33   USE prtctl         ! control print
34   USE timing         ! Timing
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   trc_adv       ! called by trctrp.F90 and stprk3_stg.F90
40   PUBLIC   trc_adv_ini   ! called by trcini.F90
41
42   !                            !!* Namelist namtrc_adv *
43   LOGICAL ::   ln_trcadv_OFF    ! no advection on passive tracers
44   LOGICAL ::   ln_trcadv_cen    ! centered scheme flag
45   INTEGER ::      nn_cen_h, nn_cen_v   ! =2/4 : horizontal and vertical choices of the order of CEN scheme
46   LOGICAL ::   ln_trcadv_fct    ! FCT scheme flag
47   INTEGER ::      nn_fct_h, nn_fct_v   ! =2/4 : horizontal and vertical choices of the order of FCT scheme
48   LOGICAL, PUBLIC ::   ln_trcadv_mus    ! MUSCL scheme flag
49   LOGICAL ::      ln_mus_ups           ! use upstream scheme in vivcinity of river mouths
50   LOGICAL ::   ln_trcadv_ubs    ! UBS scheme flag
51   INTEGER ::      nn_ubs_v             ! =2/4 : vertical choice of the order of UBS scheme
52   LOGICAL ::   ln_trcadv_qck    ! QUICKEST scheme flag
53
54   INTEGER ::   nadv             ! choice of the type of advection scheme
55   !                             ! associated indices:
56   INTEGER, PARAMETER ::   np_NO_adv  = 0   ! no T-S advection
57   INTEGER, PARAMETER ::   np_CEN     = 1   ! 2nd/4th order centered scheme
58   INTEGER, PARAMETER ::   np_FCT     = 2   ! 2nd/4th order Flux Corrected Transport scheme
59   INTEGER, PARAMETER ::   np_MUS     = 3   ! MUSCL scheme
60   INTEGER, PARAMETER ::   np_UBS     = 4   ! 3rd order Upstream Biased Scheme
61   INTEGER, PARAMETER ::   np_QCK     = 5   ! QUICK scheme
62
63   !! * Substitutions
64#  include "do_loop_substitute.h90"
65   !! * Substitutions
66#  include "do_loop_substitute.h90"
67#  include "domzgr_substitute.h90"
68   !!----------------------------------------------------------------------
69   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
70   !! $Id$
71   !! Software governed by the CeCILL license (see ./LICENSE)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE trc_adv( kt, Kbb, Kmm, ptr, Krhs, pau, pav, paw )
76      !!----------------------------------------------------------------------
77      !!                  ***  ROUTINE trc_adv  ***
78      !!
79      !! ** Purpose :   compute the ocean tracer advection trend.
80      !!
81      !! ** Method  : - Update tr(Krhs) with the advective trend following nadv
82      !!----------------------------------------------------------------------
83      INTEGER                                     , INTENT(in   ) ::   kt             ! ocean time-step index
84      INTEGER                                     , INTENT(in   ) ::   Kbb, Kmm, Krhs ! time level indices
85      REAL(wp), DIMENSION(:,:,:), OPTIONAL, TARGET, INTENT(in   ) ::   pau, pav, paw  ! advective velocity
86      REAL(wp), DIMENSION(jpi,jpj,jpk,jptra,jpt)  , INTENT(inout) ::   ptr            ! passive tracers and RHS of tracer equation
87      !
88      INTEGER ::   ji, jj, jk   ! dummy loop index
89      CHARACTER (len=22) ::   charout
90      REAL(wp), DIMENSION(:,:,:), POINTER ::   zptu, zptv, zptw
91      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zuu, zvv, zww  ! effective velocity
92      !!----------------------------------------------------------------------
93      !
94      IF( ln_timing )   CALL timing_start('trc_adv')
95      !
96      !                                         !==  effective transport  ==!
97      IF( l_offline ) THEN
98         DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpk )
99            zuu(ji,jj,jk) = uu(ji,jj,jk,Kmm)             ! already in (uu(Kmm),vv(Kmm),ww)
100            zvv(ji,jj,jk) = vv(ji,jj,jk,Kmm)
101         END_3D
102         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpk )
103            zww(ji,jj,jk) = ww(ji,jj,jk)
104         END_3D
105      ELSE                                         ! build the effective transport
106         DO_2D( nn_hls, nn_hls-1, nn_hls, nn_hls-1 )
107            zuu(ji,jj,jpk) = 0._wp
108            zvv(ji,jj,jpk) = 0._wp
109         END_2D
110         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
111            zww(ji,jj,jpk) = 0._wp
112         END_2D
113         !
114         IF( PRESENT( pau ) ) THEN                       ! RK3: advective velocity (pau,pav,paw) /= advected velocity (uu,vv,ww)
115            zptu => pau(:,:,:)
116            zptv => pav(:,:,:)
117            zptw => paw(:,:,:)
118         ELSE                                            ! MLF: advective velocity = (uu,vv,ww)
119            zptu => uu(:,:,:,Kmm)
120            zptv => vv(:,:,:,Kmm)
121            zptw => ww(:,:,:    )
122         ENDIF
123         !
124         IF( ln_wave .AND. ln_sdw )  THEN
125            DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )                            ! eulerian transport + Stokes Drift
126               zuu(ji,jj,jk) = e2u  (ji,jj) * e3u(ji,jj,jk,Kmm) * ( zptu(ji,jj,jk) + usd(ji,jj,jk) )
127               zvv(ji,jj,jk) = e1v  (ji,jj) * e3v(ji,jj,jk,Kmm) * ( zptv(ji,jj,jk) + vsd(ji,jj,jk) )
128            END_3D
129            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )
130               zww(ji,jj,jk) = e1e2t(ji,jj)                     * ( zptw(ji,jj,jk) + wsd(ji,jj,jk) )
131            END_3D
132         ELSE
133            DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
134               zuu(ji,jj,jk) = e2u  (ji,jj) * e3u(ji,jj,jk,Kmm) * zptu(ji,jj,jk)           ! eulerian transport
135               zvv(ji,jj,jk) = e1v  (ji,jj) * e3v(ji,jj,jk,Kmm) * zptv(ji,jj,jk)
136            END_3D
137            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )
138               zww(ji,jj,jk) = e1e2t(ji,jj)                     * zptw(ji,jj,jk)
139            END_3D
140         ENDIF
141         !
142         IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN                                          ! add z-tilde and/or vvl corrections
143            DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
144               zuu(ji,jj,jk) = zuu(ji,jj,jk) + un_td(ji,jj,jk)
145               zvv(ji,jj,jk) = zvv(ji,jj,jk) + vn_td(ji,jj,jk)
146            END_3D
147         ENDIF
148         !
149         IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad )   & 
150            &              CALL ldf_eiv_trp( kt, nittrc000, zuu, zvv, zww, 'TRC', Kmm, Krhs )  ! add the eiv transport
151         !
152         IF( ln_mle    )   CALL tra_mle_trp( kt, nittrc000, zuu, zvv, zww, 'TRC', Kmm       )  ! add the mle transport
153         !
154      ENDIF
155      !
156      SELECT CASE ( nadv )                      !==  compute advection trend and add it to general trend  ==!
157      !
158      CASE ( np_CEN )                                 ! Centered : 2nd / 4th order
159         CALL tra_adv_cen   ( kt, nittrc000,'TRC',          zuu, zvv, zww,      Kmm, ptr, jptra, Krhs, nn_cen_h, nn_cen_v )
160      CASE ( np_FCT )                                 ! FCT      : 2nd / 4th order
161            CALL tra_adv_fct( kt, nittrc000,'TRC', rDt_trc, zuu, zvv, zww, Kbb, Kmm, ptr, jptra, Krhs, nn_fct_h, nn_fct_v )
162      CASE ( np_MUS )                                 ! MUSCL
163            CALL tra_adv_mus( kt, nittrc000,'TRC', rDt_trc, zuu, zvv, zww, Kbb, Kmm, ptr, jptra, Krhs, ln_mus_ups         )
164      CASE ( np_UBS )                                 ! UBS
165         CALL tra_adv_ubs   ( kt, nittrc000,'TRC', rDt_trc, zuu, zvv, zww, Kbb, Kmm, ptr, jptra, Krhs, nn_ubs_v           )
166      CASE ( np_QCK )                                 ! QUICKEST
167         CALL tra_adv_qck   ( kt, nittrc000,'TRC', rDt_trc, zuu, zvv, zww, Kbb, Kmm, ptr, jptra, Krhs                     )
168      !
169      END SELECT
170      !                 
171      IF( sn_cfctl%l_prttrc ) THEN        !== print mean trends (used for debugging)
172         WRITE(charout, FMT="('adv ')")
173         CALL prt_ctl_info( charout, cdcomp = 'top' )
174         CALL prt_ctl( tab4d_1=tr(:,:,:,:,Krhs), mask1=tmask, clinfo=ctrcnm, clinfo3='trd' )
175      END IF
176      !
177      IF( ln_timing )   CALL timing_stop('trc_adv')
178      !
179   END SUBROUTINE trc_adv
180
181
182   SUBROUTINE trc_adv_ini
183      !!---------------------------------------------------------------------
184      !!                  ***  ROUTINE trc_adv_ini  ***
185      !!               
186      !! ** Purpose :   Control the consistency between namelist options for
187      !!              passive tracer advection schemes and set nadv
188      !!----------------------------------------------------------------------
189      INTEGER ::   ioptio, ios   ! Local integer
190      !!
191      NAMELIST/namtrc_adv/ ln_trcadv_OFF,                        &   ! No advection
192         &                 ln_trcadv_cen, nn_cen_h, nn_cen_v,    &   ! CEN
193         &                 ln_trcadv_fct, nn_fct_h, nn_fct_v,    &   ! FCT
194         &                 ln_trcadv_mus, ln_mus_ups,            &   ! MUSCL
195         &                 ln_trcadv_ubs,           nn_ubs_v,    &   ! UBS
196         &                 ln_trcadv_qck                             ! QCK
197      !!----------------------------------------------------------------------
198      !
199      !                                !==  Namelist  ==!
200      READ  ( numnat_ref, namtrc_adv, IOSTAT = ios, ERR = 901)
201901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtrc_adv in reference namelist' )
202      READ  ( numnat_cfg, namtrc_adv, IOSTAT = ios, ERR = 902 )
203902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtrc_adv in configuration namelist' )
204      IF(lwm) WRITE ( numont, namtrc_adv )
205      !
206      IF(lwp) THEN                           ! Namelist print
207         WRITE(numout,*)
208         WRITE(numout,*) 'trc_adv_ini : choice/control of the tracer advection scheme'
209         WRITE(numout,*) '~~~~~~~~~~~'
210         WRITE(numout,*) '   Namelist namtrc_adv : chose a advection scheme for tracers'
211         WRITE(numout,*) '      No advection on passive tracers           ln_trcadv_OFF = ', ln_trcadv_OFF
212         WRITE(numout,*) '      centered scheme                           ln_trcadv_cen = ', ln_trcadv_cen
213         WRITE(numout,*) '            horizontal 2nd/4th order               nn_cen_h   = ', nn_fct_h
214         WRITE(numout,*) '            vertical   2nd/4th order               nn_cen_v   = ', nn_fct_v
215         WRITE(numout,*) '      Flux Corrected Transport scheme           ln_trcadv_fct = ', ln_trcadv_fct
216         WRITE(numout,*) '            horizontal 2nd/4th order               nn_fct_h   = ', nn_fct_h
217         WRITE(numout,*) '            vertical   2nd/4th order               nn_fct_v   = ', nn_fct_v
218         WRITE(numout,*) '      MUSCL scheme                              ln_trcadv_mus = ', ln_trcadv_mus
219         WRITE(numout,*) '            + upstream scheme near river mouths    ln_mus_ups = ', ln_mus_ups
220         WRITE(numout,*) '      UBS scheme                                ln_trcadv_ubs = ', ln_trcadv_ubs
221         WRITE(numout,*) '            vertical   2nd/4th order               nn_ubs_v   = ', nn_ubs_v
222         WRITE(numout,*) '      QUICKEST scheme                           ln_trcadv_qck = ', ln_trcadv_qck
223      ENDIF
224      !
225      !                                !==  Parameter control & set nadv ==!
226      ioptio = 0
227      IF( ln_trcadv_OFF ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_NO_adv   ;   ENDIF
228      IF( ln_trcadv_cen ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_CEN      ;   ENDIF
229      IF( ln_trcadv_fct ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_FCT      ;   ENDIF
230      IF( ln_trcadv_mus ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_MUS      ;   ENDIF
231      IF( ln_trcadv_ubs ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_UBS      ;   ENDIF
232      IF( ln_trcadv_qck ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_QCK      ;   ENDIF
233      !
234      IF( ioptio /= 1 )   CALL ctl_stop( 'trc_adv_ini: Choose ONE advection option in namelist namtrc_adv' )
235      !
236      IF( ln_trcadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 )   &
237                        .AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 )   ) THEN
238        CALL ctl_stop( 'trc_adv_ini: CEN scheme, choose 2nd or 4th order' )
239      ENDIF
240      IF( ln_trcadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 )   &
241                        .AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 )   ) THEN
242        CALL ctl_stop( 'trc_adv_ini: FCT scheme, choose 2nd or 4th order' )
243      ENDIF
244      IF( ln_trcadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 )   ) THEN
245        CALL ctl_stop( 'trc_adv_ini: UBS scheme, choose 2nd or 4th order' )
246      ENDIF
247      IF( ln_trcadv_ubs .AND. nn_ubs_v == 4 ) THEN
248         CALL ctl_warn( 'trc_adv_ini: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
249      ENDIF
250      IF( ln_isfcav ) THEN                                                       ! ice-shelf cavities
251         IF(  ln_trcadv_cen .AND. nn_cen_v == 4    .OR.   &                            ! NO 4th order with ISF
252            & ln_trcadv_fct .AND. nn_fct_v == 4   )   CALL ctl_stop( 'tra_adv_ini: 4th order COMPACT scheme not allowed with ISF' )
253      ENDIF
254      !
255      !                                !==  Print the choice  ==! 
256      IF(lwp) THEN
257         WRITE(numout,*)
258         SELECT CASE ( nadv )
259         CASE( np_NO_adv  )   ;   WRITE(numout,*) '      ===>>   NO passive tracer advection'
260         CASE( np_CEN     )   ;   WRITE(numout,*) '      ===>>   CEN      scheme is used. Horizontal order: ', nn_cen_h,   &
261            &                                                                     ' Vertical   order: ', nn_cen_v
262         CASE( np_FCT     )   ;   WRITE(numout,*) '      ===>>   FCT      scheme is used. Horizontal order: ', nn_fct_h,   &
263            &                                                                      ' Vertical   order: ', nn_fct_v
264         CASE( np_MUS     )   ;   WRITE(numout,*) '      ===>>   MUSCL    scheme is used'
265         CASE( np_UBS     )   ;   WRITE(numout,*) '      ===>>   UBS      scheme is used'
266         CASE( np_QCK     )   ;   WRITE(numout,*) '      ===>>   QUICKEST scheme is used'
267         END SELECT
268      ENDIF
269      !
270   END SUBROUTINE trc_adv_ini
271   
272#endif
273
274  !!======================================================================
275END MODULE trcadv
Note: See TracBrowser for help on using the repository browser.