New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trasbc.F90 in NEMO/branches/2021/dev_r14393_HPC-03_Mele_Comm_Cleanup/src/OCE/TRA – NEMO

source: NEMO/branches/2021/dev_r14393_HPC-03_Mele_Comm_Cleanup/src/OCE/TRA/trasbc.F90 @ 14538

Last change on this file since 14538 was 14215, checked in by acc, 3 years ago

trunk changes to swap the order of arguments to the DO LOOP macros. These changes result in a more natural i-j-k ordering as explained in #2595. SETTE is passed before and after these changes and results are unchanged. This fixes #2595
  • Property svn:keywords set to Id
File size: 11.9 KB
Line 
1MODULE trasbc
2   !!==============================================================================
3   !!                       ***  MODULE  trasbc  ***
4   !! Ocean active tracers:  surface boundary condition
5   !!==============================================================================
6   !! History :  OPA  !  1998-10  (G. Madec, G. Roullet, M. Imbard)  Original code
7   !!            8.2  !  2001-02  (D. Ludicone)  sea ice and free surface
8   !!  NEMO      1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
10   !!             -   !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!            3.6  !  2014-11  (P. Mathiot) isf melting forcing
12   !!            4.1  !  2019-09  (P. Mathiot) isf moved in traisf
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   tra_sbc       : update the tracer trend at ocean surface
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE sbc_oce        ! surface boundary condition: ocean
20   USE dom_oce        ! ocean space domain variables
21   USE phycst         ! physical constant
22   USE eosbn2         ! Equation Of State
23   USE sbcmod         ! ln_rnf
24   USE sbcrnf         ! River runoff
25   USE traqsr         ! solar radiation penetration
26   USE trd_oce        ! trends: ocean variables
27   USE trdtra         ! trends manager: tracers
28#if defined key_asminc
29   USE asminc         ! Assimilation increment
30#endif
31   !
32   USE in_out_manager ! I/O manager
33   USE prtctl         ! Print control
34   USE iom            ! xIOS server
35   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
36   USE timing         ! Timing
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC   tra_sbc   ! routine called by step.F90
42
43   !! * Substitutions
44#  include "do_loop_substitute.h90"
45#  include "domzgr_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
48   !! $Id$
49   !! Software governed by the CeCILL license (see ./LICENSE)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE tra_sbc ( kt, Kmm, pts, Krhs )
54      !!----------------------------------------------------------------------
55      !!                  ***  ROUTINE tra_sbc  ***
56      !!
57      !! ** Purpose :   Compute the tracer surface boundary condition trend of
58      !!      (flux through the interface, concentration/dilution effect)
59      !!      and add it to the general trend of tracer equations.
60      !!
61      !! ** Method :   The (air+ice)-sea flux has two components:
62      !!      (1) Fext, external forcing (i.e. flux through the (air+ice)-sea interface);
63      !!      (2) Fwe , tracer carried with the water that is exchanged with air+ice.
64      !!               The input forcing fields (emp, rnf, sfx) contain Fext+Fwe,
65      !!             they are simply added to the tracer trend (ts(Krhs)).
66      !!               In linear free surface case (ln_linssh=T), the volume of the
67      !!             ocean does not change with the water exchanges at the (air+ice)-sea
68      !!             interface. Therefore another term has to be added, to mimic the
69      !!             concentration/dilution effect associated with water exchanges.
70      !!
71      !! ** Action  : - Update ts(Krhs) with the surface boundary condition trend
72      !!              - send trends to trdtra module for further diagnostics(l_trdtra=T)
73      !!----------------------------------------------------------------------
74      INTEGER,                                   INTENT(in   ) ::   kt         ! ocean time-step index
75      INTEGER,                                   INTENT(in   ) ::   Kmm, Krhs  ! time level indices
76      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) ::   pts        ! active tracers and RHS of tracer Eq.
77      !
78      INTEGER  ::   ji, jj, jk, jn               ! dummy loop indices
79      INTEGER  ::   ikt, ikb, isi, iei, isj, iej ! local integers
80      REAL(wp) ::   zfact, z1_e3t, zdep, ztim    ! local scalar
81      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  ztrdt, ztrds
82      !!----------------------------------------------------------------------
83      !
84      IF( ln_timing )   CALL timing_start('tra_sbc')
85      !
86      IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
87         IF( kt == nit000 ) THEN
88            IF(lwp) WRITE(numout,*)
89            IF(lwp) WRITE(numout,*) 'tra_sbc : TRAcer Surface Boundary Condition'
90            IF(lwp) WRITE(numout,*) '~~~~~~~ '
91         ENDIF
92      ENDIF
93      !
94      IF( l_trdtra ) THEN                    !* Save ta and sa trends
95         ALLOCATE( ztrdt(jpi,jpj,jpk), ztrds(jpi,jpj,jpk) )
96         ztrdt(:,:,:) = pts(:,:,:,jp_tem,Krhs)
97         ztrds(:,:,:) = pts(:,:,:,jp_sal,Krhs)
98      ENDIF
99      !
100      IF( ntsi == Nis0 ) THEN ; isi = nn_hls ; ELSE ; isi = 0 ; ENDIF    ! Avoid double-counting when using tiling
101      IF( ntsj == Njs0 ) THEN ; isj = nn_hls ; ELSE ; isj = 0 ; ENDIF
102      IF( ntei == Nie0 ) THEN ; iei = nn_hls ; ELSE ; iei = 0 ; ENDIF
103      IF( ntej == Nje0 ) THEN ; iej = nn_hls ; ELSE ; iej = 0 ; ENDIF
104
105!!gm  This should be moved into sbcmod.F90 module ? (especially now that ln_traqsr is read in namsbc namelist)
106      IF( .NOT.ln_traqsr ) THEN     ! no solar radiation penetration
107         DO_2D( isi, iei, isj, iej )
108            qns(ji,jj) = qns(ji,jj) + qsr(ji,jj)      ! total heat flux in qns
109            qsr(ji,jj) = 0._wp                        ! qsr set to zero
110         END_2D
111      ENDIF
112
113      !----------------------------------------
114      !        EMP, SFX and QNS effects
115      !----------------------------------------
116      !                             !==  Set before sbc tracer content fields  ==!
117      IF( kt == nit000 ) THEN             !* 1st time-step
118         IF( ln_rstart .AND. .NOT.l_1st_euler ) THEN      ! Restart: read in restart file
119            zfact = 0.5_wp
120            IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
121               IF(lwp) WRITE(numout,*) '          nit000-1 sbc tracer content field read in the restart file'
122               sbc_tsc(:,:,:) = 0._wp
123               CALL iom_get( numror, jpdom_auto, 'sbc_hc_b', sbc_tsc_b(:,:,jp_tem) )   ! before heat content sbc trend
124               CALL iom_get( numror, jpdom_auto, 'sbc_sc_b', sbc_tsc_b(:,:,jp_sal) )   ! before salt content sbc trend
125            ENDIF
126         ELSE                                             ! No restart or restart not found: Euler forward time stepping
127            zfact = 1._wp
128            DO_2D( isi, iei, isj, iej )
129               sbc_tsc(ji,jj,:) = 0._wp
130               sbc_tsc_b(ji,jj,:) = 0._wp
131            END_2D
132         ENDIF
133      ELSE                                !* other time-steps: swap of forcing fields
134         zfact = 0.5_wp
135         DO_2D( isi, iei, isj, iej )
136            sbc_tsc_b(ji,jj,:) = sbc_tsc(ji,jj,:)
137         END_2D
138      ENDIF
139      !                             !==  Now sbc tracer content fields  ==!
140      DO_2D( isi, iei, isj, iej )
141         sbc_tsc(ji,jj,jp_tem) = r1_rho0_rcp * qns(ji,jj)   ! non solar heat flux
142         sbc_tsc(ji,jj,jp_sal) = r1_rho0     * sfx(ji,jj)   ! salt flux due to freezing/melting
143      END_2D
144      IF( ln_linssh ) THEN                !* linear free surface
145         DO_2D( isi, iei, isj, iej )                    !==>> add concentration/dilution effect due to constant volume cell
146            sbc_tsc(ji,jj,jp_tem) = sbc_tsc(ji,jj,jp_tem) + r1_rho0 * emp(ji,jj) * pts(ji,jj,1,jp_tem,Kmm)
147            sbc_tsc(ji,jj,jp_sal) = sbc_tsc(ji,jj,jp_sal) + r1_rho0 * emp(ji,jj) * pts(ji,jj,1,jp_sal,Kmm)
148         END_2D                                 !==>> output c./d. term
149         IF( ntile == 0 .OR. ntile == nijtile )  THEN             ! Do only on the last tile
150            IF( iom_use('emp_x_sst') )   CALL iom_put( "emp_x_sst", emp (:,:) * pts(:,:,1,jp_tem,Kmm) )
151            IF( iom_use('emp_x_sss') )   CALL iom_put( "emp_x_sss", emp (:,:) * pts(:,:,1,jp_sal,Kmm) )
152         ENDIF
153      ENDIF
154      !
155      DO jn = 1, jpts               !==  update tracer trend  ==!
156         DO_2D( 0, 0, 0, 0 )
157            pts(ji,jj,1,jn,Krhs) = pts(ji,jj,1,jn,Krhs) + zfact * ( sbc_tsc_b(ji,jj,jn) + sbc_tsc(ji,jj,jn) )    &
158               &                                                / e3t(ji,jj,1,Kmm)
159         END_2D
160      END DO
161      !
162      IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only on the last tile
163         IF( lrst_oce ) THEN           !==  write sbc_tsc in the ocean restart file  ==!
164            CALL iom_rstput( kt, nitrst, numrow, 'sbc_hc_b', sbc_tsc(:,:,jp_tem) )
165            CALL iom_rstput( kt, nitrst, numrow, 'sbc_sc_b', sbc_tsc(:,:,jp_sal) )
166         ENDIF
167      ENDIF
168      !
169      !----------------------------------------
170      !        River Runoff effects
171      !----------------------------------------
172      !
173      IF( ln_rnf ) THEN         ! input of heat and salt due to river runoff
174         zfact = 0.5_wp
175         DO_2D( 0, 0, 0, 0 )
176            IF( rnf(ji,jj) /= 0._wp ) THEN
177               zdep = zfact / h_rnf(ji,jj)
178               DO jk = 1, nk_rnf(ji,jj)
179                                     pts(ji,jj,jk,jp_tem,Krhs) = pts(ji,jj,jk,jp_tem,Krhs)                                  &
180                                        &                      +  ( rnf_tsc_b(ji,jj,jp_tem) + rnf_tsc(ji,jj,jp_tem) ) * zdep
181                  IF( ln_rnf_sal )   pts(ji,jj,jk,jp_sal,Krhs) = pts(ji,jj,jk,jp_sal,Krhs)                                  &
182                                        &                      +  ( rnf_tsc_b(ji,jj,jp_sal) + rnf_tsc(ji,jj,jp_sal) ) * zdep
183               END DO
184            ENDIF
185         END_2D
186      ENDIF
187
188      IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only on the last tile
189         IF( iom_use('rnf_x_sst') )   CALL iom_put( "rnf_x_sst", rnf*pts(:,:,1,jp_tem,Kmm) )   ! runoff term on sst
190         IF( iom_use('rnf_x_sss') )   CALL iom_put( "rnf_x_sss", rnf*pts(:,:,1,jp_sal,Kmm) )   ! runoff term on sss
191      ENDIF
192
193#if defined key_asminc
194      !
195      !----------------------------------------
196      !        Assmilation effects
197      !----------------------------------------
198      !
199      IF( ln_sshinc ) THEN         ! input of heat and salt due to assimilation
200          !
201         IF( ln_linssh ) THEN
202            DO_2D( 0, 0, 0, 0 )
203               ztim = ssh_iau(ji,jj) / e3t(ji,jj,1,Kmm)
204               pts(ji,jj,1,jp_tem,Krhs) = pts(ji,jj,1,jp_tem,Krhs) + pts(ji,jj,1,jp_tem,Kmm) * ztim
205               pts(ji,jj,1,jp_sal,Krhs) = pts(ji,jj,1,jp_sal,Krhs) + pts(ji,jj,1,jp_sal,Kmm) * ztim
206            END_2D
207         ELSE
208            DO_2D( 0, 0, 0, 0 )
209               ztim = ssh_iau(ji,jj) / ( ht(ji,jj) + 1. - ssmask(ji, jj) )
210               pts(ji,jj,:,jp_tem,Krhs) = pts(ji,jj,:,jp_tem,Krhs) + pts(ji,jj,:,jp_tem,Kmm) * ztim
211               pts(ji,jj,:,jp_sal,Krhs) = pts(ji,jj,:,jp_sal,Krhs) + pts(ji,jj,:,jp_sal,Kmm) * ztim
212            END_2D
213         ENDIF
214         !
215      ENDIF
216      !
217#endif
218      !
219      IF( l_trdtra )   THEN                      ! save the horizontal diffusive trends for further diagnostics
220         ztrdt(:,:,:) = pts(:,:,:,jp_tem,Krhs) - ztrdt(:,:,:)
221         ztrds(:,:,:) = pts(:,:,:,jp_sal,Krhs) - ztrds(:,:,:)
222         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_nsr, ztrdt )
223         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_nsr, ztrds )
224         DEALLOCATE( ztrdt , ztrds )
225      ENDIF
226      !
227      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Krhs), clinfo1=' sbc  - Ta: ', mask1=tmask,   &
228         &                                  tab3d_2=pts(:,:,:,jp_sal,Krhs), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
229      !
230      IF( ln_timing )   CALL timing_stop('tra_sbc')
231      !
232   END SUBROUTINE tra_sbc
233
234   !!======================================================================
235END MODULE trasbc
Note: See TracBrowser for help on using the repository browser.