New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icethd_pnd.F90 in NEMO/branches/UKMO/NEMO_4.0_add_pond_lids_prints/src/ICE – NEMO

source: NEMO/branches/UKMO/NEMO_4.0_add_pond_lids_prints/src/ICE/icethd_pnd.F90 @ 12423

Last change on this file since 12423 was 12423, checked in by dancopsey, 4 years ago

Correct pond melting.
File size: 15.2 KB
Line 
1MODULE icethd_pnd 
2   !!======================================================================
3   !!                     ***  MODULE  icethd_pnd   ***
4   !!   sea-ice: Melt ponds on top of sea ice
5   !!======================================================================
6   !! history :       !  2012     (O. Lecomte)       Adaptation from Flocco and Turner
7   !!                 !  2017     (M. Vancoppenolle, O. Lecomte, C. Rousset) Implementation
8   !!            4.0  !  2018     (many people)      SI3 [aka Sea Ice cube]
9   !!----------------------------------------------------------------------
10#if defined key_si3
11   !!----------------------------------------------------------------------
12   !!   'key_si3' :                                     SI3 sea-ice model
13   !!----------------------------------------------------------------------
14   !!   ice_thd_pnd_init : some initialization and namelist read
15   !!   ice_thd_pnd      : main calling routine
16   !!----------------------------------------------------------------------
17   USE phycst         ! physical constants
18   USE dom_oce        ! ocean space and time domain
19   USE ice            ! sea-ice: variables
20   USE ice1D          ! sea-ice: thermodynamics variables
21   USE icetab         ! sea-ice: 1D <==> 2D transformation
22   !
23   USE in_out_manager ! I/O manager
24   USE lib_mpp        ! MPP library
25   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
26   USE timing         ! Timing
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   ice_thd_pnd_init    ! routine called by icestp.F90
32   PUBLIC   ice_thd_pnd         ! routine called by icestp.F90
33
34   INTEGER ::              nice_pnd    ! choice of the type of pond scheme
35   !                                   ! associated indices:
36   INTEGER, PARAMETER ::   np_pndNO  = 0   ! No pond scheme
37   INTEGER, PARAMETER ::   np_pndCST = 1   ! Constant pond scheme
38   INTEGER, PARAMETER ::   np_pndH12 = 2   ! Evolutive pond scheme (Holland et al. 2012)
39
40   !! * Substitutions
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
44   !! $Id$
45   !! Software governed by the CeCILL license (see ./LICENSE)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE ice_thd_pnd
50      !!-------------------------------------------------------------------
51      !!               ***  ROUTINE ice_thd_pnd   ***
52      !!               
53      !! ** Purpose :   change melt pond fraction
54      !!               
55      !! ** Method  :   brut force
56      !!-------------------------------------------------------------------
57      !
58      SELECT CASE ( nice_pnd )
59      !
60      CASE (np_pndCST)   ;   CALL pnd_CST    !==  Constant melt ponds  ==!
61         !
62      CASE (np_pndH12)   ;   CALL pnd_H12    !==  Holland et al 2012 melt ponds  ==!
63         !
64      END SELECT
65      !
66   END SUBROUTINE ice_thd_pnd 
67
68
69   SUBROUTINE pnd_CST 
70      !!-------------------------------------------------------------------
71      !!                ***  ROUTINE pnd_CST  ***
72      !!
73      !! ** Purpose :   Compute melt pond evolution
74      !!
75      !! ** Method  :   Melt pond fraction and thickness are prescribed
76      !!                to non-zero values when t_su = 0C
77      !!
78      !! ** Tunable parameters : pond fraction (rn_apnd), pond depth (rn_hpnd)
79      !!               
80      !! ** Note   : Coupling with such melt ponds is only radiative
81      !!             Advection, ridging, rafting... are bypassed
82      !!
83      !! ** References : Bush, G.W., and Trump, D.J. (2017)
84      !!-------------------------------------------------------------------
85      INTEGER  ::   ji        ! loop indices
86      !!-------------------------------------------------------------------
87      DO ji = 1, npti
88         !
89         IF( a_i_1d(ji) > 0._wp .AND. t_su_1d(ji) >= rt0 ) THEN
90            a_ip_frac_1d(ji) = rn_apnd
91            h_ip_1d(ji)      = rn_hpnd   
92            a_ip_1d(ji)      = a_ip_frac_1d(ji) * a_i_1d(ji)
93         ELSE
94            a_ip_frac_1d(ji) = 0._wp
95            h_ip_1d(ji)      = 0._wp   
96            a_ip_1d(ji)      = 0._wp
97         ENDIF
98         !
99      END DO
100      !
101   END SUBROUTINE pnd_CST
102
103
104   SUBROUTINE pnd_H12
105      !!-------------------------------------------------------------------
106      !!                ***  ROUTINE pnd_H12  ***
107      !!
108      !! ** Purpose    : Compute melt pond evolution
109      !!
110      !! ** Method     : Empirical method. A fraction of meltwater is accumulated in ponds
111      !!                 and sent to ocean when surface is freezing
112      !!
113      !!                 pond growth:      Vp = Vp + dVmelt
114      !!                    with dVmelt = R/rhow * ( rhoi*dh_i + rhos*dh_s ) * a_i
115      !!                 pond contraction: Vp = Vp * exp(0.01*MAX(Tp-Tsu,0)/Tp)
116      !!                    with Tp = -2degC
117      !! 
118      !! ** Tunable parameters : (no real expertise yet, ideas?)
119      !!
120      !! ** Note       : Stolen from CICE for quick test of the melt pond
121      !!                 radiation and freshwater interfaces
122      !!                 Coupling can be radiative AND freshwater
123      !!                 Advection, ridging, rafting are called
124      !!
125      !! ** References : Holland, M. M. et al (J Clim 2012)
126      !!-------------------------------------------------------------------
127      REAL(wp), PARAMETER ::   zrmin       = 0.15_wp  ! minimum fraction of available meltwater retained for melt ponding
128      REAL(wp), PARAMETER ::   zrmax       = 0.70_wp  ! maximum     -           -         -         -            -
129      REAL(wp), PARAMETER ::   zpnd_aspect = 0.174_wp   ! pond aspect ratio
130      REAL(wp), PARAMETER ::   zTp         = -2._wp   ! reference temperature
131      !
132      REAL(wp) ::   zfr_mlt          ! fraction of available meltwater retained for melt ponding
133      REAL(wp) ::   zdh_mlt          ! available meltwater for melt ponding (equivalent thickness change)
134      REAL(wp) ::   z1_Tp            ! inverse reference temperature
135      REAL(wp) ::   z1_rhow          ! inverse freshwater density
136      REAL(wp) ::   z1_zpnd_aspect   ! inverse pond aspect ratio
137      REAL(wp) ::   zfac, zdum
138      REAL(wp) ::   t_grad           ! Temperature deficit for refreezing
139      REAL(wp) ::   omega_dt         ! Time independent accumulated variables used for freezing
140      REAL(wp) ::   lh_ip_end        ! Lid thickness at end of timestep (temporary variable)
141      REAL(wp) ::   zdh_frz          ! Amount of melt pond that freezes (m)
142      !
143      INTEGER  ::   ji   ! loop indices
144      !!-------------------------------------------------------------------
145      z1_rhow        = 1._wp / rhow 
146      z1_zpnd_aspect = 1._wp / zpnd_aspect
147      z1_Tp          = 1._wp / zTp 
148
149      ! Define time-independent field for use in refreezing
150      omega_dt = 2.0_wp * rcnd_i * rdt_ice / (rLfus * rhow)
151
152      DO ji = 1, npti
153
154         IF (to_print(ji) == 10) THEN
155            write(numout,*)'icethd_pnd_start: h_ip_1d(ji), a_ip_frac_1d(ji), a_ip_1d(ji) = ',h_ip_1d(ji), ' ', a_ip_frac_1d(ji), ' ', a_ip_1d(ji)
156         END IF
157
158         !                                                        !--------------------------------!
159         IF( h_i_1d(ji) < rn_himin) THEN                          ! Case ice thickness < rn_himin  !
160            !                                                     !--------------------------------!
161            !--- Remove ponds on thin ice
162            a_ip_1d(ji)      = 0._wp
163            a_ip_frac_1d(ji) = 0._wp
164            h_ip_1d(ji)      = 0._wp
165            lh_ip_1d(ji)     = 0._wp
166
167            zdh_mlt = 0._wp
168            zdh_frz = 0._wp
169            !                                                     !--------------------------------!
170         ELSE                                                     ! Case ice thickness >= rn_himin !
171            !                                                     !--------------------------------!
172            v_ip_1d(ji) = h_ip_1d(ji) * a_ip_1d(ji)   ! record pond volume at previous time step
173            !
174            ! available meltwater for melt ponding
175            ! This is the change in ice thickness due to melt scaled up by the realive areas of the meltpond
176            ! and the area of sea ice feeding the melt ponds.
177            zdh_mlt = -( dh_i_sum(ji)*rhoi + dh_s_mlt(ji)*rhos ) * z1_rhow * (zrmax * a_i_1d(ji)) / a_ip_1d(ji)
178            !
179            !--- Pond gowth ---!
180            v_ip_1d(ji) = v_ip_1d(ji) + zdh_mlt * a_ip_1d(ji)
181            !
182            !--- Lid shrinking. ---!
183            lh_ip_1d(ji) = lh_ip_1d(ji) - zdh_mlt
184            !
185            !
186            !--- Pond contraction (due to refreezing) ---!
187            IF ( t_su_1d(ji) < (zTp+rt0) .AND. v_ip_1d(ji) > 0._wp ) THEN
188               t_grad = (zTp+rt0) - t_su_1d(ji)
189               
190               ! The following equation is a rearranged form of:
191               ! lid_thickness_end - lid_thickness_start = rcnd_i * t_grad * rdt_ice / (0.5*(lid_thickness_end + lid_thickness_start) * rLfus * rhow)
192               ! where: lid_thickness_start = lh_ip_1d(ji)
193               !        lid_thickness_end = lh_ip_end
194               !        omega_dt is a bunch of terms in the equation that do not change
195               ! note the use of rhow instead of rhoi as we are working with volumes and it is easier if the water and ice volumes (for the lid and the pond) are the same
196               ! (have the same density). The lid will eventually remelt anyway so it doesn't matter if we make this simplification.
197                             
198               lh_ip_end = SQRT(omega_dt * t_grad + lh_ip_1d(ji)**2)
199               zdh_frz = lh_ip_end - lh_ip_1d(ji)
200
201               ! Pond shrinking
202               v_ip_1d(ji) = v_ip_1d(ji) - zdh_frz * a_ip_1d(ji)
203
204               ! Lid growing
205               lh_ip_1d(ji) = lh_ip_1d(ji) + zdh_frz
206            ELSE
207               zdh_frz = 0._wp
208            END IF
209
210            ! melt pond mass flux (<0)
211            IF( zdh_mlt > 0._wp ) THEN
212               zfac = zdh_mlt * zrmax * a_i_1d(ji) * rhow * r1_rdtice
213               wfx_pnd_1d(ji) = wfx_pnd_1d(ji) - zfac
214               !
215               ! adjust ice/snow melting flux to balance melt pond flux (>0)
216               zdum = zfac / ( wfx_snw_sum_1d(ji) + wfx_sum_1d(ji) )
217               wfx_snw_sum_1d(ji) = wfx_snw_sum_1d(ji) * (1._wp + zdum)
218               wfx_sum_1d(ji)     = wfx_sum_1d(ji)     * (1._wp + zdum)
219            ENDIF
220            !
221            ! Make sure pond volume or lid thickness has not gone negative
222            IF ( v_ip_1d(ji) < 0._wp ) v_ip_1d(ji) = 0._wp 
223            IF ( lh_ip_1d(ji) < 0._wp ) lh_ip_1d(ji) = 0._wp
224            !
225            ! Set new pond area and depth assuming linear relation between h_ip and a_ip_frac
226            !    h_ip = zpnd_aspect * a_ip_frac = zpnd_aspect * a_ip/a_i
227            a_ip_1d(ji)      = SQRT( v_ip_1d(ji) * z1_zpnd_aspect * a_i_1d(ji) )
228            a_ip_frac_1d(ji) = a_ip_1d(ji) / a_i_1d(ji)
229            h_ip_1d(ji)      = zpnd_aspect * a_ip_frac_1d(ji)
230
231            ! If lid thickness is ten times greater than pond thickness then remove pond           
232            IF ( lh_ip_1d(ji) > h_ip_1d(ji) * 10._wp ) THEN
233                a_ip_1d(ji)      = 0._wp
234                a_ip_frac_1d(ji) = 0._wp
235                h_ip_1d(ji)      = 0._wp
236                lh_ip_1d(ji)     = 0._wp
237                v_ip_1d(ji)      = 0._wp
238            END IF
239            !
240         ENDIF
241
242         IF (to_print(ji) == 10) THEN
243            write(numout,*)'icethd_pnd: h_ip_1d(ji), zpnd_aspect, a_ip_frac_1d(ji), a_ip_1d(ji) = ',h_ip_1d(ji), zpnd_aspect, a_ip_frac_1d(ji), a_ip_1d(ji)
244            write(numout,*)'icethd_pnd: a_i_1d(ji), v_ip_1d(ji), t_su_1d(ji), zfr_mlt, zdh_mlt = ',a_i_1d(ji), ' ', v_ip_1d(ji), ' ', t_su_1d(ji), ' ', zfr_mlt, ' ', zdh_mlt
245            write(numout,*)'icethd_pnd: meltt = ', -( dh_i_sum(ji)*rhoi + dh_s_mlt(ji)*rhos ) / rhoi
246            write(numout,*)'icethd_pnd: lh_ip_1d(ji), zdh_mlt, zdh_frz, t_su_1d(ji) = ',lh_ip_1d(ji), ' ', zdh_mlt, ' ', zdh_frz, ' ', t_su_1d(ji)
247         END IF
248
249      END DO
250      !
251   END SUBROUTINE pnd_H12
252
253
254   SUBROUTINE ice_thd_pnd_init 
255      !!-------------------------------------------------------------------
256      !!                  ***  ROUTINE ice_thd_pnd_init   ***
257      !!
258      !! ** Purpose : Physical constants and parameters linked to melt ponds
259      !!              over sea ice
260      !!
261      !! ** Method  :  Read the namthd_pnd  namelist and check the melt pond 
262      !!               parameter values called at the first timestep (nit000)
263      !!
264      !! ** input   :   Namelist namthd_pnd 
265      !!-------------------------------------------------------------------
266      INTEGER  ::   ios, ioptio   ! Local integer
267      !!
268      NAMELIST/namthd_pnd/  ln_pnd_H12, ln_pnd_CST, rn_apnd, rn_hpnd, ln_pnd_alb
269      !!-------------------------------------------------------------------
270      !
271      REWIND( numnam_ice_ref )              ! Namelist namthd_pnd  in reference namelist : Melt Ponds 
272      READ  ( numnam_ice_ref, namthd_pnd, IOSTAT = ios, ERR = 901)
273901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namthd_pnd  in reference namelist', lwp )
274      REWIND( numnam_ice_cfg )              ! Namelist namthd_pnd  in configuration namelist : Melt Ponds
275      READ  ( numnam_ice_cfg, namthd_pnd, IOSTAT = ios, ERR = 902 )
276902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namthd_pnd in configuration namelist', lwp )
277      IF(lwm) WRITE ( numoni, namthd_pnd )
278      !
279      IF(lwp) THEN                        ! control print
280         WRITE(numout,*)
281         WRITE(numout,*) 'ice_thd_pnd_init: ice parameters for melt ponds'
282         WRITE(numout,*) '~~~~~~~~~~~~~~~~'
283         WRITE(numout,*) '   Namelist namicethd_pnd:'
284         WRITE(numout,*) '      Evolutive  melt pond fraction and depth (Holland et al 2012) ln_pnd_H12 = ', ln_pnd_H12
285         WRITE(numout,*) '      Prescribed melt pond fraction and depth                      ln_pnd_CST = ', ln_pnd_CST
286         WRITE(numout,*) '         Prescribed pond fraction                                  rn_apnd    = ', rn_apnd
287         WRITE(numout,*) '         Prescribed pond depth                                     rn_hpnd    = ', rn_hpnd
288         WRITE(numout,*) '      Melt ponds affect albedo or not                              ln_pnd_alb = ', ln_pnd_alb
289      ENDIF
290      !
291      !                             !== set the choice of ice pond scheme ==!
292      ioptio = 0
293                                                            nice_pnd = np_pndNO
294      IF( ln_pnd_CST ) THEN   ;   ioptio = ioptio + 1   ;   nice_pnd = np_pndCST    ;   ENDIF
295      IF( ln_pnd_H12 ) THEN   ;   ioptio = ioptio + 1   ;   nice_pnd = np_pndH12    ;   ENDIF
296      IF( ioptio > 1 )   CALL ctl_stop( 'ice_thd_pnd_init: choose one and only one pond scheme (ln_pnd_H12 or ln_pnd_CST)' )
297      !
298      SELECT CASE( nice_pnd )
299      CASE( np_pndNO )         
300         IF( ln_pnd_alb ) THEN ; ln_pnd_alb = .FALSE. ; CALL ctl_warn( 'ln_pnd_alb=false when no ponds' ) ; ENDIF
301      END SELECT
302      !
303   END SUBROUTINE ice_thd_pnd_init
304   
305#else
306   !!----------------------------------------------------------------------
307   !!   Default option          Empty module          NO SI3 sea-ice model
308   !!----------------------------------------------------------------------
309#endif 
310
311   !!======================================================================
312END MODULE icethd_pnd 
Note: See TracBrowser for help on using the repository browser.