| 1 | MODULE trasbc |
|---|
| 2 | !!============================================================================== |
|---|
| 3 | !! *** MODULE trasbc *** |
|---|
| 4 | !! Ocean active tracers: surface boundary condition |
|---|
| 5 | !!============================================================================== |
|---|
| 6 | !! History : OPA ! 1998-10 (G. Madec, G. Roullet, M. Imbard) Original code |
|---|
| 7 | !! 8.2 ! 2001-02 (D. Ludicone) sea ice and free surface |
|---|
| 8 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
|---|
| 9 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 10 | !! - ! 2010-09 (C. Ethe, G. Madec) Merge TRA-TRC |
|---|
| 11 | !! 3.6 ! 2014-11 (P. Mathiot) isf melting forcing |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! tra_sbc : update the tracer trend at ocean surface |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE oce ! ocean dynamics and active tracers |
|---|
| 18 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 19 | USE dom_oce ! ocean space domain variables |
|---|
| 20 | USE phycst ! physical constant |
|---|
| 21 | USE eosbn2 ! Equation Of State |
|---|
| 22 | USE sbcmod ! ln_rnf |
|---|
| 23 | USE sbcrnf ! River runoff |
|---|
| 24 | USE sbcisf ! Ice shelf |
|---|
| 25 | USE iscplini ! Ice sheet coupling |
|---|
| 26 | USE traqsr ! solar radiation penetration |
|---|
| 27 | USE trd_oce ! trends: ocean variables |
|---|
| 28 | USE trdtra ! trends manager: tracers |
|---|
| 29 | !JT |
|---|
| 30 | USE tradwl ! solar radiation penetration (downwell method) |
|---|
| 31 | !JT |
|---|
| 32 | #if defined key_asminc |
|---|
| 33 | USE asminc ! Assimilation increment |
|---|
| 34 | #endif |
|---|
| 35 | ! |
|---|
| 36 | USE in_out_manager ! I/O manager |
|---|
| 37 | USE prtctl ! Print control |
|---|
| 38 | USE iom ! xIOS server |
|---|
| 39 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 40 | USE timing ! Timing |
|---|
| 41 | |
|---|
| 42 | IMPLICIT NONE |
|---|
| 43 | PRIVATE |
|---|
| 44 | |
|---|
| 45 | PUBLIC tra_sbc ! routine called by step.F90 |
|---|
| 46 | |
|---|
| 47 | !! * Substitutions |
|---|
| 48 | # include "vectopt_loop_substitute.h90" |
|---|
| 49 | !!---------------------------------------------------------------------- |
|---|
| 50 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 51 | !! $Id$ |
|---|
| 52 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 53 | !!---------------------------------------------------------------------- |
|---|
| 54 | CONTAINS |
|---|
| 55 | |
|---|
| 56 | SUBROUTINE tra_sbc ( kt ) |
|---|
| 57 | !!---------------------------------------------------------------------- |
|---|
| 58 | !! *** ROUTINE tra_sbc *** |
|---|
| 59 | !! |
|---|
| 60 | !! ** Purpose : Compute the tracer surface boundary condition trend of |
|---|
| 61 | !! (flux through the interface, concentration/dilution effect) |
|---|
| 62 | !! and add it to the general trend of tracer equations. |
|---|
| 63 | !! |
|---|
| 64 | !! ** Method : The (air+ice)-sea flux has two components: |
|---|
| 65 | !! (1) Fext, external forcing (i.e. flux through the (air+ice)-sea interface); |
|---|
| 66 | !! (2) Fwe , tracer carried with the water that is exchanged with air+ice. |
|---|
| 67 | !! The input forcing fields (emp, rnf, sfx, isf) contain Fext+Fwe, |
|---|
| 68 | !! they are simply added to the tracer trend (tsa). |
|---|
| 69 | !! In linear free surface case (ln_linssh=T), the volume of the |
|---|
| 70 | !! ocean does not change with the water exchanges at the (air+ice)-sea |
|---|
| 71 | !! interface. Therefore another term has to be added, to mimic the |
|---|
| 72 | !! concentration/dilution effect associated with water exchanges. |
|---|
| 73 | !! |
|---|
| 74 | !! ** Action : - Update tsa with the surface boundary condition trend |
|---|
| 75 | !! - send trends to trdtra module for further diagnostics(l_trdtra=T) |
|---|
| 76 | !!---------------------------------------------------------------------- |
|---|
| 77 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
|---|
| 78 | ! |
|---|
| 79 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
|---|
| 80 | INTEGER :: ikt, ikb ! local integers |
|---|
| 81 | REAL(wp) :: zfact, z1_e3t, zdep, ztim ! local scalar |
|---|
| 82 | REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: ztrdt, ztrds |
|---|
| 83 | !!---------------------------------------------------------------------- |
|---|
| 84 | ! |
|---|
| 85 | IF( ln_timing ) CALL timing_start('tra_sbc') |
|---|
| 86 | ! |
|---|
| 87 | IF( kt == nit000 ) THEN |
|---|
| 88 | IF(lwp) WRITE(numout,*) |
|---|
| 89 | IF(lwp) WRITE(numout,*) 'tra_sbc : TRAcer Surface Boundary Condition' |
|---|
| 90 | IF(lwp) WRITE(numout,*) '~~~~~~~ ' |
|---|
| 91 | ENDIF |
|---|
| 92 | ! |
|---|
| 93 | IF( l_trdtra ) THEN !* Save ta and sa trends |
|---|
| 94 | ALLOCATE( ztrdt(jpi,jpj,jpk) , ztrds(jpi,jpj,jpk) ) |
|---|
| 95 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) |
|---|
| 96 | ztrds(:,:,:) = tsa(:,:,:,jp_sal) |
|---|
| 97 | ENDIF |
|---|
| 98 | ! |
|---|
| 99 | !!gm This should be moved into sbcmod.F90 module ? (especially now that ln_traqsr is read in namsbc namelist) |
|---|
| 100 | !JT |
|---|
| 101 | IF( .NOT.ln_traqsr .and. .NOT.ln_tradwl ) THEN ! no solar radiation penetration |
|---|
| 102 | !JT |
|---|
| 103 | qns(:,:) = qns(:,:) + qsr(:,:) ! total heat flux in qns |
|---|
| 104 | qsr(:,:) = 0._wp ! qsr set to zero |
|---|
| 105 | ENDIF |
|---|
| 106 | |
|---|
| 107 | !---------------------------------------- |
|---|
| 108 | ! EMP, SFX and QNS effects |
|---|
| 109 | !---------------------------------------- |
|---|
| 110 | ! !== Set before sbc tracer content fields ==! |
|---|
| 111 | IF( kt == nit000 ) THEN !* 1st time-step |
|---|
| 112 | IF( ln_rstart .AND. & ! Restart: read in restart file |
|---|
| 113 | & iom_varid( numror, 'sbc_hc_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 114 | IF(lwp) WRITE(numout,*) ' nit000-1 sbc tracer content field read in the restart file' |
|---|
| 115 | zfact = 0.5_wp |
|---|
| 116 | sbc_tsc(:,:,:) = 0._wp |
|---|
| 117 | CALL iom_get( numror, jpdom_autoglo, 'sbc_hc_b', sbc_tsc_b(:,:,jp_tem), ldxios = lrxios ) ! before heat content sbc trend |
|---|
| 118 | CALL iom_get( numror, jpdom_autoglo, 'sbc_sc_b', sbc_tsc_b(:,:,jp_sal), ldxios = lrxios ) ! before salt content sbc trend |
|---|
| 119 | ELSE ! No restart or restart not found: Euler forward time stepping |
|---|
| 120 | zfact = 1._wp |
|---|
| 121 | sbc_tsc(:,:,:) = 0._wp |
|---|
| 122 | sbc_tsc_b(:,:,:) = 0._wp |
|---|
| 123 | ENDIF |
|---|
| 124 | ELSE !* other time-steps: swap of forcing fields |
|---|
| 125 | zfact = 0.5_wp |
|---|
| 126 | sbc_tsc_b(:,:,:) = sbc_tsc(:,:,:) |
|---|
| 127 | ENDIF |
|---|
| 128 | ! !== Now sbc tracer content fields ==! |
|---|
| 129 | DO jj = 2, jpj |
|---|
| 130 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 131 | sbc_tsc(ji,jj,jp_tem) = r1_rau0_rcp * qns(ji,jj) ! non solar heat flux |
|---|
| 132 | sbc_tsc(ji,jj,jp_sal) = r1_rau0 * sfx(ji,jj) ! salt flux due to freezing/melting |
|---|
| 133 | END DO |
|---|
| 134 | END DO |
|---|
| 135 | IF( ln_linssh ) THEN !* linear free surface |
|---|
| 136 | DO jj = 2, jpj !==>> add concentration/dilution effect due to constant volume cell |
|---|
| 137 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 138 | sbc_tsc(ji,jj,jp_tem) = sbc_tsc(ji,jj,jp_tem) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_tem) |
|---|
| 139 | sbc_tsc(ji,jj,jp_sal) = sbc_tsc(ji,jj,jp_sal) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_sal) |
|---|
| 140 | END DO |
|---|
| 141 | END DO !==>> output c./d. term |
|---|
| 142 | IF( iom_use('emp_x_sst') ) CALL iom_put( "emp_x_sst", emp (:,:) * tsn(:,:,1,jp_tem) ) |
|---|
| 143 | IF( iom_use('emp_x_sss') ) CALL iom_put( "emp_x_sss", emp (:,:) * tsn(:,:,1,jp_sal) ) |
|---|
| 144 | ENDIF |
|---|
| 145 | ! |
|---|
| 146 | DO jn = 1, jpts !== update tracer trend ==! |
|---|
| 147 | DO jj = 2, jpj |
|---|
| 148 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 149 | tsa(ji,jj,1,jn) = tsa(ji,jj,1,jn) + zfact * ( sbc_tsc_b(ji,jj,jn) + sbc_tsc(ji,jj,jn) ) / e3t_n(ji,jj,1) |
|---|
| 150 | END DO |
|---|
| 151 | END DO |
|---|
| 152 | END DO |
|---|
| 153 | ! |
|---|
| 154 | IF( lrst_oce ) THEN !== write sbc_tsc in the ocean restart file ==! |
|---|
| 155 | IF( lwxios ) CALL iom_swap( cwxios_context ) |
|---|
| 156 | CALL iom_rstput( kt, nitrst, numrow, 'sbc_hc_b', sbc_tsc(:,:,jp_tem), ldxios = lwxios ) |
|---|
| 157 | CALL iom_rstput( kt, nitrst, numrow, 'sbc_sc_b', sbc_tsc(:,:,jp_sal), ldxios = lwxios ) |
|---|
| 158 | IF( lwxios ) CALL iom_swap( cxios_context ) |
|---|
| 159 | ENDIF |
|---|
| 160 | ! |
|---|
| 161 | !---------------------------------------- |
|---|
| 162 | ! Ice Shelf effects (ISF) |
|---|
| 163 | ! tbl treated as in Losh (2008) JGR |
|---|
| 164 | !---------------------------------------- |
|---|
| 165 | ! |
|---|
| 166 | !!gm BUG ? Why no differences between non-linear and linear free surface ? |
|---|
| 167 | !!gm probably taken into account in r1_hisf_tbl : to be verified |
|---|
| 168 | IF( ln_isf ) THEN |
|---|
| 169 | zfact = 0.5_wp |
|---|
| 170 | DO jj = 2, jpj |
|---|
| 171 | DO ji = fs_2, fs_jpim1 |
|---|
| 172 | ! |
|---|
| 173 | ikt = misfkt(ji,jj) |
|---|
| 174 | ikb = misfkb(ji,jj) |
|---|
| 175 | ! |
|---|
| 176 | ! level fully include in the ice shelf boundary layer |
|---|
| 177 | ! sign - because fwf sign of evapo (rnf sign of precip) |
|---|
| 178 | DO jk = ikt, ikb - 1 |
|---|
| 179 | ! compute trend |
|---|
| 180 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) & |
|---|
| 181 | & + zfact * ( risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem) ) & |
|---|
| 182 | & * r1_hisf_tbl(ji,jj) |
|---|
| 183 | END DO |
|---|
| 184 | |
|---|
| 185 | ! level partially include in ice shelf boundary layer |
|---|
| 186 | ! compute trend |
|---|
| 187 | tsa(ji,jj,ikb,jp_tem) = tsa(ji,jj,ikb,jp_tem) & |
|---|
| 188 | & + zfact * ( risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem) ) & |
|---|
| 189 | & * r1_hisf_tbl(ji,jj) * ralpha(ji,jj) |
|---|
| 190 | |
|---|
| 191 | END DO |
|---|
| 192 | END DO |
|---|
| 193 | END IF |
|---|
| 194 | ! |
|---|
| 195 | !---------------------------------------- |
|---|
| 196 | ! River Runoff effects |
|---|
| 197 | !---------------------------------------- |
|---|
| 198 | ! |
|---|
| 199 | IF( ln_rnf ) THEN ! input of heat and salt due to river runoff |
|---|
| 200 | zfact = 0.5_wp |
|---|
| 201 | DO jj = 2, jpj |
|---|
| 202 | DO ji = fs_2, fs_jpim1 |
|---|
| 203 | IF( rnf(ji,jj) /= 0._wp ) THEN |
|---|
| 204 | zdep = zfact / h_rnf(ji,jj) |
|---|
| 205 | DO jk = 1, nk_rnf(ji,jj) |
|---|
| 206 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) & |
|---|
| 207 | & + ( rnf_tsc_b(ji,jj,jp_tem) + rnf_tsc(ji,jj,jp_tem) ) * zdep |
|---|
| 208 | IF( ln_rnf_sal ) tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal) & |
|---|
| 209 | & + ( rnf_tsc_b(ji,jj,jp_sal) + rnf_tsc(ji,jj,jp_sal) ) * zdep |
|---|
| 210 | END DO |
|---|
| 211 | ENDIF |
|---|
| 212 | END DO |
|---|
| 213 | END DO |
|---|
| 214 | ENDIF |
|---|
| 215 | |
|---|
| 216 | IF( iom_use('rnf_x_sst') ) CALL iom_put( "rnf_x_sst", rnf*tsn(:,:,1,jp_tem) ) ! runoff term on sst |
|---|
| 217 | IF( iom_use('rnf_x_sss') ) CALL iom_put( "rnf_x_sss", rnf*tsn(:,:,1,jp_sal) ) ! runoff term on sss |
|---|
| 218 | |
|---|
| 219 | #if defined key_asminc |
|---|
| 220 | ! |
|---|
| 221 | !---------------------------------------- |
|---|
| 222 | ! Assmilation effects |
|---|
| 223 | !---------------------------------------- |
|---|
| 224 | ! |
|---|
| 225 | IF( ln_sshinc ) THEN ! input of heat and salt due to assimilation |
|---|
| 226 | ! |
|---|
| 227 | IF( ln_linssh ) THEN |
|---|
| 228 | DO jj = 2, jpj |
|---|
| 229 | DO ji = fs_2, fs_jpim1 |
|---|
| 230 | ztim = ssh_iau(ji,jj) / e3t_n(ji,jj,1) |
|---|
| 231 | tsa(ji,jj,1,jp_tem) = tsa(ji,jj,1,jp_tem) + tsn(ji,jj,1,jp_tem) * ztim |
|---|
| 232 | tsa(ji,jj,1,jp_sal) = tsa(ji,jj,1,jp_sal) + tsn(ji,jj,1,jp_sal) * ztim |
|---|
| 233 | END DO |
|---|
| 234 | END DO |
|---|
| 235 | ELSE |
|---|
| 236 | DO jj = 2, jpj |
|---|
| 237 | DO ji = fs_2, fs_jpim1 |
|---|
| 238 | ztim = ssh_iau(ji,jj) / ( ht_n(ji,jj) + 1. - ssmask(ji, jj) ) |
|---|
| 239 | tsa(ji,jj,:,jp_tem) = tsa(ji,jj,:,jp_tem) + tsn(ji,jj,:,jp_tem) * ztim |
|---|
| 240 | tsa(ji,jj,:,jp_sal) = tsa(ji,jj,:,jp_sal) + tsn(ji,jj,:,jp_sal) * ztim |
|---|
| 241 | END DO |
|---|
| 242 | END DO |
|---|
| 243 | ENDIF |
|---|
| 244 | ! |
|---|
| 245 | ENDIF |
|---|
| 246 | ! |
|---|
| 247 | #endif |
|---|
| 248 | ! |
|---|
| 249 | !---------------------------------------- |
|---|
| 250 | ! Ice Sheet coupling imbalance correction to have conservation |
|---|
| 251 | !---------------------------------------- |
|---|
| 252 | ! |
|---|
| 253 | IF( ln_iscpl .AND. ln_hsb) THEN ! input of heat and salt due to river runoff |
|---|
| 254 | DO jk = 1,jpk |
|---|
| 255 | DO jj = 2, jpj |
|---|
| 256 | DO ji = fs_2, fs_jpim1 |
|---|
| 257 | zdep = 1._wp / e3t_n(ji,jj,jk) |
|---|
| 258 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) - htsc_iscpl(ji,jj,jk,jp_tem) * zdep |
|---|
| 259 | tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal) - htsc_iscpl(ji,jj,jk,jp_sal) * zdep |
|---|
| 260 | END DO |
|---|
| 261 | END DO |
|---|
| 262 | END DO |
|---|
| 263 | ENDIF |
|---|
| 264 | |
|---|
| 265 | IF( l_trdtra ) THEN ! save the horizontal diffusive trends for further diagnostics |
|---|
| 266 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:) |
|---|
| 267 | ztrds(:,:,:) = tsa(:,:,:,jp_sal) - ztrds(:,:,:) |
|---|
| 268 | CALL trd_tra( kt, 'TRA', jp_tem, jptra_nsr, ztrdt ) |
|---|
| 269 | CALL trd_tra( kt, 'TRA', jp_sal, jptra_nsr, ztrds ) |
|---|
| 270 | DEALLOCATE( ztrdt , ztrds ) |
|---|
| 271 | ENDIF |
|---|
| 272 | ! |
|---|
| 273 | IF(ln_ctl) CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' sbc - Ta: ', mask1=tmask, & |
|---|
| 274 | & tab3d_2=tsa(:,:,:,jp_sal), clinfo2= ' Sa: ', mask2=tmask, clinfo3='tra' ) |
|---|
| 275 | ! |
|---|
| 276 | IF( ln_timing ) CALL timing_stop('tra_sbc') |
|---|
| 277 | ! |
|---|
| 278 | END SUBROUTINE tra_sbc |
|---|
| 279 | |
|---|
| 280 | !!====================================================================== |
|---|
| 281 | END MODULE trasbc |
|---|
