source: NEMO/branches/UKMO/NEMO_4.0_GO8_package_text_diagnostics/src/OCE/ICB/icbini.F90 @ 10948

Last change on this file since 10948 was 10948, checked in by andmirek, 19 months ago

GMED 462 iceberg model

File size: 23.9 KB
Line 
1MODULE icbini
2   !!======================================================================
3   !!                       ***  MODULE  icbini  ***
4   !! Icebergs:  initialise variables for iceberg tracking
5   !!======================================================================
6   !! History :   -   !  2010-01  (T. Martin & A. Adcroft)  Original code
7   !!            3.3  !  2011-03  (G. Madec)  Part conversion to NEMO form ; Removal of mapping from another grid
8   !!             -   !  2011-04  (S. Alderson)  Split into separate modules ; Restore restart routines
9   !!             -   !  2011-05  (S. Alderson)  generate_test_icebergs restored ; new forcing arrays with extra halo ;
10   !!             -   !                          north fold exchange arrays added
11   !!----------------------------------------------------------------------
12   !!----------------------------------------------------------------------
13   !!   icb_init     : initialise icebergs
14   !!   icb_ini_gen  : generate test icebergs
15   !!   icb_nam      : read iceberg namelist
16   !!----------------------------------------------------------------------
17   USE dom_oce        ! ocean domain
18   USE in_out_manager ! IO routines and numout in particular
19   USE lib_mpp        ! mpi library and lk_mpp in particular
20   USE sbc_oce        ! ocean  : surface boundary condition
21   USE sbc_ice        ! sea-ice: surface boundary condition
22   USE iom            ! IOM library
23   USE fldread        ! field read
24   USE lbclnk         ! lateral boundary condition - MPP link
25   !
26   USE icb_oce        ! define iceberg arrays
27   USE icbutl         ! iceberg utility routines
28   USE icbrst         ! iceberg restart routines
29   USE icbtrj         ! iceberg trajectory I/O routines
30   USE icbdia         ! iceberg budget routines
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   icb_init  ! routine called in nemogcm.F90 module
36
37   CHARACTER(len=100)                                 ::   cn_dir = './'   !: Root directory for location of icb files
38   TYPE(FLD_N)                                        ::   sn_icb          !: information about the calving file to be read
39   TYPE(FLD), PUBLIC, ALLOCATABLE     , DIMENSION(:)  ::   sf_icb          !: structure: file information, fields read
40                                                                           !: used in icbini and icbstp
41   !!----------------------------------------------------------------------
42   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
43   !! $Id$
44   !! Software governed by the CeCILL license (see ./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE icb_init( pdt, kt )
49      !!----------------------------------------------------------------------
50      !!                  ***  ROUTINE dom_init  ***
51      !!
52      !! ** Purpose :   iceberg initialization.
53      !!
54      !! ** Method  : - read the iceberg namelist
55      !!              - find non-overlapping processor interior since we can only
56      !!                have one instance of a particular iceberg
57      !!              - calculate the destinations for north fold exchanges
58      !!              - setup either test icebergs or calving file
59      !!----------------------------------------------------------------------
60      REAL(wp), INTENT(in) ::   pdt   ! iceberg time-step (rdt*nn_fsbc)
61      INTEGER , INTENT(in) ::   kt    ! time step number
62      !
63      INTEGER ::   ji, jj, jn               ! dummy loop indices
64      INTEGER ::   i1, i2, i3               ! local integers
65      INTEGER ::   ii, inum, ivar           !   -       -
66      INTEGER ::   istat1, istat2, istat3   !   -       -
67      CHARACTER(len=300) ::   cl_sdist      ! local character
68      !!----------------------------------------------------------------------
69      !
70      CALL icb_nam               ! Read and print namelist parameters
71      !
72      IF( .NOT. ln_icebergs )   RETURN
73
74      !                          ! allocate gridded fields
75      IF( icb_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'icb_alloc : unable to allocate arrays' )
76      !
77      !                          ! initialised variable with extra haloes to zero
78      uo_e(:,:) = 0._wp   ;   vo_e(:,:) = 0._wp   ;
79      ua_e(:,:) = 0._wp   ;   va_e(:,:) = 0._wp   ;
80      ff_e(:,:) = 0._wp   ;   tt_e(:,:) = 0._wp   ;
81      fr_e(:,:) = 0._wp   ;
82#if defined key_si3
83      hi_e(:,:) = 0._wp   ;
84      ui_e(:,:) = 0._wp   ;   vi_e(:,:) = 0._wp   ;
85#endif
86      ssh_e(:,:) = 0._wp  ; 
87      !
88      !                          ! open ascii output file or files for iceberg status information
89      !                          ! note that we choose to do this on all processors since we cannot
90      !                          ! predict where icebergs will be ahead of time
91      numicb=-1
92      IF( nn_verbose_level > 0 .AND. nprint>0) THEN
93         CALL ctl_opn( numicb, 'icebergs.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
94      ELSE
95         IF(lwp) CALL ctl_opn( numicb, 'icebergs.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea ) 
96      ENDIF
97
98      ! set parameters (mostly from namelist)
99      !
100      berg_dt         = pdt
101      first_width (:) = SQRT(  rn_initial_mass(:) / ( rn_LoW_ratio * rn_rho_bergs * rn_initial_thickness(:) )  )
102      first_length(:) = rn_LoW_ratio * first_width(:)
103
104      berg_grid%calving      (:,:)   = 0._wp
105      berg_grid%calving_hflx (:,:)   = 0._wp
106      berg_grid%stored_heat  (:,:)   = 0._wp
107      berg_grid%floating_melt(:,:)   = 0._wp
108      berg_grid%maxclass     (:,:)   = nclasses
109      berg_grid%stored_ice   (:,:,:) = 0._wp
110      berg_grid%tmp          (:,:)   = 0._wp
111      src_calving            (:,:)   = 0._wp
112      src_calving_hflx       (:,:)   = 0._wp
113
114      !                          ! domain for icebergs
115      IF( lk_mpp .AND. jpni == 1 )   CALL ctl_stop( 'icbinit: having ONE processor in x currently does not work' )
116      ! NB: the issue here is simply that cyclic east-west boundary condition have not been coded in mpp case
117      ! for the north fold we work out which points communicate by asking
118      ! lbc_lnk to pass processor number (valid even in single processor case)
119      ! borrow src_calving arrays for this
120      !
121      ! pack i and j together using a scaling of a power of 10
122      nicbpack = 10000
123      IF( jpiglo >= nicbpack )   CALL ctl_stop( 'icbini: processor index packing failure' )
124      nicbfldproc(:) = -1
125
126      DO jj = 1, jpj
127         DO ji = 1, jpi
128            src_calving_hflx(ji,jj) = narea
129            src_calving     (ji,jj) = nicbpack * mjg(jj) + mig(ji)
130         END DO
131      END DO
132      CALL lbc_lnk( 'icbini', src_calving_hflx, 'T', 1._wp )
133      CALL lbc_lnk( 'icbini', src_calving     , 'T', 1._wp )
134
135      ! work out interior of processor from exchange array
136      ! first entry with narea for this processor is left hand interior index
137      ! last  entry                               is right hand interior index
138      jj = nlcj/2
139      nicbdi = -1
140      nicbei = -1
141      DO ji = 1, jpi
142         i3 = INT( src_calving(ji,jj) )
143         i2 = INT( i3/nicbpack )
144         i1 = i3 - i2*nicbpack
145         i3 = INT( src_calving_hflx(ji,jj) )
146         IF( i1 == mig(ji) .AND. i3 == narea ) THEN
147            IF( nicbdi < 0 ) THEN   ;   nicbdi = ji
148            ELSE                    ;   nicbei = ji
149            ENDIF
150         ENDIF
151      END DO
152      !
153      ! repeat for j direction
154      ji = nlci/2
155      nicbdj = -1
156      nicbej = -1
157      DO jj = 1, jpj
158         i3 = INT( src_calving(ji,jj) )
159         i2 = INT( i3/nicbpack )
160         i1 = i3 - i2*nicbpack
161         i3 = INT( src_calving_hflx(ji,jj) )
162         IF( i2 == mjg(jj) .AND. i3 == narea ) THEN
163            IF( nicbdj < 0 ) THEN   ;   nicbdj = jj
164            ELSE                    ;   nicbej = jj
165            ENDIF
166         ENDIF
167      END DO
168      !   
169      ! special for east-west boundary exchange we save the destination index
170      i1 = MAX( nicbdi-1, 1)
171      i3 = INT( src_calving(i1,nlcj/2) )
172      jj = INT( i3/nicbpack )
173      ricb_left = REAL( i3 - nicbpack*jj, wp )
174      i1 = MIN( nicbei+1, jpi )
175      i3 = INT( src_calving(i1,nlcj/2) )
176      jj = INT( i3/nicbpack )
177      ricb_right = REAL( i3 - nicbpack*jj, wp )
178     
179      ! north fold
180      IF( npolj > 0 ) THEN
181         !
182         ! icebergs in row nicbej+1 get passed across fold
183         nicbfldpts(:)  = INT( src_calving(:,nicbej+1) )
184         nicbflddest(:) = INT( src_calving_hflx(:,nicbej+1) )
185         !
186         ! work out list of unique processors to talk to
187         ! pack them into a fixed size array where empty slots are marked by a -1
188         DO ji = nicbdi, nicbei
189            ii = nicbflddest(ji)
190            IF( ii .GT. 0 ) THEN     ! Needed because land suppression can mean
191                                     ! that unused points are not set in edge haloes
192               DO jn = 1, jpni
193                  ! work along array until we find an empty slot
194                  IF( nicbfldproc(jn) == -1 ) THEN
195                     nicbfldproc(jn) = ii
196                     EXIT                             !!gm EXIT should be avoided: use DO WHILE expression instead
197                  ENDIF
198                  ! before we find an empty slot, we may find processor number is already here so we exit
199                  IF( nicbfldproc(jn) == ii ) EXIT
200               END DO
201            ENDIF
202         END DO
203      ENDIF
204      !
205      IF( nn_verbose_level > 0  .AND. numicb.NE.-1 ) THEN
206         WRITE(numicb,*) 'processor ', narea
207         WRITE(numicb,*) 'jpi, jpj   ', jpi, jpj
208         WRITE(numicb,*) 'nldi, nlei ', nldi, nlei
209         WRITE(numicb,*) 'nldj, nlej ', nldj, nlej
210         WRITE(numicb,*) 'berg i interior ', nicbdi, nicbei
211         WRITE(numicb,*) 'berg j interior ', nicbdj, nicbej
212         WRITE(numicb,*) 'berg left       ', ricb_left
213         WRITE(numicb,*) 'berg right      ', ricb_right
214         jj = nlcj/2
215         WRITE(numicb,*) "central j line:"
216         WRITE(numicb,*) "i processor"
217         WRITE(numicb,*) (INT(src_calving_hflx(ji,jj)), ji=1,jpi)
218         WRITE(numicb,*) "i point"
219         WRITE(numicb,*) (INT(src_calving(ji,jj)), ji=1,jpi)
220         ji = nlci/2
221         WRITE(numicb,*) "central i line:"
222         WRITE(numicb,*) "j processor"
223         WRITE(numicb,*) (INT(src_calving_hflx(ji,jj)), jj=1,jpj)
224         WRITE(numicb,*) "j point"
225         WRITE(numicb,*) (INT(src_calving(ji,jj)), jj=1,jpj)
226         IF( npolj > 0 ) THEN
227            WRITE(numicb,*) 'north fold destination points '
228            WRITE(numicb,*) nicbfldpts
229            WRITE(numicb,*) 'north fold destination procs  '
230            WRITE(numicb,*) nicbflddest
231            WRITE(numicb,*) 'north fold destination proclist  '
232            WRITE(numicb,*) nicbfldproc
233         ENDIF
234         CALL flush(numicb)
235      ENDIF
236     
237      src_calving     (:,:) = 0._wp
238      src_calving_hflx(:,:) = 0._wp
239
240      ! definition of extended surface masked needed by icb_bilin_h
241      tmask_e(:,:) = 0._wp   ;   tmask_e(1:jpi,1:jpj) = tmask(:,:,1)
242      umask_e(:,:) = 0._wp   ;   umask_e(1:jpi,1:jpj) = umask(:,:,1)
243      vmask_e(:,:) = 0._wp   ;   vmask_e(1:jpi,1:jpj) = vmask(:,:,1)
244      CALL lbc_lnk_icb( 'icbini', tmask_e, 'T', +1._wp, 1, 1 )
245      CALL lbc_lnk_icb( 'icbini', umask_e, 'T', +1._wp, 1, 1 )
246      CALL lbc_lnk_icb( 'icbini', vmask_e, 'T', +1._wp, 1, 1 )
247      !
248      ! assign each new iceberg with a unique number constructed from the processor number
249      ! and incremented by the total number of processors
250      num_bergs(:) = 0
251      num_bergs(1) = narea - jpnij
252
253      ! when not generating test icebergs we need to setup calving file
254      IF( nn_test_icebergs < 0 .OR. ln_use_calving ) THEN
255         !
256         ! maximum distribution class array does not change in time so read it once
257         cl_sdist = TRIM( cn_dir )//TRIM( sn_icb%clname )
258         CALL iom_open ( cl_sdist, inum )                              ! open file
259         ivar = iom_varid( inum, 'maxclass', ldstop=.FALSE. )
260         IF( ivar > 0 ) THEN
261            CALL iom_get  ( inum, jpdom_data, 'maxclass', src_calving )   ! read the max distribution array
262            berg_grid%maxclass(:,:) = INT( src_calving )
263            src_calving(:,:) = 0._wp
264         ENDIF
265         CALL iom_close( inum )                                     ! close file
266         !
267         IF( nn_verbose_level > 0  .AND. numicb.NE.-1 ) THEN
268            WRITE(numicb,*)
269            WRITE(numicb,*) '          calving read in a file'
270         ENDIF
271         ALLOCATE( sf_icb(1), STAT=istat1 )         ! Create sf_icb structure (calving)
272         ALLOCATE( sf_icb(1)%fnow(jpi,jpj,1), STAT=istat2 )
273         ALLOCATE( sf_icb(1)%fdta(jpi,jpj,1,2), STAT=istat3 )
274         IF( istat1+istat2+istat3 > 0 ) THEN
275            CALL ctl_stop( 'sbc_icb: unable to allocate sf_icb structure' )   ;   RETURN
276         ENDIF
277         !                                          ! fill sf_icb with the namelist (sn_icb) and control print
278         CALL fld_fill( sf_icb, (/ sn_icb /), cn_dir, 'icb_init', 'read calving data', 'namicb' )
279         !
280      ENDIF
281
282      IF( .NOT.ln_rstart ) THEN
283         IF( nn_test_icebergs > 0 )   CALL icb_ini_gen()
284      ELSE
285         IF( nn_test_icebergs > 0 ) THEN
286            CALL icb_ini_gen()
287         ELSE
288            CALL icb_rst_read()
289            l_restarted_bergs = .TRUE.
290         ENDIF
291      ENDIF
292      !
293      IF( nn_sample_rate .GT. 0 ) CALL icb_trj_init( nitend )
294      !
295      CALL icb_dia_init()
296      !
297      IF( nn_verbose_level >= 2 )   CALL icb_utl_print('icb_init, initial status', nit000-1)
298      !
299   END SUBROUTINE icb_init
300
301
302   SUBROUTINE icb_ini_gen()
303      !!----------------------------------------------------------------------
304      !!                  ***  ROUTINE icb_ini_gen  ***
305      !!
306      !! ** Purpose :   iceberg generation
307      !!
308      !! ** Method  : - at each grid point of the test box supplied in the namelist
309      !!                generate an iceberg in one class determined by the value of
310      !!                parameter nn_test_icebergs
311      !!----------------------------------------------------------------------
312      INTEGER                         ::   ji, jj, ibergs
313      TYPE(iceberg)                   ::   localberg ! NOT a pointer but an actual local variable
314      TYPE(point)                     ::   localpt
315      INTEGER                         ::   iyr, imon, iday, ihr, imin, isec
316      INTEGER                         ::   iberg
317      !!----------------------------------------------------------------------
318
319      ! For convenience
320      iberg = nn_test_icebergs
321
322      ! call get_date(Time, iyr, imon, iday, ihr, imin, isec)
323      ! Convert nemo time variables from dom_oce into local versions
324      iyr  = nyear
325      imon = nmonth
326      iday = nday
327      ihr = INT(nsec_day/3600)
328      imin = INT((nsec_day-ihr*3600)/60)
329      isec = nsec_day - ihr*3600 - imin*60
330
331      ! no overlap for icebergs since we want only one instance of each across the whole domain
332      ! so restrict area of interest
333      ! use tmask here because tmask_i has been doctored on one side of the north fold line
334
335      DO jj = nicbdj, nicbej
336         DO ji = nicbdi, nicbei
337            IF( tmask(ji,jj,1) > 0._wp        .AND.                                       &
338                rn_test_box(1) < glamt(ji,jj) .AND. glamt(ji,jj) < rn_test_box(2) .AND.   &
339                rn_test_box(3) < gphit(ji,jj) .AND. gphit(ji,jj) < rn_test_box(4) ) THEN
340               localberg%mass_scaling = rn_mass_scaling(iberg)
341               localpt%xi = REAL( mig(ji), wp )
342               localpt%yj = REAL( mjg(jj), wp )
343               localpt%lon = icb_utl_bilin(glamt, localpt%xi, localpt%yj, 'T' )
344               localpt%lat = icb_utl_bilin(gphit, localpt%xi, localpt%yj, 'T' )
345               localpt%mass      = rn_initial_mass     (iberg)
346               localpt%thickness = rn_initial_thickness(iberg)
347               localpt%width  = first_width (iberg)
348               localpt%length = first_length(iberg)
349               localpt%year = iyr
350               localpt%day = REAL(iday,wp)+(REAL(ihr,wp)+REAL(imin,wp)/60._wp)/24._wp
351               localpt%mass_of_bits = 0._wp
352               localpt%heat_density = 0._wp
353               localpt%uvel = 0._wp
354               localpt%vvel = 0._wp
355               CALL icb_utl_incr()
356               localberg%number(:) = num_bergs(:)
357               call icb_utl_add(localberg, localpt)
358            ENDIF
359         END DO
360      END DO
361      !
362      ibergs = icb_utl_count()
363      CALL mpp_sum('icbini', ibergs)
364      IF( nn_verbose_level > 0  .AND. numicb.NE.-1 ) THEN
365         WRITE(numicb,'(a,i6,a)') 'diamonds, icb_ini_gen: ',ibergs,' were generated'
366      ENDIF
367      !
368   END SUBROUTINE icb_ini_gen
369
370
371   SUBROUTINE icb_nam
372      !!----------------------------------------------------------------------
373      !!                     ***  ROUTINE icb_nam  ***
374      !!
375      !! ** Purpose :   read iceberg namelist and print the variables.
376      !!
377      !! ** input   : - namberg namelist
378      !!----------------------------------------------------------------------
379      INTEGER  ::   jn      ! dummy loop indices
380      INTEGER  ::   ios     ! Local integer output status for namelist read
381      REAL(wp) ::   zfact   ! local scalar
382      !
383      NAMELIST/namberg/ ln_icebergs    , ln_bergdia     , nn_sample_rate      , rn_initial_mass      ,   &
384         &              rn_distribution, rn_mass_scaling, rn_initial_thickness, nn_verbose_write     ,   &
385         &              rn_rho_bergs   , rn_LoW_ratio   , nn_verbose_level    , ln_operator_splitting,   &
386         &              rn_bits_erosion_fraction        , rn_sicn_shift       , ln_passive_mode      ,   &
387         &              ln_time_average_weight          , nn_test_icebergs    , rn_test_box          ,   &
388         &              ln_use_calving , rn_speed_limit , cn_dir, sn_icb
389      !!----------------------------------------------------------------------
390
391#if defined key_agrif
392      IF(lwp) THEN
393         WRITE(numout,*)
394         WRITE(numout,*) 'icb_nam : AGRIF is not compatible with namelist namberg :  '
395         WRITE(numout,*) '~~~~~~~   definition of rn_initial_mass(nclasses) with nclasses as PARAMETER '
396         WRITE(numout,*)
397         WRITE(numout,*) '   ==>>>   force  NO icebergs used. The namelist namberg is not read'
398      ENDIF
399      ln_icebergs = .false.     
400      RETURN
401#else
402      IF(lwp) THEN
403         WRITE(numout,*)
404         WRITE(numout,*) 'icb_nam : iceberg initialization through namberg namelist read'
405         WRITE(numout,*) '~~~~~~~~ '
406      ENDIF
407#endif   
408      !                             !==  read namelist  ==!
409      REWIND( numnam_ref )              ! Namelist namberg in reference namelist : Iceberg parameters
410      READ  ( numnam_ref, namberg, IOSTAT = ios, ERR = 901)
411901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namberg in reference namelist', lwp )
412      REWIND( numnam_cfg )              ! Namelist namberg in configuration namelist : Iceberg parameters
413      READ  ( numnam_cfg, namberg, IOSTAT = ios, ERR = 902 )
414902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namberg in configuration namelist', lwp )
415      IF(lwm) WRITE ( numond, namberg )
416      !
417      IF(lwp) WRITE(numout,*)
418      IF( ln_icebergs ) THEN
419         IF(lwp) WRITE(numout,*) '   ==>>>   icebergs are used'
420      ELSE
421         IF(lwp) WRITE(numout,*) '   ==>>>   No icebergs used'
422         RETURN
423      ENDIF
424      !
425      IF( nn_test_icebergs > nclasses ) THEN
426         IF(lwp) WRITE(numout,*)
427         IF(lwp) WRITE(numout,*) '   ==>>>   Resetting of nn_test_icebergs to ', nclasses
428         nn_test_icebergs = nclasses
429      ENDIF
430      !
431      IF( nn_test_icebergs < 0 .AND. .NOT. ln_use_calving ) THEN
432         IF(lwp) WRITE(numout,*)
433         IF(lwp) WRITE(numout,*) '   ==>>>   Resetting ln_use_calving to .true. since we are not using test icebergs'
434         ln_use_calving = .true.
435      ENDIF
436      !
437      IF(lwp) THEN                  ! control print
438         WRITE(numout,*)
439         WRITE(numout,*) 'icb_nam : iceberg initialization through namberg namelist read'
440         WRITE(numout,*) '~~~~~~~~ '
441         WRITE(numout,*) '   Calculate budgets                                            ln_bergdia       = ', ln_bergdia
442         WRITE(numout,*) '   Period between sampling of position for trajectory storage   nn_sample_rate = ', nn_sample_rate
443         WRITE(numout,*) '   Mass thresholds between iceberg classes (kg)                 rn_initial_mass     ='
444         DO jn = 1, nclasses
445            WRITE(numout,'(a,f15.2)') '                                                                ', rn_initial_mass(jn)
446         ENDDO
447         WRITE(numout,*) '   Fraction of calving to apply to this class (non-dim)         rn_distribution     ='
448         DO jn = 1, nclasses
449            WRITE(numout,'(a,f10.4)') '                                                                ', rn_distribution(jn)
450         END DO
451         WRITE(numout,*) '   Ratio between effective and real iceberg mass (non-dim)      rn_mass_scaling     = '
452         DO jn = 1, nclasses
453            WRITE(numout,'(a,f10.2)') '                                                                ', rn_mass_scaling(jn)
454         END DO
455         WRITE(numout,*) '   Total thickness of newly calved bergs (m)                    rn_initial_thickness = '
456         DO jn = 1, nclasses
457            WRITE(numout,'(a,f10.2)') '                                                                ', rn_initial_thickness(jn)
458         END DO
459         WRITE(numout,*) '   Timesteps between verbose messages                           nn_verbose_write    = ', nn_verbose_write
460
461         WRITE(numout,*) '   Density of icebergs                           rn_rho_bergs  = ', rn_rho_bergs
462         WRITE(numout,*) '   Initial ratio L/W for newly calved icebergs   rn_LoW_ratio  = ', rn_LoW_ratio
463         WRITE(numout,*) '   Turn on more verbose output                          level  = ', nn_verbose_level
464         WRITE(numout,*) '   Use first order operator splitting for thermodynamics    ',   &
465            &                    'use_operator_splitting = ', ln_operator_splitting
466         WRITE(numout,*) '   Fraction of erosion melt flux to divert to bergy bits    ',   &
467            &                    'bits_erosion_fraction = ', rn_bits_erosion_fraction
468
469         WRITE(numout,*) '   Shift of sea-ice concentration in erosion flux modulation ',   &
470            &                    '(0<sicn_shift<1)    rn_sicn_shift  = ', rn_sicn_shift
471         WRITE(numout,*) '   Do not add freshwater flux from icebergs to ocean                ',   &
472            &                    '                  passive_mode            = ', ln_passive_mode
473         WRITE(numout,*) '   Time average the weight on the ocean   time_average_weight       = ', ln_time_average_weight
474         WRITE(numout,*) '   Create icebergs in absence of a restart file   nn_test_icebergs  = ', nn_test_icebergs
475         WRITE(numout,*) '                   in lon/lat box                                   = ', rn_test_box
476         WRITE(numout,*) '   Use calving data even if nn_test_icebergs > 0    ln_use_calving  = ', ln_use_calving
477         WRITE(numout,*) '   CFL speed limit for a berg            speed_limit                = ', rn_speed_limit
478         WRITE(numout,*) '   Writing Iceberg status information to icebergs.stat file        '
479      ENDIF
480      !
481      ! ensure that the sum of berg input distribution is equal to one
482      zfact = SUM( rn_distribution )
483      IF( zfact /= 1._wp .AND. 0_wp /= zfact ) THEN
484         rn_distribution(:) = rn_distribution(:) / zfact
485         IF(lwp) THEN
486            WRITE(numout,*)
487            WRITE(numout,*) '      ==>>> CAUTION:    sum of berg input distribution = ', zfact
488            WRITE(numout,*) '            *******     redistribution has been rescaled'
489            WRITE(numout,*) '                        updated berg distribution is :'
490            DO jn = 1, nclasses
491               WRITE(numout,'(a,f10.4)') '                                   ',rn_distribution(jn)
492            END DO
493         ENDIF
494      ENDIF
495      IF( MINVAL( rn_distribution(:) ) < 0._wp ) THEN
496         CALL ctl_stop( 'icb_nam: a negative rn_distribution value encountered ==>> change your namelist namberg' )
497      ENDIF
498      !
499   END SUBROUTINE icb_nam
500
501   !!======================================================================
502END MODULE icbini
Note: See TracBrowser for help on using the repository browser.