New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
domzgr.F90 in NEMO/branches/UKMO/NEMO_4.0_mirror_text_diagnostics/src/OCE/DOM – NEMO

source: NEMO/branches/UKMO/NEMO_4.0_mirror_text_diagnostics/src/OCE/DOM/domzgr.F90 @ 10986

Last change on this file since 10986 was 10986, checked in by andmirek, 5 years ago

GMED 462 add flush
File size: 18.6 KB
Line 
1MODULE domzgr
2   !!==============================================================================
3   !!                       ***  MODULE domzgr   ***
4   !! Ocean domain : definition of the vertical coordinate system
5   !!==============================================================================
6   !! History :  OPA  ! 1995-12  (G. Madec)  Original code : s vertical coordinate
7   !!                 ! 1997-07  (G. Madec)  lbc_lnk call
8   !!                 ! 1997-04  (J.-O. Beismann)
9   !!            8.5  ! 2002-09  (A. Bozec, G. Madec)  F90: Free form and module
10   !!             -   ! 2002-09  (A. de Miranda)  rigid-lid + islands
11   !!  NEMO      1.0  ! 2003-08  (G. Madec)  F90: Free form and module
12   !!             -   ! 2005-10  (A. Beckmann)  modifications for hybrid s-ccordinates & new stretching function
13   !!            2.0  ! 2006-04  (R. Benshila, G. Madec)  add zgr_zco
14   !!            3.0  ! 2008-06  (G. Madec)  insertion of domzgr_zps.h90 & conding style
15   !!            3.2  ! 2009-07  (R. Benshila) Suppression of rigid-lid option
16   !!            3.3  ! 2010-11  (G. Madec) add mbk. arrays associated to the deepest ocean level
17   !!            3.4  ! 2012-08  (J. Siddorn) added Siddorn and Furner stretching function
18   !!            3.4  ! 2012-12  (R. Bourdalle-Badie and G. Reffray)  modify C1D case 
19   !!            3.6  ! 2014-11  (P. Mathiot and C. Harris) add ice shelf capabilitye 
20   !!            3.?  ! 2015-11  (H. Liu) Modifications for Wetting/Drying
21   !!----------------------------------------------------------------------
22
23   !!----------------------------------------------------------------------
24   !!   dom_zgr       : read or set the ocean vertical coordinate system
25   !!   zgr_read      : read the vertical information in the domain configuration file
26   !!   zgr_top_bot   : ocean top and bottom level for t-, u, and v-points with 1 as minimum value
27   !!---------------------------------------------------------------------
28   USE oce            ! ocean variables
29   USE dom_oce        ! ocean domain
30   USE usrdef_zgr     ! user defined vertical coordinate system
31   USE closea         ! closed seas
32   USE depth_e3       ! depth <=> e3
33   USE wet_dry,   ONLY: ll_wd, ssh_ref  ! Wetting and drying
34   !
35   USE in_out_manager ! I/O manager
36   USE iom            ! I/O library
37   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
38   USE lib_mpp        ! distributed memory computing library
39
40   IMPLICIT NONE
41   PRIVATE
42
43   PUBLIC   dom_zgr        ! called by dom_init.F90
44
45  !! * Substitutions
46#  include "vectopt_loop_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
49   !! $Id$
50   !! Software governed by the CeCILL license (see ./LICENSE)
51   !!----------------------------------------------------------------------
52CONTAINS       
53
54   SUBROUTINE dom_zgr( k_top, k_bot )
55      !!----------------------------------------------------------------------
56      !!                ***  ROUTINE dom_zgr  ***
57      !!                   
58      !! ** Purpose :   set the depth of model levels and the resulting
59      !!              vertical scale factors.
60      !!
61      !! ** Method  : - reference 1D vertical coordinate (gdep._1d, e3._1d)
62      !!              - read/set ocean depth and ocean levels (bathy, mbathy)
63      !!              - vertical coordinate (gdep., e3.) depending on the
64      !!                coordinate chosen :
65      !!                   ln_zco=T   z-coordinate   
66      !!                   ln_zps=T   z-coordinate with partial steps
67      !!                   ln_zco=T   s-coordinate
68      !!
69      !! ** Action  :   define gdep., e3., mbathy and bathy
70      !!----------------------------------------------------------------------
71      INTEGER, DIMENSION(:,:), INTENT(out) ::   k_top, k_bot   ! ocean first and last level indices
72      !
73      INTEGER  ::   jk                  ! dummy loop index
74      INTEGER  ::   ioptio, ibat, ios   ! local integer
75      REAL(wp) ::   zrefdep             ! depth of the reference level (~10m)
76      !!----------------------------------------------------------------------
77      !
78      IF(lwp) THEN                     ! Control print
79         WRITE(numout,*)
80         WRITE(numout,*) 'dom_zgr : vertical coordinate'
81         WRITE(numout,*) '~~~~~~~'
82         IF(lflush) CALL FLUSH(numout)
83      ENDIF
84
85      IF( ln_linssh .AND. lwp) WRITE(numout,*) '   linear free surface: the vertical mesh does not change in time'
86
87
88      IF( ln_read_cfg ) THEN        !==  read in mesh_mask.nc file  ==!
89         IF(lwp) THEN
90            WRITE(numout,*)
91            WRITE(numout,*) '   ==>>>   Read vertical mesh in ', TRIM( cn_domcfg ), ' file'
92            IF(lflush) CALL FLUSH(numout)
93         ENDIF
94         !
95         CALL zgr_read   ( ln_zco  , ln_zps  , ln_sco, ln_isfcav,   & 
96            &              gdept_1d, gdepw_1d, e3t_1d, e3w_1d   ,   &    ! 1D gridpoints depth
97            &              gdept_0 , gdepw_0                    ,   &    ! gridpoints depth
98            &              e3t_0   , e3u_0   , e3v_0 , e3f_0    ,   &    ! vertical scale factors
99            &              e3w_0   , e3uw_0  , e3vw_0           ,   &    ! vertical scale factors
100            &              k_top   , k_bot            )                  ! 1st & last ocean level
101            !
102      ELSE                          !==  User defined configuration  ==!
103         IF(lwp) THEN
104            WRITE(numout,*)
105            WRITE(numout,*) '          User defined vertical mesh (usr_def_zgr)'
106            IF(lflush) CALL FLUSH(numout)
107         ENDIF
108         !
109         CALL usr_def_zgr( ln_zco  , ln_zps  , ln_sco, ln_isfcav,   & 
110            &              gdept_1d, gdepw_1d, e3t_1d, e3w_1d   ,   &    ! 1D gridpoints depth
111            &              gdept_0 , gdepw_0                    ,   &    ! gridpoints depth
112            &              e3t_0   , e3u_0   , e3v_0 , e3f_0    ,   &    ! vertical scale factors
113            &              e3w_0   , e3uw_0  , e3vw_0           ,   &    ! vertical scale factors
114            &              k_top   , k_bot            )                  ! 1st & last ocean level
115         !
116      ENDIF
117      !
118!!gm to be remove when removing the OLD definition of e3 scale factors so that gde3w disappears
119      ! Compute gde3w_0 (vertical sum of e3w)
120      gde3w_0(:,:,1) = 0.5_wp * e3w_0(:,:,1)
121      DO jk = 2, jpk
122         gde3w_0(:,:,jk) = gde3w_0(:,:,jk-1) + e3w_0(:,:,jk)
123      END DO
124      !
125      ! Any closed seas (defined by closea_mask > 0 in domain_cfg file) to be filled
126      ! in at runtime if ln_closea=.false.
127      IF( .NOT.ln_closea )   CALL clo_bat( k_top, k_bot )
128      !
129      IF(lwp) THEN                     ! Control print
130         WRITE(numout,*)
131         WRITE(numout,*) '   Type of vertical coordinate (read in ', TRIM( cn_domcfg ), ' file or set in userdef_nam) :'
132         WRITE(numout,*) '      z-coordinate - full steps      ln_zco    = ', ln_zco
133         WRITE(numout,*) '      z-coordinate - partial steps   ln_zps    = ', ln_zps
134         WRITE(numout,*) '      s- or hybrid z-s-coordinate    ln_sco    = ', ln_sco
135         WRITE(numout,*) '      ice shelf cavities             ln_isfcav = ', ln_isfcav
136         IF(lflush) CALL FLUSH(numout)
137      ENDIF
138
139      ioptio = 0                       ! Check Vertical coordinate options
140      IF( ln_zco      )   ioptio = ioptio + 1
141      IF( ln_zps      )   ioptio = ioptio + 1
142      IF( ln_sco      )   ioptio = ioptio + 1
143      IF( ioptio /= 1 )   CALL ctl_stop( ' none or several vertical coordinate options used' )
144
145
146      !                                ! top/bottom ocean level indices for t-, u- and v-points (f-point also for top)
147      CALL zgr_top_bot( k_top, k_bot )      ! with a minimum value set to 1
148     
149
150      !                                ! deepest/shallowest W level Above/Below ~10m
151!!gm BUG in s-coordinate this does not work!
152      zrefdep = 10._wp - 0.1_wp * MINVAL( e3w_1d )                   ! ref. depth with tolerance (10% of minimum layer thickness)
153      nlb10 = MINLOC( gdepw_1d, mask = gdepw_1d > zrefdep, dim = 1 ) ! shallowest W level Below ~10m
154      nla10 = nlb10 - 1                                              ! deepest    W level Above ~10m
155!!gm end bug
156      !
157      IF( nprint > 3 .AND. lwp )   THEN
158         WRITE(numout,*) ' MIN val k_top   ', MINVAL(   k_top(:,:) ), ' MAX ', MAXVAL( k_top(:,:) )
159         WRITE(numout,*) ' MIN val k_bot   ', MINVAL(   k_bot(:,:) ), ' MAX ', MAXVAL( k_bot(:,:) )
160         WRITE(numout,*) ' MIN val depth t ', MINVAL( gdept_0(:,:,:) ),   &
161            &                          ' w ', MINVAL( gdepw_0(:,:,:) ), '3w ', MINVAL( gde3w_0(:,:,:) )
162         WRITE(numout,*) ' MIN val e3    t ', MINVAL(   e3t_0(:,:,:) ), ' f ', MINVAL(   e3f_0(:,:,:) ),  &
163            &                          ' u ', MINVAL(   e3u_0(:,:,:) ), ' u ', MINVAL(   e3v_0(:,:,:) ),  &
164            &                          ' uw', MINVAL(  e3uw_0(:,:,:) ), ' vw', MINVAL(  e3vw_0(:,:,:)),   &
165            &                          ' w ', MINVAL(   e3w_0(:,:,:) )
166
167         WRITE(numout,*) ' MAX val depth t ', MAXVAL( gdept_0(:,:,:) ),   &
168            &                          ' w ', MAXVAL( gdepw_0(:,:,:) ), '3w ', MAXVAL( gde3w_0(:,:,:) )
169         WRITE(numout,*) ' MAX val e3    t ', MAXVAL(   e3t_0(:,:,:) ), ' f ', MAXVAL(   e3f_0(:,:,:) ),  &
170            &                          ' u ', MAXVAL(   e3u_0(:,:,:) ), ' u ', MAXVAL(   e3v_0(:,:,:) ),  &
171            &                          ' uw', MAXVAL(  e3uw_0(:,:,:) ), ' vw', MAXVAL(  e3vw_0(:,:,:) ),  &
172            &                          ' w ', MAXVAL(   e3w_0(:,:,:) )
173         IF(lflush) CALL FLUSH(numout)
174      ENDIF
175      !
176   END SUBROUTINE dom_zgr
177
178
179   SUBROUTINE zgr_read( ld_zco  , ld_zps  , ld_sco  , ld_isfcav,   &   ! type of vertical coordinate
180      &                 pdept_1d, pdepw_1d, pe3t_1d , pe3w_1d  ,   &   ! 1D reference vertical coordinate
181      &                 pdept , pdepw ,                            &   ! 3D t & w-points depth
182      &                 pe3t  , pe3u  , pe3v   , pe3f ,            &   ! vertical scale factors
183      &                 pe3w  , pe3uw , pe3vw         ,            &   !     -      -      -
184      &                 k_top  , k_bot    )                            ! top & bottom ocean level
185      !!---------------------------------------------------------------------
186      !!              ***  ROUTINE zgr_read  ***
187      !!
188      !! ** Purpose :   Read the vertical information in the domain configuration file
189      !!
190      !!----------------------------------------------------------------------
191      LOGICAL                   , INTENT(out) ::   ld_zco, ld_zps, ld_sco      ! vertical coordinate flags
192      LOGICAL                   , INTENT(out) ::   ld_isfcav                   ! under iceshelf cavity flag
193      REAL(wp), DIMENSION(:)    , INTENT(out) ::   pdept_1d, pdepw_1d          ! 1D grid-point depth       [m]
194      REAL(wp), DIMENSION(:)    , INTENT(out) ::   pe3t_1d , pe3w_1d           ! 1D vertical scale factors [m]
195      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pdept, pdepw                ! grid-point depth          [m]
196      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pe3t , pe3u , pe3v , pe3f   ! vertical scale factors    [m]
197      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pe3w , pe3uw, pe3vw         !    -       -      -
198      INTEGER , DIMENSION(:,:)  , INTENT(out) ::   k_top , k_bot               ! first & last ocean level
199      !
200      INTEGER  ::   jk     ! dummy loop index
201      INTEGER  ::   inum   ! local logical unit
202      REAL(WP) ::   z_zco, z_zps, z_sco, z_cav
203      REAL(wp), DIMENSION(jpi,jpj) ::   z2d   ! 2D workspace
204      !!----------------------------------------------------------------------
205      !
206      IF(lwp) THEN
207         WRITE(numout,*)
208         WRITE(numout,*) '   zgr_read : read the vertical coordinates in ', TRIM( cn_domcfg ), ' file'
209         WRITE(numout,*) '   ~~~~~~~~'
210         IF(lflush) CALL FLUSH(numout)
211      ENDIF
212      !
213      CALL iom_open( cn_domcfg, inum )
214      !
215      !                          !* type of vertical coordinate
216      CALL iom_get( inum, 'ln_zco'   , z_zco )
217      CALL iom_get( inum, 'ln_zps'   , z_zps )
218      CALL iom_get( inum, 'ln_sco'   , z_sco )
219      IF( z_zco == 0._wp ) THEN   ;   ld_zco = .false.   ;   ELSE   ;   ld_zco = .true.   ;   ENDIF
220      IF( z_zps == 0._wp ) THEN   ;   ld_zps = .false.   ;   ELSE   ;   ld_zps = .true.   ;   ENDIF
221      IF( z_sco == 0._wp ) THEN   ;   ld_sco = .false.   ;   ELSE   ;   ld_sco = .true.   ;   ENDIF
222      !
223      !                          !* ocean cavities under iceshelves
224      CALL iom_get( inum, 'ln_isfcav', z_cav )
225      IF( z_cav == 0._wp ) THEN   ;   ld_isfcav = .false.   ;   ELSE   ;   ld_isfcav = .true.   ;   ENDIF
226      !
227      !                          !* vertical scale factors
228      CALL iom_get( inum, jpdom_unknown, 'e3t_1d'  , pe3t_1d  )                     ! 1D reference coordinate
229      CALL iom_get( inum, jpdom_unknown, 'e3w_1d'  , pe3w_1d  )
230      !
231      CALL iom_get( inum, jpdom_data, 'e3t_0'  , pe3t  , lrowattr=ln_use_jattr )    ! 3D coordinate
232      CALL iom_get( inum, jpdom_data, 'e3u_0'  , pe3u  , lrowattr=ln_use_jattr )
233      CALL iom_get( inum, jpdom_data, 'e3v_0'  , pe3v  , lrowattr=ln_use_jattr )
234      CALL iom_get( inum, jpdom_data, 'e3f_0'  , pe3f  , lrowattr=ln_use_jattr )
235      CALL iom_get( inum, jpdom_data, 'e3w_0'  , pe3w  , lrowattr=ln_use_jattr )
236      CALL iom_get( inum, jpdom_data, 'e3uw_0' , pe3uw , lrowattr=ln_use_jattr )
237      CALL iom_get( inum, jpdom_data, 'e3vw_0' , pe3vw , lrowattr=ln_use_jattr )
238      !
239      !                          !* depths
240      !                                   !- old depth definition (obsolescent feature)
241      IF(  iom_varid( inum, 'gdept_1d', ldstop = .FALSE. ) > 0  .AND.  &
242         & iom_varid( inum, 'gdepw_1d', ldstop = .FALSE. ) > 0  .AND.  &
243         & iom_varid( inum, 'gdept_0' , ldstop = .FALSE. ) > 0  .AND.  &
244         & iom_varid( inum, 'gdepw_0' , ldstop = .FALSE. ) > 0    ) THEN
245         CALL ctl_warn( 'zgr_read : old definition of depths and scale factors used ', & 
246            &           '           depths at t- and w-points read in the domain configuration file')
247         CALL iom_get( inum, jpdom_unknown, 'gdept_1d', pdept_1d )   
248         CALL iom_get( inum, jpdom_unknown, 'gdepw_1d', pdepw_1d )
249         CALL iom_get( inum, jpdom_data   , 'gdept_0' , pdept , lrowattr=ln_use_jattr )
250         CALL iom_get( inum, jpdom_data   , 'gdepw_0' , pdepw , lrowattr=ln_use_jattr )
251         !
252      ELSE                                !- depths computed from e3. scale factors
253         CALL e3_to_depth( pe3t_1d, pe3w_1d, pdept_1d, pdepw_1d )    ! 1D reference depth
254         CALL e3_to_depth( pe3t   , pe3w   , pdept   , pdepw    )    ! 3D depths
255         IF(lwp) THEN
256            WRITE(numout,*)
257            WRITE(numout,*) '              Reference 1D z-coordinate depth and scale factors:'
258            WRITE(numout, "(9x,' level  gdept_1d  gdepw_1d  e3t_1d   e3w_1d  ')" )
259            WRITE(numout, "(10x, i4, 4f9.2)" ) ( jk, pdept_1d(jk), pdepw_1d(jk), pe3t_1d(jk), pe3w_1d(jk), jk = 1, jpk )
260            IF(lflush) CALL FLUSH(numout)
261         ENDIF
262      ENDIF
263      !
264      !                          !* ocean top and bottom level
265      CALL iom_get( inum, jpdom_data, 'top_level'    , z2d  , lrowattr=ln_use_jattr )   ! 1st wet T-points (ISF)
266      k_top(:,:) = NINT( z2d(:,:) )
267      CALL iom_get( inum, jpdom_data, 'bottom_level' , z2d  , lrowattr=ln_use_jattr )   ! last wet T-points
268      k_bot(:,:) = NINT( z2d(:,:) )
269      !
270      ! reference depth for negative bathy (wetting and drying only)
271      IF( ll_wd )  CALL iom_get( inum,  'rn_wd_ref_depth' , ssh_ref   )
272      !
273      CALL iom_close( inum )
274      !
275   END SUBROUTINE zgr_read
276
277
278   SUBROUTINE zgr_top_bot( k_top, k_bot )
279      !!----------------------------------------------------------------------
280      !!                    ***  ROUTINE zgr_top_bot  ***
281      !!
282      !! ** Purpose :   defines the vertical index of ocean bottom (mbk. arrays)
283      !!
284      !! ** Method  :   computes from k_top and k_bot with a minimum value of 1 over land
285      !!
286      !! ** Action  :   mikt, miku, mikv :   vertical indices of the shallowest
287      !!                                     ocean level at t-, u- & v-points
288      !!                                     (min value = 1)
289      !! ** Action  :   mbkt, mbku, mbkv :   vertical indices of the deeptest
290      !!                                     ocean level at t-, u- & v-points
291      !!                                     (min value = 1 over land)
292      !!----------------------------------------------------------------------
293      INTEGER , DIMENSION(:,:), INTENT(in) ::   k_top, k_bot   ! top & bottom ocean level indices
294      !
295      INTEGER ::   ji, jj   ! dummy loop indices
296      REAL(wp), DIMENSION(jpi,jpj) ::   zk   ! workspace
297      !!----------------------------------------------------------------------
298      !
299      IF(lwp) THEN
300         WRITE(numout,*)
301         WRITE(numout,*) '    zgr_top_bot : ocean top and bottom k-index of T-, U-, V- and W-levels '
302         WRITE(numout,*) '    ~~~~~~~~~~~'
303         IF(lflush) CALL FLUSH(numout)
304      ENDIF
305      !
306      mikt(:,:) = MAX( k_top(:,:) , 1 )    ! top    ocean k-index of T-level (=1 over land)
307      !
308      mbkt(:,:) = MAX( k_bot(:,:) , 1 )    ! bottom ocean k-index of T-level (=1 over land)
309 
310      !                                    ! N.B.  top     k-index of W-level = mikt
311      !                                    !       bottom  k-index of W-level = mbkt+1
312      DO jj = 1, jpjm1
313         DO ji = 1, jpim1
314            miku(ji,jj) = MAX(  mikt(ji+1,jj  ) , mikt(ji,jj)  )
315            mikv(ji,jj) = MAX(  mikt(ji  ,jj+1) , mikt(ji,jj)  )
316            mikf(ji,jj) = MAX(  mikt(ji  ,jj+1) , mikt(ji,jj), mikt(ji+1,jj  ), mikt(ji+1,jj+1)  )
317            !
318            mbku(ji,jj) = MIN(  mbkt(ji+1,jj  ) , mbkt(ji,jj)  )
319            mbkv(ji,jj) = MIN(  mbkt(ji  ,jj+1) , mbkt(ji,jj)  )
320         END DO
321      END DO
322      ! converte into REAL to use lbc_lnk ; impose a min value of 1 as a zero can be set in lbclnk
323      zk(:,:) = REAL( miku(:,:), wp )   ;   CALL lbc_lnk( 'domzgr', zk, 'U', 1. )   ;   miku(:,:) = MAX( NINT( zk(:,:) ), 1 )
324      zk(:,:) = REAL( mikv(:,:), wp )   ;   CALL lbc_lnk( 'domzgr', zk, 'V', 1. )   ;   mikv(:,:) = MAX( NINT( zk(:,:) ), 1 )
325      zk(:,:) = REAL( mikf(:,:), wp )   ;   CALL lbc_lnk( 'domzgr', zk, 'F', 1. )   ;   mikf(:,:) = MAX( NINT( zk(:,:) ), 1 )
326      !
327      zk(:,:) = REAL( mbku(:,:), wp )   ;   CALL lbc_lnk( 'domzgr', zk, 'U', 1. )   ;   mbku(:,:) = MAX( NINT( zk(:,:) ), 1 )
328      zk(:,:) = REAL( mbkv(:,:), wp )   ;   CALL lbc_lnk( 'domzgr', zk, 'V', 1. )   ;   mbkv(:,:) = MAX( NINT( zk(:,:) ), 1 )
329      !
330   END SUBROUTINE zgr_top_bot
331
332   !!======================================================================
333END MODULE domzgr
Note: See TracBrowser for help on using the repository browser.