New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcrnf.F90 in NEMO/branches/UKMO/NEMO_4.0.4_icesheet_and_river_coupling/src/OCE/SBC – NEMO

source: NEMO/branches/UKMO/NEMO_4.0.4_icesheet_and_river_coupling/src/OCE/SBC/sbcrnf.F90 @ 14939

Last change on this file since 14939 was 14939, checked in by timgraham, 3 years ago

Changes to allow use of a climatological iceberg distribution but taking the flux from the coupler.
File size: 33.5 KB
Line 
1MODULE sbcrnf
2   !!======================================================================
3   !!                       ***  MODULE  sbcrnf  ***
4   !! Ocean forcing:  river runoff
5   !!=====================================================================
6   !! History :  OPA  ! 2000-11  (R. Hordoir, E. Durand)  NetCDF FORMAT
7   !!   NEMO     1.0  ! 2002-09  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-07  (G. Madec)  Surface module
9   !!            3.2  ! 2009-04  (B. Lemaire)  Introduce iom_put
10   !!            3.3  ! 2010-10  (R. Furner, G. Madec) runoff distributed over ocean levels
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_rnf       : monthly runoffs read in a NetCDF file
15   !!   sbc_rnf_init  : runoffs initialisation
16   !!   rnf_mouth     : set river mouth mask
17   !!----------------------------------------------------------------------
18   USE dom_oce        ! ocean space and time domain
19   USE phycst         ! physical constants
20   USE sbc_oce        ! surface boundary condition variables
21   USE eosbn2         ! Equation Of State
22   USE closea, ONLY: l_clo_rnf, clo_rnf ! closed seas
23   !
24   USE in_out_manager ! I/O manager
25   USE fldread        ! read input field at current time step
26   USE iom            ! I/O module
27   USE lib_mpp        ! MPP library
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   sbc_rnf       ! called in sbcmod module
33   PUBLIC   sbc_rnf_div   ! called in divhor module
34   PUBLIC   sbc_rnf_alloc ! called in sbcmod module
35   PUBLIC   sbc_rnf_init  ! called in sbcmod module
36   
37   !                                                !!* namsbc_rnf namelist *
38   CHARACTER(len=100)         ::   cn_dir            !: Root directory for location of rnf files
39   LOGICAL           , PUBLIC ::   ln_rnf_depth      !: depth       river runoffs attribute specified in a file
40   LOGICAL                    ::      ln_rnf_depth_ini  !: depth       river runoffs  computed at the initialisation
41   REAL(wp)                   ::      rn_rnf_max        !: maximum value of the runoff climatologie (ln_rnf_depth_ini =T)
42   REAL(wp)                   ::      rn_dep_max        !: depth over which runoffs is spread       (ln_rnf_depth_ini =T)
43   REAL(wp)                   ::      tot_flux           !: total iceberg flux (temporary variable)
44   INTEGER                    ::      nn_rnf_depth_file !: create (=1) a runoff depth file or not (=0)
45   LOGICAL                    ::   ln_rnf_icb        !: iceberg flux is specified in a file
46   LOGICAL                    ::   ln_icb_mass       !: Scale iceberg flux to match FW flux from coupled model
47   LOGICAL                    ::   ln_rnf_tem        !: temperature river runoffs attribute specified in a file
48   LOGICAL           , PUBLIC ::   ln_rnf_sal        !: salinity    river runoffs attribute specified in a file
49   TYPE(FLD_N)       , PUBLIC ::   sn_rnf            !: information about the runoff file to be read
50   TYPE(FLD_N)                ::   sn_cnf            !: information about the runoff mouth file to be read
51   TYPE(FLD_N)                ::   sn_i_rnf          !: information about the iceberg flux file to be read
52   TYPE(FLD_N)                ::   sn_s_rnf          !: information about the salinities of runoff file to be read
53   TYPE(FLD_N)                ::   sn_t_rnf          !: information about the temperatures of runoff file to be read
54   TYPE(FLD_N)                ::   sn_dep_rnf        !: information about the depth which river inflow affects
55   LOGICAL           , PUBLIC ::   ln_rnf_mouth      !: specific treatment in mouths vicinity
56   REAL(wp)                   ::   rn_hrnf           !: runoffs, depth over which enhanced vertical mixing is used
57   REAL(wp)          , PUBLIC ::   rn_avt_rnf        !: runoffs, value of the additional vertical mixing coef. [m2/s]
58   REAL(wp)          , PUBLIC ::   rn_rfact          !: multiplicative factor for runoff
59
60   LOGICAL , PUBLIC ::   l_rnfcpl = .false.   !: runoffs recieved from oasis
61   INTEGER , PUBLIC ::   nkrnf = 0            !: nb of levels over which Kz is increased at river mouths
62   
63   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rnfmsk              !: river mouth mask (hori.)
64   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:)     ::   rnfmsk_z            !: river mouth mask (vert.)
65   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   h_rnf               !: depth of runoff in m
66   INTEGER,  PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   nk_rnf              !: depth of runoff in model levels
67   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   rnf_tsc_b, rnf_tsc  !: before and now T & S runoff contents   [K.m/s & PSU.m/s]   
68
69   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_rnf       ! structure: river runoff (file information, fields read)
70   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_i_rnf     ! structure: iceberg flux (file information, fields read)
71   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_s_rnf     ! structure: river runoff salinity (file information, fields read) 
72   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_t_rnf     ! structure: river runoff temperature (file information, fields read) 
73 
74   !!----------------------------------------------------------------------
75   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
76   !! $Id$
77   !! Software governed by the CeCILL license (see ./LICENSE)
78   !!----------------------------------------------------------------------
79CONTAINS
80
81   INTEGER FUNCTION sbc_rnf_alloc()
82      !!----------------------------------------------------------------------
83      !!                ***  ROUTINE sbc_rnf_alloc  ***
84      !!----------------------------------------------------------------------
85      ALLOCATE( rnfmsk(jpi,jpj)         , rnfmsk_z(jpk)          ,     &
86         &      h_rnf (jpi,jpj)         , nk_rnf  (jpi,jpj)      ,     &
87         &      rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
88         !
89      CALL mpp_sum ( 'sbcrnf', sbc_rnf_alloc )
90      IF( sbc_rnf_alloc > 0 )   CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
91   END FUNCTION sbc_rnf_alloc
92
93
94   SUBROUTINE sbc_rnf( kt )
95      !!----------------------------------------------------------------------
96      !!                  ***  ROUTINE sbc_rnf  ***
97      !!
98      !! ** Purpose :   Introduce a climatological run off forcing
99      !!
100      !! ** Method  :   Set each river mouth with a monthly climatology
101      !!                provided from different data.
102      !!                CAUTION : upward water flux, runoff forced to be < 0
103      !!
104      !! ** Action  :   runoff updated runoff field at time-step kt
105      !!----------------------------------------------------------------------
106      INTEGER, INTENT(in) ::   kt          ! ocean time step
107      !
108      INTEGER  ::   ji, jj    ! dummy loop indices
109      INTEGER  ::   z_err = 0 ! dummy integer for error handling
110      !!----------------------------------------------------------------------
111      REAL(wp), DIMENSION(jpi,jpj) ::   ztfrz   ! freezing point used for temperature correction
112      REAL(wp), PARAMETER ::   rsmall = 1.e-10_wp    ! ICB flux epsilon
113
114      !
115      !
116      !                                            !-------------------!
117      !                                            !   Update runoff   !
118      !                                            !-------------------!
119      !
120      !
121      IF( .NOT. l_rnfcpl )  THEN
122                            CALL fld_read ( kt, nn_fsbc, sf_rnf   )    ! Read Runoffs data and provide it at kt ( runoffs + iceberg )
123      ENDIF
124      IF(   ln_rnf_icb   )   CALL fld_read ( kt, nn_fsbc, sf_i_rnf )    ! idem for iceberg flux if required
125      IF(   ln_rnf_tem   )   CALL fld_read ( kt, nn_fsbc, sf_t_rnf )    ! idem for runoffs temperature if required
126      IF(   ln_rnf_sal   )   CALL fld_read ( kt, nn_fsbc, sf_s_rnf )    ! idem for runoffs salinity    if required
127      !
128      IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
129         !
130         IF( .NOT. l_rnfcpl ) THEN
131             rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) * tmask(:,:,1)  ! updated runoff value at time step kt
132         ENDIF
133         IF( ln_rnf_icb ) THEN
134            fwficb(:,:) = rn_rfact * ( sf_i_rnf(1)%fnow(:,:,1) ) * tmask(:,:,1)  ! updated runoff value at time step kt
135            IF( ln_icb_mass ) THEN
136                ! Modify the Iceberg FW flux to be consistent with the change in
137                ! mass of the Antarctic/Greenland ice sheet for FW conservation in
138                ! coupled model. This isn't perfect as FW flux will go into ocean at
139                ! wrong time of year but more important to maintain FW balance
140                tot_flux = SUM(fwficb(:,:)*e1e2t(:,:)*tmask_i(:,:)*greenland_icesheet_mask(:,:)) !Need to multiply by area to convert to kg/s
141                IF( lk_mpp ) CALL mpp_sum( 'icbclv', tot_flux )
142                IF( tot_flux > rsmall ) THEN
143                    WHERE( greenland_icesheet_mask(:,:) == 1.0 )                                                                                 &
144                    &    fwficb(:,:) = fwficb(:,:) * greenland_icesheet_mass_rate_of_change * rn_greenland_calving_fraction &
145                    &                                     / tot_flux
146                ELSE IF( rn_greenland_calving_fraction < rsmall ) THEN
147                    WHERE( greenland_icesheet_mask(:,:) == 1.0 ) fwficb(:,:) = 0.0
148                ELSE
149                    CALL CTL_STOP('STOP', 'No iceberg runoff data read in for Greenland. Check input file or set rn_greenland_calving_fraction=0.0')
150                ENDIF
151                tot_flux =  MAXVAL(fwficb(:,:)*tmask_i(:,:))
152                IF( lk_mpp ) CALL mpp_max( 'icbclv', tot_flux )
153                WRITE(numout,*) 'Max fwficb: ',tot_flux
154
155                tot_flux = SUM(fwficb(:,:)*e1e2t(:,:)*tmask_i(:,:)*antarctica_icesheet_mask(:,:))
156                IF( lk_mpp ) CALL mpp_sum( 'icbclv', tot_flux )
157                IF( tot_flux > rsmall ) THEN
158                    WHERE( antarctica_icesheet_mask(:,:) == 1.0 )                                                                                &
159                    &    fwficb(:,:) = fwficb(:,:) * antarctica_icesheet_mass_rate_of_change * rn_antarctica_calving_fraction &
160                    &                                     / (tot_flux  + 1.0e-10_wp )
161                ELSE IF( rn_antarctica_calving_fraction < rsmall ) THEN
162                    WHERE( antarctica_icesheet_mask(:,:) == 1.0 ) fwficb(:,:) = 0.0
163                ELSE
164                    CALL CTL_STOP('STOP', 'No iceberg runoff data read in for Greenland. Check input file or set rn_antarctica_calving_fraction=0.0')
165                ENDIF
166                tot_flux =  MAXVAL(fwficb(:,:)*tmask_i(:,:))
167                IF( lk_mpp ) CALL mpp_max( 'icbclv', tot_flux )
168                WRITE(numout,*) 'Max fwficb: ',tot_flux, antarctica_icesheet_mass_rate_of_change
169            ENDIF
170            CALL iom_put( 'iceberg_cea'  , fwficb(:,:)  )          ! output iceberg flux
171            CALL iom_put( 'hflx_icb_cea' , fwficb(:,:) * rLfus )   ! output Heat Flux into Sea Water due to Iceberg Thermodynamics -->
172            rnf(:,:) = rnf(:,:) + fwficb(:,:)                      ! fwficb isn't used anywhere else so add it to runoff here
173            qns_tot(:,:) = qns_tot(:,:) - fwficb(:,:) * rLfus      ! TG: I think this is correct
174         ENDIF
175         !
176         !                                                           ! set temperature & salinity content of runoffs
177         IF( ln_rnf_tem ) THEN                                       ! use runoffs temperature data
178            rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
179            CALL eos_fzp( sss_m(:,:), ztfrz(:,:) )
180            WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp )             ! if missing data value use SST as runoffs temperature
181               rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
182            END WHERE
183         ELSE                                                        ! use SST as runoffs temperature
184            !CEOD River is fresh water so must at least be 0 unless we consider ice
185            rnf_tsc(:,:,jp_tem) = MAX( sst_m(:,:), 0.0_wp ) * rnf(:,:) * r1_rau0
186         ENDIF
187         !                                                           ! use runoffs salinity data
188         IF( ln_rnf_sal )   rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
189         !                                                           ! else use S=0 for runoffs (done one for all in the init)
190                                         CALL iom_put( 'runoffs'     , rnf(:,:)                         )   ! output runoff mass flux
191         IF( iom_use('hflx_rnf_cea') )   CALL iom_put( 'hflx_rnf_cea', rnf_tsc(:,:,jp_tem) * rau0 * rcp )   ! output runoff sensible heat (W/m2)
192      ENDIF
193      !
194      !                                                ! ---------------------------------------- !
195      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
196         !                                             ! ---------------------------------------- !
197         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
198            & iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
199            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields red in the restart file', lrxios
200            CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b, ldxios = lrxios )     ! before runoff
201            CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem), ldxios = lrxios )   ! before heat content of runoff
202            CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal), ldxios = lrxios )   ! before salinity content of runoff
203         ELSE                                                   !* no restart: set from nit000 values
204            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields set to nit000'
205            rnf_b    (:,:  ) = rnf    (:,:  )
206            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
207         ENDIF
208      ENDIF
209      !                                                ! ---------------------------------------- !
210      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
211         !                                             ! ---------------------------------------- !
212         IF(lwp) WRITE(numout,*)
213         IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ',   &
214            &                    'at it= ', kt,' date= ', ndastp
215         IF(lwp) WRITE(numout,*) '~~~~'
216         IF( lwxios ) CALL iom_swap(      cwxios_context          )
217         CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf, ldxios = lwxios )
218         CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem), ldxios = lwxios )
219         CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal), ldxios = lwxios )
220         IF( lwxios ) CALL iom_swap(      cxios_context          )
221      ENDIF
222      !
223   END SUBROUTINE sbc_rnf
224
225
226   SUBROUTINE sbc_rnf_div( phdivn )
227      !!----------------------------------------------------------------------
228      !!                  ***  ROUTINE sbc_rnf  ***
229      !!
230      !! ** Purpose :   update the horizontal divergence with the runoff inflow
231      !!
232      !! ** Method  :
233      !!                CAUTION : rnf is positive (inflow) decreasing the
234      !!                          divergence and expressed in m/s
235      !!
236      !! ** Action  :   phdivn   decreased by the runoff inflow
237      !!----------------------------------------------------------------------
238      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   phdivn   ! horizontal divergence
239      !!
240      INTEGER  ::   ji, jj, jk   ! dummy loop indices
241      REAL(wp) ::   zfact     ! local scalar
242      !!----------------------------------------------------------------------
243      !
244      zfact = 0.5_wp
245      !
246      IF( ln_rnf_depth .OR. ln_rnf_depth_ini ) THEN      !==   runoff distributed over several levels   ==!
247         IF( ln_linssh ) THEN    !* constant volume case : just apply the runoff input flow
248            DO jj = 1, jpj
249               DO ji = 1, jpi
250                  DO jk = 1, nk_rnf(ji,jj)
251                     phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
252                  END DO
253               END DO
254            END DO
255         ELSE                    !* variable volume case
256            DO jj = 1, jpj                   ! update the depth over which runoffs are distributed
257               DO ji = 1, jpi
258                  h_rnf(ji,jj) = 0._wp
259                  DO jk = 1, nk_rnf(ji,jj)                           ! recalculates h_rnf to be the depth in metres
260                     h_rnf(ji,jj) = h_rnf(ji,jj) + e3t_n(ji,jj,jk)   ! to the bottom of the relevant grid box
261                  END DO
262                  !                          ! apply the runoff input flow
263                  DO jk = 1, nk_rnf(ji,jj)
264                     phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
265                  END DO
266               END DO
267            END DO
268         ENDIF
269      ELSE                       !==   runoff put only at the surface   ==!
270         h_rnf (:,:)   = e3t_n (:,:,1)        ! update h_rnf to be depth of top box
271         phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / e3t_n(:,:,1)
272      ENDIF
273      !
274   END SUBROUTINE sbc_rnf_div
275
276
277   SUBROUTINE sbc_rnf_init
278      !!----------------------------------------------------------------------
279      !!                  ***  ROUTINE sbc_rnf_init  ***
280      !!
281      !! ** Purpose :   Initialisation of the runoffs if (ln_rnf=T)
282      !!
283      !! ** Method  : - read the runoff namsbc_rnf namelist
284      !!
285      !! ** Action  : - read parameters
286      !!----------------------------------------------------------------------
287      CHARACTER(len=32) ::   rn_dep_file   ! runoff file name
288      INTEGER           ::   ji, jj, jk, jm    ! dummy loop indices
289      INTEGER           ::   ierror, inum  ! temporary integer
290      INTEGER           ::   ios           ! Local integer output status for namelist read
291      INTEGER           ::   nbrec         ! temporary integer
292      REAL(wp)          ::   zacoef 
293      REAL(wp), DIMENSION(jpi,jpj,2) :: zrnfcl   
294      !!
295      NAMELIST/namsbc_rnf/ cn_dir            , ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, ln_rnf_icb, ln_icb_mass,  &
296         &                 sn_rnf, sn_cnf    , sn_i_rnf, sn_s_rnf    , sn_t_rnf  , sn_dep_rnf,   &
297         &                 ln_rnf_mouth      , rn_hrnf     , rn_avt_rnf, rn_rfact,     &
298         &                 ln_rnf_depth_ini  , rn_dep_max  , rn_rnf_max, nn_rnf_depth_file
299      !!----------------------------------------------------------------------
300      !
301      !                                         !==  allocate runoff arrays
302      IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
303      !
304      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
305         ln_rnf_mouth  = .FALSE.                   ! default definition needed for example by sbc_ssr or by tra_adv_muscl
306         nkrnf         = 0
307         rnf     (:,:) = 0.0_wp
308         rnf_b   (:,:) = 0.0_wp
309         rnfmsk  (:,:) = 0.0_wp
310         rnfmsk_z(:)   = 0.0_wp
311         RETURN
312      ENDIF
313      !
314      !                                   ! ============
315      !                                   !   Namelist
316      !                                   ! ============
317      !
318      REWIND( numnam_ref )
319      READ  ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
320901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist' )
321
322      REWIND( numnam_cfg )
323      READ  ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
324902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist' )
325      IF(lwm) WRITE ( numond, namsbc_rnf )
326      !
327      !                                         ! Control print
328      IF(lwp) THEN
329         WRITE(numout,*)
330         WRITE(numout,*) 'sbc_rnf_init : runoff '
331         WRITE(numout,*) '~~~~~~~~~~~~ '
332         WRITE(numout,*) '   Namelist namsbc_rnf'
333         WRITE(numout,*) '      specific river mouths treatment            ln_rnf_mouth = ', ln_rnf_mouth
334         WRITE(numout,*) '      river mouth additional Kz                  rn_avt_rnf   = ', rn_avt_rnf
335         WRITE(numout,*) '      depth of river mouth additional mixing     rn_hrnf      = ', rn_hrnf
336         WRITE(numout,*) '      multiplicative factor for runoff           rn_rfact     = ', rn_rfact
337      ENDIF
338      !                                   ! ==================
339      !                                   !   Type of runoff
340      !                                   ! ==================
341      !
342      IF( .NOT. l_rnfcpl ) THEN                   
343         ALLOCATE( sf_rnf(1), STAT=ierror )         ! Create sf_rnf structure (runoff inflow)
344         IF(lwp) WRITE(numout,*)
345         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs inflow read in a file'
346         IF( ierror > 0 ) THEN
347            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_rnf structure' )   ;   RETURN
348         ENDIF
349         ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1)   )
350         IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
351         CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf', no_print )
352         !
353      ENDIF
354      IF( ln_rnf_icb ) THEN                      ! Create (if required) sf_i_rnf structure
355         IF(lwp) WRITE(numout,*)
356         IF(lwp) WRITE(numout,*) '          iceberg flux read in a file'
357         ALLOCATE( sf_i_rnf(1), STAT=ierror  )
358         IF( ierror > 0 ) THEN
359            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_i_rnf structure' )   ;   RETURN
360         ENDIF
361         ALLOCATE( sf_i_rnf(1)%fnow(jpi,jpj,1)   )
362         IF( sn_i_rnf%ln_tint ) ALLOCATE( sf_i_rnf(1)%fdta(jpi,jpj,1,2) )
363         CALL fld_fill (sf_i_rnf, (/ sn_i_rnf /), cn_dir, 'sbc_rnf_init', 'read iceberg flux data', 'namsbc_rnf' )
364      ELSE
365         fwficb(:,:) = 0._wp
366      ENDIF
367
368      !
369      IF( ln_rnf_tem ) THEN                      ! Create (if required) sf_t_rnf structure
370         IF(lwp) WRITE(numout,*)
371         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs temperatures read in a file'
372         ALLOCATE( sf_t_rnf(1), STAT=ierror  )
373         IF( ierror > 0 ) THEN
374            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' )   ;   RETURN
375         ENDIF
376         ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1)   )
377         IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
378         CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf', no_print )
379      ENDIF
380      !
381      IF( ln_rnf_sal  ) THEN                     ! Create (if required) sf_s_rnf and sf_t_rnf structures
382         IF(lwp) WRITE(numout,*)
383         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs salinities read in a file'
384         ALLOCATE( sf_s_rnf(1), STAT=ierror  )
385         IF( ierror > 0 ) THEN
386            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' )   ;   RETURN
387         ENDIF
388         ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1)   )
389         IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
390         CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf', no_print )
391      ENDIF
392      !
393      IF( ln_rnf_depth ) THEN                    ! depth of runoffs set from a file
394         IF(lwp) WRITE(numout,*)
395         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs depth read in a file'
396         rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
397         IF( .NOT. sn_dep_rnf%ln_clim ) THEN   ;   WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear    ! add year
398            IF( sn_dep_rnf%cltype == 'monthly' )   WRITE(rn_dep_file, '(a,"m",i2)'  ) TRIM( rn_dep_file ), nmonth   ! add month
399         ENDIF
400         CALL iom_open ( rn_dep_file, inum )                           ! open file
401         CALL iom_get  ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf )   ! read the river mouth array
402         CALL iom_close( inum )                                        ! close file
403         !
404         nk_rnf(:,:) = 0                               ! set the number of level over which river runoffs are applied
405         DO jj = 1, jpj
406            DO ji = 1, jpi
407               IF( h_rnf(ji,jj) > 0._wp ) THEN
408                  jk = 2
409                  DO WHILE ( jk < mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
410                  END DO
411                  nk_rnf(ji,jj) = jk
412               ELSEIF( h_rnf(ji,jj) == -1._wp   ) THEN   ;  nk_rnf(ji,jj) = 1
413               ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN   ;  nk_rnf(ji,jj) = mbkt(ji,jj)
414               ELSE
415                  CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999'  )
416                  WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
417               ENDIF
418            END DO
419         END DO
420         DO jj = 1, jpj                                ! set the associated depth
421            DO ji = 1, jpi
422               h_rnf(ji,jj) = 0._wp
423               DO jk = 1, nk_rnf(ji,jj)
424                  h_rnf(ji,jj) = h_rnf(ji,jj) + e3t_n(ji,jj,jk)
425               END DO
426            END DO
427         END DO
428         !
429      ELSE IF( ln_rnf_depth_ini ) THEN           ! runoffs applied at the surface
430         !
431         IF(lwp) WRITE(numout,*)
432         IF(lwp) WRITE(numout,*) '   ==>>>   depth of runoff computed once from max value of runoff'
433         IF(lwp) WRITE(numout,*) '        max value of the runoff climatologie (over global domain) rn_rnf_max = ', rn_rnf_max
434         IF(lwp) WRITE(numout,*) '        depth over which runoffs is spread                        rn_dep_max = ', rn_dep_max
435         IF(lwp) WRITE(numout,*) '        create (=1) a runoff depth file or not (=0)      nn_rnf_depth_file  = ', nn_rnf_depth_file
436
437         CALL iom_open( TRIM( sn_rnf%clname ), inum )    !  open runoff file
438         nbrec = iom_getszuld( inum )
439         zrnfcl(:,:,1) = 0._wp                                                          ! init the max to 0. in 1
440         DO jm = 1, nbrec
441            CALL iom_get( inum, jpdom_data, TRIM( sn_rnf%clvar ), zrnfcl(:,:,2), jm )   ! read the value in 2
442            zrnfcl(:,:,1) = MAXVAL( zrnfcl(:,:,:), DIM=3 )                              ! store the maximum value in time in 1
443         END DO
444         CALL iom_close( inum )
445         !
446         h_rnf(:,:) = 1.
447         !
448         zacoef = rn_dep_max / rn_rnf_max            ! coef of linear relation between runoff and its depth (150m for max of runoff)
449         !
450         WHERE( zrnfcl(:,:,1) > 0._wp )  h_rnf(:,:) = zacoef * zrnfcl(:,:,1)   ! compute depth for all runoffs
451         !
452         DO jj = 1, jpj                     ! take in account min depth of ocean rn_hmin
453            DO ji = 1, jpi
454               IF( zrnfcl(ji,jj,1) > 0._wp ) THEN
455                  jk = mbkt(ji,jj)
456                  h_rnf(ji,jj) = MIN( h_rnf(ji,jj), gdept_0(ji,jj,jk ) )
457               ENDIF
458            END DO
459         END DO
460         !
461         nk_rnf(:,:) = 0                       ! number of levels on which runoffs are distributed
462         DO jj = 1, jpj
463            DO ji = 1, jpi
464               IF( zrnfcl(ji,jj,1) > 0._wp ) THEN
465                  jk = 2
466                  DO WHILE ( jk < mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
467                  END DO
468                  nk_rnf(ji,jj) = jk
469               ELSE
470                  nk_rnf(ji,jj) = 1
471               ENDIF
472            END DO
473         END DO
474         !
475         DO jj = 1, jpj                                ! set the associated depth
476            DO ji = 1, jpi
477               h_rnf(ji,jj) = 0._wp
478               DO jk = 1, nk_rnf(ji,jj)
479                  h_rnf(ji,jj) = h_rnf(ji,jj) + e3t_n(ji,jj,jk)
480               END DO
481            END DO
482         END DO
483         !
484         IF( nn_rnf_depth_file == 1 ) THEN      !  save  output nb levels for runoff
485            IF(lwp) WRITE(numout,*) '   ==>>>   create runoff depht file'
486            CALL iom_open  ( TRIM( sn_dep_rnf%clname ), inum, ldwrt = .TRUE. )
487            CALL iom_rstput( 0, 0, inum, 'rodepth', h_rnf )
488            CALL iom_close ( inum )
489         ENDIF
490      ELSE                                       ! runoffs applied at the surface
491         nk_rnf(:,:) = 1
492         h_rnf (:,:) = e3t_n(:,:,1)
493      ENDIF
494      !
495      rnf(:,:) =  0._wp                         ! runoff initialisation
496      rnf_tsc(:,:,:) = 0._wp                    ! runoffs temperature & salinty contents initilisation
497      !
498      !                                   ! ========================
499      !                                   !   River mouth vicinity
500      !                                   ! ========================
501      !
502      IF( ln_rnf_mouth ) THEN                   ! Specific treatment in vicinity of river mouths :
503         !                                      !    - Increase Kz in surface layers ( rn_hrnf > 0 )
504         !                                      !    - set to zero SSS damping (ln_ssr=T)
505         !                                      !    - mixed upstream-centered (ln_traadv_cen2=T)
506         !
507         IF( ln_rnf_depth )   CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already',   &
508            &                                              'be spread through depth by ln_rnf_depth'               )
509         !
510         nkrnf = 0                                  ! Number of level over which Kz increase
511         IF( rn_hrnf > 0._wp ) THEN
512            nkrnf = 2
513            DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf )   ;   nkrnf = nkrnf + 1
514            END DO
515            IF( ln_sco )   CALL ctl_warn( 'sbc_rnf_init: number of levels over which Kz is increased is computed for zco...' )
516         ENDIF
517         IF(lwp) WRITE(numout,*)
518         IF(lwp) WRITE(numout,*) '   ==>>>   Specific treatment used in vicinity of river mouths :'
519         IF(lwp) WRITE(numout,*) '             - Increase Kz in surface layers (if rn_hrnf > 0 )'
520         IF(lwp) WRITE(numout,*) '               by ', rn_avt_rnf,' m2/s  over ', nkrnf, ' w-levels'
521         IF(lwp) WRITE(numout,*) '             - set to zero SSS damping       (if ln_ssr=T)'
522         IF(lwp) WRITE(numout,*) '             - mixed upstream-centered       (if ln_traadv_cen2=T)'
523         !
524         CALL rnf_mouth                             ! set river mouth mask
525         !
526      ELSE                                      ! No treatment at river mouths
527         IF(lwp) WRITE(numout,*)
528         IF(lwp) WRITE(numout,*) '   ==>>>   No specific treatment at river mouths'
529         rnfmsk  (:,:) = 0._wp
530         rnfmsk_z(:)   = 0._wp
531         nkrnf = 0
532      ENDIF
533      !
534      IF( lwxios ) THEN
535         CALL iom_set_rstw_var_active('rnf_b')
536         CALL iom_set_rstw_var_active('rnf_hc_b')
537         CALL iom_set_rstw_var_active('rnf_sc_b')
538      ENDIF
539
540   END SUBROUTINE sbc_rnf_init
541
542
543   SUBROUTINE rnf_mouth
544      !!----------------------------------------------------------------------
545      !!                  ***  ROUTINE rnf_mouth  ***
546      !!
547      !! ** Purpose :   define the river mouths mask
548      !!
549      !! ** Method  :   read the river mouth mask (=0/1) in the river runoff
550      !!                climatological file. Defined a given vertical structure.
551      !!                CAUTION, the vertical structure is hard coded on the
552      !!                first 5 levels.
553      !!                This fields can be used to:
554      !!                 - set an upstream advection scheme
555      !!                   (ln_rnf_mouth=T and ln_traadv_cen2=T)
556      !!                 - increase vertical on the top nn_krnf vertical levels
557      !!                   at river runoff input grid point (nn_krnf>=2, see step.F90)
558      !!                 - set to zero SSS restoring flux at river mouth grid points
559      !!
560      !! ** Action  :   rnfmsk   set to 1 at river runoff input, 0 elsewhere
561      !!                rnfmsk_z vertical structure
562      !!----------------------------------------------------------------------
563      INTEGER            ::   inum        ! temporary integers
564      CHARACTER(len=140) ::   cl_rnfile   ! runoff file name
565      !!----------------------------------------------------------------------
566      !
567      IF(lwp) WRITE(numout,*)
568      IF(lwp) WRITE(numout,*) '   rnf_mouth : river mouth mask'
569      IF(lwp) WRITE(numout,*) '   ~~~~~~~~~ '
570      !
571      cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
572      IF( .NOT. sn_cnf%ln_clim ) THEN   ;   WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear    ! add year
573         IF( sn_cnf%cltype == 'monthly' )   WRITE(cl_rnfile, '(a,"m",i2)'  ) TRIM( cl_rnfile ), nmonth   ! add month
574      ENDIF
575      !
576      ! horizontal mask (read in NetCDF file)
577      CALL iom_open ( cl_rnfile, inum )                           ! open file
578      CALL iom_get  ( inum, jpdom_data, sn_cnf%clvar, rnfmsk )    ! read the river mouth array
579      CALL iom_close( inum )                                      ! close file
580      !
581      IF( l_clo_rnf )   CALL clo_rnf( rnfmsk )   ! closed sea inflow set as river mouth
582      !
583      rnfmsk_z(:)   = 0._wp                                       ! vertical structure
584      rnfmsk_z(1)   = 1.0
585      rnfmsk_z(2)   = 1.0                                         ! **********
586      rnfmsk_z(3)   = 0.5                                         ! HARD CODED on the 5 first levels
587      rnfmsk_z(4)   = 0.25                                        ! **********
588      rnfmsk_z(5)   = 0.125
589      !
590   END SUBROUTINE rnf_mouth
591
592   !!======================================================================
593END MODULE sbcrnf
Note: See TracBrowser for help on using the repository browser.