1 | MODULE sbcssm |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE sbcssm *** |
---|
4 | !! Off-line : interpolation of the physical fields |
---|
5 | !!====================================================================== |
---|
6 | !! History : 3.4 ! 2012-03 (S. Alderson) original code |
---|
7 | !!---------------------------------------------------------------------- |
---|
8 | |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | !! sbc_ssm_init : initialization, namelist read, and SAVEs control |
---|
11 | !! sbc_ssm : Interpolation of the fields |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | USE oce ! ocean dynamics and tracers variables |
---|
14 | USE c1d ! 1D configuration: lk_c1d |
---|
15 | USE dom_oce ! ocean domain: variables |
---|
16 | USE zdf_oce ! ocean vertical physics: variables |
---|
17 | USE sbc_oce ! surface module: variables |
---|
18 | USE phycst ! physical constants |
---|
19 | USE eosbn2 ! equation of state - Brunt Vaisala frequency |
---|
20 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
21 | USE zpshde ! z-coord. with partial steps: horizontal derivatives |
---|
22 | USE closea ! for ln_closea |
---|
23 | ! |
---|
24 | USE in_out_manager ! I/O manager |
---|
25 | USE iom ! I/O library |
---|
26 | USE lib_mpp ! distributed memory computing library |
---|
27 | USE prtctl ! print control |
---|
28 | USE fldread ! read input fields |
---|
29 | USE timing ! Timing |
---|
30 | |
---|
31 | IMPLICIT NONE |
---|
32 | PRIVATE |
---|
33 | |
---|
34 | PUBLIC sbc_ssm_init ! called by sbc_init |
---|
35 | PUBLIC sbc_ssm ! called by sbc |
---|
36 | |
---|
37 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssm files |
---|
38 | LOGICAL :: ln_3d_uve ! specify whether input velocity data is 3D |
---|
39 | LOGICAL :: ln_read_frq ! specify whether we must read frq or not |
---|
40 | |
---|
41 | LOGICAL :: l_sasread ! Ice intilisation: =T read a file ; =F anaytical initilaistion |
---|
42 | LOGICAL :: l_initdone = .false. |
---|
43 | INTEGER :: nfld_3d |
---|
44 | INTEGER :: nfld_2d |
---|
45 | |
---|
46 | INTEGER :: jf_tem ! index of temperature |
---|
47 | INTEGER :: jf_sal ! index of salinity |
---|
48 | INTEGER :: jf_usp ! index of u velocity component |
---|
49 | INTEGER :: jf_vsp ! index of v velocity component |
---|
50 | INTEGER :: jf_ssh ! index of sea surface height |
---|
51 | INTEGER :: jf_e3t ! index of first T level thickness |
---|
52 | INTEGER :: jf_frq ! index of fraction of qsr absorbed in the 1st T level |
---|
53 | |
---|
54 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_ssm_3d ! structure of input fields (file information, fields read) |
---|
55 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_ssm_2d ! structure of input fields (file information, fields read) |
---|
56 | |
---|
57 | !!---------------------------------------------------------------------- |
---|
58 | !! NEMO/SAS 4.0 , NEMO Consortium (2018) |
---|
59 | !! $Id$ |
---|
60 | !! Software governed by the CeCILL license (see ./LICENSE) |
---|
61 | !!---------------------------------------------------------------------- |
---|
62 | CONTAINS |
---|
63 | |
---|
64 | SUBROUTINE sbc_ssm( kt ) |
---|
65 | !!---------------------------------------------------------------------- |
---|
66 | !! *** ROUTINE sbc_ssm *** |
---|
67 | !! |
---|
68 | !! ** Purpose : Prepares dynamics and physics fields from a NEMO run |
---|
69 | !! for an off-line simulation using surface processes only |
---|
70 | !! |
---|
71 | !! ** Method : calculates the position of data |
---|
72 | !! - interpolates data if needed |
---|
73 | !!---------------------------------------------------------------------- |
---|
74 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
---|
75 | ! |
---|
76 | INTEGER :: ji, jj ! dummy loop indices |
---|
77 | REAL(wp) :: ztinta ! ratio applied to after records when doing time interpolation |
---|
78 | REAL(wp) :: ztintb ! ratio applied to before records when doing time interpolation |
---|
79 | CHARACTER(len=4),SAVE :: stype |
---|
80 | !!--------------------------------------------------------------------- |
---|
81 | IF( kt == nit000 ) THEN |
---|
82 | IF( ln_TEOS10 ) THEN |
---|
83 | stype='abs' ! teos-10: using absolute salinity (sst is converted to potential temperature for the surface module) |
---|
84 | ELSE IF( ln_EOS80 ) THEN |
---|
85 | stype='pra' ! eos-80: using practical salinity |
---|
86 | ELSE IF ( ln_SEOS) THEN |
---|
87 | stype='seos' ! seos using Simplified Equation of state (sst is converted to potential temperature for the surface module) |
---|
88 | ENDIF |
---|
89 | ENDIF |
---|
90 | ! |
---|
91 | IF( ln_timing ) CALL timing_start( 'sbc_ssm') |
---|
92 | |
---|
93 | IF ( l_sasread ) THEN |
---|
94 | IF( nfld_3d > 0 ) CALL fld_read( kt, 1, sf_ssm_3d ) !== read data at kt time step ==! |
---|
95 | IF( nfld_2d > 0 ) CALL fld_read( kt, 1, sf_ssm_2d ) !== read data at kt time step ==! |
---|
96 | ! |
---|
97 | IF( ln_3d_uve ) THEN |
---|
98 | IF( .NOT. ln_linssh ) THEN |
---|
99 | e3t_m(:,:) = sf_ssm_3d(jf_e3t)%fnow(:,:,1) * tmask(:,:,1) ! vertical scale factor |
---|
100 | ELSE |
---|
101 | e3t_m(:,:) = e3t_0(:,:,1) ! vertical scale factor |
---|
102 | ENDIF |
---|
103 | ssu_m(:,:) = sf_ssm_3d(jf_usp)%fnow(:,:,1) * umask(:,:,1) ! u-velocity |
---|
104 | ssv_m(:,:) = sf_ssm_3d(jf_vsp)%fnow(:,:,1) * vmask(:,:,1) ! v-velocity |
---|
105 | ELSE |
---|
106 | IF( .NOT. ln_linssh ) THEN |
---|
107 | e3t_m(:,:) = sf_ssm_2d(jf_e3t)%fnow(:,:,1) * tmask(:,:,1) ! vertical scale factor |
---|
108 | ELSE |
---|
109 | e3t_m(:,:) = e3t_0(:,:,1) ! vertical scale factor |
---|
110 | ENDIF |
---|
111 | ssu_m(:,:) = sf_ssm_2d(jf_usp)%fnow(:,:,1) * umask(:,:,1) ! u-velocity |
---|
112 | ssv_m(:,:) = sf_ssm_2d(jf_vsp)%fnow(:,:,1) * vmask(:,:,1) ! v-velocity |
---|
113 | ENDIF |
---|
114 | ! |
---|
115 | sst_m(:,:) = sf_ssm_2d(jf_tem)%fnow(:,:,1) * tmask(:,:,1) ! temperature |
---|
116 | sss_m(:,:) = sf_ssm_2d(jf_sal)%fnow(:,:,1) * tmask(:,:,1) ! salinity |
---|
117 | ssh_m(:,:) = sf_ssm_2d(jf_ssh)%fnow(:,:,1) * tmask(:,:,1) ! sea surface height |
---|
118 | IF( ln_read_frq ) THEN |
---|
119 | frq_m(:,:) = sf_ssm_2d(jf_frq)%fnow(:,:,1) * tmask(:,:,1) ! solar penetration |
---|
120 | ELSE |
---|
121 | frq_m(:,:) = 1._wp |
---|
122 | ENDIF |
---|
123 | ELSE |
---|
124 | sss_m(:,:) = 35._wp ! =35. to obtain a physical value for the freezing point |
---|
125 | CALL eos_fzp( sss_m(:,:), sst_m(:,:) ) ! sst_m is set at the freezing point |
---|
126 | ssu_m(:,:) = 0._wp |
---|
127 | ssv_m(:,:) = 0._wp |
---|
128 | ssh_m(:,:) = 0._wp |
---|
129 | IF( .NOT. ln_linssh ) e3t_m(:,:) = e3t_0(:,:,1) !clem: necessary at least for sas2D |
---|
130 | frq_m(:,:) = 1._wp ! - - |
---|
131 | sshn (:,:) = 0._wp ! - - |
---|
132 | ENDIF |
---|
133 | |
---|
134 | IF ( nn_ice == 1 ) THEN |
---|
135 | tsn(:,:,1,jp_tem) = sst_m(:,:) |
---|
136 | tsn(:,:,1,jp_sal) = sss_m(:,:) |
---|
137 | tsb(:,:,1,jp_tem) = sst_m(:,:) |
---|
138 | tsb(:,:,1,jp_sal) = sss_m(:,:) |
---|
139 | ENDIF |
---|
140 | ub (:,:,1) = ssu_m(:,:) |
---|
141 | vb (:,:,1) = ssv_m(:,:) |
---|
142 | |
---|
143 | IF(ln_ctl) THEN ! print control |
---|
144 | CALL prt_ctl(tab2d_1=sst_m, clinfo1=' sst_m - : ', mask1=tmask ) |
---|
145 | CALL prt_ctl(tab2d_1=sss_m, clinfo1=' sss_m - : ', mask1=tmask ) |
---|
146 | CALL prt_ctl(tab2d_1=ssu_m, clinfo1=' ssu_m - : ', mask1=umask ) |
---|
147 | CALL prt_ctl(tab2d_1=ssv_m, clinfo1=' ssv_m - : ', mask1=vmask ) |
---|
148 | CALL prt_ctl(tab2d_1=ssh_m, clinfo1=' ssh_m - : ', mask1=tmask ) |
---|
149 | IF( .NOT.ln_linssh ) CALL prt_ctl(tab2d_1=ssh_m, clinfo1=' e3t_m - : ', mask1=tmask ) |
---|
150 | IF( ln_read_frq ) CALL prt_ctl(tab2d_1=frq_m, clinfo1=' frq_m - : ', mask1=tmask ) |
---|
151 | ENDIF |
---|
152 | ! |
---|
153 | IF( l_initdone ) THEN ! Mean value at each nn_fsbc time-step ! |
---|
154 | CALL iom_put( 'ssu_m', ssu_m ) |
---|
155 | CALL iom_put( 'ssv_m', ssv_m ) |
---|
156 | CALL iom_put( 'sst_m_pot', sst_m ) |
---|
157 | CALL iom_put( 'sss_m_'//stype, sss_m ) |
---|
158 | CALL iom_put( 'ssh_m', ssh_m ) |
---|
159 | IF( .NOT.ln_linssh ) CALL iom_put( 'e3t_m', e3t_m ) |
---|
160 | IF( ln_read_frq ) CALL iom_put( 'frq_m', frq_m ) |
---|
161 | ENDIF |
---|
162 | ! |
---|
163 | IF( ln_timing ) CALL timing_stop( 'sbc_ssm') |
---|
164 | ! |
---|
165 | END SUBROUTINE sbc_ssm |
---|
166 | |
---|
167 | |
---|
168 | SUBROUTINE sbc_ssm_init |
---|
169 | !!---------------------------------------------------------------------- |
---|
170 | !! *** ROUTINE sbc_ssm_init *** |
---|
171 | !! |
---|
172 | !! ** Purpose : Initialisation of sea surface mean data |
---|
173 | !!---------------------------------------------------------------------- |
---|
174 | INTEGER :: ierr, ierr0, ierr1, ierr2, ierr3 ! return error code |
---|
175 | INTEGER :: ifpr ! dummy loop indice |
---|
176 | INTEGER :: inum, idv, idimv, jpm ! local integer |
---|
177 | INTEGER :: ios ! Local integer output status for namelist read |
---|
178 | !! |
---|
179 | CHARACTER(len=100) :: cn_dir ! Root directory for location of core files |
---|
180 | TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) :: slf_3d ! array of namelist information on the fields to read |
---|
181 | TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) :: slf_2d ! array of namelist information on the fields to read |
---|
182 | TYPE(FLD_N) :: sn_tem, sn_sal ! information about the fields to be read |
---|
183 | TYPE(FLD_N) :: sn_usp, sn_vsp |
---|
184 | TYPE(FLD_N) :: sn_ssh, sn_e3t, sn_frq |
---|
185 | !! |
---|
186 | NAMELIST/namsbc_sas/ l_sasread, cn_dir, ln_3d_uve, ln_read_frq, & |
---|
187 | & sn_tem, sn_sal, sn_usp, sn_vsp, sn_ssh, sn_e3t, sn_frq |
---|
188 | !!---------------------------------------------------------------------- |
---|
189 | ! |
---|
190 | IF( ln_rstart .AND. nn_components == jp_iam_sas ) RETURN |
---|
191 | ! |
---|
192 | IF(lwp) THEN |
---|
193 | WRITE(numout,*) |
---|
194 | WRITE(numout,*) 'sbc_ssm_init : sea surface mean data initialisation ' |
---|
195 | WRITE(numout,*) '~~~~~~~~~~~~ ' |
---|
196 | ENDIF |
---|
197 | ! |
---|
198 | REWIND( numnam_ref ) ! Namelist namsbc_sas in reference namelist : Input fields |
---|
199 | READ ( numnam_ref, namsbc_sas, IOSTAT = ios, ERR = 901) |
---|
200 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_sas in reference namelist' ) |
---|
201 | REWIND( numnam_cfg ) ! Namelist namsbc_sas in configuration namelist : Input fields |
---|
202 | READ ( numnam_cfg, namsbc_sas, IOSTAT = ios, ERR = 902 ) |
---|
203 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namsbc_sas in configuration namelist' ) |
---|
204 | IF(lwm) WRITE ( numond, namsbc_sas ) |
---|
205 | ! |
---|
206 | IF(lwp) THEN ! Control print |
---|
207 | WRITE(numout,*) ' Namelist namsbc_sas' |
---|
208 | WRITE(numout,*) ' Initialisation using an input file l_sasread = ', l_sasread |
---|
209 | WRITE(numout,*) ' Are we supplying a 3D u,v and e3 field ln_3d_uve = ', ln_3d_uve |
---|
210 | WRITE(numout,*) ' Are we reading frq (fraction of qsr absorbed in the 1st T level) ln_read_frq = ', ln_read_frq |
---|
211 | ENDIF |
---|
212 | ! |
---|
213 | !! switch off stuff that isn't sensible with a standalone module |
---|
214 | !! note that we need sbc_ssm called first in sbc |
---|
215 | ! |
---|
216 | IF( ln_apr_dyn ) THEN |
---|
217 | IF( lwp ) WRITE(numout,*) ' ==>>> No atmospheric gradient needed with StandAlone Surface scheme' |
---|
218 | ln_apr_dyn = .FALSE. |
---|
219 | ENDIF |
---|
220 | IF( ln_rnf ) THEN |
---|
221 | IF( lwp ) WRITE(numout,*) ' ==>>> No runoff needed with StandAlone Surface scheme' |
---|
222 | ln_rnf = .FALSE. |
---|
223 | ENDIF |
---|
224 | IF( ln_ssr ) THEN |
---|
225 | IF( lwp ) WRITE(numout,*) ' ==>>> No surface relaxation needed with StandAlone Surface scheme' |
---|
226 | ln_ssr = .FALSE. |
---|
227 | ENDIF |
---|
228 | IF( nn_fwb > 0 ) THEN |
---|
229 | IF( lwp ) WRITE(numout,*) ' ==>>> No freshwater budget adjustment needed with StandAlone Surface scheme' |
---|
230 | nn_fwb = 0 |
---|
231 | ENDIF |
---|
232 | IF( ln_closea ) THEN |
---|
233 | IF( lwp ) WRITE(numout,*) ' ==>>> No closed seas adjustment needed with StandAlone Surface scheme' |
---|
234 | ln_closea = .false. |
---|
235 | ENDIF |
---|
236 | |
---|
237 | ! |
---|
238 | IF( l_sasread ) THEN ! store namelist information in an array |
---|
239 | ! |
---|
240 | !! following code is a bit messy, but distinguishes between when u,v are 3d arrays and |
---|
241 | !! when we have other 3d arrays that we need to read in |
---|
242 | !! so if a new field is added i.e. jf_new, just give it the next integer in sequence |
---|
243 | !! for the corresponding dimension (currently if ln_3d_uve is true, 4 for 2d and 3 for 3d, |
---|
244 | !! alternatively if ln_3d_uve is false, 6 for 2d and 1 for 3d), reset nfld_3d, nfld_2d, |
---|
245 | !! and the rest of the logic should still work |
---|
246 | ! |
---|
247 | jf_tem = 1 ; jf_ssh = 3 ! default 2D fields index |
---|
248 | jf_sal = 2 ; jf_frq = 4 ! |
---|
249 | ! |
---|
250 | IF( ln_3d_uve ) THEN |
---|
251 | jf_usp = 1 ; jf_vsp = 2 ; jf_e3t = 3 ! define 3D fields index |
---|
252 | nfld_3d = 2 + COUNT( (/.NOT.ln_linssh/) ) ! number of 3D fields to read |
---|
253 | nfld_2d = 3 + COUNT( (/ln_read_frq/) ) ! number of 2D fields to read |
---|
254 | ELSE |
---|
255 | jf_usp = 4 ; jf_e3t = 6 ! update 2D fields index |
---|
256 | jf_vsp = 5 ; jf_frq = 6 + COUNT( (/.NOT.ln_linssh/) ) |
---|
257 | ! |
---|
258 | nfld_3d = 0 ! no 3D fields to read |
---|
259 | nfld_2d = 5 + COUNT( (/.NOT.ln_linssh/) ) + COUNT( (/ln_read_frq/) ) ! number of 2D fields to read |
---|
260 | ENDIF |
---|
261 | ! |
---|
262 | IF( nfld_3d > 0 ) THEN |
---|
263 | ALLOCATE( slf_3d(nfld_3d), STAT=ierr ) ! set slf structure |
---|
264 | IF( ierr > 0 ) THEN |
---|
265 | CALL ctl_stop( 'sbc_ssm_init: unable to allocate slf 3d structure' ) ; RETURN |
---|
266 | ENDIF |
---|
267 | slf_3d(jf_usp) = sn_usp |
---|
268 | slf_3d(jf_vsp) = sn_vsp |
---|
269 | IF( .NOT.ln_linssh ) slf_3d(jf_e3t) = sn_e3t |
---|
270 | ENDIF |
---|
271 | ! |
---|
272 | IF( nfld_2d > 0 ) THEN |
---|
273 | ALLOCATE( slf_2d(nfld_2d), STAT=ierr ) ! set slf structure |
---|
274 | IF( ierr > 0 ) THEN |
---|
275 | CALL ctl_stop( 'sbc_ssm_init: unable to allocate slf 2d structure' ) ; RETURN |
---|
276 | ENDIF |
---|
277 | slf_2d(jf_tem) = sn_tem ; slf_2d(jf_sal) = sn_sal ; slf_2d(jf_ssh) = sn_ssh |
---|
278 | IF( ln_read_frq ) slf_2d(jf_frq) = sn_frq |
---|
279 | IF( .NOT. ln_3d_uve ) THEN |
---|
280 | slf_2d(jf_usp) = sn_usp ; slf_2d(jf_vsp) = sn_vsp |
---|
281 | IF( .NOT.ln_linssh ) slf_2d(jf_e3t) = sn_e3t |
---|
282 | ENDIF |
---|
283 | ENDIF |
---|
284 | ! |
---|
285 | ierr1 = 0 ! default definition if slf_?d(ifpr)%ln_tint = .false. |
---|
286 | IF( nfld_3d > 0 ) THEN |
---|
287 | ALLOCATE( sf_ssm_3d(nfld_3d), STAT=ierr ) ! set sf structure |
---|
288 | IF( ierr > 0 ) THEN |
---|
289 | CALL ctl_stop( 'sbc_ssm_init: unable to allocate sf structure' ) ; RETURN |
---|
290 | ENDIF |
---|
291 | DO ifpr = 1, nfld_3d |
---|
292 | ALLOCATE( sf_ssm_3d(ifpr)%fnow(jpi,jpj,jpk) , STAT=ierr0 ) |
---|
293 | IF( slf_3d(ifpr)%ln_tint ) ALLOCATE( sf_ssm_3d(ifpr)%fdta(jpi,jpj,jpk,2) , STAT=ierr1 ) |
---|
294 | IF( ierr0 + ierr1 > 0 ) THEN |
---|
295 | CALL ctl_stop( 'sbc_ssm_init : unable to allocate sf_ssm_3d array structure' ) ; RETURN |
---|
296 | ENDIF |
---|
297 | END DO |
---|
298 | ! ! fill sf with slf_i and control print |
---|
299 | CALL fld_fill( sf_ssm_3d, slf_3d, cn_dir, 'sbc_ssm_init', '3D Data in file', 'namsbc_ssm' ) |
---|
300 | ENDIF |
---|
301 | ! |
---|
302 | IF( nfld_2d > 0 ) THEN |
---|
303 | ALLOCATE( sf_ssm_2d(nfld_2d), STAT=ierr ) ! set sf structure |
---|
304 | IF( ierr > 0 ) THEN |
---|
305 | CALL ctl_stop( 'sbc_ssm_init: unable to allocate sf 2d structure' ) ; RETURN |
---|
306 | ENDIF |
---|
307 | DO ifpr = 1, nfld_2d |
---|
308 | ALLOCATE( sf_ssm_2d(ifpr)%fnow(jpi,jpj,1) , STAT=ierr0 ) |
---|
309 | IF( slf_2d(ifpr)%ln_tint ) ALLOCATE( sf_ssm_2d(ifpr)%fdta(jpi,jpj,1,2) , STAT=ierr1 ) |
---|
310 | IF( ierr0 + ierr1 > 0 ) THEN |
---|
311 | CALL ctl_stop( 'sbc_ssm_init : unable to allocate sf_ssm_2d array structure' ) ; RETURN |
---|
312 | ENDIF |
---|
313 | END DO |
---|
314 | ! |
---|
315 | CALL fld_fill( sf_ssm_2d, slf_2d, cn_dir, 'sbc_ssm_init', '2D Data in file', 'namsbc_ssm' ) |
---|
316 | ENDIF |
---|
317 | ! |
---|
318 | IF( nfld_3d > 0 ) DEALLOCATE( slf_3d, STAT=ierr ) |
---|
319 | IF( nfld_2d > 0 ) DEALLOCATE( slf_2d, STAT=ierr ) |
---|
320 | ! |
---|
321 | ENDIF |
---|
322 | ! |
---|
323 | CALL sbc_ssm( nit000 ) ! need to define ss?_m arrays used in iceistate |
---|
324 | l_initdone = .TRUE. |
---|
325 | ! |
---|
326 | END SUBROUTINE sbc_ssm_init |
---|
327 | |
---|
328 | !!====================================================================== |
---|
329 | END MODULE sbcssm |
---|