| 1 | MODULE zpshde |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE zpshde *** |
|---|
| 4 | !! z-coordinate + partial step : Horizontal Derivative at ocean bottom level |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 2002-04 (A. Bozec) Original code |
|---|
| 7 | !! NEMO 1.0 ! 2002-08 (G. Madec E. Durand) Optimization and Free form |
|---|
| 8 | !! - ! 2004-03 (C. Ethe) adapted for passive tracers |
|---|
| 9 | !! 3.3 ! 2010-05 (C. Ethe, G. Madec) merge TRC-TRA |
|---|
| 10 | !! 3.6 ! 2014-11 (P. Mathiot) Add zps_hde_isf (needed to open a cavity) |
|---|
| 11 | !!====================================================================== |
|---|
| 12 | |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! zps_hde : Horizontal DErivative of T, S and rd at the last |
|---|
| 15 | !! ocean level (Z-coord. with Partial Steps) |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE len_oce ! ocean lengths |
|---|
| 18 | USE phycst ! physical constants |
|---|
| 19 | USE in_out_manager ! I/O manager |
|---|
| 20 | USE eosinsitu |
|---|
| 21 | |
|---|
| 22 | IMPLICIT NONE |
|---|
| 23 | PRIVATE |
|---|
| 24 | |
|---|
| 25 | PUBLIC zps_hde ! routine called by step.F90 |
|---|
| 26 | |
|---|
| 27 | !! * Substitutions |
|---|
| 28 | !!---------------------------------------------------------------------- |
|---|
| 29 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 30 | !! $Id$ |
|---|
| 31 | !! Software governed by the CeCILL licence (./LICENSE) |
|---|
| 32 | !!---------------------------------------------------------------------- |
|---|
| 33 | CONTAINS |
|---|
| 34 | |
|---|
| 35 | SUBROUTINE zps_hde( kt, kjpt, pta, mbku, mbkv, e3w_n, gdept_n, tmask, umask, vmask, & |
|---|
| 36 | & pgtu, pgtv, prd, pgru, pgrv, & |
|---|
| 37 | & zti, zhi, zri, ztj, zhj, zrj) |
|---|
| 38 | !!---------------------------------------------------------------------- |
|---|
| 39 | !! *** ROUTINE zps_hde *** |
|---|
| 40 | !! |
|---|
| 41 | !! ** Purpose : Compute the horizontal derivative of T, S and rho |
|---|
| 42 | !! at u- and v-points with a linear interpolation for z-coordinate |
|---|
| 43 | !! with partial steps. |
|---|
| 44 | !! |
|---|
| 45 | !! ** Method : In z-coord with partial steps, scale factors on last |
|---|
| 46 | !! levels are different for each grid point, so that T, S and rd |
|---|
| 47 | !! points are not at the same depth as in z-coord. To have horizontal |
|---|
| 48 | !! gradients again, we interpolate T and S at the good depth : |
|---|
| 49 | !! Linear interpolation of T, S |
|---|
| 50 | !! Computation of di(tb) and dj(tb) by vertical interpolation: |
|---|
| 51 | !! di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~ |
|---|
| 52 | !! dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~ |
|---|
| 53 | !! This formulation computes the two cases: |
|---|
| 54 | !! CASE 1 CASE 2 |
|---|
| 55 | !! k-1 ___ ___________ k-1 ___ ___________ |
|---|
| 56 | !! Ti T~ T~ Ti+1 |
|---|
| 57 | !! _____ _____ |
|---|
| 58 | !! k | |Ti+1 k Ti | | |
|---|
| 59 | !! | |____ ____| | |
|---|
| 60 | !! ___ | | | ___ | | | |
|---|
| 61 | !! |
|---|
| 62 | !! case 1-> e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then |
|---|
| 63 | !! t~ = t(i+1,j ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1) |
|---|
| 64 | !! ( t~ = t(i ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1) ) |
|---|
| 65 | !! or |
|---|
| 66 | !! case 2-> e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then |
|---|
| 67 | !! t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i ) |
|---|
| 68 | !! ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) ) |
|---|
| 69 | !! Idem for di(s) and dj(s) |
|---|
| 70 | !! |
|---|
| 71 | !! For rho, we call eos which will compute rd~(t~,s~) at the right |
|---|
| 72 | !! depth zh from interpolated T and S for the different formulations |
|---|
| 73 | !! of the equation of state (eos). |
|---|
| 74 | !! Gradient formulation for rho : |
|---|
| 75 | !! di(rho) = rd~ - rd(i,j,k) or rd(i+1,j,k) - rd~ |
|---|
| 76 | !! |
|---|
| 77 | !! ** Action : compute for top interfaces |
|---|
| 78 | !! - pgtu, pgtv: horizontal gradient of tracer at u- & v-points |
|---|
| 79 | !! - pgru, pgrv: horizontal gradient of rho (if present) at u- & v-points |
|---|
| 80 | !!---------------------------------------------------------------------- |
|---|
| 81 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
|---|
| 82 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
|---|
| 83 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in ) :: pta ! 4D tracers fields |
|---|
| 84 | INTEGER, DIMENSION(jpi,jpj) , INTENT(in ) :: mbku, mbkv |
|---|
| 85 | REAL(wp), DIMENSION(jpi,jpj,jpk ), INTENT(in ) :: e3w_n, gdept_n |
|---|
| 86 | REAL(wp), DIMENSION(jpi,jpj,jpk ), INTENT(in ) :: tmask, umask, vmask |
|---|
| 87 | REAL(wp), DIMENSION(jpi,jpj, kjpt), INTENT( out) :: pgtu, pgtv ! hor. grad. of ptra at u- & v-pts |
|---|
| 88 | REAL(wp), DIMENSION(jpi,jpj,jpk ), INTENT(in ), OPTIONAL :: prd ! 3D density anomaly fields |
|---|
| 89 | REAL(wp), DIMENSION(jpi,jpj ), INTENT( out), OPTIONAL :: pgru, pgrv ! hor. grad of prd at u- & v-pts (bottom) |
|---|
| 90 | REAL(wp), DIMENSION(jpi,jpj ) ,INTENT(inout) :: zri, zrj, zhi, zhj ! NB: 3rd dim=1 to use eos |
|---|
| 91 | REAL(wp), DIMENSION(jpi,jpj,kjpt ) ,INTENT(inout) :: zti, ztj ! |
|---|
| 92 | ! |
|---|
| 93 | INTEGER :: ji, jj, jn ! Dummy loop indices |
|---|
| 94 | INTEGER :: iku, ikv, ikum1, ikvm1 ! partial step level (ocean bottom level) at u- and v-points |
|---|
| 95 | REAL(wp) :: ze3wu, ze3wv, zmaxu, zmaxv ! local scalars |
|---|
| 96 | REAL(wp) :: et |
|---|
| 97 | !!---------------------------------------------------------------------- |
|---|
| 98 | et = TIMER() |
|---|
| 99 | ! |
|---|
| 100 | ! |
|---|
| 101 | |
|---|
| 102 | !$ACC KERNELS |
|---|
| 103 | !$OMP PARALLEL |
|---|
| 104 | !$OMP WORKSHARE |
|---|
| 105 | pgtu(:,:,:) = 0._wp ; zti (:,:,:) = 0._wp ; zhi (:,:) = 0._wp |
|---|
| 106 | pgtv(:,:,:) = 0._wp ; ztj (:,:,:) = 0._wp ; zhj (:,:) = 0._wp |
|---|
| 107 | !$OMP END WORKSHARE |
|---|
| 108 | ! |
|---|
| 109 | !$OMP DO PRIVATE(iku,ikv,ikum1,ikvm1,ze3wu,ze3wv,zmaxu) |
|---|
| 110 | DO jn = 1, kjpt !== Interpolation of tracers at the last ocean level ==! |
|---|
| 111 | ! |
|---|
| 112 | DO jj = 1, jpjm1 |
|---|
| 113 | DO ji = 1, jpim1 |
|---|
| 114 | iku = mbku(ji,jj) ; ikum1 = MAX( iku - 1 , 1 ) ! last and before last ocean level at u- & v-points |
|---|
| 115 | ikv = mbkv(ji,jj) ; ikvm1 = MAX( ikv - 1 , 1 ) ! if level first is a p-step, ik.m1=1 |
|---|
| 116 | !!gm BUG ? when applied to before fields, e3w_b should be used.... |
|---|
| 117 | ze3wu = e3w_n(ji+1,jj ,iku) - e3w_n(ji,jj,iku) |
|---|
| 118 | ze3wv = e3w_n(ji ,jj+1,ikv) - e3w_n(ji,jj,ikv) |
|---|
| 119 | ! |
|---|
| 120 | ! i- direction |
|---|
| 121 | IF( ze3wu >= 0._wp ) THEN ! case 1 |
|---|
| 122 | zmaxu = ze3wu / e3w_n(ji+1,jj,iku) |
|---|
| 123 | ! interpolated values of tracers |
|---|
| 124 | zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) ) |
|---|
| 125 | ! gradient of tracers |
|---|
| 126 | pgtu(ji,jj,jn) = umask(ji,jj,1) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) ) |
|---|
| 127 | ELSE ! case 2 |
|---|
| 128 | zmaxu = -ze3wu / e3w_n(ji,jj,iku) |
|---|
| 129 | ! interpolated values of tracers |
|---|
| 130 | zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) ) |
|---|
| 131 | ! gradient of tracers |
|---|
| 132 | pgtu(ji,jj,jn) = umask(ji,jj,1) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) ) |
|---|
| 133 | ENDIF |
|---|
| 134 | ! |
|---|
| 135 | ! j- direction |
|---|
| 136 | IF( ze3wv >= 0._wp ) THEN ! case 1 |
|---|
| 137 | zmaxv = ze3wv / e3w_n(ji,jj+1,ikv) |
|---|
| 138 | ! interpolated values of tracers |
|---|
| 139 | ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) ) |
|---|
| 140 | ! gradient of tracers |
|---|
| 141 | pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) ) |
|---|
| 142 | ELSE ! case 2 |
|---|
| 143 | zmaxv = -ze3wv / e3w_n(ji,jj,ikv) |
|---|
| 144 | ! interpolated values of tracers |
|---|
| 145 | ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) ) |
|---|
| 146 | ! gradient of tracers |
|---|
| 147 | pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) ) |
|---|
| 148 | ENDIF |
|---|
| 149 | END DO |
|---|
| 150 | END DO |
|---|
| 151 | ! MJB CALL lbc_lnk_multi( pgtu(:,:,jn), 'U', -1. , pgtv(:,:,jn), 'V', -1. ) ! Lateral boundary cond. |
|---|
| 152 | ! |
|---|
| 153 | END DO |
|---|
| 154 | !$OMP END PARALLEL |
|---|
| 155 | !$ACC END KERNELS |
|---|
| 156 | ! |
|---|
| 157 | IF( PRESENT( prd ) ) THEN !== horizontal derivative of density anomalies (rd) ==! (optional part) |
|---|
| 158 | !$ACC KERNELS |
|---|
| 159 | |
|---|
| 160 | !$OMP PARALLEL |
|---|
| 161 | !$OMP WORKSHARE |
|---|
| 162 | pgru(:,:) = 0._wp |
|---|
| 163 | pgrv(:,:) = 0._wp ! depth of the partial step level |
|---|
| 164 | !$OMP END WORKSHARE |
|---|
| 165 | !$OMP DO PRIVATE(iku,ikv,ze3wu,ze3wv) |
|---|
| 166 | DO jj = 1, jpjm1 |
|---|
| 167 | DO ji = 1, jpim1 |
|---|
| 168 | iku = mbku(ji,jj) |
|---|
| 169 | ikv = mbkv(ji,jj) |
|---|
| 170 | ze3wu = e3w_n(ji+1,jj ,iku) - e3w_n(ji,jj,iku) |
|---|
| 171 | ze3wv = e3w_n(ji ,jj+1,ikv) - e3w_n(ji,jj,ikv) |
|---|
| 172 | IF( ze3wu >= 0._wp ) THEN ; zhi(ji,jj) = gdept_n(ji ,jj,iku) ! i-direction: case 1 |
|---|
| 173 | ELSE ; zhi(ji,jj) = gdept_n(ji+1,jj,iku) ! - - case 2 |
|---|
| 174 | ENDIF |
|---|
| 175 | IF( ze3wv >= 0._wp ) THEN ; zhj(ji,jj) = gdept_n(ji,jj ,ikv) ! j-direction: case 1 |
|---|
| 176 | ELSE ; zhj(ji,jj) = gdept_n(ji,jj+1,ikv) ! - - case 2 |
|---|
| 177 | ENDIF |
|---|
| 178 | END DO |
|---|
| 179 | END DO |
|---|
| 180 | ! |
|---|
| 181 | !$OMP END PARALLEL |
|---|
| 182 | !$ACC END KERNELS |
|---|
| 183 | ! _2d re-instated here to make it easier to read ! |
|---|
| 184 | CALL eos_insitu_2d( zti, zhi, zri ) ! interpolated density from zti, ztj |
|---|
| 185 | CALL eos_insitu_2d( ztj, zhj, zrj ) ! at the partial step depth output in zri, zrj |
|---|
| 186 | |
|---|
| 187 | ! |
|---|
| 188 | !$ACC KERNELS |
|---|
| 189 | !$OMP PARALLEL DO PRIVATE(iku,ikv,ze3wu,ze3wv) |
|---|
| 190 | DO jj = 1, jpjm1 ! Gradient of density at the last level |
|---|
| 191 | DO ji = 1, jpim1 |
|---|
| 192 | iku = mbku(ji,jj) |
|---|
| 193 | ikv = mbkv(ji,jj) |
|---|
| 194 | ze3wu = e3w_n(ji+1,jj ,iku) - e3w_n(ji,jj,iku) |
|---|
| 195 | ze3wv = e3w_n(ji ,jj+1,ikv) - e3w_n(ji,jj,ikv) |
|---|
| 196 | IF( ze3wu >= 0._wp ) THEN ; pgru(ji,jj) = umask(ji,jj,1) * ( zri(ji ,jj ) - prd(ji,jj,iku) ) ! i: 1 |
|---|
| 197 | ELSE ; pgru(ji,jj) = umask(ji,jj,1) * ( prd(ji+1,jj,iku) - zri(ji,jj ) ) ! i: 2 |
|---|
| 198 | ENDIF |
|---|
| 199 | IF( ze3wv >= 0._wp ) THEN ; pgrv(ji,jj) = vmask(ji,jj,1) * ( zrj(ji,jj ) - prd(ji,jj,ikv) ) ! j: 1 |
|---|
| 200 | ELSE ; pgrv(ji,jj) = vmask(ji,jj,1) * ( prd(ji,jj+1,ikv) - zrj(ji,jj ) ) ! j: 2 |
|---|
| 201 | ENDIF |
|---|
| 202 | END DO |
|---|
| 203 | END DO |
|---|
| 204 | !$ACC END KERNELS |
|---|
| 205 | ! MJB CALL lbc_lnk_multi( pgru , 'U', -1. , pgrv , 'V', -1. ) ! Lateral boundary conditions |
|---|
| 206 | ! |
|---|
| 207 | END IF |
|---|
| 208 | ! ! |
|---|
| 209 | !zps_hde_time = zps_hde_time + (TIMER() - et) ! Timer moved up call tree |
|---|
| 210 | END SUBROUTINE zps_hde |
|---|
| 211 | |
|---|
| 212 | !!====================================================================== |
|---|
| 213 | END MODULE zpshde |
|---|
