1 | MODULE eosinsitu |
---|
2 | !!============================================================================== |
---|
3 | !! *** MODULE eosbn2 *** |
---|
4 | !! Equation Of Seawater : in situ density - Brunt-Vaisala frequency |
---|
5 | !!============================================================================== |
---|
6 | !! History : OPA ! 1989-03 (O. Marti) Original code |
---|
7 | !! 6.0 ! 1994-07 (G. Madec, M. Imbard) add bn2 |
---|
8 | !! 6.0 ! 1994-08 (G. Madec) Add Jackett & McDougall eos |
---|
9 | !! 7.0 ! 1996-01 (G. Madec) statement function for e3 |
---|
10 | !! 8.1 ! 1997-07 (G. Madec) density instead of volumic mass |
---|
11 | !! - ! 1999-02 (G. Madec, N. Grima) semi-implicit pressure gradient |
---|
12 | !! 8.2 ! 2001-09 (M. Ben Jelloul) bugfix on linear eos |
---|
13 | !! NEMO 1.0 ! 2002-10 (G. Madec) add eos_init |
---|
14 | !! - ! 2002-11 (G. Madec, A. Bozec) partial step, eos_insitu_2d |
---|
15 | !! - ! 2003-08 (G. Madec) F90, free form |
---|
16 | !! 3.0 ! 2006-08 (G. Madec) add tfreez function (now eos_fzp function) |
---|
17 | !! 3.3 ! 2010-05 (C. Ethe, G. Madec) merge TRC-TRA |
---|
18 | !! - ! 2010-10 (G. Nurser, G. Madec) add alpha/beta used in ldfslp |
---|
19 | !! 3.7 ! 2012-03 (F. Roquet, G. Madec) add primitive of alpha and beta used in PE computation |
---|
20 | !! - ! 2012-05 (F. Roquet) add Vallis and original JM95 equation of state |
---|
21 | !! - ! 2013-04 (F. Roquet, G. Madec) add eos_rab, change bn2 computation and reorganize the module |
---|
22 | !! - ! 2014-09 (F. Roquet) add TEOS-10, S-EOS, and modify EOS-80 |
---|
23 | !! - ! 2015-06 (P.A. Bouttier) eos_fzp functions changed to subroutines for AGRIF |
---|
24 | !!---------------------------------------------------------------------- |
---|
25 | |
---|
26 | !!---------------------------------------------------------------------- |
---|
27 | !! eos : generic interface of the equation of state |
---|
28 | !! eos_insitu : Compute the in situ density |
---|
29 | !! eos_insitu_pot: Compute the insitu and surface referenced potential volumic mass |
---|
30 | !! eos_insitu_2d : Compute the in situ density for 2d fields |
---|
31 | !! eos_init : set eos parameters (namelist) |
---|
32 | !!---------------------------------------------------------------------- |
---|
33 | USE phycst ! physical constants |
---|
34 | USE in_out_manager ! I/O manager |
---|
35 | USE len_oce ! lengths: e.g. jpi, jpj |
---|
36 | ! |
---|
37 | |
---|
38 | IMPLICIT NONE |
---|
39 | ! |
---|
40 | PUBLIC eos_insitu |
---|
41 | PUBLIC eos_insitu_pot |
---|
42 | PUBLIC eos_init ! called by istate module |
---|
43 | PUBLIC eos_insitu_2d |
---|
44 | PUBLIC eos_rab_3d |
---|
45 | PUBLIC bn2 |
---|
46 | |
---|
47 | ! !!** Namelist nameos ** |
---|
48 | LOGICAL , PUBLIC :: ln_TEOS10 ! determine if eos_pt_from_ct is used to compute sst_m |
---|
49 | LOGICAL , PUBLIC :: ln_EOS80 ! determine if eos_pt_from_ct is used to compute sst_m |
---|
50 | LOGICAL , PUBLIC :: ln_SEOS ! determine if eos_pt_from_ct is used to compute sst_m |
---|
51 | |
---|
52 | ! Parameters |
---|
53 | LOGICAL , PUBLIC :: l_useCT ! =T in ln_TEOS10=T (i.e. use eos_pt_from_ct to compute sst_m), =F otherwise |
---|
54 | INTEGER , PUBLIC :: neos ! Identifier for equation of state used |
---|
55 | |
---|
56 | INTEGER , PARAMETER :: np_teos10 = -1 ! parameter for using TEOS10 |
---|
57 | INTEGER , PARAMETER :: np_eos80 = 0 ! parameter for using EOS80 |
---|
58 | INTEGER , PARAMETER :: np_seos = 1 ! parameter for using Simplified Equation of state |
---|
59 | |
---|
60 | ! !!! simplified eos coefficients (default value: Vallis 2006) |
---|
61 | REAL(wp) :: rn_a0 = 1.6550e-1_wp ! thermal expansion coeff. |
---|
62 | REAL(wp) :: rn_b0 = 7.6554e-1_wp ! saline expansion coeff. |
---|
63 | REAL(wp) :: rn_lambda1 = 5.9520e-2_wp ! cabbeling coeff. in T^2 |
---|
64 | REAL(wp) :: rn_lambda2 = 5.4914e-4_wp ! cabbeling coeff. in S^2 |
---|
65 | REAL(wp) :: rn_mu1 = 1.4970e-4_wp ! thermobaric coeff. in T |
---|
66 | REAL(wp) :: rn_mu2 = 1.1090e-5_wp ! thermobaric coeff. in S |
---|
67 | REAL(wp) :: rn_nu = 2.4341e-3_wp ! cabbeling coeff. in theta*salt |
---|
68 | |
---|
69 | ! TEOS10/EOS80 parameters |
---|
70 | REAL(wp) :: r1_S0, r1_T0, r1_Z0, rdeltaS |
---|
71 | |
---|
72 | ! EOS parameters |
---|
73 | REAL(wp) :: EOS000 , EOS100 , EOS200 , EOS300 , EOS400 , EOS500 , EOS600 |
---|
74 | REAL(wp) :: EOS010 , EOS110 , EOS210 , EOS310 , EOS410 , EOS510 |
---|
75 | REAL(wp) :: EOS020 , EOS120 , EOS220 , EOS320 , EOS420 |
---|
76 | REAL(wp) :: EOS030 , EOS130 , EOS230 , EOS330 |
---|
77 | REAL(wp) :: EOS040 , EOS140 , EOS240 |
---|
78 | REAL(wp) :: EOS050 , EOS150 |
---|
79 | REAL(wp) :: EOS060 |
---|
80 | REAL(wp) :: EOS001 , EOS101 , EOS201 , EOS301 , EOS401 |
---|
81 | REAL(wp) :: EOS011 , EOS111 , EOS211 , EOS311 |
---|
82 | REAL(wp) :: EOS021 , EOS121 , EOS221 |
---|
83 | REAL(wp) :: EOS031 , EOS131 |
---|
84 | REAL(wp) :: EOS041 |
---|
85 | REAL(wp) :: EOS002 , EOS102 , EOS202 |
---|
86 | REAL(wp) :: EOS012 , EOS112 |
---|
87 | REAL(wp) :: EOS022 |
---|
88 | REAL(wp) :: EOS003 , EOS103 |
---|
89 | REAL(wp) :: EOS013 |
---|
90 | |
---|
91 | ! ALPHA parameters |
---|
92 | REAL(wp) :: ALP000 , ALP100 , ALP200 , ALP300 , ALP400 , ALP500 |
---|
93 | REAL(wp) :: ALP010 , ALP110 , ALP210 , ALP310 , ALP410 |
---|
94 | REAL(wp) :: ALP020 , ALP120 , ALP220 , ALP320 |
---|
95 | REAL(wp) :: ALP030 , ALP130 , ALP230 |
---|
96 | REAL(wp) :: ALP040 , ALP140 |
---|
97 | REAL(wp) :: ALP050 |
---|
98 | REAL(wp) :: ALP001 , ALP101 , ALP201 , ALP301 |
---|
99 | REAL(wp) :: ALP011 , ALP111 , ALP211 |
---|
100 | REAL(wp) :: ALP021 , ALP121 |
---|
101 | REAL(wp) :: ALP031 |
---|
102 | REAL(wp) :: ALP002 , ALP102 |
---|
103 | REAL(wp) :: ALP012 |
---|
104 | REAL(wp) :: ALP003 |
---|
105 | |
---|
106 | ! BETA parameters |
---|
107 | REAL(wp) :: BET000 , BET100 , BET200 , BET300 , BET400 , BET500 |
---|
108 | REAL(wp) :: BET010 , BET110 , BET210 , BET310 , BET410 |
---|
109 | REAL(wp) :: BET020 , BET120 , BET220 , BET320 |
---|
110 | REAL(wp) :: BET030 , BET130 , BET230 |
---|
111 | REAL(wp) :: BET040 , BET140 |
---|
112 | REAL(wp) :: BET050 |
---|
113 | REAL(wp) :: BET001 , BET101 , BET201 , BET301 |
---|
114 | REAL(wp) :: BET011 , BET111 , BET211 |
---|
115 | REAL(wp) :: BET021 , BET121 |
---|
116 | REAL(wp) :: BET031 |
---|
117 | REAL(wp) :: BET002 , BET102 |
---|
118 | REAL(wp) :: BET012 |
---|
119 | REAL(wp) :: BET003 |
---|
120 | |
---|
121 | ! PEN parameters |
---|
122 | REAL(wp) :: PEN000 , PEN100 , PEN200 , PEN300 , PEN400 |
---|
123 | REAL(wp) :: PEN010 , PEN110 , PEN210 , PEN310 |
---|
124 | REAL(wp) :: PEN020 , PEN120 , PEN220 |
---|
125 | REAL(wp) :: PEN030 , PEN130 |
---|
126 | REAL(wp) :: PEN040 |
---|
127 | REAL(wp) :: PEN001 , PEN101 , PEN201 |
---|
128 | REAL(wp) :: PEN011 , PEN111 |
---|
129 | REAL(wp) :: PEN021 |
---|
130 | REAL(wp) :: PEN002 , PEN102 |
---|
131 | REAL(wp) :: PEN012 |
---|
132 | |
---|
133 | ! ALPHA_PEN parameters |
---|
134 | REAL(wp) :: APE000 , APE100 , APE200 , APE300 |
---|
135 | REAL(wp) :: APE010 , APE110 , APE210 |
---|
136 | REAL(wp) :: APE020 , APE120 |
---|
137 | REAL(wp) :: APE030 |
---|
138 | REAL(wp) :: APE001 , APE101 |
---|
139 | REAL(wp) :: APE011 |
---|
140 | REAL(wp) :: APE002 |
---|
141 | |
---|
142 | ! BETA_PEN parameters |
---|
143 | REAL(wp) :: BPE000 , BPE100 , BPE200 , BPE300 |
---|
144 | REAL(wp) :: BPE010 , BPE110 , BPE210 |
---|
145 | REAL(wp) :: BPE020 , BPE120 |
---|
146 | REAL(wp) :: BPE030 |
---|
147 | REAL(wp) :: BPE001 , BPE101 |
---|
148 | REAL(wp) :: BPE011 |
---|
149 | REAL(wp) :: BPE002 |
---|
150 | |
---|
151 | !! * Substitutions |
---|
152 | # include "vectopt_loop_substitute.h90" |
---|
153 | !!---------------------------------------------------------------------- |
---|
154 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
---|
155 | !! $Id$ |
---|
156 | !! Software governed by the CeCILL licence (./LICENSE) |
---|
157 | !!---------------------------------------------------------------------- |
---|
158 | CONTAINS |
---|
159 | |
---|
160 | SUBROUTINE eos_insitu( pts, tmask, prd, pdep ) |
---|
161 | !!---------------------------------------------------------------------- |
---|
162 | !! *** ROUTINE eos_insitu *** |
---|
163 | !! |
---|
164 | !! ** Purpose : Compute the in situ density (ratio rho/rau0) from |
---|
165 | !! potential temperature and salinity using an equation of state |
---|
166 | !! selected in the nameos namelist |
---|
167 | !! |
---|
168 | !! ** Method : prd(t,s,z) = ( rho(t,s,z) - rau0 ) / rau0 |
---|
169 | !! with prd in situ density anomaly no units |
---|
170 | !! t TEOS10: CT or EOS80: PT Celsius |
---|
171 | !! s TEOS10: SA or EOS80: SP TEOS10: g/kg or EOS80: psu |
---|
172 | !! z depth meters |
---|
173 | !! rho in situ density kg/m^3 |
---|
174 | !! rau0 reference density kg/m^3 |
---|
175 | !! |
---|
176 | !! ln_teos10 : polynomial TEOS-10 equation of state is used for rho(t,s,z). |
---|
177 | !! Check value: rho = 1028.21993233072 kg/m^3 for z=3000 dbar, ct=3 Celsius, sa=35.5 g/kg |
---|
178 | !! |
---|
179 | !! ln_eos80 : polynomial EOS-80 equation of state is used for rho(t,s,z). |
---|
180 | !! Check value: rho = 1028.35011066567 kg/m^3 for z=3000 dbar, pt=3 Celsius, sp=35.5 psu |
---|
181 | !! |
---|
182 | !! ln_seos : simplified equation of state |
---|
183 | !! prd(t,s,z) = ( -a0*(1+lambda/2*(T-T0)+mu*z+nu*(S-S0))*(T-T0) + b0*(S-S0) ) / rau0 |
---|
184 | !! linear case function of T only: rn_alpha<>0, other coefficients = 0 |
---|
185 | !! linear eos function of T and S: rn_alpha and rn_beta<>0, other coefficients=0 |
---|
186 | !! Vallis like equation: use default values of coefficients |
---|
187 | !! |
---|
188 | !! ** Action : compute prd , the in situ density (no units) |
---|
189 | !! |
---|
190 | !! References : Roquet et al, Ocean Modelling, in preparation (2014) |
---|
191 | !! Vallis, Atmospheric and Oceanic Fluid Dynamics, 2006 |
---|
192 | !! TEOS-10 Manual, 2010 |
---|
193 | !!---------------------------------------------------------------------- |
---|
194 | REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in ) :: pts ! 1 : potential temperature [Celsius] |
---|
195 | ! ! 2 : salinity [psu] |
---|
196 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in ) :: tmask ! mask at T points |
---|
197 | REAL(wp), DIMENSION(jpi,jpj,jpk ), INTENT( out) :: prd ! in situ density [-] |
---|
198 | REAL(wp), DIMENSION(jpi,jpj,jpk ), INTENT(in ) :: pdep ! depth [m] |
---|
199 | ! |
---|
200 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
201 | REAL(wp) :: zt , zh , zs , ztm ! local scalars |
---|
202 | REAL(wp) :: zn , zn0, zn1, zn2, zn3 ! - - |
---|
203 | !!---------------------------------------------------------------------- |
---|
204 | ! |
---|
205 | ! |
---|
206 | SELECT CASE( neos ) |
---|
207 | ! |
---|
208 | CASE( np_teos10, np_eos80 ) !== polynomial TEOS-10 / EOS-80 ==! |
---|
209 | !$OMP PARALLEL DO PRIVATE(zh,zt,zs,ztm,zn,zn0,zn1,zn2,zn3) |
---|
210 | DO jk = 1, jpkm1 |
---|
211 | DO jj = 1, jpj |
---|
212 | DO ji = 1, jpi |
---|
213 | ! |
---|
214 | zh = pdep(ji,jj,jk) * r1_Z0 ! depth |
---|
215 | zt = pts (ji,jj,jk,jp_tem) * r1_T0 ! temperature |
---|
216 | zs = SQRT( ABS( pts(ji,jj,jk,jp_sal) + rdeltaS ) * r1_S0 ) ! square root salinity |
---|
217 | ztm = tmask(ji,jj,jk) ! tmask |
---|
218 | ! |
---|
219 | zn3 = EOS013*zt & |
---|
220 | & + EOS103*zs+EOS003 |
---|
221 | ! |
---|
222 | zn2 = (EOS022*zt & |
---|
223 | & + EOS112*zs+EOS012)*zt & |
---|
224 | & + (EOS202*zs+EOS102)*zs+EOS002 |
---|
225 | ! |
---|
226 | zn1 = (((EOS041*zt & |
---|
227 | & + EOS131*zs+EOS031)*zt & |
---|
228 | & + (EOS221*zs+EOS121)*zs+EOS021)*zt & |
---|
229 | & + ((EOS311*zs+EOS211)*zs+EOS111)*zs+EOS011)*zt & |
---|
230 | & + (((EOS401*zs+EOS301)*zs+EOS201)*zs+EOS101)*zs+EOS001 |
---|
231 | ! |
---|
232 | zn0 = (((((EOS060*zt & |
---|
233 | & + EOS150*zs+EOS050)*zt & |
---|
234 | & + (EOS240*zs+EOS140)*zs+EOS040)*zt & |
---|
235 | & + ((EOS330*zs+EOS230)*zs+EOS130)*zs+EOS030)*zt & |
---|
236 | & + (((EOS420*zs+EOS320)*zs+EOS220)*zs+EOS120)*zs+EOS020)*zt & |
---|
237 | & + ((((EOS510*zs+EOS410)*zs+EOS310)*zs+EOS210)*zs+EOS110)*zs+EOS010)*zt & |
---|
238 | & + (((((EOS600*zs+EOS500)*zs+EOS400)*zs+EOS300)*zs+EOS200)*zs+EOS100)*zs+EOS000 |
---|
239 | ! |
---|
240 | zn = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0 |
---|
241 | ! |
---|
242 | prd(ji,jj,jk) = ( zn * r1_rau0 - 1._wp ) * ztm ! density anomaly (masked) |
---|
243 | ! |
---|
244 | END DO |
---|
245 | END DO |
---|
246 | END DO |
---|
247 | ! |
---|
248 | CASE( np_seos ) !== simplified EOS ==! |
---|
249 | |
---|
250 | !$OMP PARALLEL DO PRIVATE(zt,zs,zh,ztm,zn) |
---|
251 | DO jk = 1, jpkm1 |
---|
252 | DO jj = 1, jpj |
---|
253 | DO ji = 1, jpi |
---|
254 | zt = pts (ji,jj,jk,jp_tem) - 10._wp |
---|
255 | zs = pts (ji,jj,jk,jp_sal) - 35._wp |
---|
256 | zh = pdep (ji,jj,jk) |
---|
257 | ztm = tmask(ji,jj,jk) |
---|
258 | ! |
---|
259 | zn = - rn_a0 * ( 1._wp + 0.5_wp*rn_lambda1*zt + rn_mu1*zh ) * zt & |
---|
260 | & + rn_b0 * ( 1._wp - 0.5_wp*rn_lambda2*zs - rn_mu2*zh ) * zs & |
---|
261 | & - rn_nu * zt * zs |
---|
262 | ! |
---|
263 | prd(ji,jj,jk) = zn * r1_rau0 * ztm ! density anomaly (masked) |
---|
264 | END DO |
---|
265 | END DO |
---|
266 | END DO |
---|
267 | |
---|
268 | END SELECT |
---|
269 | ! |
---|
270 | END SUBROUTINE eos_insitu |
---|
271 | |
---|
272 | SUBROUTINE eos_insitu_pot(pts, tmask, prd, prhop, pdep ) |
---|
273 | !!---------------------------------------------------------------------- |
---|
274 | !! *** ROUTINE eos_insitu_pot *** |
---|
275 | !! |
---|
276 | !! ** Purpose : Compute the in situ density (ratio rho/rau0) and the |
---|
277 | !! potential volumic mass (Kg/m3) from potential temperature and |
---|
278 | !! salinity fields using an equation of state selected in the |
---|
279 | !! namelist. |
---|
280 | !! |
---|
281 | !! ** Action : - prd , the in situ density (no units) |
---|
282 | !! - prhop, the potential volumic mass (Kg/m3) |
---|
283 | !! |
---|
284 | !!---------------------------------------------------------------------- |
---|
285 | REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in ) :: pts ! 1 : potential temperature [Celsius] |
---|
286 | ! ! 2 : salinity [psu] |
---|
287 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in ) :: tmask ! mask at T points |
---|
288 | REAL(wp), DIMENSION(jpi,jpj,jpk ), INTENT( out) :: prd ! in situ density [-] |
---|
289 | REAL(wp), DIMENSION(jpi,jpj,jpk ), INTENT( out) :: prhop ! potential density (surface referenced) |
---|
290 | REAL(wp), DIMENSION(jpi,jpj,jpk ), INTENT(in ) :: pdep ! depth [m] |
---|
291 | ! |
---|
292 | INTEGER :: ji, jj, jk, jsmp ! dummy loop indices |
---|
293 | INTEGER :: jdof |
---|
294 | REAL(wp) :: zt , zh , zstemp, zs , ztm ! local scalars |
---|
295 | REAL(wp) :: zn , zn0, zn1, zn2, zn3 ! - - |
---|
296 | REAL(wp) :: et |
---|
297 | !!---------------------------------------------------------------------- |
---|
298 | ! |
---|
299 | et = TIMER() |
---|
300 | SELECT CASE ( neos ) |
---|
301 | ! |
---|
302 | CASE( np_teos10, np_eos80 ) !== polynomial TEOS-10 / EOS-80 ==! |
---|
303 | ! |
---|
304 | ! Stochastic equation of state has been removed |
---|
305 | ! Non-stochastic equation of state |
---|
306 | !$OMP PARALLEL DO PRIVATE(zh,zt,zs,ztm,zn0,zn1,zn2,zn3,zn) |
---|
307 | DO jk = 1, jpkm1 |
---|
308 | DO jj = 1, jpj |
---|
309 | DO ji = 1, jpi |
---|
310 | ! |
---|
311 | zh = pdep(ji,jj,jk) * r1_Z0 ! depth |
---|
312 | zt = pts (ji,jj,jk,jp_tem) * r1_T0 ! temperature |
---|
313 | zs = SQRT( ABS( pts(ji,jj,jk,jp_sal) + rdeltaS ) * r1_S0 ) ! square root salinity |
---|
314 | ztm = tmask(ji,jj,jk) ! tmask |
---|
315 | ! |
---|
316 | zn3 = EOS013*zt & |
---|
317 | & + EOS103*zs+EOS003 |
---|
318 | ! |
---|
319 | zn2 = (EOS022*zt & |
---|
320 | & + EOS112*zs+EOS012)*zt & |
---|
321 | & + (EOS202*zs+EOS102)*zs+EOS002 |
---|
322 | ! |
---|
323 | zn1 = (((EOS041*zt & |
---|
324 | & + EOS131*zs+EOS031)*zt & |
---|
325 | & + (EOS221*zs+EOS121)*zs+EOS021)*zt & |
---|
326 | & + ((EOS311*zs+EOS211)*zs+EOS111)*zs+EOS011)*zt & |
---|
327 | & + (((EOS401*zs+EOS301)*zs+EOS201)*zs+EOS101)*zs+EOS001 |
---|
328 | ! |
---|
329 | zn0 = (((((EOS060*zt & |
---|
330 | & + EOS150*zs+EOS050)*zt & |
---|
331 | & + (EOS240*zs+EOS140)*zs+EOS040)*zt & |
---|
332 | & + ((EOS330*zs+EOS230)*zs+EOS130)*zs+EOS030)*zt & |
---|
333 | & + (((EOS420*zs+EOS320)*zs+EOS220)*zs+EOS120)*zs+EOS020)*zt & |
---|
334 | & + ((((EOS510*zs+EOS410)*zs+EOS310)*zs+EOS210)*zs+EOS110)*zs+EOS010)*zt & |
---|
335 | & + (((((EOS600*zs+EOS500)*zs+EOS400)*zs+EOS300)*zs+EOS200)*zs+EOS100)*zs+EOS000 |
---|
336 | ! |
---|
337 | zn = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0 |
---|
338 | ! |
---|
339 | prhop(ji,jj,jk) = zn0 * ztm ! potential density referenced at the surface |
---|
340 | ! |
---|
341 | prd(ji,jj,jk) = ( zn * r1_rau0 - 1._wp ) * ztm ! density anomaly (masked) |
---|
342 | END DO |
---|
343 | END DO |
---|
344 | END DO |
---|
345 | |
---|
346 | CASE( np_seos ) !== simplified EOS ==! |
---|
347 | ! |
---|
348 | !$OMP PARALLEL DO PRIVATE(zt,zs,zh,ztm,zn) |
---|
349 | DO jk = 1, jpkm1 |
---|
350 | DO jj = 1, jpj |
---|
351 | DO ji = 1, jpi |
---|
352 | zt = pts (ji,jj,jk,jp_tem) - 10._wp |
---|
353 | zs = pts (ji,jj,jk,jp_sal) - 35._wp |
---|
354 | zh = pdep (ji,jj,jk) |
---|
355 | ztm = tmask(ji,jj,jk) |
---|
356 | ! ! potential density referenced at the surface |
---|
357 | zn = - rn_a0 * ( 1._wp + 0.5_wp*rn_lambda1*zt ) * zt & |
---|
358 | & + rn_b0 * ( 1._wp - 0.5_wp*rn_lambda2*zs ) * zs & |
---|
359 | & - rn_nu * zt * zs |
---|
360 | prhop(ji,jj,jk) = ( rau0 + zn ) * ztm |
---|
361 | ! ! density anomaly (masked) |
---|
362 | zn = zn - ( rn_a0 * rn_mu1 * zt + rn_b0 * rn_mu2 * zs ) * zh |
---|
363 | prd(ji,jj,jk) = zn * r1_rau0 * ztm |
---|
364 | ! |
---|
365 | END DO |
---|
366 | END DO |
---|
367 | END DO |
---|
368 | ! |
---|
369 | END SELECT |
---|
370 | !eos_time = eos_time + (TIMER() - et) ! Timer moved up the tree |
---|
371 | ! |
---|
372 | ! |
---|
373 | END SUBROUTINE eos_insitu_pot |
---|
374 | |
---|
375 | SUBROUTINE eos_insitu_2d( pts, pdep, prd ) |
---|
376 | !!---------------------------------------------------------------------- |
---|
377 | !! *** ROUTINE eos_insitu_2d *** |
---|
378 | !! |
---|
379 | !! ** Purpose : Compute the in situ density (ratio rho/rau0) from |
---|
380 | !! potential temperature and salinity using an equation of state |
---|
381 | !! selected in the nameos namelist. * 2D field case |
---|
382 | !! |
---|
383 | !! ** Action : - prd , the in situ density (no units) (unmasked) |
---|
384 | !! |
---|
385 | !!---------------------------------------------------------------------- |
---|
386 | REAL(wp), DIMENSION(jpi,jpj,jpts), INTENT(in ) :: pts ! 1 : potential temperature [Celsius] |
---|
387 | ! ! 2 : salinity [psu] |
---|
388 | REAL(wp), DIMENSION(jpi,jpj) , INTENT(in ) :: pdep ! depth [m] |
---|
389 | REAL(wp), DIMENSION(jpi,jpj) , INTENT( out) :: prd ! in situ density |
---|
390 | ! |
---|
391 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
392 | REAL(wp) :: zt , zh , zs ! local scalars |
---|
393 | REAL(wp) :: zn , zn0, zn1, zn2, zn3 ! - - |
---|
394 | REAL(wp) :: et |
---|
395 | !!---------------------------------------------------------------------- |
---|
396 | ! |
---|
397 | et = TIMER() |
---|
398 | !$OMP PARALLEL WORKSHARE |
---|
399 | prd(:,:) = 0._wp |
---|
400 | !$OMP END PARALLEL WORKSHARE |
---|
401 | ! |
---|
402 | SELECT CASE( neos ) |
---|
403 | ! |
---|
404 | CASE( np_teos10, np_eos80 ) !== polynomial TEOS-10 / EOS-80 ==! |
---|
405 | ! |
---|
406 | !$OMP PARALLEL DO PRIVATE(zh,zt,zs,zn0,zn1,zn2,zn3,zn) |
---|
407 | DO jj = 1, jpjm1 |
---|
408 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
409 | ! |
---|
410 | zh = pdep(ji,jj) * r1_Z0 ! depth |
---|
411 | zt = pts (ji,jj,jp_tem) * r1_T0 ! temperature |
---|
412 | zs = SQRT( ABS( pts(ji,jj,jp_sal) + rdeltaS ) * r1_S0 ) ! square root salinity |
---|
413 | ! |
---|
414 | zn3 = EOS013*zt & |
---|
415 | & + EOS103*zs+EOS003 |
---|
416 | ! |
---|
417 | zn2 = (EOS022*zt & |
---|
418 | & + EOS112*zs+EOS012)*zt & |
---|
419 | & + (EOS202*zs+EOS102)*zs+EOS002 |
---|
420 | ! |
---|
421 | zn1 = (((EOS041*zt & |
---|
422 | & + EOS131*zs+EOS031)*zt & |
---|
423 | & + (EOS221*zs+EOS121)*zs+EOS021)*zt & |
---|
424 | & + ((EOS311*zs+EOS211)*zs+EOS111)*zs+EOS011)*zt & |
---|
425 | & + (((EOS401*zs+EOS301)*zs+EOS201)*zs+EOS101)*zs+EOS001 |
---|
426 | ! |
---|
427 | zn0 = (((((EOS060*zt & |
---|
428 | & + EOS150*zs+EOS050)*zt & |
---|
429 | & + (EOS240*zs+EOS140)*zs+EOS040)*zt & |
---|
430 | & + ((EOS330*zs+EOS230)*zs+EOS130)*zs+EOS030)*zt & |
---|
431 | & + (((EOS420*zs+EOS320)*zs+EOS220)*zs+EOS120)*zs+EOS020)*zt & |
---|
432 | & + ((((EOS510*zs+EOS410)*zs+EOS310)*zs+EOS210)*zs+EOS110)*zs+EOS010)*zt & |
---|
433 | & + (((((EOS600*zs+EOS500)*zs+EOS400)*zs+EOS300)*zs+EOS200)*zs+EOS100)*zs+EOS000 |
---|
434 | ! |
---|
435 | zn = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0 |
---|
436 | ! |
---|
437 | prd(ji,jj) = zn * r1_rau0 - 1._wp ! unmasked in situ density anomaly |
---|
438 | ! |
---|
439 | END DO |
---|
440 | END DO |
---|
441 | ! ! |
---|
442 | CASE( np_seos ) !== simplified EOS ==! |
---|
443 | ! |
---|
444 | !$OMP PARALLEL DO PRIVATE(zt,zs,zh,zn) |
---|
445 | DO jj = 1, jpjm1 |
---|
446 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
447 | ! |
---|
448 | zt = pts (ji,jj,jp_tem) - 10._wp |
---|
449 | zs = pts (ji,jj,jp_sal) - 35._wp |
---|
450 | zh = pdep (ji,jj) ! depth at the partial step level |
---|
451 | ! |
---|
452 | zn = - rn_a0 * ( 1._wp + 0.5_wp*rn_lambda1*zt + rn_mu1*zh ) * zt & |
---|
453 | & + rn_b0 * ( 1._wp - 0.5_wp*rn_lambda2*zs - rn_mu2*zh ) * zs & |
---|
454 | & - rn_nu * zt * zs |
---|
455 | ! |
---|
456 | prd(ji,jj) = zn * r1_rau0 ! unmasked in situ density anomaly |
---|
457 | ! |
---|
458 | END DO |
---|
459 | END DO |
---|
460 | ! |
---|
461 | ! |
---|
462 | END SELECT |
---|
463 | !eos2d_time = eos2d_time + (TIMER() - et) ! Timer moved up call tree |
---|
464 | ! |
---|
465 | END SUBROUTINE eos_insitu_2d |
---|
466 | |
---|
467 | SUBROUTINE eos_rab_3d( pts, gdept_n, tmask, pab ) |
---|
468 | !!---------------------------------------------------------------------- |
---|
469 | !! *** ROUTINE rab_3d *** |
---|
470 | !! |
---|
471 | !! ** Purpose : Calculates thermal/haline expansion ratio at T-points |
---|
472 | !! |
---|
473 | !! ** Method : calculates alpha / beta at T-points |
---|
474 | !! |
---|
475 | !! ** Action : - pab : thermal/haline expansion ratio at T-points |
---|
476 | !!---------------------------------------------------------------------- |
---|
477 | REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in ) :: pts ! pot. temperature & salinity |
---|
478 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in ) :: gdept_n |
---|
479 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in ) :: tmask ! mask at T points |
---|
480 | REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT( out) :: pab ! thermal/haline expansion ratio |
---|
481 | ! |
---|
482 | |
---|
483 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
484 | REAL(wp) :: zt , zh , zs , ztm ! local scalars |
---|
485 | REAL(wp) :: zn , zn0, zn1, zn2, zn3 ! - - |
---|
486 | !!---------------------------------------------------------------------- |
---|
487 | ! ! |
---|
488 | SELECT CASE ( neos ) |
---|
489 | ! |
---|
490 | CASE( np_teos10, np_eos80 ) !== polynomial TEOS-10 / EOS-80 ==! |
---|
491 | ! |
---|
492 | DO jk = 1, jpkm1 |
---|
493 | DO jj = 1, jpj |
---|
494 | DO ji = 1, jpi |
---|
495 | ! |
---|
496 | zh = gdept_n(ji,jj,jk) * r1_Z0 ! depth |
---|
497 | zt = pts (ji,jj,jk,jp_tem) * r1_T0 ! temperature |
---|
498 | zs = SQRT( ABS( pts(ji,jj,jk,jp_sal) + rdeltaS ) * r1_S0 ) ! square root salinity |
---|
499 | ztm = tmask(ji,jj,jk) ! tmask |
---|
500 | ! |
---|
501 | ! alpha |
---|
502 | zn3 = ALP003 |
---|
503 | ! |
---|
504 | zn2 = ALP012*zt + ALP102*zs+ALP002 |
---|
505 | ! |
---|
506 | zn1 = ((ALP031*zt & |
---|
507 | & + ALP121*zs+ALP021)*zt & |
---|
508 | & + (ALP211*zs+ALP111)*zs+ALP011)*zt & |
---|
509 | & + ((ALP301*zs+ALP201)*zs+ALP101)*zs+ALP001 |
---|
510 | ! |
---|
511 | zn0 = ((((ALP050*zt & |
---|
512 | & + ALP140*zs+ALP040)*zt & |
---|
513 | & + (ALP230*zs+ALP130)*zs+ALP030)*zt & |
---|
514 | & + ((ALP320*zs+ALP220)*zs+ALP120)*zs+ALP020)*zt & |
---|
515 | & + (((ALP410*zs+ALP310)*zs+ALP210)*zs+ALP110)*zs+ALP010)*zt & |
---|
516 | & + ((((ALP500*zs+ALP400)*zs+ALP300)*zs+ALP200)*zs+ALP100)*zs+ALP000 |
---|
517 | ! |
---|
518 | zn = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0 |
---|
519 | ! |
---|
520 | pab(ji,jj,jk,jp_tem) = zn * r1_rau0 * ztm |
---|
521 | ! |
---|
522 | ! beta |
---|
523 | zn3 = BET003 |
---|
524 | ! |
---|
525 | zn2 = BET012*zt + BET102*zs+BET002 |
---|
526 | ! |
---|
527 | zn1 = ((BET031*zt & |
---|
528 | & + BET121*zs+BET021)*zt & |
---|
529 | & + (BET211*zs+BET111)*zs+BET011)*zt & |
---|
530 | & + ((BET301*zs+BET201)*zs+BET101)*zs+BET001 |
---|
531 | ! |
---|
532 | zn0 = ((((BET050*zt & |
---|
533 | & + BET140*zs+BET040)*zt & |
---|
534 | & + (BET230*zs+BET130)*zs+BET030)*zt & |
---|
535 | & + ((BET320*zs+BET220)*zs+BET120)*zs+BET020)*zt & |
---|
536 | & + (((BET410*zs+BET310)*zs+BET210)*zs+BET110)*zs+BET010)*zt & |
---|
537 | & + ((((BET500*zs+BET400)*zs+BET300)*zs+BET200)*zs+BET100)*zs+BET000 |
---|
538 | ! |
---|
539 | zn = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0 |
---|
540 | ! |
---|
541 | pab(ji,jj,jk,jp_sal) = zn / zs * r1_rau0 * ztm |
---|
542 | ! |
---|
543 | END DO |
---|
544 | END DO |
---|
545 | END DO |
---|
546 | ! |
---|
547 | CASE( np_seos ) !== simplified EOS ==! |
---|
548 | ! |
---|
549 | DO jk = 1, jpkm1 |
---|
550 | DO jj = 1, jpj |
---|
551 | DO ji = 1, jpi |
---|
552 | zt = pts (ji,jj,jk,jp_tem) - 10._wp ! pot. temperature anomaly (t-T0) |
---|
553 | zs = pts (ji,jj,jk,jp_sal) - 35._wp ! abs. salinity anomaly (s-S0) |
---|
554 | zh = gdept_n(ji,jj,jk) ! depth in meters at t-point |
---|
555 | ztm = tmask(ji,jj,jk) ! land/sea bottom mask = surf. mask |
---|
556 | ! |
---|
557 | zn = rn_a0 * ( 1._wp + rn_lambda1*zt + rn_mu1*zh ) + rn_nu*zs |
---|
558 | pab(ji,jj,jk,jp_tem) = zn * r1_rau0 * ztm ! alpha |
---|
559 | ! |
---|
560 | zn = rn_b0 * ( 1._wp - rn_lambda2*zs - rn_mu2*zh ) - rn_nu*zt |
---|
561 | pab(ji,jj,jk,jp_sal) = zn * r1_rau0 * ztm ! beta |
---|
562 | ! |
---|
563 | END DO |
---|
564 | END DO |
---|
565 | END DO |
---|
566 | ! |
---|
567 | CASE DEFAULT |
---|
568 | IF(lwp) WRITE(numout,cform_err) |
---|
569 | IF(lwp) WRITE(numout,*) ' bad flag value for neos = ', neos |
---|
570 | ! |
---|
571 | END SELECT |
---|
572 | ! |
---|
573 | ! |
---|
574 | END SUBROUTINE eos_rab_3d |
---|
575 | |
---|
576 | SUBROUTINE bn2( pts, pab, gdepw_n, gdept_n, e3w_n, wmask, pn2 ) |
---|
577 | !!---------------------------------------------------------------------- |
---|
578 | !! *** ROUTINE bn2 *** |
---|
579 | !! |
---|
580 | !! ** Purpose : Compute the local Brunt-Vaisala frequency at the |
---|
581 | !! time-step of the input arguments |
---|
582 | !! |
---|
583 | !! ** Method : pn2 = grav * (alpha dk[T] + beta dk[S] ) / e3w |
---|
584 | !! where alpha and beta are given in pab, and computed on T-points. |
---|
585 | !! N.B. N^2 is set one for all to zero at jk=1 in istate module. |
---|
586 | !! |
---|
587 | !! ** Action : pn2 : square of the brunt-vaisala frequency at w-point |
---|
588 | !! |
---|
589 | !!---------------------------------------------------------------------- |
---|
590 | REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in ) :: pts ! pot. temperature and salinity [Celsius,psu] |
---|
591 | REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in ) :: pab ! thermal/haline expansion coef. [Celsius-1,psu-1] |
---|
592 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in ) :: gdepw_n, gdept_n, e3w_n, wmask |
---|
593 | REAL(wp), DIMENSION(jpi,jpj,jpk ), INTENT( out) :: pn2 ! Brunt-Vaisala frequency squared [1/s^2] |
---|
594 | ! |
---|
595 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
596 | REAL(wp) :: zaw, zbw, zrw ! local scalars |
---|
597 | !!---------------------------------------------------------------------- |
---|
598 | ! |
---|
599 | DO jk = 2, jpkm1 ! interior points only (2=< jk =< jpkm1 ) |
---|
600 | DO jj = 1, jpj ! surface and bottom value set to zero one for all in istate.F90 |
---|
601 | DO ji = 1, jpi |
---|
602 | zrw = ( gdepw_n(ji,jj,jk ) - gdept_n(ji,jj,jk) ) & |
---|
603 | & / ( gdept_n(ji,jj,jk-1) - gdept_n(ji,jj,jk) ) |
---|
604 | ! |
---|
605 | zaw = pab(ji,jj,jk,jp_tem) * (1. - zrw) + pab(ji,jj,jk-1,jp_tem) * zrw |
---|
606 | zbw = pab(ji,jj,jk,jp_sal) * (1. - zrw) + pab(ji,jj,jk-1,jp_sal) * zrw |
---|
607 | ! |
---|
608 | pn2(ji,jj,jk) = grav * ( zaw * ( pts(ji,jj,jk-1,jp_tem) - pts(ji,jj,jk,jp_tem) ) & |
---|
609 | & - zbw * ( pts(ji,jj,jk-1,jp_sal) - pts(ji,jj,jk,jp_sal) ) ) & |
---|
610 | & / e3w_n(ji,jj,jk) * wmask(ji,jj,jk) |
---|
611 | END DO |
---|
612 | END DO |
---|
613 | END DO |
---|
614 | ! |
---|
615 | ! |
---|
616 | END SUBROUTINE bn2 |
---|
617 | |
---|
618 | SUBROUTINE eos_init |
---|
619 | !!---------------------------------------------------------------------- |
---|
620 | !! *** ROUTINE eos_init *** |
---|
621 | !! |
---|
622 | !! ** Purpose : initializations for the equation of state |
---|
623 | !! |
---|
624 | !! ** Method : Read the namelist nameos and control the parameters |
---|
625 | !!---------------------------------------------------------------------- |
---|
626 | INTEGER :: ios ! local integer |
---|
627 | INTEGER :: ioptio ! local integer |
---|
628 | !! |
---|
629 | NAMELIST/nameos/ ln_TEOS10, ln_EOS80, ln_SEOS, rn_a0, rn_b0, rn_lambda1, rn_mu1, & |
---|
630 | & rn_lambda2, rn_mu2, rn_nu |
---|
631 | !!---------------------------------------------------------------------- |
---|
632 | ! |
---|
633 | OPEN( UNIT=numnam_cfg, FILE='nam_eos', FORM='FORMATTED', STATUS='OLD' ) |
---|
634 | READ( numnam_cfg, nameos ) |
---|
635 | CLOSE( numnam_cfg ) |
---|
636 | |
---|
637 | IF(lwm) WRITE( numond, nameos ) |
---|
638 | ! |
---|
639 | rau0 = 1026._wp !: volumic mass of reference [kg/m3] |
---|
640 | rcp = 3991.86795711963_wp !: heat capacity [J/K] |
---|
641 | ! |
---|
642 | IF(lwp) THEN ! Control print |
---|
643 | WRITE(numout,*) |
---|
644 | WRITE(numout,*) 'eos_init : equation of state' |
---|
645 | WRITE(numout,*) '~~~~~~~~' |
---|
646 | WRITE(numout,*) ' Namelist nameos : Chosen the Equation Of Seawater (EOS)' |
---|
647 | WRITE(numout,*) ' TEOS-10 : rho=F(Conservative Temperature, Absolute Salinity, depth) ln_TEOS10 = ', ln_TEOS10 |
---|
648 | WRITE(numout,*) ' EOS-80 : rho=F(Potential Temperature, Practical Salinity, depth) ln_EOS80 = ', ln_EOS80 |
---|
649 | WRITE(numout,*) ' S-EOS : rho=F(Conservative Temperature, Absolute Salinity, depth) ln_SEOS = ', ln_SEOS |
---|
650 | ENDIF |
---|
651 | |
---|
652 | ! Check options for equation of state & set neos based on logical flags |
---|
653 | ioptio = 0 |
---|
654 | IF( ln_TEOS10 ) THEN ; ioptio = ioptio+1 ; neos = np_teos10 ; ENDIF |
---|
655 | IF( ln_EOS80 ) THEN ; ioptio = ioptio+1 ; neos = np_eos80 ; ENDIF |
---|
656 | IF( ln_SEOS ) THEN ; ioptio = ioptio+1 ; neos = np_seos ; ENDIF |
---|
657 | IF( ioptio /= 1 ) THEN |
---|
658 | WRITE(numout,*) "Exactly one equation of state option must be selected" |
---|
659 | STOP |
---|
660 | END IF |
---|
661 | ! |
---|
662 | SELECT CASE( neos ) ! check option |
---|
663 | ! |
---|
664 | CASE( np_teos10 ) !== polynomial TEOS-10 ==! |
---|
665 | IF(lwp) WRITE(numout,*) |
---|
666 | IF(lwp) WRITE(numout,*) ' ==>>> use of TEOS-10 equation of state (cons. temp. and abs. salinity)' |
---|
667 | ! |
---|
668 | l_useCT = .TRUE. ! model temperature is Conservative temperature |
---|
669 | ! |
---|
670 | rdeltaS = 32._wp |
---|
671 | r1_S0 = 0.875_wp/35.16504_wp |
---|
672 | r1_T0 = 1._wp/40._wp |
---|
673 | r1_Z0 = 1.e-4_wp |
---|
674 | ! |
---|
675 | EOS000 = 8.0189615746e+02_wp |
---|
676 | EOS100 = 8.6672408165e+02_wp |
---|
677 | EOS200 = -1.7864682637e+03_wp |
---|
678 | EOS300 = 2.0375295546e+03_wp |
---|
679 | EOS400 = -1.2849161071e+03_wp |
---|
680 | EOS500 = 4.3227585684e+02_wp |
---|
681 | EOS600 = -6.0579916612e+01_wp |
---|
682 | EOS010 = 2.6010145068e+01_wp |
---|
683 | EOS110 = -6.5281885265e+01_wp |
---|
684 | EOS210 = 8.1770425108e+01_wp |
---|
685 | EOS310 = -5.6888046321e+01_wp |
---|
686 | EOS410 = 1.7681814114e+01_wp |
---|
687 | EOS510 = -1.9193502195_wp |
---|
688 | EOS020 = -3.7074170417e+01_wp |
---|
689 | EOS120 = 6.1548258127e+01_wp |
---|
690 | EOS220 = -6.0362551501e+01_wp |
---|
691 | EOS320 = 2.9130021253e+01_wp |
---|
692 | EOS420 = -5.4723692739_wp |
---|
693 | EOS030 = 2.1661789529e+01_wp |
---|
694 | EOS130 = -3.3449108469e+01_wp |
---|
695 | EOS230 = 1.9717078466e+01_wp |
---|
696 | EOS330 = -3.1742946532_wp |
---|
697 | EOS040 = -8.3627885467_wp |
---|
698 | EOS140 = 1.1311538584e+01_wp |
---|
699 | EOS240 = -5.3563304045_wp |
---|
700 | EOS050 = 5.4048723791e-01_wp |
---|
701 | EOS150 = 4.8169980163e-01_wp |
---|
702 | EOS060 = -1.9083568888e-01_wp |
---|
703 | EOS001 = 1.9681925209e+01_wp |
---|
704 | EOS101 = -4.2549998214e+01_wp |
---|
705 | EOS201 = 5.0774768218e+01_wp |
---|
706 | EOS301 = -3.0938076334e+01_wp |
---|
707 | EOS401 = 6.6051753097_wp |
---|
708 | EOS011 = -1.3336301113e+01_wp |
---|
709 | EOS111 = -4.4870114575_wp |
---|
710 | EOS211 = 5.0042598061_wp |
---|
711 | EOS311 = -6.5399043664e-01_wp |
---|
712 | EOS021 = 6.7080479603_wp |
---|
713 | EOS121 = 3.5063081279_wp |
---|
714 | EOS221 = -1.8795372996_wp |
---|
715 | EOS031 = -2.4649669534_wp |
---|
716 | EOS131 = -5.5077101279e-01_wp |
---|
717 | EOS041 = 5.5927935970e-01_wp |
---|
718 | EOS002 = 2.0660924175_wp |
---|
719 | EOS102 = -4.9527603989_wp |
---|
720 | EOS202 = 2.5019633244_wp |
---|
721 | EOS012 = 2.0564311499_wp |
---|
722 | EOS112 = -2.1311365518e-01_wp |
---|
723 | EOS022 = -1.2419983026_wp |
---|
724 | EOS003 = -2.3342758797e-02_wp |
---|
725 | EOS103 = -1.8507636718e-02_wp |
---|
726 | EOS013 = 3.7969820455e-01_wp |
---|
727 | ! |
---|
728 | ALP000 = -6.5025362670e-01_wp |
---|
729 | ALP100 = 1.6320471316_wp |
---|
730 | ALP200 = -2.0442606277_wp |
---|
731 | ALP300 = 1.4222011580_wp |
---|
732 | ALP400 = -4.4204535284e-01_wp |
---|
733 | ALP500 = 4.7983755487e-02_wp |
---|
734 | ALP010 = 1.8537085209_wp |
---|
735 | ALP110 = -3.0774129064_wp |
---|
736 | ALP210 = 3.0181275751_wp |
---|
737 | ALP310 = -1.4565010626_wp |
---|
738 | ALP410 = 2.7361846370e-01_wp |
---|
739 | ALP020 = -1.6246342147_wp |
---|
740 | ALP120 = 2.5086831352_wp |
---|
741 | ALP220 = -1.4787808849_wp |
---|
742 | ALP320 = 2.3807209899e-01_wp |
---|
743 | ALP030 = 8.3627885467e-01_wp |
---|
744 | ALP130 = -1.1311538584_wp |
---|
745 | ALP230 = 5.3563304045e-01_wp |
---|
746 | ALP040 = -6.7560904739e-02_wp |
---|
747 | ALP140 = -6.0212475204e-02_wp |
---|
748 | ALP050 = 2.8625353333e-02_wp |
---|
749 | ALP001 = 3.3340752782e-01_wp |
---|
750 | ALP101 = 1.1217528644e-01_wp |
---|
751 | ALP201 = -1.2510649515e-01_wp |
---|
752 | ALP301 = 1.6349760916e-02_wp |
---|
753 | ALP011 = -3.3540239802e-01_wp |
---|
754 | ALP111 = -1.7531540640e-01_wp |
---|
755 | ALP211 = 9.3976864981e-02_wp |
---|
756 | ALP021 = 1.8487252150e-01_wp |
---|
757 | ALP121 = 4.1307825959e-02_wp |
---|
758 | ALP031 = -5.5927935970e-02_wp |
---|
759 | ALP002 = -5.1410778748e-02_wp |
---|
760 | ALP102 = 5.3278413794e-03_wp |
---|
761 | ALP012 = 6.2099915132e-02_wp |
---|
762 | ALP003 = -9.4924551138e-03_wp |
---|
763 | ! |
---|
764 | BET000 = 1.0783203594e+01_wp |
---|
765 | BET100 = -4.4452095908e+01_wp |
---|
766 | BET200 = 7.6048755820e+01_wp |
---|
767 | BET300 = -6.3944280668e+01_wp |
---|
768 | BET400 = 2.6890441098e+01_wp |
---|
769 | BET500 = -4.5221697773_wp |
---|
770 | BET010 = -8.1219372432e-01_wp |
---|
771 | BET110 = 2.0346663041_wp |
---|
772 | BET210 = -2.1232895170_wp |
---|
773 | BET310 = 8.7994140485e-01_wp |
---|
774 | BET410 = -1.1939638360e-01_wp |
---|
775 | BET020 = 7.6574242289e-01_wp |
---|
776 | BET120 = -1.5019813020_wp |
---|
777 | BET220 = 1.0872489522_wp |
---|
778 | BET320 = -2.7233429080e-01_wp |
---|
779 | BET030 = -4.1615152308e-01_wp |
---|
780 | BET130 = 4.9061350869e-01_wp |
---|
781 | BET230 = -1.1847737788e-01_wp |
---|
782 | BET040 = 1.4073062708e-01_wp |
---|
783 | BET140 = -1.3327978879e-01_wp |
---|
784 | BET050 = 5.9929880134e-03_wp |
---|
785 | BET001 = -5.2937873009e-01_wp |
---|
786 | BET101 = 1.2634116779_wp |
---|
787 | BET201 = -1.1547328025_wp |
---|
788 | BET301 = 3.2870876279e-01_wp |
---|
789 | BET011 = -5.5824407214e-02_wp |
---|
790 | BET111 = 1.2451933313e-01_wp |
---|
791 | BET211 = -2.4409539932e-02_wp |
---|
792 | BET021 = 4.3623149752e-02_wp |
---|
793 | BET121 = -4.6767901790e-02_wp |
---|
794 | BET031 = -6.8523260060e-03_wp |
---|
795 | BET002 = -6.1618945251e-02_wp |
---|
796 | BET102 = 6.2255521644e-02_wp |
---|
797 | BET012 = -2.6514181169e-03_wp |
---|
798 | BET003 = -2.3025968587e-04_wp |
---|
799 | ! |
---|
800 | PEN000 = -9.8409626043_wp |
---|
801 | PEN100 = 2.1274999107e+01_wp |
---|
802 | PEN200 = -2.5387384109e+01_wp |
---|
803 | PEN300 = 1.5469038167e+01_wp |
---|
804 | PEN400 = -3.3025876549_wp |
---|
805 | PEN010 = 6.6681505563_wp |
---|
806 | PEN110 = 2.2435057288_wp |
---|
807 | PEN210 = -2.5021299030_wp |
---|
808 | PEN310 = 3.2699521832e-01_wp |
---|
809 | PEN020 = -3.3540239802_wp |
---|
810 | PEN120 = -1.7531540640_wp |
---|
811 | PEN220 = 9.3976864981e-01_wp |
---|
812 | PEN030 = 1.2324834767_wp |
---|
813 | PEN130 = 2.7538550639e-01_wp |
---|
814 | PEN040 = -2.7963967985e-01_wp |
---|
815 | PEN001 = -1.3773949450_wp |
---|
816 | PEN101 = 3.3018402659_wp |
---|
817 | PEN201 = -1.6679755496_wp |
---|
818 | PEN011 = -1.3709540999_wp |
---|
819 | PEN111 = 1.4207577012e-01_wp |
---|
820 | PEN021 = 8.2799886843e-01_wp |
---|
821 | PEN002 = 1.7507069098e-02_wp |
---|
822 | PEN102 = 1.3880727538e-02_wp |
---|
823 | PEN012 = -2.8477365341e-01_wp |
---|
824 | ! |
---|
825 | APE000 = -1.6670376391e-01_wp |
---|
826 | APE100 = -5.6087643219e-02_wp |
---|
827 | APE200 = 6.2553247576e-02_wp |
---|
828 | APE300 = -8.1748804580e-03_wp |
---|
829 | APE010 = 1.6770119901e-01_wp |
---|
830 | APE110 = 8.7657703198e-02_wp |
---|
831 | APE210 = -4.6988432490e-02_wp |
---|
832 | APE020 = -9.2436260751e-02_wp |
---|
833 | APE120 = -2.0653912979e-02_wp |
---|
834 | APE030 = 2.7963967985e-02_wp |
---|
835 | APE001 = 3.4273852498e-02_wp |
---|
836 | APE101 = -3.5518942529e-03_wp |
---|
837 | APE011 = -4.1399943421e-02_wp |
---|
838 | APE002 = 7.1193413354e-03_wp |
---|
839 | ! |
---|
840 | BPE000 = 2.6468936504e-01_wp |
---|
841 | BPE100 = -6.3170583896e-01_wp |
---|
842 | BPE200 = 5.7736640125e-01_wp |
---|
843 | BPE300 = -1.6435438140e-01_wp |
---|
844 | BPE010 = 2.7912203607e-02_wp |
---|
845 | BPE110 = -6.2259666565e-02_wp |
---|
846 | BPE210 = 1.2204769966e-02_wp |
---|
847 | BPE020 = -2.1811574876e-02_wp |
---|
848 | BPE120 = 2.3383950895e-02_wp |
---|
849 | BPE030 = 3.4261630030e-03_wp |
---|
850 | BPE001 = 4.1079296834e-02_wp |
---|
851 | BPE101 = -4.1503681096e-02_wp |
---|
852 | BPE011 = 1.7676120780e-03_wp |
---|
853 | BPE002 = 1.7269476440e-04_wp |
---|
854 | ! |
---|
855 | CASE( np_eos80 ) !== polynomial EOS-80 formulation ==! |
---|
856 | ! |
---|
857 | IF(lwp) WRITE(numout,*) |
---|
858 | IF(lwp) WRITE(numout,*) ' ==>>> use of EOS-80 equation of state (pot. temp. and pract. salinity)' |
---|
859 | ! |
---|
860 | l_useCT = .FALSE. ! model temperature is Potential temperature |
---|
861 | rdeltaS = 20._wp |
---|
862 | r1_S0 = 1._wp/40._wp |
---|
863 | r1_T0 = 1._wp/40._wp |
---|
864 | r1_Z0 = 1.e-4_wp |
---|
865 | ! |
---|
866 | EOS000 = 9.5356891948e+02_wp |
---|
867 | EOS100 = 1.7136499189e+02_wp |
---|
868 | EOS200 = -3.7501039454e+02_wp |
---|
869 | EOS300 = 5.1856810420e+02_wp |
---|
870 | EOS400 = -3.7264470465e+02_wp |
---|
871 | EOS500 = 1.4302533998e+02_wp |
---|
872 | EOS600 = -2.2856621162e+01_wp |
---|
873 | EOS010 = 1.0087518651e+01_wp |
---|
874 | EOS110 = -1.3647741861e+01_wp |
---|
875 | EOS210 = 8.8478359933_wp |
---|
876 | EOS310 = -7.2329388377_wp |
---|
877 | EOS410 = 1.4774410611_wp |
---|
878 | EOS510 = 2.0036720553e-01_wp |
---|
879 | EOS020 = -2.5579830599e+01_wp |
---|
880 | EOS120 = 2.4043512327e+01_wp |
---|
881 | EOS220 = -1.6807503990e+01_wp |
---|
882 | EOS320 = 8.3811577084_wp |
---|
883 | EOS420 = -1.9771060192_wp |
---|
884 | EOS030 = 1.6846451198e+01_wp |
---|
885 | EOS130 = -2.1482926901e+01_wp |
---|
886 | EOS230 = 1.0108954054e+01_wp |
---|
887 | EOS330 = -6.2675951440e-01_wp |
---|
888 | EOS040 = -8.0812310102_wp |
---|
889 | EOS140 = 1.0102374985e+01_wp |
---|
890 | EOS240 = -4.8340368631_wp |
---|
891 | EOS050 = 1.2079167803_wp |
---|
892 | EOS150 = 1.1515380987e-01_wp |
---|
893 | EOS060 = -2.4520288837e-01_wp |
---|
894 | EOS001 = 1.0748601068e+01_wp |
---|
895 | EOS101 = -1.7817043500e+01_wp |
---|
896 | EOS201 = 2.2181366768e+01_wp |
---|
897 | EOS301 = -1.6750916338e+01_wp |
---|
898 | EOS401 = 4.1202230403_wp |
---|
899 | EOS011 = -1.5852644587e+01_wp |
---|
900 | EOS111 = -7.6639383522e-01_wp |
---|
901 | EOS211 = 4.1144627302_wp |
---|
902 | EOS311 = -6.6955877448e-01_wp |
---|
903 | EOS021 = 9.9994861860_wp |
---|
904 | EOS121 = -1.9467067787e-01_wp |
---|
905 | EOS221 = -1.2177554330_wp |
---|
906 | EOS031 = -3.4866102017_wp |
---|
907 | EOS131 = 2.2229155620e-01_wp |
---|
908 | EOS041 = 5.9503008642e-01_wp |
---|
909 | EOS002 = 1.0375676547_wp |
---|
910 | EOS102 = -3.4249470629_wp |
---|
911 | EOS202 = 2.0542026429_wp |
---|
912 | EOS012 = 2.1836324814_wp |
---|
913 | EOS112 = -3.4453674320e-01_wp |
---|
914 | EOS022 = -1.2548163097_wp |
---|
915 | EOS003 = 1.8729078427e-02_wp |
---|
916 | EOS103 = -5.7238495240e-02_wp |
---|
917 | EOS013 = 3.8306136687e-01_wp |
---|
918 | ! |
---|
919 | ALP000 = -2.5218796628e-01_wp |
---|
920 | ALP100 = 3.4119354654e-01_wp |
---|
921 | ALP200 = -2.2119589983e-01_wp |
---|
922 | ALP300 = 1.8082347094e-01_wp |
---|
923 | ALP400 = -3.6936026529e-02_wp |
---|
924 | ALP500 = -5.0091801383e-03_wp |
---|
925 | ALP010 = 1.2789915300_wp |
---|
926 | ALP110 = -1.2021756164_wp |
---|
927 | ALP210 = 8.4037519952e-01_wp |
---|
928 | ALP310 = -4.1905788542e-01_wp |
---|
929 | ALP410 = 9.8855300959e-02_wp |
---|
930 | ALP020 = -1.2634838399_wp |
---|
931 | ALP120 = 1.6112195176_wp |
---|
932 | ALP220 = -7.5817155402e-01_wp |
---|
933 | ALP320 = 4.7006963580e-02_wp |
---|
934 | ALP030 = 8.0812310102e-01_wp |
---|
935 | ALP130 = -1.0102374985_wp |
---|
936 | ALP230 = 4.8340368631e-01_wp |
---|
937 | ALP040 = -1.5098959754e-01_wp |
---|
938 | ALP140 = -1.4394226233e-02_wp |
---|
939 | ALP050 = 3.6780433255e-02_wp |
---|
940 | ALP001 = 3.9631611467e-01_wp |
---|
941 | ALP101 = 1.9159845880e-02_wp |
---|
942 | ALP201 = -1.0286156825e-01_wp |
---|
943 | ALP301 = 1.6738969362e-02_wp |
---|
944 | ALP011 = -4.9997430930e-01_wp |
---|
945 | ALP111 = 9.7335338937e-03_wp |
---|
946 | ALP211 = 6.0887771651e-02_wp |
---|
947 | ALP021 = 2.6149576513e-01_wp |
---|
948 | ALP121 = -1.6671866715e-02_wp |
---|
949 | ALP031 = -5.9503008642e-02_wp |
---|
950 | ALP002 = -5.4590812035e-02_wp |
---|
951 | ALP102 = 8.6134185799e-03_wp |
---|
952 | ALP012 = 6.2740815484e-02_wp |
---|
953 | ALP003 = -9.5765341718e-03_wp |
---|
954 | ! |
---|
955 | BET000 = 2.1420623987_wp |
---|
956 | BET100 = -9.3752598635_wp |
---|
957 | BET200 = 1.9446303907e+01_wp |
---|
958 | BET300 = -1.8632235232e+01_wp |
---|
959 | BET400 = 8.9390837485_wp |
---|
960 | BET500 = -1.7142465871_wp |
---|
961 | BET010 = -1.7059677327e-01_wp |
---|
962 | BET110 = 2.2119589983e-01_wp |
---|
963 | BET210 = -2.7123520642e-01_wp |
---|
964 | BET310 = 7.3872053057e-02_wp |
---|
965 | BET410 = 1.2522950346e-02_wp |
---|
966 | BET020 = 3.0054390409e-01_wp |
---|
967 | BET120 = -4.2018759976e-01_wp |
---|
968 | BET220 = 3.1429341406e-01_wp |
---|
969 | BET320 = -9.8855300959e-02_wp |
---|
970 | BET030 = -2.6853658626e-01_wp |
---|
971 | BET130 = 2.5272385134e-01_wp |
---|
972 | BET230 = -2.3503481790e-02_wp |
---|
973 | BET040 = 1.2627968731e-01_wp |
---|
974 | BET140 = -1.2085092158e-01_wp |
---|
975 | BET050 = 1.4394226233e-03_wp |
---|
976 | BET001 = -2.2271304375e-01_wp |
---|
977 | BET101 = 5.5453416919e-01_wp |
---|
978 | BET201 = -6.2815936268e-01_wp |
---|
979 | BET301 = 2.0601115202e-01_wp |
---|
980 | BET011 = -9.5799229402e-03_wp |
---|
981 | BET111 = 1.0286156825e-01_wp |
---|
982 | BET211 = -2.5108454043e-02_wp |
---|
983 | BET021 = -2.4333834734e-03_wp |
---|
984 | BET121 = -3.0443885826e-02_wp |
---|
985 | BET031 = 2.7786444526e-03_wp |
---|
986 | BET002 = -4.2811838287e-02_wp |
---|
987 | BET102 = 5.1355066072e-02_wp |
---|
988 | BET012 = -4.3067092900e-03_wp |
---|
989 | BET003 = -7.1548119050e-04_wp |
---|
990 | ! |
---|
991 | PEN000 = -5.3743005340_wp |
---|
992 | PEN100 = 8.9085217499_wp |
---|
993 | PEN200 = -1.1090683384e+01_wp |
---|
994 | PEN300 = 8.3754581690_wp |
---|
995 | PEN400 = -2.0601115202_wp |
---|
996 | PEN010 = 7.9263222935_wp |
---|
997 | PEN110 = 3.8319691761e-01_wp |
---|
998 | PEN210 = -2.0572313651_wp |
---|
999 | PEN310 = 3.3477938724e-01_wp |
---|
1000 | PEN020 = -4.9997430930_wp |
---|
1001 | PEN120 = 9.7335338937e-02_wp |
---|
1002 | PEN220 = 6.0887771651e-01_wp |
---|
1003 | PEN030 = 1.7433051009_wp |
---|
1004 | PEN130 = -1.1114577810e-01_wp |
---|
1005 | PEN040 = -2.9751504321e-01_wp |
---|
1006 | PEN001 = -6.9171176978e-01_wp |
---|
1007 | PEN101 = 2.2832980419_wp |
---|
1008 | PEN201 = -1.3694684286_wp |
---|
1009 | PEN011 = -1.4557549876_wp |
---|
1010 | PEN111 = 2.2969116213e-01_wp |
---|
1011 | PEN021 = 8.3654420645e-01_wp |
---|
1012 | PEN002 = -1.4046808820e-02_wp |
---|
1013 | PEN102 = 4.2928871430e-02_wp |
---|
1014 | PEN012 = -2.8729602515e-01_wp |
---|
1015 | ! |
---|
1016 | APE000 = -1.9815805734e-01_wp |
---|
1017 | APE100 = -9.5799229402e-03_wp |
---|
1018 | APE200 = 5.1430784127e-02_wp |
---|
1019 | APE300 = -8.3694846809e-03_wp |
---|
1020 | APE010 = 2.4998715465e-01_wp |
---|
1021 | APE110 = -4.8667669469e-03_wp |
---|
1022 | APE210 = -3.0443885826e-02_wp |
---|
1023 | APE020 = -1.3074788257e-01_wp |
---|
1024 | APE120 = 8.3359333577e-03_wp |
---|
1025 | APE030 = 2.9751504321e-02_wp |
---|
1026 | APE001 = 3.6393874690e-02_wp |
---|
1027 | APE101 = -5.7422790533e-03_wp |
---|
1028 | APE011 = -4.1827210323e-02_wp |
---|
1029 | APE002 = 7.1824006288e-03_wp |
---|
1030 | ! |
---|
1031 | BPE000 = 1.1135652187e-01_wp |
---|
1032 | BPE100 = -2.7726708459e-01_wp |
---|
1033 | BPE200 = 3.1407968134e-01_wp |
---|
1034 | BPE300 = -1.0300557601e-01_wp |
---|
1035 | BPE010 = 4.7899614701e-03_wp |
---|
1036 | BPE110 = -5.1430784127e-02_wp |
---|
1037 | BPE210 = 1.2554227021e-02_wp |
---|
1038 | BPE020 = 1.2166917367e-03_wp |
---|
1039 | BPE120 = 1.5221942913e-02_wp |
---|
1040 | BPE030 = -1.3893222263e-03_wp |
---|
1041 | BPE001 = 2.8541225524e-02_wp |
---|
1042 | BPE101 = -3.4236710714e-02_wp |
---|
1043 | BPE011 = 2.8711395266e-03_wp |
---|
1044 | BPE002 = 5.3661089288e-04_wp |
---|
1045 | ! |
---|
1046 | CASE( np_seos ) !== Simplified EOS ==! |
---|
1047 | IF(lwp) THEN |
---|
1048 | WRITE(numout,*) |
---|
1049 | WRITE(numout,*) ' ==>>> use of simplified eos: ' |
---|
1050 | WRITE(numout,*) ' rhd(dT=T-10,dS=S-35,Z) = [-a0*(1+lambda1/2*dT+mu1*Z)*dT ' |
---|
1051 | WRITE(numout,*) ' + b0*(1+lambda2/2*dT+mu2*Z)*dS - nu*dT*dS] / rau0' |
---|
1052 | WRITE(numout,*) ' with the following coefficients :' |
---|
1053 | WRITE(numout,*) ' thermal exp. coef. rn_a0 = ', rn_a0 |
---|
1054 | WRITE(numout,*) ' saline cont. coef. rn_b0 = ', rn_b0 |
---|
1055 | WRITE(numout,*) ' cabbeling coef. rn_lambda1 = ', rn_lambda1 |
---|
1056 | WRITE(numout,*) ' cabbeling coef. rn_lambda2 = ', rn_lambda2 |
---|
1057 | WRITE(numout,*) ' thermobar. coef. rn_mu1 = ', rn_mu1 |
---|
1058 | WRITE(numout,*) ' thermobar. coef. rn_mu2 = ', rn_mu2 |
---|
1059 | WRITE(numout,*) ' 2nd cabbel. coef. rn_nu = ', rn_nu |
---|
1060 | WRITE(numout,*) ' Caution: rn_beta0=0 incompatible with ddm parameterization ' |
---|
1061 | ENDIF |
---|
1062 | l_useCT = .TRUE. ! Use conservative temperature |
---|
1063 | ! |
---|
1064 | CASE DEFAULT !== ERROR in neos ==! |
---|
1065 | WRITE(ctmp1,*) ' bad flag value for neos = ', neos, '. You should never see this error' |
---|
1066 | STOP |
---|
1067 | ! |
---|
1068 | END SELECT |
---|
1069 | ! |
---|
1070 | rau0_rcp = rau0 * rcp |
---|
1071 | r1_rau0 = 1._wp / rau0 |
---|
1072 | r1_rcp = 1._wp / rcp |
---|
1073 | r1_rau0_rcp = 1._wp / rau0_rcp |
---|
1074 | ! |
---|
1075 | IF(lwp) THEN |
---|
1076 | IF( l_useCT ) THEN |
---|
1077 | WRITE(numout,*) |
---|
1078 | WRITE(numout,*) ' ==>>> model uses Conservative Temperature' |
---|
1079 | WRITE(numout,*) ' Important: model must be initialized with CT and SA fields' |
---|
1080 | ELSE |
---|
1081 | WRITE(numout,*) |
---|
1082 | WRITE(numout,*) ' ==>>> model does not use Conservative Temperature' |
---|
1083 | ENDIF |
---|
1084 | ENDIF |
---|
1085 | ! |
---|
1086 | IF(lwp) WRITE(numout,*) |
---|
1087 | IF(lwp) WRITE(numout,*) ' Associated physical constant' |
---|
1088 | IF(lwp) WRITE(numout,*) ' volumic mass of reference rau0 = ', rau0 , ' kg/m^3' |
---|
1089 | IF(lwp) WRITE(numout,*) ' 1. / rau0 r1_rau0 = ', r1_rau0, ' m^3/kg' |
---|
1090 | IF(lwp) WRITE(numout,*) ' ocean specific heat rcp = ', rcp , ' J/Kelvin' |
---|
1091 | IF(lwp) WRITE(numout,*) ' rau0 * rcp rau0_rcp = ', rau0_rcp |
---|
1092 | IF(lwp) WRITE(numout,*) ' 1. / ( rau0 * rcp ) r1_rau0_rcp = ', r1_rau0_rcp |
---|
1093 | ! |
---|
1094 | END SUBROUTINE eos_init |
---|
1095 | |
---|
1096 | !!====================================================================== |
---|
1097 | END MODULE eosinsitu |
---|