New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iom.F90 in NEMO/branches/NERC/dev_release-3.4_NEMOTAM_consolidated/NEMOGCM/NEMO/OPA_SRC/IOM – NEMO

source: NEMO/branches/NERC/dev_release-3.4_NEMOTAM_consolidated/NEMOGCM/NEMO/OPA_SRC/IOM/iom.F90 @ 11809

Last change on this file since 11809 was 3720, checked in by cbricaud, 11 years ago

correction ticket 955 & 956
  • Property svn:keywords set to Id
File size: 63.1 KB
Line 
1MODULE iom
2   !!=====================================================================
3   !!                    ***  MODULE  iom ***
4   !! Input/Output manager :  Library to read input files
5   !!====================================================================
6   !! History :  2.0  ! 2005-12  (J. Belier) Original code
7   !!            2.0  ! 2006-02  (S. Masson) Adaptation to NEMO
8   !!            3.0  ! 2007-07  (D. Storkey) Changes to iom_gettime
9   !!            3.4  ! 2012-12  (R. Bourdalle-Badie and G. Reffray)  add C1D case 
10   !!--------------------------------------------------------------------
11
12   !!--------------------------------------------------------------------
13   !!   iom_open       : open a file read only
14   !!   iom_close      : close a file or all files opened by iom
15   !!   iom_get        : read a field (interfaced to several routines)
16   !!   iom_gettime    : read the time axis cdvar in the file
17   !!   iom_varid      : get the id of a variable in a file
18   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
19   !!--------------------------------------------------------------------
20   USE dom_oce         ! ocean space and time domain
21   USE c1d             ! 1D vertical configuration
22   USE flo_oce         ! floats module declarations
23   USE lbclnk          ! lateal boundary condition / mpp exchanges
24   USE iom_def         ! iom variables definitions
25   USE iom_ioipsl      ! NetCDF format with IOIPSL library
26   USE iom_nf90        ! NetCDF format with native NetCDF library
27   USE iom_rstdimg     ! restarts access direct format "dimg" style...
28   USE in_out_manager  ! I/O manager
29   USE lib_mpp           ! MPP library
30#if defined key_iomput
31   USE sbc_oce, ONLY :   nn_fsbc         ! ocean space and time domain
32   USE domngb          ! ocean space and time domain
33   USE phycst          ! physical constants
34   USE dianam          ! build name of file
35   USE mod_event_client
36   USE mod_attribut
37# endif
38
39   IMPLICIT NONE
40   PUBLIC   !   must be public to be able to access iom_def through iom
41   
42#if defined key_iomput
43   LOGICAL, PUBLIC, PARAMETER ::   lk_iomput = .TRUE.        !: iom_put flag
44#else
45   LOGICAL, PUBLIC, PARAMETER ::   lk_iomput = .FALSE.       !: iom_put flag
46#endif
47   PUBLIC iom_init, iom_swap, iom_open, iom_close, iom_setkt, iom_varid, iom_get, iom_gettime, iom_rstput, iom_put
48   PUBLIC iom_getatt
49
50   PRIVATE iom_rp0d, iom_rp1d, iom_rp2d, iom_rp3d
51   PRIVATE iom_g0d, iom_g1d, iom_g2d, iom_g3d, iom_get_123d
52   PRIVATE iom_p1d, iom_p2d, iom_p3d
53#if defined key_iomput
54   PRIVATE set_grid
55# endif
56
57   INTERFACE iom_get
58      MODULE PROCEDURE iom_g0d, iom_g1d, iom_g2d, iom_g3d
59   END INTERFACE
60   INTERFACE iom_getatt
61      MODULE PROCEDURE iom_g0d_intatt
62   END INTERFACE
63   INTERFACE iom_rstput
64      MODULE PROCEDURE iom_rp0d, iom_rp1d, iom_rp2d, iom_rp3d
65   END INTERFACE
66  INTERFACE iom_put
67     MODULE PROCEDURE iom_p0d, iom_p1d, iom_p2d, iom_p3d
68  END INTERFACE
69#if defined key_iomput
70   INTERFACE iom_setkt
71      MODULE PROCEDURE event__set_timestep
72   END INTERFACE
73# endif
74
75   !!----------------------------------------------------------------------
76   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
77   !! $Id$
78   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
79   !!----------------------------------------------------------------------
80
81CONTAINS
82
83   SUBROUTINE iom_init
84      !!----------------------------------------------------------------------
85      !!                     ***  ROUTINE   ***
86      !!
87      !! ** Purpose :   
88      !!
89      !!----------------------------------------------------------------------
90#if defined key_iomput
91      REAL(wp) ::   ztmp
92      !!----------------------------------------------------------------------
93      ! read the xml file
94      IF( Agrif_Root() ) CALL event__parse_xml_file( 'iodef.xml' )   ! <- to get from the nameliste (namrun)...
95      CALL iom_swap
96
97      ! calendar parameters
98      SELECT CASE ( nleapy )        ! Choose calendar for IOIPSL
99      CASE ( 1)   ;   CALL event__set_calendar('gregorian')
100      CASE ( 0)   ;   CALL event__set_calendar('noleap'   )
101      CASE (30)   ;   CALL event__set_calendar('360d'     )
102      END SELECT
103      ztmp = fjulday - adatrj
104      IF( ABS(ztmp  - REAL(NINT(ztmp),wp)) < 0.1 / rday )   ztmp = REAL(NINT(ztmp),wp)   ! avoid truncation error
105      CALL event__set_time_parameters( nit000 - 1, ztmp, rdt )
106
107      ! horizontal grid definition
108      CALL set_scalar
109      CALL set_grid( "grid_T", glamt, gphit )
110      CALL set_grid( "grid_U", glamu, gphiu )
111      CALL set_grid( "grid_V", glamv, gphiv )
112      CALL set_grid( "grid_W", glamt, gphit )
113
114      ! vertical grid definition
115      CALL event__set_vert_axis( "deptht", gdept_0 )
116      CALL event__set_vert_axis( "depthu", gdept_0 )
117      CALL event__set_vert_axis( "depthv", gdept_0 )
118      CALL event__set_vert_axis( "depthw", gdepw_0 )
119# if defined key_floats
120      CALL event__set_vert_axis( "nfloat", REAL(nfloat,wp)  )
121# endif
122     
123      ! automatic definitions of some of the xml attributs
124      CALL set_xmlatt
125
126      ! end file definition
127      CALL event__close_io_definition
128#endif
129
130   END SUBROUTINE iom_init
131
132
133   SUBROUTINE iom_swap
134      !!---------------------------------------------------------------------
135      !!                   ***  SUBROUTINE  iom_swap  ***
136      !!
137      !! ** Purpose :  swap context between different agrif grid for xmlio_server
138      !!---------------------------------------------------------------------
139#if defined key_iomput
140
141     IF( TRIM(Agrif_CFixed()) == '0' ) THEN
142        CALL event__swap_context("nemo")
143     ELSE
144        CALL event__swap_context(TRIM(Agrif_CFixed())//"_nemo")
145     ENDIF
146
147#endif
148   END SUBROUTINE iom_swap
149
150
151   SUBROUTINE iom_open( cdname, kiomid, ldwrt, kdom, kiolib, ldstop, ldiof )
152      !!---------------------------------------------------------------------
153      !!                   ***  SUBROUTINE  iom_open  ***
154      !!
155      !! ** Purpose :  open an input file (return 0 if not found)
156      !!---------------------------------------------------------------------
157      CHARACTER(len=*), INTENT(in   )           ::   cdname   ! File name
158      INTEGER         , INTENT(  out)           ::   kiomid   ! iom identifier of the opened file
159      LOGICAL         , INTENT(in   ), OPTIONAL ::   ldwrt    ! open in write modeb          (default = .FALSE.)
160      INTEGER         , INTENT(in   ), OPTIONAL ::   kdom     ! Type of domain to be written (default = jpdom_local_noovlap)
161      INTEGER         , INTENT(in   ), OPTIONAL ::   kiolib   ! library used to open the file (default = jpnf90)
162      LOGICAL         , INTENT(in   ), OPTIONAL ::   ldstop   ! stop if open to read a non-existing file (default = .TRUE.)
163      LOGICAL         , INTENT(in   ), OPTIONAL ::   ldiof    ! Interp On the Fly, needed for AGRIF (default = .FALSE.)
164
165      CHARACTER(LEN=100)    ::   clname    ! the name of the file based on cdname [[+clcpu]+clcpu]
166      CHARACTER(LEN=100)    ::   cltmpn    ! tempory name to store clname (in writting mode)
167      CHARACTER(LEN=10)     ::   clsuffix  ! ".nc" or ".dimg"
168      CHARACTER(LEN=15)     ::   clcpu     ! the cpu number (max jpmax_digits digits)
169      CHARACTER(LEN=100)    ::   clinfo    ! info character
170      LOGICAL               ::   llok      ! check the existence
171      LOGICAL               ::   llwrt     ! local definition of ldwrt
172      LOGICAL               ::   llnoov    ! local definition to read overlap
173      LOGICAL               ::   llstop    ! local definition of ldstop
174      LOGICAL               ::   lliof     ! local definition of ldiof
175      INTEGER               ::   iolib     ! library do we use to open the file
176      INTEGER               ::   icnt      ! counter for digits in clcpu (max = jpmax_digits)
177      INTEGER               ::   iln, ils  ! lengths of character
178      INTEGER               ::   idom      ! type of domain
179      INTEGER               ::   istop     !
180      INTEGER, DIMENSION(2,5) ::   idompar ! domain parameters:
181      ! local number of points for x,y dimensions
182      ! position of first local point for x,y dimensions
183      ! position of last local point for x,y dimensions
184      ! start halo size for x,y dimensions
185      ! end halo size for x,y dimensions
186      !---------------------------------------------------------------------
187      ! Initializations and control
188      ! =============
189      kiomid = -1
190      clinfo = '                    iom_open ~~~  '
191      istop = nstop
192      ! if iom_open is called for the first time: initialize iom_file(:)%nfid to 0
193      ! (could be done when defining iom_file in f95 but not in f90)
194      IF( Agrif_Root() ) THEN
195         IF( iom_open_init == 0 ) THEN
196            iom_file(:)%nfid = 0
197            iom_open_init = 1
198         ENDIF
199      ENDIF
200      ! do we read or write the file?
201      IF( PRESENT(ldwrt) ) THEN   ;   llwrt = ldwrt
202      ELSE                        ;   llwrt = .FALSE.
203      ENDIF
204      ! do we call ctl_stop if we try to open a non-existing file in read mode?
205      IF( PRESENT(ldstop) ) THEN   ;   llstop = ldstop
206      ELSE                         ;   llstop = .TRUE.
207      ENDIF
208      ! what library do we use to open the file?
209      IF( PRESENT(kiolib) ) THEN   ;   iolib = kiolib
210      ELSE                         ;   iolib = jpnf90
211      ENDIF
212      ! are we using interpolation on the fly?
213      IF( PRESENT(ldiof) ) THEN   ;   lliof = ldiof
214      ELSE                        ;   lliof = .FALSE.
215      ENDIF
216      ! do we read the overlap
217      ! ugly patch SM+JMM+RB to overwrite global definition in some cases
218      llnoov = (jpni * jpnj ) == jpnij .AND. .NOT. lk_agrif 
219      ! create the file name by added, if needed, TRIM(Agrif_CFixed()) and TRIM(clsuffix)
220      ! =============
221      clname   = trim(cdname)
222      IF ( .NOT. Agrif_Root() .AND. .NOT. lliof ) THEN
223         iln    = INDEX(clname,'/') 
224         cltmpn = clname(1:iln)
225         clname = clname(iln+1:LEN_TRIM(clname))
226         clname=TRIM(cltmpn)//TRIM(Agrif_CFixed())//'_'//TRIM(clname)
227      ENDIF
228      ! which suffix should we use?
229      SELECT CASE (iolib)
230      CASE (jpioipsl ) ;   clsuffix = '.nc'
231      CASE (jpnf90   ) ;   clsuffix = '.nc'
232      CASE (jprstdimg) ;   clsuffix = '.dimg'
233      CASE DEFAULT     ;   clsuffix = ''
234         CALL ctl_stop( TRIM(clinfo), 'accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
235      END SELECT
236      ! Add the suffix if needed
237      iln = LEN_TRIM(clname)
238      ils = LEN_TRIM(clsuffix)
239      IF( iln <= ils .OR. INDEX( TRIM(clname), TRIM(clsuffix), back = .TRUE. ) /= iln - ils + 1 )   &
240         &   clname = TRIM(clname)//TRIM(clsuffix)
241      cltmpn = clname   ! store this name
242      ! try to find if the file to be opened already exist
243      ! =============
244      INQUIRE( FILE = clname, EXIST = llok )
245      IF( .NOT.llok ) THEN
246         ! we try to add the cpu number to the name
247         IF( iolib == jprstdimg ) THEN   ;   WRITE(clcpu,*) narea
248         ELSE                            ;   WRITE(clcpu,*) narea-1
249         ENDIF
250         clcpu  = TRIM(ADJUSTL(clcpu))
251         iln = INDEX(clname,TRIM(clsuffix), back = .TRUE.)
252         clname = clname(1:iln-1)//'_'//TRIM(clcpu)//TRIM(clsuffix)
253         icnt = 0
254         INQUIRE( FILE = clname, EXIST = llok ) 
255         ! we try different formats for the cpu number by adding 0
256         DO WHILE( .NOT.llok .AND. icnt < jpmax_digits )
257            clcpu  = "0"//trim(clcpu)
258            clname = clname(1:iln-1)//'_'//TRIM(clcpu)//TRIM(clsuffix)
259            INQUIRE( FILE = clname, EXIST = llok )
260            icnt = icnt + 1
261         END DO
262      ENDIF
263      IF( llwrt ) THEN
264         ! check the domain definition
265! JMM + SM: ugly patch before getting the new version of lib_mpp)
266!         idom = jpdom_local_noovlap   ! default definition
267         IF( llnoov ) THEN   ;   idom = jpdom_local_noovlap   ! default definition
268         ELSE                ;   idom = jpdom_local_full      ! default definition
269         ENDIF
270         IF( PRESENT(kdom) )   idom = kdom
271         ! create the domain informations
272         ! =============
273         SELECT CASE (idom)
274         CASE (jpdom_local_full)
275            idompar(:,1) = (/ jpi             , jpj              /)
276            idompar(:,2) = (/ nimpp           , njmpp            /)
277            idompar(:,3) = (/ nimpp + jpi - 1 , njmpp + jpj - 1  /)
278            idompar(:,4) = (/ nldi - 1        , nldj - 1         /)
279            idompar(:,5) = (/ jpi - nlei      , jpj - nlej       /)
280         CASE (jpdom_local_noextra)
281            idompar(:,1) = (/ nlci            , nlcj             /)
282            idompar(:,2) = (/ nimpp           , njmpp            /)
283            idompar(:,3) = (/ nimpp + nlci - 1, njmpp + nlcj - 1 /)
284            idompar(:,4) = (/ nldi - 1        , nldj - 1         /)
285            idompar(:,5) = (/ nlci - nlei     , nlcj - nlej      /)
286         CASE (jpdom_local_noovlap)
287            idompar(:,1) = (/ nlei  - nldi + 1, nlej  - nldj + 1 /)
288            idompar(:,2) = (/ nimpp + nldi - 1, njmpp + nldj - 1 /)
289            idompar(:,3) = (/ nimpp + nlei - 1, njmpp + nlej - 1 /)
290            idompar(:,4) = (/ 0               , 0                /)
291            idompar(:,5) = (/ 0               , 0                /)
292         CASE DEFAULT
293            CALL ctl_stop( TRIM(clinfo), 'wrong value of kdom, only jpdom_local* cases are accepted' )
294         END SELECT
295      ENDIF
296      ! Open the NetCDF or RSTDIMG file
297      ! =============
298      ! do we have some free file identifier?
299      IF( MINVAL(iom_file(:)%nfid) /= 0 )   &
300         &   CALL ctl_stop( TRIM(clinfo), 'No more free file identifier', 'increase jpmax_files in iom_def' )
301      ! if no file was found...
302      IF( .NOT. llok ) THEN
303         IF( .NOT. llwrt ) THEN   ! we are in read mode
304            IF( llstop ) THEN   ;   CALL ctl_stop( TRIM(clinfo), 'File '//TRIM(cltmpn)//'* not found' )
305            ELSE                ;   istop = nstop + 1   ! make sure that istop /= nstop so we don't open the file
306            ENDIF
307         ELSE                     ! we are in write mode so we
308            clname = cltmpn       ! get back the file name without the cpu number
309         ENDIF
310      ELSE
311         IF( llwrt .AND. .NOT. ln_clobber ) THEN   ! we stop as we want to write in a new file
312            CALL ctl_stop( TRIM(clinfo), 'We want to write in a new file but '//TRIM(clname)//' already exists...' )
313            istop = nstop + 1                      ! make sure that istop /= nstop so we don't open the file
314         ENDIF
315      ENDIF
316      IF( istop == nstop ) THEN   ! no error within this routine
317         SELECT CASE (iolib)
318         CASE (jpioipsl )   ;   CALL iom_ioipsl_open(  clname, kiomid, llwrt, llok, idompar )
319         CASE (jpnf90   )   ;   CALL iom_nf90_open(    clname, kiomid, llwrt, llok, idompar )
320         CASE (jprstdimg)   ;   CALL iom_rstdimg_open( clname, kiomid, llwrt, llok, idompar )
321         CASE DEFAULT
322            CALL ctl_stop( TRIM(clinfo)//' accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
323         END SELECT
324      ENDIF
325      !
326   END SUBROUTINE iom_open
327
328
329   SUBROUTINE iom_close( kiomid )
330      !!--------------------------------------------------------------------
331      !!                   ***  SUBROUTINE  iom_close  ***
332      !!
333      !! ** Purpose : close an input file, or all files opened by iom
334      !!--------------------------------------------------------------------
335      INTEGER, INTENT(inout), OPTIONAL ::   kiomid   ! iom identifier of the file to be closed
336      !                                              ! return 0 when file is properly closed
337      !                                              ! No argument: all files opened by iom are closed
338
339      INTEGER ::   jf         ! dummy loop indices
340      INTEGER ::   i_s, i_e   ! temporary integer
341      CHARACTER(LEN=100)    ::   clinfo    ! info character
342      !---------------------------------------------------------------------
343      !
344      clinfo = '                    iom_close ~~~  '
345      IF( PRESENT(kiomid) ) THEN
346         i_s = kiomid
347         i_e = kiomid
348      ELSE
349         i_s = 1
350         i_e = jpmax_files
351#if defined key_iomput
352         CALL event__stop_ioserver
353#endif
354      ENDIF
355
356      IF( i_s > 0 ) THEN
357         DO jf = i_s, i_e
358            IF( iom_file(jf)%nfid > 0 ) THEN
359               SELECT CASE (iom_file(jf)%iolib)
360               CASE (jpioipsl )   ;   CALL iom_ioipsl_close(  jf )
361               CASE (jpnf90   )   ;   CALL iom_nf90_close(    jf )
362               CASE (jprstdimg)   ;   CALL iom_rstdimg_close( jf )
363               CASE DEFAULT
364                  CALL ctl_stop( TRIM(clinfo)//' accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
365               END SELECT
366               iom_file(jf)%nfid       = 0          ! free the id
367               IF( PRESENT(kiomid) )   kiomid = 0   ! return 0 as id to specify that the file was closed
368               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' close file: '//TRIM(iom_file(jf)%name)//' ok'
369            ELSEIF( PRESENT(kiomid) ) THEN
370               WRITE(ctmp1,*) '--->',  kiomid
371               CALL ctl_stop( TRIM(clinfo)//' Invalid file identifier', ctmp1 )
372            ENDIF
373         END DO
374      ENDIF
375      !   
376   END SUBROUTINE iom_close
377
378
379   FUNCTION iom_varid ( kiomid, cdvar, kdimsz, ldstop ) 
380      !!-----------------------------------------------------------------------
381      !!                  ***  FUNCTION  iom_varid  ***
382      !!
383      !! ** Purpose : get the id of a variable in a file (return 0 if not found)
384      !!-----------------------------------------------------------------------
385      INTEGER              , INTENT(in   )           ::   kiomid   ! file Identifier
386      CHARACTER(len=*)     , INTENT(in   )           ::   cdvar    ! name of the variable
387      INTEGER, DIMENSION(:), INTENT(  out), OPTIONAL ::   kdimsz   ! size of the dimensions
388      LOGICAL              , INTENT(in   ), OPTIONAL ::   ldstop   ! stop if looking for non-existing variable (default = .TRUE.)
389      !
390      INTEGER                        ::   iom_varid, iiv, i_nvd
391      LOGICAL                        ::   ll_fnd
392      CHARACTER(LEN=100)             ::   clinfo                   ! info character
393      LOGICAL                        ::   llstop                   ! local definition of ldstop
394      !!-----------------------------------------------------------------------
395      iom_varid = 0                         ! default definition
396      ! do we call ctl_stop if we look for non-existing variable?
397      IF( PRESENT(ldstop) ) THEN   ;   llstop = ldstop
398      ELSE                         ;   llstop = .TRUE.
399      ENDIF
400      !
401      IF( kiomid > 0 ) THEN
402         clinfo = 'iom_varid, file: '//trim(iom_file(kiomid)%name)//', var: '//trim(cdvar)
403         IF( iom_file(kiomid)%nfid == 0 ) THEN
404            CALL ctl_stop( trim(clinfo), 'the file is not open' )
405         ELSE
406            ll_fnd  = .FALSE.
407            iiv = 0
408            !
409            DO WHILE ( .NOT.ll_fnd .AND. iiv < iom_file(kiomid)%nvars )
410               iiv = iiv + 1
411               ll_fnd  = ( TRIM(cdvar) == TRIM(iom_file(kiomid)%cn_var(iiv)) )
412            END DO
413            !
414            IF( .NOT.ll_fnd ) THEN
415               iiv = iiv + 1
416               IF( iiv <= jpmax_vars ) THEN
417                  SELECT CASE (iom_file(kiomid)%iolib)
418                  CASE (jpioipsl )   ;   iom_varid = iom_ioipsl_varid( kiomid, cdvar, iiv, kdimsz )
419                  CASE (jpnf90   )   ;   iom_varid = iom_nf90_varid  ( kiomid, cdvar, iiv, kdimsz )
420                  CASE (jprstdimg)   ;   iom_varid = -1   ! all variables are listed in iom_file
421                  CASE DEFAULT   
422                     CALL ctl_stop( TRIM(clinfo)//' accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
423                  END SELECT
424               ELSE
425                  CALL ctl_stop( trim(clinfo), 'Too many variables in the file '//iom_file(kiomid)%name,   &
426                        &                         'increase the parameter jpmax_vars')
427               ENDIF
428               IF( llstop .AND. iom_varid == -1 )   CALL ctl_stop( TRIM(clinfo)//' not found' ) 
429            ELSE
430               iom_varid = iiv
431               IF( PRESENT(kdimsz) ) THEN
432                  i_nvd = iom_file(kiomid)%ndims(iiv)
433                  IF( i_nvd == size(kdimsz) ) THEN
434                     kdimsz(:) = iom_file(kiomid)%dimsz(1:i_nvd,iiv)
435                  ELSE
436                     WRITE(ctmp1,*) i_nvd, size(kdimsz)
437                     CALL ctl_stop( trim(clinfo), 'error in kdimsz size'//trim(ctmp1) )
438                  ENDIF
439               ENDIF
440            ENDIF
441         ENDIF
442      ENDIF
443      !
444   END FUNCTION iom_varid
445
446
447   !!----------------------------------------------------------------------
448   !!                   INTERFACE iom_get
449   !!----------------------------------------------------------------------
450   SUBROUTINE iom_g0d( kiomid, cdvar, pvar )
451      INTEGER         , INTENT(in   )                 ::   kiomid    ! Identifier of the file
452      CHARACTER(len=*), INTENT(in   )                 ::   cdvar     ! Name of the variable
453      REAL(wp)        , INTENT(  out)                 ::   pvar      ! read field
454      !
455      INTEGER               :: idvar   ! variable id
456      !
457      IF( kiomid > 0 ) THEN
458         idvar = iom_varid( kiomid, cdvar )
459         IF( iom_file(kiomid)%nfid > 0 .AND. idvar > 0 ) THEN
460            SELECT CASE (iom_file(kiomid)%iolib)
461            CASE (jpioipsl )   ;   CALL iom_ioipsl_get(  kiomid, idvar, pvar )
462            CASE (jpnf90   )   ;   CALL iom_nf90_get(    kiomid, idvar, pvar )
463            CASE (jprstdimg)   ;   CALL iom_rstdimg_get( kiomid, idvar, pvar )
464            CASE DEFAULT   
465               CALL ctl_stop( 'iom_g0d: accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
466            END SELECT
467         ENDIF
468      ENDIF
469   END SUBROUTINE iom_g0d
470
471   SUBROUTINE iom_g1d( kiomid, kdom, cdvar, pvar, ktime, kstart, kcount )
472      INTEGER         , INTENT(in   )                         ::   kiomid    ! Identifier of the file
473      INTEGER         , INTENT(in   )                         ::   kdom      ! Type of domain to be read
474      CHARACTER(len=*), INTENT(in   )                         ::   cdvar     ! Name of the variable
475      REAL(wp)        , INTENT(  out), DIMENSION(:)           ::   pvar      ! read field
476      INTEGER         , INTENT(in   )              , OPTIONAL ::   ktime     ! record number
477      INTEGER         , INTENT(in   ), DIMENSION(1), OPTIONAL ::   kstart    ! start axis position of the reading
478      INTEGER         , INTENT(in   ), DIMENSION(1), OPTIONAL ::   kcount    ! number of points in each axis
479      !
480      IF( kiomid > 0 ) THEN
481         IF( iom_file(kiomid)%nfid > 0 ) CALL iom_get_123d( kiomid, kdom       , cdvar        , pv_r1d=pvar,   &
482              &                                                     ktime=ktime, kstart=kstart, kcount=kcount )
483      ENDIF
484   END SUBROUTINE iom_g1d
485
486   SUBROUTINE iom_g2d( kiomid, kdom, cdvar, pvar, ktime, kstart, kcount )
487      INTEGER         , INTENT(in   )                           ::   kiomid    ! Identifier of the file
488      INTEGER         , INTENT(in   )                           ::   kdom      ! Type of domain to be read
489      CHARACTER(len=*), INTENT(in   )                           ::   cdvar     ! Name of the variable
490      REAL(wp)        , INTENT(  out), DIMENSION(:,:)           ::   pvar      ! read field
491      INTEGER         , INTENT(in   )                , OPTIONAL ::   ktime     ! record number
492      INTEGER         , INTENT(in   ), DIMENSION(2)  , OPTIONAL ::   kstart    ! start axis position of the reading
493      INTEGER         , INTENT(in   ), DIMENSION(2)  , OPTIONAL ::   kcount    ! number of points in each axis
494      !
495      IF( kiomid > 0 ) THEN
496         IF( iom_file(kiomid)%nfid > 0 ) CALL iom_get_123d( kiomid, kdom       , cdvar        , pv_r2d=pvar,   &
497              &                                                     ktime=ktime, kstart=kstart, kcount=kcount )
498      ENDIF
499   END SUBROUTINE iom_g2d
500
501   SUBROUTINE iom_g3d( kiomid, kdom, cdvar, pvar, ktime, kstart, kcount )
502      INTEGER         , INTENT(in   )                             ::   kiomid    ! Identifier of the file
503      INTEGER         , INTENT(in   )                             ::   kdom      ! Type of domain to be read
504      CHARACTER(len=*), INTENT(in   )                             ::   cdvar     ! Name of the variable
505      REAL(wp)        , INTENT(  out), DIMENSION(:,:,:)           ::   pvar      ! read field
506      INTEGER         , INTENT(in   )                  , OPTIONAL ::   ktime     ! record number
507      INTEGER         , INTENT(in   ), DIMENSION(3)    , OPTIONAL ::   kstart    ! start axis position of the reading
508      INTEGER         , INTENT(in   ), DIMENSION(3)    , OPTIONAL ::   kcount    ! number of points in each axis
509      !
510      IF( kiomid > 0 ) THEN
511         IF( iom_file(kiomid)%nfid > 0 ) CALL iom_get_123d( kiomid, kdom       , cdvar        , pv_r3d=pvar,   &
512              &                                                     ktime=ktime, kstart=kstart, kcount=kcount )
513      ENDIF
514   END SUBROUTINE iom_g3d
515   !!----------------------------------------------------------------------
516
517   SUBROUTINE iom_get_123d( kiomid, kdom  , cdvar ,   &
518         &                  pv_r1d, pv_r2d, pv_r3d,   &
519         &                  ktime , kstart, kcount  )
520      !!-----------------------------------------------------------------------
521      !!                  ***  ROUTINE  iom_get_123d  ***
522      !!
523      !! ** Purpose : read a 1D/2D/3D variable
524      !!
525      !! ** Method : read ONE record at each CALL
526      !!-----------------------------------------------------------------------
527      INTEGER                    , INTENT(in   )           ::   kiomid     ! Identifier of the file
528      INTEGER                    , INTENT(in   )           ::   kdom       ! Type of domain to be read
529      CHARACTER(len=*)           , INTENT(in   )           ::   cdvar      ! Name of the variable
530      REAL(wp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d     ! read field (1D case)
531      REAL(wp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d     ! read field (2D case)
532      REAL(wp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d     ! read field (3D case)
533      INTEGER                    , INTENT(in   ), OPTIONAL ::   ktime      ! record number
534      INTEGER , DIMENSION(:)     , INTENT(in   ), OPTIONAL ::   kstart     ! start position of the reading in each axis
535      INTEGER , DIMENSION(:)     , INTENT(in   ), OPTIONAL ::   kcount     ! number of points to be read in each axis
536      !
537      LOGICAL                        ::   llnoov      ! local definition to read overlap
538      INTEGER                        ::   jl          ! loop on number of dimension
539      INTEGER                        ::   idom        ! type of domain
540      INTEGER                        ::   idvar       ! id of the variable
541      INTEGER                        ::   inbdim      ! number of dimensions of the variable
542      INTEGER                        ::   idmspc      ! number of spatial dimensions
543      INTEGER                        ::   itime       ! record number
544      INTEGER                        ::   istop       ! temporary value of nstop
545      INTEGER                        ::   ix1, ix2, iy1, iy2   ! subdomain indexes
546      INTEGER                        ::   ji, jj      ! loop counters
547      INTEGER                        ::   irankpv       !
548      INTEGER                        ::   ind1, ind2  ! substring index
549      INTEGER, DIMENSION(jpmax_dims) ::   istart      ! starting point to read for each axis
550      INTEGER, DIMENSION(jpmax_dims) ::   icnt        ! number of value to read along each axis
551      INTEGER, DIMENSION(jpmax_dims) ::   idimsz      ! size of the dimensions of the variable
552      INTEGER, DIMENSION(jpmax_dims) ::   ishape      ! size of the dimensions of the variable
553      REAL(wp)                       ::   zscf, zofs  ! sacle_factor and add_offset
554      INTEGER                        ::   itmp        ! temporary integer
555      CHARACTER(LEN=100)             ::   clinfo      ! info character
556      CHARACTER(LEN=100)             ::   clname      ! file name
557      CHARACTER(LEN=1)               ::   clrankpv, cldmspc      !
558      !---------------------------------------------------------------------
559      !
560      clname = iom_file(kiomid)%name   !   esier to read
561      clinfo = '          iom_get_123d, file: '//trim(clname)//', var: '//trim(cdvar)
562      ! local definition of the domain ?
563      idom = kdom
564      ! do we read the overlap
565      ! ugly patch SM+JMM+RB to overwrite global definition in some cases
566      llnoov = (jpni * jpnj ) == jpnij .AND. .NOT. lk_agrif 
567      ! check kcount and kstart optionals parameters...
568      IF( PRESENT(kcount) .AND. (.NOT. PRESENT(kstart)) ) CALL ctl_stop(trim(clinfo), 'kcount present needs kstart present')
569      IF( PRESENT(kstart) .AND. (.NOT. PRESENT(kcount)) ) CALL ctl_stop(trim(clinfo), 'kstart present needs kcount present')
570      IF( PRESENT(kstart) .AND. idom /= jpdom_unknown   ) CALL ctl_stop(trim(clinfo), 'kstart present needs kdom = jpdom_unknown')
571
572      ! Search for the variable in the data base (eventually actualize data)
573      istop = nstop
574      idvar = iom_varid( kiomid, cdvar )
575      !
576      IF( idvar > 0 ) THEN
577         ! to write iom_file(kiomid)%dimsz in a shorter way !
578         idimsz(:) = iom_file(kiomid)%dimsz(:, idvar) 
579         inbdim = iom_file(kiomid)%ndims(idvar)            ! number of dimensions in the file
580         idmspc = inbdim                                   ! number of spatial dimensions in the file
581         IF( iom_file(kiomid)%luld(idvar) )   idmspc = inbdim - 1
582         IF( idmspc > 3 )   CALL ctl_stop(trim(clinfo), 'the file has more than 3 spatial dimensions this case is not coded...') 
583         !
584         ! update idom definition...
585         ! Identify the domain in case of jpdom_auto(glo/dta) definition
586         IF( idom == jpdom_autoglo .OR. idom == jpdom_autodta ) THEN           
587            IF( idom == jpdom_autoglo ) THEN   ;   idom = jpdom_global 
588            ELSE                               ;   idom = jpdom_data
589            ENDIF
590            ind1 = INDEX( clname, '_', back = .TRUE. ) + 1
591            ind2 = INDEX( clname, '.', back = .TRUE. ) - 1
592            IF( ind2 > ind1 ) THEN   ;   IF( VERIFY( clname(ind1:ind2), '0123456789' ) == 0 )   idom = jpdom_local   ;   ENDIF
593         ENDIF
594         ! Identify the domain in case of jpdom_local definition
595         IF( idom == jpdom_local ) THEN
596            IF(     idimsz(1) == jpi               .AND. idimsz(2) == jpj               ) THEN   ;   idom = jpdom_local_full
597            ELSEIF( idimsz(1) == nlci              .AND. idimsz(2) == nlcj              ) THEN   ;   idom = jpdom_local_noextra
598            ELSEIF( idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN   ;   idom = jpdom_local_noovlap
599            ELSE   ;   CALL ctl_stop( trim(clinfo), 'impossible to identify the local domain' )
600            ENDIF
601         ENDIF
602         !
603         ! check the consistency between input array and data rank in the file
604         !
605         ! initializations
606         itime = 1
607         IF( PRESENT(ktime) ) itime = ktime
608
609         irankpv = 1 * COUNT( (/PRESENT(pv_r1d)/) ) + 2 * COUNT( (/PRESENT(pv_r2d)/) ) + 3 * COUNT( (/PRESENT(pv_r3d)/) )
610         WRITE(clrankpv, fmt='(i1)') irankpv
611         WRITE(cldmspc , fmt='(i1)') idmspc
612         !
613         IF(     idmspc <  irankpv ) THEN
614            CALL ctl_stop( TRIM(clinfo), 'The file has only '//cldmspc//' spatial dimension',   &
615               &                         'it is impossible to read a '//clrankpv//'D array from this file...' )
616         ELSEIF( idmspc == irankpv ) THEN
617            IF( PRESENT(pv_r1d) .AND. idom /= jpdom_unknown )   &
618               &   CALL ctl_stop( TRIM(clinfo), 'case not coded...You must use jpdom_unknown' )
619         ELSEIF( idmspc >  irankpv ) THEN
620               IF( PRESENT(pv_r2d) .AND. itime == 1 .AND. idimsz(3) == 1 .AND. idmspc == 3 ) THEN
621                  CALL ctl_warn( trim(clinfo), '2D array but 3 spatial dimensions for the data...'              ,   &
622                        &         'As the size of the z dimension is 1 and as we try to read the first record, ',   &
623                        &         'we accept this case, even if there is a possible mix-up between z and time dimension' )   
624                  idmspc = idmspc - 1
625               ELSE
626                  CALL ctl_stop( TRIM(clinfo), 'To keep iom lisibility, when reading a '//clrankpv//'D array,'         ,   &
627                     &                         'we do not accept data with more than '//cldmspc//' spatial dimension',   &
628                     &                         'Use ncwa -a to suppress the unnecessary dimensions' )
629               ENDIF
630         ENDIF
631
632         !
633         ! definition of istart and icnt
634         !
635         icnt  (:) = 1
636         istart(:) = 1
637         istart(idmspc+1) = itime
638
639         IF(              PRESENT(kstart)       ) THEN ; istart(1:idmspc) = kstart(1:idmspc) ; icnt(1:idmspc) = kcount(1:idmspc)
640         ELSE
641            IF(           idom == jpdom_unknown ) THEN                                       ; icnt(1:idmspc) = idimsz(1:idmspc)
642            ELSE
643               IF( .NOT. PRESENT(pv_r1d) ) THEN   !   not a 1D array
644                  IF(     idom == jpdom_data    ) THEN ; istart(1:2) = (/ mig(1), mjg(1) /)  ! icnt(1:2) done bellow
645                  ELSEIF( idom == jpdom_global  ) THEN ; istart(1:2) = (/ nimpp , njmpp  /)  ! icnt(1:2) done bellow
646                  ENDIF
647                  ! we do not read the overlap                     -> we start to read at nldi, nldj
648! JMM + SM: ugly patch before getting the new version of lib_mpp)
649!                  IF( idom /= jpdom_local_noovlap )   istart(1:2) = istart(1:2) + (/ nldi - 1, nldj - 1 /)
650                  IF( llnoov .AND. idom /= jpdom_local_noovlap ) istart(1:2) = istart(1:2) + (/ nldi - 1, nldj - 1 /)
651                  ! we do not read the overlap and the extra-halos -> from nldi to nlei and from nldj to nlej
652! JMM + SM: ugly patch before getting the new version of lib_mpp)
653!                  icnt(1:2) = (/ nlei - nldi + 1, nlej - nldj + 1 /)
654                  IF( llnoov ) THEN   ;   icnt(1:2) = (/ nlei - nldi + 1, nlej - nldj + 1 /)
655                  ELSE                ;   icnt(1:2) = (/ nlci           , nlcj            /)
656                  ENDIF
657                  IF( PRESENT(pv_r3d) ) THEN
658                     IF( idom == jpdom_data ) THEN   ; icnt(3) = jpkdta
659                     ELSE                            ; icnt(3) = jpk
660                     ENDIF
661                  ENDIF
662               ENDIF
663            ENDIF
664         ENDIF
665
666         ! check that istart and icnt can be used with this file
667         !-
668         DO jl = 1, jpmax_dims
669            itmp = istart(jl)+icnt(jl)-1
670            IF( itmp > idimsz(jl) .AND. idimsz(jl) /= 0 ) THEN
671               WRITE( ctmp1, FMT="('(istart(', i1, ') + icnt(', i1, ') - 1) = ', i5)" ) jl, jl, itmp
672               WRITE( ctmp2, FMT="(' is larger than idimsz(', i1,') = ', i5)"         ) jl, idimsz(jl)
673               CALL ctl_stop( trim(clinfo), 'start and count too big regarding to the size of the data, ', ctmp1, ctmp2 )     
674            ENDIF
675         END DO
676
677         ! check that icnt matches the input array
678         !-     
679         IF( idom == jpdom_unknown ) THEN
680            IF( irankpv == 1 )        ishape(1:1) = SHAPE(pv_r1d)
681            IF( irankpv == 2 )        ishape(1:2) = SHAPE(pv_r2d)
682            IF( irankpv == 3 )        ishape(1:3) = SHAPE(pv_r3d)
683            ctmp1 = 'd'
684         ELSE
685            IF( irankpv == 2 ) THEN
686! JMM + SM: ugly patch before getting the new version of lib_mpp)
687!               ishape(1:2) = SHAPE(pv_r2d(nldi:nlei,nldj:nlej  ))   ;   ctmp1 = 'd(nldi:nlei,nldj:nlej)'
688               IF( llnoov ) THEN ; ishape(1:2)=SHAPE(pv_r2d(nldi:nlei,nldj:nlej  )) ; ctmp1='d(nldi:nlei,nldj:nlej)'
689               ELSE              ; ishape(1:2)=SHAPE(pv_r2d(1   :nlci,1   :nlcj  )) ; ctmp1='d(1:nlci,1:nlcj)'
690               ENDIF
691            ENDIF
692            IF( irankpv == 3 ) THEN 
693! JMM + SM: ugly patch before getting the new version of lib_mpp)
694!               ishape(1:3) = SHAPE(pv_r3d(nldi:nlei,nldj:nlej,:))   ;   ctmp1 = 'd(nldi:nlei,nldj:nlej,:)'
695               IF( llnoov ) THEN ; ishape(1:3)=SHAPE(pv_r3d(nldi:nlei,nldj:nlej,:)) ; ctmp1='d(nldi:nlei,nldj:nlej,:)'
696               ELSE              ; ishape(1:3)=SHAPE(pv_r3d(1   :nlci,1   :nlcj,:)) ; ctmp1='d(1:nlci,1:nlcj,:)'
697               ENDIF
698            ENDIF
699         ENDIF
700         
701         DO jl = 1, irankpv
702            WRITE( ctmp2, FMT="(', ', i1,'): ', i5,' /= icnt(', i1,'):', i5)" ) jl, ishape(jl), jl, icnt(jl)
703            IF( ishape(jl) /= icnt(jl) )   CALL ctl_stop( TRIM(clinfo), 'size(pv_r'//clrankpv//TRIM(ctmp1)//TRIM(ctmp2) )
704         END DO
705
706      ENDIF
707
708      ! read the data
709      !-     
710      IF( idvar > 0 .AND. istop == nstop ) THEN   ! no additional errors until this point...
711         !
712         ! find the right index of the array to be read
713! JMM + SM: ugly patch before getting the new version of lib_mpp)
714!         IF( idom /= jpdom_unknown ) THEN   ;   ix1 = nldi   ;   ix2 = nlei      ;   iy1 = nldj   ;   iy2 = nlej
715!         ELSE                               ;   ix1 = 1      ;   ix2 = icnt(1)   ;   iy1 = 1      ;   iy2 = icnt(2)
716!         ENDIF
717         IF( llnoov ) THEN
718            IF( idom /= jpdom_unknown ) THEN   ;   ix1 = nldi   ;   ix2 = nlei      ;   iy1 = nldj   ;   iy2 = nlej
719            ELSE                               ;   ix1 = 1      ;   ix2 = icnt(1)   ;   iy1 = 1      ;   iy2 = icnt(2)
720            ENDIF
721         ELSE
722            IF( idom /= jpdom_unknown ) THEN   ;   ix1 = 1      ;   ix2 = nlci      ;   iy1 = 1      ;   iy2 = nlcj
723            ELSE                               ;   ix1 = 1      ;   ix2 = icnt(1)   ;   iy1 = 1      ;   iy2 = icnt(2)
724            ENDIF
725         ENDIF
726     
727         SELECT CASE (iom_file(kiomid)%iolib)
728         CASE (jpioipsl )   ;   CALL iom_ioipsl_get(  kiomid, idvar, inbdim, istart, icnt, ix1, ix2, iy1, iy2,   &
729            &                                         pv_r1d, pv_r2d, pv_r3d )
730         CASE (jpnf90   )   ;   CALL iom_nf90_get(    kiomid, idvar, inbdim, istart, icnt, ix1, ix2, iy1, iy2,   &
731            &                                         pv_r1d, pv_r2d, pv_r3d )
732         CASE (jprstdimg)   ;   CALL iom_rstdimg_get( kiomid, idom, idvar, ix1, ix2, iy1, iy2,   &
733            &                                         pv_r1d, pv_r2d, pv_r3d )
734         CASE DEFAULT   
735            CALL ctl_stop( TRIM(clinfo)//' accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
736         END SELECT
737
738         IF( istop == nstop ) THEN   ! no additional errors until this point...
739            IF(lwp) WRITE(numout,"(10x,' read ',a,' (rec: ',i4,') in ',a,' ok')") TRIM(cdvar), itime, TRIM(iom_file(kiomid)%name)
740         
741            !--- overlap areas and extra hallows (mpp)
742            IF(     PRESENT(pv_r2d) .AND. idom /= jpdom_unknown ) THEN
743               CALL lbc_lnk( pv_r2d,'Z',-999.,'no0' )
744            ELSEIF( PRESENT(pv_r3d) .AND. idom /= jpdom_unknown ) THEN
745               ! this if could be simplified with the new lbc_lnk that works with any size of the 3rd dimension
746               IF( icnt(3) == jpk ) THEN
747                  CALL lbc_lnk( pv_r3d,'Z',-999.,'no0' )
748               ELSE   ! put some arbitrary value (a call to lbc_lnk will be done later...)
749                  DO jj = nlcj+1, jpj   ;   pv_r3d(1:nlci, jj, :) = pv_r3d(1:nlci, nlej, :)   ;   END DO
750                  DO ji = nlci+1, jpi   ;   pv_r3d(ji    , : , :) = pv_r3d(nlei  , :   , :)   ;   END DO
751               ENDIF
752            ENDIF
753           
754            ! C1D case : always call lbc_lnk to replicate the central value over the whole 3X3 domain
755            IF( lk_c1d .AND. PRESENT(pv_r2d) )   CALL lbc_lnk( pv_r2d,'Z',1. )
756            IF( lk_c1d .AND. PRESENT(pv_r3d) )   CALL lbc_lnk( pv_r3d,'Z',1. )
757   
758            !--- Apply scale_factor and offset
759            zscf = iom_file(kiomid)%scf(idvar)      ! scale factor
760            zofs = iom_file(kiomid)%ofs(idvar)      ! offset
761            IF(     PRESENT(pv_r1d) ) THEN
762               IF( zscf /= 1. )   pv_r1d(:) = pv_r1d(:) * zscf 
763               IF( zofs /= 0. )   pv_r1d(:) = pv_r1d(:) + zofs
764            ELSEIF( PRESENT(pv_r2d) ) THEN
765!CDIR COLLAPSE
766               IF( zscf /= 1.)   pv_r2d(:,:) = pv_r2d(:,:) * zscf
767!CDIR COLLAPSE
768               IF( zofs /= 0.)   pv_r2d(:,:) = pv_r2d(:,:) + zofs
769            ELSEIF( PRESENT(pv_r3d) ) THEN
770!CDIR COLLAPSE
771               IF( zscf /= 1.)   pv_r3d(:,:,:) = pv_r3d(:,:,:) * zscf
772!CDIR COLLAPSE
773               IF( zofs /= 0.)   pv_r3d(:,:,:) = pv_r3d(:,:,:) + zofs
774            ENDIF
775            !
776         ENDIF
777         !
778      ENDIF
779      !
780   END SUBROUTINE iom_get_123d
781
782
783   SUBROUTINE iom_gettime( kiomid, ptime, cdvar, kntime, cdunits, cdcalendar )
784      !!--------------------------------------------------------------------
785      !!                   ***  SUBROUTINE iom_gettime  ***
786      !!
787      !! ** Purpose : read the time axis cdvar in the file
788      !!--------------------------------------------------------------------
789      INTEGER                    , INTENT(in   ) ::   kiomid     ! file Identifier
790      REAL(wp), DIMENSION(:)     , INTENT(  out) ::   ptime      ! the time axis
791      CHARACTER(len=*), OPTIONAL , INTENT(in   ) ::   cdvar      ! time axis name
792      INTEGER         , OPTIONAL , INTENT(  out) ::   kntime     ! number of times in file
793      CHARACTER(len=*), OPTIONAL , INTENT(  out) ::   cdunits    ! units attribute of time coordinate
794      CHARACTER(len=*), OPTIONAL , INTENT(  out) ::   cdcalendar ! calendar attribute of
795      !
796      INTEGER, DIMENSION(1) :: kdimsz
797      INTEGER            ::   idvar    ! id of the variable
798      CHARACTER(LEN=32)  ::   tname    ! local name of time coordinate
799      CHARACTER(LEN=100) ::   clinfo   ! info character
800      !---------------------------------------------------------------------
801      !
802      IF ( PRESENT(cdvar) ) THEN
803         tname = cdvar
804      ELSE
805         tname = iom_file(kiomid)%uldname
806      ENDIF
807      IF( kiomid > 0 ) THEN
808         clinfo = 'iom_gettime, file: '//trim(iom_file(kiomid)%name)//', var: '//trim(tname)
809         IF ( PRESENT(kntime) ) THEN
810            idvar  = iom_varid( kiomid, tname, kdimsz = kdimsz )
811            kntime = kdimsz(1)
812         ELSE
813            idvar = iom_varid( kiomid, tname )
814         ENDIF
815         !
816         ptime(:) = 0. ! default definition
817         IF( idvar > 0 ) THEN
818            IF( iom_file(kiomid)%ndims(idvar) == 1 ) THEN
819               IF( iom_file(kiomid)%luld(idvar) ) THEN
820                  IF( iom_file(kiomid)%dimsz(1,idvar) <= size(ptime) ) THEN
821                     SELECT CASE (iom_file(kiomid)%iolib)
822                     CASE (jpioipsl )   ;   CALL iom_ioipsl_gettime( kiomid, idvar, ptime, cdunits, cdcalendar )
823                     CASE (jpnf90   )   ;   CALL iom_nf90_gettime(   kiomid, idvar, ptime, cdunits, cdcalendar )
824                     CASE (jprstdimg)   ;   CALL ctl_stop( TRIM(clinfo)//' case IO library == jprstdimg not coded...' )
825                     CASE DEFAULT   
826                        CALL ctl_stop( TRIM(clinfo)//' accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
827                     END SELECT
828                  ELSE
829                     WRITE(ctmp1,*) 'error with the size of ptime ',size(ptime),iom_file(kiomid)%dimsz(1,idvar)
830                     CALL ctl_stop( trim(clinfo), trim(ctmp1) )
831                  ENDIF
832               ELSE
833                  CALL ctl_stop( trim(clinfo), 'variable dimension is not unlimited... use iom_get' )
834               ENDIF
835            ELSE
836               CALL ctl_stop( trim(clinfo), 'the variable has more than 1 dimension' )
837            ENDIF
838         ELSE
839            CALL ctl_stop( trim(clinfo), 'variable not found in '//iom_file(kiomid)%name )
840         ENDIF
841      ENDIF
842      !
843   END SUBROUTINE iom_gettime
844
845
846   !!----------------------------------------------------------------------
847   !!                   INTERFACE iom_getatt
848   !!----------------------------------------------------------------------
849   SUBROUTINE iom_g0d_intatt( kiomid, cdatt, pvar )
850      INTEGER         , INTENT(in   )                 ::   kiomid    ! Identifier of the file
851      CHARACTER(len=*), INTENT(in   )                 ::   cdatt     ! Name of the attribute
852      INTEGER         , INTENT(  out)                 ::   pvar      ! read field
853      !
854      IF( kiomid > 0 ) THEN
855         IF( iom_file(kiomid)%nfid > 0 ) THEN
856            SELECT CASE (iom_file(kiomid)%iolib)
857            CASE (jpioipsl )   ;   CALL ctl_stop('iom_getatt: only nf90 available')
858            CASE (jpnf90   )   ;   CALL iom_nf90_getatt( kiomid, cdatt, pvar )
859            CASE (jprstdimg)   ;   CALL ctl_stop('iom_getatt: only nf90 available')
860            CASE DEFAULT   
861               CALL ctl_stop( 'iom_g0d_att: accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
862            END SELECT
863         ENDIF
864      ENDIF
865   END SUBROUTINE iom_g0d_intatt
866
867
868   !!----------------------------------------------------------------------
869   !!                   INTERFACE iom_rstput
870   !!----------------------------------------------------------------------
871   SUBROUTINE iom_rp0d( kt, kwrite, kiomid, cdvar, pvar, ktype )
872      INTEGER         , INTENT(in)                         ::   kt       ! ocean time-step
873      INTEGER         , INTENT(in)                         ::   kwrite   ! writing time-step
874      INTEGER         , INTENT(in)                         ::   kiomid   ! Identifier of the file
875      CHARACTER(len=*), INTENT(in)                         ::   cdvar    ! time axis name
876      REAL(wp)        , INTENT(in)                         ::   pvar     ! written field
877      INTEGER         , INTENT(in), OPTIONAL               ::   ktype    ! variable external type
878      INTEGER :: ivid   ! variable id
879      IF( kiomid > 0 ) THEN
880         IF( iom_file(kiomid)%nfid > 0 ) THEN
881            ivid = iom_varid( kiomid, cdvar, ldstop = .FALSE. )
882            SELECT CASE (iom_file(kiomid)%iolib)
883            CASE (jpioipsl )   ;   CALL iom_ioipsl_rstput( kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r0d = pvar )
884            CASE (jpnf90   )   ;   CALL iom_nf90_rstput(   kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r0d = pvar )
885            CASE (jprstdimg)   ;   IF( kt == kwrite )    CALL iom_rstdimg_rstput( kiomid, cdvar, ivid, pvar )
886            CASE DEFAULT     
887               CALL ctl_stop( 'iom_rp0d: accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
888            END SELECT
889         ENDIF
890      ENDIF
891   END SUBROUTINE iom_rp0d
892
893   SUBROUTINE iom_rp1d( kt, kwrite, kiomid, cdvar, pvar, ktype )
894      INTEGER         , INTENT(in)                         ::   kt       ! ocean time-step
895      INTEGER         , INTENT(in)                         ::   kwrite   ! writing time-step
896      INTEGER         , INTENT(in)                         ::   kiomid   ! Identifier of the file
897      CHARACTER(len=*), INTENT(in)                         ::   cdvar    ! time axis name
898      REAL(wp)        , INTENT(in), DIMENSION(          :) ::   pvar     ! written field
899      INTEGER         , INTENT(in), OPTIONAL               ::   ktype    ! variable external type
900      INTEGER :: ivid   ! variable id
901      IF( kiomid > 0 ) THEN
902         IF( iom_file(kiomid)%nfid > 0 ) THEN
903            ivid = iom_varid( kiomid, cdvar, ldstop = .FALSE. )
904            SELECT CASE (iom_file(kiomid)%iolib)
905            CASE (jpioipsl )   ;   CALL iom_ioipsl_rstput( kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r1d = pvar )
906            CASE (jpnf90   )   ;   CALL iom_nf90_rstput(   kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r1d = pvar )
907            CASE (jprstdimg)   ;   IF( kt == kwrite )    CALL iom_rstdimg_rstput( kiomid, cdvar, ivid, pv_r1d = pvar )
908            CASE DEFAULT     
909               CALL ctl_stop( 'iom_rp1d: accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
910            END SELECT
911         ENDIF
912      ENDIF
913   END SUBROUTINE iom_rp1d
914
915   SUBROUTINE iom_rp2d( kt, kwrite, kiomid, cdvar, pvar, ktype )
916      INTEGER         , INTENT(in)                         ::   kt       ! ocean time-step
917      INTEGER         , INTENT(in)                         ::   kwrite   ! writing time-step
918      INTEGER         , INTENT(in)                         ::   kiomid   ! Identifier of the file
919      CHARACTER(len=*), INTENT(in)                         ::   cdvar    ! time axis name
920      REAL(wp)        , INTENT(in), DIMENSION(:,    :    ) ::   pvar     ! written field
921      INTEGER         , INTENT(in), OPTIONAL               ::   ktype    ! variable external type
922      INTEGER :: ivid   ! variable id
923      IF( kiomid > 0 ) THEN
924         IF( iom_file(kiomid)%nfid > 0 ) THEN
925            ivid = iom_varid( kiomid, cdvar, ldstop = .FALSE. )
926            SELECT CASE (iom_file(kiomid)%iolib)
927            CASE (jpioipsl )   ;   CALL iom_ioipsl_rstput( kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r2d = pvar )
928            CASE (jpnf90   )   ;   CALL iom_nf90_rstput(   kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r2d = pvar )
929            CASE (jprstdimg)   ;   IF( kt == kwrite )   CALL iom_rstdimg_rstput( kiomid, cdvar, ivid, pv_r2d = pvar ) 
930            CASE DEFAULT     
931               CALL ctl_stop( 'iom_rp2d: accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
932            END SELECT
933         ENDIF
934      ENDIF
935   END SUBROUTINE iom_rp2d
936
937   SUBROUTINE iom_rp3d( kt, kwrite, kiomid, cdvar, pvar, ktype )
938      INTEGER         , INTENT(in)                         ::   kt       ! ocean time-step
939      INTEGER         , INTENT(in)                         ::   kwrite   ! writing time-step
940      INTEGER         , INTENT(in)                         ::   kiomid   ! Identifier of the file
941      CHARACTER(len=*), INTENT(in)                         ::   cdvar    ! time axis name
942      REAL(wp)        , INTENT(in),       DIMENSION(:,:,:) ::   pvar     ! written field
943      INTEGER         , INTENT(in), OPTIONAL               ::   ktype    ! variable external type
944      INTEGER :: ivid   ! variable id
945      IF( kiomid > 0 ) THEN
946         IF( iom_file(kiomid)%nfid > 0 ) THEN
947            ivid = iom_varid( kiomid, cdvar, ldstop = .FALSE. )
948            SELECT CASE (iom_file(kiomid)%iolib)
949            CASE (jpioipsl )   ;   CALL iom_ioipsl_rstput( kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r3d = pvar )
950            CASE (jpnf90   )   ;   CALL iom_nf90_rstput(   kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r3d = pvar )
951            CASE (jprstdimg)   ;   IF( kt == kwrite )   CALL iom_rstdimg_rstput( kiomid, cdvar, ivid, pv_r3d = pvar )
952            CASE DEFAULT     
953               CALL ctl_stop( 'iom_rp3d: accepted IO library are only jpioipsl and jprstdimg' )
954            END SELECT
955         ENDIF
956      ENDIF
957   END SUBROUTINE iom_rp3d
958
959
960   !!----------------------------------------------------------------------
961   !!                   INTERFACE iom_put
962   !!----------------------------------------------------------------------
963   SUBROUTINE iom_p0d( cdname, pfield0d )
964      CHARACTER(LEN=*), INTENT(in) ::   cdname
965      REAL(wp)        , INTENT(in) ::   pfield0d
966#if defined key_iomput
967      CALL event__write_field2D( cdname, RESHAPE( (/pfield0d/), (/1,1/) ) )
968#else
969      IF( .FALSE. )   WRITE(numout,*) cdname, pfield0d   ! useless test to avoid compilation warnings
970#endif
971   END SUBROUTINE iom_p0d
972
973   SUBROUTINE iom_p1d( cdname, pfield1d )
974      CHARACTER(LEN=*)          , INTENT(in) ::   cdname
975      REAL(wp),     DIMENSION(:), INTENT(in) ::   pfield1d
976      INTEGER :: jpz
977#if defined key_iomput
978      jpz=SIZE(pfield1d)
979      CALL event__write_field3D( cdname, RESHAPE( (/pfield1d/), (/1,1,jpz/) ) )
980#else
981      IF( .FALSE. )   WRITE(numout,*) cdname, pfield1d   ! useless test to avoid compilation warnings
982#endif
983   END SUBROUTINE iom_p1d
984
985   SUBROUTINE iom_p2d( cdname, pfield2d )
986      CHARACTER(LEN=*)            , INTENT(in) ::   cdname
987      REAL(wp),     DIMENSION(:,:), INTENT(in) ::   pfield2d
988#if defined key_iomput
989      CALL event__write_field2D( cdname, pfield2d(nldi:nlei, nldj:nlej) )
990#else
991      IF( .FALSE. )   WRITE(numout,*) cdname, pfield2d   ! useless test to avoid compilation warnings
992#endif
993   END SUBROUTINE iom_p2d
994
995   SUBROUTINE iom_p3d( cdname, pfield3d )
996      CHARACTER(LEN=*)                , INTENT(in) ::   cdname
997      REAL(wp),       DIMENSION(:,:,:), INTENT(in) ::   pfield3d
998#if defined key_iomput
999      CALL event__write_field3D( cdname, pfield3d(nldi:nlei, nldj:nlej, :) )
1000#else
1001      IF( .FALSE. )   WRITE(numout,*) cdname, pfield3d   ! useless test to avoid compilation warnings
1002#endif
1003   END SUBROUTINE iom_p3d
1004   !!----------------------------------------------------------------------
1005
1006
1007#if defined key_iomput
1008
1009   SUBROUTINE set_grid( cdname, plon, plat )
1010      !!----------------------------------------------------------------------
1011      !!                     ***  ROUTINE   ***
1012      !!
1013      !! ** Purpose :   define horizontal grids
1014      !!
1015      !!----------------------------------------------------------------------
1016      CHARACTER(LEN=*)            , INTENT(in) ::   cdname
1017      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   plon
1018      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   plat
1019
1020      CALL event__set_grid_dimension( cdname, jpiglo, jpjglo)
1021      CALL event__set_grid_domain( cdname, nlei-nldi+1, nlej-nldj+1, nimpp+nldi-1, njmpp+nldj-1, &
1022         &                         plon(nldi:nlei, nldj:nlej), plat(nldi:nlei, nldj:nlej) )
1023      CALL event__set_grid_type_nemo( cdname )
1024
1025   END SUBROUTINE set_grid
1026
1027
1028   SUBROUTINE set_scalar
1029      !!----------------------------------------------------------------------
1030      !!                     ***  ROUTINE   ***
1031      !!
1032      !! ** Purpose :   define fake grids for scalar point
1033      !!
1034      !!----------------------------------------------------------------------
1035      REAL(wp), DIMENSION(1,1) ::   zz = 1.
1036      !!----------------------------------------------------------------------
1037      CALL event__set_grid_dimension( 'scalarpoint', jpnij, 1)
1038      CALL event__set_grid_domain   ( 'scalarpoint', 1, 1, narea, 1, zz, zz )
1039      CALL event__set_grid_type_nemo( 'scalarpoint' )
1040
1041   END SUBROUTINE set_scalar
1042
1043
1044   SUBROUTINE set_xmlatt
1045      !!----------------------------------------------------------------------
1046      !!                     ***  ROUTINE   ***
1047      !!
1048      !! ** Purpose :   automatic definitions of some of the xml attributs...
1049      !!
1050      !!----------------------------------------------------------------------
1051      CHARACTER(len=6),DIMENSION( 8) ::   clsuff                   ! suffix name
1052      CHARACTER(len=1),DIMENSION( 3) ::   clgrd                    ! suffix name
1053      CHARACTER(len=50)              ::   clname                   ! file name
1054      CHARACTER(len=1)               ::   cl1                      ! 1 character
1055      CHARACTER(len=2)               ::   cl2                      ! 1 character
1056      INTEGER                        ::   idt                      ! time-step in seconds
1057      INTEGER                        ::   iddss, ihhss             ! number of seconds in 1 day, 1 hour and 1 year
1058      INTEGER                        ::   iyymo                    ! number of months in 1 year
1059      INTEGER                        ::   jg, jh, jd, jm, jy       ! loop counters
1060      INTEGER                        ::   ix, iy                   ! i-,j- index
1061      REAL(wp)        ,DIMENSION(11) ::   zlontao                  ! longitudes of tao    moorings
1062      REAL(wp)        ,DIMENSION( 7) ::   zlattao                  ! latitudes  of tao    moorings
1063      REAL(wp)        ,DIMENSION( 4) ::   zlonrama                 ! longitudes of rama   moorings
1064      REAL(wp)        ,DIMENSION(11) ::   zlatrama                 ! latitudes  of rama   moorings
1065      REAL(wp)        ,DIMENSION( 3) ::   zlonpira                 ! longitudes of pirata moorings
1066      REAL(wp)        ,DIMENSION( 9) ::   zlatpira                 ! latitudes  of pirata moorings
1067      !!----------------------------------------------------------------------
1068      !
1069      idt   = NINT( rdttra(1)     )
1070      iddss = NINT( rday          )                                         ! number of seconds in 1 day
1071      ihhss = NINT( rmmss * rhhmm )                                         ! number of seconds in 1 hour
1072      iyymo = NINT( raamo         )                                         ! number of months in 1 year
1073
1074      ! frequency of the call of iom_put (attribut: freq_op)
1075      CALL event__set_attribut( 'field_definition', attr( field__freq_op, idt           ) )    ! model time-step
1076      CALL event__set_attribut( 'SBC'             , attr( field__freq_op, idt * nn_fsbc ) )    ! SBC time-step
1077     
1078      ! output file names (attribut: name)
1079      clsuff(:) = (/ 'grid_T', 'grid_U', 'grid_V', 'grid_W', 'icemod', 'ptrc_T', 'diad_T', 'scalar' /)     
1080      DO jg = 1, SIZE(clsuff)                                                                  ! grid type
1081         DO jh = 1, 12                                                                         ! 1, 2, 3, 4, 6, 12 hours
1082            IF( MOD(12,jh) == 0 ) THEN
1083               WRITE(cl2,'(i2)') jh 
1084               CALL dia_nam( clname, jh * ihhss, clsuff(jg), ldfsec = .TRUE. )
1085               CALL event__set_attribut( TRIM(ADJUSTL(cl2))//'h_'//clsuff(jg), attr( file__name, TRIM(clname) ) )
1086            ENDIF
1087         END DO
1088         DO jd = 1, 5, 2                                                                       ! 1, 3, 5 days
1089            WRITE(cl1,'(i1)') jd 
1090            CALL dia_nam( clname, jd * iddss, clsuff(jg), ldfsec = .TRUE. )
1091            CALL event__set_attribut( cl1//'d_'//clsuff(jg), attr( file__name, TRIM(clname) ) )
1092         END DO
1093         DO jm = 1, 6                                                                          ! 1, 2, 3, 4, 6 months
1094            IF( MOD(6,jm) == 0 ) THEN
1095               WRITE(cl1,'(i1)') jm 
1096               CALL dia_nam( clname, -jm, clsuff(jg) )
1097               CALL event__set_attribut( cl1//'m_'//clsuff(jg), attr( file__name, TRIM(clname) ) )
1098            ENDIF
1099         END DO
1100         DO jy = 1, 10                                                                         ! 1, 2, 5, 10 years 
1101            IF( MOD(10,jy) == 0 ) THEN
1102               WRITE(cl2,'(i2)') jy 
1103               CALL dia_nam( clname, -jy * iyymo, clsuff(jg) )
1104               CALL event__set_attribut( TRIM(ADJUSTL(cl2))//'y_'//clsuff(jg), attr( file__name, TRIM(clname) ) )
1105            ENDIF
1106         END DO
1107      END DO
1108
1109      ! Zooms...
1110      clgrd = (/ 'T', 'U', 'W' /) 
1111      DO jg = 1, SIZE(clgrd)                                                                   ! grid type
1112         cl1 = clgrd(jg)
1113         ! Equatorial section (attributs: jbegin, ni, name_suffix)
1114         CALL dom_ngb( 0., 0., ix, iy, cl1 )
1115         CALL event__set_attribut( 'Eq'//cl1, attr( zoom__jbegin     , iy     ) )
1116         CALL event__set_attribut( 'Eq'//cl1, attr( zoom__ni         , jpiglo ) )
1117         CALL event__set_attribut( 'Eq'//cl1, attr( file__name_suffix, '_Eq'  ) )
1118      END DO
1119      ! TAO moorings (attributs: ibegin, jbegin, name_suffix)
1120      zlontao = (/ 137.0, 147.0, 156.0, 165.0, -180.0, -170.0, -155.0, -140.0, -125.0, -110.0, -95.0 /)
1121      zlattao = (/  -8.0,  -5.0,  -2.0,   0.0,    2.0,    5.0,    8.0 /)
1122      CALL set_mooring( zlontao, zlattao )
1123      ! RAMA moorings (attributs: ibegin, jbegin, name_suffix)
1124      zlonrama = (/  55.0,  67.0, 80.5, 90.0 /)
1125      zlatrama = (/ -16.0, -12.0, -8.0, -4.0, -1.5, 0.0, 1.5, 4.0, 8.0, 12.0, 15.0 /)
1126      CALL set_mooring( zlonrama, zlatrama )
1127      ! PIRATA moorings (attributs: ibegin, jbegin, name_suffix)
1128      zlonpira = (/ -38.0, -23.0, -10.0 /)
1129      zlatpira = (/ -19.0, -14.0,  -8.0, 0.0, 4.0, 8.0, 12.0, 15.0, 20.0 /)
1130      CALL set_mooring( zlonpira, zlatpira )
1131     
1132   END SUBROUTINE set_xmlatt
1133
1134
1135   SUBROUTINE set_mooring( plon, plat)
1136      !!----------------------------------------------------------------------
1137      !!                     ***  ROUTINE   ***
1138      !!
1139      !! ** Purpose :   automatic definitions of moorings xml attributs...
1140      !!
1141      !!----------------------------------------------------------------------
1142      REAL(wp), DIMENSION(:), INTENT(in) ::  plon, plat           ! longitudes/latitudes oft the mooring
1143      !
1144!!$      CHARACTER(len=1),DIMENSION(4) ::   clgrd = (/ 'T', 'U', 'V', 'W' /)   ! suffix name
1145      CHARACTER(len=1),DIMENSION(1) ::   clgrd = (/ 'T' /)        ! suffix name
1146      CHARACTER(len=50)             ::   clname                   ! file name
1147      CHARACTER(len=1)              ::   cl1                      ! 1 character
1148      CHARACTER(len=6)              ::   clon,clat                ! name of longitude, latitude
1149      INTEGER                       ::   ji, jj, jg               ! loop counters
1150      INTEGER                       ::   ix, iy                   ! i-,j- index
1151      REAL(wp)                      ::   zlon, zlat
1152      !!----------------------------------------------------------------------
1153      DO jg = 1, SIZE(clgrd)
1154         cl1 = clgrd(jg)
1155         DO ji = 1, SIZE(plon)
1156            DO jj = 1, SIZE(plat)
1157               zlon = plon(ji)
1158               zlat = plat(jj)
1159               ! modifications for RAMA moorings
1160               IF( zlon ==  67. .AND. zlat ==  15. )   zlon =  65.
1161               IF( zlon ==  90. .AND. zlat <=  -4. )   zlon =  95.
1162               IF( zlon ==  95. .AND. zlat ==  -4. )   zlat =  -5.
1163               ! modifications for PIRATA moorings
1164               IF( zlon == -38. .AND. zlat == -19. )   zlon = -34.
1165               IF( zlon == -38. .AND. zlat == -14. )   zlon = -32.
1166               IF( zlon == -38. .AND. zlat ==  -8. )   zlon = -30.
1167               IF( zlon == -38. .AND. zlat ==   0. )   zlon = -35.
1168               IF( zlon == -23. .AND. zlat ==  20. )   zlat =  21.
1169               IF( zlon == -10. .AND. zlat == -14. )   zlat = -10.
1170               IF( zlon == -10. .AND. zlat ==  -8. )   zlat =  -6.
1171               IF( zlon == -10. .AND. zlat ==   4. ) THEN   ;   zlon = 0.   ;   zlat = 0.   ;   ENDIF
1172               CALL dom_ngb( zlon, zlat, ix, iy, cl1 )
1173               IF( zlon >= 0. ) THEN 
1174                  IF( zlon == REAL(NINT(zlon), wp) ) THEN   ;   WRITE(clon, '(i3,  a)') NINT( zlon), 'e'
1175                  ELSE                                      ;   WRITE(clon, '(f5.1,a)')       zlon , 'e'
1176                  ENDIF
1177               ELSE             
1178                  IF( zlon == REAL(NINT(zlon), wp) ) THEN   ;   WRITE(clon, '(i3,  a)') NINT(-zlon), 'w'
1179                  ELSE                                      ;   WRITE(clon, '(f5.1,a)')      -zlon , 'w'
1180                  ENDIF
1181               ENDIF
1182               IF( zlat >= 0. ) THEN 
1183                  IF( zlat == REAL(NINT(zlat), wp) ) THEN   ;   WRITE(clat, '(i2,  a)') NINT( zlat), 'n'
1184                  ELSE                                      ;   WRITE(clat, '(f4.1,a)')       zlat , 'n'
1185                  ENDIF
1186               ELSE             
1187                  IF( zlat == REAL(NINT(zlat), wp) ) THEN   ;   WRITE(clat, '(i2,  a)') NINT(-zlat), 's'
1188                  ELSE                                      ;   WRITE(clat, '(f4.1,a)')      -zlat , 's'
1189                  ENDIF
1190               ENDIF
1191               clname = TRIM(ADJUSTL(clat))//TRIM(ADJUSTL(clon))
1192               CALL event__set_attribut( TRIM(clname)//cl1, attr( zoom__ibegin     , ix                ) )
1193               CALL event__set_attribut( TRIM(clname)//cl1, attr( zoom__jbegin     , iy                ) )
1194               CALL event__set_attribut( TRIM(clname)//cl1, attr( file__name_suffix, '_'//TRIM(clname) ) )     
1195            END DO
1196         END DO
1197      END DO
1198     
1199   END SUBROUTINE set_mooring
1200
1201#else
1202
1203   SUBROUTINE iom_setkt( kt )
1204      INTEGER, INTENT(in   )::   kt 
1205      IF( .FALSE. )   WRITE(numout,*) kt   ! useless test to avoid compilation warnings
1206   END SUBROUTINE iom_setkt
1207
1208#endif
1209
1210
1211   !!======================================================================
1212END MODULE iom
Note: See TracBrowser for help on using the repository browser.