source: NEMO/branches/UKMO/NEMO_4.0.1_biharmonic_GM/src/OCE/LDF/ldfdyn.F90 @ 12691

Last change on this file since 12691 was 12691, checked in by davestorkey, 8 months ago

UKMO/NEMO_4.0.1_biharmonic_GM : stabilising correction terms

File size: 41.7 KB
Line 
1MODULE ldfdyn
2   !!======================================================================
3   !!                       ***  MODULE  ldfdyn  ***
4   !! Ocean physics:  lateral viscosity coefficient
5   !!=====================================================================
6   !! History :  OPA  ! 1997-07  (G. Madec)  multi dimensional coefficients
7   !!   NEMO     1.0  ! 2002-09  (G. Madec)  F90: Free form and module
8   !!            3.7  ! 2014-01  (F. Lemarie, G. Madec)  restructuration/simplification of ahm specification,
9   !!                 !                                  add velocity dependent coefficient and optional read in file
10   !!            4.0  ! 2020-02  (C. Wilson, ...) add bhm coefficient for bi-Laplacian GM implementation via momentum     
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   ldf_dyn_init  : initialization, namelist read, and parameters control
15   !!   ldf_dyn       : update lateral eddy viscosity coefficients at each time step
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers   
18   USE dom_oce         ! ocean space and time domain
19   USE phycst          ! physical constants
20   USE ldfslp          ! lateral diffusion: slopes of mixing orientation
21   USE ldfc1d_c2d      ! lateral diffusion: 1D and 2D cases
22   !
23   USE in_out_manager  ! I/O manager
24   USE iom             ! I/O module for ehanced bottom friction file
25   USE timing          ! Timing
26   USE lib_mpp         ! distribued memory computing library
27   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   ldf_dyn_init   ! called by nemogcm.F90
33   PUBLIC   ldf_dyn        ! called by step.F90
34
35   !                                    !!* Namelist namdyn_ldf : lateral mixing on momentum *
36   LOGICAL , PUBLIC ::   ln_dynldf_OFF   !: No operator (i.e. no explicit diffusion)
37   LOGICAL , PUBLIC ::   ln_dynldf_lap   !: laplacian operator
38   LOGICAL , PUBLIC ::   ln_dynldf_bgm   !: bi-Laplacian GM implementation via momentum
39   LOGICAL , PUBLIC ::   ln_dynldf_blp   !: bilaplacian operator
40   LOGICAL , PUBLIC ::   ln_dynldf_lev   !: iso-level direction
41   LOGICAL , PUBLIC ::   ln_dynldf_hor   !: horizontal (geopotential) direction
42!  LOGICAL , PUBLIC ::   ln_dynldf_iso   !: iso-neutral direction                        (see ldfslp)
43   INTEGER , PUBLIC ::   nn_ahm_ijk_t    !: choice of time & space variations of the lateral eddy viscosity coef.
44   !                                        !  time invariant coefficients:  aht = 1/2  Ud*Ld   (lap case)
45   !                                           !                             bht = 1/12 Ud*Ld^3 (blp case)
46   INTEGER , PUBLIC ::   nn_bhm_ijk_t    !: choice of time & space variations of the lateral bi-Laplacian GM coef.
47   REAL(wp), PUBLIC ::   rn_Uv                 !: lateral viscous velocity  [m/s]
48   REAL(wp), PUBLIC ::   rn_Lv                 !: lateral viscous length    [m]
49   !                                        ! Smagorinsky viscosity  (nn_ahm_ijk_t = 32)
50   REAL(wp), PUBLIC ::   rn_csmc               !: Smagorinsky constant of proportionality
51   REAL(wp), PUBLIC ::   rn_minfac             !: Multiplicative factor of theorectical minimum Smagorinsky viscosity
52   REAL(wp), PUBLIC ::   rn_maxfac             !: Multiplicative factor of theorectical maximum Smagorinsky viscosity
53   !                                        ! iso-neutral laplacian (ln_dynldf_lap=ln_dynldf_iso=T)
54   REAL(wp), PUBLIC ::   rn_ahm_b              !: lateral laplacian background eddy viscosity  [m2/s]
55   REAL(wp), PUBLIC ::   rn_bhm_b              !: lateral bi-Laplacian GM background eddy viscosity  [m4/s]
56   REAL(wp), PUBLIC ::   rn_bgmzcrit           !: critical depth (>=0) for linear tapering of bi-Lap. GM coef. to zero at surface [m]
57   !                                    !!* Parameter to control the type of lateral viscous operator
58   INTEGER, PARAMETER, PUBLIC ::   np_ERROR  =-10                       !: error in setting the operator
59   INTEGER, PARAMETER, PUBLIC ::   np_no_ldf = 00                       !: without operator (i.e. no lateral viscous trend)
60   !                          !!      laplacian     !    bilaplacian    !
61   INTEGER, PARAMETER, PUBLIC ::   np_lap    = 10   ,   np_blp    = 20  !: iso-level operator
62   INTEGER, PARAMETER, PUBLIC ::   np_lap_i  = 11                       !: iso-neutral or geopotential operator
63   INTEGER, PARAMETER, PUBLIC ::   np_bgm    = 30                       !: iso-level operator, bi-Laplacian GM
64   INTEGER           , PUBLIC ::   nldf_dyn         !: type of lateral diffusion used defined from ln_dynldf_... (namlist logicals)
65   LOGICAL           , PUBLIC ::   l_ldfdyn_time    !: flag for time variation of the lateral eddy viscosity coef.
66
67   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   ahmt, ahmf   !: eddy viscosity coef. at T- and F-points [m2/s or m4/s]
68   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   bhm          !: eddy viscosity coef. for bi-Laplacian GM at W-points (cf. avm) [m4/s]
69   REAL(wp),         ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   dtensq       !: horizontal tension squared         (Smagorinsky only)
70   REAL(wp),         ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   dshesq       !: horizontal shearing strain squared (Smagorinsky only)
71   REAL(wp),         ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   esqt, esqf   !: Square of the local gridscale (e1e2/(e1+e2))**2           
72
73   REAL(wp) ::   r1_2    = 0.5_wp            ! =1/2
74   REAL(wp) ::   r1_4    = 0.25_wp           ! =1/4
75   REAL(wp) ::   r1_8    = 0.125_wp          ! =1/8
76   REAL(wp) ::   r1_12   = 1._wp / 12._wp    ! =1/12
77   REAL(wp) ::   r1_288  = 1._wp / 288._wp   ! =1/( 12^2 * 2 )
78
79   !! * Substitutions
80#  include "vectopt_loop_substitute.h90"
81   !!----------------------------------------------------------------------
82   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
83   !! $Id: ldfdyn.F90 11653 2019-10-04 12:34:02Z davestorkey $
84   !! Software governed by the CeCILL license (see ./LICENSE)
85   !!----------------------------------------------------------------------
86CONTAINS
87
88   SUBROUTINE ldf_dyn_init
89      !!----------------------------------------------------------------------
90      !!                  ***  ROUTINE ldf_dyn_init  ***
91      !!                   
92      !! ** Purpose :   set the horizontal ocean dynamics physics
93      !!
94      !! ** Method  :   the eddy viscosity coef. specification depends on:
95      !!              - the operator:
96      !!             ln_dynldf_lap = T     laplacian operator
97      !!             ln_dynldf_blp = T   bilaplacian operator
98      !!             ln_dynldf_bgm = T   bi-Laplacian GM operator
99      !!              - the parameter nn_ahm_ijk_t:
100      !!    nn_ahm_ijk_t  =  0 => = constant
101      !!                  = 10 => = F(z) :     = constant with a reduction of 1/4 with depth
102      !!                  =-20 => = F(i,j)     = shape read in 'eddy_viscosity.nc' file
103      !!                  = 20    = F(i,j)     = F(e1,e2) or F(e1^3,e2^3) (lap or bilap case)
104      !!                  =-30 => = F(i,j,k)   = shape read in 'eddy_viscosity.nc'  file
105      !!                  = 30    = F(i,j,k)   = 2D (case 20) + decrease with depth (case 10)
106      !!                  = 31    = F(i,j,k,t) = F(local velocity) (  |u|e  /12   laplacian operator
107      !!                                                           or |u|e^3/12 bilaplacian operator )
108      !!                  = 32    = F(i,j,k,t) = F(local deformation rate and gridscale) (D and L) (Smagorinsky) 
109      !!                                                           (   L^2|D|      laplacian operator
110      !!                                                           or  L^4|D|/8  bilaplacian operator )
111      !!                - the parameter nn_bhm_ijk_t:
112      !!    nn_bhm_ijk_t  = 11 => = F(z) :     = constant, with BCs set to zero at top and bottom
113      !!    nn_bhm_ijk_t  = 12 => = F(z) :     = constant in interior, linear taper to zero at surface,
114      !!                                         for depths < rn_bgmzcrit, with BCs set to zero at top and bottom
115      !!    nn_bhm_ijk_t  = 13 => = F(z) :     = bhm0 X dx^2 X dz^2, with BCs set to zero at top and bottom
116      !!----------------------------------------------------------------------
117      INTEGER  ::   ji, jj, jk                     ! dummy loop indices
118      INTEGER  ::   ioptio, ierr, inum, ios, inn   ! local integer
119      INTEGER  ::   ikw                            ! local integer
120      REAL(wp) ::   zah0, zah_max, zUfac           ! local scalar
121      REAL(wp) ::   bhm0, lhscrit, lhscritmax      ! local scalar
122      CHARACTER(len=5) ::   cl_Units               ! units (m2/s or m4/s)
123      !!
124      NAMELIST/namdyn_ldf/ ln_dynldf_OFF, ln_dynldf_lap, ln_dynldf_blp,   &   ! type of operator
125         &                 ln_dynldf_bgm,                                 &   ! type of operator
126         &                 ln_dynldf_lev, ln_dynldf_hor, ln_dynldf_iso,   &   ! acting direction of the operator
127         &                 nn_ahm_ijk_t , rn_Uv    , rn_Lv,   rn_ahm_b,   &   ! lateral eddy coefficient
128         &                 nn_bhm_ijk_t, rn_bhm_b, rn_bgmzcrit,           &   ! lateral bi-Lap. GM coefficient
129         &                 rn_csmc      , rn_minfac    , rn_maxfac            ! Smagorinsky settings
130      !!----------------------------------------------------------------------
131      !
132      REWIND( numnam_ref )              ! Namelist namdyn_ldf in reference namelist : Lateral physics
133      READ  ( numnam_ref, namdyn_ldf, IOSTAT = ios, ERR = 901)
134901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_ldf in reference namelist' )
135
136      REWIND( numnam_cfg )              ! Namelist namdyn_ldf in configuration namelist : Lateral physics
137      READ  ( numnam_cfg, namdyn_ldf, IOSTAT = ios, ERR = 902 )
138902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdyn_ldf in configuration namelist' )
139      IF(lwm) WRITE ( numond, namdyn_ldf )
140
141      IF(lwp) THEN                      ! Parameter print
142         WRITE(numout,*)
143         WRITE(numout,*) 'ldf_dyn : lateral momentum physics'
144         WRITE(numout,*) '~~~~~~~'
145         WRITE(numout,*) '   Namelist namdyn_ldf : set lateral mixing parameters'
146         !
147         WRITE(numout,*) '      type :'
148         WRITE(numout,*) '         no explicit diffusion                ln_dynldf_OFF = ', ln_dynldf_OFF
149         WRITE(numout,*) '         laplacian operator                   ln_dynldf_lap = ', ln_dynldf_lap
150         WRITE(numout,*) '         bilaplacian operator                 ln_dynldf_blp = ', ln_dynldf_blp
151         WRITE(numout,*) '         bi-Laplacian GM operator             ln_dynldf_bgm = ', ln_dynldf_bgm
152         WRITE(numout,*) '         critical depth for taper (if used)   rn_bgmzcrit   = ', rn_bgmzcrit
153         !
154         WRITE(numout,*) '      direction of action :'
155         WRITE(numout,*) '         iso-level                            ln_dynldf_lev = ', ln_dynldf_lev
156         WRITE(numout,*) '         horizontal (geopotential)            ln_dynldf_hor = ', ln_dynldf_hor
157         WRITE(numout,*) '         iso-neutral                          ln_dynldf_iso = ', ln_dynldf_iso
158         !
159         WRITE(numout,*) '      coefficients :'
160         WRITE(numout,*) '         type of time-space variation         nn_ahm_ijk_t  = ', nn_ahm_ijk_t
161         WRITE(numout,*) '         lateral viscous velocity  (if cst)      rn_Uv      = ', rn_Uv, ' m/s'
162         WRITE(numout,*) '         lateral viscous length    (if cst)      rn_Lv      = ', rn_Lv, ' m'
163         WRITE(numout,*) '         background viscosity (iso-lap case)     rn_ahm_b   = ', rn_ahm_b, ' m2/s'
164         WRITE(numout,*) '         bi-Laplacian GM background viscosity    rn_bhm_b   = ', rn_bhm_b, ' m4/s'
165         WRITE(numout,*) '      Smagorinsky settings (nn_ahm_ijk_t  = 32) :'
166         WRITE(numout,*) '         Smagorinsky coefficient              rn_csmc       = ', rn_csmc
167         WRITE(numout,*) '         factor multiplier for eddy visc.'
168         WRITE(numout,*) '            lower limit (default 1.0)         rn_minfac    = ', rn_minfac
169         WRITE(numout,*) '            upper limit (default 1.0)         rn_maxfac    = ', rn_maxfac
170      ENDIF
171
172      !
173      !           !==  type of lateral operator used  ==!   (set nldf_dyn)
174      !           !=====================================!
175      !
176      nldf_dyn = np_ERROR
177      ioptio = 0
178      !CW exclude combination of lap+blp (as in existing code), but allow other combinations
179      IF( ln_dynldf_OFF ) THEN   ;   nldf_dyn = np_no_ldf   ;   ioptio = ioptio + 1   ;   ENDIF
180      IF( ln_dynldf_lap ) THEN   ;                              ioptio = ioptio + 5   ;   ENDIF
181      IF( ln_dynldf_blp ) THEN   ;                              ioptio = ioptio + 5   ;   ENDIF
182      IF( ln_dynldf_bgm ) THEN   ;                              ioptio = ioptio + 1   ;   ENDIF
183      !
184      IF( (ioptio < 1).OR.(ioptio > 6) )   CALL ctl_stop( 'dyn_ldf_init: use at least ONE of the 4 operator options (NONE/lap/blp/bgm) but not (lap+blp)' )
185      !
186
187      IF(.NOT.ln_dynldf_OFF ) THEN     !==  direction ==>> type of operator  ==!
188         ioptio = 0
189         IF( ln_dynldf_lev )   ioptio = ioptio + 1
190         IF( ln_dynldf_hor )   ioptio = ioptio + 1
191         IF( ln_dynldf_iso )   ioptio = ioptio + 1
192         IF( ioptio /= 1   )   CALL ctl_stop( 'dyn_ldf_init: use ONE of the 3 direction options (level/hor/iso)' )
193         !
194         !                             ! Set nldf_dyn, the type of lateral diffusion, from ln_dynldf_... logicals
195         ierr = 0
196         IF( ln_dynldf_lap ) THEN         ! laplacian operator
197            IF( ln_zco ) THEN                   ! z-coordinate
198               IF ( ln_dynldf_lev )   nldf_dyn = np_lap     ! iso-level = horizontal (no rotation)
199               IF ( ln_dynldf_hor )   nldf_dyn = np_lap     ! iso-level = horizontal (no rotation)
200               IF ( ln_dynldf_iso )   nldf_dyn = np_lap_i   ! iso-neutral            (   rotation)
201            ENDIF
202            IF( ln_zps ) THEN                   ! z-coordinate with partial step
203               IF ( ln_dynldf_lev )   nldf_dyn = np_lap     ! iso-level              (no rotation)
204               IF ( ln_dynldf_hor )   nldf_dyn = np_lap     ! iso-level              (no rotation)
205               IF ( ln_dynldf_iso )   nldf_dyn = np_lap_i   ! iso-neutral            (   rotation)
206            ENDIF
207            IF( ln_sco ) THEN                   ! s-coordinate
208               IF ( ln_dynldf_lev )   nldf_dyn = np_lap     ! iso-level = horizontal (no rotation)
209               IF ( ln_dynldf_hor )   nldf_dyn = np_lap_i   ! horizontal             (   rotation)
210               IF ( ln_dynldf_iso )   nldf_dyn = np_lap_i   ! iso-neutral            (   rotation)
211            ENDIF
212         ENDIF
213         !
214         IF( ln_dynldf_blp ) THEN         ! bilaplacian operator
215            IF( ln_zco ) THEN                   ! z-coordinate
216               IF( ln_dynldf_lev )   nldf_dyn = np_blp   ! iso-level = horizontal (no rotation)
217               IF( ln_dynldf_hor )   nldf_dyn = np_blp   ! iso-level = horizontal (no rotation)
218               IF( ln_dynldf_iso )   ierr = 2            ! iso-neutral            (   rotation)
219            ENDIF
220            IF( ln_zps ) THEN                   ! z-coordinate with partial step
221               IF( ln_dynldf_lev )   nldf_dyn = np_blp   ! iso-level              (no rotation)
222               IF( ln_dynldf_hor )   nldf_dyn = np_blp   ! iso-level              (no rotation)
223               IF( ln_dynldf_iso )   ierr = 2            ! iso-neutral            (   rotation)
224            ENDIF
225            IF( ln_sco ) THEN                   ! s-coordinate
226               IF( ln_dynldf_lev )   nldf_dyn = np_blp   ! iso-level              (no rotation)
227               IF( ln_dynldf_hor )   ierr = 2            ! horizontal             (   rotation)
228               IF( ln_dynldf_iso )   ierr = 2            ! iso-neutral            (   rotation)
229            ENDIF
230         ENDIF
231         !
232         IF( ln_dynldf_bgm ) THEN         ! bi-Laplacian GM operator
233            IF( ln_zco ) THEN                   ! z-coordinate
234               IF( ln_dynldf_lev )   nldf_dyn = np_bgm   ! iso-level = horizontal (no rotation)
235               IF( ln_dynldf_hor )   nldf_dyn = np_bgm   ! iso-level = horizontal (no rotation)
236               IF( ln_dynldf_iso )   ierr = 3            ! iso-neutral            (   rotation)
237            ENDIF
238            IF( ln_zps ) THEN                   ! z-coordinate with partial step
239               IF( ln_dynldf_lev )   nldf_dyn = np_bgm   ! iso-level              (no rotation)
240               IF( ln_dynldf_hor )   nldf_dyn = np_bgm   ! iso-level              (no rotation)
241               IF( ln_dynldf_iso )   ierr = 3            ! iso-neutral            (   rotation)
242            ENDIF
243            IF( ln_sco ) THEN                   ! s-coordinate
244               IF( ln_dynldf_lev )   nldf_dyn = np_bgm   ! iso-level              (no rotation)
245               IF( ln_dynldf_hor )   ierr = 3            ! horizontal             (   rotation)
246               IF( ln_dynldf_iso )   ierr = 3            ! iso-neutral            (   rotation)
247            ENDIF
248         ENDIF
249         !         
250
251         IF( ierr == 2 )   CALL ctl_stop( 'rotated bi-laplacian operator does not exist' )
252         !
253         IF( ierr == 3 )   CALL ctl_stop( 'rotated bi-Laplacian GM operator does not exist' )
254         !
255
256         IF( nldf_dyn == np_lap_i )   l_ldfslp = .TRUE.  ! rotation require the computation of the slopes
257         !
258      ENDIF
259      !
260      IF(lwp) THEN
261         WRITE(numout,*)
262         SELECT CASE( nldf_dyn )
263         CASE( np_no_ldf )   ;   WRITE(numout,*) '   ==>>>   NO lateral viscosity'
264         CASE( np_lap    )   ;   WRITE(numout,*) '   ==>>>   iso-level laplacian operator'
265         CASE( np_lap_i  )   ;   WRITE(numout,*) '   ==>>>   rotated laplacian operator with iso-level background'
266         CASE( np_blp    )   ;   WRITE(numout,*) '   ==>>>   iso-level bi-laplacian operator'
267         CASE( np_bgm    )   ;   WRITE(numout,*) '   ==>>>   iso-level bi-Laplacian GM operator'
268         END SELECT
269         WRITE(numout,*)
270      ENDIF
271     
272      !
273      !           !==  Space/time variation of eddy coefficients  ==!
274      !           !=================================================!
275      !
276      l_ldfdyn_time = .FALSE.                ! no time variation except in case defined below
277      !
278      IF( ln_dynldf_OFF ) THEN
279         !CW
280         !IF(lwp) WRITE(numout,*) '   ==>>>   No viscous operator selected. ahmt and ahmf are not allocated'
281         IF(lwp) WRITE(numout,*) '   ==>>>   No viscous operator selected. ahmt, ahmf, bhm are not allocated'
282         !
283         RETURN
284         !
285      ELSE                                   !==  a lateral diffusion operator is used  ==!
286         !
287         !                                         ! allocate the ahm arrays
288         ALLOCATE( ahmt(jpi,jpj,jpk) , ahmf(jpi,jpj,jpk) , bhm(jpi,jpj,jpk) , STAT=ierr )
289         !
290         IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'ldf_dyn_init: failed to allocate arrays')
291         !
292         ahmt(:,:,:) = 0._wp                       ! init to 0 needed
293         ahmf(:,:,:) = 0._wp
294         bhm(:,:,:)  = 0._wp                       ! init to 0 needed
295         !                                        ! value of lap/blp eddy mixing coef.
296         IF(     ln_dynldf_lap ) THEN   ;   zUfac = r1_2 *rn_Uv   ;   inn = 1   ;   cl_Units = ' m2/s'   !   laplacian
297         ELSEIF( ln_dynldf_blp ) THEN   ;   zUfac = r1_12*rn_Uv   ;   inn = 3   ;   cl_Units = ' m4/s'   ! bilaplacian
298         ELSEIF( ln_dynldf_bgm ) THEN   ;   bhm0 = rn_bhm_b       ;             ;   cl_Units = ' m4/s'   ! bi-Laplacian GM
299         ENDIF
300         zah0    = zUfac *    rn_Lv**inn              ! mixing coefficient
301         zah_max = zUfac * (ra*rad)**inn              ! maximum reachable coefficient (value at the Equator)
302         !
303         SELECT CASE(  nn_ahm_ijk_t  )             !* Specification of space-time variations of ahmt, ahmf
304         !
305         CASE(   0  )      !==  constant  ==!
306            IF(lwp) WRITE(numout,*) '   ==>>>   eddy viscosity. = constant = ', zah0, cl_Units
307            ahmt(:,:,1:jpkm1) = zah0
308            ahmf(:,:,1:jpkm1) = zah0
309            !
310         CASE(  10  )      !==  fixed profile  ==!
311            IF(lwp) WRITE(numout,*) '   ==>>>   eddy viscosity = F( depth )'
312            IF(lwp) WRITE(numout,*) '           surface viscous coef. = constant = ', zah0, cl_Units
313            ahmt(:,:,1) = zah0                        ! constant surface value
314            ahmf(:,:,1) = zah0
315            CALL ldf_c1d( 'DYN', ahmt(:,:,1), ahmf(:,:,1), ahmt, ahmf )
316            !       
317         CASE ( -20 )      !== fixed horizontal shape read in file  ==!
318            IF(lwp) WRITE(numout,*) '   ==>>>   eddy viscosity = F(i,j) read in eddy_viscosity.nc file'
319            CALL iom_open( 'eddy_viscosity_2D.nc', inum )
320            CALL iom_get ( inum, jpdom_data, 'ahmt_2d', ahmt(:,:,1) )
321            CALL iom_get ( inum, jpdom_data, 'ahmf_2d', ahmf(:,:,1) )
322            CALL iom_close( inum )
323            DO jk = 2, jpkm1
324               ahmt(:,:,jk) = ahmt(:,:,1)
325               ahmf(:,:,jk) = ahmf(:,:,1)
326            END DO
327            !
328         CASE(  20  )      !== fixed horizontal shape  ==!
329            IF(lwp) WRITE(numout,*) '   ==>>>   eddy viscosity = F( e1, e2 ) or F( e1^3, e2^3 ) (lap. or blp. case)'
330            IF(lwp) WRITE(numout,*) '           using a fixed viscous velocity = ', rn_Uv  ,' m/s   and   Lv = Max(e1,e2)'
331            IF(lwp) WRITE(numout,*) '           maximum reachable coefficient (at the Equator) = ', zah_max, cl_Units, '  for e1=1°)'
332            CALL ldf_c2d( 'DYN', zUfac      , inn        , ahmt, ahmf )         ! surface value proportional to scale factor^inn
333            !
334         CASE( -30  )      !== fixed 3D shape read in file  ==!
335            IF(lwp) WRITE(numout,*) '   ==>>>   eddy viscosity = F(i,j,k) read in eddy_viscosity_3D.nc file'
336            CALL iom_open( 'eddy_viscosity_3D.nc', inum )
337            CALL iom_get ( inum, jpdom_data, 'ahmt_3d', ahmt )
338            CALL iom_get ( inum, jpdom_data, 'ahmf_3d', ahmf )
339            CALL iom_close( inum )
340            !
341         CASE(  30  )       !==  fixed 3D shape  ==!
342            IF(lwp) WRITE(numout,*) '   ==>>>   eddy viscosity = F( latitude, longitude, depth )'
343            IF(lwp) WRITE(numout,*) '           using a fixed viscous velocity = ', rn_Uv  ,' m/s   and   Ld = Max(e1,e2)'
344            IF(lwp) WRITE(numout,*) '           maximum reachable coefficient (at the Equator) = ', zah_max, cl_Units, '  for e1=1°)'
345            CALL ldf_c2d( 'DYN', zUfac      , inn        , ahmt, ahmf )         ! surface value proportional to scale factor^inn
346            CALL ldf_c1d( 'DYN', ahmt(:,:,1), ahmf(:,:,1), ahmt, ahmf )  ! reduction with depth
347            !
348         CASE(  31  )       !==  time varying 3D field  ==!
349            IF(lwp) WRITE(numout,*) '   ==>>>   eddy viscosity = F( latitude, longitude, depth , time )'
350            IF(lwp) WRITE(numout,*) '           proportional to the local velocity : 1/2 |u|e (lap) or 1/12 |u|e^3 (blp)'
351            !
352            l_ldfdyn_time = .TRUE.     ! will be calculated by call to ldf_dyn routine in step.F90
353            !
354         CASE(  32  )       !==  time varying 3D field  ==!
355            IF(lwp) WRITE(numout,*) '   ==>>>   eddy viscosity = F( latitude, longitude, depth , time )'
356            IF(lwp) WRITE(numout,*) '           proportional to the local deformation rate and gridscale (Smagorinsky)'
357            !
358            l_ldfdyn_time = .TRUE.     ! will be calculated by call to ldf_dyn routine in step.F90
359            !
360            !                          ! allocate arrays used in ldf_dyn.
361            ALLOCATE( dtensq(jpi,jpj,jpk) , dshesq(jpi,jpj,jpk) , esqt(jpi,jpj) , esqf(jpi,jpj) , STAT=ierr )
362            IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'ldf_dyn_init: failed to allocate Smagorinsky arrays')
363            !
364            DO jj = 1, jpj             ! Set local gridscale values
365               DO ji = 1, jpi
366                  esqt(ji,jj) = ( 2._wp * e1e2t(ji,jj) / ( e1t(ji,jj) + e2t(ji,jj) ) )**2 
367                  esqf(ji,jj) = ( 2._wp * e1e2f(ji,jj) / ( e1f(ji,jj) + e2f(ji,jj) ) )**2 
368               END DO
369            END DO
370            !
371         CASE DEFAULT
372            CALL ctl_stop('ldf_dyn_init: wrong choice for nn_ahm_ijk_t, the type of space-time variation of ahm')
373         END SELECT
374!CW      Add separate structure options for bi-Laplacian GM, to allow it to be used in combination with other types of diffusion, above.
375
376         IF( ln_dynldf_bgm ) THEN
377            SELECT CASE (nn_bhm_ijk_t)
378               !CW Define bi-Laplacian GM diffusivity and test the related computational stability criterion   
379
380            CASE(  11  )      !==  fixed profile: constant except for zero at top and bottom, so that eddy-induced velocity, w*=0  ==!
381               IF(lwp) WRITE(numout,*) '   ==>>>   bi-Laplacian GM eddy viscosity = constant in interior, zero at top and bottom'
382               IF(lwp) WRITE(numout,*) '           interior viscous coef. = constant = ', bhm0, cl_Units
383
384               !     First set to constant in interior, all levels
385               DO jj = 2, jpjm1
386                  DO ji = 2, jpim1
387                     bhm(ji,jj,:) = bhm0
388                  ENDDO
389               ENDDO
390
391               !     Surface BC : set to zero
392               bhm(:,:,1)   = 0._wp
393               !     Flat bottom BC : set to zero
394               bhm(:,:,jpk) = 0._wp 
395               !     Variable bathymetry case: diffusive fluxes masked in dyn_ldf_bgm
396
397               !CW Test criterion for two grid-length mode for BGM scheme with leapfrog timestepping
398               ! \frac{{\kappa \Delta t}{(\Delta z)^2 (\Delta x)^2}< 1/32
399               ! test at T-point - may need to revise this choice!!!!
400
401               ! Find domain maximum value of LHS, then test inequality.
402
403               ! initialise
404               lhscritmax=0._wp
405
406               DO jj = 2, jpjm1
407                  DO ji = 2, jpim1
408                     ikw = mbkt(ji,jj) !bottom last wet T-level
409                     DO jk = 2, ikw
410                        lhscrit=bhm0*rdt/(e3t_n(ji,jj,jk)**2*e1t(ji,jj)**2)
411                        IF(lhscrit .gt. lhscritmax) lhscritmax=lhscrit
412                     ENDDO
413                  ENDDO
414               ENDDO
415
416               IF ( lhscrit .ge. 1._wp/32._wp) THEN
417                  IF(lwp) THEN
418                     WRITE(numout,*)
419                     WRITE(numout,*) ' WARNING : Bi-Laplacian GM eddy viscosity is not',              &
420                          &            ' consistent with the model time step and grid setup: ', &
421                          &            ' LHS=',lhscrit, & 
422                          &            'Should be < 0.03125 in order to avoid computational instability (Mike Bell, Dave Storkey)'
423                     WRITE(numout,*) ' ========='
424                     WRITE(numout,*)
425                  ENDIF
426                  ! CW: warn, don't stop, as we may wish to violate this theoretical limit.
427                  ! CALL ctl_stop( 'ldf_dyn_init', 'Inconsistent Bi-Lap. GM diffusivity')
428               ELSE
429                  IF(lwp) THEN
430                     WRITE(numout,*)
431                     WRITE(numout,*) ' INFORMATION : Bi-Laplacian GM eddy viscosity is ',              &
432                          &            ' consistent with the model time step and grid setup: ', &
433                          &            ' LHS=',lhscrit, & 
434                          &            'Should be < 0.03125 in order to avoid computational instability (Mike Bell, Dave Storkey)'
435                     WRITE(numout,*) ' ========='
436                     WRITE(numout,*)
437                  ENDIF
438               ENDIF
439               !-----------------------------
440            CASE(  12  )      !==  fixed profile: constant in interior, zero at bottom and linearly-tapering to zero at top, over depth shallower than rn_bgmzcrit  ==!
441               IF(lwp) WRITE(numout,*) '   ==>>>   bi-Laplacian GM eddy viscosity = constant in interior, zero at bottom and'
442               IF(lwp) WRITE(numout,*) '           linearly-tapering to zero at top, over depth shallower than ', rn_bgmzcrit, ' metres.'
443               IF(lwp) WRITE(numout,*) '           Interior viscous coef. = constant = ', bhm0, cl_Units
444
445               !     Impose linear taper from interior value to zero at zero depth, for depths < rn_bgmzcrit
446               !     N.B. Test criterion for two grid-length mode for BGM scheme with leapfrog timestepping not implemented for this case yet.
447
448               DO jk = 1, jpk
449
450                  IF (gdept_1d(jk) .lt. rn_bgmzcrit) THEN
451
452                     DO jj = 2, jpjm1
453                        DO ji = 2, jpim1
454                           bhm(ji,jj,jk) = bhm0 * gdepw_1d(jk)/rn_bgmzcrit
455                        ENDDO
456                     ENDDO
457
458                  ELSE
459
460                     ! constant at depth rn_bgmzcrit and larger
461                     DO jj = 2, jpjm1
462                        DO ji = 2, jpim1
463                           bhm(ji,jj,jk) = bhm0
464                        ENDDO
465                     ENDDO
466
467                  ENDIF
468
469               ENDDO
470
471               !     Surface BC : set to zero
472               bhm(:,:,1)   = 0._wp 
473               !     Flat bottom BC : set to zero
474               bhm(:,:,jpk) = 0._wp 
475               !     Variable bathymetry case: diffusive fluxes masked in dyn_ldf_bgm
476
477               !--------------------------------
478            CASE(  13  )      !==  fixed profile: steady profile of the form bhm0 X dx^2 X dz^2 in interior, zero at bottom and top  ==!
479
480               cl_Units = ' 1/s'
481
482               IF(lwp) WRITE(numout,*) '   ==>>>   bi-Laplacian GM eddy viscosity : steady profile of the form'
483               IF(lwp) WRITE(numout,*) '           bhm0 X dx^2 X dz^2 in interior, zero boundary conds. at bottom and top.'
484               IF(lwp) WRITE(numout,*) '           In this case, bhm0 is the constant of proportionality,'
485               IF(lwp) WRITE(numout,*) '           dimensioned as [diffusivity]/L^4, i.e. bhm0=', bhm0, cl_Units
486
487               cl_Units = ' m4/s'
488
489               !     N.B. Test criterion for two grid-length mode for BGM scheme with leapfrog timestepping not implemented for this case yet.
490
491               DO jk = 1, jpk
492                  ! constant at depth rn_bgmzcrit and larger
493                  DO jj = 2, jpjm1
494                     DO ji = 2, jpim1
495                        bhm(ji,jj,jk) = bhm0*e1t(ji,jj)**2*e3w_n(ji,jj,jk)**2
496                     ENDDO
497                  ENDDO
498               ENDDO
499
500               !     Surface BC : set to zero
501               bhm(:,:,1)   = 0._wp 
502               !     Flat bottom BC : set to zero
503               bhm(:,:,jpk) = 0._wp 
504               !     Variable bathymetry case: diffusive fluxes masked in dyn_ldf_bgm
505
506               !--------------------------------
507
508            CASE DEFAULT
509               CALL ctl_stop('ldf_dyn_init: wrong choice for nn_bhm_ijk_t, the type of space-time variation of bhm')
510            END SELECT
511         ENDIF ! ln_dynldf_bgm
512         !
513         IF( .NOT.l_ldfdyn_time ) THEN             !* No time variation
514            IF(     ln_dynldf_lap ) THEN                 !   laplacian operator (mask only)
515               ahmt(:,:,1:jpkm1) =       ahmt(:,:,1:jpkm1)   * tmask(:,:,1:jpkm1)
516               ahmf(:,:,1:jpkm1) =       ahmf(:,:,1:jpkm1)   * fmask(:,:,1:jpkm1)
517            ELSEIF( ln_dynldf_blp ) THEN                 ! bilaplacian operator (square root + mask)
518               ahmt(:,:,1:jpkm1) = SQRT( ahmt(:,:,1:jpkm1) ) * tmask(:,:,1:jpkm1)
519               ahmf(:,:,1:jpkm1) = SQRT( ahmf(:,:,1:jpkm1) ) * fmask(:,:,1:jpkm1)
520               !CW
521            ELSEIF( ln_dynldf_bgm ) THEN                 !bi-Laplacian GM operator (mask only)
522               bhm(:,:,1:jpkm1) =       bhm(:,:,1:jpkm1)   * wmask(:,:,1:jpkm1)
523               CALL lbc_lnk( 'ldf_dyn_init', bhm , 'W', 1. ) 
524               !
525            ENDIF
526         ENDIF
527         !
528      ENDIF
529      !
530    END SUBROUTINE ldf_dyn_init
531
532
533    SUBROUTINE ldf_dyn( kt )
534      !!----------------------------------------------------------------------
535      !!                  ***  ROUTINE ldf_dyn  ***
536      !!
537      !! ** Purpose :   update at kt the momentum lateral mixing coeff. (ahmt and ahmf)
538      !!
539      !! ** Method  :   time varying eddy viscosity coefficients:
540      !!
541      !!    nn_ahm_ijk_t = 31    ahmt, ahmf = F(i,j,k,t) = F(local velocity)
542      !!                         ( |u|e /12  or  |u|e^3/12 for laplacian or bilaplacian operator )
543      !!
544      !!    nn_ahm_ijk_t = 32    ahmt, ahmf = F(i,j,k,t) = F(local deformation rate and gridscale) (D and L) (Smagorinsky) 
545      !!                         ( L^2|D|    or  L^4|D|/8  for laplacian or bilaplacian operator )
546      !!
547      !! ** note    :    in BLP cases the sqrt of the eddy coef is returned, since bilaplacian is en re-entrant laplacian
548      !! ** action  :    ahmt, ahmf   updated at each time step
549      !!----------------------------------------------------------------------
550      INTEGER, INTENT(in) ::   kt   ! time step index
551      !
552      INTEGER  ::   ji, jj, jk   ! dummy loop indices
553      REAL(wp) ::   zu2pv2_ij_p1, zu2pv2_ij, zu2pv2_ij_m1, zemax   ! local scalar (option 31)
554      REAL(wp) ::   zcmsmag, zstabf_lo, zstabf_up, zdelta, zdb     ! local scalar (option 32)
555      !!----------------------------------------------------------------------
556      !
557      IF( ln_timing )   CALL timing_start('ldf_dyn')
558      !
559      SELECT CASE(  nn_ahm_ijk_t  )       !== Eddy vicosity coefficients ==!
560         !
561      CASE(  31  )       !==  time varying 3D field  ==!   = F( local velocity )
562         !
563         IF( ln_dynldf_lap   ) THEN        ! laplacian operator : |u| e /12 = |u/144| e
564            DO jk = 1, jpkm1
565               DO jj = 2, jpjm1
566                  DO ji = fs_2, fs_jpim1
567                     zu2pv2_ij    = ub(ji  ,jj  ,jk) * ub(ji  ,jj  ,jk) + vb(ji  ,jj  ,jk) * vb(ji  ,jj  ,jk)
568                     zu2pv2_ij_m1 = ub(ji-1,jj  ,jk) * ub(ji-1,jj  ,jk) + vb(ji  ,jj-1,jk) * vb(ji  ,jj-1,jk)
569                     zemax = MAX( e1t(ji,jj) , e2t(ji,jj) )
570                     ahmt(ji,jj,jk) = SQRT( (zu2pv2_ij + zu2pv2_ij_m1) * r1_288 ) * zemax * tmask(ji,jj,jk)      ! 288= 12*12 * 2
571                  END DO
572               END DO
573               DO jj = 1, jpjm1
574                  DO ji = 1, fs_jpim1
575                     zu2pv2_ij_p1 = ub(ji  ,jj+1,jk) * ub(ji  ,jj+1,jk) + vb(ji+1,jj  ,jk) * vb(ji+1,jj  ,jk)
576                     zu2pv2_ij    = ub(ji  ,jj  ,jk) * ub(ji  ,jj  ,jk) + vb(ji  ,jj  ,jk) * vb(ji  ,jj  ,jk)
577                     zemax = MAX( e1f(ji,jj) , e2f(ji,jj) )
578                     ahmf(ji,jj,jk) = SQRT( (zu2pv2_ij + zu2pv2_ij_p1) * r1_288 ) * zemax * fmask(ji,jj,jk)      ! 288= 12*12 * 2
579                  END DO
580               END DO
581            END DO
582         ELSEIF( ln_dynldf_blp ) THEN      ! bilaplacian operator : sqrt( |u| e^3 /12 ) = sqrt( |u/144| e ) * e
583            DO jk = 1, jpkm1
584               DO jj = 2, jpjm1
585                  DO ji = fs_2, fs_jpim1
586                     zu2pv2_ij    = ub(ji  ,jj  ,jk) * ub(ji  ,jj  ,jk) + vb(ji  ,jj  ,jk) * vb(ji  ,jj  ,jk)
587                     zu2pv2_ij_m1 = ub(ji-1,jj  ,jk) * ub(ji-1,jj  ,jk) + vb(ji  ,jj-1,jk) * vb(ji  ,jj-1,jk)
588                     zemax = MAX( e1t(ji,jj) , e2t(ji,jj) )
589                     ahmt(ji,jj,jk) = SQRT(  SQRT( (zu2pv2_ij + zu2pv2_ij_m1) * r1_288 ) * zemax  ) * zemax * tmask(ji,jj,jk)
590                  END DO
591               END DO
592               DO jj = 1, jpjm1
593                  DO ji = 1, fs_jpim1
594                     zu2pv2_ij_p1 = ub(ji  ,jj+1,jk) * ub(ji  ,jj+1,jk) + vb(ji+1,jj  ,jk) * vb(ji+1,jj  ,jk)
595                     zu2pv2_ij    = ub(ji  ,jj  ,jk) * ub(ji  ,jj  ,jk) + vb(ji  ,jj  ,jk) * vb(ji  ,jj  ,jk)
596                     zemax = MAX( e1f(ji,jj) , e2f(ji,jj) )
597                     ahmf(ji,jj,jk) = SQRT(  SQRT( (zu2pv2_ij + zu2pv2_ij_p1) * r1_288 ) * zemax  ) * zemax * fmask(ji,jj,jk)
598                  END DO
599               END DO
600            END DO
601         ENDIF
602         !
603         CALL lbc_lnk_multi( 'ldfdyn', ahmt, 'T', 1.,  ahmf, 'F', 1. )
604         !
605         !
606      CASE(  32  )       !==  time varying 3D field  ==!   = F( local deformation rate and gridscale ) (Smagorinsky)
607         !
608         IF( ln_dynldf_lap .OR. ln_dynldf_blp  ) THEN        ! laplacian operator : (C_smag/pi)^2 L^2 |D|
609            !
610            zcmsmag   = (rn_csmc/rpi)**2                                            ! (C_smag/pi)^2
611            zstabf_lo = rn_minfac * rn_minfac / ( 2._wp * 4._wp * zcmsmag )         ! lower limit stability factor scaling
612            zstabf_up = rn_maxfac / ( 4._wp * zcmsmag * 2._wp * rdt )               ! upper limit stability factor scaling
613            IF( ln_dynldf_blp ) zstabf_lo = ( 16._wp / 9._wp ) * zstabf_lo          ! provide |U|L^3/12 lower limit instead
614            !                                                                       ! of |U|L^3/16 in blp case
615            DO jk = 1, jpkm1
616               !
617               DO jj = 2, jpjm1
618                  DO ji = 2, jpim1
619                     zdb =   ( ub(ji,jj,jk) * r1_e2u(ji,jj) - ub(ji-1,jj,jk) * r1_e2u(ji-1,jj) ) * r1_e1t(ji,jj) * e2t(ji,jj)  &
620                          &  - ( vb(ji,jj,jk) * r1_e1v(ji,jj) - vb(ji,jj-1,jk) * r1_e1v(ji,jj-1) ) * r1_e2t(ji,jj) * e1t(ji,jj)
621                     dtensq(ji,jj,jk) = zdb * zdb * tmask(ji,jj,jk)
622                  END DO
623               END DO
624               !
625               DO jj = 1, jpjm1
626                  DO ji = 1, jpim1
627                     zdb =   ( ub(ji,jj+1,jk) * r1_e1u(ji,jj+1) - ub(ji,jj,jk) * r1_e1u(ji,jj) ) * r1_e2f(ji,jj) * e1f(ji,jj)  &
628                          &  + ( vb(ji+1,jj,jk) * r1_e2v(ji+1,jj) - vb(ji,jj,jk) * r1_e2v(ji,jj) ) * r1_e1f(ji,jj) * e2f(ji,jj)
629                     dshesq(ji,jj,jk) = zdb * zdb * fmask(ji,jj,jk)
630                  END DO
631               END DO
632               !
633            END DO
634            !
635            CALL lbc_lnk_multi( 'ldfdyn', dtensq, 'T', 1. )  ! lbc_lnk on dshesq not needed
636            !
637            DO jk = 1, jpkm1
638               !
639               DO jj = 2, jpjm1                                ! T-point value
640                  DO ji = fs_2, fs_jpim1
641                     !
642                     zu2pv2_ij    = ub(ji  ,jj  ,jk) * ub(ji  ,jj  ,jk) + vb(ji  ,jj  ,jk) * vb(ji  ,jj  ,jk)
643                     zu2pv2_ij_m1 = ub(ji-1,jj  ,jk) * ub(ji-1,jj  ,jk) + vb(ji  ,jj-1,jk) * vb(ji  ,jj-1,jk)
644                     !
645                     zdelta         = zcmsmag * esqt(ji,jj)                                        ! L^2 * (C_smag/pi)^2
646                     ahmt(ji,jj,jk) = zdelta * SQRT(          dtensq(ji  ,jj,jk) +                         &
647                          &                            r1_4 * ( dshesq(ji  ,jj,jk) + dshesq(ji  ,jj-1,jk) +  &
648                          &                                     dshesq(ji-1,jj,jk) + dshesq(ji-1,jj-1,jk) ) )
649                     ahmt(ji,jj,jk) = MAX( ahmt(ji,jj,jk), SQRT( (zu2pv2_ij + zu2pv2_ij_m1) * zdelta * zstabf_lo ) ) ! Impose lower limit == minfac  * |U|L/2
650                     ahmt(ji,jj,jk) = MIN( ahmt(ji,jj,jk),                                    zdelta * zstabf_up )   ! Impose upper limit == maxfac  * L^2/(4*2dt)
651                     !
652                  END DO
653               END DO
654               !
655               DO jj = 1, jpjm1                                ! F-point value
656                  DO ji = 1, fs_jpim1
657                     !
658                     zu2pv2_ij_p1 = ub(ji  ,jj+1,jk) * ub(ji  ,jj+1,jk) + vb(ji+1,jj  ,jk) * vb(ji+1,jj  ,jk)
659                     zu2pv2_ij    = ub(ji  ,jj  ,jk) * ub(ji  ,jj  ,jk) + vb(ji  ,jj  ,jk) * vb(ji  ,jj  ,jk)
660                     !
661                     zdelta         = zcmsmag * esqf(ji,jj)                                        ! L^2 * (C_smag/pi)^2
662                     ahmf(ji,jj,jk) = zdelta * SQRT(          dshesq(ji  ,jj,jk) +                         &
663                          &                            r1_4 * ( dtensq(ji  ,jj,jk) + dtensq(ji  ,jj+1,jk) +  &
664                          &                                     dtensq(ji+1,jj,jk) + dtensq(ji+1,jj+1,jk) ) )
665                     ahmf(ji,jj,jk) = MAX( ahmf(ji,jj,jk), SQRT( (zu2pv2_ij + zu2pv2_ij_p1) * zdelta * zstabf_lo ) ) ! Impose lower limit == minfac  * |U|L/2
666                     ahmf(ji,jj,jk) = MIN( ahmf(ji,jj,jk),                                    zdelta * zstabf_up )   ! Impose upper limit == maxfac  * L^2/(4*2dt)
667                     !
668                  END DO
669               END DO
670               !
671            END DO
672            !
673         ENDIF
674         !
675         IF( ln_dynldf_blp ) THEN      ! bilaplacian operator : sqrt( (C_smag/pi)^2 L^4 |D|/8)
676            !                          !                      = sqrt( A_lap_smag L^2/8 )
677            !                          ! stability limits already applied to laplacian values
678            !                          ! effective default limits are 1/12 |U|L^3 < B_hm < 1//(32*2dt) L^4
679            DO jk = 1, jpkm1
680               DO jj = 2, jpjm1
681                  DO ji = fs_2, fs_jpim1
682                     ahmt(ji,jj,jk) = SQRT( r1_8 * esqt(ji,jj) * ahmt(ji,jj,jk) )
683                  END DO
684               END DO
685               DO jj = 1, jpjm1
686                  DO ji = 1, fs_jpim1
687                     ahmf(ji,jj,jk) = SQRT( r1_8 * esqf(ji,jj) * ahmf(ji,jj,jk) )
688                  END DO
689               END DO
690            END DO
691            !
692         ENDIF
693         !
694         CALL lbc_lnk_multi( 'ldfdyn', ahmt, 'T', 1. , ahmf, 'F', 1. )
695         !
696      END SELECT
697      !
698      CALL iom_put( "ahmt_2d", ahmt(:,:,1) )   ! surface u-eddy diffusivity coeff.
699      CALL iom_put( "ahmf_2d", ahmf(:,:,1) )   ! surface v-eddy diffusivity coeff.
700      CALL iom_put( "ahmt_3d", ahmt(:,:,:) )   ! 3D      u-eddy diffusivity coeff.
701      CALL iom_put( "ahmf_3d", ahmf(:,:,:) )   ! 3D      v-eddy diffusivity coeff.
702      !
703      IF( ln_timing )   CALL timing_stop('ldf_dyn')
704      !
705   END SUBROUTINE ldf_dyn
706
707   !!======================================================================
708END MODULE ldfdyn
Note: See TracBrowser for help on using the repository browser.