| 1 | MODULE traldf_triad |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE traldf_triad *** |
|---|
| 4 | !! Ocean tracers: horizontal component of the lateral tracer mixing trend |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.3 ! 2010-10 (G. Nurser, C. Harris, G. Madec) Griffies operator (original code) |
|---|
| 7 | !! 3.7 ! 2013-12 (F. Lemarie, G. Madec) triad operator (Griffies) + Method of Stabilizing Correction |
|---|
| 8 | !!---------------------------------------------------------------------- |
|---|
| 9 | |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | !! tra_ldf_triad : update the tracer trend with the iso-neutral laplacian triad-operator |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | USE oce ! ocean dynamics and active tracers |
|---|
| 14 | USE dom_oce ! ocean space and time domain |
|---|
| 15 | ! TEMP: [tiling] This change not necessary if XIOS has subdomain support |
|---|
| 16 | USE domtile |
|---|
| 17 | USE domutl, ONLY : is_tile |
|---|
| 18 | USE phycst ! physical constants |
|---|
| 19 | USE trc_oce ! share passive tracers/Ocean variables |
|---|
| 20 | USE zdf_oce ! ocean vertical physics |
|---|
| 21 | USE ldftra ! lateral physics: eddy diffusivity |
|---|
| 22 | USE ldfslp ! lateral physics: iso-neutral slopes |
|---|
| 23 | USE traldf_iso ! lateral diffusion (Madec operator) (tra_ldf_iso routine) |
|---|
| 24 | USE diaptr ! poleward transport diagnostics |
|---|
| 25 | USE diaar5 ! AR5 diagnostics |
|---|
| 26 | USE zpshde ! partial step: hor. derivative (zps_hde routine) |
|---|
| 27 | ! |
|---|
| 28 | USE in_out_manager ! I/O manager |
|---|
| 29 | USE iom ! I/O library |
|---|
| 30 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 31 | USE lib_mpp ! MPP library |
|---|
| 32 | |
|---|
| 33 | IMPLICIT NONE |
|---|
| 34 | PRIVATE |
|---|
| 35 | |
|---|
| 36 | PUBLIC tra_ldf_triad ! routine called by traldf.F90 |
|---|
| 37 | |
|---|
| 38 | LOGICAL :: l_ptr ! flag to compute poleward transport |
|---|
| 39 | LOGICAL :: l_hst ! flag to compute heat transport |
|---|
| 40 | |
|---|
| 41 | |
|---|
| 42 | !! * Substitutions |
|---|
| 43 | # include "do_loop_substitute.h90" |
|---|
| 44 | # include "domzgr_substitute.h90" |
|---|
| 45 | !!---------------------------------------------------------------------- |
|---|
| 46 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 47 | !! $Id$ |
|---|
| 48 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 49 | !!---------------------------------------------------------------------- |
|---|
| 50 | CONTAINS |
|---|
| 51 | |
|---|
| 52 | SUBROUTINE tra_ldf_triad( kt, Kmm, kit000, cdtype, pahu, pahv, & |
|---|
| 53 | & pgu , pgv , pgui, pgvi, & |
|---|
| 54 | & pt, pt2, pt_rhs, kjpt, kpass ) |
|---|
| 55 | !! |
|---|
| 56 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
|---|
| 57 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
|---|
| 58 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
|---|
| 59 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
|---|
| 60 | INTEGER , INTENT(in ) :: kpass ! =1/2 first or second passage |
|---|
| 61 | INTEGER , INTENT(in ) :: Kmm ! ocean time level indices |
|---|
| 62 | REAL(wp), DIMENSION(:,:,:) , INTENT(in ) :: pahu, pahv ! eddy diffusivity at u- and v-points [m2/s] |
|---|
| 63 | REAL(wp), DIMENSION(:,:,:) , INTENT(in ) :: pgu , pgv ! tracer gradient at pstep levels |
|---|
| 64 | REAL(wp), DIMENSION(:,:,:) , INTENT(in ) :: pgui, pgvi ! tracer gradient at top levels |
|---|
| 65 | REAL(wp), DIMENSION(:,:,:,:), INTENT(in ) :: pt ! tracer (kpass=1) or laplacian of tracer (kpass=2) |
|---|
| 66 | REAL(wp), DIMENSION(:,:,:,:), INTENT(in ) :: pt2 ! tracer (only used in kpass=2) |
|---|
| 67 | REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) :: pt_rhs ! tracer trend |
|---|
| 68 | !! |
|---|
| 69 | CALL tra_ldf_triad_t( kt, Kmm, kit000, cdtype, pahu, pahv, is_tile(pahu), & |
|---|
| 70 | & pgu , pgv , is_tile(pgu) , pgui, pgvi, is_tile(pgui), & |
|---|
| 71 | & pt, is_tile(pt), pt2, is_tile(pt2), pt_rhs, is_tile(pt_rhs), kjpt, kpass ) |
|---|
| 72 | END SUBROUTINE tra_ldf_triad |
|---|
| 73 | |
|---|
| 74 | |
|---|
| 75 | SUBROUTINE tra_ldf_triad_t( kt, Kmm, kit000, cdtype, pahu, pahv, ktah, & |
|---|
| 76 | & pgu , pgv , ktg , pgui, pgvi, ktgi, & |
|---|
| 77 | & pt, ktt, pt2, ktt2, pt_rhs, ktt_rhs, kjpt, kpass ) |
|---|
| 78 | !!---------------------------------------------------------------------- |
|---|
| 79 | !! *** ROUTINE tra_ldf_triad *** |
|---|
| 80 | !! |
|---|
| 81 | !! ** Purpose : Compute the before horizontal tracer (t & s) diffusive |
|---|
| 82 | !! trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and |
|---|
| 83 | !! add it to the general trend of tracer equation. |
|---|
| 84 | !! |
|---|
| 85 | !! ** Method : The horizontal component of the lateral diffusive trends |
|---|
| 86 | !! is provided by a 2nd order operator rotated along neural or geopo- |
|---|
| 87 | !! tential surfaces to which an eddy induced advection can be added |
|---|
| 88 | !! It is computed using before fields (forward in time) and isopyc- |
|---|
| 89 | !! nal or geopotential slopes computed in routine ldfslp. |
|---|
| 90 | !! |
|---|
| 91 | !! see documentation for the desciption |
|---|
| 92 | !! |
|---|
| 93 | !! ** Action : pt_rhs updated with the before rotated diffusion |
|---|
| 94 | !! ah_wslp2 .... |
|---|
| 95 | !! akz stabilizing vertical diffusivity coefficient (used in trazdf_imp) |
|---|
| 96 | !!---------------------------------------------------------------------- |
|---|
| 97 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
|---|
| 98 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
|---|
| 99 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
|---|
| 100 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
|---|
| 101 | INTEGER , INTENT(in ) :: kpass ! =1/2 first or second passage |
|---|
| 102 | INTEGER , INTENT(in) :: Kmm ! ocean time level indices |
|---|
| 103 | INTEGER , INTENT(in ) :: ktah, ktg, ktgi, ktt, ktt2, ktt_rhs |
|---|
| 104 | REAL(wp), DIMENSION(A2D_T(ktah), JPK) , INTENT(in ) :: pahu, pahv ! eddy diffusivity at u- and v-points [m2/s] |
|---|
| 105 | REAL(wp), DIMENSION(A2D_T(ktg), KJPT), INTENT(in ) :: pgu , pgv ! tracer gradient at pstep levels |
|---|
| 106 | REAL(wp), DIMENSION(A2D_T(ktgi), KJPT), INTENT(in ) :: pgui, pgvi ! tracer gradient at top levels |
|---|
| 107 | REAL(wp), DIMENSION(A2D_T(ktt), JPK,KJPT), INTENT(in ) :: pt ! tracer (kpass=1) or laplacian of tracer (kpass=2) |
|---|
| 108 | REAL(wp), DIMENSION(A2D_T(ktt2), JPK,KJPT), INTENT(in ) :: pt2 ! tracer (only used in kpass=2) |
|---|
| 109 | REAL(wp), DIMENSION(A2D_T(ktt_rhs),JPK,KJPT), INTENT(inout) :: pt_rhs ! tracer trend |
|---|
| 110 | ! |
|---|
| 111 | INTEGER :: ji, jj, jk, jn, kp ! dummy loop indices |
|---|
| 112 | REAL(wp) :: zcoef0, ze3w_2, zsign ! - - |
|---|
| 113 | ! |
|---|
| 114 | REAL(wp) :: zslope2, zbu, zbv, zbu1, zbv1, zslope21, zah, zah1, zah_ip1, zah_jp1, zbu_ip1, zbv_jp1 |
|---|
| 115 | REAL(wp) :: ze1ur, ze2vr, ze3wr, zdxt, zdyt, zdzt, zdyt_jp1, ze3wr_jp1, zdzt_jp1, zah_slp1, zah_slp_jp1, zaei_slp_jp1 |
|---|
| 116 | REAL(wp) :: zah_slp, zaei_slp, zdxt_ip1, ze3wr_ip1, zdzt_ip1, zah_slp_ip1, zaei_slp_ip1, zaei_slp1 |
|---|
| 117 | REAL(wp), DIMENSION(A2D(nn_hls),0:1) :: zdkt3d ! vertical tracer gradient at 2 levels |
|---|
| 118 | REAL(wp), DIMENSION(A2D(nn_hls) ) :: z2d ! 2D workspace |
|---|
| 119 | REAL(wp), DIMENSION(A2D(nn_hls) ,jpk) :: zdit, zdjt, zftu, zftv, ztfw ! 3D - |
|---|
| 120 | ! TEMP: [tiling] This can be A2D(nn_hls) if XIOS has subdomain support |
|---|
| 121 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpsi_uw, zpsi_vw |
|---|
| 122 | !!---------------------------------------------------------------------- |
|---|
| 123 | ! |
|---|
| 124 | IF( ntile == 0 .OR. ntile == 1 ) THEN ! Do only on the first tile |
|---|
| 125 | IF( kpass == 1 .AND. kt == kit000 ) THEN |
|---|
| 126 | IF(lwp) WRITE(numout,*) |
|---|
| 127 | IF(lwp) WRITE(numout,*) 'tra_ldf_triad : rotated laplacian diffusion operator on ', cdtype |
|---|
| 128 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~' |
|---|
| 129 | ENDIF |
|---|
| 130 | ! |
|---|
| 131 | l_hst = .FALSE. |
|---|
| 132 | l_ptr = .FALSE. |
|---|
| 133 | IF( cdtype == 'TRA' ) THEN |
|---|
| 134 | IF( iom_use( 'sophtldf' ) .OR. iom_use( 'sopstldf') ) l_ptr = .TRUE. |
|---|
| 135 | IF( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. & |
|---|
| 136 | & iom_use("uadv_salttr") .OR. iom_use("vadv_salttr") ) l_hst = .TRUE. |
|---|
| 137 | ENDIF |
|---|
| 138 | ENDIF |
|---|
| 139 | ! |
|---|
| 140 | IF( kpass == 1 ) THEN ; zsign = 1._wp ! bilaplacian operator require a minus sign (eddy diffusivity >0) |
|---|
| 141 | ELSE ; zsign = -1._wp |
|---|
| 142 | ENDIF |
|---|
| 143 | ! |
|---|
| 144 | !!---------------------------------------------------------------------- |
|---|
| 145 | !! 0 - calculate ah_wslp2, akz, and optionally zpsi_uw, zpsi_vw |
|---|
| 146 | !!---------------------------------------------------------------------- |
|---|
| 147 | ! |
|---|
| 148 | IF( kpass == 1 ) THEN !== first pass only and whatever the tracer is ==! |
|---|
| 149 | ! |
|---|
| 150 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpk ) |
|---|
| 151 | akz (ji,jj,jk) = 0._wp |
|---|
| 152 | ah_wslp2(ji,jj,jk) = 0._wp |
|---|
| 153 | END_3D |
|---|
| 154 | ! |
|---|
| 155 | DO kp = 0, 1 ! i-k triads |
|---|
| 156 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 ) |
|---|
| 157 | ze3wr = 1._wp / e3w(ji,jj,jk+kp,Kmm) |
|---|
| 158 | zbu = e1e2u(ji,jj) * e3u(ji,jj,jk,Kmm) |
|---|
| 159 | zbu1 = e1e2u(ji-1,jj) * e3u(ji-1,jj,jk,Kmm) |
|---|
| 160 | zah = 0.25_wp * pahu(ji,jj,jk) |
|---|
| 161 | zah1 = 0.25_wp * pahu(ji-1,jj,jk) |
|---|
| 162 | ! Subtract s-coordinate slope at t-points to give slope rel to s-surfaces (do this by *adding* gradient of depth) |
|---|
| 163 | zslope2 = triadi_g(ji,jj,jk,1,kp) + ( gdept(ji+1,jj,jk,Kmm) - gdept(ji,jj,jk,Kmm) ) * r1_e1u(ji,jj) * umask(ji,jj,jk+kp) |
|---|
| 164 | zslope2 = zslope2 *zslope2 |
|---|
| 165 | zslope21 = triadi_g(ji,jj,jk,0,kp) + ( gdept(ji,jj,jk,Kmm) - gdept(ji-1,jj,jk,Kmm) ) * r1_e1u(ji-1,jj) * umask(ji-1,jj,jk+kp) |
|---|
| 166 | zslope21 = zslope21 *zslope21 |
|---|
| 167 | ! round brackets added to fix the order of floating point operations |
|---|
| 168 | ! needed to ensure halo 1 - halo 2 compatibility |
|---|
| 169 | ah_wslp2(ji,jj,jk+kp) = ah_wslp2(ji,jj,jk+kp) + ( zah * zbu * ze3wr * r1_e1e2t(ji,jj) * zslope2 & |
|---|
| 170 | & + zah1 * zbu1 * ze3wr * r1_e1e2t(ji,jj) * zslope21 & |
|---|
| 171 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 172 | akz (ji,jj,jk+kp) = akz (ji,jj,jk+kp) + ( zah * r1_e1u(ji,jj) * r1_e1u(ji,jj) * umask(ji,jj,jk+kp) & |
|---|
| 173 | + zah1 * r1_e1u(ji-1,jj) * r1_e1u(ji-1,jj) * umask(ji-1,jj,jk+kp) & |
|---|
| 174 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 175 | END_3D |
|---|
| 176 | END DO |
|---|
| 177 | ! |
|---|
| 178 | DO kp = 0, 1 ! j-k triads |
|---|
| 179 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 ) |
|---|
| 180 | ze3wr = 1.0_wp / e3w(ji,jj,jk+kp,Kmm) |
|---|
| 181 | zbv = e1e2v(ji,jj) * e3v(ji,jj,jk,Kmm) |
|---|
| 182 | zbv1 = e1e2v(ji,jj-1) * e3v(ji,jj-1,jk,Kmm) |
|---|
| 183 | zah = 0.25_wp * pahv(ji,jj,jk) |
|---|
| 184 | zah1 = 0.25_wp * pahv(ji,jj-1,jk) |
|---|
| 185 | ! Subtract s-coordinate slope at t-points to give slope rel to s surfaces |
|---|
| 186 | ! (do this by *adding* gradient of depth) |
|---|
| 187 | zslope2 = triadj_g(ji,jj,jk,1,kp) + ( gdept(ji,jj+1,jk,Kmm) - gdept(ji,jj,jk,Kmm) ) * r1_e2v(ji,jj) * vmask(ji,jj,jk+kp) |
|---|
| 188 | zslope2 = zslope2 * zslope2 |
|---|
| 189 | zslope21 = triadj_g(ji,jj,jk,0,kp) + ( gdept(ji,jj,jk,Kmm) - gdept(ji,jj-1,jk,Kmm) ) * r1_e2v(ji,jj-1) * vmask(ji,jj-1,jk+kp) |
|---|
| 190 | zslope21 = zslope21 * zslope21 |
|---|
| 191 | ! round brackets added to fix the order of floating point operations |
|---|
| 192 | ! needed to ensure halo 1 - halo 2 compatibility |
|---|
| 193 | ah_wslp2(ji,jj,jk+kp) = ah_wslp2(ji,jj,jk+kp) + ( zah * zbv * ze3wr * r1_e1e2t(ji,jj) * zslope2 & |
|---|
| 194 | & + zah1 * zbv1 * ze3wr * r1_e1e2t(ji,jj) * zslope21 & |
|---|
| 195 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 196 | akz (ji,jj,jk+kp) = akz (ji,jj,jk+kp) + ( zah * r1_e2v(ji,jj) * r1_e2v(ji,jj) * vmask(ji,jj,jk+kp) & |
|---|
| 197 | & + zah1 * r1_e2v(ji,jj-1) * r1_e2v(ji,jj-1) * vmask(ji,jj-1,jk+kp) & |
|---|
| 198 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 199 | ! |
|---|
| 200 | END_3D |
|---|
| 201 | END DO |
|---|
| 202 | ! |
|---|
| 203 | IF( ln_traldf_msc ) THEN ! stabilizing vertical diffusivity coefficient |
|---|
| 204 | ! |
|---|
| 205 | IF( ln_traldf_blp ) THEN ! bilaplacian operator |
|---|
| 206 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) |
|---|
| 207 | akz(ji,jj,jk) = 16._wp & |
|---|
| 208 | & * ah_wslp2 (ji,jj,jk) & |
|---|
| 209 | & * ( akz (ji,jj,jk) & |
|---|
| 210 | & + ah_wslp2(ji,jj,jk) & |
|---|
| 211 | & / ( e3w (ji,jj,jk,Kmm) * e3w(ji,jj,jk,Kmm) ) ) |
|---|
| 212 | END_3D |
|---|
| 213 | ELSEIF( ln_traldf_lap ) THEN ! laplacian operator |
|---|
| 214 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) |
|---|
| 215 | ze3w_2 = e3w(ji,jj,jk,Kmm) * e3w(ji,jj,jk,Kmm) |
|---|
| 216 | zcoef0 = rDt * ( akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2 ) |
|---|
| 217 | akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * r1_Dt |
|---|
| 218 | END_3D |
|---|
| 219 | ENDIF |
|---|
| 220 | ! |
|---|
| 221 | ELSE ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit |
|---|
| 222 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpk ) |
|---|
| 223 | akz(ji,jj,jk) = ah_wslp2(ji,jj,jk) |
|---|
| 224 | END_3D |
|---|
| 225 | ENDIF |
|---|
| 226 | ! |
|---|
| 227 | ! TEMP: [tiling] These changes not necessary if XIOS has subdomain support |
|---|
| 228 | IF( ntile == 0 .OR. ntile == nijtile ) THEN ! Do only for the full domain |
|---|
| 229 | IF( ln_ldfeiv_dia .AND. cdtype == 'TRA' ) THEN |
|---|
| 230 | IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 ) |
|---|
| 231 | |
|---|
| 232 | zpsi_uw(:,:,:) = 0._wp |
|---|
| 233 | zpsi_vw(:,:,:) = 0._wp |
|---|
| 234 | |
|---|
| 235 | DO kp = 0, 1 |
|---|
| 236 | DO_3D( 1, 0, 1, 0, 1, jpkm1 ) |
|---|
| 237 | ! round brackets added to fix the order of floating point operations |
|---|
| 238 | ! needed to ensure halo 1 - halo 2 compatibility |
|---|
| 239 | zpsi_uw(ji,jj,jk+kp) = zpsi_uw(ji,jj,jk+kp) & |
|---|
| 240 | & + ( 0.25_wp * aeiu(ji,jj,jk) * e2u(ji,jj) * triadi_g(ji,jj,jk,1,kp) & |
|---|
| 241 | & + 0.25_wp * aeiu(ji,jj,jk) * e2u(ji,jj) * triadi_g(ji+1,jj,jk,0,kp) & |
|---|
| 242 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 243 | zpsi_vw(ji,jj,jk+kp) = zpsi_vw(ji,jj,jk+kp) & |
|---|
| 244 | & + ( 0.25_wp * aeiv(ji,jj,jk) * e1v(ji,jj) * triadj_g(ji,jj,jk,1,kp) & |
|---|
| 245 | & + 0.25_wp * aeiv(ji,jj,jk) * e1v(ji,jj) * triadj_g(ji,jj+1,jk,0,kp) & |
|---|
| 246 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 247 | END_3D |
|---|
| 248 | END DO |
|---|
| 249 | CALL ldf_eiv_dia( zpsi_uw, zpsi_vw, Kmm ) |
|---|
| 250 | |
|---|
| 251 | IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = nijtile ) |
|---|
| 252 | ENDIF |
|---|
| 253 | ENDIF |
|---|
| 254 | ! |
|---|
| 255 | ENDIF !== end 1st pass only ==! |
|---|
| 256 | ! |
|---|
| 257 | ! ! =========== |
|---|
| 258 | DO jn = 1, kjpt ! tracer loop |
|---|
| 259 | ! ! =========== |
|---|
| 260 | ! Zero fluxes for each tracer |
|---|
| 261 | !!gm this should probably be done outside the jn loop |
|---|
| 262 | ztfw(:,:,:) = 0._wp |
|---|
| 263 | zftu(:,:,:) = 0._wp |
|---|
| 264 | zftv(:,:,:) = 0._wp |
|---|
| 265 | ! |
|---|
| 266 | DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 ) !== before lateral T & S gradients at T-level jk ==! |
|---|
| 267 | zdit(ji,jj,jk) = ( pt(ji+1,jj ,jk,jn) - pt(ji,jj,jk,jn) ) * umask(ji,jj,jk) |
|---|
| 268 | zdjt(ji,jj,jk) = ( pt(ji ,jj+1,jk,jn) - pt(ji,jj,jk,jn) ) * vmask(ji,jj,jk) |
|---|
| 269 | END_3D |
|---|
| 270 | IF( ln_zps .AND. l_grad_zps ) THEN ! partial steps: correction at top/bottom ocean level |
|---|
| 271 | DO_2D( nn_hls, nn_hls-1, nn_hls, nn_hls-1 ) ! bottom level |
|---|
| 272 | zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn) |
|---|
| 273 | zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn) |
|---|
| 274 | END_2D |
|---|
| 275 | IF( ln_isfcav ) THEN ! top level (ocean cavities only) |
|---|
| 276 | DO_2D( nn_hls, nn_hls-1, nn_hls, nn_hls-1 ) |
|---|
| 277 | IF( miku(ji,jj) > 1 ) zdit(ji,jj,miku(ji,jj) ) = pgui(ji,jj,jn) |
|---|
| 278 | IF( mikv(ji,jj) > 1 ) zdjt(ji,jj,mikv(ji,jj) ) = pgvi(ji,jj,jn) |
|---|
| 279 | END_2D |
|---|
| 280 | ENDIF |
|---|
| 281 | ENDIF |
|---|
| 282 | ! |
|---|
| 283 | !!---------------------------------------------------------------------- |
|---|
| 284 | !! II - horizontal trend (full) |
|---|
| 285 | !!---------------------------------------------------------------------- |
|---|
| 286 | ! |
|---|
| 287 | DO jk = 1, jpkm1 |
|---|
| 288 | ! !== Vertical tracer gradient at level jk and jk+1 |
|---|
| 289 | DO_2D( nn_hls, nn_hls, nn_hls, nn_hls ) |
|---|
| 290 | zdkt3d(ji,jj,1) = ( pt(ji,jj,jk,jn) - pt(ji,jj,jk+1,jn) ) * tmask(ji,jj,jk+1) |
|---|
| 291 | END_2D |
|---|
| 292 | ! |
|---|
| 293 | ! ! surface boundary condition: zdkt3d(jk=0)=zdkt3d(jk=1) |
|---|
| 294 | IF( jk == 1 ) THEN ; zdkt3d(:,:,0) = zdkt3d(:,:,1) |
|---|
| 295 | ELSE |
|---|
| 296 | DO_2D( nn_hls, nn_hls, nn_hls, nn_hls ) |
|---|
| 297 | zdkt3d(ji,jj,0) = ( pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) ) * tmask(ji,jj,jk) |
|---|
| 298 | END_2D |
|---|
| 299 | ENDIF |
|---|
| 300 | ! |
|---|
| 301 | zaei_slp = 0._wp |
|---|
| 302 | ! |
|---|
| 303 | IF( ln_botmix_triad ) THEN |
|---|
| 304 | DO kp = 0, 1 !== Horizontal & vertical fluxes |
|---|
| 305 | DO_2D( nn_hls, nn_hls-1, nn_hls, nn_hls-1 ) |
|---|
| 306 | ze1ur = r1_e1u(ji,jj) |
|---|
| 307 | zdxt = zdit(ji,jj,jk) * ze1ur |
|---|
| 308 | zdxt_ip1 = zdit(ji+1,jj,jk) * r1_e1u(ji+1,jj) |
|---|
| 309 | ze3wr = 1._wp / e3w(ji,jj,jk+kp,Kmm) |
|---|
| 310 | ze3wr_ip1 = 1._wp / e3w(ji+1,jj,jk+kp,Kmm) |
|---|
| 311 | zdzt = zdkt3d(ji,jj,kp) * ze3wr |
|---|
| 312 | zdzt_ip1 = zdkt3d(ji+1,jj,kp) * ze3wr_ip1 |
|---|
| 313 | ! |
|---|
| 314 | zbu = 0.25_wp * e1e2u(ji,jj) * e3u(ji,jj,jk,Kmm) |
|---|
| 315 | zbu_ip1 = 0.25_wp * e1e2u(ji+1,jj) * e3u(ji+1,jj,jk,Kmm) |
|---|
| 316 | ! ln_botmix_triad is .T. don't mask zah for bottom half cells !!gm ????? ahu is masked.... |
|---|
| 317 | zah = pahu(ji,jj,jk) |
|---|
| 318 | zah_ip1 = pahu(ji+1,jj,jk) |
|---|
| 319 | zah_slp = zah * triadi(ji,jj,jk,1,kp) |
|---|
| 320 | zah_slp_ip1 = zah_ip1 * triadi(ji+1,jj,jk,1,kp) |
|---|
| 321 | zah_slp1 = zah * triadi(ji+1,jj,jk,0,kp) |
|---|
| 322 | IF( ln_ldfeiv ) THEN |
|---|
| 323 | zaei_slp = aeiu(ji,jj,jk) * triadi_g(ji,jj,jk,1,kp) |
|---|
| 324 | zaei_slp_ip1 = aeiu(ji+1,jj,jk) * triadi_g(ji+1,jj,jk,1,kp) |
|---|
| 325 | zaei_slp1 = aeiu(ji,jj,jk) * triadi_g(ji+1,jj,jk,0,kp) |
|---|
| 326 | ENDIF |
|---|
| 327 | ! round brackets added to fix the order of floating point operations |
|---|
| 328 | ! needed to ensure halo 1 - halo 2 compatibility |
|---|
| 329 | zftu(ji ,jj,jk ) = zftu(ji ,jj,jk ) & |
|---|
| 330 | & - ( ( zah * zdxt + ( zah_slp - zaei_slp ) * zdzt ) * zbu * ze1ur & |
|---|
| 331 | & + ( zah * zdxt + zah_slp1 * zdzt_ip1 - zaei_slp1 * zdzt_ip1 ) * zbu * ze1ur & |
|---|
| 332 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 333 | ztfw(ji+1,jj,jk+kp) = ztfw(ji+1,jj,jk+kp) & |
|---|
| 334 | & - ( (zah_slp_ip1 + zaei_slp_ip1) * zdxt_ip1 * zbu_ip1 * ze3wr_ip1 & |
|---|
| 335 | & + ( zah_slp1 + zaei_slp1) * zdxt * zbu * ze3wr_ip1 & |
|---|
| 336 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 337 | END_2D |
|---|
| 338 | END DO |
|---|
| 339 | ! |
|---|
| 340 | DO kp = 0, 1 |
|---|
| 341 | DO_2D( nn_hls, nn_hls-1, nn_hls, nn_hls-1 ) |
|---|
| 342 | ze2vr = r1_e2v(ji,jj) |
|---|
| 343 | zdyt = zdjt(ji,jj,jk) * ze2vr |
|---|
| 344 | zdyt_jp1 = zdjt(ji,jj+1,jk) * r1_e2v(ji,jj+1) |
|---|
| 345 | ze3wr = 1._wp / e3w(ji,jj,jk+kp,Kmm) |
|---|
| 346 | ze3wr_jp1 = 1._wp / e3w(ji,jj+1,jk+kp,Kmm) |
|---|
| 347 | zdzt = zdkt3d(ji,jj,kp) * ze3wr |
|---|
| 348 | zdzt_jp1 = zdkt3d(ji,jj+1,kp) * ze3wr_jp1 |
|---|
| 349 | zbv = 0.25_wp * e1e2v(ji,jj) * e3v(ji,jj,jk,Kmm) |
|---|
| 350 | zbv_jp1 = 0.25_wp * e1e2v(ji,jj+1) * e3v(ji,jj+1,jk,Kmm) |
|---|
| 351 | ! ln_botmix_triad is .T. don't mask zah for bottom half cells !!gm ????? ahu is masked.... |
|---|
| 352 | zah = pahv(ji,jj,jk) ! pahv(ji,jj+jp,jk) ???? |
|---|
| 353 | zah_jp1 = pahv(ji,jj+1,jk) |
|---|
| 354 | zah_slp = zah * triadj(ji,jj,jk,1,kp) |
|---|
| 355 | zah_slp1 = zah * triadj(ji,jj+1,jk,0,kp) |
|---|
| 356 | zah_slp_jp1 = zah_jp1 * triadj(ji,jj+1,jk,1,kp) |
|---|
| 357 | IF( ln_ldfeiv ) THEN |
|---|
| 358 | zaei_slp = aeiv(ji,jj,jk) * triadj_g(ji,jj,jk,1,kp) |
|---|
| 359 | zaei_slp_jp1 = aeiv(ji,jj+1,jk) * triadj_g(ji,jj+1,jk,1,kp) |
|---|
| 360 | zaei_slp1 = aeiv(ji,jj,jk) * triadj_g(ji,jj+1,jk,0,kp) |
|---|
| 361 | ENDIF |
|---|
| 362 | ! round brackets added to fix the order of floating point operations |
|---|
| 363 | ! needed to ensure halo 1 - halo 2 compatibility |
|---|
| 364 | zftv(ji,jj ,jk ) = zftv(ji,jj ,jk ) & |
|---|
| 365 | & - ( ( zah * zdyt + ( zah_slp - zaei_slp ) * zdzt ) * zbv * ze2vr & |
|---|
| 366 | & + ( zah * zdyt + zah_slp1 * zdzt_jp1 - zaei_slp1 * zdzt_jp1 ) * zbv * ze2vr & |
|---|
| 367 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 368 | ztfw(ji,jj+1,jk+kp) = ztfw(ji,jj+1,jk+kp) & |
|---|
| 369 | & - ( ( zah_slp_jp1 + zaei_slp_jp1) * zdyt_jp1 * zbv_jp1 * ze3wr_jp1 & |
|---|
| 370 | & + ( zah_slp1 + zaei_slp1) * zdyt * zbv * ze3wr_jp1 & |
|---|
| 371 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 372 | END_2D |
|---|
| 373 | END DO |
|---|
| 374 | ! |
|---|
| 375 | ELSE |
|---|
| 376 | ! |
|---|
| 377 | DO kp = 0, 1 !== Horizontal & vertical fluxes |
|---|
| 378 | DO_2D( nn_hls, nn_hls-1, nn_hls, nn_hls-1 ) |
|---|
| 379 | ze1ur = r1_e1u(ji,jj) |
|---|
| 380 | zdxt = zdit(ji,jj,jk) * ze1ur |
|---|
| 381 | zdxt_ip1 = zdit(ji+1,jj,jk) * r1_e1u(ji+1,jj) |
|---|
| 382 | ze3wr = 1._wp / e3w(ji,jj,jk+kp,Kmm) |
|---|
| 383 | ze3wr_ip1 = 1._wp / e3w(ji+1,jj,jk+kp,Kmm) |
|---|
| 384 | zdzt = zdkt3d(ji,jj,kp) * ze3wr |
|---|
| 385 | zdzt_ip1 = zdkt3d(ji+1,jj,kp) * ze3wr_ip1 |
|---|
| 386 | ! |
|---|
| 387 | zbu = 0.25_wp * e1e2u(ji,jj) * e3u(ji,jj,jk,Kmm) |
|---|
| 388 | zbu_ip1 = 0.25_wp * e1e2u(ji+1,jj) * e3u(ji+1,jj,jk,Kmm) |
|---|
| 389 | ! ln_botmix_triad is .F. mask zah for bottom half cells |
|---|
| 390 | zah = pahu(ji,jj,jk) * umask(ji,jj,jk+kp) ! pahu(ji+ip,jj,jk) ===>> ???? |
|---|
| 391 | zah_ip1 = pahu(ji+1,jj,jk) * umask(ji+1,jj,jk+kp) |
|---|
| 392 | zah_slp = zah * triadi(ji,jj,jk,1,kp) |
|---|
| 393 | zah_slp_ip1 = zah_ip1 * triadi(ji+1,jj,jk,1,kp) |
|---|
| 394 | zah_slp1 = zah * triadi(ji+1,jj,jk,0,kp) |
|---|
| 395 | IF( ln_ldfeiv ) THEN |
|---|
| 396 | zaei_slp = aeiu(ji,jj,jk) * triadi_g(ji,jj,jk,1,kp) |
|---|
| 397 | zaei_slp_ip1 = aeiu(ji+1,jj,jk) * triadi_g(ji+1,jj,jk,1,kp) |
|---|
| 398 | zaei_slp1 = aeiu(ji,jj,jk) * triadi_g(ji+1,jj,jk,0,kp) |
|---|
| 399 | ENDIF |
|---|
| 400 | ! zftu(ji ,jj,jk ) = zftu(ji ,jj,jk ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur - ( zah * zdxt + (zah_slp1 - zaei_slp1) * zdzt_ip1 ) * zbu * ze1ur |
|---|
| 401 | ! ztfw(ji+1,jj,jk+kp) = ztfw(ji+1,jj,jk+kp) - (zah_slp_ip1 + zaei_slp_ip1) * zdxt_ip1 * zbu_ip1 * ze3wr_ip1 - (zah_slp1 + zaei_slp1) * zdxt * zbu * ze3wr_ip1 |
|---|
| 402 | ! round brackets added to fix the order of floating point operations |
|---|
| 403 | ! needed to ensure halo 1 - halo 2 compatibility |
|---|
| 404 | zftu(ji ,jj,jk ) = zftu(ji ,jj,jk ) & |
|---|
| 405 | & - ( ( zah * zdxt + ( zah_slp - zaei_slp ) * zdzt ) * zbu * ze1ur & |
|---|
| 406 | & + ( zah * zdxt + zah_slp1 * zdzt_ip1 - zaei_slp1 * zdzt_ip1 ) * zbu * ze1ur & |
|---|
| 407 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 408 | ztfw(ji+1,jj,jk+kp) = ztfw(ji+1,jj,jk+kp) & |
|---|
| 409 | & - ( (zah_slp_ip1 + zaei_slp_ip1) * zdxt_ip1 * zbu_ip1 * ze3wr_ip1 & |
|---|
| 410 | & + ( zah_slp1 + zaei_slp1) * zdxt * zbu * ze3wr_ip1 & |
|---|
| 411 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 412 | END_2D |
|---|
| 413 | END DO |
|---|
| 414 | ! |
|---|
| 415 | DO kp = 0, 1 |
|---|
| 416 | DO_2D( nn_hls, nn_hls-1, nn_hls, nn_hls-1 ) |
|---|
| 417 | ze2vr = r1_e2v(ji,jj) |
|---|
| 418 | zdyt = zdjt(ji,jj,jk) * ze2vr |
|---|
| 419 | zdyt_jp1 = zdjt(ji,jj+1,jk) * r1_e2v(ji,jj+1) |
|---|
| 420 | ze3wr = 1._wp / e3w(ji,jj,jk+kp,Kmm) |
|---|
| 421 | ze3wr_jp1 = 1._wp / e3w(ji,jj+1,jk+kp,Kmm) |
|---|
| 422 | zdzt = zdkt3d(ji,jj,kp) * ze3wr |
|---|
| 423 | zdzt_jp1 = zdkt3d(ji,jj+1,kp) * ze3wr_jp1 |
|---|
| 424 | zbv = 0.25_wp * e1e2v(ji,jj) * e3v(ji,jj,jk,Kmm) |
|---|
| 425 | zbv_jp1 = 0.25_wp * e1e2v(ji,jj+1) * e3v(ji,jj+1,jk,Kmm) |
|---|
| 426 | ! ln_botmix_triad is .F. mask zah for bottom half cells |
|---|
| 427 | zah = pahv(ji,jj,jk) * vmask(ji,jj,jk+kp) ! pahv(ji,jj+jp,jk) ???? |
|---|
| 428 | zah_jp1 = pahv(ji,jj+1,jk) * vmask(ji,jj+1,jk+kp) |
|---|
| 429 | zah_slp = zah * triadj(ji,jj,jk,1,kp) |
|---|
| 430 | zah_slp1 = zah * triadj(ji,jj+1,jk,0,kp) |
|---|
| 431 | zah_slp_jp1 = zah_jp1 * triadj(ji,jj+1,jk,1,kp) |
|---|
| 432 | IF( ln_ldfeiv ) THEN |
|---|
| 433 | zaei_slp = aeiv(ji,jj,jk) * triadj_g(ji,jj,jk,1,kp) |
|---|
| 434 | zaei_slp_jp1 = aeiv(ji,jj+1,jk) * triadj_g(ji,jj+1,jk,1,kp) |
|---|
| 435 | zaei_slp1 = aeiv(ji,jj,jk) * triadj_g(ji,jj+1,jk,0,kp) |
|---|
| 436 | ENDIF |
|---|
| 437 | ! zftv(ji,jj ,jk ) = zftv(ji,jj ,jk ) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr - ( zah * zdyt + (zah_slp1 - zaei_slp1) * zdzt_jp1 ) * zbv * ze2vr |
|---|
| 438 | ! ztfw(ji,jj+1,jk+kp) = ztfw(ji,jj+1,jk+kp) - ( zah_slp_jp1 + zaei_slp_jp1) * zdyt_jp1 * zbv_jp1 * ze3wr_jp1 - (zah_slp1 + zaei_slp1) * zdyt * zbv * ze3wr_jp1 |
|---|
| 439 | ! round brackets added to fix the order of floating point operations |
|---|
| 440 | ! needed to ensure halo 1 - halo 2 compatibility |
|---|
| 441 | zftv(ji,jj ,jk ) = zftv(ji,jj ,jk ) & |
|---|
| 442 | & - ( ( zah * zdyt + ( zah_slp - zaei_slp ) * zdzt ) * zbv * ze2vr & |
|---|
| 443 | & + ( zah * zdyt + zah_slp1 * zdzt_jp1 - zaei_slp1 * zdzt_jp1 ) * zbv * ze2vr & |
|---|
| 444 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 445 | ztfw(ji,jj+1,jk+kp) = ztfw(ji,jj+1,jk+kp) & |
|---|
| 446 | & - ( ( zah_slp_jp1 + zaei_slp_jp1) * zdyt_jp1 * zbv_jp1 * ze3wr_jp1 & |
|---|
| 447 | & + ( zah_slp1 + zaei_slp1) * zdyt * zbv * ze3wr_jp1 & |
|---|
| 448 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 449 | END_2D |
|---|
| 450 | END DO |
|---|
| 451 | ENDIF |
|---|
| 452 | ! !== horizontal divergence and add to the general trend ==! |
|---|
| 453 | DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 ) |
|---|
| 454 | ! round brackets added to fix the order of floating point operations |
|---|
| 455 | ! needed to ensure halo 1 - halo 2 compatibility |
|---|
| 456 | pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn) & |
|---|
| 457 | & + zsign * ( ( zftu(ji-1,jj ,jk) - zftu(ji,jj,jk) & |
|---|
| 458 | & ) & ! bracket for halo 1 - halo 2 compatibility |
|---|
| 459 | & + ( zftv(ji,jj-1,jk) - zftv(ji,jj,jk) & |
|---|
| 460 | & ) & ! bracket for halo 1 - halo 2 compatibility |
|---|
| 461 | & ) / ( e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) ) |
|---|
| 462 | END_2D |
|---|
| 463 | ! |
|---|
| 464 | END DO |
|---|
| 465 | ! |
|---|
| 466 | ! !== add the vertical 33 flux ==! |
|---|
| 467 | IF( ln_traldf_lap ) THEN ! laplacian case: eddy coef = ah_wslp2 - akz |
|---|
| 468 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) |
|---|
| 469 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * tmask(ji,jj,jk) & |
|---|
| 470 | & * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) ) & |
|---|
| 471 | & * ( pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) ) |
|---|
| 472 | END_3D |
|---|
| 473 | ELSE ! bilaplacian |
|---|
| 474 | SELECT CASE( kpass ) |
|---|
| 475 | CASE( 1 ) ! 1st pass : eddy coef = ah_wslp2 |
|---|
| 476 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) |
|---|
| 477 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * tmask(ji,jj,jk) & |
|---|
| 478 | & * ah_wslp2(ji,jj,jk) * ( pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) ) |
|---|
| 479 | END_3D |
|---|
| 480 | CASE( 2 ) ! 2nd pass : eddy flux = ah_wslp2 and akz applied on pt and pt2 gradients, resp. |
|---|
| 481 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) |
|---|
| 482 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * tmask(ji,jj,jk) & |
|---|
| 483 | & * ( ah_wslp2(ji,jj,jk) * ( pt (ji,jj,jk-1,jn) - pt (ji,jj,jk,jn) ) & |
|---|
| 484 | & + akz (ji,jj,jk) * ( pt2(ji,jj,jk-1,jn) - pt2(ji,jj,jk,jn) ) ) |
|---|
| 485 | END_3D |
|---|
| 486 | END SELECT |
|---|
| 487 | ENDIF |
|---|
| 488 | ! |
|---|
| 489 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 ) !== Divergence of vertical fluxes added to pta ==! |
|---|
| 490 | pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn) & |
|---|
| 491 | & + zsign * ( ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk) ) & |
|---|
| 492 | & / ( e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) ) |
|---|
| 493 | END_3D |
|---|
| 494 | ! |
|---|
| 495 | IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR. & !== first pass only ( laplacian) ==! |
|---|
| 496 | ( kpass == 2 .AND. ln_traldf_blp ) ) THEN !== 2nd pass (bilaplacian) ==! |
|---|
| 497 | ! |
|---|
| 498 | ! ! "Poleward" diffusive heat or salt transports (T-S case only) |
|---|
| 499 | IF( l_ptr ) CALL dia_ptr_hst( jn, 'ldf', zftv(:,:,:) ) |
|---|
| 500 | ! ! Diffusive heat transports |
|---|
| 501 | IF( l_hst ) CALL dia_ar5_hst( jn, 'ldf', zftu(:,:,:), zftv(:,:,:) ) |
|---|
| 502 | ! |
|---|
| 503 | ENDIF !== end pass selection ==! |
|---|
| 504 | ! |
|---|
| 505 | ! ! =============== |
|---|
| 506 | END DO ! end tracer loop |
|---|
| 507 | ! ! =============== |
|---|
| 508 | END SUBROUTINE tra_ldf_triad_t |
|---|
| 509 | |
|---|
| 510 | !!============================================================================== |
|---|
| 511 | END MODULE traldf_triad |
|---|
