source: NEMO/branches/UKMO/NEMO_4.0.1_meltpond_improvements/src/ICE/icedyn_adv_umx.F90 @ 12636

Last change on this file since 12636 was 12636, checked in by dancopsey, 8 months ago

Add:

  • Melt pond lids
  • Melt pond maximum area and thickness
  • Melt pond vertical flushing
  • Area contributing to melt ponds depends on total ice fraction
File size: 84.6 KB
Line 
1MODULE icedyn_adv_umx
2   !!==============================================================================
3   !!                       ***  MODULE  icedyn_adv_umx  ***
4   !! sea-ice : advection using the ULTIMATE-MACHO scheme
5   !!==============================================================================
6   !! History :  3.6  !  2014-11  (C. Rousset, G. Madec)  Original code
7   !!            4.0  !  2018     (many people)           SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3'                                       SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   !!   ice_dyn_adv_umx   : update the tracer fields
14   !!   ultimate_x(_y)    : compute a tracer value at velocity points using ULTIMATE scheme at various orders
15   !!   macho             : compute the fluxes
16   !!   nonosc_ice        : limit the fluxes using a non-oscillatory algorithm
17   !!----------------------------------------------------------------------
18   USE phycst         ! physical constant
19   USE dom_oce        ! ocean domain
20   USE sbc_oce , ONLY : nn_fsbc   ! update frequency of surface boundary condition
21   USE ice            ! sea-ice variables
22   USE icevar         ! sea-ice: operations
23   !
24   USE in_out_manager ! I/O manager
25   USE iom            ! I/O manager library
26   USE lib_mpp        ! MPP library
27   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
28   USE lbclnk         ! lateral boundary conditions (or mpp links)
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   ice_dyn_adv_umx   ! called by icedyn_adv.F90
34   !
35   INTEGER, PARAMETER ::   np_advS = 1         ! advection for S and T:    dVS/dt = -div(      uVS     ) => np_advS = 1
36   !                                                                    or dVS/dt = -div( uA * uHS / u ) => np_advS = 2
37   !                                                                    or dVS/dt = -div( uV * uS  / u ) => np_advS = 3
38   INTEGER, PARAMETER ::   np_limiter = 1      ! limiter: 1 = nonosc
39   !                                                      2 = superbee
40   !                                                      3 = h3
41   LOGICAL            ::   ll_upsxy  = .TRUE.   ! alternate directions for upstream
42   LOGICAL            ::   ll_hoxy   = .TRUE.   ! alternate directions for high order
43   LOGICAL            ::   ll_neg    = .TRUE.   ! if T interpolated at u/v points is negative or v_i < 1.e-6
44   !                                                 then interpolate T at u/v points using the upstream scheme
45   LOGICAL            ::   ll_prelim = .FALSE.  ! prelimiter from: Zalesak(1979) eq. 14 => not well defined in 2D
46   !
47   REAL(wp)           ::   z1_6   = 1._wp /   6._wp   ! =1/6
48   REAL(wp)           ::   z1_120 = 1._wp / 120._wp   ! =1/120
49   !
50   INTEGER, ALLOCATABLE, DIMENSION(:,:,:) ::   imsk_small, jmsk_small
51   !
52   !! * Substitutions
53#  include "vectopt_loop_substitute.h90"
54   !!----------------------------------------------------------------------
55   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
56   !! $Id$
57   !! Software governed by the CeCILL licence     (./LICENSE)
58   !!----------------------------------------------------------------------
59CONTAINS
60
61   SUBROUTINE ice_dyn_adv_umx( kn_umx, kt, pu_ice, pv_ice, ph_i, ph_s, ph_ip,  &
62      &                        pato_i, pv_i, pv_s, psv_i, poa_i, pa_i, pa_ip, pv_ip, plh_ip, pe_s, pe_i )
63      !!----------------------------------------------------------------------
64      !!                  ***  ROUTINE ice_dyn_adv_umx  ***
65      !!
66      !! **  Purpose :   Compute the now trend due to total advection of
67      !!                 tracers and add it to the general trend of tracer equations
68      !!                 using an "Ultimate-Macho" scheme
69      !!
70      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
71      !!----------------------------------------------------------------------
72      INTEGER                     , INTENT(in   ) ::   kn_umx     ! order of the scheme (1-5=UM or 20=CEN2)
73      INTEGER                     , INTENT(in   ) ::   kt         ! time step
74      REAL(wp), DIMENSION(:,:)    , INTENT(in   ) ::   pu_ice     ! ice i-velocity
75      REAL(wp), DIMENSION(:,:)    , INTENT(in   ) ::   pv_ice     ! ice j-velocity
76      REAL(wp), DIMENSION(:,:,:)  , INTENT(in   ) ::   ph_i       ! ice thickness
77      REAL(wp), DIMENSION(:,:,:)  , INTENT(in   ) ::   ph_s       ! snw thickness
78      REAL(wp), DIMENSION(:,:,:)  , INTENT(in   ) ::   ph_ip      ! ice pond thickness
79      REAL(wp), DIMENSION(:,:)    , INTENT(inout) ::   pato_i     ! open water area
80      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_i       ! ice volume
81      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_s       ! snw volume
82      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   psv_i      ! salt content
83      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   poa_i      ! age content
84      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pa_i       ! ice concentration
85      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pa_ip      ! melt pond concentration
86      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_ip      ! melt pond volume
87      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   plh_ip     ! melt pond lid thickness
88      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) ::   pe_s       ! snw heat content
89      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) ::   pe_i       ! ice heat content
90      !
91      INTEGER  ::   ji, jj, jk, jl, jt      ! dummy loop indices
92      INTEGER  ::   icycle                  ! number of sub-timestep for the advection
93      REAL(wp) ::   zamsk                   ! 1 if advection of concentration, 0 if advection of other tracers
94      REAL(wp) ::   zdt, zvi_cen
95      REAL(wp), DIMENSION(1)           ::   zcflprv, zcflnow   ! for global communication
96      REAL(wp), DIMENSION(jpi,jpj)     ::   zudy, zvdx, zcu_box, zcv_box
97      REAL(wp), DIMENSION(jpi,jpj)     ::   zati1, zati2
98      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   zu_cat, zv_cat
99      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   zua_ho, zva_ho, zua_ups, zva_ups
100      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   z1_ai , z1_aip, zhvar
101      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   zhi_max, zhs_max, zhip_max
102      !
103      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   zuv_ho, zvv_ho, zuv_ups, zvv_ups, z1_vi, z1_vs 
104      !!----------------------------------------------------------------------
105      !
106      IF( kt == nit000 .AND. lwp )   WRITE(numout,*) '-- ice_dyn_adv_umx: Ultimate-Macho advection scheme'
107      !
108      ! --- Record max of the surrounding 9-pts ice thick. (for call Hbig) --- !
109      DO jl = 1, jpl
110         DO jj = 2, jpjm1
111            DO ji = fs_2, fs_jpim1
112               zhip_max(ji,jj,jl) = MAX( epsi20, ph_ip(ji,jj,jl), ph_ip(ji+1,jj  ,jl), ph_ip(ji  ,jj+1,jl), &
113                  &                                               ph_ip(ji-1,jj  ,jl), ph_ip(ji  ,jj-1,jl), &
114                  &                                               ph_ip(ji+1,jj+1,jl), ph_ip(ji-1,jj-1,jl), &
115                  &                                               ph_ip(ji+1,jj-1,jl), ph_ip(ji-1,jj+1,jl) )
116               zhi_max (ji,jj,jl) = MAX( epsi20, ph_i (ji,jj,jl), ph_i (ji+1,jj  ,jl), ph_i (ji  ,jj+1,jl), &
117                  &                                               ph_i (ji-1,jj  ,jl), ph_i (ji  ,jj-1,jl), &
118                  &                                               ph_i (ji+1,jj+1,jl), ph_i (ji-1,jj-1,jl), &
119                  &                                               ph_i (ji+1,jj-1,jl), ph_i (ji-1,jj+1,jl) )
120               zhs_max (ji,jj,jl) = MAX( epsi20, ph_s (ji,jj,jl), ph_s (ji+1,jj  ,jl), ph_s (ji  ,jj+1,jl), &
121                  &                                               ph_s (ji-1,jj  ,jl), ph_s (ji  ,jj-1,jl), &
122                  &                                               ph_s (ji+1,jj+1,jl), ph_s (ji-1,jj-1,jl), &
123                  &                                               ph_s (ji+1,jj-1,jl), ph_s (ji-1,jj+1,jl) )
124            END DO
125         END DO
126      END DO
127      CALL lbc_lnk_multi( 'icedyn_adv_umx', zhi_max, 'T', 1., zhs_max, 'T', 1., zhip_max, 'T', 1. )
128      !
129      !
130      ! --- If ice drift is too fast, use  subtime steps for advection (CFL test for stability) --- !
131      !        Note: the advection split is applied at the next time-step in order to avoid blocking global comm.
132      !              this should not affect too much the stability
133      zcflnow(1) =                  MAXVAL( ABS( pu_ice(:,:) ) * rdt_ice * r1_e1u(:,:) )
134      zcflnow(1) = MAX( zcflnow(1), MAXVAL( ABS( pv_ice(:,:) ) * rdt_ice * r1_e2v(:,:) ) )
135     
136      ! non-blocking global communication send zcflnow and receive zcflprv
137      CALL mpp_delay_max( 'icedyn_adv_umx', 'cflice', zcflnow(:), zcflprv(:), kt == nitend - nn_fsbc + 1 )
138
139      IF( zcflprv(1) > .5 ) THEN   ;   icycle = 2
140      ELSE                         ;   icycle = 1
141      ENDIF
142      zdt = rdt_ice / REAL(icycle)
143
144      ! --- transport --- !
145      zudy(:,:) = pu_ice(:,:) * e2u(:,:)
146      zvdx(:,:) = pv_ice(:,:) * e1v(:,:)
147      !
148      ! setup transport for each ice cat
149      DO jl = 1, jpl
150         zu_cat(:,:,jl) = zudy(:,:)
151         zv_cat(:,:,jl) = zvdx(:,:)
152      END DO
153      !
154      ! --- define velocity for advection: u*grad(H) --- !
155      DO jj = 2, jpjm1
156         DO ji = fs_2, fs_jpim1
157            IF    ( pu_ice(ji,jj) * pu_ice(ji-1,jj) <= 0._wp ) THEN   ;   zcu_box(ji,jj) = 0._wp
158            ELSEIF( pu_ice(ji,jj)                   >  0._wp ) THEN   ;   zcu_box(ji,jj) = pu_ice(ji-1,jj)
159            ELSE                                                      ;   zcu_box(ji,jj) = pu_ice(ji  ,jj)
160            ENDIF
161
162            IF    ( pv_ice(ji,jj) * pv_ice(ji,jj-1) <= 0._wp ) THEN   ;   zcv_box(ji,jj) = 0._wp
163            ELSEIF( pv_ice(ji,jj)                   >  0._wp ) THEN   ;   zcv_box(ji,jj) = pv_ice(ji,jj-1)
164            ELSE                                                      ;   zcv_box(ji,jj) = pv_ice(ji,jj  )
165            ENDIF
166         END DO
167      END DO
168
169      !---------------!
170      !== advection ==!
171      !---------------!
172      DO jt = 1, icycle
173
174         ! record at_i before advection (for open water)
175         zati1(:,:) = SUM( pa_i(:,:,:), dim=3 )
176         
177         ! inverse of A and Ap
178         WHERE( pa_i(:,:,:) >= epsi20 )   ;   z1_ai(:,:,:) = 1._wp / pa_i(:,:,:)
179         ELSEWHERE                        ;   z1_ai(:,:,:) = 0.
180         END WHERE
181         WHERE( pa_ip(:,:,:) >= epsi20 )  ;   z1_aip(:,:,:) = 1._wp / pa_ip(:,:,:)
182         ELSEWHERE                        ;   z1_aip(:,:,:) = 0.
183         END WHERE
184         !
185         ! setup a mask where advection will be upstream
186         IF( ll_neg ) THEN
187            IF( .NOT. ALLOCATED(imsk_small) )   ALLOCATE( imsk_small(jpi,jpj,jpl) ) 
188            IF( .NOT. ALLOCATED(jmsk_small) )   ALLOCATE( jmsk_small(jpi,jpj,jpl) ) 
189            DO jl = 1, jpl
190               DO jj = 1, jpjm1
191                  DO ji = 1, jpim1
192                     zvi_cen = 0.5_wp * ( pv_i(ji+1,jj,jl) + pv_i(ji,jj,jl) )
193                     IF( zvi_cen < epsi06) THEN   ;   imsk_small(ji,jj,jl) = 0
194                     ELSE                         ;   imsk_small(ji,jj,jl) = 1   ;   ENDIF
195                     zvi_cen = 0.5_wp * ( pv_i(ji,jj+1,jl) + pv_i(ji,jj,jl) )
196                     IF( zvi_cen < epsi06) THEN   ;   jmsk_small(ji,jj,jl) = 0
197                     ELSE                         ;   jmsk_small(ji,jj,jl) = 1   ;   ENDIF
198                  END DO
199               END DO
200            END DO
201         ENDIF
202         !
203         ! ----------------------- !
204         ! ==> start advection <== !
205         ! ----------------------- !
206         !
207         !== Ice area ==!
208         zamsk = 1._wp
209         CALL adv_umx( zamsk, kn_umx, jt, kt, zdt, zudy, zvdx, zu_cat , zv_cat , zcu_box, zcv_box, &
210            &                                      pa_i, pa_i, zua_ups, zva_ups, zua_ho , zva_ho )
211         !
212         !                             ! --------------------------------- !
213         IF( np_advS == 1 ) THEN       ! -- advection form: -div( uVS ) -- !
214            !                          ! --------------------------------- !
215            zamsk = 0._wp
216            !== Ice volume ==!
217            zhvar(:,:,:) = pv_i(:,:,:) * z1_ai(:,:,:)
218            CALL adv_umx( zamsk, kn_umx, jt, kt, zdt, zudy , zvdx, zua_ho , zva_ho , zcu_box, zcv_box, &
219               &                                      zhvar, pv_i, zua_ups, zva_ups )
220            !== Snw volume ==!         
221            zhvar(:,:,:) = pv_s(:,:,:) * z1_ai(:,:,:)
222            CALL adv_umx( zamsk, kn_umx, jt, kt, zdt, zudy , zvdx, zua_ho , zva_ho , zcu_box, zcv_box, &
223               &                                      zhvar, pv_s, zua_ups, zva_ups )
224            !
225            zamsk = 1._wp
226            !== Salt content ==!
227            CALL adv_umx( zamsk, kn_umx, jt, kt, zdt, zudy , zvdx , zu_cat, zv_cat, zcu_box, zcv_box, &
228               &                                      psv_i, psv_i )
229            !== Ice heat content ==!
230            DO jk = 1, nlay_i
231               CALL adv_umx( zamsk, kn_umx, jt, kt, zdt, zudy , zvdx , zu_cat, zv_cat, zcu_box, zcv_box, &
232                  &                                      pe_i(:,:,jk,:), pe_i(:,:,jk,:) )
233            END DO
234            !== Snw heat content ==!
235            DO jk = 1, nlay_s
236               CALL adv_umx( zamsk, kn_umx, jt, kt, zdt, zudy , zvdx , zu_cat, zv_cat, zcu_box, zcv_box, &
237                  &                                      pe_s(:,:,jk,:), pe_s(:,:,jk,:) )
238            END DO
239            !
240            !                          ! ------------------------------------------ !
241         ELSEIF( np_advS == 2 ) THEN   ! -- advection form: -div( uA * uHS / u ) -- !
242            !                          ! ------------------------------------------ !
243            zamsk = 0._wp
244            !== Ice volume ==!
245            zhvar(:,:,:) = pv_i(:,:,:) * z1_ai(:,:,:)
246            CALL adv_umx( zamsk, kn_umx, jt, kt, zdt, zudy , zvdx, zua_ho , zva_ho , zcu_box, zcv_box, &
247               &                                      zhvar, pv_i, zua_ups, zva_ups )
248            !== Snw volume ==!         
249            zhvar(:,:,:) = pv_s(:,:,:) * z1_ai(:,:,:)
250            CALL adv_umx( zamsk, kn_umx, jt, kt, zdt, zudy , zvdx, zua_ho , zva_ho , zcu_box, zcv_box, &
251               &                                      zhvar, pv_s, zua_ups, zva_ups )
252            !== Salt content ==!
253            zhvar(:,:,:) = psv_i(:,:,:) * z1_ai(:,:,:)
254            CALL adv_umx( zamsk, kn_umx, jt, kt, zdt, zudy , zvdx , zua_ho , zva_ho , zcu_box, zcv_box, &
255               &                                      zhvar, psv_i, zua_ups, zva_ups )
256            !== Ice heat content ==!
257            DO jk = 1, nlay_i
258               zhvar(:,:,:) = pe_i(:,:,jk,:) * z1_ai(:,:,:)
259               CALL adv_umx( zamsk, kn_umx, jt, kt, zdt, zudy , zvdx, zua_ho, zva_ho, zcu_box, zcv_box, &
260                  &                                      zhvar, pe_i(:,:,jk,:), zua_ups, zva_ups )
261            END DO
262            !== Snw heat content ==!
263            DO jk = 1, nlay_s
264               zhvar(:,:,:) = pe_s(:,:,jk,:) * z1_ai(:,:,:)
265               CALL adv_umx( zamsk, kn_umx, jt, kt, zdt, zudy , zvdx, zua_ho, zva_ho, zcu_box, zcv_box, &
266                  &                                      zhvar, pe_s(:,:,jk,:), zua_ups, zva_ups )
267            END DO
268            !
269            !                          ! ----------------------------------------- !
270         ELSEIF( np_advS == 3 ) THEN   ! -- advection form: -div( uV * uS / u ) -- !
271            !                          ! ----------------------------------------- !
272            zamsk = 0._wp
273            !
274            ALLOCATE( zuv_ho (jpi,jpj,jpl), zvv_ho (jpi,jpj,jpl),  &
275               &      zuv_ups(jpi,jpj,jpl), zvv_ups(jpi,jpj,jpl), z1_vi(jpi,jpj,jpl), z1_vs(jpi,jpj,jpl) )
276            !
277            ! inverse of Vi
278            WHERE( pv_i(:,:,:) >= epsi20 )   ;   z1_vi(:,:,:) = 1._wp / pv_i(:,:,:)
279            ELSEWHERE                        ;   z1_vi(:,:,:) = 0.
280            END WHERE
281            ! inverse of Vs
282            WHERE( pv_s(:,:,:) >= epsi20 )   ;   z1_vs(:,:,:) = 1._wp / pv_s(:,:,:)
283            ELSEWHERE                        ;   z1_vs(:,:,:) = 0.
284            END WHERE
285            !
286            ! It is important to first calculate the ice fields and then the snow fields (because we use the same arrays)
287            !
288            !== Ice volume ==!
289            zuv_ups = zua_ups
290            zvv_ups = zva_ups
291            zhvar(:,:,:) = pv_i(:,:,:) * z1_ai(:,:,:)
292            CALL adv_umx( zamsk, kn_umx, jt, kt, zdt, zudy , zvdx, zua_ho , zva_ho , zcu_box, zcv_box, &
293               &                                      zhvar, pv_i, zuv_ups, zvv_ups, zuv_ho , zvv_ho )
294            !== Salt content ==!
295            zhvar(:,:,:) = psv_i(:,:,:) * z1_vi(:,:,:)
296            CALL adv_umx( zamsk, kn_umx, jt, kt, zdt, zudy , zvdx , zuv_ho , zvv_ho , zcu_box, zcv_box, &
297               &                                      zhvar, psv_i, zuv_ups, zvv_ups )
298            !== Ice heat content ==!
299            DO jk = 1, nlay_i
300               zhvar(:,:,:) = pe_i(:,:,jk,:) * z1_vi(:,:,:)
301               CALL adv_umx( zamsk, kn_umx, jt, kt, zdt, zudy , zvdx, zuv_ho, zvv_ho, zcu_box, zcv_box, &
302                  &                                      zhvar, pe_i(:,:,jk,:), zuv_ups, zvv_ups )
303            END DO
304            !== Snow volume ==!         
305            zuv_ups = zua_ups
306            zvv_ups = zva_ups
307            zhvar(:,:,:) = pv_s(:,:,:) * z1_ai(:,:,:)
308            CALL adv_umx( zamsk, kn_umx, jt, kt, zdt, zudy , zvdx, zua_ho , zva_ho , zcu_box, zcv_box, &
309               &                                      zhvar, pv_s, zuv_ups, zvv_ups, zuv_ho , zvv_ho )
310            !== Snw heat content ==!
311            DO jk = 1, nlay_s
312               zhvar(:,:,:) = pe_s(:,:,jk,:) * z1_vs(:,:,:)
313               CALL adv_umx( zamsk, kn_umx, jt, kt, zdt, zudy , zvdx, zuv_ho, zvv_ho, zcu_box, zcv_box, &
314                  &                                      zhvar, pe_s(:,:,jk,:), zuv_ups, zvv_ups )
315            END DO
316            !
317            DEALLOCATE( zuv_ho, zvv_ho, zuv_ups, zvv_ups, z1_vi, z1_vs )
318            !
319         ENDIF
320         !
321         !== Ice age ==!
322         zamsk = 1._wp
323         CALL adv_umx( zamsk, kn_umx, jt, kt, zdt, zudy , zvdx , zu_cat, zv_cat, zcu_box, zcv_box, &
324            &                                      poa_i, poa_i )
325         !
326         !== melt ponds ==!
327         IF ( ln_pnd_H12 ) THEN
328            ! concentration
329            zamsk = 1._wp
330            CALL adv_umx( zamsk, kn_umx, jt, kt, zdt, zudy , zvdx , zu_cat , zv_cat , zcu_box, zcv_box, &
331               &                                      pa_ip, pa_ip, zua_ups, zva_ups, zua_ho , zva_ho )
332            ! volume
333            zamsk = 0._wp
334            zhvar(:,:,:) = pv_ip(:,:,:) * z1_aip(:,:,:)
335            CALL adv_umx( zamsk, kn_umx, jt, kt, zdt, zudy , zvdx , zua_ho , zva_ho , zcu_box, zcv_box, &
336               &                                      zhvar, pv_ip, zua_ups, zva_ups )
337            ! lid thickness
338            zamsk = 0._wp
339            zhvar(:,:,:) = plh_ip(:,:,:) * z1_aip(:,:,:)
340            CALL adv_umx( zamsk, kn_umx, jt, kt, zdt, zudy , zvdx , zua_ho , zva_ho , zcu_box, zcv_box, &
341               &                                      zhvar, plh_ip, zua_ups, zva_ups )
342           
343         ENDIF
344         !
345         !== Open water area ==!
346         zati2(:,:) = SUM( pa_i(:,:,:), dim=3 )
347         DO jj = 2, jpjm1
348            DO ji = fs_2, fs_jpim1
349               pato_i(ji,jj) = pato_i(ji,jj) - ( zati2(ji,jj) - zati1(ji,jj) ) & 
350                  &                          - ( zudy(ji,jj) - zudy(ji-1,jj) + zvdx(ji,jj) - zvdx(ji,jj-1) ) * r1_e1e2t(ji,jj) * zdt
351            END DO
352         END DO
353         CALL lbc_lnk( 'icedyn_adv_umx', pato_i, 'T',  1. )
354         !
355         !
356         ! --- Ensure non-negative fields and in-bound thicknesses --- !
357         ! Remove negative values (conservation is ensured)
358         !    (because advected fields are not perfectly bounded and tiny negative values can occur, e.g. -1.e-20)
359         CALL ice_var_zapneg( zdt, pato_i, pv_i, pv_s, psv_i, poa_i, pa_i, pa_ip, pv_ip, plh_ip, pe_s, pe_i )
360         !
361         ! Make sure ice thickness is not too big
362         !    (because ice thickness can be too large where ice concentration is very small)
363         CALL Hbig( zdt, zhi_max, zhs_max, zhip_max, pv_i, pv_s, psv_i, poa_i, pa_i, pa_ip, pv_ip, pe_s, pe_i )
364
365      END DO
366      !
367   END SUBROUTINE ice_dyn_adv_umx
368
369   
370   SUBROUTINE adv_umx( pamsk, kn_umx, jt, kt, pdt, pu, pv, puc, pvc, pubox, pvbox,  &
371      &                                            pt, ptc, pua_ups, pva_ups, pua_ho, pva_ho )
372      !!----------------------------------------------------------------------
373      !!                  ***  ROUTINE adv_umx  ***
374      !!
375      !! **  Purpose :   Compute the now trend due to total advection of
376      !!                 tracers and add it to the general trend of tracer equations
377      !!
378      !! **  Method  :   - calculate upstream fluxes and upstream solution for tracers V/A(=H) etc
379      !!                 - calculate tracer H at u and v points (Ultimate)
380      !!                 - calculate the high order fluxes using alterning directions (Macho)
381      !!                 - apply a limiter on the fluxes (nonosc_ice)
382      !!                 - convert this tracer flux to a "volume" flux (uH -> uV)
383      !!                 - apply a limiter a second time on the volumes fluxes (nonosc_ice)
384      !!                 - calculate the high order solution for V
385      !!
386      !! ** Action : solve 3 equations => a) dA/dt  = -div(uA)
387      !!                                  b) dV/dt  = -div(uV)  using dH/dt = -u.grad(H)
388      !!                                  c) dVS/dt = -div(uVS) using either dHS/dt = -u.grad(HS) or dS/dt = -u.grad(S)
389      !!
390      !!             in eq. b), - fluxes uH are evaluated (with UMx) and limited with nonosc_ice. This step is necessary to get a good H.
391      !!                        - then we convert this flux to a "volume" flux this way => uH * uA / u
392      !!                             where uA is the flux from eq. a)
393      !!                             this "volume" flux is also limited with nonosc_ice (otherwise overshoots can occur)
394      !!                        - at last we estimate dV/dt = -div(uH * uA / u)
395      !!
396      !!             in eq. c), one can solve the equation for  S (ln_advS=T), then dVS/dt = -div(uV * uS  / u)
397      !!                                                or for HS (ln_advS=F), then dVS/dt = -div(uA * uHS / u)
398      !!
399      !! ** Note : - this method can lead to tiny negative V (-1.e-20) => set it to 0 while conserving mass etc.
400      !!           - At the ice edge, Ultimate scheme can lead to:
401      !!                              1) negative interpolated tracers at u-v points
402      !!                              2) non-zero interpolated tracers at u-v points eventhough there is no ice and velocity is outward
403      !!                              Solution for 1): apply an upstream scheme when it occurs. A better solution would be to degrade the order of
404      !!                                               the scheme automatically by applying a mask of the ice cover inside Ultimate (not done).
405      !!                              Solution for 2): we set it to 0 in this case
406      !!           - Eventhough 1D tests give very good results (typically the one from Schar & Smolarkiewiecz), the 2D is less good.
407      !!             Large values of H can appear for very small ice concentration, and when it does it messes the things up since we
408      !!             work on H (and not V). It is partly related to the multi-category approach
409      !!             Therefore, after advection we limit the thickness to the largest value of the 9-points around (only if ice
410      !!             concentration is small). Since we do not limit S and T, large values can occur at the edge but it does not really matter
411      !!             since sv_i and e_i are still good.
412      !!----------------------------------------------------------------------
413      REAL(wp)                        , INTENT(in   )           ::   pamsk            ! advection of concentration (1) or other tracers (0)
414      INTEGER                         , INTENT(in   )           ::   kn_umx           ! order of the scheme (1-5=UM or 20=CEN2)
415      INTEGER                         , INTENT(in   )           ::   jt               ! number of sub-iteration
416      INTEGER                         , INTENT(in   )           ::   kt               ! number of iteration
417      REAL(wp)                        , INTENT(in   )           ::   pdt              ! tracer time-step
418      REAL(wp), DIMENSION(:,:  )      , INTENT(in   )           ::   pu   , pv        ! 2 ice velocity components => u*e2
419      REAL(wp), DIMENSION(:,:,:)      , INTENT(in   )           ::   puc  , pvc       ! 2 ice velocity components => u*e2 or u*a*e2u
420      REAL(wp), DIMENSION(:,:  )      , INTENT(in   )           ::   pubox, pvbox     ! upstream velocity
421      REAL(wp), DIMENSION(:,:,:)      , INTENT(inout)           ::   pt               ! tracer field
422      REAL(wp), DIMENSION(:,:,:)      , INTENT(inout)           ::   ptc              ! tracer content field
423      REAL(wp), DIMENSION(jpi,jpj,jpl), INTENT(inout), OPTIONAL ::   pua_ups, pva_ups ! upstream u*a fluxes
424      REAL(wp), DIMENSION(jpi,jpj,jpl), INTENT(  out), OPTIONAL ::   pua_ho, pva_ho   ! high order u*a fluxes
425      !
426      INTEGER  ::   ji, jj, jl       ! dummy loop indices 
427      REAL(wp) ::   ztra             ! local scalar
428      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   zfu_ho , zfv_ho , zpt
429      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   zfu_ups, zfv_ups, zt_ups
430      !!----------------------------------------------------------------------
431      !
432      ! Upstream (_ups) fluxes
433      ! -----------------------
434      CALL upstream( pamsk, jt, kt, pdt, pt, pu, pv, zt_ups, zfu_ups, zfv_ups )
435     
436      ! High order (_ho) fluxes
437      ! -----------------------
438      SELECT CASE( kn_umx )
439         !
440      CASE ( 20 )                          !== centered second order ==!
441         !
442         CALL cen2( pamsk, jt, kt, pdt, pt, pu, pv, zt_ups, zfu_ups, zfv_ups, zfu_ho, zfv_ho )
443         !
444      CASE ( 1:5 )                         !== 1st to 5th order ULTIMATE-MACHO scheme ==!
445         !
446         CALL macho( pamsk, kn_umx, jt, kt, pdt, pt, pu, pv, pubox, pvbox, zt_ups, zfu_ups, zfv_ups, zfu_ho, zfv_ho )
447         !
448      END SELECT
449      !
450      !              --ho    --ho
451      ! new fluxes = u*H  *  u*a / u
452      ! ----------------------------
453      IF( pamsk == 0._wp ) THEN
454         DO jl = 1, jpl
455            DO jj = 1, jpjm1
456               DO ji = 1, fs_jpim1
457                  IF( ABS( pu(ji,jj) ) > epsi10 ) THEN
458                     zfu_ho (ji,jj,jl) = zfu_ho (ji,jj,jl) * puc    (ji,jj,jl) / pu(ji,jj)
459                     zfu_ups(ji,jj,jl) = zfu_ups(ji,jj,jl) * pua_ups(ji,jj,jl) / pu(ji,jj)
460                  ELSE
461                     zfu_ho (ji,jj,jl) = 0._wp
462                     zfu_ups(ji,jj,jl) = 0._wp
463                  ENDIF
464                  !
465                  IF( ABS( pv(ji,jj) ) > epsi10 ) THEN
466                     zfv_ho (ji,jj,jl) = zfv_ho (ji,jj,jl) * pvc    (ji,jj,jl) / pv(ji,jj)
467                     zfv_ups(ji,jj,jl) = zfv_ups(ji,jj,jl) * pva_ups(ji,jj,jl) / pv(ji,jj)
468                  ELSE
469                     zfv_ho (ji,jj,jl) = 0._wp 
470                     zfv_ups(ji,jj,jl) = 0._wp 
471                  ENDIF
472               END DO
473            END DO
474         END DO
475
476         ! the new "volume" fluxes must also be "flux corrected"
477         ! thus we calculate the upstream solution and apply a limiter again
478         DO jl = 1, jpl
479            DO jj = 2, jpjm1
480               DO ji = fs_2, fs_jpim1
481                  ztra = - ( zfu_ups(ji,jj,jl) - zfu_ups(ji-1,jj,jl) + zfv_ups(ji,jj,jl) - zfv_ups(ji,jj-1,jl) )
482                  !
483                  zt_ups(ji,jj,jl) = ( ptc(ji,jj,jl) + ztra * r1_e1e2t(ji,jj) * pdt ) * tmask(ji,jj,1)
484               END DO
485            END DO
486         END DO
487         CALL lbc_lnk( 'icedyn_adv_umx', zt_ups, 'T',  1. )
488         !
489         IF    ( np_limiter == 1 ) THEN
490            CALL nonosc_ice( 1._wp, pdt, pu, pv, ptc, zt_ups, zfu_ups, zfv_ups, zfu_ho, zfv_ho )
491         ELSEIF( np_limiter == 2 .OR. np_limiter == 3 ) THEN
492            CALL limiter_x( pdt, pu, ptc, zfu_ups, zfu_ho )
493            CALL limiter_y( pdt, pv, ptc, zfv_ups, zfv_ho )
494         ENDIF
495         !
496      ENDIF
497      !                                   --ho    --ups
498      ! in case of advection of A: output u*a and u*a
499      ! -----------------------------------------------
500      IF( PRESENT( pua_ho ) ) THEN
501         DO jl = 1, jpl
502            DO jj = 1, jpjm1
503               DO ji = 1, fs_jpim1
504                  pua_ho (ji,jj,jl) = zfu_ho (ji,jj,jl) ; pva_ho (ji,jj,jl) = zfv_ho (ji,jj,jl)
505                  pua_ups(ji,jj,jl) = zfu_ups(ji,jj,jl) ; pva_ups(ji,jj,jl) = zfv_ups(ji,jj,jl)
506              END DO
507            END DO
508         END DO
509      ENDIF
510      !
511      ! final trend with corrected fluxes
512      ! ---------------------------------
513      DO jl = 1, jpl
514         DO jj = 2, jpjm1
515            DO ji = fs_2, fs_jpim1 
516               ztra = - ( zfu_ho(ji,jj,jl) - zfu_ho(ji-1,jj,jl) + zfv_ho(ji,jj,jl) - zfv_ho(ji,jj-1,jl) ) 
517               !
518               ptc(ji,jj,jl) = ( ptc(ji,jj,jl) + ztra * r1_e1e2t(ji,jj) * pdt ) * tmask(ji,jj,1)               
519            END DO
520         END DO
521      END DO
522      CALL lbc_lnk( 'icedyn_adv_umx', ptc, 'T',  1. )
523      !
524   END SUBROUTINE adv_umx
525
526
527   SUBROUTINE upstream( pamsk, jt, kt, pdt, pt, pu, pv, pt_ups, pfu_ups, pfv_ups )
528      !!---------------------------------------------------------------------
529      !!                    ***  ROUTINE upstream  ***
530      !!     
531      !! **  Purpose :   compute the upstream fluxes and upstream guess of tracer
532      !!----------------------------------------------------------------------
533      REAL(wp)                        , INTENT(in   ) ::   pamsk            ! advection of concentration (1) or other tracers (0)
534      INTEGER                         , INTENT(in   ) ::   jt               ! number of sub-iteration
535      INTEGER                         , INTENT(in   ) ::   kt               ! number of iteration
536      REAL(wp)                        , INTENT(in   ) ::   pdt              ! tracer time-step
537      REAL(wp), DIMENSION(:,:,:)      , INTENT(in   ) ::   pt               ! tracer fields
538      REAL(wp), DIMENSION(:,:  )      , INTENT(in   ) ::   pu, pv           ! 2 ice velocity components
539      REAL(wp), DIMENSION(jpi,jpj,jpl), INTENT(  out) ::   pt_ups           ! upstream guess of tracer
540      REAL(wp), DIMENSION(jpi,jpj,jpl), INTENT(  out) ::   pfu_ups, pfv_ups ! upstream fluxes
541      !
542      INTEGER  ::   ji, jj, jl    ! dummy loop indices
543      REAL(wp) ::   ztra          ! local scalar
544      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   zpt
545      !!----------------------------------------------------------------------
546
547      IF( .NOT. ll_upsxy ) THEN         !** no alternate directions **!
548         !
549         DO jl = 1, jpl
550            DO jj = 1, jpjm1
551               DO ji = 1, fs_jpim1
552                  pfu_ups(ji,jj,jl) = MAX( pu(ji,jj), 0._wp ) * pt(ji,jj,jl) + MIN( pu(ji,jj), 0._wp ) * pt(ji+1,jj,jl)
553                  pfv_ups(ji,jj,jl) = MAX( pv(ji,jj), 0._wp ) * pt(ji,jj,jl) + MIN( pv(ji,jj), 0._wp ) * pt(ji,jj+1,jl)
554               END DO
555            END DO
556         END DO
557         !
558      ELSE                              !** alternate directions **!
559         !
560         IF( MOD( (kt - 1) / nn_fsbc , 2 ) ==  MOD( (jt - 1) , 2 ) ) THEN   !==  odd ice time step:  adv_x then adv_y  ==!
561            !
562            DO jl = 1, jpl              !-- flux in x-direction
563               DO jj = 1, jpjm1
564                  DO ji = 1, fs_jpim1
565                     pfu_ups(ji,jj,jl) = MAX( pu(ji,jj), 0._wp ) * pt(ji,jj,jl) + MIN( pu(ji,jj), 0._wp ) * pt(ji+1,jj,jl)
566                  END DO
567               END DO
568            END DO
569            !
570            DO jl = 1, jpl              !-- first guess of tracer from u-flux
571               DO jj = 2, jpjm1
572                  DO ji = fs_2, fs_jpim1
573                     ztra = - ( pfu_ups(ji,jj,jl) - pfu_ups(ji-1,jj,jl) )              &
574                        &   + ( pu     (ji,jj   ) - pu     (ji-1,jj   ) ) * pt(ji,jj,jl) * (1.-pamsk)
575                     !
576                     zpt(ji,jj,jl) = ( pt(ji,jj,jl) + ztra * pdt * r1_e1e2t(ji,jj) ) * tmask(ji,jj,1)
577                  END DO
578               END DO
579            END DO
580            CALL lbc_lnk( 'icedyn_adv_umx', zpt, 'T', 1. )
581            !
582            DO jl = 1, jpl              !-- flux in y-direction
583               DO jj = 1, jpjm1
584                  DO ji = 1, fs_jpim1
585                     pfv_ups(ji,jj,jl) = MAX( pv(ji,jj), 0._wp ) * zpt(ji,jj,jl) + MIN( pv(ji,jj), 0._wp ) * zpt(ji,jj+1,jl)
586                  END DO
587               END DO
588            END DO
589            !
590         ELSE                                                               !==  even ice time step:  adv_y then adv_x  ==!
591            !
592            DO jl = 1, jpl              !-- flux in y-direction
593               DO jj = 1, jpjm1
594                  DO ji = 1, fs_jpim1
595                     pfv_ups(ji,jj,jl) = MAX( pv(ji,jj), 0._wp ) * pt(ji,jj,jl) + MIN( pv(ji,jj), 0._wp ) * pt(ji,jj+1,jl)
596                  END DO
597               END DO
598            END DO
599            !
600            DO jl = 1, jpl              !-- first guess of tracer from v-flux
601               DO jj = 2, jpjm1
602                  DO ji = fs_2, fs_jpim1
603                     ztra = - ( pfv_ups(ji,jj,jl) - pfv_ups(ji,jj-1,jl) )  &
604                        &   + ( pv     (ji,jj   ) - pv     (ji,jj-1   ) ) * pt(ji,jj,jl) * (1.-pamsk)
605                     !
606                     zpt(ji,jj,jl) = ( pt(ji,jj,jl) + ztra * pdt * r1_e1e2t(ji,jj) ) * tmask(ji,jj,1)
607                  END DO
608               END DO
609            END DO
610            CALL lbc_lnk( 'icedyn_adv_umx', zpt, 'T', 1. )
611            !
612            DO jl = 1, jpl              !-- flux in x-direction
613               DO jj = 1, jpjm1
614                  DO ji = 1, fs_jpim1
615                     pfu_ups(ji,jj,jl) = MAX( pu(ji,jj), 0._wp ) * zpt(ji,jj,jl) + MIN( pu(ji,jj), 0._wp ) * zpt(ji+1,jj,jl)
616                  END DO
617               END DO
618            END DO
619            !
620         ENDIF
621         
622      ENDIF
623      !
624      DO jl = 1, jpl                    !-- after tracer with upstream scheme
625         DO jj = 2, jpjm1
626            DO ji = fs_2, fs_jpim1
627               ztra = - (   pfu_ups(ji,jj,jl) - pfu_ups(ji-1,jj  ,jl)   &
628                  &       + pfv_ups(ji,jj,jl) - pfv_ups(ji  ,jj-1,jl) ) &
629                  &   + (   pu     (ji,jj   ) - pu     (ji-1,jj     )   &
630                  &       + pv     (ji,jj   ) - pv     (ji  ,jj-1   ) ) * pt(ji,jj,jl) * (1.-pamsk)
631               !
632               pt_ups(ji,jj,jl) = ( pt(ji,jj,jl) + ztra * pdt * r1_e1e2t(ji,jj) ) * tmask(ji,jj,1)
633            END DO
634         END DO
635      END DO
636      CALL lbc_lnk( 'icedyn_adv_umx', pt_ups, 'T', 1. )
637
638   END SUBROUTINE upstream
639
640   
641   SUBROUTINE cen2( pamsk, jt, kt, pdt, pt, pu, pv, pt_ups, pfu_ups, pfv_ups, pfu_ho, pfv_ho )
642      !!---------------------------------------------------------------------
643      !!                    ***  ROUTINE cen2  ***
644      !!     
645      !! **  Purpose :   compute the high order fluxes using a centered
646      !!                 second order scheme
647      !!----------------------------------------------------------------------
648      REAL(wp)                        , INTENT(in   ) ::   pamsk            ! advection of concentration (1) or other tracers (0)
649      INTEGER                         , INTENT(in   ) ::   jt               ! number of sub-iteration
650      INTEGER                         , INTENT(in   ) ::   kt               ! number of iteration
651      REAL(wp)                        , INTENT(in   ) ::   pdt              ! tracer time-step
652      REAL(wp), DIMENSION(:,:,:)      , INTENT(in   ) ::   pt               ! tracer fields
653      REAL(wp), DIMENSION(:,:  )      , INTENT(in   ) ::   pu, pv           ! 2 ice velocity components
654      REAL(wp), DIMENSION(:,:,:)      , INTENT(in   ) ::   pt_ups           ! upstream guess of tracer
655      REAL(wp), DIMENSION(:,:,:)      , INTENT(in   ) ::   pfu_ups, pfv_ups ! upstream fluxes
656      REAL(wp), DIMENSION(jpi,jpj,jpl), INTENT(  out) ::   pfu_ho, pfv_ho   ! high order fluxes
657      !
658      INTEGER  ::   ji, jj, jl    ! dummy loop indices
659      REAL(wp) ::   ztra          ! local scalar
660      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   zpt
661      !!----------------------------------------------------------------------
662      !
663      IF( .NOT.ll_hoxy ) THEN           !** no alternate directions **!
664         !
665         DO jl = 1, jpl
666            DO jj = 1, jpjm1
667               DO ji = 1, fs_jpim1
668                  pfu_ho(ji,jj,jl) = 0.5_wp * pu(ji,jj) * ( pt(ji,jj,jl) + pt(ji+1,jj  ,jl) )
669                  pfv_ho(ji,jj,jl) = 0.5_wp * pv(ji,jj) * ( pt(ji,jj,jl) + pt(ji  ,jj+1,jl) )
670               END DO
671            END DO
672         END DO
673         !
674         IF    ( np_limiter == 1 ) THEN
675            CALL nonosc_ice( pamsk, pdt, pu, pv, pt, pt_ups, pfu_ups, pfv_ups, pfu_ho, pfv_ho )
676         ELSEIF( np_limiter == 2 .OR. np_limiter == 3 ) THEN
677            CALL limiter_x( pdt, pu, pt, pfu_ups, pfu_ho )
678            CALL limiter_y( pdt, pv, pt, pfv_ups, pfv_ho )
679         ENDIF
680         !
681      ELSE                              !** alternate directions **!
682         !
683         IF( MOD( (kt - 1) / nn_fsbc , 2 ) ==  MOD( (jt - 1) , 2 ) ) THEN   !==  odd ice time step:  adv_x then adv_y  ==!
684            !
685            DO jl = 1, jpl              !-- flux in x-direction
686               DO jj = 1, jpjm1
687                  DO ji = 1, fs_jpim1
688                     pfu_ho(ji,jj,jl) = 0.5_wp * pu(ji,jj) * ( pt(ji,jj,jl) + pt(ji+1,jj,jl) )
689                  END DO
690               END DO
691            END DO
692            IF( np_limiter == 2 .OR. np_limiter == 3 )   CALL limiter_x( pdt, pu, pt, pfu_ups, pfu_ho )
693
694            DO jl = 1, jpl              !-- first guess of tracer from u-flux
695               DO jj = 2, jpjm1
696                  DO ji = fs_2, fs_jpim1
697                     ztra = - ( pfu_ho(ji,jj,jl) - pfu_ho(ji-1,jj,jl) )              &
698                        &   + ( pu    (ji,jj   ) - pu    (ji-1,jj   ) ) * pt(ji,jj,jl) * (1.-pamsk)
699                     !
700                     zpt(ji,jj,jl) = ( pt(ji,jj,jl) + ztra * pdt * r1_e1e2t(ji,jj) ) * tmask(ji,jj,1)
701                  END DO
702               END DO
703            END DO
704            CALL lbc_lnk( 'icedyn_adv_umx', zpt, 'T', 1. )
705
706            DO jl = 1, jpl              !-- flux in y-direction
707               DO jj = 1, jpjm1
708                  DO ji = 1, fs_jpim1
709                     pfv_ho(ji,jj,jl) = 0.5_wp * pv(ji,jj) * ( zpt(ji,jj,jl) + zpt(ji,jj+1,jl) )
710                  END DO
711               END DO
712            END DO
713            IF( np_limiter == 2 .OR. np_limiter == 3 )   CALL limiter_y( pdt, pv, pt, pfv_ups, pfv_ho )
714
715         ELSE                                                               !==  even ice time step:  adv_y then adv_x  ==!
716            !
717            DO jl = 1, jpl              !-- flux in y-direction
718               DO jj = 1, jpjm1
719                  DO ji = 1, fs_jpim1
720                     pfv_ho(ji,jj,jl) = 0.5_wp * pv(ji,jj) * ( pt(ji,jj,jl) + pt(ji,jj+1,jl) )
721                  END DO
722               END DO
723            END DO
724            IF( np_limiter == 2 .OR. np_limiter == 3 )   CALL limiter_y( pdt, pv, pt, pfv_ups, pfv_ho )
725            !
726            DO jl = 1, jpl              !-- first guess of tracer from v-flux
727               DO jj = 2, jpjm1
728                  DO ji = fs_2, fs_jpim1
729                     ztra = - ( pfv_ho(ji,jj,jl) - pfv_ho(ji,jj-1,jl) )  &
730                        &   + ( pv    (ji,jj   ) - pv    (ji,jj-1   ) ) * pt(ji,jj,jl) * (1.-pamsk)
731                     !
732                     zpt(ji,jj,jl) = ( pt(ji,jj,jl) + ztra * pdt * r1_e1e2t(ji,jj) ) * tmask(ji,jj,1)
733                  END DO
734               END DO
735            END DO
736            CALL lbc_lnk( 'icedyn_adv_umx', zpt, 'T', 1. )
737            !
738            DO jl = 1, jpl              !-- flux in x-direction
739               DO jj = 1, jpjm1
740                  DO ji = 1, fs_jpim1
741                     pfu_ho(ji,jj,jl) = 0.5_wp * pu(ji,jj) * ( zpt(ji,jj,jl) + zpt(ji+1,jj,jl) )
742                  END DO
743               END DO
744            END DO
745            IF( np_limiter == 2 .OR. np_limiter == 3 )   CALL limiter_x( pdt, pu, pt, pfu_ups, pfu_ho )
746
747         ENDIF
748         IF( np_limiter == 1 )   CALL nonosc_ice( pamsk, pdt, pu, pv, pt, pt_ups, pfu_ups, pfv_ups, pfu_ho, pfv_ho )
749         
750      ENDIF
751   
752   END SUBROUTINE cen2
753
754   
755   SUBROUTINE macho( pamsk, kn_umx, jt, kt, pdt, pt, pu, pv, pubox, pvbox, pt_ups, pfu_ups, pfv_ups, pfu_ho, pfv_ho )
756      !!---------------------------------------------------------------------
757      !!                    ***  ROUTINE macho  ***
758      !!     
759      !! **  Purpose :   compute the high order fluxes using Ultimate-Macho scheme 
760      !!
761      !! **  Method  :   ...
762      !!
763      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
764      !!----------------------------------------------------------------------
765      REAL(wp)                        , INTENT(in   ) ::   pamsk            ! advection of concentration (1) or other tracers (0)
766      INTEGER                         , INTENT(in   ) ::   kn_umx           ! order of the scheme (1-5=UM or 20=CEN2)
767      INTEGER                         , INTENT(in   ) ::   jt               ! number of sub-iteration
768      INTEGER                         , INTENT(in   ) ::   kt               ! number of iteration
769      REAL(wp)                        , INTENT(in   ) ::   pdt              ! tracer time-step
770      REAL(wp), DIMENSION(:,:,:)      , INTENT(in   ) ::   pt               ! tracer fields
771      REAL(wp), DIMENSION(:,:  )      , INTENT(in   ) ::   pu, pv           ! 2 ice velocity components
772      REAL(wp), DIMENSION(:,:  )      , INTENT(in   ) ::   pubox, pvbox     ! upstream velocity
773      REAL(wp), DIMENSION(:,:,:)      , INTENT(in   ) ::   pt_ups           ! upstream guess of tracer
774      REAL(wp), DIMENSION(:,:,:)      , INTENT(in   ) ::   pfu_ups, pfv_ups ! upstream fluxes
775      REAL(wp), DIMENSION(jpi,jpj,jpl), INTENT(  out) ::   pfu_ho, pfv_ho   ! high order fluxes
776      !
777      INTEGER  ::   ji, jj, jl    ! dummy loop indices
778      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   zt_u, zt_v, zpt
779      !!----------------------------------------------------------------------
780      !
781      IF( MOD( (kt - 1) / nn_fsbc , 2 ) ==  MOD( (jt - 1) , 2 ) ) THEN   !==  odd ice time step:  adv_x then adv_y  ==!
782         !
783         !                                                        !--  ultimate interpolation of pt at u-point  --!
784         CALL ultimate_x( pamsk, kn_umx, pdt, pt, pu, zt_u, pfu_ho )
785         !                                                        !--  limiter in x --!
786         IF( np_limiter == 2 .OR. np_limiter == 3 )   CALL limiter_x( pdt, pu, pt, pfu_ups, pfu_ho )
787         !                                                        !--  advective form update in zpt  --!
788         DO jl = 1, jpl
789            DO jj = 2, jpjm1
790               DO ji = fs_2, fs_jpim1
791                  zpt(ji,jj,jl) = ( pt(ji,jj,jl) - (  pubox(ji,jj   ) * ( zt_u(ji,jj,jl) - zt_u(ji-1,jj,jl) ) * r1_e1t  (ji,jj) &
792                     &                              + pt   (ji,jj,jl) * ( pu  (ji,jj   ) - pu  (ji-1,jj   ) ) * r1_e1e2t(ji,jj) &
793                     &                                                                                        * pamsk           &
794                     &                             ) * pdt ) * tmask(ji,jj,1)
795               END DO
796            END DO
797         END DO
798         CALL lbc_lnk( 'icedyn_adv_umx', zpt, 'T', 1. )
799         !
800         !                                                        !--  ultimate interpolation of pt at v-point  --!
801         IF( ll_hoxy ) THEN
802            CALL ultimate_y( pamsk, kn_umx, pdt, zpt, pv, zt_v, pfv_ho )
803         ELSE
804            CALL ultimate_y( pamsk, kn_umx, pdt, pt , pv, zt_v, pfv_ho )
805         ENDIF
806         !                                                        !--  limiter in y --!
807         IF( np_limiter == 2 .OR. np_limiter == 3 )   CALL limiter_y( pdt, pv, pt, pfv_ups, pfv_ho )
808         !         
809         !
810      ELSE                                                               !==  even ice time step:  adv_y then adv_x  ==!
811         !
812         !                                                        !--  ultimate interpolation of pt at v-point  --!
813         CALL ultimate_y( pamsk, kn_umx, pdt, pt, pv, zt_v, pfv_ho )
814         !                                                        !--  limiter in y --!
815         IF( np_limiter == 2 .OR. np_limiter == 3 )   CALL limiter_y( pdt, pv, pt, pfv_ups, pfv_ho )
816         !                                                        !--  advective form update in zpt  --!
817         DO jl = 1, jpl
818            DO jj = 2, jpjm1
819               DO ji = fs_2, fs_jpim1
820                  zpt(ji,jj,jl) = ( pt(ji,jj,jl) - (  pvbox(ji,jj   ) * ( zt_v(ji,jj,jl) - zt_v(ji,jj-1,jl) ) * r1_e2t  (ji,jj) &
821                     &                              + pt   (ji,jj,jl) * ( pv  (ji,jj   ) - pv  (ji,jj-1   ) ) * r1_e1e2t(ji,jj) &
822                     &                                                                                        * pamsk           &
823                     &                             ) * pdt ) * tmask(ji,jj,1) 
824               END DO
825            END DO
826         END DO
827         CALL lbc_lnk( 'icedyn_adv_umx', zpt, 'T', 1. )
828         !
829         !                                                        !--  ultimate interpolation of pt at u-point  --!
830         IF( ll_hoxy ) THEN
831            CALL ultimate_x( pamsk, kn_umx, pdt, zpt, pu, zt_u, pfu_ho )
832         ELSE
833            CALL ultimate_x( pamsk, kn_umx, pdt, pt , pu, zt_u, pfu_ho )
834         ENDIF
835         !                                                        !--  limiter in x --!
836         IF( np_limiter == 2 .OR. np_limiter == 3 )   CALL limiter_x( pdt, pu, pt, pfu_ups, pfu_ho )
837         !
838      ENDIF
839
840      IF( np_limiter == 1 )   CALL nonosc_ice( pamsk, pdt, pu, pv, pt, pt_ups, pfu_ups, pfv_ups, pfu_ho, pfv_ho )
841      !
842   END SUBROUTINE macho
843
844
845   SUBROUTINE ultimate_x( pamsk, kn_umx, pdt, pt, pu, pt_u, pfu_ho )
846      !!---------------------------------------------------------------------
847      !!                    ***  ROUTINE ultimate_x  ***
848      !!     
849      !! **  Purpose :   compute tracer at u-points
850      !!
851      !! **  Method  :   ...
852      !!
853      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
854      !!----------------------------------------------------------------------
855      REAL(wp)                        , INTENT(in   ) ::   pamsk     ! advection of concentration (1) or other tracers (0)
856      INTEGER                         , INTENT(in   ) ::   kn_umx    ! order of the scheme (1-5=UM or 20=CEN2)
857      REAL(wp)                        , INTENT(in   ) ::   pdt       ! tracer time-step
858      REAL(wp), DIMENSION(:,:  )      , INTENT(in   ) ::   pu        ! ice i-velocity component
859      REAL(wp), DIMENSION(:,:,:)      , INTENT(in   ) ::   pt        ! tracer fields
860      REAL(wp), DIMENSION(jpi,jpj,jpl), INTENT(  out) ::   pt_u      ! tracer at u-point
861      REAL(wp), DIMENSION(jpi,jpj,jpl), INTENT(  out) ::   pfu_ho    ! high order flux
862      !
863      INTEGER  ::   ji, jj, jl             ! dummy loop indices
864      REAL(wp) ::   zcu, zdx2, zdx4        !   -      -
865      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   ztu1, ztu2, ztu3, ztu4
866      !!----------------------------------------------------------------------
867      !
868      !                                                     !--  Laplacian in i-direction  --!
869      DO jl = 1, jpl
870         DO jj = 2, jpjm1         ! First derivative (gradient)
871            DO ji = 1, fs_jpim1
872               ztu1(ji,jj,jl) = ( pt(ji+1,jj,jl) - pt(ji,jj,jl) ) * r1_e1u(ji,jj) * umask(ji,jj,1)
873            END DO
874            !                     ! Second derivative (Laplacian)
875            DO ji = fs_2, fs_jpim1
876               ztu2(ji,jj,jl) = ( ztu1(ji,jj,jl) - ztu1(ji-1,jj,jl) ) * r1_e1t(ji,jj)
877            END DO
878         END DO
879      END DO
880      CALL lbc_lnk( 'icedyn_adv_umx', ztu2, 'T', 1. )
881      !
882      !                                                     !--  BiLaplacian in i-direction  --!
883      DO jl = 1, jpl
884         DO jj = 2, jpjm1         ! Third derivative
885            DO ji = 1, fs_jpim1
886               ztu3(ji,jj,jl) = ( ztu2(ji+1,jj,jl) - ztu2(ji,jj,jl) ) * r1_e1u(ji,jj) * umask(ji,jj,1)
887            END DO
888            !                     ! Fourth derivative
889            DO ji = fs_2, fs_jpim1
890               ztu4(ji,jj,jl) = ( ztu3(ji,jj,jl) - ztu3(ji-1,jj,jl) ) * r1_e1t(ji,jj)
891            END DO
892         END DO
893      END DO
894      CALL lbc_lnk( 'icedyn_adv_umx', ztu4, 'T', 1. )
895      !
896      !
897      SELECT CASE (kn_umx )
898      !
899      CASE( 1 )                                                   !==  1st order central TIM  ==! (Eq. 21)
900         !       
901         DO jl = 1, jpl
902            DO jj = 1, jpjm1
903               DO ji = 1, fs_jpim1   ! vector opt.
904                  pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * (                                pt(ji+1,jj,jl) + pt(ji,jj,jl)   &
905                     &                                         - SIGN( 1._wp, pu(ji,jj) ) * ( pt(ji+1,jj,jl) - pt(ji,jj,jl) ) )
906               END DO
907            END DO
908         END DO
909         !
910      CASE( 2 )                                                   !==  2nd order central TIM  ==! (Eq. 23)
911         !
912         DO jl = 1, jpl
913            DO jj = 1, jpjm1
914               DO ji = 1, fs_jpim1   ! vector opt.
915                  zcu  = pu(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
916                  pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * (                                pt(ji+1,jj,jl) + pt(ji,jj,jl)   &
917                     &                                                            - zcu   * ( pt(ji+1,jj,jl) - pt(ji,jj,jl) ) ) 
918               END DO
919            END DO
920         END DO
921         
922      CASE( 3 )                                                   !==  3rd order central TIM  ==! (Eq. 24)
923         !
924         DO jl = 1, jpl
925            DO jj = 1, jpjm1
926               DO ji = 1, fs_jpim1   ! vector opt.
927                  zcu  = pu(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
928                  zdx2 = e1u(ji,jj) * e1u(ji,jj)
929!!rachid          zdx2 = e1u(ji,jj) * e1t(ji,jj)
930                  pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * (         (                      pt  (ji+1,jj,jl) + pt  (ji,jj,jl)     &
931                     &                                                            - zcu   * ( pt  (ji+1,jj,jl) - pt  (ji,jj,jl) ) ) &
932                     &        + z1_6 * zdx2 * ( zcu*zcu - 1._wp ) *    (                      ztu2(ji+1,jj,jl) + ztu2(ji,jj,jl)     &
933                     &                                               - SIGN( 1._wp, zcu ) * ( ztu2(ji+1,jj,jl) - ztu2(ji,jj,jl) ) ) )
934               END DO
935            END DO
936         END DO
937         !
938      CASE( 4 )                                                   !==  4th order central TIM  ==! (Eq. 27)
939         !
940         DO jl = 1, jpl
941            DO jj = 1, jpjm1
942               DO ji = 1, fs_jpim1   ! vector opt.
943                  zcu  = pu(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
944                  zdx2 = e1u(ji,jj) * e1u(ji,jj)
945!!rachid          zdx2 = e1u(ji,jj) * e1t(ji,jj)
946                  pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * (         (                      pt  (ji+1,jj,jl) + pt  (ji,jj,jl)     &
947                     &                                                            - zcu   * ( pt  (ji+1,jj,jl) - pt  (ji,jj,jl) ) ) &
948                     &        + z1_6 * zdx2 * ( zcu*zcu - 1._wp ) *    (                      ztu2(ji+1,jj,jl) + ztu2(ji,jj,jl)     &
949                     &                                                   - 0.5_wp * zcu   * ( ztu2(ji+1,jj,jl) - ztu2(ji,jj,jl) ) ) )
950               END DO
951            END DO
952         END DO
953         !
954      CASE( 5 )                                                   !==  5th order central TIM  ==! (Eq. 29)
955         !
956         DO jl = 1, jpl
957            DO jj = 1, jpjm1
958               DO ji = 1, fs_jpim1   ! vector opt.
959                  zcu  = pu(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
960                  zdx2 = e1u(ji,jj) * e1u(ji,jj)
961!!rachid          zdx2 = e1u(ji,jj) * e1t(ji,jj)
962                  zdx4 = zdx2 * zdx2
963                  pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * (        (                       pt  (ji+1,jj,jl) + pt  (ji,jj,jl)     &
964                     &                                                            - zcu   * ( pt  (ji+1,jj,jl) - pt  (ji,jj,jl) ) ) &
965                     &        + z1_6   * zdx2 * ( zcu*zcu - 1._wp ) * (                       ztu2(ji+1,jj,jl) + ztu2(ji,jj,jl)     &
966                     &                                                   - 0.5_wp * zcu   * ( ztu2(ji+1,jj,jl) - ztu2(ji,jj,jl) ) ) &
967                     &        + z1_120 * zdx4 * ( zcu*zcu - 1._wp ) * ( zcu*zcu - 4._wp ) * ( ztu4(ji+1,jj,jl) + ztu4(ji,jj,jl)     &
968                     &                                               - SIGN( 1._wp, zcu ) * ( ztu4(ji+1,jj,jl) - ztu4(ji,jj,jl) ) ) )
969               END DO
970            END DO
971         END DO
972         !
973      END SELECT
974      !
975      ! if pt at u-point is negative then use the upstream value
976      !    this should not be necessary if a proper sea-ice mask is set in Ultimate
977      !    to degrade the order of the scheme when necessary (for ex. at the ice edge)
978      IF( ll_neg ) THEN
979         DO jl = 1, jpl
980            DO jj = 1, jpjm1
981               DO ji = 1, fs_jpim1
982                  IF( pt_u(ji,jj,jl) < 0._wp .OR. ( imsk_small(ji,jj,jl) == 0 .AND. pamsk == 0. ) ) THEN
983                     pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * (                                pt(ji+1,jj,jl) + pt(ji,jj,jl)   &
984                        &                                         - SIGN( 1._wp, pu(ji,jj) ) * ( pt(ji+1,jj,jl) - pt(ji,jj,jl) ) )
985                  ENDIF
986               END DO
987            END DO
988         END DO
989      ENDIF
990      !                                                     !-- High order flux in i-direction  --!
991      DO jl = 1, jpl
992         DO jj = 1, jpjm1
993            DO ji = 1, fs_jpim1   ! vector opt.
994               pfu_ho(ji,jj,jl) = pu(ji,jj) * pt_u(ji,jj,jl)
995            END DO
996         END DO
997      END DO
998      !
999   END SUBROUTINE ultimate_x
1000   
1001 
1002   SUBROUTINE ultimate_y( pamsk, kn_umx, pdt, pt, pv, pt_v, pfv_ho )
1003      !!---------------------------------------------------------------------
1004      !!                    ***  ROUTINE ultimate_y  ***
1005      !!     
1006      !! **  Purpose :   compute tracer at v-points
1007      !!
1008      !! **  Method  :   ...
1009      !!
1010      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
1011      !!----------------------------------------------------------------------
1012      REAL(wp)                        , INTENT(in   ) ::   pamsk     ! advection of concentration (1) or other tracers (0)
1013      INTEGER                         , INTENT(in   ) ::   kn_umx    ! order of the scheme (1-5=UM or 20=CEN2)
1014      REAL(wp)                        , INTENT(in   ) ::   pdt       ! tracer time-step
1015      REAL(wp), DIMENSION(:,:  )      , INTENT(in   ) ::   pv        ! ice j-velocity component
1016      REAL(wp), DIMENSION(:,:,:)      , INTENT(in   ) ::   pt        ! tracer fields
1017      REAL(wp), DIMENSION(jpi,jpj,jpl), INTENT(  out) ::   pt_v      ! tracer at v-point
1018      REAL(wp), DIMENSION(jpi,jpj,jpl), INTENT(  out) ::   pfv_ho    ! high order flux
1019      !
1020      INTEGER  ::   ji, jj, jl         ! dummy loop indices
1021      REAL(wp) ::   zcv, zdy2, zdy4    !   -      -
1022      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   ztv1, ztv2, ztv3, ztv4
1023      !!----------------------------------------------------------------------
1024      !
1025      !                                                     !--  Laplacian in j-direction  --!
1026      DO jl = 1, jpl
1027         DO jj = 1, jpjm1         ! First derivative (gradient)
1028            DO ji = fs_2, fs_jpim1
1029               ztv1(ji,jj,jl) = ( pt(ji,jj+1,jl) - pt(ji,jj,jl) ) * r1_e2v(ji,jj) * vmask(ji,jj,1)
1030            END DO
1031         END DO
1032         DO jj = 2, jpjm1         ! Second derivative (Laplacian)
1033            DO ji = fs_2, fs_jpim1
1034               ztv2(ji,jj,jl) = ( ztv1(ji,jj,jl) - ztv1(ji,jj-1,jl) ) * r1_e2t(ji,jj)
1035            END DO
1036         END DO
1037      END DO
1038      CALL lbc_lnk( 'icedyn_adv_umx', ztv2, 'T', 1. )
1039      !
1040      !                                                     !--  BiLaplacian in j-direction  --!
1041      DO jl = 1, jpl
1042         DO jj = 1, jpjm1         ! First derivative
1043            DO ji = fs_2, fs_jpim1
1044               ztv3(ji,jj,jl) = ( ztv2(ji,jj+1,jl) - ztv2(ji,jj,jl) ) * r1_e2v(ji,jj) * vmask(ji,jj,1)
1045            END DO
1046         END DO
1047         DO jj = 2, jpjm1         ! Second derivative
1048            DO ji = fs_2, fs_jpim1
1049               ztv4(ji,jj,jl) = ( ztv3(ji,jj,jl) - ztv3(ji,jj-1,jl) ) * r1_e2t(ji,jj)
1050            END DO
1051         END DO
1052      END DO
1053      CALL lbc_lnk( 'icedyn_adv_umx', ztv4, 'T', 1. )
1054      !
1055      !
1056      SELECT CASE (kn_umx )
1057         !
1058      CASE( 1 )                                                !==  1st order central TIM  ==! (Eq. 21)
1059         DO jl = 1, jpl
1060            DO jj = 1, jpjm1
1061               DO ji = 1, fs_jpim1
1062                  pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * (                                pt(ji,jj+1,jl) + pt(ji,jj,jl)   &
1063                     &                                         - SIGN( 1._wp, pv(ji,jj) ) * ( pt(ji,jj+1,jl) - pt(ji,jj,jl) ) )
1064               END DO
1065            END DO
1066         END DO
1067         !
1068      CASE( 2 )                                                !==  2nd order central TIM  ==! (Eq. 23)
1069         DO jl = 1, jpl
1070            DO jj = 1, jpjm1
1071               DO ji = 1, fs_jpim1
1072                  zcv  = pv(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
1073                  pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * (                                pt(ji,jj+1,jl) + pt(ji,jj,jl)   &
1074                     &                                                            - zcv *   ( pt(ji,jj+1,jl) - pt(ji,jj,jl) ) )
1075               END DO
1076            END DO
1077         END DO
1078         !
1079      CASE( 3 )                                                !==  3rd order central TIM  ==! (Eq. 24)
1080         DO jl = 1, jpl
1081            DO jj = 1, jpjm1
1082               DO ji = 1, fs_jpim1
1083                  zcv  = pv(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
1084                  zdy2 = e2v(ji,jj) * e2v(ji,jj)
1085!!rachid          zdy2 = e2v(ji,jj) * e2t(ji,jj)
1086                  pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * (      (                         pt  (ji,jj+1,jl) + pt  (ji,jj,jl)     &
1087                     &                                                            - zcv   * ( pt  (ji,jj+1,jl) - pt  (ji,jj,jl) ) ) &
1088                     &        + z1_6 * zdy2 * ( zcv*zcv - 1._wp ) * (                         ztv2(ji,jj+1,jl) + ztv2(ji,jj,jl)     &
1089                     &                                               - SIGN( 1._wp, zcv ) * ( ztv2(ji,jj+1,jl) - ztv2(ji,jj,jl) ) ) )
1090               END DO
1091            END DO
1092         END DO
1093         !
1094      CASE( 4 )                                                !==  4th order central TIM  ==! (Eq. 27)
1095         DO jl = 1, jpl
1096            DO jj = 1, jpjm1
1097               DO ji = 1, fs_jpim1
1098                  zcv  = pv(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
1099                  zdy2 = e2v(ji,jj) * e2v(ji,jj)
1100!!rachid          zdy2 = e2v(ji,jj) * e2t(ji,jj)
1101                  pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * (      (                         pt  (ji,jj+1,jl) + pt  (ji,jj,jl)     &
1102                     &                                                            - zcv   * ( pt  (ji,jj+1,jl) - pt  (ji,jj,jl) ) ) &
1103                     &        + z1_6 * zdy2 * ( zcv*zcv - 1._wp ) * (                         ztv2(ji,jj+1,jl) + ztv2(ji,jj,jl)     &
1104                     &                                                   - 0.5_wp * zcv   * ( ztv2(ji,jj+1,jl) - ztv2(ji,jj,jl) ) ) )
1105               END DO
1106            END DO
1107         END DO
1108         !
1109      CASE( 5 )                                                !==  5th order central TIM  ==! (Eq. 29)
1110         DO jl = 1, jpl
1111            DO jj = 1, jpjm1
1112               DO ji = 1, fs_jpim1
1113                  zcv  = pv(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
1114                  zdy2 = e2v(ji,jj) * e2v(ji,jj)
1115!!rachid          zdy2 = e2v(ji,jj) * e2t(ji,jj)
1116                  zdy4 = zdy2 * zdy2
1117                  pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * (                              ( pt  (ji,jj+1,jl) + pt  (ji,jj,jl)     &
1118                     &                                                            - zcv   * ( pt  (ji,jj+1,jl) - pt  (ji,jj,jl) ) ) &
1119                     &        + z1_6   * zdy2 * ( zcv*zcv - 1._wp ) * (                       ztv2(ji,jj+1,jl) + ztv2(ji,jj,jl)     &
1120                     &                                                   - 0.5_wp * zcv   * ( ztv2(ji,jj+1,jl) - ztv2(ji,jj,jl) ) ) &
1121                     &        + z1_120 * zdy4 * ( zcv*zcv - 1._wp ) * ( zcv*zcv - 4._wp ) * ( ztv4(ji,jj+1,jl) + ztv4(ji,jj,jl)     &
1122                     &                                               - SIGN( 1._wp, zcv ) * ( ztv4(ji,jj+1,jl) - ztv4(ji,jj,jl) ) ) )
1123               END DO
1124            END DO
1125         END DO
1126         !
1127      END SELECT
1128      !
1129      ! if pt at v-point is negative then use the upstream value
1130      !    this should not be necessary if a proper sea-ice mask is set in Ultimate
1131      !    to degrade the order of the scheme when necessary (for ex. at the ice edge)
1132      IF( ll_neg ) THEN
1133         DO jl = 1, jpl
1134            DO jj = 1, jpjm1
1135               DO ji = 1, fs_jpim1
1136                  IF( pt_v(ji,jj,jl) < 0._wp .OR. ( jmsk_small(ji,jj,jl) == 0 .AND. pamsk == 0. ) ) THEN
1137                     pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * (                              ( pt(ji,jj+1,jl) + pt(ji,jj,jl) )  &
1138                        &                                         - SIGN( 1._wp, pv(ji,jj) ) * ( pt(ji,jj+1,jl) - pt(ji,jj,jl) ) )
1139                  ENDIF
1140               END DO
1141            END DO
1142         END DO
1143      ENDIF
1144      !                                                     !-- High order flux in j-direction  --!
1145      DO jl = 1, jpl
1146         DO jj = 1, jpjm1
1147            DO ji = 1, fs_jpim1   ! vector opt.
1148               pfv_ho(ji,jj,jl) = pv(ji,jj) * pt_v(ji,jj,jl)
1149            END DO
1150         END DO
1151      END DO
1152      !
1153   END SUBROUTINE ultimate_y
1154     
1155
1156   SUBROUTINE nonosc_ice( pamsk, pdt, pu, pv, pt, pt_ups, pfu_ups, pfv_ups, pfu_ho, pfv_ho )
1157      !!---------------------------------------------------------------------
1158      !!                    ***  ROUTINE nonosc_ice  ***
1159      !!     
1160      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
1161      !!       scheme and the before field by a non-oscillatory algorithm
1162      !!
1163      !! **  Method  :   ...
1164      !!----------------------------------------------------------------------
1165      REAL(wp)                   , INTENT(in   ) ::   pamsk            ! advection of concentration (1) or other tracers (0)
1166      REAL(wp)                   , INTENT(in   ) ::   pdt              ! tracer time-step
1167      REAL(wp), DIMENSION (:,:  ), INTENT(in   ) ::   pu               ! ice i-velocity => u*e2
1168      REAL(wp), DIMENSION (:,:  ), INTENT(in   ) ::   pv               ! ice j-velocity => v*e1
1169      REAL(wp), DIMENSION (:,:,:), INTENT(in   ) ::   pt, pt_ups       ! before field & upstream guess of after field
1170      REAL(wp), DIMENSION (:,:,:), INTENT(in   ) ::   pfv_ups, pfu_ups ! upstream flux
1171      REAL(wp), DIMENSION (:,:,:), INTENT(inout) ::   pfv_ho, pfu_ho   ! monotonic flux
1172      !
1173      INTEGER  ::   ji, jj, jl    ! dummy loop indices
1174      REAL(wp) ::   zpos, zneg, zbig, zup, zdo, z1_dt              ! local scalars
1175      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zcoef, zzt       !   -      -
1176      REAL(wp), DIMENSION(jpi,jpj    ) :: zbup, zbdo
1177      REAL(wp), DIMENSION(jpi,jpj,jpl) :: zbetup, zbetdo, zti_ups, ztj_ups
1178      !!----------------------------------------------------------------------
1179      zbig = 1.e+40_wp
1180     
1181      ! antidiffusive flux : high order minus low order
1182      ! --------------------------------------------------
1183      DO jl = 1, jpl
1184         DO jj = 1, jpjm1
1185            DO ji = 1, fs_jpim1   ! vector opt.
1186               pfu_ho(ji,jj,jl) = pfu_ho(ji,jj,jl) - pfu_ups(ji,jj,jl)
1187               pfv_ho(ji,jj,jl) = pfv_ho(ji,jj,jl) - pfv_ups(ji,jj,jl)
1188            END DO
1189         END DO
1190      END DO
1191
1192      ! extreme case where pfu_ho has to be zero
1193      ! ----------------------------------------
1194      !                                    pfu_ho
1195      !                           *         --->
1196      !                        |      |  *   |        |
1197      !                        |      |      |    *   |   
1198      !                        |      |      |        |    *
1199      !            t_ups :       i-1     i       i+1       i+2   
1200      IF( ll_prelim ) THEN
1201         
1202         DO jl = 1, jpl
1203            DO jj = 2, jpjm1
1204               DO ji = fs_2, fs_jpim1 
1205                  zti_ups(ji,jj,jl)= pt_ups(ji+1,jj  ,jl)
1206                  ztj_ups(ji,jj,jl)= pt_ups(ji  ,jj+1,jl)
1207               END DO
1208            END DO
1209         END DO
1210         CALL lbc_lnk_multi( 'icedyn_adv_umx', zti_ups, 'T', 1., ztj_ups, 'T', 1. )
1211
1212         DO jl = 1, jpl
1213            DO jj = 2, jpjm1
1214               DO ji = fs_2, fs_jpim1
1215                  IF ( pfu_ho(ji,jj,jl) * ( pt_ups(ji+1,jj  ,jl) - pt_ups(ji,jj,jl) ) <= 0._wp .AND.  &
1216                     & pfv_ho(ji,jj,jl) * ( pt_ups(ji  ,jj+1,jl) - pt_ups(ji,jj,jl) ) <= 0._wp ) THEN
1217                     !
1218                     IF(  pfu_ho(ji,jj,jl) * ( zti_ups(ji+1,jj  ,jl) - zti_ups(ji,jj,jl) ) <= 0._wp .AND.  &
1219                        & pfv_ho(ji,jj,jl) * ( ztj_ups(ji  ,jj+1,jl) - ztj_ups(ji,jj,jl) ) <= 0._wp ) THEN
1220                        pfu_ho(ji,jj,jl)=0._wp
1221                        pfv_ho(ji,jj,jl)=0._wp
1222                     ENDIF
1223                     !
1224                     IF(  pfu_ho(ji,jj,jl) * ( pt_ups(ji,jj,jl) - pt_ups(ji-1,jj  ,jl) ) <= 0._wp .AND.  &
1225                        & pfv_ho(ji,jj,jl) * ( pt_ups(ji,jj,jl) - pt_ups(ji  ,jj-1,jl) ) <= 0._wp ) THEN
1226                        pfu_ho(ji,jj,jl)=0._wp
1227                        pfv_ho(ji,jj,jl)=0._wp
1228                     ENDIF
1229                     !
1230                  ENDIF
1231               END DO
1232            END DO
1233         END DO
1234         CALL lbc_lnk_multi( 'icedyn_adv_umx', pfu_ho, 'U', -1., pfv_ho, 'V', -1. )   ! lateral boundary cond.
1235
1236      ENDIF
1237
1238      ! Search local extrema
1239      ! --------------------
1240      ! max/min of pt & pt_ups with large negative/positive value (-/+zbig) outside ice cover
1241      z1_dt = 1._wp / pdt
1242      DO jl = 1, jpl
1243         
1244         DO jj = 1, jpj
1245            DO ji = 1, jpi
1246               IF    ( pt(ji,jj,jl) <= 0._wp .AND. pt_ups(ji,jj,jl) <= 0._wp ) THEN
1247                  zbup(ji,jj) = -zbig
1248                  zbdo(ji,jj) =  zbig
1249               ELSEIF( pt(ji,jj,jl) <= 0._wp .AND. pt_ups(ji,jj,jl) > 0._wp ) THEN
1250                  zbup(ji,jj) = pt_ups(ji,jj,jl)
1251                  zbdo(ji,jj) = pt_ups(ji,jj,jl)
1252               ELSEIF( pt(ji,jj,jl) > 0._wp .AND. pt_ups(ji,jj,jl) <= 0._wp ) THEN
1253                  zbup(ji,jj) = pt(ji,jj,jl)
1254                  zbdo(ji,jj) = pt(ji,jj,jl)
1255               ELSE
1256                  zbup(ji,jj) = MAX( pt(ji,jj,jl) , pt_ups(ji,jj,jl) )
1257                  zbdo(ji,jj) = MIN( pt(ji,jj,jl) , pt_ups(ji,jj,jl) )
1258               ENDIF
1259            END DO
1260         END DO
1261
1262         DO jj = 2, jpjm1
1263            DO ji = fs_2, fs_jpim1   ! vector opt.
1264               !
1265               zup  = MAX( zbup(ji,jj), zbup(ji-1,jj), zbup(ji+1,jj), zbup(ji,jj-1), zbup(ji,jj+1) )  ! search max/min in neighbourhood
1266               zdo  = MIN( zbdo(ji,jj), zbdo(ji-1,jj), zbdo(ji+1,jj), zbdo(ji,jj-1), zbdo(ji,jj+1) )
1267               !
1268               zpos = MAX( 0._wp, pfu_ho(ji-1,jj  ,jl) ) - MIN( 0._wp, pfu_ho(ji  ,jj  ,jl) ) &  ! positive/negative part of the flux
1269                  & + MAX( 0._wp, pfv_ho(ji  ,jj-1,jl) ) - MIN( 0._wp, pfv_ho(ji  ,jj  ,jl) )
1270               zneg = MAX( 0._wp, pfu_ho(ji  ,jj  ,jl) ) - MIN( 0._wp, pfu_ho(ji-1,jj  ,jl) ) &
1271                  & + MAX( 0._wp, pfv_ho(ji  ,jj  ,jl) ) - MIN( 0._wp, pfv_ho(ji  ,jj-1,jl) )
1272               !
1273               zpos = zpos - (pt(ji,jj,jl) * MIN( 0., pu(ji,jj) - pu(ji-1,jj) ) + pt(ji,jj,jl) * MIN( 0., pv(ji,jj) - pv(ji,jj-1) ) &
1274                  &          ) * ( 1. - pamsk )
1275               zneg = zneg + (pt(ji,jj,jl) * MAX( 0., pu(ji,jj) - pu(ji-1,jj) ) + pt(ji,jj,jl) * MAX( 0., pv(ji,jj) - pv(ji,jj-1) ) &
1276                  &          ) * ( 1. - pamsk )
1277               !
1278               !                                  ! up & down beta terms
1279               ! clem: zbetup and zbetdo must be 0 for zpos>1.e-10 & zneg>1.e-10 (do not put 0 instead of 1.e-10 !!!)
1280               IF( zpos > epsi10 ) THEN ; zbetup(ji,jj,jl) = MAX( 0._wp, zup - pt_ups(ji,jj,jl) ) / zpos * e1e2t(ji,jj) * z1_dt
1281               ELSE                     ; zbetup(ji,jj,jl) = 0._wp ! zbig
1282               ENDIF
1283               !
1284               IF( zneg > epsi10 ) THEN ; zbetdo(ji,jj,jl) = MAX( 0._wp, pt_ups(ji,jj,jl) - zdo ) / zneg * e1e2t(ji,jj) * z1_dt
1285               ELSE                     ; zbetdo(ji,jj,jl) = 0._wp ! zbig
1286               ENDIF
1287               !
1288               ! if all the points are outside ice cover
1289               IF( zup == -zbig )   zbetup(ji,jj,jl) = 0._wp ! zbig
1290               IF( zdo ==  zbig )   zbetdo(ji,jj,jl) = 0._wp ! zbig           
1291               !
1292            END DO
1293         END DO
1294      END DO
1295      CALL lbc_lnk_multi( 'icedyn_adv_umx', zbetup, 'T', 1., zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
1296
1297     
1298      ! monotonic flux in the y direction
1299      ! ---------------------------------
1300      DO jl = 1, jpl
1301         DO jj = 1, jpjm1
1302            DO ji = 1, fs_jpim1   ! vector opt.
1303               zau = MIN( 1._wp , zbetdo(ji,jj,jl) , zbetup(ji+1,jj,jl) )
1304               zbu = MIN( 1._wp , zbetup(ji,jj,jl) , zbetdo(ji+1,jj,jl) )
1305               zcu = 0.5_wp + SIGN( 0.5_wp , pfu_ho(ji,jj,jl) )
1306               !
1307               zcoef = ( zcu * zau + ( 1._wp - zcu ) * zbu )
1308               !
1309               pfu_ho(ji,jj,jl) = pfu_ho(ji,jj,jl) * zcoef + pfu_ups(ji,jj,jl)
1310               !
1311            END DO
1312         END DO
1313
1314         DO jj = 1, jpjm1
1315            DO ji = 1, fs_jpim1   ! vector opt.
1316               zav = MIN( 1._wp , zbetdo(ji,jj,jl) , zbetup(ji,jj+1,jl) )
1317               zbv = MIN( 1._wp , zbetup(ji,jj,jl) , zbetdo(ji,jj+1,jl) )
1318               zcv = 0.5_wp + SIGN( 0.5_wp , pfv_ho(ji,jj,jl) )
1319               !
1320               zcoef = ( zcv * zav + ( 1._wp - zcv ) * zbv )
1321               !
1322               pfv_ho(ji,jj,jl) = pfv_ho(ji,jj,jl) * zcoef + pfv_ups(ji,jj,jl)
1323               !
1324            END DO
1325         END DO
1326
1327      END DO
1328      !
1329   END SUBROUTINE nonosc_ice
1330
1331   
1332   SUBROUTINE limiter_x( pdt, pu, pt, pfu_ups, pfu_ho )
1333      !!---------------------------------------------------------------------
1334      !!                    ***  ROUTINE limiter_x  ***
1335      !!     
1336      !! **  Purpose :   compute flux limiter
1337      !!----------------------------------------------------------------------
1338      REAL(wp)                  , INTENT(in   ) ::   pdt          ! tracer time-step
1339      REAL(wp), DIMENSION(:,:  ), INTENT(in   ) ::   pu           ! ice i-velocity => u*e2
1340      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pt           ! ice tracer
1341      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pfu_ups      ! upstream flux
1342      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pfu_ho       ! high order flux
1343      !
1344      REAL(wp) ::   Cr, Rjm, Rj, Rjp, uCFL, zpsi, zh3, zlimiter, Rr
1345      INTEGER  ::   ji, jj, jl    ! dummy loop indices
1346      REAL(wp), DIMENSION (jpi,jpj,jpl) ::   zslpx       ! tracer slopes
1347      !!----------------------------------------------------------------------
1348      !
1349      DO jl = 1, jpl
1350         DO jj = 2, jpjm1
1351            DO ji = fs_2, fs_jpim1   ! vector opt.
1352               zslpx(ji,jj,jl) = ( pt(ji+1,jj,jl) - pt(ji,jj,jl) ) * umask(ji,jj,1)
1353            END DO
1354         END DO
1355      END DO
1356      CALL lbc_lnk( 'icedyn_adv_umx', zslpx, 'U', -1.)   ! lateral boundary cond.
1357     
1358      DO jl = 1, jpl
1359         DO jj = 2, jpjm1
1360            DO ji = fs_2, fs_jpim1   ! vector opt.
1361               uCFL = pdt * ABS( pu(ji,jj) ) * r1_e1e2t(ji,jj)
1362               
1363               Rjm = zslpx(ji-1,jj,jl)
1364               Rj  = zslpx(ji  ,jj,jl)
1365               Rjp = zslpx(ji+1,jj,jl)
1366
1367               IF( np_limiter == 3 ) THEN
1368
1369                  IF( pu(ji,jj) > 0. ) THEN   ;   Rr = Rjm
1370                  ELSE                        ;   Rr = Rjp
1371                  ENDIF
1372
1373                  zh3 = pfu_ho(ji,jj,jl) - pfu_ups(ji,jj,jl)     
1374                  IF( Rj > 0. ) THEN
1375                     zlimiter =  MAX( 0., MIN( zh3, MAX(-Rr * 0.5 * ABS(pu(ji,jj)),  &
1376                        &        MIN( 2. * Rr * 0.5 * ABS(pu(ji,jj)),  zh3,  1.5 * Rj * 0.5 * ABS(pu(ji,jj)) ) ) ) )
1377                  ELSE
1378                     zlimiter = -MAX( 0., MIN(-zh3, MAX( Rr * 0.5 * ABS(pu(ji,jj)),  &
1379                        &        MIN(-2. * Rr * 0.5 * ABS(pu(ji,jj)), -zh3, -1.5 * Rj * 0.5 * ABS(pu(ji,jj)) ) ) ) )
1380                  ENDIF
1381                  pfu_ho(ji,jj,jl) = pfu_ups(ji,jj,jl) + zlimiter
1382
1383               ELSEIF( np_limiter == 2 ) THEN
1384                  IF( Rj /= 0. ) THEN
1385                     IF( pu(ji,jj) > 0. ) THEN   ;   Cr = Rjm / Rj
1386                     ELSE                        ;   Cr = Rjp / Rj
1387                     ENDIF
1388                  ELSE
1389                     Cr = 0.
1390                  ENDIF
1391
1392                  ! -- superbee --
1393                  zpsi = MAX( 0., MAX( MIN(1.,2.*Cr), MIN(2.,Cr) ) )
1394                  ! -- van albada 2 --
1395                  !!zpsi = 2.*Cr / (Cr*Cr+1.)
1396                  ! -- sweby (with beta=1) --
1397                  !!zpsi = MAX( 0., MAX( MIN(1.,1.*Cr), MIN(1.,Cr) ) )
1398                  ! -- van Leer --
1399                  !!zpsi = ( Cr + ABS(Cr) ) / ( 1. + ABS(Cr) )
1400                  ! -- ospre --
1401                  !!zpsi = 1.5 * ( Cr*Cr + Cr ) / ( Cr*Cr + Cr + 1. )
1402                  ! -- koren --
1403                  !!zpsi = MAX( 0., MIN( 2.*Cr, MIN( (1.+2*Cr)/3., 2. ) ) )
1404                  ! -- charm --
1405                  !IF( Cr > 0. ) THEN   ;   zpsi = Cr * (3.*Cr + 1.) / ( (Cr + 1.) * (Cr + 1.) )
1406                  !ELSE                 ;   zpsi = 0.
1407                  !ENDIF
1408                  ! -- van albada 1 --
1409                  !!zpsi = (Cr*Cr + Cr) / (Cr*Cr +1)
1410                  ! -- smart --
1411                  !!zpsi = MAX( 0., MIN( 2.*Cr, MIN( 0.25+0.75*Cr, 4. ) ) )
1412                  ! -- umist --
1413                  !!zpsi = MAX( 0., MIN( 2.*Cr, MIN( 0.25+0.75*Cr, MIN(0.75+0.25*Cr, 2. ) ) ) )
1414
1415                  ! high order flux corrected by the limiter
1416                  pfu_ho(ji,jj,jl) = pfu_ho(ji,jj,jl) - ABS( pu(ji,jj) ) * ( (1.-zpsi) + uCFL*zpsi ) * Rj * 0.5
1417
1418               ENDIF
1419            END DO
1420         END DO
1421      END DO
1422      CALL lbc_lnk( 'icedyn_adv_umx', pfu_ho, 'U', -1.)   ! lateral boundary cond.
1423      !
1424   END SUBROUTINE limiter_x
1425
1426   
1427   SUBROUTINE limiter_y( pdt, pv, pt, pfv_ups, pfv_ho )
1428      !!---------------------------------------------------------------------
1429      !!                    ***  ROUTINE limiter_y  ***
1430      !!     
1431      !! **  Purpose :   compute flux limiter
1432      !!----------------------------------------------------------------------
1433      REAL(wp)                   , INTENT(in   ) ::   pdt          ! tracer time-step
1434      REAL(wp), DIMENSION (:,:  ), INTENT(in   ) ::   pv           ! ice i-velocity => u*e2
1435      REAL(wp), DIMENSION (:,:,:), INTENT(in   ) ::   pt           ! ice tracer
1436      REAL(wp), DIMENSION (:,:,:), INTENT(in   ) ::   pfv_ups      ! upstream flux
1437      REAL(wp), DIMENSION (:,:,:), INTENT(inout) ::   pfv_ho       ! high order flux
1438      !
1439      REAL(wp) ::   Cr, Rjm, Rj, Rjp, vCFL, zpsi, zh3, zlimiter, Rr
1440      INTEGER  ::   ji, jj, jl    ! dummy loop indices
1441      REAL(wp), DIMENSION (jpi,jpj,jpl) ::   zslpy       ! tracer slopes
1442      !!----------------------------------------------------------------------
1443      !
1444      DO jl = 1, jpl
1445         DO jj = 2, jpjm1
1446            DO ji = fs_2, fs_jpim1   ! vector opt.
1447               zslpy(ji,jj,jl) = ( pt(ji,jj+1,jl) - pt(ji,jj,jl) ) * vmask(ji,jj,1)
1448            END DO
1449         END DO
1450      END DO
1451      CALL lbc_lnk( 'icedyn_adv_umx', zslpy, 'V', -1.)   ! lateral boundary cond.
1452
1453      DO jl = 1, jpl
1454         DO jj = 2, jpjm1
1455            DO ji = fs_2, fs_jpim1   ! vector opt.
1456               vCFL = pdt * ABS( pv(ji,jj) ) * r1_e1e2t(ji,jj)
1457
1458               Rjm = zslpy(ji,jj-1,jl)
1459               Rj  = zslpy(ji,jj  ,jl)
1460               Rjp = zslpy(ji,jj+1,jl)
1461
1462               IF( np_limiter == 3 ) THEN
1463
1464                  IF( pv(ji,jj) > 0. ) THEN   ;   Rr = Rjm
1465                  ELSE                        ;   Rr = Rjp
1466                  ENDIF
1467
1468                  zh3 = pfv_ho(ji,jj,jl) - pfv_ups(ji,jj,jl)     
1469                  IF( Rj > 0. ) THEN
1470                     zlimiter =  MAX( 0., MIN( zh3, MAX(-Rr * 0.5 * ABS(pv(ji,jj)),  &
1471                        &        MIN( 2. * Rr * 0.5 * ABS(pv(ji,jj)),  zh3,  1.5 * Rj * 0.5 * ABS(pv(ji,jj)) ) ) ) )
1472                  ELSE
1473                     zlimiter = -MAX( 0., MIN(-zh3, MAX( Rr * 0.5 * ABS(pv(ji,jj)),  &
1474                        &        MIN(-2. * Rr * 0.5 * ABS(pv(ji,jj)), -zh3, -1.5 * Rj * 0.5 * ABS(pv(ji,jj)) ) ) ) )
1475                  ENDIF
1476                  pfv_ho(ji,jj,jl) = pfv_ups(ji,jj,jl) + zlimiter
1477
1478               ELSEIF( np_limiter == 2 ) THEN
1479
1480                  IF( Rj /= 0. ) THEN
1481                     IF( pv(ji,jj) > 0. ) THEN   ;   Cr = Rjm / Rj
1482                     ELSE                        ;   Cr = Rjp / Rj
1483                     ENDIF
1484                  ELSE
1485                     Cr = 0.
1486                  ENDIF
1487
1488                  ! -- superbee --
1489                  zpsi = MAX( 0., MAX( MIN(1.,2.*Cr), MIN(2.,Cr) ) )
1490                  ! -- van albada 2 --
1491                  !!zpsi = 2.*Cr / (Cr*Cr+1.)
1492                  ! -- sweby (with beta=1) --
1493                  !!zpsi = MAX( 0., MAX( MIN(1.,1.*Cr), MIN(1.,Cr) ) )
1494                  ! -- van Leer --
1495                  !!zpsi = ( Cr + ABS(Cr) ) / ( 1. + ABS(Cr) )
1496                  ! -- ospre --
1497                  !!zpsi = 1.5 * ( Cr*Cr + Cr ) / ( Cr*Cr + Cr + 1. )
1498                  ! -- koren --
1499                  !!zpsi = MAX( 0., MIN( 2.*Cr, MIN( (1.+2*Cr)/3., 2. ) ) )
1500                  ! -- charm --
1501                  !IF( Cr > 0. ) THEN   ;   zpsi = Cr * (3.*Cr + 1.) / ( (Cr + 1.) * (Cr + 1.) )
1502                  !ELSE                 ;   zpsi = 0.
1503                  !ENDIF
1504                  ! -- van albada 1 --
1505                  !!zpsi = (Cr*Cr + Cr) / (Cr*Cr +1)
1506                  ! -- smart --
1507                  !!zpsi = MAX( 0., MIN( 2.*Cr, MIN( 0.25+0.75*Cr, 4. ) ) )
1508                  ! -- umist --
1509                  !!zpsi = MAX( 0., MIN( 2.*Cr, MIN( 0.25+0.75*Cr, MIN(0.75+0.25*Cr, 2. ) ) ) )
1510
1511                  ! high order flux corrected by the limiter
1512                  pfv_ho(ji,jj,jl) = pfv_ho(ji,jj,jl) - ABS( pv(ji,jj) ) * ( (1.-zpsi) + vCFL*zpsi ) * Rj * 0.5
1513
1514               ENDIF
1515            END DO
1516         END DO
1517      END DO
1518      CALL lbc_lnk( 'icedyn_adv_umx', pfv_ho, 'V', -1.)   ! lateral boundary cond.
1519      !
1520   END SUBROUTINE limiter_y
1521
1522
1523   SUBROUTINE Hbig( pdt, phi_max, phs_max, phip_max, pv_i, pv_s, psv_i, poa_i, pa_i, pa_ip, pv_ip, pe_s, pe_i )
1524      !!-------------------------------------------------------------------
1525      !!                  ***  ROUTINE Hbig  ***
1526      !!
1527      !! ** Purpose : Thickness correction in case advection scheme creates
1528      !!              abnormally thick ice or snow
1529      !!
1530      !! ** Method  : 1- check whether ice thickness is larger than the surrounding 9-points
1531      !!                 (before advection) and reduce it by adapting ice concentration
1532      !!              2- check whether snow thickness is larger than the surrounding 9-points
1533      !!                 (before advection) and reduce it by sending the excess in the ocean
1534      !!              3- check whether snow load deplets the snow-ice interface below sea level$
1535      !!                 and reduce it by sending the excess in the ocean
1536      !!              4- correct pond concentration to avoid a_ip > a_i
1537      !!
1538      !! ** input   : Max thickness of the surrounding 9-points
1539      !!-------------------------------------------------------------------
1540      REAL(wp)                    , INTENT(in   ) ::   pdt                          ! tracer time-step
1541      REAL(wp), DIMENSION(:,:,:)  , INTENT(in   ) ::   phi_max, phs_max, phip_max   ! max ice thick from surrounding 9-pts
1542      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_i, pv_s, psv_i, poa_i, pa_i, pa_ip, pv_ip
1543      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) ::   pe_s
1544      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) ::   pe_i
1545      !
1546      INTEGER  ::   ji, jj, jk, jl         ! dummy loop indices
1547      REAL(wp) ::   z1_dt, zhip, zhi, zhs, zvs_excess, zfra
1548      REAL(wp), DIMENSION(jpi,jpj) ::   zswitch
1549      !!-------------------------------------------------------------------
1550      !
1551      z1_dt = 1._wp / pdt
1552      !
1553      DO jl = 1, jpl
1554
1555         DO jj = 1, jpj
1556            DO ji = 1, jpi
1557               IF ( pv_i(ji,jj,jl) > 0._wp ) THEN
1558                  !
1559                  !                               ! -- check h_ip -- !
1560                  ! if h_ip is larger than the surrounding 9 pts => reduce h_ip and increase a_ip
1561                  IF( ln_pnd_H12 .AND. pv_ip(ji,jj,jl) > 0._wp ) THEN
1562                     zhip = pv_ip(ji,jj,jl) / MAX( epsi20, pa_ip(ji,jj,jl) )
1563                     IF( zhip > phip_max(ji,jj,jl) .AND. pa_ip(ji,jj,jl) < 0.15 ) THEN
1564                        pa_ip(ji,jj,jl) = pv_ip(ji,jj,jl) / phip_max(ji,jj,jl)
1565                     ENDIF
1566                  ENDIF
1567                  !
1568                  !                               ! -- check h_i -- !
1569                  ! if h_i is larger than the surrounding 9 pts => reduce h_i and increase a_i
1570                  zhi = pv_i(ji,jj,jl) / pa_i(ji,jj,jl)
1571                  IF( zhi > phi_max(ji,jj,jl) .AND. pa_i(ji,jj,jl) < 0.15 ) THEN
1572                     pa_i(ji,jj,jl) = pv_i(ji,jj,jl) / MIN( phi_max(ji,jj,jl), hi_max(jpl) )   !-- bound h_i to hi_max (99 m)
1573                  ENDIF
1574                  !
1575                  !                               ! -- check h_s -- !
1576                  ! if h_s is larger than the surrounding 9 pts => put the snow excess in the ocean
1577                  zhs = pv_s(ji,jj,jl) / pa_i(ji,jj,jl)
1578                  IF( pv_s(ji,jj,jl) > 0._wp .AND. zhs > phs_max(ji,jj,jl) .AND. pa_i(ji,jj,jl) < 0.15 ) THEN
1579                     zfra = phs_max(ji,jj,jl) / MAX( zhs, epsi20 )
1580                     !
1581                     wfx_res(ji,jj) = wfx_res(ji,jj) + ( pv_s(ji,jj,jl) - pa_i(ji,jj,jl) * phs_max(ji,jj,jl) ) * rhos * z1_dt
1582                     hfx_res(ji,jj) = hfx_res(ji,jj) - SUM( pe_s(ji,jj,1:nlay_s,jl) ) * ( 1._wp - zfra ) * z1_dt ! W.m-2 <0
1583                     !
1584                     pe_s(ji,jj,1:nlay_s,jl) = pe_s(ji,jj,1:nlay_s,jl) * zfra
1585                     pv_s(ji,jj,jl)          = pa_i(ji,jj,jl) * phs_max(ji,jj,jl)
1586                  ENDIF           
1587                  !
1588                  !                               ! -- check snow load -- !
1589                  ! if snow load makes snow-ice interface to deplet below the ocean surface => put the snow excess in the ocean
1590                  !    this correction is crucial because of the call to routine icecor afterwards which imposes a mini of ice thick. (rn_himin)
1591                  !    this imposed mini can artificially make the snow very thick (if concentration decreases drastically)
1592                  zvs_excess = MAX( 0._wp, pv_s(ji,jj,jl) - pv_i(ji,jj,jl) * (rau0-rhoi) * r1_rhos )
1593                  IF( zvs_excess > 0._wp ) THEN
1594                     zfra = ( pv_s(ji,jj,jl) - zvs_excess ) / MAX( pv_s(ji,jj,jl), epsi20 )
1595                     wfx_res(ji,jj) = wfx_res(ji,jj) + zvs_excess * rhos * z1_dt
1596                     hfx_res(ji,jj) = hfx_res(ji,jj) - SUM( pe_s(ji,jj,1:nlay_s,jl) ) * ( 1._wp - zfra ) * z1_dt ! W.m-2 <0
1597                     !
1598                     pe_s(ji,jj,1:nlay_s,jl) = pe_s(ji,jj,1:nlay_s,jl) * zfra
1599                     pv_s(ji,jj,jl)          = pv_s(ji,jj,jl) - zvs_excess
1600                  ENDIF
1601                 
1602               ENDIF
1603            END DO
1604         END DO
1605      END DO 
1606      !                                           !-- correct pond concentration to avoid a_ip > a_i
1607      WHERE( pa_ip(:,:,:) > pa_i(:,:,:) )   pa_ip(:,:,:) = pa_i(:,:,:)
1608      !
1609      !
1610   END SUBROUTINE Hbig
1611   
1612#else
1613   !!----------------------------------------------------------------------
1614   !!   Default option           Dummy module         NO SI3 sea-ice model
1615   !!----------------------------------------------------------------------
1616#endif
1617
1618   !!======================================================================
1619END MODULE icedyn_adv_umx
Note: See TracBrowser for help on using the repository browser.