New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in NEMO/branches/NERC/dev_release-3.4_NEMOTAM_consolidated/NEMOGCM/NEMO/OPA_SRC – NEMO

Context Navigation

source: NEMO/branches/NERC/dev_release-3.4_NEMOTAM_consolidated/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 11809

Last change on this file since 11809 was 5168, checked in by pabouttier, 9 years ago
Fixed several bugs described in Ticket #1360
Property svn:keywords set to `Id`
File size: 37.1 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! 3.4 ! 2011-11 (C. Harris) decomposition changes for running with CICE
31	!!----------------------------------------------------------------------
32
33	!!----------------------------------------------------------------------
34	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
35	!! nemo_init : initialization of the NEMO system
36	!! nemo_ctl : initialisation of the contol print
37	!! nemo_closefile : close remaining open files
38	!! nemo_alloc : dynamical allocation
39	!! nemo_partition : calculate MPP domain decomposition
40	!! factorise : calculate the factors of the no. of MPI processes
41	!!----------------------------------------------------------------------
42	USE step_oce ! module used in the ocean time stepping module
43	USE sbc_oce ! surface boundary condition: ocean
44	USE cla ! cross land advection (tra_cla routine)
45	USE domcfg ! domain configuration (dom_cfg routine)
46	USE mppini ! shared/distributed memory setting (mpp_init routine)
47	USE domain ! domain initialization (dom_init routine)
48	USE obcini ! open boundary cond. initialization (obc_ini routine)
49	USE bdyini ! open boundary cond. initialization (bdy_init routine)
50	USE bdydta ! open boundary cond. initialization (bdy_dta_init routine)
51	USE bdytides ! open boundary cond. initialization (tide_init routine)
52	USE istate ! initial state setting (istate_init routine)
53	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
54	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
55	USE zdfini ! vertical physics setting (zdf_init routine)
56	USE phycst ! physical constant (par_cst routine)
57	USE trdmod ! momentum/tracers trends (trd_mod_init routine)
58	USE asmbkg ! writing out state trajectory
59	USE diaptr ! poleward transports (dia_ptr_init routine)
60	USE diadct ! sections transports (dia_dct_init routine)
61	USE diaobs ! Observation diagnostics (dia_obs_init routine)
62	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
63	USE step ! NEMO time-stepping (stp routine)
64	#if defined key_oasis3
65	USE cpl_oasis3 ! OASIS3 coupling
66	#elif defined key_oasis4
67	USE cpl_oasis4 ! OASIS4 coupling (not working)
68	#endif
69	USE c1d ! 1D configuration
70	USE step_c1d ! Time stepping loop for the 1D configuration
71	#if defined key_top
72	USE trcini ! passive tracer initialisation
73	#endif
74	USE lib_mpp ! distributed memory computing
75	#if defined key_iomput
76	USE mod_ioclient
77	#endif
78	USE tamtrj ! Output trajectory, needed for TAM
79	USE asminc
80
81	IMPLICIT NONE
82	PRIVATE
83
84	PUBLIC nemo_gcm ! called by model.F90
85	PUBLIC nemo_init ! needed by AGRIF
86	PUBLIC nemo_alloc ! needed by TAM
87	PUBLIC nemo_closefile ! Needed by NEMOTAM
88	PUBLIC nemo_partition ! needed by NEMOTAM
89
90	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
91
92	!!----------------------------------------------------------------------
93	!! NEMO/OPA 4.0 , NEMO Consortium (2011)
94	!! $Id$
95	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
96	!!----------------------------------------------------------------------
97	CONTAINS
98
99	SUBROUTINE nemo_gcm
100	!!----------------------------------------------------------------------
101	!! * ROUTINE nemo_gcm *
102	!!
103	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
104	!! curvilinear mesh on the sphere.
105	!!
106	!! ** Method : - model general initialization
107	!! - launch the time-stepping (stp routine)
108	!! - finalize the run by closing files and communications
109	!!
110	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
111	!! Madec, 2008, internal report, IPSL.
112	!!----------------------------------------------------------------------
113	INTEGER :: istp, jk ! time step index
114	!!----------------------------------------------------------------------
115	!
116	#if defined key_agrif
117	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
118	#endif
119
120	! !-----------------------!
121	CALL nemo_init !== Initialisations ==!
122	! !-----------------------!
123	#if defined key_agrif
124	CALL Agrif_Declare_Var ! AGRIF: set the meshes
125	# if defined key_top
126	CALL Agrif_Declare_Var_Top ! AGRIF: set the meshes
127	# endif
128	#endif
129	! check that all process are still there... If some process have an error,
130	! they will never enter in step and other processes will wait until the end of the cpu time!
131	IF( lk_mpp ) CALL mpp_max( nstop )
132
133	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
134
135	! !-----------------------!
136	! !== time stepping ==!
137	! !-----------------------!
138	istp = nit000
139	#if defined key_c1d
140	DO WHILE ( istp <= nitend .AND. nstop == 0 )
141	CALL stp_c1d( istp )
142	istp = istp + 1
143	END DO
144	#else
145	IF( lk_asminc ) THEN
146	IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 ) ! Output background fields
147	IF( ln_asmdin ) THEN ! Direct initialization
148	IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 ) ! Tracers
149	IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 ) ! Dynamics
150	IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 ) ! SSH
151	ENDIF
152	ENDIF
153
154	DO WHILE ( istp <= nitend .AND. nstop == 0 )
155	#if defined key_agrif
156	CALL Agrif_Step( stp ) ! AGRIF: time stepping
157	#else
158	!-------------------------------------------------------------!
159	! This trick ensures a minimum consistency between mixing coef.
160	! and other variables
161	IF( lk_zdftke .AND. lk_asminc .AND. ln_asmdin .AND. ( istp == nit000) ) THEN
162	CALL tke_avn ! recompute avt, avm,
163	! avmu, avmv and dissl (approximation)
164	DO jk = nit000, nit000 + 2
165	CALL zdf_tke( jk ) ;
166	END DO
167
168	END IF
169	!-------------------------------------------------------------!
170
171	CALL stp( istp ) ! standard time stepping
172	#endif
173	istp = istp + 1
174	IF( lk_mpp ) CALL mpp_max( nstop )
175	END DO
176	#endif
177
178	IF( lk_diaobs ) CALL dia_obs_wri
179
180	! !------------------------!
181	! !== finalize the run ==!
182	! !------------------------!
183	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
184	!
185	IF( nstop /= 0 .AND. lwp ) THEN ! error print
186	WRITE(numout,cform_err)
187	WRITE(numout,*) nstop, ' error have been found'
188	ENDIF
189	!
190	#if defined key_agrif
191	CALL Agrif_ParentGrid_To_ChildGrid()
192	IF( lk_diaobs ) CALL dia_obs_wri
193	IF( nn_timing == 1 ) CALL timing_finalize
194	CALL Agrif_ChildGrid_To_ParentGrid()
195	#endif
196	IF( nn_timing == 1 ) CALL timing_finalize
197	!
198	CALL nemo_closefile
199	#if defined key_oasis3 \|\| defined key_oasis4
200	CALL cpl_prism_finalize ! end coupling and mpp communications with OASIS
201	#else
202	IF( lk_mpp ) CALL mppstop ! end mpp communications
203	#endif
204	!
205	END SUBROUTINE nemo_gcm
206
207
208	SUBROUTINE nemo_init
209	!!----------------------------------------------------------------------
210	!! * ROUTINE nemo_init *
211	!!
212	!! ** Purpose : initialization of the NEMO GCM
213	!!----------------------------------------------------------------------
214	INTEGER :: ji ! dummy loop indices
215	INTEGER :: ilocal_comm ! local integer
216	CHARACTER(len=80), DIMENSION(16) :: cltxt
217	!!
218	NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, &
219	& nn_isplt, nn_jsplt, nn_jctls, nn_jctle, &
220	& nn_bench, nn_timing
221	!!----------------------------------------------------------------------
222	!
223	cltxt = ''
224	!
225	! ! open Namelist file
226	CALL ctl_opn( numnam, 'namelist', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
227	!
228	READ( numnam, namctl ) ! Namelist namctl : Control prints & Benchmark
229	!
230	! !--------------------------------------------!
231	! ! set communicator & select the local node !
232	! !--------------------------------------------!
233	#if defined key_iomput
234	IF( Agrif_Root() ) THEN
235	# if defined key_oasis3 \|\| defined key_oasis4
236	CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis
237	# endif
238	CALL init_ioclient( ilocal_comm ) ! exchange io_server nemo local communicator with the io_server
239	ENDIF
240	narea = mynode( cltxt, numnam, nstop, ilocal_comm ) ! Nodes selection
241	#else
242	# if defined key_oasis3 \|\| defined key_oasis4
243	IF( Agrif_Root() ) THEN
244	CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis
245	ENDIF
246	narea = mynode( cltxt, numnam, nstop, ilocal_comm ) ! Nodes selection (control print return in cltxt)
247	# else
248	ilocal_comm = 0
249	narea = mynode( cltxt, numnam, nstop ) ! Nodes selection (control print return in cltxt)
250	# endif
251	#endif
252	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
253
254	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
255
256	! If dimensions of processor grid weren't specified in the namelist file
257	! then we calculate them here now that we have our communicator size
258	IF( (jpni < 1) .OR. (jpnj < 1) )THEN
259	#if defined key_mpp_mpi
260	IF( Agrif_Root() ) CALL nemo_partition(mppsize)
261	#else
262	jpni = 1
263	jpnj = 1
264	jpnij = jpni*jpnj
265	#endif
266	END IF
267
268	! Calculate domain dimensions given calculated jpni and jpnj
269	! This used to be done in par_oce.F90 when they were parameters rather
270	! than variables
271	IF( Agrif_Root() ) THEN
272	jpi = ( jpiglo-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
273	#if defined key_nemocice_decomp
274	jpj = ( jpjglo+1-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
275	#else
276	jpj = ( jpjglo-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
277	#endif
278	jpk = jpkdta ! third dim
279	jpim1 = jpi-1 ! inner domain indices
280	jpjm1 = jpj-1 ! " "
281	jpkm1 = jpk-1 ! " "
282	jpij = jpi*jpj ! jpi x j
283	ENDIF
284
285	IF(lwp) THEN ! open listing units
286	!
287	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
288	!
289	WRITE(numout,*)
290	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
291	WRITE(numout,*) ' NEMO team'
292	WRITE(numout,*) ' Ocean General Circulation Model'
293	WRITE(numout,*) ' version 3.4 (2011) '
294	WRITE(numout,*)
295	WRITE(numout,*)
296	DO ji = 1, SIZE(cltxt)
297	IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode
298	END DO
299	WRITE(numout,cform_aaa) ! Flag AAAAAAA
300	!
301	ENDIF
302
303	! Now we know the dimensions of the grid and numout has been set we can
304	! allocate arrays
305	CALL nemo_alloc()
306
307	! !-------------------------------!
308	! ! NEMO general initialization !
309	! !-------------------------------!
310
311	CALL nemo_ctl ! Control prints & Benchmark
312
313	! ! Domain decomposition
314	IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out
315	ELSE ; CALL mpp_init2 ! eliminate land processors
316	ENDIF
317	!
318	IF( nn_timing == 1 ) CALL timing_init
319	!
320	! ! General initialization
321	CALL phy_cst ! Physical constants
322	CALL eos_init ! Equation of state
323	CALL dom_cfg ! Domain configuration
324	CALL dom_init ! Domain
325
326	IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined)
327
328	IF( ln_ctl ) CALL prt_ctl_init ! Print control
329
330	IF( lk_obc ) CALL obc_init ! Open boundaries
331	IF( lk_bdy ) CALL bdy_init ! Open boundaries initialisation
332	IF( lk_bdy ) CALL bdy_dta_init ! Open boundaries initialisation of external data arrays
333	IF( lk_bdy ) CALL tide_init ! Open boundaries initialisation of tidal harmonic forcing
334
335	CALL flush(numout)
336	CALL dyn_nept_init ! simplified form of Neptune effect
337	CALL flush(numout)
338	CALL asm_inc_rea_nam ! to fix properly neuler value
339	! in istate_init
340	CALL istate_init ! ocean initial state (Dynamics and tracers)
341
342	! ! Ocean physics
343	CALL sbc_init ! Forcings : surface module
344	! ! Vertical physics
345	CALL zdf_init ! namelist read
346	CALL zdf_bfr_init ! bottom friction
347	IF( lk_zdfric ) CALL zdf_ric_init ! Richardson number dependent Kz
348	IF( lk_zdftke ) CALL zdf_tke_init ! TKE closure scheme
349	IF( lk_zdfgls ) CALL zdf_gls_init ! GLS closure scheme
350	IF( lk_zdfkpp ) CALL zdf_kpp_init ! KPP closure scheme
351	IF( lk_zdftmx ) CALL zdf_tmx_init ! tidal vertical mixing
352	IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) &
353	& CALL zdf_ddm_init ! double diffusive mixing
354	! ! Lateral physics
355	CALL ldf_tra_init ! Lateral ocean tracer physics
356	CALL ldf_dyn_init ! Lateral ocean momentum physics
357	IF( lk_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
358
359	! ! Active tracers
360	CALL tra_qsr_init ! penetrative solar radiation qsr
361	CALL tra_bbc_init ! bottom heat flux
362	IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
363	IF( ln_tradmp ) CALL tra_dmp_init ! internal damping trends
364	CALL tra_adv_init ! horizontal & vertical advection
365	CALL tra_ldf_init ! lateral mixing
366	CALL tra_zdf_init ! vertical mixing and after tracer fields
367
368	! ! Dynamics
369	CALL dyn_adv_init ! advection (vector or flux form)
370	CALL dyn_vor_init ! vorticity term including Coriolis
371	CALL dyn_ldf_init ! lateral mixing
372	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
373	CALL dyn_zdf_init ! vertical diffusion
374	CALL dyn_spg_init ! surface pressure gradient
375
376	! ! Misc. options
377	IF( nn_cla == 1 ) CALL cla_init ! Cross Land Advection
378
379	#if defined key_top
380	! ! Passive tracers
381	CALL trc_init
382	#endif
383	! ! Diagnostics
384	IF( lk_floats ) CALL flo_init ! drifting Floats
385	CALL iom_init ! iom_put initialization
386	IF( lk_diaar5 ) CALL dia_ar5_init ! ar5 diag
387	CALL dia_ptr_init ! Poleward TRansports initialization
388	IF( lk_diadct ) CALL dia_dct_init ! Sections tranports
389	CALL dia_hsb_init ! heat content, salt content and volume budgets
390	CALL trd_mod_init ! Mixed-layer/Vorticity/Integral constraints trends
391	IF( lk_diaobs ) THEN ! Observation & model comparison
392	CALL dia_obs_init ! Initialize observational data
393	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
394	ENDIF
395	! ! Assimilation increments
396	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
397	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
398	CALL tam_trj_init ! Trajectory handling
399	!
400	END SUBROUTINE nemo_init
401
402
403	SUBROUTINE nemo_ctl
404	!!----------------------------------------------------------------------
405	!! * ROUTINE nemo_ctl *
406	!!
407	!! ** Purpose : control print setting
408	!!
409	!! ** Method : - print namctl information and check some consistencies
410	!!----------------------------------------------------------------------
411	!
412	IF(lwp) THEN ! control print
413	WRITE(numout,*)
414	WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
415	WRITE(numout,*) '~~~~~~~ '
416	WRITE(numout,*) ' Namelist namctl'
417	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
418	WRITE(numout,*) ' level of print nn_print = ', nn_print
419	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
420	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
421	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
422	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
423	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
424	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
425	WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench
426	WRITE(numout,*) ' timing activated (0/1) nn_timing = ', nn_timing
427	ENDIF
428	!
429	nprint = nn_print ! convert DOCTOR namelist names into OLD names
430	nictls = nn_ictls
431	nictle = nn_ictle
432	njctls = nn_jctls
433	njctle = nn_jctle
434	isplt = nn_isplt
435	jsplt = nn_jsplt
436	nbench = nn_bench
437	! ! Parameter control
438	!
439	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
440	IF( lk_mpp .AND. jpnij > 1 ) THEN
441	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
442	ELSE
443	IF( isplt == 1 .AND. jsplt == 1 ) THEN
444	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
445	& ' - the print control will be done over the whole domain' )
446	ENDIF
447	ijsplt = isplt * jsplt ! total number of processors ijsplt
448	ENDIF
449	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
450	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
451	!
452	! ! indices used for the SUM control
453	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
454	lsp_area = .FALSE.
455	ELSE ! print control done over a specific area
456	lsp_area = .TRUE.
457	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
458	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
459	nictls = 1
460	ENDIF
461	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
462	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
463	nictle = jpiglo
464	ENDIF
465	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
466	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
467	njctls = 1
468	ENDIF
469	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
470	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
471	njctle = jpjglo
472	ENDIF
473	ENDIF
474	ENDIF
475	!
476	IF( nbench == 1 ) THEN ! Benchmark
477	SELECT CASE ( cp_cfg )
478	CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' )
479	CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', &
480	& ' key_gyre must be used or set nbench = 0' )
481	END SELECT
482	ENDIF
483	!
484	IF( lk_c1d .AND. .NOT.lk_iomput ) CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ', &
485	& 'with the IOM Input/Output manager. ' , &
486	& 'Compile with key_iomput enabled' )
487	!
488	IF( 1_wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ', &
489	& 'f2003 standard. ' , &
490	& 'Compile with key_nosignedzero enabled' )
491	!
492	END SUBROUTINE nemo_ctl
493
494
495	SUBROUTINE nemo_closefile
496	!!----------------------------------------------------------------------
497	!! * ROUTINE nemo_closefile *
498	!!
499	!! ** Purpose : Close the files
500	!!----------------------------------------------------------------------
501	!
502	IF( lk_mpp ) CALL mppsync
503	!
504	CALL iom_close ! close all input/output files managed by iom_*
505	!
506	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
507	IF( numsol /= -1 ) CLOSE( numsol ) ! solver file
508	IF( numnam /= -1 ) CLOSE( numnam ) ! oce namelist
509	IF( numnam_ice /= -1 ) CLOSE( numnam_ice ) ! ice namelist
510	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
511	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
512	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
513	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
514	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
515
516	!
517	numout = 6 ! redefine numout in case it is used after this point...
518	!
519	END SUBROUTINE nemo_closefile
520
521
522	SUBROUTINE nemo_alloc
523	!!----------------------------------------------------------------------
524	!! * ROUTINE nemo_alloc *
525	!!
526	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
527	!!
528	!! ** Method :
529	!!----------------------------------------------------------------------
530	USE diawri , ONLY: dia_wri_alloc
531	USE dom_oce , ONLY: dom_oce_alloc
532	USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
533	USE ldftra_oce, ONLY: ldftra_oce_alloc
534	USE trc_oce , ONLY: trc_oce_alloc
535	!
536	INTEGER :: ierr
537	!!----------------------------------------------------------------------
538	!
539	ierr = oce_alloc () ! ocean
540	ierr = ierr + dia_wri_alloc ()
541	ierr = ierr + dom_oce_alloc () ! ocean domain
542	ierr = ierr + ldfdyn_oce_alloc() ! ocean lateral physics : dynamics
543	ierr = ierr + ldftra_oce_alloc() ! ocean lateral physics : tracers
544	ierr = ierr + zdf_oce_alloc () ! ocean vertical physics
545	!
546	ierr = ierr + lib_mpp_alloc (numout) ! mpp exchanges
547	ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays
548	!
549	IF( lk_mpp ) CALL mpp_sum( ierr )
550	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
551	!
552	END SUBROUTINE nemo_alloc
553
554
555	SUBROUTINE nemo_partition( num_pes )
556	!!----------------------------------------------------------------------
557	!! * ROUTINE nemo_partition *
558	!!
559	!! ** Purpose :
560	!!
561	!! ** Method :
562	!!----------------------------------------------------------------------
563	INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
564	!
565	INTEGER, PARAMETER :: nfactmax = 20
566	INTEGER :: nfact ! The no. of factors returned
567	INTEGER :: ierr ! Error flag
568	INTEGER :: ji
569	INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
570	INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
571	!!----------------------------------------------------------------------
572
573	ierr = 0
574
575	CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
576
577	IF( nfact <= 1 ) THEN
578	WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
579	WRITE (numout, *) ' : using grid of ',num_pes,' x 1'
580	jpnj = 1
581	jpni = num_pes
582	ELSE
583	! Search through factors for the pair that are closest in value
584	mindiff = 1000000
585	imin = 1
586	DO ji = 1, nfact-1, 2
587	idiff = ABS( ifact(ji) - ifact(ji+1) )
588	IF( idiff < mindiff ) THEN
589	mindiff = idiff
590	imin = ji
591	ENDIF
592	END DO
593	jpnj = ifact(imin)
594	jpni = ifact(imin + 1)
595	ENDIF
596	!
597	jpnij = jpni*jpnj
598	!
599	END SUBROUTINE nemo_partition
600
601
602	SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
603	!!----------------------------------------------------------------------
604	!! * ROUTINE factorise *
605	!!
606	!! ** Purpose : return the prime factors of n.
607	!! knfax factors are returned in array kfax which is of
608	!! maximum dimension kmaxfax.
609	!! ** Method :
610	!!----------------------------------------------------------------------
611	INTEGER , INTENT(in ) :: kn, kmaxfax
612	INTEGER , INTENT( out) :: kerr, knfax
613	INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax
614	!
615	INTEGER :: ifac, jl, inu
616	INTEGER, PARAMETER :: ntest = 14
617	INTEGER :: ilfax(ntest)
618
619	! lfax contains the set of allowed factors.
620	data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256, &
621	& 128, 64, 32, 16, 8, 4, 2 /
622	!!----------------------------------------------------------------------
623
624	! Clear the error flag and initialise output vars
625	kerr = 0
626	kfax = 1
627	knfax = 0
628
629	! Find the factors of n.
630	IF( kn == 1 ) GOTO 20
631
632	! nu holds the unfactorised part of the number.
633	! knfax holds the number of factors found.
634	! l points to the allowed factor list.
635	! ifac holds the current factor.
636
637	inu = kn
638	knfax = 0
639
640	DO jl = ntest, 1, -1
641	!
642	ifac = ilfax(jl)
643	IF( ifac > inu ) CYCLE
644
645	! Test whether the factor will divide.
646
647	IF( MOD(inu,ifac) == 0 ) THEN
648	!
649	knfax = knfax + 1 ! Add the factor to the list
650	IF( knfax > kmaxfax ) THEN
651	kerr = 6
652	write (,) 'FACTOR: insufficient space in factor array ', knfax
653	return
654	ENDIF
655	kfax(knfax) = ifac
656	! Store the other factor that goes with this one
657	knfax = knfax + 1
658	kfax(knfax) = inu / ifac
659	!WRITE (,) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
660	ENDIF
661	!
662	END DO
663
664	20 CONTINUE ! Label 20 is the exit point from the factor search loop.
665	!
666	END SUBROUTINE factorise
667
668	#if defined key_mpp_mpi
669	SUBROUTINE nemo_northcomms
670	!!======================================================================
671	!! * ROUTINE nemo_northcomms *
672	!! nemo_northcomms : Setup for north fold exchanges with explicit peer to peer messaging
673	!!=====================================================================
674	!!----------------------------------------------------------------------
675	!!
676	!! ** Purpose : Initialization of the northern neighbours lists.
677	!!----------------------------------------------------------------------
678	!! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE)
679	!!----------------------------------------------------------------------
680
681	INTEGER :: ji, jj, jk, ij, jtyp ! dummy loop indices
682	INTEGER :: ijpj ! number of rows involved in north-fold exchange
683	INTEGER :: northcomms_alloc ! allocate return status
684	REAL(wp), ALLOCATABLE, DIMENSION ( :,: ) :: znnbrs ! workspace
685	LOGICAL, ALLOCATABLE, DIMENSION ( : ) :: lrankset ! workspace
686
687	IF(lwp) WRITE(numout,*)
688	IF(lwp) WRITE(numout,*) 'nemo_northcomms : Initialization of the northern neighbours lists'
689	IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
690
691	!!----------------------------------------------------------------------
692	ALLOCATE( znnbrs(jpi,jpj), stat = northcomms_alloc )
693	ALLOCATE( lrankset(jpnij), stat = northcomms_alloc )
694	IF( northcomms_alloc /= 0 ) THEN
695	WRITE(numout,cform_war)
696	WRITE(numout,*) 'northcomms_alloc : failed to allocate arrays'
697	CALL ctl_stop( 'STOP', 'nemo_northcomms : unable to allocate temporary arrays' )
698	ENDIF
699	nsndto = 0
700	isendto = -1
701	ijpj = 4
702	!
703	! This routine has been called because ln_nnogather has been set true ( nammpp )
704	! However, these first few exchanges have to use the mpi_allgather method to
705	! establish the neighbour lists to use in subsequent peer to peer exchanges.
706	! Consequently, set l_north_nogather to be false here and set it true only after
707	! the lists have been established.
708	!
709	l_north_nogather = .FALSE.
710	!
711	! Exchange and store ranks on northern rows
712
713	DO jtyp = 1,4
714
715	lrankset = .FALSE.
716	znnbrs = narea
717	SELECT CASE (jtyp)
718	CASE(1)
719	CALL lbc_lnk( znnbrs, 'T', 1. ) ! Type 1: T,W-points
720	CASE(2)
721	CALL lbc_lnk( znnbrs, 'U', 1. ) ! Type 2: U-point
722	CASE(3)
723	CALL lbc_lnk( znnbrs, 'V', 1. ) ! Type 3: V-point
724	CASE(4)
725	CALL lbc_lnk( znnbrs, 'F', 1. ) ! Type 4: F-point
726	END SELECT
727
728	IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
729	DO jj = nlcj-ijpj+1, nlcj
730	ij = jj - nlcj + ijpj
731	DO ji = 1,jpi
732	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
733	& lrankset(INT(znnbrs(ji,jj))) = .true.
734	END DO
735	END DO
736
737	DO jj = 1,jpnij
738	IF ( lrankset(jj) ) THEN
739	nsndto(jtyp) = nsndto(jtyp) + 1
740	IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
741	CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
742	& ' jpmaxngh will need to be increased ')
743	ENDIF
744	isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank
745	ENDIF
746	END DO
747	ENDIF
748
749	END DO
750
751	!
752	! Type 5: I-point
753	!
754	! ICE point exchanges may involve some averaging. The neighbours list is
755	! built up using two exchanges to ensure that the whole stencil is covered.
756	! lrankset should not be reset between these 'J' and 'K' point exchanges
757
758	jtyp = 5
759	lrankset = .FALSE.
760	znnbrs = narea
761	CALL lbc_lnk( znnbrs, 'J', 1. ) ! first ice U-V point
762
763	IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
764	DO jj = nlcj-ijpj+1, nlcj
765	ij = jj - nlcj + ijpj
766	DO ji = 1,jpi
767	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
768	& lrankset(INT(znnbrs(ji,jj))) = .true.
769	END DO
770	END DO
771	ENDIF
772
773	znnbrs = narea
774	CALL lbc_lnk( znnbrs, 'K', 1. ) ! second ice U-V point
775
776	IF ( njmppt(narea) .EQ. MAXVAL( njmppt )) THEN
777	DO jj = nlcj-ijpj+1, nlcj
778	ij = jj - nlcj + ijpj
779	DO ji = 1,jpi
780	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
781	& lrankset( INT(znnbrs(ji,jj))) = .true.
782	END DO
783	END DO
784
785	DO jj = 1,jpnij
786	IF ( lrankset(jj) ) THEN
787	nsndto(jtyp) = nsndto(jtyp) + 1
788	IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
789	CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
790	& ' jpmaxngh will need to be increased ')
791	ENDIF
792	isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank
793	ENDIF
794	END DO
795	!
796	! For northern row areas, set l_north_nogather so that all subsequent exchanges
797	! can use peer to peer communications at the north fold
798	!
799	l_north_nogather = .TRUE.
800	!
801	ENDIF
802	DEALLOCATE( znnbrs )
803	DEALLOCATE( lrankset )
804
805	END SUBROUTINE nemo_northcomms
806	#else
807	SUBROUTINE nemo_northcomms ! Dummy routine
808	WRITE(,) 'nemo_northcomms: You should not have seen this print! error?'
809	END SUBROUTINE nemo_northcomms
810	#endif
811	!!======================================================================
812	END MODULE nemogcm

Note: See TracBrowser for help on using the repository browser.

Download in other formats: