[3443] | 1 | MODULE p4zprod |
---|
| 2 | !!====================================================================== |
---|
| 3 | !! *** MODULE p4zprod *** |
---|
| 4 | !! TOP : Growth Rate of the two phytoplanktons groups |
---|
| 5 | !!====================================================================== |
---|
| 6 | !! History : 1.0 ! 2004 (O. Aumont) Original code |
---|
| 7 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
---|
| 8 | !! 3.4 ! 2011-05 (O. Aumont, C. Ethe) New parameterization of light limitation |
---|
| 9 | !!---------------------------------------------------------------------- |
---|
[9169] | 10 | !! p4z_prod : Compute the growth Rate of the two phytoplanktons groups |
---|
| 11 | !! p4z_prod_init : Initialization of the parameters for growth |
---|
| 12 | !! p4z_prod_alloc : Allocate variables for growth |
---|
[3443] | 13 | !!---------------------------------------------------------------------- |
---|
[9169] | 14 | USE oce_trc ! shared variables between ocean and passive tracers |
---|
| 15 | USE trc ! passive tracers common variables |
---|
| 16 | USE sms_pisces ! PISCES Source Minus Sink variables |
---|
[10227] | 17 | USE p4zlim ! Co-limitations of differents nutrients |
---|
[9169] | 18 | USE prtctl_trc ! print control for debugging |
---|
| 19 | USE iom ! I/O manager |
---|
[3443] | 20 | |
---|
| 21 | IMPLICIT NONE |
---|
| 22 | PRIVATE |
---|
| 23 | |
---|
| 24 | PUBLIC p4z_prod ! called in p4zbio.F90 |
---|
| 25 | PUBLIC p4z_prod_init ! called in trcsms_pisces.F90 |
---|
| 26 | PUBLIC p4z_prod_alloc |
---|
| 27 | |
---|
[9169] | 28 | REAL(wp), PUBLIC :: pislopen !: |
---|
| 29 | REAL(wp), PUBLIC :: pisloped !: |
---|
| 30 | REAL(wp), PUBLIC :: xadap !: |
---|
| 31 | REAL(wp), PUBLIC :: excretn !: |
---|
| 32 | REAL(wp), PUBLIC :: excretd !: |
---|
| 33 | REAL(wp), PUBLIC :: bresp !: |
---|
| 34 | REAL(wp), PUBLIC :: chlcnm !: |
---|
| 35 | REAL(wp), PUBLIC :: chlcdm !: |
---|
| 36 | REAL(wp), PUBLIC :: chlcmin !: |
---|
| 37 | REAL(wp), PUBLIC :: fecnm !: |
---|
| 38 | REAL(wp), PUBLIC :: fecdm !: |
---|
| 39 | REAL(wp), PUBLIC :: grosip !: |
---|
[3443] | 40 | |
---|
| 41 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: quotan !: proxy of N quota in Nanophyto |
---|
| 42 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: quotad !: proxy of N quota in diatomee |
---|
| 43 | |
---|
[9169] | 44 | REAL(wp) :: r1_rday ! 1 / rday |
---|
| 45 | REAL(wp) :: texcretn ! 1 - excretn |
---|
| 46 | REAL(wp) :: texcretd ! 1 - excretd |
---|
[3443] | 47 | |
---|
| 48 | !!---------------------------------------------------------------------- |
---|
[10067] | 49 | !! NEMO/TOP 4.0 , NEMO Consortium (2018) |
---|
[13587] | 50 | !! $Id$ |
---|
[10068] | 51 | !! Software governed by the CeCILL license (see ./LICENSE) |
---|
[3443] | 52 | !!---------------------------------------------------------------------- |
---|
| 53 | CONTAINS |
---|
| 54 | |
---|
[5385] | 55 | SUBROUTINE p4z_prod( kt , knt ) |
---|
[3443] | 56 | !!--------------------------------------------------------------------- |
---|
| 57 | !! *** ROUTINE p4z_prod *** |
---|
| 58 | !! |
---|
| 59 | !! ** Purpose : Compute the phytoplankton production depending on |
---|
| 60 | !! light, temperature and nutrient availability |
---|
| 61 | !! |
---|
| 62 | !! ** Method : - ??? |
---|
| 63 | !!--------------------------------------------------------------------- |
---|
[9169] | 64 | INTEGER, INTENT(in) :: kt, knt ! |
---|
[3443] | 65 | ! |
---|
| 66 | INTEGER :: ji, jj, jk |
---|
[3446] | 67 | REAL(wp) :: zsilfac, znanotot, zdiattot, zconctemp, zconctemp2 |
---|
[7646] | 68 | REAL(wp) :: zratio, zmax, zsilim, ztn, zadap, zlim, zsilfac2, zsiborn |
---|
| 69 | REAL(wp) :: zprod, zproreg, zproreg2, zprochln, zprochld |
---|
| 70 | REAL(wp) :: zmaxday, zdocprod, zpislopen, zpisloped |
---|
| 71 | REAL(wp) :: zmxltst, zmxlday |
---|
| 72 | REAL(wp) :: zrum, zcodel, zargu, zval, zfeup, chlcnm_n, chlcdm_n |
---|
[4996] | 73 | REAL(wp) :: zfact |
---|
[3443] | 74 | CHARACTER (len=25) :: charout |
---|
[9125] | 75 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: zw2d |
---|
| 76 | REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d |
---|
| 77 | REAL(wp), DIMENSION(jpi,jpj ) :: zstrn, zmixnano, zmixdiat |
---|
[10362] | 78 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprmaxn,zprmaxd |
---|
[9125] | 79 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpislopeadn, zpislopeadd, zysopt |
---|
| 80 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprdia, zprbio, zprdch, zprnch |
---|
| 81 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprorcan, zprorcad, zprofed, zprofen |
---|
| 82 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpronewn, zpronewd |
---|
| 83 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zmxl_fac, zmxl_chl |
---|
[10362] | 84 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpligprod1, zpligprod2 |
---|
[3443] | 85 | !!--------------------------------------------------------------------- |
---|
| 86 | ! |
---|
[9124] | 87 | IF( ln_timing ) CALL timing_start('p4z_prod') |
---|
[3443] | 88 | ! |
---|
| 89 | ! Allocate temporary workspace |
---|
| 90 | ! |
---|
[12280] | 91 | zprorcan(:,:,:) = 0._wp ; zprorcad(:,:,:) = 0._wp ; zprofed (:,:,:) = 0._wp |
---|
| 92 | zprofen (:,:,:) = 0._wp ; zysopt (:,:,:) = 0._wp |
---|
| 93 | zpronewn(:,:,:) = 0._wp ; zpronewd(:,:,:) = 0._wp ; zprdia (:,:,:) = 0._wp |
---|
| 94 | zprbio (:,:,:) = 0._wp ; zprdch (:,:,:) = 0._wp ; zprnch (:,:,:) = 0._wp |
---|
| 95 | zmxl_fac(:,:,:) = 0._wp ; zmxl_chl(:,:,:) = 0._wp |
---|
[7753] | 96 | |
---|
| 97 | ! Computation of the optimal production |
---|
[10362] | 98 | zprmaxn(:,:,:) = 0.8_wp * r1_rday * tgfunc(:,:,:) |
---|
| 99 | zprmaxd(:,:,:) = zprmaxn(:,:,:) |
---|
[7753] | 100 | |
---|
[3443] | 101 | ! compute the day length depending on latitude and the day |
---|
| 102 | zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp ) |
---|
| 103 | zcodel = ASIN( SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp ) ) |
---|
| 104 | |
---|
| 105 | ! day length in hours |
---|
[7753] | 106 | zstrn(:,:) = 0. |
---|
[3443] | 107 | DO jj = 1, jpj |
---|
| 108 | DO ji = 1, jpi |
---|
| 109 | zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad ) |
---|
| 110 | zargu = MAX( -1., MIN( 1., zargu ) ) |
---|
| 111 | zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. ) |
---|
| 112 | END DO |
---|
| 113 | END DO |
---|
| 114 | |
---|
[7646] | 115 | ! Impact of the day duration and light intermittency on phytoplankton growth |
---|
[5385] | 116 | DO jk = 1, jpkm1 |
---|
| 117 | DO jj = 1 ,jpj |
---|
| 118 | DO ji = 1, jpi |
---|
| 119 | IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN |
---|
| 120 | zval = MAX( 1., zstrn(ji,jj) ) |
---|
[7646] | 121 | IF( gdept_n(ji,jj,jk) <= hmld(ji,jj) ) THEN |
---|
| 122 | zval = zval * MIN(1., heup_01(ji,jj) / ( hmld(ji,jj) + rtrn )) |
---|
| 123 | ENDIF |
---|
| 124 | zmxl_chl(ji,jj,jk) = zval / 24. |
---|
| 125 | zmxl_fac(ji,jj,jk) = 1.5 * zval / ( 12. + zval ) |
---|
[5385] | 126 | ENDIF |
---|
[3443] | 127 | END DO |
---|
| 128 | END DO |
---|
[5385] | 129 | END DO |
---|
[3443] | 130 | |
---|
[10362] | 131 | zprbio(:,:,:) = zprmaxn(:,:,:) * zmxl_fac(:,:,:) |
---|
| 132 | zprdia(:,:,:) = zprmaxd(:,:,:) * zmxl_fac(:,:,:) |
---|
[7646] | 133 | |
---|
[3443] | 134 | ! Maximum light intensity |
---|
[7753] | 135 | WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24. |
---|
[3443] | 136 | |
---|
[7646] | 137 | ! Computation of the P-I slope for nanos and diatoms |
---|
| 138 | DO jk = 1, jpkm1 |
---|
| 139 | DO jj = 1, jpj |
---|
| 140 | DO ji = 1, jpi |
---|
| 141 | IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN |
---|
| 142 | ztn = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. ) |
---|
| 143 | zadap = xadap * ztn / ( 2.+ ztn ) |
---|
| 144 | zconctemp = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia ) |
---|
| 145 | zconctemp2 = trb(ji,jj,jk,jpdia) - zconctemp |
---|
| 146 | ! |
---|
| 147 | zpislopeadn(ji,jj,jk) = pislopen * ( 1.+ zadap * EXP( -0.25 * enano(ji,jj,jk) ) ) & |
---|
| 148 | & * trb(ji,jj,jk,jpnch) /( trb(ji,jj,jk,jpphy) * 12. + rtrn) |
---|
| 149 | ! |
---|
| 150 | zpislopeadd(ji,jj,jk) = (pislopen * zconctemp2 + pisloped * zconctemp) / ( trb(ji,jj,jk,jpdia) + rtrn ) & |
---|
| 151 | & * trb(ji,jj,jk,jpdch) /( trb(ji,jj,jk,jpdia) * 12. + rtrn) |
---|
| 152 | ENDIF |
---|
| 153 | END DO |
---|
| 154 | END DO |
---|
| 155 | END DO |
---|
| 156 | |
---|
[10401] | 157 | DO jk = 1, jpkm1 |
---|
| 158 | DO jj = 1, jpj |
---|
| 159 | DO ji = 1, jpi |
---|
| 160 | IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN |
---|
| 161 | ! Computation of production function for Carbon |
---|
| 162 | ! --------------------------------------------- |
---|
| 163 | zpislopen = zpislopeadn(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) & |
---|
| 164 | & * zmxl_fac(ji,jj,jk) * rday + rtrn) |
---|
| 165 | zpisloped = zpislopeadd(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) & |
---|
| 166 | & * zmxl_fac(ji,jj,jk) * rday + rtrn) |
---|
| 167 | zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) ) ) |
---|
| 168 | zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) ) ) |
---|
| 169 | ! Computation of production function for Chlorophyll |
---|
| 170 | !-------------------------------------------------- |
---|
| 171 | zpislopen = zpislopeadn(ji,jj,jk) / ( zprmaxn(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn ) |
---|
| 172 | zpisloped = zpislopeadd(ji,jj,jk) / ( zprmaxd(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn ) |
---|
| 173 | zprnch(ji,jj,jk) = zprmaxn(ji,jj,jk) * ( 1.- EXP( -zpislopen * enanom(ji,jj,jk) ) ) |
---|
| 174 | zprdch(ji,jj,jk) = zprmaxd(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediatm(ji,jj,jk) ) ) |
---|
| 175 | ENDIF |
---|
[3443] | 176 | END DO |
---|
| 177 | END DO |
---|
[10401] | 178 | END DO |
---|
[3443] | 179 | |
---|
| 180 | ! Computation of a proxy of the N/C ratio |
---|
| 181 | ! --------------------------------------- |
---|
| 182 | DO jk = 1, jpkm1 |
---|
| 183 | DO jj = 1, jpj |
---|
| 184 | DO ji = 1, jpi |
---|
[4529] | 185 | zval = MIN( xnanopo4(ji,jj,jk), ( xnanonh4(ji,jj,jk) + xnanono3(ji,jj,jk) ) ) & |
---|
[10362] | 186 | & * zprmaxn(ji,jj,jk) / ( zprbio(ji,jj,jk) + rtrn ) |
---|
[4529] | 187 | quotan(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval ) |
---|
| 188 | zval = MIN( xdiatpo4(ji,jj,jk), ( xdiatnh4(ji,jj,jk) + xdiatno3(ji,jj,jk) ) ) & |
---|
[10362] | 189 | & * zprmaxd(ji,jj,jk) / ( zprdia(ji,jj,jk) + rtrn ) |
---|
[4529] | 190 | quotad(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval ) |
---|
[3443] | 191 | END DO |
---|
| 192 | END DO |
---|
| 193 | END DO |
---|
| 194 | |
---|
| 195 | |
---|
| 196 | DO jk = 1, jpkm1 |
---|
| 197 | DO jj = 1, jpj |
---|
| 198 | DO ji = 1, jpi |
---|
| 199 | |
---|
[5385] | 200 | IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN |
---|
[3443] | 201 | ! Si/C of diatoms |
---|
| 202 | ! ------------------------ |
---|
| 203 | ! Si/C increases with iron stress and silicate availability |
---|
| 204 | ! Si/C is arbitrariliy increased for very high Si concentrations |
---|
| 205 | ! to mimic the very high ratios observed in the Southern Ocean (silpot2) |
---|
[5385] | 206 | zlim = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi1 ) |
---|
[10362] | 207 | zsilim = MIN( zprdia(ji,jj,jk) / ( zprmaxd(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) ) |
---|
[3443] | 208 | zsilfac = 4.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) ) ) + 1.e0 |
---|
[5385] | 209 | zsiborn = trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil) |
---|
[3446] | 210 | IF (gphit(ji,jj) < -30 ) THEN |
---|
| 211 | zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 ) |
---|
| 212 | ELSE |
---|
| 213 | zsilfac2 = 1. + zsiborn / ( zsiborn + xksi2**3 ) |
---|
| 214 | ENDIF |
---|
| 215 | zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2 |
---|
[3443] | 216 | ENDIF |
---|
| 217 | END DO |
---|
| 218 | END DO |
---|
| 219 | END DO |
---|
| 220 | |
---|
[7646] | 221 | ! Mixed-layer effect on production |
---|
| 222 | ! Sea-ice effect on production |
---|
| 223 | |
---|
[3443] | 224 | DO jk = 1, jpkm1 |
---|
| 225 | DO jj = 1, jpj |
---|
| 226 | DO ji = 1, jpi |
---|
[6945] | 227 | zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) ) |
---|
| 228 | zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) ) |
---|
[3443] | 229 | END DO |
---|
| 230 | END DO |
---|
| 231 | END DO |
---|
| 232 | |
---|
| 233 | ! Computation of the various production terms |
---|
| 234 | DO jk = 1, jpkm1 |
---|
| 235 | DO jj = 1, jpj |
---|
| 236 | DO ji = 1, jpi |
---|
[5385] | 237 | IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN |
---|
[7646] | 238 | ! production terms for nanophyto. (C) |
---|
| 239 | zprorcan(ji,jj,jk) = zprbio(ji,jj,jk) * xlimphy(ji,jj,jk) * trb(ji,jj,jk,jpphy) * rfact2 |
---|
| 240 | zpronewn(ji,jj,jk) = zprorcan(ji,jj,jk)* xnanono3(ji,jj,jk) / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn ) |
---|
[3443] | 241 | ! |
---|
[7646] | 242 | zratio = trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) * fecnm + rtrn ) |
---|
[3443] | 243 | zmax = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) |
---|
[10362] | 244 | zprofen(ji,jj,jk) = fecnm * zprmaxn(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) ) & |
---|
[3443] | 245 | & * ( 4. - 4.5 * xlimnfe(ji,jj,jk) / ( xlimnfe(ji,jj,jk) + 0.5 ) ) & |
---|
[3446] | 246 | & * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concnfe(ji,jj,jk) ) & |
---|
[5385] | 247 | & * zmax * trb(ji,jj,jk,jpphy) * rfact2 |
---|
[7646] | 248 | ! production terms for diatoms (C) |
---|
[5385] | 249 | zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trb(ji,jj,jk,jpdia) * rfact2 |
---|
[3443] | 250 | zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk) / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn ) |
---|
| 251 | ! |
---|
[7646] | 252 | zratio = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) * fecdm + rtrn ) |
---|
[3443] | 253 | zmax = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) |
---|
[10362] | 254 | zprofed(ji,jj,jk) = fecdm * zprmaxd(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) ) & |
---|
[3443] | 255 | & * ( 4. - 4.5 * xlimdfe(ji,jj,jk) / ( xlimdfe(ji,jj,jk) + 0.5 ) ) & |
---|
[3446] | 256 | & * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concdfe(ji,jj,jk) ) & |
---|
[5385] | 257 | & * zmax * trb(ji,jj,jk,jpdia) * rfact2 |
---|
[3443] | 258 | ENDIF |
---|
| 259 | END DO |
---|
| 260 | END DO |
---|
| 261 | END DO |
---|
| 262 | |
---|
[7646] | 263 | ! Computation of the chlorophyll production terms |
---|
[6945] | 264 | DO jk = 1, jpkm1 |
---|
| 265 | DO jj = 1, jpj |
---|
| 266 | DO ji = 1, jpi |
---|
| 267 | IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN |
---|
| 268 | ! production terms for nanophyto. ( chlorophyll ) |
---|
[10362] | 269 | znanotot = enanom(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn ) |
---|
[7646] | 270 | zprod = rday * zprorcan(ji,jj,jk) * zprnch(ji,jj,jk) * xlimphy(ji,jj,jk) |
---|
| 271 | zprochln = chlcmin * 12. * zprorcan (ji,jj,jk) |
---|
| 272 | chlcnm_n = MIN ( chlcnm, ( chlcnm / (1. - 1.14 / 43.4 *tsn(ji,jj,jk,jp_tem))) * (1. - 1.14 / 43.4 * 20.)) |
---|
| 273 | zprochln = zprochln + (chlcnm_n-chlcmin) * 12. * zprod / & |
---|
| 274 | & ( zpislopeadn(ji,jj,jk) * znanotot +rtrn) |
---|
| 275 | ! production terms for diatoms ( chlorophyll ) |
---|
[10362] | 276 | zdiattot = ediatm(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn ) |
---|
[7646] | 277 | zprod = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * xlimdia(ji,jj,jk) |
---|
| 278 | zprochld = chlcmin * 12. * zprorcad(ji,jj,jk) |
---|
| 279 | chlcdm_n = MIN ( chlcdm, ( chlcdm / (1. - 1.14 / 43.4 * tsn(ji,jj,jk,jp_tem))) * (1. - 1.14 / 43.4 * 20.)) |
---|
| 280 | zprochld = zprochld + (chlcdm_n-chlcmin) * 12. * zprod / & |
---|
| 281 | & ( zpislopeadd(ji,jj,jk) * zdiattot +rtrn ) |
---|
| 282 | ! Update the arrays TRA which contain the Chla sources and sinks |
---|
| 283 | tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln * texcretn |
---|
| 284 | tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld * texcretd |
---|
[6945] | 285 | ENDIF |
---|
[3443] | 286 | END DO |
---|
| 287 | END DO |
---|
[6945] | 288 | END DO |
---|
[3443] | 289 | |
---|
| 290 | ! Update the arrays TRA which contain the biological sources and sinks |
---|
| 291 | DO jk = 1, jpkm1 |
---|
| 292 | DO jj = 1, jpj |
---|
| 293 | DO ji =1 ,jpi |
---|
[7646] | 294 | IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN |
---|
| 295 | zproreg = zprorcan(ji,jj,jk) - zpronewn(ji,jj,jk) |
---|
| 296 | zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk) |
---|
| 297 | zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk) |
---|
| 298 | tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk) |
---|
| 299 | tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronewn(ji,jj,jk) - zpronewd(ji,jj,jk) |
---|
| 300 | tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproreg - zproreg2 |
---|
| 301 | tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorcan(ji,jj,jk) * texcretn |
---|
| 302 | tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcretn |
---|
| 303 | tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcretd |
---|
| 304 | tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcretd |
---|
| 305 | tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcretd |
---|
| 306 | tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zdocprod |
---|
| 307 | tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproreg + zproreg2) & |
---|
| 308 | & + ( o2ut + o2nit ) * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) ) |
---|
| 309 | ! |
---|
| 310 | zfeup = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk) |
---|
| 311 | tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zfeup |
---|
| 312 | tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) - texcretd * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) |
---|
| 313 | tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk) |
---|
| 314 | tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) ) & |
---|
| 315 | & - rno3 * ( zproreg + zproreg2 ) |
---|
| 316 | ENDIF |
---|
| 317 | END DO |
---|
[3443] | 318 | END DO |
---|
| 319 | END DO |
---|
[7646] | 320 | ! |
---|
| 321 | IF( ln_ligand ) THEN |
---|
[12280] | 322 | zpligprod1(:,:,:) = 0._wp ; zpligprod2(:,:,:) = 0._wp |
---|
[7646] | 323 | DO jk = 1, jpkm1 |
---|
| 324 | DO jj = 1, jpj |
---|
| 325 | DO ji =1 ,jpi |
---|
| 326 | IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN |
---|
| 327 | zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk) |
---|
| 328 | zfeup = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk) |
---|
| 329 | tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zdocprod * ldocp - zfeup * plig(ji,jj,jk) * lthet |
---|
[10362] | 330 | zpligprod1(ji,jj,jk) = zdocprod * ldocp |
---|
| 331 | zpligprod2(ji,jj,jk) = zfeup * plig(ji,jj,jk) * lthet |
---|
[7646] | 332 | ENDIF |
---|
| 333 | END DO |
---|
| 334 | END DO |
---|
| 335 | END DO |
---|
| 336 | ENDIF |
---|
[3443] | 337 | |
---|
| 338 | |
---|
[4996] | 339 | ! Total primary production per year |
---|
[5385] | 340 | IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc ) ) & |
---|
[10425] | 341 | & tpp = glob_sum( 'p4zprod', ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * cvol(:,:,:) ) |
---|
[4996] | 342 | |
---|
[12276] | 343 | IF( lk_iomput .AND. knt == nrdttrc ) THEN |
---|
| 344 | zfact = 1.e+3 * rfact2r ! conversion from mol/l/kt to mol/m3/s |
---|
| 345 | ! |
---|
| 346 | CALL iom_put( "PPPHYN" , zprorcan(:,:,:) * zfact * tmask(:,:,:) ) ! primary production by nanophyto |
---|
| 347 | CALL iom_put( "PPPHYD" , zprorcad(:,:,:) * zfact * tmask(:,:,:) ) ! primary production by diatomes |
---|
| 348 | CALL iom_put( "PPNEWN" , zpronewn(:,:,:) * zfact * tmask(:,:,:) ) ! new primary production by nanophyto |
---|
| 349 | CALL iom_put( "PPNEWD" , zpronewd(:,:,:) * zfact * tmask(:,:,:) ) ! new primary production by diatomes |
---|
| 350 | CALL iom_put( "PBSi" , zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:) ) ! biogenic silica production |
---|
| 351 | CALL iom_put( "PFeN" , zprofen(:,:,:) * zfact * tmask(:,:,:) ) ! biogenic iron production by nanophyto |
---|
| 352 | CALL iom_put( "PFeD" , zprofed(:,:,:) * zfact * tmask(:,:,:) ) ! biogenic iron production by diatomes |
---|
[12280] | 353 | IF( ln_ligand ) THEN |
---|
| 354 | CALL iom_put( "LPRODP" , zpligprod1(:,:,:) * 1e9 * zfact * tmask(:,:,:) ) |
---|
| 355 | CALL iom_put( "LDETP" , zpligprod2(:,:,:) * 1e9 * zfact * tmask(:,:,:) ) |
---|
| 356 | ENDIF |
---|
[12276] | 357 | CALL iom_put( "Mumax" , zprmaxn(:,:,:) * tmask(:,:,:) ) ! Maximum growth rate |
---|
| 358 | CALL iom_put( "MuN" , zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:) ) ! Realized growth rate for nanophyto |
---|
| 359 | CALL iom_put( "MuD" , zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:) ) ! Realized growth rate for diatoms |
---|
| 360 | CALL iom_put( "LNlight" , zprbio (:,:,:) / (zprmaxn(:,:,:) + rtrn) * tmask(:,:,:) ) ! light limitation term |
---|
| 361 | CALL iom_put( "LDlight" , zprdia (:,:,:) / (zprmaxd(:,:,:) + rtrn) * tmask(:,:,:) ) |
---|
| 362 | CALL iom_put( "TPP" , ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * zfact * tmask(:,:,:) ) ! total primary production |
---|
| 363 | CALL iom_put( "TPNEW" , ( zpronewn(:,:,:) + zpronewd(:,:,:) ) * zfact * tmask(:,:,:) ) ! total new production |
---|
| 364 | CALL iom_put( "TPBFE" , ( zprofen(:,:,:) + zprofed(:,:,:) ) * zfact * tmask(:,:,:) ) ! total biogenic iron production |
---|
| 365 | CALL iom_put( "tintpp" , tpp * zfact ) ! global total integrated primary production molC/s |
---|
[4996] | 366 | ENDIF |
---|
[3443] | 367 | |
---|
[4996] | 368 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
---|
[3443] | 369 | WRITE(charout, FMT="('prod')") |
---|
| 370 | CALL prt_ctl_trc_info(charout) |
---|
| 371 | CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm) |
---|
[4996] | 372 | ENDIF |
---|
[9169] | 373 | ! |
---|
| 374 | IF( ln_timing ) CALL timing_stop('p4z_prod') |
---|
| 375 | ! |
---|
[3443] | 376 | END SUBROUTINE p4z_prod |
---|
| 377 | |
---|
| 378 | |
---|
| 379 | SUBROUTINE p4z_prod_init |
---|
| 380 | !!---------------------------------------------------------------------- |
---|
| 381 | !! *** ROUTINE p4z_prod_init *** |
---|
| 382 | !! |
---|
| 383 | !! ** Purpose : Initialization of phytoplankton production parameters |
---|
| 384 | !! |
---|
| 385 | !! ** Method : Read the nampisprod namelist and check the parameters |
---|
| 386 | !! called at the first timestep (nittrc000) |
---|
| 387 | !! |
---|
| 388 | !! ** input : Namelist nampisprod |
---|
| 389 | !!---------------------------------------------------------------------- |
---|
[9169] | 390 | INTEGER :: ios ! Local integer |
---|
[3443] | 391 | ! |
---|
[10401] | 392 | NAMELIST/namp4zprod/ pislopen, pisloped, xadap, bresp, excretn, excretd, & |
---|
[3443] | 393 | & chlcnm, chlcdm, chlcmin, fecnm, fecdm, grosip |
---|
| 394 | !!---------------------------------------------------------------------- |
---|
[9169] | 395 | ! |
---|
| 396 | IF(lwp) THEN ! control print |
---|
| 397 | WRITE(numout,*) |
---|
| 398 | WRITE(numout,*) 'p4z_prod_init : phytoplankton growth' |
---|
| 399 | WRITE(numout,*) '~~~~~~~~~~~~~' |
---|
| 400 | ENDIF |
---|
| 401 | ! |
---|
[12276] | 402 | REWIND( numnatp_ref ) |
---|
[7646] | 403 | READ ( numnatp_ref, namp4zprod, IOSTAT = ios, ERR = 901) |
---|
[11536] | 404 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zprod in reference namelist' ) |
---|
[12276] | 405 | |
---|
| 406 | REWIND( numnatp_cfg ) |
---|
[7646] | 407 | READ ( numnatp_cfg, namp4zprod, IOSTAT = ios, ERR = 902 ) |
---|
[11536] | 408 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namp4zprod in configuration namelist' ) |
---|
[9169] | 409 | IF(lwm) WRITE( numonp, namp4zprod ) |
---|
[4147] | 410 | |
---|
[3443] | 411 | IF(lwp) THEN ! control print |
---|
[9169] | 412 | WRITE(numout,*) ' Namelist : namp4zprod' |
---|
| 413 | WRITE(numout,*) ' mean Si/C ratio grosip =', grosip |
---|
| 414 | WRITE(numout,*) ' P-I slope pislopen =', pislopen |
---|
| 415 | WRITE(numout,*) ' Acclimation factor to low light xadap =', xadap |
---|
| 416 | WRITE(numout,*) ' excretion ratio of nanophytoplankton excretn =', excretn |
---|
| 417 | WRITE(numout,*) ' excretion ratio of diatoms excretd =', excretd |
---|
[10401] | 418 | WRITE(numout,*) ' basal respiration in phytoplankton bresp =', bresp |
---|
| 419 | WRITE(numout,*) ' Maximum Chl/C in phytoplankton chlcmin =', chlcmin |
---|
[9169] | 420 | WRITE(numout,*) ' P-I slope for diatoms pisloped =', pisloped |
---|
| 421 | WRITE(numout,*) ' Minimum Chl/C in nanophytoplankton chlcnm =', chlcnm |
---|
| 422 | WRITE(numout,*) ' Minimum Chl/C in diatoms chlcdm =', chlcdm |
---|
| 423 | WRITE(numout,*) ' Maximum Fe/C in nanophytoplankton fecnm =', fecnm |
---|
| 424 | WRITE(numout,*) ' Minimum Fe/C in diatoms fecdm =', fecdm |
---|
[3443] | 425 | ENDIF |
---|
| 426 | ! |
---|
| 427 | r1_rday = 1._wp / rday |
---|
[7646] | 428 | texcretn = 1._wp - excretn |
---|
| 429 | texcretd = 1._wp - excretd |
---|
[3443] | 430 | tpp = 0._wp |
---|
| 431 | ! |
---|
| 432 | END SUBROUTINE p4z_prod_init |
---|
| 433 | |
---|
| 434 | |
---|
| 435 | INTEGER FUNCTION p4z_prod_alloc() |
---|
| 436 | !!---------------------------------------------------------------------- |
---|
| 437 | !! *** ROUTINE p4z_prod_alloc *** |
---|
| 438 | !!---------------------------------------------------------------------- |
---|
[10362] | 439 | ALLOCATE( quotan(jpi,jpj,jpk), quotad(jpi,jpj,jpk), STAT = p4z_prod_alloc ) |
---|
[3443] | 440 | ! |
---|
[10425] | 441 | IF( p4z_prod_alloc /= 0 ) CALL ctl_stop( 'STOP', 'p4z_prod_alloc : failed to allocate arrays.' ) |
---|
[3443] | 442 | ! |
---|
| 443 | END FUNCTION p4z_prod_alloc |
---|
[9124] | 444 | |
---|
[3443] | 445 | !!====================================================================== |
---|
[5656] | 446 | END MODULE p4zprod |
---|