New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
ldftra.F90 in NEMO/branches/UKMO/NEMO_4.0.1_GM_rossby_radius_cutoff/src/OCE/LDF – NEMO

source: NEMO/branches/UKMO/NEMO_4.0.1_GM_rossby_radius_cutoff/src/OCE/LDF/ldftra.F90 @ 12861

Last change on this file since 12861 was 12861, checked in by davestorkey, 4 years ago

UKMO/NEMO_4.0.1_GM_rossby_radius_cutoff : science changes.
File size: 54.2 KB
Line 
1MODULE ldftra
2   !!======================================================================
3   !!                       ***  MODULE  ldftra  ***
4   !! Ocean physics:  lateral diffusivity coefficients
5   !!=====================================================================
6   !! History :       ! 1997-07  (G. Madec)  from inimix.F split in 2 routines
7   !!   NEMO     1.0  ! 2002-09  (G. Madec)  F90: Free form and module
8   !!            2.0  ! 2005-11  (G. Madec) 
9   !!            3.7  ! 2013-12  (F. Lemarie, G. Madec)  restructuration/simplification of aht/aeiv specification,
10   !!                 !                                  add velocity dependent coefficient and optional read in file
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   ldf_tra_init : initialization, namelist read, and parameters control
15   !!   ldf_tra      : update lateral eddy diffusivity coefficients at each time step
16   !!   ldf_eiv_init : initialization of the eiv coeff. from namelist choices
17   !!   ldf_eiv      : time evolution of the eiv coefficients (function of the growth rate of baroclinic instability)
18   !!   ldf_eiv_trp  : add to the input ocean transport the contribution of the EIV parametrization
19   !!   ldf_eiv_dia  : diagnose the eddy induced velocity from the eiv streamfunction
20   !!----------------------------------------------------------------------
21   USE oce             ! ocean dynamics and tracers
22   USE dom_oce         ! ocean space and time domain
23   USE phycst          ! physical constants
24   USE ldfslp          ! lateral diffusion: slope of iso-neutral surfaces
25   USE ldfc1d_c2d      ! lateral diffusion: 1D & 2D cases
26   USE diaptr
27   !
28   USE in_out_manager  ! I/O manager
29   USE iom             ! I/O module for ehanced bottom friction file
30   USE lib_mpp         ! distribued memory computing library
31   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   ldf_tra_init   ! called by nemogcm.F90
37   PUBLIC   ldf_tra        ! called by step.F90
38   PUBLIC   ldf_eiv_init   ! called by nemogcm.F90
39   PUBLIC   ldf_eiv        ! called by step.F90
40   PUBLIC   ldf_eiv_trp    ! called by traadv.F90
41   PUBLIC   ldf_eiv_dia    ! called by traldf_iso and traldf_iso_triad.F90
42   
43   !                                   !!* Namelist namtra_ldf : lateral mixing on tracers *
44   !                                    != Operator type =!
45   LOGICAL , PUBLIC ::   ln_traldf_OFF       !: no operator: No explicit diffusion
46   LOGICAL , PUBLIC ::   ln_traldf_lap       !: laplacian operator
47   LOGICAL , PUBLIC ::   ln_traldf_blp       !: bilaplacian operator
48   !                                    != Direction of action =!
49   LOGICAL , PUBLIC ::   ln_traldf_lev       !: iso-level direction
50   LOGICAL , PUBLIC ::   ln_traldf_hor       !: horizontal (geopotential) direction
51!  LOGICAL , PUBLIC ::   ln_traldf_iso       !: iso-neutral direction                    (see ldfslp)
52   !                                    != iso-neutral options =!
53!  LOGICAL , PUBLIC ::   ln_traldf_triad     !: griffies triad scheme                    (see ldfslp)
54   LOGICAL , PUBLIC ::   ln_traldf_msc       !: Method of Stabilizing Correction
55!  LOGICAL , PUBLIC ::   ln_triad_iso        !: pure horizontal mixing in ML             (see ldfslp)
56!  LOGICAL , PUBLIC ::   ln_botmix_triad     !: mixing on bottom                         (see ldfslp)
57!  REAL(wp), PUBLIC ::   rn_sw_triad         !: =1/0 switching triad / all 4 triads used (see ldfslp)
58!  REAL(wp), PUBLIC ::   rn_slpmax           !: slope limit                              (see ldfslp)
59   !                                    !=  Coefficients =!
60   INTEGER , PUBLIC ::   nn_aht_ijk_t        !: choice of time & space variations of the lateral eddy diffusivity coef.
61   !                                            !  time invariant coefficients:  aht_0 = 1/2  Ud*Ld   (lap case)
62   !                                            !                                bht_0 = 1/12 Ud*Ld^3 (blp case)
63   REAL(wp), PUBLIC ::      rn_Ud               !: lateral diffusive velocity  [m/s]
64   REAL(wp), PUBLIC ::      rn_Ld               !: lateral diffusive length    [m]
65
66   !                                   !!* Namelist namtra_eiv : eddy induced velocity param. *
67   !                                    != Use/diagnose eiv =!
68   LOGICAL , PUBLIC ::   ln_ldfeiv           !: eddy induced velocity flag
69   LOGICAL , PUBLIC ::   ln_ldfeiv_dia       !: diagnose & output eiv streamfunction and velocity (IOM)
70   !                                    != Coefficients =!
71   INTEGER , PUBLIC ::   nn_aei_ijk_t        !: choice of time/space variation of the eiv coeff.
72   REAL(wp), PUBLIC ::      rn_Ue               !: lateral diffusive velocity  [m/s]
73   REAL(wp), PUBLIC ::      rn_Le               !: lateral diffusive length    [m]
74   
75   !                                  ! Flag to control the type of lateral diffusive operator
76   INTEGER, PARAMETER, PUBLIC ::   np_ERROR  =-10   ! error in specification of lateral diffusion
77   INTEGER, PARAMETER, PUBLIC ::   np_no_ldf = 00   ! without operator (i.e. no lateral diffusive trend)
78   !                          !!      laplacian     !    bilaplacian    !
79   INTEGER, PARAMETER, PUBLIC ::   np_lap    = 10   ,   np_blp    = 20  ! iso-level operator
80   INTEGER, PARAMETER, PUBLIC ::   np_lap_i  = 11   ,   np_blp_i  = 21  ! standard iso-neutral or geopotential operator
81   INTEGER, PARAMETER, PUBLIC ::   np_lap_it = 12   ,   np_blp_it = 22  ! triad    iso-neutral or geopotential operator
82
83   INTEGER , PUBLIC ::   nldf_tra      = 0         !: type of lateral diffusion used defined from ln_traldf_... (namlist logicals)
84   LOGICAL , PUBLIC ::   l_ldftra_time = .FALSE.   !: flag for time variation of the lateral eddy diffusivity coef.
85   LOGICAL , PUBLIC ::   l_ldfeiv_time = .FALSE.   !: flag for time variation of the eiv coef.
86   LOGICAL , PUBLIC ::   l_Ro_cutoff   = .FALSE.   !: flag for Rossby-radius cutoff in calcn of eiv coeff
87
88   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   ahtu, ahtv   !: eddy diffusivity coef. at U- and V-points   [m2/s]
89   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   aeiu, aeiv   !: eddy induced velocity coeff.                [m2/s]
90
91   REAL(wp) ::   aht0, aei0               ! constant eddy coefficients (deduced from namelist values)                     [m2/s]
92   REAL(wp) ::   r1_2  = 0.5_wp           ! =1/2
93   REAL(wp) ::   r1_4  = 0.25_wp          ! =1/4
94   REAL(wp) ::   r1_12 = 1._wp / 12._wp   ! =1/12
95
96   !! * Substitutions
97#  include "vectopt_loop_substitute.h90"
98   !!----------------------------------------------------------------------
99   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
100   !! $Id$
101   !! Software governed by the CeCILL license (see ./LICENSE)
102   !!----------------------------------------------------------------------
103CONTAINS
104
105   SUBROUTINE ldf_tra_init
106      !!----------------------------------------------------------------------
107      !!                  ***  ROUTINE ldf_tra_init  ***
108      !!
109      !! ** Purpose :   initializations of the tracer lateral mixing coeff.
110      !!
111      !! ** Method  : * the eddy diffusivity coef. specification depends on:
112      !!
113      !!    ln_traldf_lap = T     laplacian operator
114      !!    ln_traldf_blp = T   bilaplacian operator
115      !!
116      !!    nn_aht_ijk_t  =  0 => = constant
117      !!                  !
118      !!                  = 10 => = F(z) : constant with a reduction of 1/4 with depth
119      !!                  !
120      !!                  =-20 => = F(i,j)   = shape read in 'eddy_diffusivity.nc' file
121      !!                  = 20    = F(i,j)   = F(e1,e2) or F(e1^3,e2^3) (lap or bilap case)
122      !!                  = 21    = F(i,j,t) = F(growth rate of baroclinic instability)
123      !!                  !
124      !!                  =-30 => = F(i,j,k)   = shape read in 'eddy_diffusivity.nc' file
125      !!                  = 30    = F(i,j,k)   = 2D (case 20) + decrease with depth (case 10)
126      !!                  = 31    = F(i,j,k,t) = F(local velocity) (  1/2  |u|e     laplacian operator
127      !!                                                           or 1/12 |u|e^3 bilaplacian operator )
128      !!              * initialisation of the eddy induced velocity coefficient by a call to ldf_eiv_init
129      !!           
130      !! ** action  : ahtu, ahtv initialized one for all or l_ldftra_time set to true
131      !!              aeiu, aeiv initialized one for all or l_ldfeiv_time set to true
132      !!----------------------------------------------------------------------
133      INTEGER  ::   jk                             ! dummy loop indices
134      INTEGER  ::   ioptio, ierr, inum, ios, inn   ! local integer
135      REAL(wp) ::   zah_max, zUfac                 !   -      -
136      CHARACTER(len=5) ::   cl_Units               ! units (m2/s or m4/s)
137      !!
138      NAMELIST/namtra_ldf/ ln_traldf_OFF, ln_traldf_lap  , ln_traldf_blp  ,   &   ! type of operator
139         &                 ln_traldf_lev, ln_traldf_hor  , ln_traldf_triad,   &   ! acting direction of the operator
140         &                 ln_traldf_iso, ln_traldf_msc  ,  rn_slpmax     ,   &   ! option for iso-neutral operator
141         &                 ln_triad_iso , ln_botmix_triad, rn_sw_triad    ,   &   ! option for triad operator
142         &                 nn_aht_ijk_t , rn_Ud          , rn_Ld                  ! lateral eddy coefficient
143      !!----------------------------------------------------------------------
144      !
145      IF(lwp) THEN                      ! control print
146         WRITE(numout,*)
147         WRITE(numout,*) 'ldf_tra_init : lateral tracer diffusion'
148         WRITE(numout,*) '~~~~~~~~~~~~ '
149      ENDIF
150     
151      !
152      !  Choice of lateral tracer physics
153      ! =================================
154      !
155      REWIND( numnam_ref )              ! Namelist namtra_ldf in reference namelist : Lateral physics on tracers
156      READ  ( numnam_ref, namtra_ldf, IOSTAT = ios, ERR = 901)
157901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtra_ldf in reference namelist' )
158      REWIND( numnam_cfg )              ! Namelist namtra_ldf in configuration namelist : Lateral physics on tracers
159      READ  ( numnam_cfg, namtra_ldf, IOSTAT = ios, ERR = 902 )
160902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtra_ldf in configuration namelist' )
161      IF(lwm) WRITE( numond, namtra_ldf )
162      !
163      IF(lwp) THEN                      ! control print
164         WRITE(numout,*) '   Namelist : namtra_ldf --- lateral mixing parameters (type, direction, coefficients)'
165         WRITE(numout,*) '      type :'
166         WRITE(numout,*) '         no explicit diffusion                   ln_traldf_OFF   = ', ln_traldf_OFF
167         WRITE(numout,*) '         laplacian operator                      ln_traldf_lap   = ', ln_traldf_lap
168         WRITE(numout,*) '         bilaplacian operator                    ln_traldf_blp   = ', ln_traldf_blp
169         WRITE(numout,*) '      direction of action :'
170         WRITE(numout,*) '         iso-level                               ln_traldf_lev   = ', ln_traldf_lev
171         WRITE(numout,*) '         horizontal (geopotential)               ln_traldf_hor   = ', ln_traldf_hor
172         WRITE(numout,*) '         iso-neutral Madec operator              ln_traldf_iso   = ', ln_traldf_iso
173         WRITE(numout,*) '         iso-neutral triad operator              ln_traldf_triad = ', ln_traldf_triad
174         WRITE(numout,*) '            use the Method of Stab. Correction   ln_traldf_msc   = ', ln_traldf_msc
175         WRITE(numout,*) '            maximum isoppycnal slope             rn_slpmax       = ', rn_slpmax
176         WRITE(numout,*) '            pure lateral mixing in ML            ln_triad_iso    = ', ln_triad_iso
177         WRITE(numout,*) '            switching triad or not               rn_sw_triad     = ', rn_sw_triad
178         WRITE(numout,*) '            lateral mixing on bottom             ln_botmix_triad = ', ln_botmix_triad
179         WRITE(numout,*) '      coefficients :'
180         WRITE(numout,*) '         type of time-space variation            nn_aht_ijk_t    = ', nn_aht_ijk_t
181         WRITE(numout,*) '            lateral diffusive velocity (if cst)  rn_Ud           = ', rn_Ud, ' m/s'
182         WRITE(numout,*) '            lateral diffusive length   (if cst)  rn_Ld           = ', rn_Ld, ' m'
183      ENDIF
184      !
185      !
186      ! Operator and its acting direction   (set nldf_tra) 
187      ! =================================
188      !
189      nldf_tra = np_ERROR
190      ioptio   = 0
191      IF( ln_traldf_OFF ) THEN   ;   nldf_tra = np_no_ldf   ;   ioptio = ioptio + 1   ;   ENDIF
192      IF( ln_traldf_lap ) THEN   ;                              ioptio = ioptio + 1   ;   ENDIF
193      IF( ln_traldf_blp ) THEN   ;                              ioptio = ioptio + 1   ;   ENDIF
194      IF( ioptio /=  1  )   CALL ctl_stop( 'tra_ldf_init: use ONE of the 3 operator options (NONE/lap/blp)' )
195      !
196      IF( .NOT.ln_traldf_OFF ) THEN    !==  direction ==>> type of operator  ==!
197         ioptio = 0
198         IF( ln_traldf_lev   )   ioptio = ioptio + 1
199         IF( ln_traldf_hor   )   ioptio = ioptio + 1
200         IF( ln_traldf_iso   )   ioptio = ioptio + 1
201         IF( ln_traldf_triad )   ioptio = ioptio + 1
202         IF( ioptio /=  1  )   CALL ctl_stop( 'tra_ldf_init: use ONE direction (level/hor/iso/triad)' )
203         !
204         !                                ! defined the type of lateral diffusion from ln_traldf_... logicals
205         ierr = 0
206         IF ( ln_traldf_lap ) THEN        ! laplacian operator
207            IF ( ln_zco ) THEN                  ! z-coordinate
208               IF ( ln_traldf_lev   )   nldf_tra = np_lap     ! iso-level = horizontal (no rotation)
209               IF ( ln_traldf_hor   )   nldf_tra = np_lap     ! iso-level = horizontal (no rotation)
210               IF ( ln_traldf_iso   )   nldf_tra = np_lap_i   ! iso-neutral: standard  (   rotation)
211               IF ( ln_traldf_triad )   nldf_tra = np_lap_it  ! iso-neutral: triad     (   rotation)
212            ENDIF
213            IF ( ln_zps ) THEN                  ! z-coordinate with partial step
214               IF ( ln_traldf_lev   )   ierr     = 1          ! iso-level not allowed
215               IF ( ln_traldf_hor   )   nldf_tra = np_lap     ! horizontal             (no rotation)
216               IF ( ln_traldf_iso   )   nldf_tra = np_lap_i   ! iso-neutral: standard     (rotation)
217               IF ( ln_traldf_triad )   nldf_tra = np_lap_it  ! iso-neutral: triad        (rotation)
218            ENDIF
219            IF ( ln_sco ) THEN                  ! s-coordinate
220               IF ( ln_traldf_lev   )   nldf_tra = np_lap     ! iso-level              (no rotation)
221               IF ( ln_traldf_hor   )   nldf_tra = np_lap_i   ! horizontal             (   rotation)
222               IF ( ln_traldf_iso   )   nldf_tra = np_lap_i   ! iso-neutral: standard  (   rotation)
223               IF ( ln_traldf_triad )   nldf_tra = np_lap_it  ! iso-neutral: triad     (   rotation)
224            ENDIF
225         ENDIF
226         !
227         IF( ln_traldf_blp ) THEN         ! bilaplacian operator
228            IF ( ln_zco ) THEN                  ! z-coordinate
229               IF ( ln_traldf_lev   )   nldf_tra = np_blp     ! iso-level = horizontal (no rotation)
230               IF ( ln_traldf_hor   )   nldf_tra = np_blp     ! iso-level = horizontal (no rotation)
231               IF ( ln_traldf_iso   )   nldf_tra = np_blp_i   ! iso-neutral: standard  (   rotation)
232               IF ( ln_traldf_triad )   nldf_tra = np_blp_it  ! iso-neutral: triad     (   rotation)
233            ENDIF
234            IF ( ln_zps ) THEN                  ! z-coordinate with partial step
235               IF ( ln_traldf_lev   )   ierr     = 1          ! iso-level not allowed
236               IF ( ln_traldf_hor   )   nldf_tra = np_blp     ! horizontal             (no rotation)
237               IF ( ln_traldf_iso   )   nldf_tra = np_blp_i   ! iso-neutral: standard  (   rotation)
238               IF ( ln_traldf_triad )   nldf_tra = np_blp_it  ! iso-neutral: triad     (   rotation)
239            ENDIF
240            IF ( ln_sco ) THEN                  ! s-coordinate
241               IF ( ln_traldf_lev   )   nldf_tra = np_blp     ! iso-level              (no rotation)
242               IF ( ln_traldf_hor   )   nldf_tra = np_blp_it  ! horizontal             (   rotation)
243               IF ( ln_traldf_iso   )   nldf_tra = np_blp_i   ! iso-neutral: standard  (   rotation)
244               IF ( ln_traldf_triad )   nldf_tra = np_blp_it  ! iso-neutral: triad     (   rotation)
245            ENDIF
246         ENDIF
247         IF ( ierr == 1 )   CALL ctl_stop( 'iso-level in z-partial step, not allowed' )
248      ENDIF
249      !
250      IF( ln_ldfeiv .AND. .NOT.( ln_traldf_iso .OR. ln_traldf_triad ) )                &
251           &            CALL ctl_stop( 'ln_ldfeiv=T requires iso-neutral laplacian diffusion' )
252      IF( ln_isfcav .AND. ln_traldf_triad ) &
253           &            CALL ctl_stop( ' ice shelf cavity and traldf_triad not tested' )
254           !
255      IF(  nldf_tra == np_lap_i .OR. nldf_tra == np_lap_it .OR. &
256         & nldf_tra == np_blp_i .OR. nldf_tra == np_blp_it  )   l_ldfslp = .TRUE.    ! slope of neutral surfaces required
257      !
258      IF( ln_traldf_blp .AND. ( ln_traldf_iso .OR. ln_traldf_triad) ) THEN     ! iso-neutral bilaplacian need MSC
259         IF( .NOT.ln_traldf_msc )   CALL ctl_stop( 'tra_ldf_init: iso-neutral bilaplacian requires ln_traldf_msc=.true.' )
260      ENDIF
261      !
262      IF(lwp) THEN
263         WRITE(numout,*)
264         SELECT CASE( nldf_tra )
265         CASE( np_no_ldf )   ;   WRITE(numout,*) '   ==>>>   NO lateral diffusion'
266         CASE( np_lap    )   ;   WRITE(numout,*) '   ==>>>   laplacian iso-level operator'
267         CASE( np_lap_i  )   ;   WRITE(numout,*) '   ==>>>   Rotated laplacian operator (standard)'
268         CASE( np_lap_it )   ;   WRITE(numout,*) '   ==>>>   Rotated laplacian operator (triad)'
269         CASE( np_blp    )   ;   WRITE(numout,*) '   ==>>>   bilaplacian iso-level operator'
270         CASE( np_blp_i  )   ;   WRITE(numout,*) '   ==>>>   Rotated bilaplacian operator (standard)'
271         CASE( np_blp_it )   ;   WRITE(numout,*) '   ==>>>   Rotated bilaplacian operator (triad)'
272         END SELECT
273         WRITE(numout,*)
274      ENDIF
275
276      !
277      !  Space/time variation of eddy coefficients
278      ! ===========================================
279      !
280      l_ldftra_time = .FALSE.                ! no time variation except in case defined below
281      !
282      IF( ln_traldf_OFF ) THEN               !== no explicit diffusive operator  ==!
283         !
284         IF(lwp) WRITE(numout,*) '   ==>>>   No diffusive operator selected. ahtu and ahtv are not allocated'
285         RETURN
286         !
287      ELSE                                   !==  a lateral diffusion operator is used  ==!
288         !
289         !                                         ! allocate the aht arrays
290         ALLOCATE( ahtu(jpi,jpj,jpk) , ahtv(jpi,jpj,jpk) , STAT=ierr )
291         IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'ldf_tra_init: failed to allocate arrays')
292         !
293         ahtu(:,:,jpk) = 0._wp                     ! last level always 0 
294         ahtv(:,:,jpk) = 0._wp
295         !.
296         !                                         ! value of lap/blp eddy mixing coef.
297         IF(     ln_traldf_lap ) THEN   ;   zUfac = r1_2 *rn_Ud   ;   inn = 1   ;   cl_Units = ' m2/s'   !   laplacian
298         ELSEIF( ln_traldf_blp ) THEN   ;   zUfac = r1_12*rn_Ud   ;   inn = 3   ;   cl_Units = ' m4/s'   ! bilaplacian
299         ENDIF
300         aht0    = zUfac *    rn_Ld**inn              ! mixing coefficient
301         zah_max = zUfac * (ra*rad)**inn              ! maximum reachable coefficient (value at the Equator for e1=1 degree)
302         !
303         !
304         SELECT CASE(  nn_aht_ijk_t  )             !* Specification of space-time variations of ahtu, ahtv
305         !
306         CASE(   0  )      !==  constant  ==!
307            IF(lwp) WRITE(numout,*) '   ==>>>   eddy diffusivity = constant = ', aht0, cl_Units
308            ahtu(:,:,1:jpkm1) = aht0
309            ahtv(:,:,1:jpkm1) = aht0
310            !
311         CASE(  10  )      !==  fixed profile  ==!
312            IF(lwp) WRITE(numout,*) '   ==>>>   eddy diffusivity = F( depth )'
313            IF(lwp) WRITE(numout,*) '           surface eddy diffusivity = constant = ', aht0, cl_Units
314            ahtu(:,:,1) = aht0                        ! constant surface value
315            ahtv(:,:,1) = aht0
316            CALL ldf_c1d( 'TRA', ahtu(:,:,1), ahtv(:,:,1), ahtu, ahtv )
317            !
318         CASE ( -20 )      !== fixed horizontal shape and magnitude read in file  ==!
319            IF(lwp) WRITE(numout,*) '   ==>>>   eddy diffusivity = F(i,j) read in eddy_diffusivity.nc file'
320            CALL iom_open( 'eddy_diffusivity_2D.nc', inum )
321            CALL iom_get ( inum, jpdom_data, 'ahtu_2D', ahtu(:,:,1) )
322            CALL iom_get ( inum, jpdom_data, 'ahtv_2D', ahtv(:,:,1) )
323            CALL iom_close( inum )
324            DO jk = 2, jpkm1
325               ahtu(:,:,jk) = ahtu(:,:,1)
326               ahtv(:,:,jk) = ahtv(:,:,1)
327            END DO
328            !
329         CASE(  20  )      !== fixed horizontal shape  ==!
330            IF(lwp) WRITE(numout,*) '   ==>>>   eddy diffusivity = F( e1, e2 ) or F( e1^3, e2^3 ) (lap or blp case)'
331            IF(lwp) WRITE(numout,*) '           using a fixed diffusive velocity = ', rn_Ud,' m/s   and   Ld = Max(e1,e2)'
332            IF(lwp) WRITE(numout,*) '           maximum reachable coefficient (at the Equator) = ', zah_max, cl_Units, '  for e1=1°)'
333            CALL ldf_c2d( 'TRA', zUfac      , inn        , ahtu, ahtv )    ! value proportional to scale factor^inn
334            !
335         CASE(  21  )      !==  time varying 2D field  ==!
336            IF(lwp) WRITE(numout,*) '   ==>>>   eddy diffusivity = F( latitude, longitude, time )'
337            IF(lwp) WRITE(numout,*) '                            = F( growth rate of baroclinic instability )'
338            IF(lwp) WRITE(numout,*) '            min value = 0.2 * aht0 (with aht0= 1/2 rn_Ud*rn_Ld)'
339            IF(lwp) WRITE(numout,*) '            max value =       aei0 (with aei0=1/2 rn_Ue*Le  increased to aht0 within 20N-20S'
340            !
341            l_ldftra_time = .TRUE.     ! will be calculated by call to ldf_tra routine in step.F90
342            !
343            IF( ln_traldf_blp )   CALL ctl_stop( 'ldf_tra_init: aht=F( growth rate of baroc. insta .)',   &
344               &                                 '              incompatible with bilaplacian operator' )
345            !
346         CASE( -30  )      !== fixed 3D shape read in file  ==!
347            IF(lwp) WRITE(numout,*) '   ==>>>   eddy diffusivity = F(i,j,k) read in eddy_diffusivity.nc file'
348            CALL iom_open( 'eddy_diffusivity_3D.nc', inum )
349            CALL iom_get ( inum, jpdom_data, 'ahtu_3D', ahtu )
350            CALL iom_get ( inum, jpdom_data, 'ahtv_3D', ahtv )
351            CALL iom_close( inum )
352            !
353         CASE(  30  )      !==  fixed 3D shape  ==!
354            IF(lwp) WRITE(numout,*) '   ==>>>   eddy diffusivity = F( latitude, longitude, depth )'
355            IF(lwp) WRITE(numout,*) '           using a fixed diffusive velocity = ', rn_Ud,' m/s   and   Ld = Max(e1,e2)'
356            IF(lwp) WRITE(numout,*) '           maximum reachable coefficient (at the Equator) = ', zah_max, cl_Units, '  for e1=1°)'
357            CALL ldf_c2d( 'TRA', zUfac      , inn        , ahtu, ahtv )    ! surface value proportional to scale factor^inn
358            CALL ldf_c1d( 'TRA', ahtu(:,:,1), ahtv(:,:,1), ahtu, ahtv )    ! reduction with depth
359            !
360         CASE(  31  )      !==  time varying 3D field  ==!
361            IF(lwp) WRITE(numout,*) '   ==>>>   eddy diffusivity = F( latitude, longitude, depth , time )'
362            IF(lwp) WRITE(numout,*) '           proportional to the velocity : 1/2 |u|e or 1/12 |u|e^3'
363            !
364            l_ldftra_time = .TRUE.     ! will be calculated by call to ldf_tra routine in step.F90
365            !
366         CASE DEFAULT
367            CALL ctl_stop('ldf_tra_init: wrong choice for nn_aht_ijk_t, the type of space-time variation of aht')
368         END SELECT
369         !
370         IF( .NOT.l_ldftra_time ) THEN             !* No time variation
371            IF(     ln_traldf_lap ) THEN                 !   laplacian operator (mask only)
372               ahtu(:,:,1:jpkm1) =       ahtu(:,:,1:jpkm1)   * umask(:,:,1:jpkm1)
373               ahtv(:,:,1:jpkm1) =       ahtv(:,:,1:jpkm1)   * vmask(:,:,1:jpkm1)
374            ELSEIF( ln_traldf_blp ) THEN                 ! bilaplacian operator (square root + mask)
375               ahtu(:,:,1:jpkm1) = SQRT( ahtu(:,:,1:jpkm1) ) * umask(:,:,1:jpkm1)
376               ahtv(:,:,1:jpkm1) = SQRT( ahtv(:,:,1:jpkm1) ) * vmask(:,:,1:jpkm1)
377            ENDIF
378         ENDIF
379         !
380      ENDIF
381      !
382   END SUBROUTINE ldf_tra_init
383
384
385   SUBROUTINE ldf_tra( kt )
386      !!----------------------------------------------------------------------
387      !!                  ***  ROUTINE ldf_tra  ***
388      !!
389      !! ** Purpose :   update at kt the tracer lateral mixing coeff. (aht and aeiv)
390      !!
391      !! ** Method  : * time varying eddy diffusivity coefficients:
392      !!
393      !!    nn_aei_ijk_t = 21    aeiu, aeiv = F(i,j,  t) = F(growth rate of baroclinic instability)
394      !!                                                   with a reduction to 0 in vicinity of the Equator
395      !!    nn_aht_ijk_t = 21    ahtu, ahtv = F(i,j,  t) = F(growth rate of baroclinic instability)
396      !!
397      !!                 = 31    ahtu, ahtv = F(i,j,k,t) = F(local velocity) (  |u|e  /12   laplacian operator
398      !!                                                                     or |u|e^3/12 bilaplacian operator )
399      !!
400      !!              * time varying EIV coefficients: call to ldf_eiv routine
401      !!
402      !! ** action  :   ahtu, ahtv   update at each time step   
403      !!                aeiu, aeiv      -       -     -    -   (if ln_ldfeiv=T)
404      !!----------------------------------------------------------------------
405      INTEGER, INTENT(in) ::   kt   ! time step
406      !
407      INTEGER  ::   ji, jj, jk   ! dummy loop indices
408      REAL(wp) ::   zaht, zahf, zaht_min, zDaht, z1_f20   ! local scalar
409      !!----------------------------------------------------------------------
410      !
411      IF( ln_ldfeiv .AND. ( nn_aei_ijk_t == 21 .OR. nn_aei_ijk_t == 22 ) ) THEN       
412         !                                ! eddy induced velocity coefficients
413         !                                ! =F(growth rate of baroclinic instability)
414         !                                ! max value aeiv_0 ; decreased to 0 within 20N-20S
415         CALL ldf_eiv( kt, aei0, aeiu, aeiv, l_Ro_cutoff )
416      ENDIF
417      !
418      SELECT CASE(  nn_aht_ijk_t  )       ! Eddy diffusivity coefficients
419      !
420      CASE(  21  )       !==  time varying 2D field  ==!   = F( growth rate of baroclinic instability )
421         !                                             !   min value 0.2*aht0
422         !                                             !   max value aht0 (aei0 if nn_aei_ijk_t=21)
423         !                                             !   increase to aht0 within 20N-20S
424         IF( ln_ldfeiv .AND. nn_aei_ijk_t == 21 ) THEN   ! use the already computed aei.
425            ahtu(:,:,1) = aeiu(:,:,1)
426            ahtv(:,:,1) = aeiv(:,:,1)
427         ELSE                                            ! compute aht.
428            CALL ldf_eiv( kt, aht0, ahtu, ahtv, .false. )
429         ENDIF
430         !
431         z1_f20   = 1._wp / (  2._wp * omega * SIN( rad * 20._wp )  )   ! 1 / ff(20 degrees)   
432         zaht_min = 0.2_wp * aht0                                       ! minimum value for aht
433         zDaht    = aht0 - zaht_min                                     
434         DO jj = 1, jpj
435            DO ji = 1, jpi
436               !!gm CAUTION : here we assume lat/lon grid in 20deg N/S band (like all ORCA cfg)
437               !!     ==>>>   The Coriolis value is identical for t- & u_points, and for v- and f-points
438               zaht = ( 1._wp -  MIN( 1._wp , ABS( ff_t(ji,jj) * z1_f20 ) ) ) * zDaht
439               zahf = ( 1._wp -  MIN( 1._wp , ABS( ff_f(ji,jj) * z1_f20 ) ) ) * zDaht
440               ahtu(ji,jj,1) = (  MAX( zaht_min, ahtu(ji,jj,1) ) + zaht  )     ! min value zaht_min
441               ahtv(ji,jj,1) = (  MAX( zaht_min, ahtv(ji,jj,1) ) + zahf  )     ! increase within 20S-20N
442            END DO
443         END DO
444         DO jk = 1, jpkm1                             ! deeper value = surface value + mask for all levels
445            ahtu(:,:,jk) = ahtu(:,:,1) * umask(:,:,jk)
446            ahtv(:,:,jk) = ahtv(:,:,1) * vmask(:,:,jk)
447         END DO
448         !
449      CASE(  31  )       !==  time varying 3D field  ==!   = F( local velocity )
450         IF( ln_traldf_lap     ) THEN          !   laplacian operator |u| e /12
451            DO jk = 1, jpkm1
452               ahtu(:,:,jk) = ABS( ub(:,:,jk) ) * e1u(:,:) * r1_12   ! n.b. ub,vb are masked
453               ahtv(:,:,jk) = ABS( vb(:,:,jk) ) * e2v(:,:) * r1_12
454            END DO
455         ELSEIF( ln_traldf_blp ) THEN      ! bilaplacian operator      sqrt( |u| e^3 /12 ) = sqrt( |u| e /12 ) * e
456            DO jk = 1, jpkm1
457               ahtu(:,:,jk) = SQRT(  ABS( ub(:,:,jk) ) * e1u(:,:) * r1_12  ) * e1u(:,:)
458               ahtv(:,:,jk) = SQRT(  ABS( vb(:,:,jk) ) * e2v(:,:) * r1_12  ) * e2v(:,:)
459            END DO
460         ENDIF
461         !
462      END SELECT
463      !
464      CALL iom_put( "ahtu_2d", ahtu(:,:,1) )   ! surface u-eddy diffusivity coeff.
465      CALL iom_put( "ahtv_2d", ahtv(:,:,1) )   ! surface v-eddy diffusivity coeff.
466      CALL iom_put( "ahtu_3d", ahtu(:,:,:) )   ! 3D      u-eddy diffusivity coeff.
467      CALL iom_put( "ahtv_3d", ahtv(:,:,:) )   ! 3D      v-eddy diffusivity coeff.
468      !
469      IF( ln_ldfeiv ) THEN
470        CALL iom_put( "aeiu_2d", aeiu(:,:,1) )   ! surface u-EIV coeff.
471        CALL iom_put( "aeiv_2d", aeiv(:,:,1) )   ! surface v-EIV coeff.
472        CALL iom_put( "aeiu_3d", aeiu(:,:,:) )   ! 3D      u-EIV coeff.
473        CALL iom_put( "aeiv_3d", aeiv(:,:,:) )   ! 3D      v-EIV coeff.
474      ENDIF
475      !
476   END SUBROUTINE ldf_tra
477
478
479   SUBROUTINE ldf_eiv_init
480      !!----------------------------------------------------------------------
481      !!                  ***  ROUTINE ldf_eiv_init  ***
482      !!
483      !! ** Purpose :   initialization of the eiv coeff. from namelist choices.
484      !!
485      !! ** Method  :   the eiv diffusivity coef. specification depends on:
486      !!    nn_aei_ijk_t  =  0 => = constant
487      !!                  !
488      !!                  = 10 => = F(z) : constant with a reduction of 1/4 with depth
489      !!                  !
490      !!                  =-20 => = F(i,j)   = shape read in 'eddy_diffusivity.nc' file
491      !!                  = 20    = F(i,j)   = F(e1,e2) or F(e1^3,e2^3) (lap or bilap case)
492      !!                  = 21    = F(i,j,t) = F(growth rate of baroclinic instability)
493      !!                  !
494      !!                  =-30 => = F(i,j,k)   = shape read in 'eddy_diffusivity.nc' file
495      !!                  = 30    = F(i,j,k)   = 2D (case 20) + decrease with depth (case 10)
496      !!
497      !! ** Action  :   aeiu , aeiv   :  initialized one for all or l_ldftra_time set to true
498      !!                l_ldfeiv_time : =T if EIV coefficients vary with time
499      !!----------------------------------------------------------------------
500      INTEGER  ::   jk                     ! dummy loop indices
501      INTEGER  ::   ierr, inum, ios, inn   ! local integer
502      REAL(wp) ::   zah_max, zUfac         !   -   scalar
503      !!
504      NAMELIST/namtra_eiv/ ln_ldfeiv   , ln_ldfeiv_dia,   &   ! eddy induced velocity (eiv)
505         &                 nn_aei_ijk_t, rn_Ue, rn_Le         ! eiv  coefficient
506      !!----------------------------------------------------------------------
507      !
508      IF(lwp) THEN                      ! control print
509         WRITE(numout,*)
510         WRITE(numout,*) 'ldf_eiv_init : eddy induced velocity parametrization'
511         WRITE(numout,*) '~~~~~~~~~~~~ '
512      ENDIF
513      !
514      REWIND( numnam_ref )              ! Namelist namtra_eiv in reference namelist : eddy induced velocity param.
515      READ  ( numnam_ref, namtra_eiv, IOSTAT = ios, ERR = 901)
516901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtra_eiv in reference namelist' )
517      !
518      REWIND( numnam_cfg )              ! Namelist namtra_eiv in configuration namelist : eddy induced velocity param.
519      READ  ( numnam_cfg, namtra_eiv, IOSTAT = ios, ERR = 902 )
520902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtra_eiv in configuration namelist' )
521      IF(lwm)  WRITE ( numond, namtra_eiv )
522
523      IF(lwp) THEN                      ! control print
524         WRITE(numout,*) '   Namelist namtra_eiv : '
525         WRITE(numout,*) '      Eddy Induced Velocity (eiv) param.         ln_ldfeiv     = ', ln_ldfeiv
526         WRITE(numout,*) '      eiv streamfunction & velocity diag.        ln_ldfeiv_dia = ', ln_ldfeiv_dia
527         WRITE(numout,*) '      coefficients :'
528         WRITE(numout,*) '         type of time-space variation            nn_aei_ijk_t  = ', nn_aei_ijk_t
529         WRITE(numout,*) '         lateral diffusive velocity (if cst)     rn_Ue         = ', rn_Ue, ' m/s'
530         WRITE(numout,*) '         lateral diffusive length   (if cst)     rn_Le         = ', rn_Le, ' m'
531         WRITE(numout,*)
532      ENDIF
533      !
534      l_ldfeiv_time = .FALSE.       ! no time variation except in case defined below
535      !
536      !
537      IF( .NOT.ln_ldfeiv ) THEN     !== Parametrization not used  ==!
538         !
539         IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity param is NOT used'
540         ln_ldfeiv_dia = .FALSE.
541         !
542      ELSE                          !== use the parametrization  ==!
543         !
544         IF(lwp) WRITE(numout,*) '   ==>>>   use eddy induced velocity parametrization'
545         IF(lwp) WRITE(numout,*)
546         !
547         IF( ln_traldf_blp )   CALL ctl_stop( 'ldf_eiv_init: eddy induced velocity ONLY with laplacian diffusivity' )
548         !
549         !                                != allocate the aei arrays
550         ALLOCATE( aeiu(jpi,jpj,jpk), aeiv(jpi,jpj,jpk), STAT=ierr )
551         IF( ierr /= 0 )   CALL ctl_stop('STOP', 'ldf_eiv: failed to allocate arrays')
552         !
553         !                                != Specification of space-time variations of eaiu, aeiv
554         !
555         aeiu(:,:,jpk) = 0._wp               ! last level always 0 
556         aeiv(:,:,jpk) = 0._wp
557         !                                   ! value of EIV coef. (laplacian operator)
558         zUfac = r1_2 *rn_Ue                    ! velocity factor
559         inn = 1                                ! L-exponent
560         aei0    = zUfac *    rn_Le**inn        ! mixing coefficient
561         zah_max = zUfac * (ra*rad)**inn        ! maximum reachable coefficient (value at the Equator)
562
563         l_Ro_cutoff = .FALSE.
564         SELECT CASE( nn_aei_ijk_t )         !* Specification of space-time variations
565         !
566         CASE(   0  )                        !--  constant  --!
567            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = constant = ', aei0, ' m2/s'
568            aeiu(:,:,1:jpkm1) = aei0
569            aeiv(:,:,1:jpkm1) = aei0
570            !
571         CASE(  10  )                        !--  fixed profile  --!
572            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = F( depth )'
573            IF(lwp) WRITE(numout,*) '           surface eddy diffusivity = constant = ', aht0, ' m2/s'
574            aeiu(:,:,1) = aei0                  ! constant surface value
575            aeiv(:,:,1) = aei0
576            CALL ldf_c1d( 'TRA', aeiu(:,:,1), aeiv(:,:,1), aeiu, aeiv )
577            !
578         CASE ( -20 )                        !--  fixed horizontal shape read in file  --!
579            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = F(i,j) read in eddy_diffusivity_2D.nc file'
580            CALL iom_open ( 'eddy_induced_velocity_2D.nc', inum )
581            CALL iom_get  ( inum, jpdom_data, 'aeiu', aeiu(:,:,1) )
582            CALL iom_get  ( inum, jpdom_data, 'aeiv', aeiv(:,:,1) )
583            CALL iom_close( inum )
584            DO jk = 2, jpkm1
585               aeiu(:,:,jk) = aeiu(:,:,1)
586               aeiv(:,:,jk) = aeiv(:,:,1)
587            END DO
588            !
589         CASE(  20  )                        !--  fixed horizontal shape  --!
590            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = F( e1, e2 )'
591            IF(lwp) WRITE(numout,*) '           using a fixed diffusive velocity = ', rn_Ue, ' m/s   and   Le = Max(e1,e2)'
592            IF(lwp) WRITE(numout,*) '           maximum reachable coefficient (at the Equator) = ', zah_max, ' m2/s   for e1=1°)'
593            CALL ldf_c2d( 'TRA', zUfac      , inn        , aeiu, aeiv )    ! value proportional to scale factor^inn
594            !
595         CASE(  21  )                        !--  time varying 2D field  --!
596            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = F( latitude, longitude, time )'
597            IF(lwp) WRITE(numout,*) '                                       = F( growth rate of baroclinic instability )'
598            IF(lwp) WRITE(numout,*) '           maximum allowed value: aei0 = ', aei0, ' m2/s'
599            !
600            l_ldfeiv_time = .TRUE.     ! will be calculated by call to ldf_tra routine in step.F90
601            !
602         CASE(  22  )                        !--  time varying 2D field with cutoff --!
603            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = F( latitude, longitude, time )'
604            IF(lwp) WRITE(numout,*) '                                       = F( growth rate of baroclinic instability )'
605            IF(lwp) WRITE(numout,*) '           maximum allowed value: aei0 = ', aei0, ' m2/s'
606            IF(lwp) WRITE(numout,*) '           Applied only where Rossby radius resolved by 2.dx'
607            !
608            l_Ro_cutoff   = .TRUE.
609            l_ldfeiv_time = .TRUE.     ! will be calculated by call to ldf_tra routine in step.F90
610            !
611         CASE( -30  )                        !-- fixed 3D shape read in file  --!
612            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = F(i,j,k) read in eddy_diffusivity_3D.nc file'
613            CALL iom_open ( 'eddy_induced_velocity_3D.nc', inum )
614            CALL iom_get  ( inum, jpdom_data, 'aeiu', aeiu )
615            CALL iom_get  ( inum, jpdom_data, 'aeiv', aeiv )
616            CALL iom_close( inum )
617            !
618         CASE(  30  )                        !--  fixed 3D shape  --!
619            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = F( latitude, longitude, depth )'
620            CALL ldf_c2d( 'TRA', zUfac      , inn        , aeiu, aeiv )    ! surface value proportional to scale factor^inn
621            CALL ldf_c1d( 'TRA', aeiu(:,:,1), aeiv(:,:,1), aeiu, aeiv )    ! reduction with depth
622            !
623         CASE DEFAULT
624            CALL ctl_stop('ldf_tra_init: wrong choice for nn_aei_ijk_t, the type of space-time variation of aei')
625         END SELECT
626         !
627         IF( .NOT.l_ldfeiv_time ) THEN             !* mask if No time variation
628            DO jk = 1, jpkm1
629               aeiu(:,:,jk) = aeiu(:,:,jk) * umask(:,:,jk)
630               ahtv(:,:,jk) = ahtv(:,:,jk) * vmask(:,:,jk)
631            END DO
632         ENDIF
633         !
634      ENDIF
635      !                   
636   END SUBROUTINE ldf_eiv_init
637
638
639   SUBROUTINE ldf_eiv( kt, paei0, paeiu, paeiv, l_Ro_cutoff )
640      !!----------------------------------------------------------------------
641      !!                  ***  ROUTINE ldf_eiv  ***
642      !!
643      !! ** Purpose :   Compute the eddy induced velocity coefficient from the
644      !!              growth rate of baroclinic instability.
645      !!
646      !! ** Method  :   coefficient function of the growth rate of baroclinic instability
647      !!
648      !! Reference : Treguier et al. JPO 1997   ; Held and Larichev JAS 1996
649      !!----------------------------------------------------------------------
650      INTEGER                         , INTENT(in   ) ::   kt             ! ocean time-step index
651      REAL(wp)                        , INTENT(inout) ::   paei0          ! max value            [m2/s]
652      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   paeiu, paeiv   ! eiv coefficient      [m2/s]
653      LOGICAL                         , INTENT(in   ) ::   l_Ro_cutoff    ! Rossby radius cutoff yes/no
654      !
655      INTEGER  ::   ji, jj, jk    ! dummy loop indices
656      REAL(wp) ::   zfw, ze3w, zn2, z1_f20, zaht, zaht_min, zzaei    ! local scalars
657      REAL(wp), DIMENSION(jpi,jpj) ::   zn, zah, zhw, zRo, zRo_lim, zaeiw   ! 2D workspace
658      !!----------------------------------------------------------------------
659      !
660      zn (:,:) = 0._wp        ! Local initialization
661      zhw(:,:) = 5._wp
662      zah(:,:) = 0._wp
663      zRo(:,:) = 0._wp
664      zRo_lim(:,:) = 0._wp
665      !                       ! Compute lateral diffusive coefficient at T-point
666      IF( ln_traldf_triad ) THEN
667         DO jk = 1, jpk
668            DO jj = 2, jpjm1
669               DO ji = 2, jpim1
670                  ! Take the max of N^2 and zero then take the vertical sum
671                  ! of the square root of the resulting N^2 ( required to compute
672                  ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
673                  zn2 = MAX( rn2b(ji,jj,jk), 0._wp )
674                  zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * e3w_n(ji,jj,jk)
675                  ! Compute elements required for the inverse time scale of baroclinic
676                  ! eddies using the isopycnal slopes calculated in ldfslp.F :
677                  ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
678                  ze3w = e3w_n(ji,jj,jk) * tmask(ji,jj,jk)
679                  zah(ji,jj) = zah(ji,jj) + zn2 * wslp2(ji,jj,jk) * ze3w
680                  zhw(ji,jj) = zhw(ji,jj) + ze3w
681               END DO
682            END DO
683         END DO
684      ELSE
685         DO jk = 1, jpk
686            DO jj = 2, jpjm1
687               DO ji = 2, jpim1
688                  ! Take the max of N^2 and zero then take the vertical sum
689                  ! of the square root of the resulting N^2 ( required to compute
690                  ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
691                  zn2 = MAX( rn2b(ji,jj,jk), 0._wp )
692                  zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * e3w_n(ji,jj,jk)
693                  ! Compute elements required for the inverse time scale of baroclinic
694                  ! eddies using the isopycnal slopes calculated in ldfslp.F :
695                  ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
696                  ze3w = e3w_n(ji,jj,jk) * tmask(ji,jj,jk)
697                  zah(ji,jj) = zah(ji,jj) + zn2 * ( wslpi(ji,jj,jk) * wslpi(ji,jj,jk)   &
698                     &                            + wslpj(ji,jj,jk) * wslpj(ji,jj,jk) ) * ze3w
699                  zhw(ji,jj) = zhw(ji,jj) + ze3w
700               END DO
701            END DO
702         END DO
703      ENDIF
704
705      DO jj = 2, jpjm1
706         DO ji = fs_2, fs_jpim1   ! vector opt.
707            zfw = MAX( ABS( 2. * omega * SIN( rad * gphit(ji,jj) ) ) , 1.e-10 )
708            ! Rossby radius at w-point taken between 2 km and  40km
709            zRo(ji,jj) = .4 * zn(ji,jj) / zfw
710            zRo_lim(ji,jj) = MAX(  2.e3 , MIN( zRo(ji,jj), 40.e3 )  )
711            ! Compute aeiw by multiplying Ro^2 and T^-1
712            zaeiw(ji,jj) = zRo_lim(ji,jj) * zRo_lim(ji,jj) * SQRT( zah(ji,jj) / zhw(ji,jj) ) * tmask(ji,jj,1)
713         END DO
714      END DO
715      CALL iom_put('RossRad',zRo)
716      !                                         !==  Bound on eiv coeff.  ==!
717      z1_f20 = 1._wp / (  2._wp * omega * sin( rad * 20._wp )  )
718      DO jj = 2, jpjm1
719         DO ji = fs_2, fs_jpim1   ! vector opt.
720            zzaei = MIN( 1._wp, ABS( ff_t(ji,jj) * z1_f20 ) ) * zaeiw(ji,jj)     ! tropical decrease
721! JD : modifications here to introduce scaling by local rossby radius of deformation vs local grid scale
722! arbitrary decision that GM is de-activated if local rossy radius larger than 2 times local grid scale
723! based on Hallberg (2013)
724            IF ( l_Ro_cutoff .AND. zRo(ji,jj) >= ( 2._wp * MIN( e1t(ji,jj), e2t(ji,jj) ) ) ) THEN
725! TODO : use a version of zRo that integrates over a few time steps ?
726                zaeiw(ji,jj) = 0._wp
727            ELSE
728                zaeiw(ji,jj) = MIN( zzaei, paei0 )
729            ENDIF
730         END DO
731      END DO
732      CALL lbc_lnk( 'ldftra', zaeiw(:,:), 'W', 1. )       ! lateral boundary condition
733      !               
734      DO jj = 2, jpjm1                          !== aei at u- and v-points  ==!
735         DO ji = fs_2, fs_jpim1   ! vector opt.
736            paeiu(ji,jj,1) = 0.5_wp * ( zaeiw(ji,jj) + zaeiw(ji+1,jj  ) ) * umask(ji,jj,1)
737            paeiv(ji,jj,1) = 0.5_wp * ( zaeiw(ji,jj) + zaeiw(ji  ,jj+1) ) * vmask(ji,jj,1)
738         END DO
739      END DO
740      CALL lbc_lnk_multi( 'ldftra', paeiu(:,:,1), 'U', 1. , paeiv(:,:,1), 'V', 1. )      ! lateral boundary condition
741
742      DO jk = 2, jpkm1                          !==  deeper values equal the surface one  ==!
743         paeiu(:,:,jk) = paeiu(:,:,1) * umask(:,:,jk)
744         paeiv(:,:,jk) = paeiv(:,:,1) * vmask(:,:,jk)
745      END DO
746      ! 
747   END SUBROUTINE ldf_eiv
748
749
750   SUBROUTINE ldf_eiv_trp( kt, kit000, pun, pvn, pwn, cdtype )
751      !!----------------------------------------------------------------------
752      !!                  ***  ROUTINE ldf_eiv_trp  ***
753      !!
754      !! ** Purpose :   add to the input ocean transport the contribution of
755      !!              the eddy induced velocity parametrization.
756      !!
757      !! ** Method  :   The eddy induced transport is computed from a flux stream-
758      !!              function which depends on the slope of iso-neutral surfaces
759      !!              (see ldf_slp). For example, in the i-k plan :
760      !!                   psi_uw = mk(aeiu) e2u mi(wslpi)   [in m3/s]
761      !!                   Utr_eiv = - dk[psi_uw]
762      !!                   Vtr_eiv = + di[psi_uw]
763      !!                ln_ldfeiv_dia = T : output the associated streamfunction,
764      !!                                    velocity and heat transport (call ldf_eiv_dia)
765      !!
766      !! ** Action  : pun, pvn increased by the eiv transport
767      !!----------------------------------------------------------------------
768      INTEGER                         , INTENT(in   ) ::   kt       ! ocean time-step index
769      INTEGER                         , INTENT(in   ) ::   kit000   ! first time step index
770      CHARACTER(len=3)                , INTENT(in   ) ::   cdtype   ! =TRA or TRC (tracer indicator)
771      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pun      ! in : 3 ocean transport components   [m3/s]
772      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pvn      ! out: 3 ocean transport components   [m3/s]
773      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pwn      ! increased by the eiv                [m3/s]
774      !!
775      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
776      REAL(wp) ::   zuwk, zuwk1, zuwi, zuwi1   ! local scalars
777      REAL(wp) ::   zvwk, zvwk1, zvwj, zvwj1   !   -      -
778      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zpsi_uw, zpsi_vw
779      !!----------------------------------------------------------------------
780      !
781      IF( kt == kit000 )  THEN
782         IF(lwp) WRITE(numout,*)
783         IF(lwp) WRITE(numout,*) 'ldf_eiv_trp : eddy induced advection on ', cdtype,' :'
784         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   add to velocity fields the eiv component'
785      ENDIF
786
787     
788      zpsi_uw(:,:, 1 ) = 0._wp   ;   zpsi_vw(:,:, 1 ) = 0._wp
789      zpsi_uw(:,:,jpk) = 0._wp   ;   zpsi_vw(:,:,jpk) = 0._wp
790      !
791      DO jk = 2, jpkm1
792         DO jj = 1, jpjm1
793            DO ji = 1, fs_jpim1   ! vector opt.
794               zpsi_uw(ji,jj,jk) = - r1_4 * e2u(ji,jj) * ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk) )   &
795                  &                                    * ( aeiu (ji,jj,jk-1) + aeiu (ji  ,jj,jk) ) * umask(ji,jj,jk)
796               zpsi_vw(ji,jj,jk) = - r1_4 * e1v(ji,jj) * ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk) )   &
797                  &                                    * ( aeiv (ji,jj,jk-1) + aeiv (ji,jj  ,jk) ) * vmask(ji,jj,jk)
798            END DO
799         END DO
800      END DO
801      !
802      DO jk = 1, jpkm1
803         DO jj = 1, jpjm1
804            DO ji = 1, fs_jpim1   ! vector opt.               
805               pun(ji,jj,jk) = pun(ji,jj,jk) - ( zpsi_uw(ji,jj,jk) - zpsi_uw(ji,jj,jk+1) )
806               pvn(ji,jj,jk) = pvn(ji,jj,jk) - ( zpsi_vw(ji,jj,jk) - zpsi_vw(ji,jj,jk+1) )
807            END DO
808         END DO
809      END DO
810      DO jk = 1, jpkm1
811         DO jj = 2, jpjm1
812            DO ji = fs_2, fs_jpim1   ! vector opt.
813               pwn(ji,jj,jk) = pwn(ji,jj,jk) + (  zpsi_uw(ji,jj,jk) - zpsi_uw(ji-1,jj  ,jk)   &
814                  &                             + zpsi_vw(ji,jj,jk) - zpsi_vw(ji  ,jj-1,jk) )
815            END DO
816         END DO
817      END DO
818      !
819      !                              ! diagnose the eddy induced velocity and associated heat transport
820      IF( ln_ldfeiv_dia .AND. cdtype == 'TRA' )   CALL ldf_eiv_dia( zpsi_uw, zpsi_vw )
821      !
822    END SUBROUTINE ldf_eiv_trp
823
824
825   SUBROUTINE ldf_eiv_dia( psi_uw, psi_vw )
826      !!----------------------------------------------------------------------
827      !!                  ***  ROUTINE ldf_eiv_dia  ***
828      !!
829      !! ** Purpose :   diagnose the eddy induced velocity and its associated
830      !!              vertically integrated heat transport.
831      !!
832      !! ** Method :
833      !!
834      !!----------------------------------------------------------------------
835      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   psi_uw, psi_vw   ! streamfunction   [m3/s]
836      !
837      INTEGER  ::   ji, jj, jk    ! dummy loop indices
838      REAL(wp) ::   zztmp   ! local scalar
839      REAL(wp), DIMENSION(jpi,jpj)     ::   zw2d   ! 2D workspace
840      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zw3d   ! 3D workspace
841      !!----------------------------------------------------------------------
842      !
843!!gm I don't like this routine....   Crazy  way of doing things, not optimal at all...
844!!gm     to be redesigned....   
845      !                                                  !==  eiv stream function: output  ==!
846      CALL lbc_lnk_multi( 'ldftra', psi_uw, 'U', -1. , psi_vw, 'V', -1. )
847      !
848!!gm      CALL iom_put( "psi_eiv_uw", psi_uw )                 ! output
849!!gm      CALL iom_put( "psi_eiv_vw", psi_vw )
850      !
851      !                                                  !==  eiv velocities: calculate and output  ==!
852      !
853      zw3d(:,:,jpk) = 0._wp                                    ! bottom value always 0
854      !
855      DO jk = 1, jpkm1                                         ! e2u e3u u_eiv = -dk[psi_uw]
856         zw3d(:,:,jk) = ( psi_uw(:,:,jk+1) - psi_uw(:,:,jk) ) / ( e2u(:,:) * e3u_n(:,:,jk) )
857      END DO
858      CALL iom_put( "uoce_eiv", zw3d )
859      !
860      DO jk = 1, jpkm1                                         ! e1v e3v v_eiv = -dk[psi_vw]
861         zw3d(:,:,jk) = ( psi_vw(:,:,jk+1) - psi_vw(:,:,jk) ) / ( e1v(:,:) * e3v_n(:,:,jk) )
862      END DO
863      CALL iom_put( "voce_eiv", zw3d )
864      !
865      DO jk = 1, jpkm1                                         ! e1 e2 w_eiv = dk[psix] + dk[psix]
866         DO jj = 2, jpjm1
867            DO ji = fs_2, fs_jpim1  ! vector opt.
868               zw3d(ji,jj,jk) = (  psi_vw(ji,jj,jk) - psi_vw(ji  ,jj-1,jk)    &
869                  &              + psi_uw(ji,jj,jk) - psi_uw(ji-1,jj  ,jk)  ) / e1e2t(ji,jj)
870            END DO
871         END DO
872      END DO
873      CALL lbc_lnk( 'ldftra', zw3d, 'T', 1. )      ! lateral boundary condition
874      CALL iom_put( "woce_eiv", zw3d )
875      !
876      !
877      zztmp = 0.5_wp * rau0 * rcp 
878      IF( iom_use('ueiv_heattr') .OR. iom_use('ueiv_heattr3d') ) THEN
879        zw2d(:,:)   = 0._wp 
880        zw3d(:,:,:) = 0._wp 
881        DO jk = 1, jpkm1
882           DO jj = 2, jpjm1
883              DO ji = fs_2, fs_jpim1   ! vector opt.
884                 zw3d(ji,jj,jk) = zw3d(ji,jj,jk) + ( psi_uw(ji,jj,jk+1)      - psi_uw(ji,jj,jk)          )   &
885                    &                            * ( tsn   (ji,jj,jk,jp_tem) + tsn   (ji+1,jj,jk,jp_tem) ) 
886                 zw2d(ji,jj) = zw2d(ji,jj) + zw3d(ji,jj,jk)
887              END DO
888           END DO
889        END DO
890        CALL lbc_lnk( 'ldftra', zw2d, 'U', -1. )
891        CALL lbc_lnk( 'ldftra', zw3d, 'U', -1. )
892        CALL iom_put( "ueiv_heattr"  , zztmp * zw2d )                  ! heat transport in i-direction
893        CALL iom_put( "ueiv_heattr3d", zztmp * zw3d )                  ! heat transport in i-direction
894      ENDIF
895      zw2d(:,:)   = 0._wp 
896      zw3d(:,:,:) = 0._wp 
897      DO jk = 1, jpkm1
898         DO jj = 2, jpjm1
899            DO ji = fs_2, fs_jpim1   ! vector opt.
900               zw3d(ji,jj,jk) = zw3d(ji,jj,jk) + ( psi_vw(ji,jj,jk+1)      - psi_vw(ji,jj,jk)          )   &
901                  &                            * ( tsn   (ji,jj,jk,jp_tem) + tsn   (ji,jj+1,jk,jp_tem) ) 
902               zw2d(ji,jj) = zw2d(ji,jj) + zw3d(ji,jj,jk)
903            END DO
904         END DO
905      END DO
906      CALL lbc_lnk( 'ldftra', zw2d, 'V', -1. )
907      CALL iom_put( "veiv_heattr", zztmp * zw2d )                  !  heat transport in j-direction
908      CALL iom_put( "veiv_heattr", zztmp * zw3d )                  !  heat transport in j-direction
909      !
910      IF( ln_diaptr )  CALL dia_ptr_hst( jp_tem, 'eiv', 0.5 * zw3d )
911      !
912      zztmp = 0.5_wp * 0.5
913      IF( iom_use('ueiv_salttr') .OR. iom_use('ueiv_salttr3d')) THEN
914        zw2d(:,:) = 0._wp 
915        zw3d(:,:,:) = 0._wp 
916        DO jk = 1, jpkm1
917           DO jj = 2, jpjm1
918              DO ji = fs_2, fs_jpim1   ! vector opt.
919                 zw3d(ji,jj,jk) = zw3d(ji,jj,jk) * ( psi_uw(ji,jj,jk+1)      - psi_uw(ji,jj,jk)          )   &
920                    &                            * ( tsn   (ji,jj,jk,jp_sal) + tsn   (ji+1,jj,jk,jp_sal) ) 
921                 zw2d(ji,jj) = zw2d(ji,jj) + zw3d(ji,jj,jk)
922              END DO
923           END DO
924        END DO
925        CALL lbc_lnk( 'ldftra', zw2d, 'U', -1. )
926        CALL lbc_lnk( 'ldftra', zw3d, 'U', -1. )
927        CALL iom_put( "ueiv_salttr", zztmp * zw2d )                  ! salt transport in i-direction
928        CALL iom_put( "ueiv_salttr3d", zztmp * zw3d )                  ! salt transport in i-direction
929      ENDIF
930      zw2d(:,:) = 0._wp 
931      zw3d(:,:,:) = 0._wp 
932      DO jk = 1, jpkm1
933         DO jj = 2, jpjm1
934            DO ji = fs_2, fs_jpim1   ! vector opt.
935               zw3d(ji,jj,jk) = zw3d(ji,jj,jk) + ( psi_vw(ji,jj,jk+1)      - psi_vw(ji,jj,jk)          )   &
936                  &                            * ( tsn   (ji,jj,jk,jp_sal) + tsn   (ji,jj+1,jk,jp_sal) ) 
937               zw2d(ji,jj) = zw2d(ji,jj) + zw3d(ji,jj,jk)
938            END DO
939         END DO
940      END DO
941      CALL lbc_lnk( 'ldftra', zw2d, 'V', -1. )
942      CALL iom_put( "veiv_salttr", zztmp * zw2d )                  !  salt transport in j-direction
943      CALL iom_put( "veiv_salttr", zztmp * zw3d )                  !  salt transport in j-direction
944      !
945      IF( ln_diaptr ) CALL dia_ptr_hst( jp_sal, 'eiv', 0.5 * zw3d )
946      !
947      !
948   END SUBROUTINE ldf_eiv_dia
949
950   !!======================================================================
951END MODULE ldftra
Note: See TracBrowser for help on using the repository browser.