New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcfwb.F90 in NEMO/branches/2021/ticket2680_C1D_PAPA/tests/ISOMIP+/MY_SRC – NEMO

source: NEMO/branches/2021/ticket2680_C1D_PAPA/tests/ISOMIP+/MY_SRC/sbcfwb.F90 @ 15015

Last change on this file since 15015 was 15015, checked in by gsamson, 3 years ago

merge trunk into branch (#2680)
File size: 14.9 KB
Line 
1MODULE sbcfwb
2   !!======================================================================
3   !!                       ***  MODULE  sbcfwb  ***
4   !! Ocean fluxes   : domain averaged freshwater budget
5   !!======================================================================
6   !! History :  OPA  ! 2001-02  (E. Durand)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-08  (G. Madec)  Surface module
9   !!            3.2  ! 2009-07  (C. Talandier) emp mean s spread over erp area
10   !!            3.6  ! 2014-11  (P. Mathiot  ) add ice shelf melting
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_fwb       : freshwater budget for global ocean configurations (free surface & forced mode)
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and tracers
17   USE dom_oce        ! ocean space and time domain
18   USE sbc_oce        ! surface ocean boundary condition
19   USE isf_oce , ONLY : fwfisf_cav, fwfisf_par, ln_isfcpl, ln_isfcpl_cons, risfcpl_cons_ssh ! ice shelf melting contribution
20   USE sbc_ice , ONLY : snwice_mass, snwice_mass_b, snwice_fmass
21   USE phycst         ! physical constants
22   USE sbcrnf         ! ocean runoffs
23   USE sbcssr         ! Sea-Surface damping terms
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            ! IOM
27   USE lib_mpp        ! distribued memory computing library
28   USE timing         ! Timing
29   USE lbclnk         ! ocean lateral boundary conditions
30   USE lib_fortran    !
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   sbc_fwb    ! routine called by step
36
37   REAL(wp) ::   rn_fwb0   ! initial freshwater adjustment flux [kg/m2/s] (nn_fwb = 2 only)
38   REAL(wp) ::   a_fwb     ! annual domain averaged freshwater budget from the
39                           ! previous year
40   REAL(wp) ::   area      ! global mean ocean surface (interior domain)
41
42   !!----------------------------------------------------------------------
43   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
44   !! $Id: sbcfwb.F90 11395 2019-08-02 14:19:00Z mathiot $
45   !! Software governed by the CeCILL license (see ./LICENSE)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc, Kmm )
50      !!---------------------------------------------------------------------
51      !!                  ***  ROUTINE sbc_fwb  ***
52      !!
53      !! ** Purpose :   Control the mean sea surface drift
54      !!
55      !! ** Method  :   several ways  depending on kn_fwb
56      !!                =0 no control
57      !!                =1 global mean of emp set to zero at each nn_fsbc time step
58      !!                =2 annual global mean corrected from previous year
59      !!                =3 global mean of emp set to zero at each nn_fsbc time step
60      !!                   & spread out over erp area depending its sign
61      !! Note: if sea ice is embedded it is taken into account when computing the budget
62      !!----------------------------------------------------------------------
63      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
64      INTEGER, INTENT( in ) ::   kn_fsbc  !
65      INTEGER, INTENT( in ) ::   kn_fwb   ! ocean time-step index
66      INTEGER, INTENT( in ) ::   Kmm      ! ocean time level index
67      !
68      INTEGER  ::   ios, inum, ikty       ! local integers
69      REAL(wp) ::   z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp                ! local scalars
70      REAL(wp) ::   zsurf_neg, zsurf_pos, zsurf_tospread, zcoef          !   -      -
71      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztmsk_neg, ztmsk_pos, z_wgt ! 2D workspaces
72      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztmsk_tospread, zerp_cor    !   -      -
73      REAL(wp)   ,DIMENSION(1) ::   z_fwfprv 
74      COMPLEX(dp),DIMENSION(1) ::   y_fwfnow 
75      !
76      NAMELIST/namsbc_fwb/rn_fwb0
77      !!----------------------------------------------------------------------
78      !
79      IF( kt == nit000 ) THEN
80         READ( numnam_ref, namsbc_fwb, IOSTAT = ios, ERR = 901 )
81901      IF( ios /= 0 ) CALL ctl_nam( ios, 'namsbc_fwb in reference namelist'     )
82         READ( numnam_cfg, namsbc_fwb, IOSTAT = ios, ERR = 902 )
83902      IF( ios >  0 ) CALL ctl_nam( ios, 'namsbc_fwb in configuration namelist' )
84         IF(lwm) WRITE( numond, namsbc_fwb )
85         IF(lwp) THEN
86            WRITE(numout,*)
87            WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction'
88            WRITE(numout,*) '~~~~~~~'
89            IF( kn_fwb == 1 )   WRITE(numout,*) '          instantaneously set to zero'
90            IF( kn_fwb == 4 )   WRITE(numout,*) '          instantaneously set to zero with heat and salt flux correction (ISOMIP+)'
91            IF( kn_fwb == 3 )   WRITE(numout,*) '          fwf set to zero and spread out over erp area'
92            IF( kn_fwb == 2 ) THEN
93               WRITE(numout,*) '          adjusted from previous year budget'
94               WRITE(numout,*)
95               WRITE(numout,*) '   Namelist namsbc_fwb'
96               WRITE(numout,*) '      Initial freshwater adjustment flux [kg/m2/s] = ', rn_fwb0
97            END IF
98         ENDIF
99         !
100         IF( kn_fwb == 3 .AND. nn_sssr /= 2 )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' )
101         IF( kn_fwb == 3 .AND. ln_isfcav    )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 with ln_isfcav = .TRUE. not working, we stop ' )
102         !
103         area = glob_sum( 'sbcfwb', e1e2t(:,:) * tmask(:,:,1))           ! interior global domain surface
104         ! isf cavities are excluded because it can feedback to the melting with generation of inhibition of plumes
105         ! and in case of no melt, it can generate HSSW.
106         !
107#if ! defined key_si3 && ! defined key_cice
108         snwice_mass_b(:,:) = 0.e0               ! no sea-ice model is being used : no snow+ice mass
109         snwice_mass  (:,:) = 0.e0
110         snwice_fmass (:,:) = 0.e0
111#endif
112         !
113      ENDIF
114
115      SELECT CASE ( kn_fwb )
116      !
117      CASE ( 1 )                             !==  global mean fwf set to zero  ==!
118         !
119         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
120            y_fwfnow(1) = local_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) - fwfisf_cav(:,:) - fwfisf_par(:,:) - snwice_fmass(:,:) ) )
121            CALL mpp_delay_sum( 'sbcfwb', 'fwb', y_fwfnow(:), z_fwfprv(:), kt == nitend - nn_fsbc + 1 )
122            z_fwfprv(1) = z_fwfprv(1) / area
123            zcoef = z_fwfprv(1) * rcp
124            emp(:,:) = emp(:,:) - z_fwfprv(1)        * tmask(:,:,1)
125            qns(:,:) = qns(:,:) + zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
126            ! outputs
127            IF( iom_use('hflx_fwb_cea') )  CALL iom_put( 'hflx_fwb_cea', zcoef * sst_m(:,:) * tmask(:,:,1) )
128            IF( iom_use('vflx_fwb_cea') )  CALL iom_put( 'vflx_fwb_cea', z_fwfprv(1)        * tmask(:,:,1) )
129         ENDIF
130         !
131      CASE ( 4 )                             !==  global mean fwf set to zero (ISOMIP case) ==!
132         !
133         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
134            z_fwf = glob_sum( 'sbcfwb',  e1e2t(:,:) * ( emp(:,:) - rnf(:,:) - fwfisf_cav(:,:) - fwfisf_par(:,:) - snwice_fmass(:,:) ) )
135            !
136            ! correction for ice sheet coupling testing (ie remove the excess through the surface)
137            ! test impact on the melt as conservation correction made in depth
138            ! test conservation level as sbcfwb is conserving
139            ! avoid the model to blow up for large ssh drop (isomip OCEAN3 with melt switch off and uniform T/S)
140            IF (ln_isfcpl .AND. ln_isfcpl_cons) THEN
141               z_fwf = z_fwf + glob_sum( 'sbcfwb',  e1e2t(:,:) * risfcpl_cons_ssh(:,:) * rho0 )
142            END IF
143            !
144            z_fwf = z_fwf / area
145            zcoef = z_fwf * rcp
146            emp(:,:) = emp(:,:) - z_fwf              * tmask(:,:,1) ! (Eq. 34 AD2015)
147            qns(:,:) = qns(:,:) + zcoef * sst_m(:,:) * tmask(:,:,1) ! (Eq. 35 AD2015) ! use sst_m to avoid generation of any bouyancy fluxes
148            sfx(:,:) = sfx(:,:) + z_fwf * sss_m(:,:) * tmask(:,:,1) ! (Eq. 36 AD2015) ! use sss_m to avoid generation of any bouyancy fluxes
149         ENDIF
150         !
151      CASE ( 2 )                             !==  fw adjustment based on fw budget at the end of the previous year  ==!
152         !
153         IF( kt == nit000 ) THEN                                                                    ! initialisation
154            !                                                                                       ! set the fw adjustment (a_fwb)
155            IF ( ln_rstart .AND. iom_varid( numror, 'a_fwb',   ldstop = .FALSE. ) > 0 ) THEN        !    as read from restart file
156               IF(lwp) WRITE(numout,*) 'sbc_fwb : reading FW-budget adjustment from restart file'
157               CALL iom_get( numror, 'a_fwb',   a_fwb )
158            ELSE                                                                                    !    as specified in namelist
159               a_fwb = rn_fwb0
160            END IF
161            !
162            IF(lwp)WRITE(numout,*)
163            IF(lwp)WRITE(numout,*)'sbc_fwb : initial freshwater-budget adjustment = ', a_fwb, 'kg/m2/s'
164            !
165         ENDIF   
166         !                                         ! Update a_fwb if new year start
167         ikty = 365 * 86400 / rn_Dt                  !!bug  use of 365 days leap year or 360d year !!!!!!!
168         IF( MOD( kt, ikty ) == 0 ) THEN
169                                                      ! mean sea level taking into account the ice+snow
170                                                      ! sum over the global domain
171            a_fwb   = glob_sum( 'sbcfwb', e1e2t(:,:) * ( ssh(:,:,Kmm) + snwice_mass(:,:) * r1_rho0 ) )
172            a_fwb   = a_fwb * 1.e+3 / ( area * rday * 365. )     ! convert in Kg/m3/s = mm/s
173!!gm        !                                                      !!bug 365d year
174         ENDIF
175         !
176         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN         ! correct the freshwater fluxes
177            zcoef = a_fwb * rcp
178            emp(:,:) = emp(:,:) + a_fwb              * tmask(:,:,1)
179            qns(:,:) = qns(:,:) - zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
180            ! outputs
181            IF( iom_use('hflx_fwb_cea') )  CALL iom_put( 'hflx_fwb_cea', -zcoef * sst_m(:,:) * tmask(:,:,1) )
182            IF( iom_use('vflx_fwb_cea') )  CALL iom_put( 'vflx_fwb_cea', -a_fwb              * tmask(:,:,1) )
183         ENDIF
184         ! Output restart information
185         IF( lrst_oce ) THEN
186            IF(lwp) WRITE(numout,*)
187            IF(lwp) WRITE(numout,*) 'sbc_fwb : writing FW-budget adjustment to ocean restart file at it = ', kt
188            IF(lwp) WRITE(numout,*) '~~~~'
189            CALL iom_rstput( kt, nitrst, numrow, 'a_fwb',   a_fwb )
190         END IF
191         !
192         IF( kt == nitend .AND. lwp ) WRITE(numout,*) 'sbc_fwb : final freshwater-budget adjustment = ', a_fwb, 'kg/m2/s'
193         !
194      CASE ( 3 )                             !==  global fwf set to zero and spread out over erp area  ==!
195         !
196         ALLOCATE( ztmsk_neg(jpi,jpj) , ztmsk_pos(jpi,jpj) , ztmsk_tospread(jpi,jpj) , z_wgt(jpi,jpj) , zerp_cor(jpi,jpj) )
197         !
198         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
199            ztmsk_pos(:,:) = tmask_i(:,:)                      ! Select <0 and >0 area of erp
200            WHERE( erp < 0._wp )   ztmsk_pos = 0._wp
201            ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:)
202            !                                                  ! fwf global mean (excluding ocean to ice/snow exchanges)
203            z_fwf     = glob_sum( 'sbcfwb', e1e2t(:,:) * ( emp(:,:) - rnf(:,:) - fwfisf_cav(:,:) - fwfisf_par(:,:) - snwice_fmass(:,:) ) ) / area
204            !           
205            IF( z_fwf < 0._wp ) THEN         ! spread out over >0 erp area to increase evaporation
206               zsurf_pos = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_pos(:,:) )
207               zsurf_tospread      = zsurf_pos
208               ztmsk_tospread(:,:) = ztmsk_pos(:,:)
209            ELSE                             ! spread out over <0 erp area to increase precipitation
210               zsurf_neg = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_neg(:,:) )  ! Area filled by <0 and >0 erp
211               zsurf_tospread      = zsurf_neg
212               ztmsk_tospread(:,:) = ztmsk_neg(:,:)
213            ENDIF
214            !
215            zsum_fwf   = glob_sum( 'sbcfwb', e1e2t(:,:) * z_fwf )         ! fwf global mean over <0 or >0 erp area
216!!gm :  zsum_fwf   = z_fwf * area   ???  it is right?  I think so....
217            z_fwf_nsrf =  zsum_fwf / ( zsurf_tospread + rsmall )
218            !                                                  ! weight to respect erp field 2D structure
219            zsum_erp   = glob_sum( 'sbcfwb', ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) )
220            z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall )
221            !                                                  ! final correction term to apply
222            zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:)
223            !
224!!gm   ===>>>>  lbc_lnk should be useless as all the computation is done over the whole domain !
225            CALL lbc_lnk( 'sbcfwb', zerp_cor, 'T', 1.0_wp )
226            !
227            emp(:,:) = emp(:,:) + zerp_cor(:,:)
228            qns(:,:) = qns(:,:) - zerp_cor(:,:) * rcp * sst_m(:,:)  ! account for change to the heat budget due to fw correction
229            erp(:,:) = erp(:,:) + zerp_cor(:,:)
230            ! outputs
231            IF( iom_use('hflx_fwb_cea') )  CALL iom_put( 'hflx_fwb_cea', -zerp_cor(:,:) * rcp * sst_m(:,:) )
232            IF( iom_use('vflx_fwb_cea') )  CALL iom_put( 'vflx_fwb_cea', -zerp_cor(:,:) )
233            !
234            IF( lwp ) THEN                   ! control print
235               IF( z_fwf < 0._wp ) THEN
236                  WRITE(numout,*)'   z_fwf < 0'
237                  WRITE(numout,*)'   SUM(erp+)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
238               ELSE
239                  WRITE(numout,*)'   z_fwf >= 0'
240                  WRITE(numout,*)'   SUM(erp-)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
241               ENDIF
242               WRITE(numout,*)'   SUM(empG)     = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv'
243               WRITE(numout,*)'   z_fwf         = ', z_fwf      ,' Kg/m2/s'
244               WRITE(numout,*)'   z_fwf_nsrf    = ', z_fwf_nsrf ,' Kg/m2/s'
245               WRITE(numout,*)'   MIN(zerp_cor) = ', MINVAL(zerp_cor) 
246               WRITE(numout,*)'   MAX(zerp_cor) = ', MAXVAL(zerp_cor) 
247            ENDIF
248         ENDIF
249         DEALLOCATE( ztmsk_neg , ztmsk_pos , ztmsk_tospread , z_wgt , zerp_cor )
250         !
251      CASE DEFAULT                           !==  you should never be there  ==!
252         CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' )
253         !
254      END SELECT
255      !
256   END SUBROUTINE sbc_fwb
257
258   !!======================================================================
259END MODULE sbcfwb
Note: See TracBrowser for help on using the repository browser.