New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icerst.F90 in NEMO/branches/UKMO/NEMO_4.0_add_pond_lids_prints/src/ICE – NEMO

source: NEMO/branches/UKMO/NEMO_4.0_add_pond_lids_prints/src/ICE/icerst.F90 @ 12658

Last change on this file since 12658 was 12394, checked in by dancopsey, 4 years ago

Fix compile and XIOS errors.
File size: 11.3 KB
Line 
1MODULE icerst
2   !!======================================================================
3   !!                     ***  MODULE  icerst  ***
4   !!   sea-ice :  write/read the ice restart file
5   !!======================================================================
6   !! History:   4.0  !  2018     (many people)      SI3 [aka Sea Ice cube]
7   !!----------------------------------------------------------------------
8#if defined key_si3
9   !!----------------------------------------------------------------------
10   !!   'key_si3'                                       SI3 sea-ice model
11   !!----------------------------------------------------------------------
12   !!   ice_rst_opn   : open  restart file
13   !!   ice_rst_write : write restart file
14   !!   ice_rst_read  : read  restart file
15   !!----------------------------------------------------------------------
16   USE ice            ! sea-ice variables
17   USE dom_oce        ! ocean domain
18   USE sbc_oce , ONLY : nn_fsbc, ln_cpl
19   USE icectl
20   !
21   USE in_out_manager ! I/O manager
22   USE iom            ! I/O manager library
23   USE lib_mpp        ! MPP library
24   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   ice_rst_opn     ! called by icestp
30   PUBLIC   ice_rst_write   ! called by icestp
31   PUBLIC   ice_rst_read    ! called by ice_init
32
33   !!----------------------------------------------------------------------
34   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
35   !! $Id$
36   !! Software governed by the CeCILL license (see ./LICENSE)
37   !!----------------------------------------------------------------------
38CONTAINS
39
40   SUBROUTINE ice_rst_opn( kt )
41      !!----------------------------------------------------------------------
42      !!                    ***  ice_rst_opn  ***
43      !!
44      !! ** purpose  :   open restart file
45      !!----------------------------------------------------------------------
46      INTEGER, INTENT(in) ::   kt       ! number of iteration
47      !
48      CHARACTER(len=20)   ::   clkt     ! ocean time-step define as a character
49      CHARACTER(len=50)   ::   clname   ! ice output restart file name
50      CHARACTER(len=256)  ::   clpath   ! full path to ice output restart file
51      !!----------------------------------------------------------------------
52      !
53      IF( kt == nit000 )   lrst_ice = .FALSE.   ! default definition
54
55      ! in order to get better performances with NetCDF format, we open and define the ice restart file
56      ! one ice time step before writing the data (-> at nitrst - 2*nn_fsbc + 1), except if we write ice
57      ! restart files every ice time step or if an ice restart file was writen at nitend - 2*nn_fsbc + 1
58      IF( kt == nitrst - 2*nn_fsbc + 1 .OR. nstock == nn_fsbc    &
59         &                             .OR. ( kt == nitend - nn_fsbc + 1 .AND. .NOT. lrst_ice ) ) THEN
60         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN
61            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
62            IF( nitrst > 99999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
63            ELSE                           ;   WRITE(clkt, '(i8.8)') nitrst
64            ENDIF
65            ! create the file
66            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_icerst_out)
67            clpath = TRIM(cn_icerst_outdir) 
68            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath)//'/'
69            IF(lwp) THEN
70               WRITE(numout,*)
71               WRITE(numout,*) '             open ice restart NetCDF file: ',TRIM(clpath)//clname
72               IF( kt == nitrst - 2*nn_fsbc + 1 ) THEN
73                  WRITE(numout,*) '             kt = nitrst - 2*nn_fsbc + 1 = ', kt,' date= ', ndastp
74               ELSE
75                  WRITE(numout,*) '             kt = '                         , kt,' date= ', ndastp
76               ENDIF
77            ENDIF
78            !
79            CALL iom_open( TRIM(clpath)//TRIM(clname), numriw, ldwrt = .TRUE., kdlev = jpl )
80            lrst_ice = .TRUE.
81         ENDIF
82      ENDIF
83      !
84      IF( ln_icectl )   CALL ice_prt( kt, iiceprt, jiceprt, 1, ' - Beginning the time step - ' )   ! control print
85      !
86   END SUBROUTINE ice_rst_opn
87
88
89   SUBROUTINE ice_rst_write( kt )
90      !!----------------------------------------------------------------------
91      !!                    ***  ice_rst_write  ***
92      !!
93      !! ** purpose  :   write restart file
94      !!----------------------------------------------------------------------
95      INTEGER, INTENT(in) ::   kt     ! number of iteration
96      !!
97      INTEGER ::   jk    ! dummy loop indices
98      INTEGER ::   iter
99      CHARACTER(len=25) ::   znam
100      CHARACTER(len=2)  ::   zchar, zchar1
101      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   z3d   ! 3D workspace
102      !!----------------------------------------------------------------------
103
104      iter = kt + nn_fsbc - 1   ! ice restarts are written at kt == nitrst - nn_fsbc + 1
105
106      IF( iter == nitrst ) THEN
107         IF(lwp) WRITE(numout,*)
108         IF(lwp) WRITE(numout,*) 'ice_rst_write : write ice restart file  kt =', kt
109         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~'         
110      ENDIF
111
112      ! Write in numriw (if iter == nitrst)
113      ! ------------------
114      !                                                                        ! calendar control
115      CALL iom_rstput( iter, nitrst, numriw, 'nn_fsbc', REAL( nn_fsbc, wp ) )      ! time-step
116      CALL iom_rstput( iter, nitrst, numriw, 'kt_ice' , REAL( iter   , wp ) )      ! date
117      CALL iom_delay_rst( 'WRITE', 'ICE', numriw )   ! save only ice delayed global communication variables
118
119      ! Prognostic variables
120      CALL iom_rstput( iter, nitrst, numriw, 'v_i' , v_i  )
121      CALL iom_rstput( iter, nitrst, numriw, 'v_s' , v_s  )
122      CALL iom_rstput( iter, nitrst, numriw, 'sv_i', sv_i )
123      CALL iom_rstput( iter, nitrst, numriw, 'oa_i', oa_i )
124      CALL iom_rstput( iter, nitrst, numriw, 'a_i' , a_i  )
125      CALL iom_rstput( iter, nitrst, numriw, 't_su', t_su )
126      ! Melt ponds
127      CALL iom_rstput( iter, nitrst, numriw, 'a_ip', a_ip )
128      CALL iom_rstput( iter, nitrst, numriw, 'v_ip', v_ip )
129      CALL iom_rstput( iter, nitrst, numriw, 'lh_ip', lh_ip )
130      ! Snow enthalpy
131      DO jk = 1, nlay_s 
132         WRITE(zchar1,'(I2.2)') jk
133         znam = 'e_s'//'_l'//zchar1
134         z3d(:,:,:) = e_s(:,:,jk,:)
135         CALL iom_rstput( iter, nitrst, numriw, znam , z3d )
136      END DO
137      ! Ice enthalpy
138      DO jk = 1, nlay_i 
139         WRITE(zchar1,'(I2.2)') jk
140         znam = 'e_i'//'_l'//zchar1
141         z3d(:,:,:) = e_i(:,:,jk,:)
142         CALL iom_rstput( iter, nitrst, numriw, znam , z3d )
143      END DO
144      ! ice velocity
145      CALL iom_rstput( iter, nitrst, numriw, 'u_ice', u_ice ) ! u_ice
146      CALL iom_rstput( iter, nitrst, numriw, 'v_ice', v_ice ) ! v_ice
147      ! fields needed for Met Office (Jules) coupling
148      IF( ln_cpl ) THEN
149         CALL iom_rstput( iter, nitrst, numriw, 'cnd_ice', cnd_ice )
150         CALL iom_rstput( iter, nitrst, numriw, 't1_ice' , t1_ice  )
151      ENDIF
152      !
153
154      ! close restart file
155      ! ------------------
156      IF( iter == nitrst ) THEN
157         CALL iom_close( numriw )
158         lrst_ice = .FALSE.
159      ENDIF
160      !
161   END SUBROUTINE ice_rst_write
162
163
164   SUBROUTINE ice_rst_read
165      !!----------------------------------------------------------------------
166      !!                    ***  ice_rst_read  ***
167      !!
168      !! ** purpose  :   read restart file
169      !!----------------------------------------------------------------------
170      INTEGER           ::   jk
171      LOGICAL           ::   llok
172      INTEGER           ::   id1            ! local integer
173      CHARACTER(len=25) ::   znam
174      CHARACTER(len=2)  ::   zchar, zchar1
175      REAL(wp)          ::   zfice, ziter
176      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   z3d   ! 3D workspace
177      !!----------------------------------------------------------------------
178
179      IF(lwp) THEN
180         WRITE(numout,*)
181         WRITE(numout,*) 'ice_rst_read: read ice NetCDF restart file'
182         WRITE(numout,*) '~~~~~~~~~~~~'
183      ENDIF
184
185      CALL iom_open ( TRIM(cn_icerst_indir)//'/'//cn_icerst_in, numrir, kdlev = jpl )
186
187      CALL iom_get( numrir, 'nn_fsbc', zfice )
188      CALL iom_get( numrir, 'kt_ice' , ziter )   
189      IF(lwp) WRITE(numout,*) '   read ice restart file at time step    : ', ziter
190      IF(lwp) WRITE(numout,*) '   in any case we force it to nit000 - 1 : ', nit000 - 1
191
192      ! Control of date
193      IF( ( nit000 - NINT(ziter) ) /= 1 .AND. ABS( nrstdt ) == 1 )   &
194         &     CALL ctl_stop( 'ice_rst_read ===>>>> : problem with nit000 in ice restart',  &
195         &                   '   verify the file or rerun with the value 0 for the',        &
196         &                   '   control of time parameter  nrstdt' )
197      IF( NINT(zfice) /= nn_fsbc          .AND. ABS( nrstdt ) == 1 )   &
198         &     CALL ctl_stop( 'ice_rst_read ===>>>> : problem with nn_fsbc in ice restart',  &
199         &                   '   verify the file or rerun with the value 0 for the',         &
200         &                   '   control of time parameter  nrstdt' )
201
202      ! Prognostic variables
203      CALL iom_get( numrir, jpdom_autoglo, 'v_i' , v_i  )
204      CALL iom_get( numrir, jpdom_autoglo, 'v_s' , v_s  )
205      CALL iom_get( numrir, jpdom_autoglo, 'sv_i', sv_i )
206      CALL iom_get( numrir, jpdom_autoglo, 'oa_i', oa_i )
207      CALL iom_get( numrir, jpdom_autoglo, 'a_i' , a_i  )
208      CALL iom_get( numrir, jpdom_autoglo, 't_su', t_su )
209      ! Melt ponds
210      id1 = iom_varid( numrir, 'a_ip' , ldstop = .FALSE. )
211      IF( id1 > 0 ) THEN                       ! fields exist (melt ponds)
212         CALL iom_get( numrir, jpdom_autoglo, 'a_ip' , a_ip )
213         CALL iom_get( numrir, jpdom_autoglo, 'v_ip' , v_ip )
214         CALL iom_get( numrir, jpdom_autoglo, 'lh_ip' , lh_ip )
215      ELSE                                     ! start from rest
216         IF(lwp) WRITE(numout,*) '   ==>>   previous run without melt ponds output then set it to zero'
217         a_ip(:,:,:) = 0._wp
218         v_ip(:,:,:) = 0._wp
219         lh_ip(:,:,:) = 0._wp
220      ENDIF
221      WRITE(numout,*) 'icerst: lh_ip(42,26,1) = ',lh_ip(42,26,1)
222      ! Snow enthalpy
223      DO jk = 1, nlay_s
224         WRITE(zchar1,'(I2.2)') jk
225         znam = 'e_s'//'_l'//zchar1
226         CALL iom_get( numrir, jpdom_autoglo, znam , z3d )
227         e_s(:,:,jk,:) = z3d(:,:,:)
228      END DO
229      ! Ice enthalpy
230      DO jk = 1, nlay_i
231         WRITE(zchar1,'(I2.2)') jk
232         znam = 'e_i'//'_l'//zchar1
233         CALL iom_get( numrir, jpdom_autoglo, znam , z3d )
234         e_i(:,:,jk,:) = z3d(:,:,:)
235      END DO
236      ! ice velocity
237      CALL iom_get( numrir, jpdom_autoglo, 'u_ice', u_ice )
238      CALL iom_get( numrir, jpdom_autoglo, 'v_ice', v_ice )
239
240      CALL iom_delay_rst( 'READ', 'ICE', numrir )   ! read only ice delayed global communication variables
241
242      ! fields needed for Met Office (Jules) coupling
243      IF( ln_cpl ) THEN
244         CALL iom_get( numrir, jpdom_autoglo, 'cnd_ice', cnd_ice )
245         CALL iom_get( numrir, jpdom_autoglo, 't1_ice' , t1_ice  )
246      ENDIF
247
248   END SUBROUTINE ice_rst_read
249
250#else
251   !!----------------------------------------------------------------------
252   !!   Default option :       Empty module           NO SI3 sea-ice model
253   !!----------------------------------------------------------------------
254#endif
255
256   !!======================================================================
257END MODULE icerst
Note: See TracBrowser for help on using the repository browser.