| 1 | MODULE zdfiwm |
|---|
| 2 | !!======================================================================== |
|---|
| 3 | !! *** MODULE zdfiwm *** |
|---|
| 4 | !! Ocean physics: Internal gravity wave-driven vertical mixing |
|---|
| 5 | !!======================================================================== |
|---|
| 6 | !! History : 1.0 ! 2004-04 (L. Bessieres, G. Madec) Original code |
|---|
| 7 | !! - ! 2006-08 (A. Koch-Larrouy) Indonesian strait |
|---|
| 8 | !! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase |
|---|
| 9 | !! 3.6 ! 2016-03 (C. de Lavergne) New param: internal wave-driven mixing |
|---|
| 10 | !! 4.0 ! 2017-04 (G. Madec) renamed module, remove the old param. and the CPP keys |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! zdf_iwm : global momentum & tracer Kz with wave induced Kz |
|---|
| 15 | !! zdf_iwm_init : global momentum & tracer Kz with wave induced Kz |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE oce ! ocean dynamics and tracers variables |
|---|
| 18 | USE dom_oce ! ocean space and time domain variables |
|---|
| 19 | USE zdf_oce ! ocean vertical physics variables |
|---|
| 20 | USE zdfddm ! ocean vertical physics: double diffusive mixing |
|---|
| 21 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 22 | USE eosbn2 ! ocean equation of state |
|---|
| 23 | USE phycst ! physical constants |
|---|
| 24 | ! |
|---|
| 25 | USE fldread ! field read |
|---|
| 26 | USE prtctl ! Print control |
|---|
| 27 | USE in_out_manager ! I/O manager |
|---|
| 28 | USE iom ! I/O Manager |
|---|
| 29 | USE lib_mpp ! MPP library |
|---|
| 30 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 31 | |
|---|
| 32 | IMPLICIT NONE |
|---|
| 33 | PRIVATE |
|---|
| 34 | |
|---|
| 35 | PUBLIC zdf_iwm ! called in step module |
|---|
| 36 | PUBLIC zdf_iwm_init ! called in nemogcm module |
|---|
| 37 | |
|---|
| 38 | ! !!* Namelist namzdf_iwm : internal wave-driven mixing * |
|---|
| 39 | INTEGER :: nn_zpyc ! pycnocline-intensified mixing energy proportional to N (=1) or N^2 (=2) |
|---|
| 40 | LOGICAL :: ln_mevar ! variable (=T) or constant (=F) mixing efficiency |
|---|
| 41 | LOGICAL :: ln_tsdiff ! account for differential T/S wave-driven mixing (=T) or not (=F) |
|---|
| 42 | |
|---|
| 43 | REAL(wp):: r1_6 = 1._wp / 6._wp |
|---|
| 44 | |
|---|
| 45 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: ebot_iwm ! power available from high-mode wave breaking (W/m2) |
|---|
| 46 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: epyc_iwm ! power available from low-mode, pycnocline-intensified wave breaking (W/m2) |
|---|
| 47 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: ecri_iwm ! power available from low-mode, critical slope wave breaking (W/m2) |
|---|
| 48 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: hbot_iwm ! WKB decay scale for high-mode energy dissipation (m) |
|---|
| 49 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: hcri_iwm ! decay scale for low-mode critical slope dissipation (m) |
|---|
| 50 | |
|---|
| 51 | !! * Substitutions |
|---|
| 52 | # include "do_loop_substitute.h90" |
|---|
| 53 | # include "domzgr_substitute.h90" |
|---|
| 54 | !!---------------------------------------------------------------------- |
|---|
| 55 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 56 | !! $Id$ |
|---|
| 57 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 58 | !!---------------------------------------------------------------------- |
|---|
| 59 | CONTAINS |
|---|
| 60 | |
|---|
| 61 | INTEGER FUNCTION zdf_iwm_alloc() |
|---|
| 62 | !!---------------------------------------------------------------------- |
|---|
| 63 | !! *** FUNCTION zdf_iwm_alloc *** |
|---|
| 64 | !!---------------------------------------------------------------------- |
|---|
| 65 | ALLOCATE( ebot_iwm(jpi,jpj), epyc_iwm(jpi,jpj), ecri_iwm(jpi,jpj) , & |
|---|
| 66 | & hbot_iwm(jpi,jpj), hcri_iwm(jpi,jpj) , STAT=zdf_iwm_alloc ) |
|---|
| 67 | ! |
|---|
| 68 | CALL mpp_sum ( 'zdfiwm', zdf_iwm_alloc ) |
|---|
| 69 | IF( zdf_iwm_alloc /= 0 ) CALL ctl_stop( 'STOP', 'zdf_iwm_alloc: failed to allocate arrays' ) |
|---|
| 70 | END FUNCTION zdf_iwm_alloc |
|---|
| 71 | |
|---|
| 72 | |
|---|
| 73 | SUBROUTINE zdf_iwm( kt, Kmm, p_avm, p_avt, p_avs ) |
|---|
| 74 | !!---------------------------------------------------------------------- |
|---|
| 75 | !! *** ROUTINE zdf_iwm *** |
|---|
| 76 | !! |
|---|
| 77 | !! ** Purpose : add to the vertical mixing coefficients the effect of |
|---|
| 78 | !! breaking internal waves. |
|---|
| 79 | !! |
|---|
| 80 | !! ** Method : - internal wave-driven vertical mixing is given by: |
|---|
| 81 | !! Kz_wave = min( 100 cm2/s, f( Reb = zemx_iwm /( Nu * N^2 ) ) |
|---|
| 82 | !! where zemx_iwm is the 3D space distribution of the wave-breaking |
|---|
| 83 | !! energy and Nu the molecular kinematic viscosity. |
|---|
| 84 | !! The function f(Reb) is linear (constant mixing efficiency) |
|---|
| 85 | !! if the namelist parameter ln_mevar = F and nonlinear if ln_mevar = T. |
|---|
| 86 | !! |
|---|
| 87 | !! - Compute zemx_iwm, the 3D power density that allows to compute |
|---|
| 88 | !! Reb and therefrom the wave-induced vertical diffusivity. |
|---|
| 89 | !! This is divided into three components: |
|---|
| 90 | !! 1. Bottom-intensified low-mode dissipation at critical slopes |
|---|
| 91 | !! zemx_iwm(z) = ( ecri_iwm / rho0 ) * EXP( -(H-z)/hcri_iwm ) |
|---|
| 92 | !! / ( 1. - EXP( - H/hcri_iwm ) ) * hcri_iwm |
|---|
| 93 | !! where hcri_iwm is the characteristic length scale of the bottom |
|---|
| 94 | !! intensification, ecri_iwm a map of available power, and H the ocean depth. |
|---|
| 95 | !! 2. Pycnocline-intensified low-mode dissipation |
|---|
| 96 | !! zemx_iwm(z) = ( epyc_iwm / rho0 ) * ( sqrt(rn2(z))^nn_zpyc ) |
|---|
| 97 | !! / SUM( sqrt(rn2(z))^nn_zpyc * e3w[z) ) |
|---|
| 98 | !! where epyc_iwm is a map of available power, and nn_zpyc |
|---|
| 99 | !! is the chosen stratification-dependence of the internal wave |
|---|
| 100 | !! energy dissipation. |
|---|
| 101 | !! 3. WKB-height dependent high mode dissipation |
|---|
| 102 | !! zemx_iwm(z) = ( ebot_iwm / rho0 ) * rn2(z) * EXP(-z_wkb(z)/hbot_iwm) |
|---|
| 103 | !! / SUM( rn2(z) * EXP(-z_wkb(z)/hbot_iwm) * e3w[z) ) |
|---|
| 104 | !! where hbot_iwm is the characteristic length scale of the WKB bottom |
|---|
| 105 | !! intensification, ebot_iwm is a map of available power, and z_wkb is the |
|---|
| 106 | !! WKB-stretched height above bottom defined as |
|---|
| 107 | !! z_wkb(z) = H * SUM( sqrt(rn2(z'>=z)) * e3w[z'>=z) ) |
|---|
| 108 | !! / SUM( sqrt(rn2(z')) * e3w[z') ) |
|---|
| 109 | !! |
|---|
| 110 | !! - update the model vertical eddy viscosity and diffusivity: |
|---|
| 111 | !! avt = avt + av_wave |
|---|
| 112 | !! avm = avm + av_wave |
|---|
| 113 | !! |
|---|
| 114 | !! - if namelist parameter ln_tsdiff = T, account for differential mixing: |
|---|
| 115 | !! avs = avt + av_wave * diffusivity_ratio(Reb) |
|---|
| 116 | !! |
|---|
| 117 | !! ** Action : - avt, avs, avm, increased by tide internal wave-driven mixing |
|---|
| 118 | !! |
|---|
| 119 | !! References : de Lavergne et al. 2015, JPO; 2016, in prep. |
|---|
| 120 | !!---------------------------------------------------------------------- |
|---|
| 121 | INTEGER , INTENT(in ) :: kt ! ocean time step |
|---|
| 122 | INTEGER , INTENT(in ) :: Kmm ! time level index |
|---|
| 123 | REAL(wp), DIMENSION(:,:,:) , INTENT(inout) :: p_avm ! momentum Kz (w-points) |
|---|
| 124 | REAL(wp), DIMENSION(:,:,:) , INTENT(inout) :: p_avt, p_avs ! tracer Kz (w-points) |
|---|
| 125 | ! |
|---|
| 126 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 127 | REAL(wp), SAVE :: zztmp |
|---|
| 128 | REAL(wp) :: ztmp1, ztmp2 ! scalar workspace |
|---|
| 129 | REAL(wp), DIMENSION(A2D(nn_hls)) :: zfact ! Used for vertical structure |
|---|
| 130 | REAL(wp), DIMENSION(A2D(nn_hls)) :: zhdep ! Ocean depth |
|---|
| 131 | REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zwkb ! WKB-stretched height above bottom |
|---|
| 132 | REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zweight ! Weight for high mode vertical distribution |
|---|
| 133 | REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: znu_t ! Molecular kinematic viscosity (T grid) |
|---|
| 134 | REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: znu_w ! Molecular kinematic viscosity (W grid) |
|---|
| 135 | REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zReb ! Turbulence intensity parameter |
|---|
| 136 | REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zemx_iwm ! local energy density available for mixing (W/kg) |
|---|
| 137 | REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zav_ratio ! S/T diffusivity ratio (only for ln_tsdiff=T) |
|---|
| 138 | REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zav_wave ! Internal wave-induced diffusivity |
|---|
| 139 | REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: z3d ! 3D workspace used for iom_put |
|---|
| 140 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: z2d ! 2D - - - - |
|---|
| 141 | !!---------------------------------------------------------------------- |
|---|
| 142 | ! |
|---|
| 143 | ! |
|---|
| 144 | ! Set to zero the 1st and last vertical levels of appropriate variables |
|---|
| 145 | IF( iom_use("emix_iwm") ) THEN |
|---|
| 146 | zemx_iwm(:,:,:) = 0._wp |
|---|
| 147 | ENDIF |
|---|
| 148 | IF( iom_use("av_ratio") ) THEN |
|---|
| 149 | zav_ratio(:,:,:) = 0._wp |
|---|
| 150 | ENDIF |
|---|
| 151 | IF( iom_use("av_wave") .OR. sn_cfctl%l_prtctl ) THEN |
|---|
| 152 | zav_wave(:,:,:) = 0._wp |
|---|
| 153 | ENDIF |
|---|
| 154 | ! |
|---|
| 155 | ! ! ----------------------------- ! |
|---|
| 156 | ! ! Internal wave-driven mixing ! (compute zav_wave) |
|---|
| 157 | ! ! ----------------------------- ! |
|---|
| 158 | ! |
|---|
| 159 | ! !* Critical slope mixing: distribute energy over the time-varying ocean depth, |
|---|
| 160 | ! using an exponential decay from the seafloor. |
|---|
| 161 | DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 ) ! part independent of the level |
|---|
| 162 | zhdep(ji,jj) = gdepw_0(ji,jj,mbkt(ji,jj)+1) ! depth of the ocean |
|---|
| 163 | zfact(ji,jj) = rho0 * ( 1._wp - EXP( -zhdep(ji,jj) / hcri_iwm(ji,jj) ) ) |
|---|
| 164 | IF( zfact(ji,jj) /= 0._wp ) zfact(ji,jj) = ecri_iwm(ji,jj) / zfact(ji,jj) |
|---|
| 165 | END_2D |
|---|
| 166 | !!gm gde3w ==>>> check for ssh taken into account.... seem OK gde3w_n=gdept(:,:,:,Kmm) - ssh(:,:,Kmm) |
|---|
| 167 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) ! complete with the level-dependent part |
|---|
| 168 | IF ( zfact(ji,jj) == 0._wp .OR. wmask(ji,jj,jk) == 0._wp ) THEN ! optimization |
|---|
| 169 | zemx_iwm(ji,jj,jk) = 0._wp |
|---|
| 170 | ELSE |
|---|
| 171 | zemx_iwm(ji,jj,jk) = zfact(ji,jj) * ( EXP( ( gde3w(ji,jj,jk ) - zhdep(ji,jj) ) / hcri_iwm(ji,jj) ) & |
|---|
| 172 | & - EXP( ( gde3w(ji,jj,jk-1) - zhdep(ji,jj) ) / hcri_iwm(ji,jj) ) ) & |
|---|
| 173 | & / ( gde3w(ji,jj,jk) - gde3w(ji,jj,jk-1) ) |
|---|
| 174 | ENDIF |
|---|
| 175 | END_3D |
|---|
| 176 | !!gm delta(gde3w) = e3t(:,:,:,Kmm) !! Please verify the grid-point position w versus t-point |
|---|
| 177 | !!gm it seems to me that only 1/hcri_iwm is used ==> compute it one for all |
|---|
| 178 | |
|---|
| 179 | |
|---|
| 180 | ! !* Pycnocline-intensified mixing: distribute energy over the time-varying |
|---|
| 181 | ! !* ocean depth as proportional to sqrt(rn2)^nn_zpyc |
|---|
| 182 | ! ! (NB: N2 is masked, so no use of wmask here) |
|---|
| 183 | SELECT CASE ( nn_zpyc ) |
|---|
| 184 | ! |
|---|
| 185 | CASE ( 1 ) ! Dissipation scales as N (recommended) |
|---|
| 186 | ! |
|---|
| 187 | DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 ) |
|---|
| 188 | zfact(ji,jj) = 0._wp |
|---|
| 189 | END_2D |
|---|
| 190 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) ! part independent of the level |
|---|
| 191 | zfact(ji,jj) = zfact(ji,jj) + e3w(ji,jj,jk,Kmm) * SQRT( MAX( 0._wp, rn2(ji,jj,jk) ) ) * wmask(ji,jj,jk) |
|---|
| 192 | END_3D |
|---|
| 193 | ! |
|---|
| 194 | DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 ) |
|---|
| 195 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = epyc_iwm(ji,jj) / ( rho0 * zfact(ji,jj) ) |
|---|
| 196 | END_2D |
|---|
| 197 | ! |
|---|
| 198 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) ! complete with the level-dependent part |
|---|
| 199 | zemx_iwm(ji,jj,jk) = zemx_iwm(ji,jj,jk) + zfact(ji,jj) * SQRT( MAX( 0._wp, rn2(ji,jj,jk) ) ) * wmask(ji,jj,jk) |
|---|
| 200 | END_3D |
|---|
| 201 | ! |
|---|
| 202 | CASE ( 2 ) ! Dissipation scales as N^2 |
|---|
| 203 | ! |
|---|
| 204 | DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 ) |
|---|
| 205 | zfact(ji,jj) = 0._wp |
|---|
| 206 | END_2D |
|---|
| 207 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) ! part independent of the level |
|---|
| 208 | zfact(ji,jj) = zfact(ji,jj) + e3w(ji,jj,jk,Kmm) * MAX( 0._wp, rn2(ji,jj,jk) ) * wmask(ji,jj,jk) |
|---|
| 209 | END_3D |
|---|
| 210 | ! |
|---|
| 211 | DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 ) |
|---|
| 212 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = epyc_iwm(ji,jj) / ( rho0 * zfact(ji,jj) ) |
|---|
| 213 | END_2D |
|---|
| 214 | ! |
|---|
| 215 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) |
|---|
| 216 | zemx_iwm(ji,jj,jk) = zemx_iwm(ji,jj,jk) + zfact(ji,jj) * MAX( 0._wp, rn2(ji,jj,jk) ) * wmask(ji,jj,jk) |
|---|
| 217 | END_3D |
|---|
| 218 | ! |
|---|
| 219 | END SELECT |
|---|
| 220 | |
|---|
| 221 | ! !* WKB-height dependent mixing: distribute energy over the time-varying |
|---|
| 222 | ! !* ocean depth as proportional to rn2 * exp(-z_wkb/rn_hbot) |
|---|
| 223 | ! |
|---|
| 224 | DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 ) |
|---|
| 225 | zwkb(ji,jj,1) = 0._wp |
|---|
| 226 | END_2D |
|---|
| 227 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) |
|---|
| 228 | zwkb(ji,jj,jk) = zwkb(ji,jj,jk-1) + e3w(ji,jj,jk,Kmm) * SQRT( MAX( 0._wp, rn2(ji,jj,jk) ) ) * wmask(ji,jj,jk) |
|---|
| 229 | END_3D |
|---|
| 230 | DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 ) |
|---|
| 231 | zfact(ji,jj) = zwkb(ji,jj,jpkm1) |
|---|
| 232 | END_2D |
|---|
| 233 | ! |
|---|
| 234 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) |
|---|
| 235 | IF( zfact(ji,jj) /= 0 ) zwkb(ji,jj,jk) = zhdep(ji,jj) * ( zfact(ji,jj) - zwkb(ji,jj,jk) ) & |
|---|
| 236 | & * wmask(ji,jj,jk) / zfact(ji,jj) |
|---|
| 237 | END_3D |
|---|
| 238 | DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 ) |
|---|
| 239 | zwkb (ji,jj,1) = zhdep(ji,jj) * wmask(ji,jj,1) |
|---|
| 240 | END_2D |
|---|
| 241 | ! |
|---|
| 242 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) |
|---|
| 243 | IF ( rn2(ji,jj,jk) <= 0._wp .OR. wmask(ji,jj,jk) == 0._wp ) THEN ! optimization: EXP coast a lot |
|---|
| 244 | zweight(ji,jj,jk) = 0._wp |
|---|
| 245 | ELSE |
|---|
| 246 | zweight(ji,jj,jk) = rn2(ji,jj,jk) * hbot_iwm(ji,jj) & |
|---|
| 247 | & * ( EXP( -zwkb(ji,jj,jk) / hbot_iwm(ji,jj) ) - EXP( -zwkb(ji,jj,jk-1) / hbot_iwm(ji,jj) ) ) |
|---|
| 248 | ENDIF |
|---|
| 249 | END_3D |
|---|
| 250 | ! |
|---|
| 251 | DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 ) |
|---|
| 252 | zfact(ji,jj) = 0._wp |
|---|
| 253 | END_2D |
|---|
| 254 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) ! part independent of the level |
|---|
| 255 | zfact(ji,jj) = zfact(ji,jj) + zweight(ji,jj,jk) |
|---|
| 256 | END_3D |
|---|
| 257 | ! |
|---|
| 258 | DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 ) |
|---|
| 259 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = ebot_iwm(ji,jj) / ( rho0 * zfact(ji,jj) ) |
|---|
| 260 | END_2D |
|---|
| 261 | ! |
|---|
| 262 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) ! complete with the level-dependent part |
|---|
| 263 | zemx_iwm(ji,jj,jk) = zemx_iwm(ji,jj,jk) + zweight(ji,jj,jk) * zfact(ji,jj) * wmask(ji,jj,jk) & |
|---|
| 264 | & / ( gde3w(ji,jj,jk) - gde3w(ji,jj,jk-1) ) |
|---|
| 265 | !!gm use of e3t(ji,jj,:,Kmm) just above? |
|---|
| 266 | END_3D |
|---|
| 267 | ! |
|---|
| 268 | !!gm this is to be replaced by just a constant value znu=1.e-6 m2/s |
|---|
| 269 | ! Calculate molecular kinematic viscosity |
|---|
| 270 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 ) |
|---|
| 271 | znu_t(ji,jj,jk) = 1.e-4_wp * ( 17.91_wp - 0.53810_wp * ts(ji,jj,jk,jp_tem,Kmm) & |
|---|
| 272 | & + 0.00694_wp * ts(ji,jj,jk,jp_tem,Kmm) * ts(ji,jj,jk,jp_tem,Kmm) & |
|---|
| 273 | & + 0.02305_wp * ts(ji,jj,jk,jp_sal,Kmm) ) * tmask(ji,jj,jk) * r1_rho0 |
|---|
| 274 | END_3D |
|---|
| 275 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) |
|---|
| 276 | znu_w(ji,jj,jk) = 0.5_wp * ( znu_t(ji,jj,jk-1) + znu_t(ji,jj,jk) ) * wmask(ji,jj,jk) |
|---|
| 277 | END_3D |
|---|
| 278 | !!gm end |
|---|
| 279 | ! |
|---|
| 280 | ! Calculate turbulence intensity parameter Reb |
|---|
| 281 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) |
|---|
| 282 | zReb(ji,jj,jk) = zemx_iwm(ji,jj,jk) / MAX( 1.e-20_wp, znu_w(ji,jj,jk) * rn2(ji,jj,jk) ) |
|---|
| 283 | END_3D |
|---|
| 284 | ! |
|---|
| 285 | ! Define internal wave-induced diffusivity |
|---|
| 286 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) |
|---|
| 287 | zav_wave(ji,jj,jk) = znu_w(ji,jj,jk) * zReb(ji,jj,jk) * r1_6 ! This corresponds to a constant mixing efficiency of 1/6 |
|---|
| 288 | END_3D |
|---|
| 289 | ! |
|---|
| 290 | IF( ln_mevar ) THEN ! Variable mixing efficiency case : modify zav_wave in the |
|---|
| 291 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) ! energetic (Reb > 480) and buoyancy-controlled (Reb <10.224 ) regimes |
|---|
| 292 | IF( zReb(ji,jj,jk) > 480.00_wp ) THEN |
|---|
| 293 | zav_wave(ji,jj,jk) = 3.6515_wp * znu_w(ji,jj,jk) * SQRT( zReb(ji,jj,jk) ) |
|---|
| 294 | ELSEIF( zReb(ji,jj,jk) < 10.224_wp ) THEN |
|---|
| 295 | zav_wave(ji,jj,jk) = 0.052125_wp * znu_w(ji,jj,jk) * zReb(ji,jj,jk) * SQRT( zReb(ji,jj,jk) ) |
|---|
| 296 | ENDIF |
|---|
| 297 | END_3D |
|---|
| 298 | ENDIF |
|---|
| 299 | ! |
|---|
| 300 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) ! Bound diffusivity by molecular value and 100 cm2/s |
|---|
| 301 | zav_wave(ji,jj,jk) = MIN( MAX( 1.4e-7_wp, zav_wave(ji,jj,jk) ), 1.e-2_wp ) * wmask(ji,jj,jk) |
|---|
| 302 | END_3D |
|---|
| 303 | ! |
|---|
| 304 | IF( kt == nit000 ) THEN !* Control print at first time-step: diagnose the energy consumed by zav_wave |
|---|
| 305 | IF( .NOT. l_istiled .OR. ntile == 1 ) zztmp = 0._wp ! Do only on the first tile |
|---|
| 306 | !!gm used of glosum 3D.... |
|---|
| 307 | DO_3D( 0, 0, 0, 0, 2, jpkm1 ) |
|---|
| 308 | zztmp = zztmp + e3w(ji,jj,jk,Kmm) * e1e2t(ji,jj) & |
|---|
| 309 | & * MAX( 0._wp, rn2(ji,jj,jk) ) * zav_wave(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 310 | END_3D |
|---|
| 311 | |
|---|
| 312 | IF( .NOT. l_istiled .OR. ntile == nijtile ) THEN ! Do only on the last tile |
|---|
| 313 | CALL mpp_sum( 'zdfiwm', zztmp ) |
|---|
| 314 | zztmp = rho0 * zztmp ! Global integral of rauo * Kz * N^2 = power contributing to mixing |
|---|
| 315 | ! |
|---|
| 316 | IF(lwp) THEN |
|---|
| 317 | WRITE(numout,*) |
|---|
| 318 | WRITE(numout,*) 'zdf_iwm : Internal wave-driven mixing (iwm)' |
|---|
| 319 | WRITE(numout,*) '~~~~~~~ ' |
|---|
| 320 | WRITE(numout,*) |
|---|
| 321 | WRITE(numout,*) ' Total power consumption by av_wave = ', zztmp * 1.e-12_wp, 'TW' |
|---|
| 322 | ENDIF |
|---|
| 323 | ENDIF |
|---|
| 324 | ENDIF |
|---|
| 325 | |
|---|
| 326 | ! ! ----------------------- ! |
|---|
| 327 | ! ! Update mixing coefs ! |
|---|
| 328 | ! ! ----------------------- ! |
|---|
| 329 | ! |
|---|
| 330 | IF( ln_tsdiff ) THEN !* Option for differential mixing of salinity and temperature |
|---|
| 331 | ztmp1 = 0.505_wp + 0.495_wp * TANH( 0.92_wp * ( LOG10( 1.e-20_wp ) - 0.60_wp ) ) |
|---|
| 332 | DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) ! Calculate S/T diffusivity ratio as a function of Reb |
|---|
| 333 | ztmp2 = zReb(ji,jj,jk) * 5._wp * r1_6 |
|---|
| 334 | IF ( ztmp2 > 1.e-20_wp .AND. wmask(ji,jj,jk) == 1._wp ) THEN |
|---|
| 335 | zav_ratio(ji,jj,jk) = 0.505_wp + 0.495_wp * TANH( 0.92_wp * ( LOG10(ztmp2) - 0.60_wp ) ) |
|---|
| 336 | ELSE |
|---|
| 337 | zav_ratio(ji,jj,jk) = ztmp1 * wmask(ji,jj,jk) |
|---|
| 338 | ENDIF |
|---|
| 339 | END_3D |
|---|
| 340 | CALL iom_put( "av_ratio", zav_ratio ) |
|---|
| 341 | DO_3D_OVR( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) !* update momentum & tracer diffusivity with wave-driven mixing |
|---|
| 342 | p_avs(ji,jj,jk) = p_avs(ji,jj,jk) + zav_wave(ji,jj,jk) * zav_ratio(ji,jj,jk) |
|---|
| 343 | p_avt(ji,jj,jk) = p_avt(ji,jj,jk) + zav_wave(ji,jj,jk) |
|---|
| 344 | p_avm(ji,jj,jk) = p_avm(ji,jj,jk) + zav_wave(ji,jj,jk) |
|---|
| 345 | END_3D |
|---|
| 346 | ! |
|---|
| 347 | ELSE !* update momentum & tracer diffusivity with wave-driven mixing |
|---|
| 348 | DO_3D_OVR( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) |
|---|
| 349 | p_avs(ji,jj,jk) = p_avs(ji,jj,jk) + zav_wave(ji,jj,jk) |
|---|
| 350 | p_avt(ji,jj,jk) = p_avt(ji,jj,jk) + zav_wave(ji,jj,jk) |
|---|
| 351 | p_avm(ji,jj,jk) = p_avm(ji,jj,jk) + zav_wave(ji,jj,jk) |
|---|
| 352 | END_3D |
|---|
| 353 | ENDIF |
|---|
| 354 | |
|---|
| 355 | ! !* output internal wave-driven mixing coefficient |
|---|
| 356 | CALL iom_put( "av_wave", zav_wave ) |
|---|
| 357 | !* output useful diagnostics: Kz*N^2 , |
|---|
| 358 | !!gm Kz*N2 should take into account the ratio avs/avt if it is used.... (see diaar5) |
|---|
| 359 | ! vertical integral of rho0 * Kz * N^2 , energy density (zemx_iwm) |
|---|
| 360 | IF( iom_use("bflx_iwm") .OR. iom_use("pcmap_iwm") ) THEN |
|---|
| 361 | ALLOCATE( z2d(A2D(nn_hls)) , z3d(A2D(nn_hls),jpk) ) |
|---|
| 362 | ! Initialisation for iom_put |
|---|
| 363 | z2d(:,:) = 0._wp ; z3d(:,:,:) = 0._wp |
|---|
| 364 | |
|---|
| 365 | DO_3D( 0, 0, 0, 0, 2, jpkm1 ) |
|---|
| 366 | z3d(ji,jj,jk) = MAX( 0._wp, rn2(ji,jj,jk) ) * zav_wave(ji,jj,jk) |
|---|
| 367 | z2d(ji,jj) = z2d(ji,jj) + e3w(ji,jj,jk,Kmm) * z3d(ji,jj,jk) * wmask(ji,jj,jk) |
|---|
| 368 | END_3D |
|---|
| 369 | DO_2D( 0, 0, 0, 0 ) |
|---|
| 370 | z2d(ji,jj) = rho0 * z2d(ji,jj) |
|---|
| 371 | END_2D |
|---|
| 372 | CALL iom_put( "bflx_iwm", z3d ) |
|---|
| 373 | CALL iom_put( "pcmap_iwm", z2d ) |
|---|
| 374 | DEALLOCATE( z2d , z3d ) |
|---|
| 375 | ENDIF |
|---|
| 376 | CALL iom_put( "emix_iwm", zemx_iwm ) |
|---|
| 377 | |
|---|
| 378 | IF(sn_cfctl%l_prtctl) CALL prt_ctl(tab3d_1=zav_wave , clinfo1=' iwm - av_wave: ', tab3d_2=avt, clinfo2=' avt: ', kdim=jpk) |
|---|
| 379 | ! |
|---|
| 380 | END SUBROUTINE zdf_iwm |
|---|
| 381 | |
|---|
| 382 | |
|---|
| 383 | SUBROUTINE zdf_iwm_init |
|---|
| 384 | !!---------------------------------------------------------------------- |
|---|
| 385 | !! *** ROUTINE zdf_iwm_init *** |
|---|
| 386 | !! |
|---|
| 387 | !! ** Purpose : Initialization of the wave-driven vertical mixing, reading |
|---|
| 388 | !! of input power maps and decay length scales in netcdf files. |
|---|
| 389 | !! |
|---|
| 390 | !! ** Method : - Read the namzdf_iwm namelist and check the parameters |
|---|
| 391 | !! |
|---|
| 392 | !! - Read the input data in NetCDF files : |
|---|
| 393 | !! power available from high-mode wave breaking (mixing_power_bot.nc) |
|---|
| 394 | !! power available from pycnocline-intensified wave-breaking (mixing_power_pyc.nc) |
|---|
| 395 | !! power available from critical slope wave-breaking (mixing_power_cri.nc) |
|---|
| 396 | !! WKB decay scale for high-mode wave-breaking (decay_scale_bot.nc) |
|---|
| 397 | !! decay scale for critical slope wave-breaking (decay_scale_cri.nc) |
|---|
| 398 | !! |
|---|
| 399 | !! ** input : - Namlist namzdf_iwm |
|---|
| 400 | !! - NetCDF files : mixing_power_bot.nc, mixing_power_pyc.nc, mixing_power_cri.nc, |
|---|
| 401 | !! decay_scale_bot.nc decay_scale_cri.nc |
|---|
| 402 | !! |
|---|
| 403 | !! ** Action : - Increase by 1 the nstop flag is setting problem encounter |
|---|
| 404 | !! - Define ebot_iwm, epyc_iwm, ecri_iwm, hbot_iwm, hcri_iwm |
|---|
| 405 | !! |
|---|
| 406 | !! References : de Lavergne et al. JPO, 2015 ; de Lavergne PhD 2016 |
|---|
| 407 | !! de Lavergne et al. in prep., 2017 |
|---|
| 408 | !!---------------------------------------------------------------------- |
|---|
| 409 | INTEGER :: ifpr ! dummy loop indices |
|---|
| 410 | INTEGER :: inum ! local integer |
|---|
| 411 | INTEGER :: ios |
|---|
| 412 | REAL(wp) :: zbot, zpyc, zcri ! local scalars |
|---|
| 413 | ! |
|---|
| 414 | CHARACTER(len=256) :: cn_dir ! Root directory for location of ssr files |
|---|
| 415 | INTEGER, PARAMETER :: jpiwm = 5 ! maximum number of files to read |
|---|
| 416 | INTEGER, PARAMETER :: jp_mpb = 1 |
|---|
| 417 | INTEGER, PARAMETER :: jp_mpp = 2 |
|---|
| 418 | INTEGER, PARAMETER :: jp_mpc = 3 |
|---|
| 419 | INTEGER, PARAMETER :: jp_dsb = 4 |
|---|
| 420 | INTEGER, PARAMETER :: jp_dsc = 5 |
|---|
| 421 | ! |
|---|
| 422 | TYPE(FLD_N), DIMENSION(jpiwm) :: slf_iwm ! array of namelist informations |
|---|
| 423 | TYPE(FLD_N) :: sn_mpb, sn_mpp, sn_mpc ! informations about Mixing Power field to be read |
|---|
| 424 | TYPE(FLD_N) :: sn_dsb, sn_dsc ! informations about Decay Scale field to be read |
|---|
| 425 | TYPE(FLD ), DIMENSION(jpiwm) :: sf_iwm ! structure of input fields (file informations, fields read) |
|---|
| 426 | ! |
|---|
| 427 | NAMELIST/namzdf_iwm/ nn_zpyc, ln_mevar, ln_tsdiff, & |
|---|
| 428 | & cn_dir, sn_mpb, sn_mpp, sn_mpc, sn_dsb, sn_dsc |
|---|
| 429 | !!---------------------------------------------------------------------- |
|---|
| 430 | ! |
|---|
| 431 | READ ( numnam_ref, namzdf_iwm, IOSTAT = ios, ERR = 901) |
|---|
| 432 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_iwm in reference namelist' ) |
|---|
| 433 | ! |
|---|
| 434 | READ ( numnam_cfg, namzdf_iwm, IOSTAT = ios, ERR = 902 ) |
|---|
| 435 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namzdf_iwm in configuration namelist' ) |
|---|
| 436 | IF(lwm) WRITE ( numond, namzdf_iwm ) |
|---|
| 437 | ! |
|---|
| 438 | IF(lwp) THEN ! Control print |
|---|
| 439 | WRITE(numout,*) |
|---|
| 440 | WRITE(numout,*) 'zdf_iwm_init : internal wave-driven mixing' |
|---|
| 441 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 442 | WRITE(numout,*) ' Namelist namzdf_iwm : set wave-driven mixing parameters' |
|---|
| 443 | WRITE(numout,*) ' Pycnocline-intensified diss. scales as N (=1) or N^2 (=2) = ', nn_zpyc |
|---|
| 444 | WRITE(numout,*) ' Variable (T) or constant (F) mixing efficiency = ', ln_mevar |
|---|
| 445 | WRITE(numout,*) ' Differential internal wave-driven mixing (T) or not (F) = ', ln_tsdiff |
|---|
| 446 | ENDIF |
|---|
| 447 | |
|---|
| 448 | ! The new wave-driven mixing parameterization elevates avt and avm in the interior, and |
|---|
| 449 | ! ensures that avt remains larger than its molecular value (=1.4e-7). Therefore, avtb should |
|---|
| 450 | ! be set here to a very small value, and avmb to its (uniform) molecular value (=1.4e-6). |
|---|
| 451 | avmb(:) = 1.4e-6_wp ! viscous molecular value |
|---|
| 452 | avtb(:) = 1.e-10_wp ! very small diffusive minimum (background avt is specified in zdf_iwm) |
|---|
| 453 | avtb_2d(:,:) = 1.e0_wp ! uniform |
|---|
| 454 | IF(lwp) THEN ! Control print |
|---|
| 455 | WRITE(numout,*) |
|---|
| 456 | WRITE(numout,*) ' Force the background value applied to avm & avt in TKE to be everywhere ', & |
|---|
| 457 | & 'the viscous molecular value & a very small diffusive value, resp.' |
|---|
| 458 | ENDIF |
|---|
| 459 | |
|---|
| 460 | ! ! allocate iwm arrays |
|---|
| 461 | IF( zdf_iwm_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'zdf_iwm_init : unable to allocate iwm arrays' ) |
|---|
| 462 | ! |
|---|
| 463 | ! store namelist information in an array |
|---|
| 464 | slf_iwm(jp_mpb) = sn_mpb ; slf_iwm(jp_mpp) = sn_mpp ; slf_iwm(jp_mpc) = sn_mpc |
|---|
| 465 | slf_iwm(jp_dsb) = sn_dsb ; slf_iwm(jp_dsc) = sn_dsc |
|---|
| 466 | ! |
|---|
| 467 | DO ifpr= 1, jpiwm |
|---|
| 468 | ALLOCATE( sf_iwm(ifpr)%fnow(jpi,jpj,1) ) |
|---|
| 469 | IF( slf_iwm(ifpr)%ln_tint )ALLOCATE( sf_iwm(ifpr)%fdta(jpi,jpj,1,2) ) |
|---|
| 470 | END DO |
|---|
| 471 | |
|---|
| 472 | ! fill sf_iwm with sf_iwm and control print |
|---|
| 473 | CALL fld_fill( sf_iwm, slf_iwm , cn_dir, 'zdfiwm_init', 'iwm input file', 'namiwm' ) |
|---|
| 474 | |
|---|
| 475 | ! ! hard-coded default definition (to be defined in namelist ?) |
|---|
| 476 | sf_iwm(jp_mpb)%fnow(:,:,1) = 1.e-6 |
|---|
| 477 | sf_iwm(jp_mpp)%fnow(:,:,1) = 1.e-6 |
|---|
| 478 | sf_iwm(jp_mpc)%fnow(:,:,1) = 1.e-10 |
|---|
| 479 | sf_iwm(jp_dsb)%fnow(:,:,1) = 100. |
|---|
| 480 | sf_iwm(jp_dsc)%fnow(:,:,1) = 100. |
|---|
| 481 | |
|---|
| 482 | ! ! read necessary fields |
|---|
| 483 | CALL fld_read( nit000, 1, sf_iwm ) |
|---|
| 484 | |
|---|
| 485 | ebot_iwm(:,:) = sf_iwm(1)%fnow(:,:,1) * ssmask(:,:) ! energy flux for high-mode wave breaking [W/m2] |
|---|
| 486 | epyc_iwm(:,:) = sf_iwm(2)%fnow(:,:,1) * ssmask(:,:) ! energy flux for pynocline-intensified wave breaking [W/m2] |
|---|
| 487 | ecri_iwm(:,:) = sf_iwm(3)%fnow(:,:,1) * ssmask(:,:) ! energy flux for critical slope wave breaking [W/m2] |
|---|
| 488 | hbot_iwm(:,:) = sf_iwm(4)%fnow(:,:,1) ! spatially variable decay scale for high-mode wave breaking [m] |
|---|
| 489 | hcri_iwm(:,:) = sf_iwm(5)%fnow(:,:,1) ! spatially variable decay scale for critical slope wave breaking [m] |
|---|
| 490 | |
|---|
| 491 | zbot = glob_sum( 'zdfiwm', e1e2t(:,:) * ebot_iwm(:,:) ) |
|---|
| 492 | zpyc = glob_sum( 'zdfiwm', e1e2t(:,:) * epyc_iwm(:,:) ) |
|---|
| 493 | zcri = glob_sum( 'zdfiwm', e1e2t(:,:) * ecri_iwm(:,:) ) |
|---|
| 494 | |
|---|
| 495 | IF(lwp) THEN |
|---|
| 496 | WRITE(numout,*) ' High-mode wave-breaking energy: ', zbot * 1.e-12_wp, 'TW' |
|---|
| 497 | WRITE(numout,*) ' Pycnocline-intensifed wave-breaking energy: ', zpyc * 1.e-12_wp, 'TW' |
|---|
| 498 | WRITE(numout,*) ' Critical slope wave-breaking energy: ', zcri * 1.e-12_wp, 'TW' |
|---|
| 499 | ENDIF |
|---|
| 500 | ! |
|---|
| 501 | END SUBROUTINE zdf_iwm_init |
|---|
| 502 | |
|---|
| 503 | !!====================================================================== |
|---|
| 504 | END MODULE zdfiwm |
|---|
