Context Navigation

nemogcm.F90

Last change on this file was 13771, checked in by dancopsey, 4 years ago
Merge in version NEMO_4.0.1 version of this branch.
File size: 35.8 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! - ! 2011-11 (C. Harris) decomposition changes for running with CICE
31	!! 3.6 ! 2012-05 (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32	!! - ! 2014-12 (G. Madec) remove KPP scheme and cross-land advection (cla)
33	!! 4.0 ! 2016-10 (G. Madec, S. Flavoni) domain configuration / user defined interface
34	!!----------------------------------------------------------------------
35
36	!!----------------------------------------------------------------------
37	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38	!! nemo_init : initialization of the NEMO system
39	!! nemo_ctl : initialisation of the contol print
40	!! nemo_closefile: close remaining open files
41	!! nemo_alloc : dynamical allocation
42	!!----------------------------------------------------------------------
43	USE step_oce ! module used in the ocean time stepping module (step.F90)
44	USE phycst ! physical constant (par_cst routine)
45	USE domain ! domain initialization (dom_init & dom_cfg routines)
46	USE closea ! treatment of closed seas (for ln_closea)
47	USE usrdef_nam ! user defined configuration
48	USE tideini ! tidal components initialization (tide_ini routine)
49	USE bdy_oce, ONLY : ln_bdy
50	USE bdyini ! open boundary cond. setting (bdy_init routine)
51	USE istate ! initial state setting (istate_init routine)
52	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
53	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
54	USE trdini ! dyn/tra trends initialization (trd_init routine)
55	USE asminc ! assimilation increments
56	USE asmbkg ! writing out state trajectory
57	USE diaptr ! poleward transports (dia_ptr_init routine)
58	USE diadct ! sections transports (dia_dct_init routine)
59	USE diaobs ! Observation diagnostics (dia_obs_init routine)
60	USE diacfl ! CFL diagnostics (dia_cfl_init routine)
61	USE diaharm ! tidal harmonics diagnostics (dia_harm_init routine)
62	USE step ! NEMO time-stepping (stp routine)
63	USE icbini ! handle bergs, initialisation
64	USE icbstp ! handle bergs, calving, themodynamics and transport
65	USE cpl_oasis3 ! OASIS3 coupling
66	USE c1d ! 1D configuration
67	USE step_c1d ! Time stepping loop for the 1D configuration
68	USE dyndmp ! Momentum damping
69	USE stopar ! Stochastic param.: ???
70	USE stopts ! Stochastic param.: ???
71	USE diurnal_bulk ! diurnal bulk SST
72	USE step_diu ! diurnal bulk SST timestepping (called from here if run offline)
73	USE crsini ! initialise grid coarsening utility
74	USE dia25h ! 25h mean output
75	USE sbc_oce , ONLY : lk_oasis
76	USE wet_dry ! Wetting and drying setting (wad_init routine)
77	#if defined key_top
78	USE trcini ! passive tracer initialisation
79	#endif
80	#if defined key_nemocice_decomp
81	USE ice_domain_size, only: nx_global, ny_global
82	#endif
83	!
84	USE in_out_manager ! I/O manager
85	USE lib_mpp ! distributed memory computing
86	USE mppini ! shared/distributed memory setting (mpp_init routine)
87	USE lbcnfd , ONLY : isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
88	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
89	USE sbccpl
90	#if defined key_iomput
91	USE xios ! xIOserver
92	#endif
93	#if defined key_agrif
94	USE agrif_all_update ! Master Agrif update
95	#endif
96
97	IMPLICIT NONE
98	PRIVATE
99
100	PUBLIC nemo_gcm ! called by model.F90
101	PUBLIC nemo_init ! needed by AGRIF
102	PUBLIC nemo_alloc ! needed by TAM
103
104	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
105
106	#if defined key_mpp_mpi
107	! need MPI_Wtime
108	INCLUDE 'mpif.h'
109	#endif
110
111	!!----------------------------------------------------------------------
112	!! NEMO/OCE 4.0 , NEMO Consortium (2018)
113	!! $Id$
114	!! Software governed by the CeCILL license (see ./LICENSE)
115	!!----------------------------------------------------------------------
116	CONTAINS
117
118	SUBROUTINE nemo_gcm
119	!!----------------------------------------------------------------------
120	!! * ROUTINE nemo_gcm *
121	!!
122	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
123	!! curvilinear mesh on the sphere.
124	!!
125	!! ** Method : - model general initialization
126	!! - launch the time-stepping (stp routine)
127	!! - finalize the run by closing files and communications
128	!!
129	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
130	!! Madec, 2008, internal report, IPSL.
131	!!----------------------------------------------------------------------
132	INTEGER :: istp ! time step index
133	REAL(wp):: zstptiming ! elapsed time for 1 time step
134	!!----------------------------------------------------------------------
135	!
136	#if defined key_agrif
137	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
138	#endif
139	! !-----------------------!
140	CALL nemo_init !== Initialisations ==!
141	! !-----------------------!
142	#if defined key_agrif
143	CALL Agrif_Declare_Var_dom ! AGRIF: set the meshes for DOM
144	CALL Agrif_Declare_Var ! " " " " " DYN/TRA
145	# if defined key_top
146	CALL Agrif_Declare_Var_top ! " " " " " TOP
147	# endif
148	# if defined key_si3
149	CALL Agrif_Declare_Var_ice ! " " " " " Sea ice
150	# endif
151	#endif
152	! check that all process are still there... If some process have an error,
153	! they will never enter in step and other processes will wait until the end of the cpu time!
154	CALL mpp_max( 'nemogcm', nstop )
155
156	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
157
158	! !-----------------------!
159	! !== time stepping ==!
160	! !-----------------------!
161	istp = nit000
162	!
163	#if defined key_c1d
164	DO WHILE ( istp <= nitend .AND. nstop == 0 ) !== C1D time-stepping ==!
165	CALL stp_c1d( istp )
166	istp = istp + 1
167	END DO
168	#else
169	!
170	# if defined key_agrif
171	! !== AGRIF time-stepping ==!
172	CALL Agrif_Regrid()
173	!
174	! Recursive update from highest nested level to lowest:
175	CALL Agrif_step_child_adj(Agrif_Update_All)
176	!
177	DO WHILE( istp <= nitend .AND. nstop == 0 )
178	CALL stp
179	istp = istp + 1
180	END DO
181	!
182	# else
183	!
184	IF( .NOT.ln_diurnal_only ) THEN !== Standard time-stepping ==!
185	!
186	DO WHILE( istp <= nitend .AND. nstop == 0 )
187
188	ncom_stp = istp
189	IF( ln_timing ) THEN
190	zstptiming = MPI_Wtime()
191	IF ( istp == ( nit000 + 1 ) ) elapsed_time = zstptiming
192	IF ( istp == nitend ) elapsed_time = zstptiming - elapsed_time
193	ENDIF
194
195	IF (lk_oasis) THEN
196	CALL sbc_cpl_snd( istp ) ! Coupling to atmos
197	ENDIF
198	CALL stp ( istp )
199	istp = istp + 1
200
201	IF( lwp .AND. ln_timing ) WRITE(numtime,*) 'timing step ', istp-1, ' : ', MPI_Wtime() - zstptiming
202
203	END DO
204	!
205	ELSE !== diurnal SST time-steeping only ==!
206	!
207	DO WHILE( istp <= nitend .AND. nstop == 0 )
208	CALL stp_diurnal( istp ) ! time step only the diurnal SST
209	istp = istp + 1
210	END DO
211	!
212	ENDIF
213	!
214	# endif
215	!
216	#endif
217	!
218	IF( ln_diaobs ) CALL dia_obs_wri
219	!
220	IF( ln_icebergs ) CALL icb_end( nitend )
221
222	! !------------------------!
223	! !== finalize the run ==!
224	! !------------------------!
225	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
226	!
227	IF( nstop /= 0 .AND. lwp ) THEN ! error print
228	WRITE(ctmp1,*) ' ==>>> nemo_gcm: a total of ', nstop, ' errors have been found'
229	IF( ngrdstop > 0 ) THEN
230	WRITE(ctmp9,'(i2)') ngrdstop
231	WRITE(ctmp2,*) ' E R R O R detected in Agrif grid '//TRIM(ctmp9)
232	WRITE(ctmp3,) ' Look for "E R R O R" messages in all existing '//TRIM(ctmp9)//'_ocean_output files'
233	CALL ctl_stop( ' ', ctmp1, ' ', ctmp2, ' ', ctmp3 )
234	ELSE
235	WRITE(ctmp2,) ' Look for "E R R O R" messages in all existing ocean_output files'
236	CALL ctl_stop( ' ', ctmp1, ' ', ctmp2 )
237	ENDIF
238	ENDIF
239	!
240	IF( ln_timing ) CALL timing_finalize
241	!
242	CALL nemo_closefile
243	!
244	#if defined key_iomput
245	CALL xios_finalize ! end mpp communications with xios
246	IF( lk_oasis ) CALL cpl_finalize ! end coupling and mpp communications with OASIS
247	#else
248	IF ( lk_oasis ) THEN ; CALL cpl_finalize ! end coupling and mpp communications with OASIS
249	ELSEIF( lk_mpp ) THEN ; CALL mppstop ! end mpp communications
250	ENDIF
251	#endif
252	!
253	IF(lwm) THEN
254	IF( nstop == 0 ) THEN ; STOP 0
255	ELSE ; STOP 123
256	ENDIF
257	ENDIF
258	!
259	END SUBROUTINE nemo_gcm
260
261
262	SUBROUTINE nemo_init
263	!!----------------------------------------------------------------------
264	!! * ROUTINE nemo_init *
265	!!
266	!! ** Purpose : initialization of the NEMO GCM
267	!!----------------------------------------------------------------------
268	INTEGER :: ios, ilocal_comm ! local integers
269	!!
270	NAMELIST/namctl/ ln_ctl , sn_cfctl, nn_print, nn_ictls, nn_ictle, &
271	& nn_isplt , nn_jsplt, nn_jctls, nn_jctle, &
272	& ln_timing, ln_diacfl
273	NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
274	!!----------------------------------------------------------------------
275	!
276	cxios_context = 'nemo'
277	!
278	! !-------------------------------------------------!
279	! ! set communicator & select the local rank !
280	! ! must be done as soon as possible to get narea !
281	! !-------------------------------------------------!
282	!
283	#if defined key_iomput
284	IF( Agrif_Root() ) THEN
285	IF( lk_oasis ) THEN
286	CALL cpl_init( "toyoce", ilocal_comm ) ! nemo local communicator given by oasis
287	CALL xios_initialize( "not used" , local_comm =ilocal_comm ) ! send nemo communicator to xios
288	ELSE
289	CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm ) ! nemo local communicator given by xios
290	ENDIF
291	ENDIF
292	CALL mpp_start( ilocal_comm )
293	#else
294	IF( lk_oasis ) THEN
295	IF( Agrif_Root() ) THEN
296	CALL cpl_init( "toyoce", ilocal_comm ) ! nemo local communicator given by oasis
297	ENDIF
298	CALL mpp_start( ilocal_comm )
299	ELSE
300	CALL mpp_start( )
301	ENDIF
302	#endif
303	!
304	narea = mpprank + 1 ! mpprank: the rank of proc (0 --> mppsize -1 )
305	lwm = (narea == 1) ! control of output namelists
306	!
307	! !---------------------------------------------------------------!
308	! ! Open output files, reference and configuration namelist files !
309	! !---------------------------------------------------------------!
310	!
311	! open ocean.output as soon as possible to get all output prints (including errors messages)
312	IF( lwm ) CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
313	! open reference and configuration namelist files
314	CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
315	CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
316	IF( lwm ) CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
317	! open /dev/null file to be able to supress output write easily
318	IF( Agrif_Root() ) THEN
319	CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
320	#ifdef key_agrif
321	ELSE
322	numnul = Agrif_Parent(numnul)
323	#endif
324	ENDIF
325	!
326	! !--------------------!
327	! ! Open listing units ! -> need ln_ctl from namctl to define lwp
328	! !--------------------!
329	!
330	REWIND( numnam_ref ) ! Namelist namctl in reference namelist
331	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
332	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist' )
333	REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist
334	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
335	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist' )
336	!
337	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
338	!
339	IF(lwp) THEN ! open listing units
340	!
341	IF( .NOT. lwm ) & ! alreay opened for narea == 1
342	& CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
343	!
344	WRITE(numout,*)
345	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
346	WRITE(numout,*) ' NEMO team'
347	WRITE(numout,*) ' Ocean General Circulation Model'
348	WRITE(numout,*) ' NEMO version 4.0 (2019) '
349	WRITE(numout,*)
350	WRITE(numout,*) " ._ ._ ._ ._ ._ "
351	WRITE(numout,*) " _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
352	WRITE(numout,*)
353	WRITE(numout,*) " o _, _, "
354	WRITE(numout,*) " o .' ( .-' / "
355	WRITE(numout,*) " o _/..._'. .' / "
356	WRITE(numout,*) " ( o .-'` ` '-./ _.' "
357	WRITE(numout,*) " ) ( o) ;= <_ ( "
358	WRITE(numout,*) " ( '-.,\\__ __.-;`\ '. ) "
359	WRITE(numout,*) " ) ) \) \|`\ \) '. \ ( ( "
360	WRITE(numout,*) " ( ( \_/ '-._\ ) ) "
361	WRITE(numout,*) " ) ) jgs ` ( ( "
362	WRITE(numout,*) " ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
363	WRITE(numout,*)
364	!
365	WRITE(numout,cform_aaa) ! Flag AAAAAAA
366	!
367	ENDIF
368	!
369	! finalize the definition of namctl variables
370	IF( sn_cfctl%l_config ) THEN
371	! Activate finer control of report outputs
372	! optionally switch off output from selected areas (note this only
373	! applies to output which does not involve global communications)
374	IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax ) .OR. &
375	& ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) ) &
376	& CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
377	ELSE
378	! Use ln_ctl to turn on or off all options.
379	CALL nemo_set_cfctl( sn_cfctl, ln_ctl, .TRUE. )
380	ENDIF
381	!
382	IF(lwm) WRITE( numond, namctl )
383	!
384	! !------------------------------------!
385	! ! Set global domain size parameters !
386	! !------------------------------------!
387	!
388	REWIND( numnam_ref ) ! Namelist namcfg in reference namelist
389	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
390	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist' )
391	REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist
392	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
393	904 IF( ios > 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist' )
394	!
395	IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file
396	CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
397	ELSE ! user-defined namelist
398	CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
399	ENDIF
400	!
401	IF(lwm) WRITE( numond, namcfg )
402	!
403	! !-----------------------------------------!
404	! ! mpp parameters and domain decomposition !
405	! !-----------------------------------------!
406	CALL mpp_init
407
408	! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
409	CALL nemo_alloc()
410
411	! !-------------------------------!
412	! ! NEMO general initialization !
413	! !-------------------------------!
414
415	CALL nemo_ctl ! Control prints
416	!
417	! ! General initialization
418	IF( ln_timing ) CALL timing_init ! timing
419	IF( ln_timing ) CALL timing_start( 'nemo_init')
420	!
421	CALL phy_cst ! Physical constants
422	CALL eos_init ! Equation of state
423	IF( lk_c1d ) CALL c1d_init ! 1D column configuration
424	CALL wad_init ! Wetting and drying options
425	CALL dom_init("OPA") ! Domain
426	IF( ln_crs ) CALL crs_init ! coarsened grid: domain initialization
427	IF( ln_ctl ) CALL prt_ctl_init ! Print control
428
429	CALL diurnal_sst_bulk_init ! diurnal sst
430	IF( ln_diurnal ) CALL diurnal_sst_coolskin_init ! cool skin
431	!
432	IF( ln_diurnal_only ) THEN ! diurnal only: a subset of the initialisation routines
433	CALL istate_init ! ocean initial state (Dynamics and tracers)
434	CALL sbc_init ! Forcings : surface module
435	CALL tra_qsr_init ! penetrative solar radiation qsr
436	IF( ln_diaobs ) THEN ! Observation & model comparison
437	CALL dia_obs_init ! Initialize observational data
438	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
439	ENDIF
440	IF( lk_asminc ) CALL asm_inc_init ! Assimilation increments
441	!
442	RETURN ! end of initialization
443	ENDIF
444
445	CALL istate_init ! ocean initial state (Dynamics and tracers)
446
447	! ! external forcing
448	CALL tide_init ! tidal harmonics
449	CALL sbc_init ! surface boundary conditions (including sea-ice)
450	CALL bdy_init ! Open boundaries initialisation
451
452	! ! Ocean physics
453	CALL zdf_phy_init ! Vertical physics
454
455	! ! Lateral physics
456	CALL ldf_tra_init ! Lateral ocean tracer physics
457	CALL ldf_eiv_init ! eddy induced velocity param.
458	CALL ldf_dyn_init ! Lateral ocean momentum physics
459
460	! ! Active tracers
461	IF( ln_traqsr ) CALL tra_qsr_init ! penetrative solar radiation qsr
462	CALL tra_bbc_init ! bottom heat flux
463	CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
464	CALL tra_dmp_init ! internal tracer damping
465	CALL tra_adv_init ! horizontal & vertical advection
466	CALL tra_ldf_init ! lateral mixing
467
468	! ! Dynamics
469	IF( lk_c1d ) CALL dyn_dmp_init ! internal momentum damping
470	CALL dyn_adv_init ! advection (vector or flux form)
471	CALL dyn_vor_init ! vorticity term including Coriolis
472	CALL dyn_ldf_init ! lateral mixing
473	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
474	CALL dyn_spg_init ! surface pressure gradient
475
476	#if defined key_top
477	! ! Passive tracers
478	CALL trc_init
479	#endif
480	IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
481
482	! ! Icebergs
483	CALL icb_init( rdt, nit000) ! initialise icebergs instance
484
485	! ! Misc. options
486	CALL sto_par_init ! Stochastic parametrization
487	IF( ln_sto_eos ) CALL sto_pts_init ! RRandom T/S fluctuations
488
489	! ! Diagnostics
490	CALL flo_init ! drifting Floats
491	IF( ln_diacfl ) CALL dia_cfl_init ! Initialise CFL diagnostics
492	CALL dia_ptr_init ! Poleward TRansports initialization
493	CALL dia_dct_init ! Sections tranports
494	CALL dia_hsb_init ! heat content, salt content and volume budgets
495	CALL trd_init ! Mixed-layer/Vorticity/Integral constraints trends
496	CALL dia_obs_init ! Initialize observational data
497	CALL dia_25h_init ! 25h mean outputs
498	CALL dia_harm_init ! tidal harmonics outputs
499	IF( ln_diaobs ) CALL dia_obs( nit000-1 ) ! Observation operator for restart
500
501	! ! Assimilation increments
502	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
503	!
504	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
505
506	IF (nstop > 0) THEN
507	CALL CTL_STOP('STOP','Critical errors in NEMO initialisation')
508	END IF
509
510	!
511	IF( ln_timing ) CALL timing_stop( 'nemo_init')
512	!
513	END SUBROUTINE nemo_init
514
515
516	SUBROUTINE nemo_ctl
517	!!----------------------------------------------------------------------
518	!! * ROUTINE nemo_ctl *
519	!!
520	!! ** Purpose : control print setting
521	!!
522	!! ** Method : - print namctl and namcfg information and check some consistencies
523	!!----------------------------------------------------------------------
524	!
525	IF(lwp) THEN ! control print
526	WRITE(numout,*)
527	WRITE(numout,*) 'nemo_ctl: Control prints'
528	WRITE(numout,*) '~~~~~~~~'
529	WRITE(numout,*) ' Namelist namctl'
530	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
531	WRITE(numout,*) ' finer control over o/p sn_cfctl%l_config = ', sn_cfctl%l_config
532	WRITE(numout,*) ' sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
533	WRITE(numout,*) ' sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
534	WRITE(numout,*) ' sn_cfctl%l_oceout = ', sn_cfctl%l_oceout
535	WRITE(numout,*) ' sn_cfctl%l_layout = ', sn_cfctl%l_layout
536	WRITE(numout,*) ' sn_cfctl%l_mppout = ', sn_cfctl%l_mppout
537	WRITE(numout,*) ' sn_cfctl%l_mpptop = ', sn_cfctl%l_mpptop
538	WRITE(numout,*) ' sn_cfctl%procmin = ', sn_cfctl%procmin
539	WRITE(numout,*) ' sn_cfctl%procmax = ', sn_cfctl%procmax
540	WRITE(numout,*) ' sn_cfctl%procincr = ', sn_cfctl%procincr
541	WRITE(numout,*) ' sn_cfctl%ptimincr = ', sn_cfctl%ptimincr
542	WRITE(numout,*) ' level of print nn_print = ', nn_print
543	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
544	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
545	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
546	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
547	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
548	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
549	WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing
550	WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl
551	ENDIF
552	!
553	nprint = nn_print ! convert DOCTOR namelist names into OLD names
554	nictls = nn_ictls
555	nictle = nn_ictle
556	njctls = nn_jctls
557	njctle = nn_jctle
558	isplt = nn_isplt
559	jsplt = nn_jsplt
560
561	IF(lwp) THEN ! control print
562	WRITE(numout,*)
563	WRITE(numout,*) ' Namelist namcfg'
564	WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg
565	WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg)
566	WRITE(numout,*) ' keep closed seas in the domain (if exist) ln_closea = ', ln_closea
567	WRITE(numout,*) ' create a configuration definition file ln_write_cfg = ', ln_write_cfg
568	WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out)
569	WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
570	ENDIF
571	IF( .NOT.ln_read_cfg ) ln_closea = .false. ! dealing possible only with a domcfg file
572	!
573	! ! Parameter control
574	!
575	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
576	IF( lk_mpp .AND. jpnij > 1 ) THEN
577	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
578	ELSE
579	IF( isplt == 1 .AND. jsplt == 1 ) THEN
580	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
581	& ' - the print control will be done over the whole domain' )
582	ENDIF
583	ijsplt = isplt * jsplt ! total number of processors ijsplt
584	ENDIF
585	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
586	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
587	!
588	! ! indices used for the SUM control
589	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
590	lsp_area = .FALSE.
591	ELSE ! print control done over a specific area
592	lsp_area = .TRUE.
593	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
594	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
595	nictls = 1
596	ENDIF
597	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
598	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
599	nictle = jpiglo
600	ENDIF
601	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
602	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
603	njctls = 1
604	ENDIF
605	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
606	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
607	njctle = jpjglo
608	ENDIF
609	ENDIF
610	ENDIF
611	!
612	IF( 1._wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.', &
613	& 'Compile with key_nosignedzero enabled:', &
614	& '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
615	!
616	#if defined key_agrif
617	IF( ln_timing ) CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
618	#endif
619	!
620	END SUBROUTINE nemo_ctl
621
622
623	SUBROUTINE nemo_closefile
624	!!----------------------------------------------------------------------
625	!! * ROUTINE nemo_closefile *
626	!!
627	!! ** Purpose : Close the files
628	!!----------------------------------------------------------------------
629	!
630	IF( lk_mpp ) CALL mppsync
631	!
632	CALL iom_close ! close all input/output files managed by iom_*
633	!
634	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
635	IF( numrun /= -1 ) CLOSE( numrun ) ! run statistics file
636	IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist
637	IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist
638	IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist
639	IF( numnam_ice_ref /= -1 ) CLOSE( numnam_ice_ref ) ! ice reference namelist
640	IF( numnam_ice_cfg /= -1 ) CLOSE( numnam_ice_cfg ) ! ice configuration namelist
641	IF( lwm.AND.numoni /= -1 ) CLOSE( numoni ) ! ice output namelist
642	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
643	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
644	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
645	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
646	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
647	!
648	numout = 6 ! redefine numout in case it is used after this point...
649	!
650	END SUBROUTINE nemo_closefile
651
652
653	SUBROUTINE nemo_alloc
654	!!----------------------------------------------------------------------
655	!! * ROUTINE nemo_alloc *
656	!!
657	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
658	!!
659	!! ** Method :
660	!!----------------------------------------------------------------------
661	USE diawri , ONLY : dia_wri_alloc
662	USE dom_oce , ONLY : dom_oce_alloc
663	USE trc_oce , ONLY : trc_oce_alloc
664	USE bdy_oce , ONLY : bdy_oce_alloc
665	!
666	INTEGER :: ierr
667	!!----------------------------------------------------------------------
668	!
669	ierr = oce_alloc () ! ocean
670	ierr = ierr + dia_wri_alloc()
671	ierr = ierr + dom_oce_alloc() ! ocean domain
672	ierr = ierr + zdf_oce_alloc() ! ocean vertical physics
673	ierr = ierr + trc_oce_alloc() ! shared TRC / TRA arrays
674	ierr = ierr + bdy_oce_alloc() ! bdy masks (incl. initialization)
675	!
676	CALL mpp_sum( 'nemogcm', ierr )
677	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
678	!
679	END SUBROUTINE nemo_alloc
680
681
682	SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
683	!!----------------------------------------------------------------------
684	!! * ROUTINE nemo_set_cfctl *
685	!!
686	!! ** Purpose : Set elements of the output control structure to setto.
687	!! for_all should be .false. unless all areas are to be
688	!! treated identically.
689	!!
690	!! ** Method : Note this routine can be used to switch on/off some
691	!! types of output for selected areas but any output types
692	!! that involve global communications (e.g. mpp_max, glob_sum)
693	!! should be protected from selective switching by the
694	!! for_all argument
695	!!----------------------------------------------------------------------
696	LOGICAL :: setto, for_all
697	TYPE(sn_ctl) :: sn_cfctl
698	!!----------------------------------------------------------------------
699	IF( for_all ) THEN
700	sn_cfctl%l_runstat = setto
701	sn_cfctl%l_trcstat = setto
702	ENDIF
703	sn_cfctl%l_oceout = setto
704	sn_cfctl%l_layout = setto
705	sn_cfctl%l_mppout = setto
706	sn_cfctl%l_mpptop = setto
707	END SUBROUTINE nemo_set_cfctl
708
709	!!======================================================================
710	END MODULE nemogcm
711

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: NEMO/branches/UKMO/NEMO_4.0.3_GC_couple_pkg/src/OCE/nemogcm.F90

Download in other formats: