New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in NEMO/branches/UKMO/NEMO_4.0_mirror_text_diagnostics/src/OCE/DYN – NEMO

source: NEMO/branches/UKMO/NEMO_4.0_mirror_text_diagnostics/src/OCE/DYN/dynhpg.F90 @ 10986

Last change on this file since 10986 was 10986, checked in by andmirek, 5 years ago

GMED 462 add flush

File size: 72.7 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
34   USE dom_oce         ! ocean space and time domain
35   USE wet_dry         ! wetting and drying
36   USE phycst          ! physical constants
37   USE trd_oce         ! trends: ocean variables
38   USE trddyn          ! trend manager: dynamics
39!jc   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
40   !
41   USE in_out_manager  ! I/O manager
42   USE prtctl          ! Print control
43   USE lbclnk          ! lateral boundary condition
44   USE lib_mpp         ! MPP library
45   USE eosbn2          ! compute density
46   USE timing          ! Timing
47   USE iom
48
49   IMPLICIT NONE
50   PRIVATE
51
52   PUBLIC   dyn_hpg        ! routine called by step module
53   PUBLIC   dyn_hpg_init   ! routine called by opa module
54
55   !                                !!* Namelist namdyn_hpg : hydrostatic pressure gradient
56   LOGICAL, PUBLIC ::   ln_hpg_zco   !: z-coordinate - full steps
57   LOGICAL, PUBLIC ::   ln_hpg_zps   !: z-coordinate - partial steps (interpolation)
58   LOGICAL, PUBLIC ::   ln_hpg_sco   !: s-coordinate (standard jacobian formulation)
59   LOGICAL, PUBLIC ::   ln_hpg_djc   !: s-coordinate (Density Jacobian with Cubic polynomial)
60   LOGICAL, PUBLIC ::   ln_hpg_prj   !: s-coordinate (Pressure Jacobian scheme)
61   LOGICAL, PUBLIC ::   ln_hpg_isf   !: s-coordinate similar to sco modify for isf
62
63   !                                !! Flag to control the type of hydrostatic pressure gradient
64   INTEGER, PARAMETER ::   np_ERROR  =-10   ! error in specification of lateral diffusion
65   INTEGER, PARAMETER ::   np_zco    =  0   ! z-coordinate - full steps
66   INTEGER, PARAMETER ::   np_zps    =  1   ! z-coordinate - partial steps (interpolation)
67   INTEGER, PARAMETER ::   np_sco    =  2   ! s-coordinate (standard jacobian formulation)
68   INTEGER, PARAMETER ::   np_djc    =  3   ! s-coordinate (Density Jacobian with Cubic polynomial)
69   INTEGER, PARAMETER ::   np_prj    =  4   ! s-coordinate (Pressure Jacobian scheme)
70   INTEGER, PARAMETER ::   np_isf    =  5   ! s-coordinate similar to sco modify for isf
71   !
72   INTEGER, PUBLIC ::   nhpg         !: type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
73
74   !! * Substitutions
75#  include "vectopt_loop_substitute.h90"
76   !!----------------------------------------------------------------------
77   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
78   !! $Id$
79   !! Software governed by the CeCILL license (see ./LICENSE)
80   !!----------------------------------------------------------------------
81CONTAINS
82
83   SUBROUTINE dyn_hpg( kt )
84      !!---------------------------------------------------------------------
85      !!                  ***  ROUTINE dyn_hpg  ***
86      !!
87      !! ** Method  :   Call the hydrostatic pressure gradient routine
88      !!              using the scheme defined in the namelist
89      !!
90      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
91      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
92      !!----------------------------------------------------------------------
93      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
94      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrdu, ztrdv
95      !!----------------------------------------------------------------------
96      !
97      IF( ln_timing )   CALL timing_start('dyn_hpg')
98      !
99      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
100         ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
101         ztrdu(:,:,:) = ua(:,:,:)
102         ztrdv(:,:,:) = va(:,:,:)
103      ENDIF
104      !
105      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
106      CASE ( np_zco )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
107      CASE ( np_zps )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
108      CASE ( np_sco )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
109      CASE ( np_djc )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
110      CASE ( np_prj )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
111      CASE ( np_isf )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
112      END SELECT
113      !
114      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
115         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
116         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
117         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
118         DEALLOCATE( ztrdu , ztrdv )
119      ENDIF
120      !
121      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
122         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
123      !
124      IF( ln_timing )   CALL timing_stop('dyn_hpg')
125      !
126   END SUBROUTINE dyn_hpg
127
128
129   SUBROUTINE dyn_hpg_init
130      !!----------------------------------------------------------------------
131      !!                 ***  ROUTINE dyn_hpg_init  ***
132      !!
133      !! ** Purpose :   initializations for the hydrostatic pressure gradient
134      !!              computation and consistency control
135      !!
136      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
137      !!      with the type of vertical coordinate used (zco, zps, sco)
138      !!----------------------------------------------------------------------
139      INTEGER ::   ioptio = 0      ! temporary integer
140      INTEGER ::   ios             ! Local integer output status for namelist read
141      !!
142      INTEGER  ::   ji, jj, jk, ikt    ! dummy loop indices      ISF
143      REAL(wp) ::   znad
144      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  zts_top, zrhd   ! hypothesys on isf density
145      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  zrhdtop_isf    ! density at bottom of ISF
146      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  ziceload       ! density at bottom of ISF
147      !!
148      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
149         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf
150      !!----------------------------------------------------------------------
151      !
152      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
153      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
154901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
155      !
156      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
157      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
158902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
159      IF(lwm .AND. nprint > 2) WRITE ( numond, namdyn_hpg )
160      !
161      IF(lwp) THEN                   ! Control print
162         WRITE(numout,*)
163         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
164         WRITE(numout,*) '~~~~~~~~~~~~'
165         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
166         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
167         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
168         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
169         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
170         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
171         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
172         IF(lflush) CALL FLUSH(numout)
173      ENDIF
174      !
175      IF( ln_hpg_djc )   &
176         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method',   &
177         &                 '   currently disabled (bugs under investigation).'        ,   &
178         &                 '   Please select either  ln_hpg_sco or  ln_hpg_prj instead' )
179         !
180      IF( .NOT.ln_linssh .AND. .NOT.(ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )          &
181         &   CALL ctl_stop('dyn_hpg_init : non-linear free surface requires either ',   &
182         &                 '   the standard jacobian formulation hpg_sco    or '    ,   &
183         &                 '   the pressure jacobian formulation hpg_prj'             )
184         !
185      IF( ln_hpg_isf ) THEN
186         IF( .NOT. ln_isfcav )   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
187       ELSE
188         IF(       ln_isfcav )   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
189      ENDIF
190      !
191      !                               ! Set nhpg from ln_hpg_... flags & consistency check
192      nhpg   = np_ERROR
193      ioptio = 0
194      IF( ln_hpg_zco ) THEN   ;   nhpg = np_zco   ;   ioptio = ioptio +1   ;   ENDIF
195      IF( ln_hpg_zps ) THEN   ;   nhpg = np_zps   ;   ioptio = ioptio +1   ;   ENDIF
196      IF( ln_hpg_sco ) THEN   ;   nhpg = np_sco   ;   ioptio = ioptio +1   ;   ENDIF
197      IF( ln_hpg_djc ) THEN   ;   nhpg = np_djc   ;   ioptio = ioptio +1   ;   ENDIF
198      IF( ln_hpg_prj ) THEN   ;   nhpg = np_prj   ;   ioptio = ioptio +1   ;   ENDIF
199      IF( ln_hpg_isf ) THEN   ;   nhpg = np_isf   ;   ioptio = ioptio +1   ;   ENDIF
200      !
201      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
202      !
203      IF(lwp) THEN
204         WRITE(numout,*)
205         SELECT CASE( nhpg )
206         CASE( np_zco )   ;   WRITE(numout,*) '   ==>>>   z-coord. - full steps '
207         CASE( np_zps )   ;   WRITE(numout,*) '   ==>>>   z-coord. - partial steps (interpolation)'
208         CASE( np_sco )   ;   WRITE(numout,*) '   ==>>>   s-coord. (standard jacobian formulation)'
209         CASE( np_djc )   ;   WRITE(numout,*) '   ==>>>   s-coord. (Density Jacobian: Cubic polynomial)'
210         CASE( np_prj )   ;   WRITE(numout,*) '   ==>>>   s-coord. (Pressure Jacobian: Cubic polynomial)'
211         CASE( np_isf )   ;   WRITE(numout,*) '   ==>>>   s-coord. (standard jacobian formulation) for isf'
212         END SELECT
213         WRITE(numout,*)
214         IF(lflush) CALL FLUSH(numout)
215      ENDIF
216      !                         
217      IF ( .NOT. ln_isfcav ) THEN     !--- no ice shelf load
218         riceload(:,:) = 0._wp
219         !
220      ELSE                            !--- set an ice shelf load
221         !
222         IF(lwp) THEN
223            WRITE(numout,*)
224            WRITE(numout,*) '   ice shelf case: set the ice-shelf load'
225            IF(lflush) CALL FLUSH(numout)
226         ENDIF
227         ALLOCATE( zts_top(jpi,jpj,jpts) , zrhd(jpi,jpj,jpk) , zrhdtop_isf(jpi,jpj) , ziceload(jpi,jpj) ) 
228         !
229         znad = 1._wp                     !- To use density and not density anomaly
230         !
231         !                                !- assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
232         zts_top(:,:,jp_tem) = -1.9_wp   ;   zts_top(:,:,jp_sal) = 34.4_wp
233         !
234         DO jk = 1, jpk                   !- compute density of the water displaced by the ice shelf
235            CALL eos( zts_top(:,:,:), gdept_n(:,:,jk), zrhd(:,:,jk) )
236         END DO
237         !
238         !                                !- compute rhd at the ice/oce interface (ice shelf side)
239         CALL eos( zts_top , risfdep, zrhdtop_isf )
240         !
241         !                                !- Surface value + ice shelf gradient
242         ziceload = 0._wp                       ! compute pressure due to ice shelf load
243         DO jj = 1, jpj                         ! (used to compute hpgi/j for all the level from 1 to miku/v)
244            DO ji = 1, jpi                      ! divided by 2 later
245               ikt = mikt(ji,jj)
246               ziceload(ji,jj) = ziceload(ji,jj) + (znad + zrhd(ji,jj,1) ) * e3w_n(ji,jj,1) * (1._wp - tmask(ji,jj,1))
247               DO jk = 2, ikt-1
248                  ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhd(ji,jj,jk-1) + zrhd(ji,jj,jk)) * e3w_n(ji,jj,jk) &
249                     &                              * (1._wp - tmask(ji,jj,jk))
250               END DO
251               IF (ikt  >=  2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + zrhd(ji,jj,ikt-1)) &
252                  &                                              * ( risfdep(ji,jj) - gdept_n(ji,jj,ikt-1) )
253            END DO
254         END DO
255         riceload(:,:) = ziceload(:,:)  ! need to be saved for diaar5
256         !
257         DEALLOCATE( zts_top , zrhd , zrhdtop_isf , ziceload ) 
258      ENDIF
259      !
260   END SUBROUTINE dyn_hpg_init
261
262
263   SUBROUTINE hpg_zco( kt )
264      !!---------------------------------------------------------------------
265      !!                  ***  ROUTINE hpg_zco  ***
266      !!
267      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
268      !!      The now hydrostatic pressure gradient at a given level, jk,
269      !!      is computed by taking the vertical integral of the in-situ
270      !!      density gradient along the model level from the suface to that
271      !!      level:    zhpi = grav .....
272      !!                zhpj = grav .....
273      !!      add it to the general momentum trend (ua,va).
274      !!            ua = ua - 1/e1u * zhpi
275      !!            va = va - 1/e2v * zhpj
276      !!
277      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
278      !!----------------------------------------------------------------------
279      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
280      !
281      INTEGER  ::   ji, jj, jk       ! dummy loop indices
282      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
283      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zhpi, zhpj
284      !!----------------------------------------------------------------------
285      !
286      IF( kt == nit000 .AND. lwp) THEN
287         WRITE(numout,*)
288         WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
289         WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
290         IF(lflush) CALL FLUSH(numout)
291      ENDIF
292
293      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
294
295      ! Surface value
296      DO jj = 2, jpjm1
297         DO ji = fs_2, fs_jpim1   ! vector opt.
298            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
299            ! hydrostatic pressure gradient
300            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
301            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
302            ! add to the general momentum trend
303            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
304            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
305         END DO
306      END DO
307
308      !
309      ! interior value (2=<jk=<jpkm1)
310      DO jk = 2, jpkm1
311         DO jj = 2, jpjm1
312            DO ji = fs_2, fs_jpim1   ! vector opt.
313               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
314               ! hydrostatic pressure gradient
315               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
316                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )    &
317                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
318
319               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
320                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )    &
321                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
322               ! add to the general momentum trend
323               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
324               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
325            END DO
326         END DO
327      END DO
328      !
329   END SUBROUTINE hpg_zco
330
331
332   SUBROUTINE hpg_zps( kt )
333      !!---------------------------------------------------------------------
334      !!                 ***  ROUTINE hpg_zps  ***
335      !!
336      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
337      !!
338      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
339      !!----------------------------------------------------------------------
340      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
341      !!
342      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
343      INTEGER  ::   iku, ikv                         ! temporary integers
344      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
345      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zhpi, zhpj
346      !!----------------------------------------------------------------------
347      !
348      IF( kt == nit000 .AND. lwp) THEN
349         WRITE(numout,*)
350         WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
351         WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
352         IF(lflush) CALL FLUSH(numout)
353      ENDIF
354
355      ! Partial steps: bottom before horizontal gradient of t, s, rd at the last ocean level
356!jc      CALL zps_hde    ( kt, jpts, tsn, gtsu, gtsv, rhd, gru , grv )
357
358      ! Local constant initialization
359      zcoef0 = - grav * 0.5_wp
360
361      !  Surface value (also valid in partial step case)
362      DO jj = 2, jpjm1
363         DO ji = fs_2, fs_jpim1   ! vector opt.
364            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
365            ! hydrostatic pressure gradient
366            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
367            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
368            ! add to the general momentum trend
369            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
370            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
371         END DO
372      END DO
373
374      ! interior value (2=<jk=<jpkm1)
375      DO jk = 2, jpkm1
376         DO jj = 2, jpjm1
377            DO ji = fs_2, fs_jpim1   ! vector opt.
378               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
379               ! hydrostatic pressure gradient
380               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
381                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
382                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
383
384               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
385                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
386                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
387               ! add to the general momentum trend
388               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
389               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
390            END DO
391         END DO
392      END DO
393
394      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
395      DO jj = 2, jpjm1
396         DO ji = 2, jpim1
397            iku = mbku(ji,jj)
398            ikv = mbkv(ji,jj)
399            zcoef2 = zcoef0 * MIN( e3w_n(ji,jj,iku), e3w_n(ji+1,jj  ,iku) )
400            zcoef3 = zcoef0 * MIN( e3w_n(ji,jj,ikv), e3w_n(ji  ,jj+1,ikv) )
401            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
402               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
403               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
404                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) * r1_e1u(ji,jj)
405               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
406            ENDIF
407            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
408               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
409               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
410                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) * r1_e2v(ji,jj)
411               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
412            ENDIF
413         END DO
414      END DO
415      !
416   END SUBROUTINE hpg_zps
417
418
419   SUBROUTINE hpg_sco( kt )
420      !!---------------------------------------------------------------------
421      !!                  ***  ROUTINE hpg_sco  ***
422      !!
423      !! ** Method  :   s-coordinate case. Jacobian scheme.
424      !!      The now hydrostatic pressure gradient at a given level, jk,
425      !!      is computed by taking the vertical integral of the in-situ
426      !!      density gradient along the model level from the suface to that
427      !!      level. s-coordinates (ln_sco): a corrective term is added
428      !!      to the horizontal pressure gradient :
429      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
430      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
431      !!      add it to the general momentum trend (ua,va).
432      !!         ua = ua - 1/e1u * zhpi
433      !!         va = va - 1/e2v * zhpj
434      !!
435      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
436      !!----------------------------------------------------------------------
437      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
438      !!
439      INTEGER  ::   ji, jj, jk, jii, jjj                 ! dummy loop indices
440      REAL(wp) ::   zcoef0, zuap, zvap, znad, ztmp       ! temporary scalars
441      LOGICAL  ::   ll_tmp1, ll_tmp2                     ! local logical variables
442      REAL(wp), DIMENSION(jpi,jpj,jpk)      ::   zhpi, zhpj
443      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
444      !!----------------------------------------------------------------------
445      !
446      IF( ln_wd_il ) ALLOCATE(zcpx(jpi,jpj), zcpy(jpi,jpj))
447      !
448      IF( kt == nit000 .AND. lwp) THEN
449         WRITE(numout,*)
450         WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
451         WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
452         IF(lflush) CALL FLUSH(numout)
453      ENDIF
454      !
455      zcoef0 = - grav * 0.5_wp
456      IF ( ln_linssh ) THEN   ;   znad = 0._wp         ! Fixed    volume: density anomaly
457      ELSE                    ;   znad = 1._wp         ! Variable volume: density
458      ENDIF
459      !
460      IF( ln_wd_il ) THEN
461        DO jj = 2, jpjm1
462           DO ji = 2, jpim1 
463             ll_tmp1 = MIN(  sshn(ji,jj)               ,  sshn(ji+1,jj) ) >                &
464                  &    MAX( -ht_0(ji,jj)               , -ht_0(ji+1,jj) ) .AND.            &
465                  &    MAX(  sshn(ji,jj) +  ht_0(ji,jj),  sshn(ji+1,jj) + ht_0(ji+1,jj) )  &
466                  &                                                       > rn_wdmin1 + rn_wdmin2
467             ll_tmp2 = ( ABS( sshn(ji,jj)              -  sshn(ji+1,jj) ) > 1.E-12 ) .AND. (       &
468                  &    MAX(   sshn(ji,jj)              ,  sshn(ji+1,jj) ) >                &
469                  &    MAX(  -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
470
471             IF(ll_tmp1) THEN
472               zcpx(ji,jj) = 1.0_wp
473             ELSE IF(ll_tmp2) THEN
474               ! no worries about  sshn(ji+1,jj) -  sshn(ji  ,jj) = 0, it won't happen ! here
475               zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
476                           &    / (sshn(ji+1,jj) - sshn(ji  ,jj)) )
477             ELSE
478               zcpx(ji,jj) = 0._wp
479             END IF
480     
481             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji,jj+1) ) >                &
482                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
483                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji,jj+1) + ht_0(ji,jj+1) )  &
484                  &                                                      > rn_wdmin1 + rn_wdmin2
485             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji,jj+1) ) > 1.E-12 ) .AND. (        &
486                  &    MAX(   sshn(ji,jj)             ,  sshn(ji,jj+1) ) >                &
487                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
488
489             IF(ll_tmp1) THEN
490               zcpy(ji,jj) = 1.0_wp
491             ELSE IF(ll_tmp2) THEN
492               ! no worries about  sshn(ji,jj+1) -  sshn(ji,jj  ) = 0, it won't happen ! here
493               zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
494                           &    / (sshn(ji,jj+1) - sshn(ji,jj  )) )
495             ELSE
496               zcpy(ji,jj) = 0._wp
497             END IF
498           END DO
499        END DO
500        CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1., zcpy, 'V', 1. )
501      END IF
502
503      ! Surface value
504      DO jj = 2, jpjm1
505         DO ji = fs_2, fs_jpim1   ! vector opt.
506            ! hydrostatic pressure gradient along s-surfaces
507            zhpi(ji,jj,1) = zcoef0 * (  e3w_n(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )    &
508               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e1u(ji,jj)
509            zhpj(ji,jj,1) = zcoef0 * (  e3w_n(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )    &
510               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e2v(ji,jj)
511            ! s-coordinate pressure gradient correction
512            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
513               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
514            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
515               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
516            !
517            IF( ln_wd_il ) THEN
518               zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
519               zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
520               zuap = zuap * zcpx(ji,jj)
521               zvap = zvap * zcpy(ji,jj)
522            ENDIF
523            !
524            ! add to the general momentum trend
525            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
526            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
527         END DO
528      END DO
529
530      ! interior value (2=<jk=<jpkm1)
531      DO jk = 2, jpkm1
532         DO jj = 2, jpjm1
533            DO ji = fs_2, fs_jpim1   ! vector opt.
534               ! hydrostatic pressure gradient along s-surfaces
535               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj)   &
536                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
537                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
538               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj)   &
539                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
540                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
541               ! s-coordinate pressure gradient correction
542               zuap = -zcoef0 * ( rhd    (ji+1,jj  ,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
543                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) * r1_e1u(ji,jj)
544               zvap = -zcoef0 * ( rhd    (ji  ,jj+1,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
545                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) * r1_e2v(ji,jj)
546               !
547               IF( ln_wd_il ) THEN
548                  zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
549                  zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
550                  zuap = zuap * zcpx(ji,jj)
551                  zvap = zvap * zcpy(ji,jj)
552               ENDIF
553               !
554               ! add to the general momentum trend
555               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
556               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
557            END DO
558         END DO
559      END DO
560      !
561      IF( ln_wd_il )  DEALLOCATE( zcpx , zcpy )
562      !
563   END SUBROUTINE hpg_sco
564
565
566   SUBROUTINE hpg_isf( kt )
567      !!---------------------------------------------------------------------
568      !!                  ***  ROUTINE hpg_isf  ***
569      !!
570      !! ** Method  :   s-coordinate case. Jacobian scheme.
571      !!      The now hydrostatic pressure gradient at a given level, jk,
572      !!      is computed by taking the vertical integral of the in-situ
573      !!      density gradient along the model level from the suface to that
574      !!      level. s-coordinates (ln_sco): a corrective term is added
575      !!      to the horizontal pressure gradient :
576      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
577      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
578      !!      add it to the general momentum trend (ua,va).
579      !!         ua = ua - 1/e1u * zhpi
580      !!         va = va - 1/e2v * zhpj
581      !!      iceload is added and partial cell case are added to the top and bottom
582      !!     
583      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
584      !!----------------------------------------------------------------------
585      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
586      !!
587      INTEGER  ::   ji, jj, jk, ikt, iktp1i, iktp1j   ! dummy loop indices
588      REAL(wp) ::   zcoef0, zuap, zvap, znad          ! temporary scalars
589      REAL(wp), DIMENSION(jpi,jpj,jpk ) ::  zhpi, zhpj
590      REAL(wp), DIMENSION(jpi,jpj,jpts) ::  zts_top
591      REAL(wp), DIMENSION(jpi,jpj)      ::  zrhdtop_oce
592      !!----------------------------------------------------------------------
593      !
594      zcoef0 = - grav * 0.5_wp   ! Local constant initialization
595      !
596      znad=1._wp                 ! To use density and not density anomaly
597      !
598      !                          ! iniitialised to 0. zhpi zhpi
599      zhpi(:,:,:) = 0._wp   ;   zhpj(:,:,:) = 0._wp
600
601      ! compute rhd at the ice/oce interface (ocean side)
602      ! usefull to reduce residual current in the test case ISOMIP with no melting
603      DO ji = 1, jpi
604        DO jj = 1, jpj
605          ikt = mikt(ji,jj)
606          zts_top(ji,jj,1) = tsn(ji,jj,ikt,1)
607          zts_top(ji,jj,2) = tsn(ji,jj,ikt,2)
608        END DO
609      END DO
610      CALL eos( zts_top, risfdep, zrhdtop_oce )
611
612!==================================================================================     
613!===== Compute surface value =====================================================
614!==================================================================================
615      DO jj = 2, jpjm1
616         DO ji = fs_2, fs_jpim1   ! vector opt.
617            ikt    = mikt(ji,jj)
618            iktp1i = mikt(ji+1,jj)
619            iktp1j = mikt(ji,jj+1)
620            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
621            ! we assume ISF is in isostatic equilibrium
622            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * e3w_n(ji+1,jj,iktp1i)                                    &
623               &                                    * ( 2._wp * znad + rhd(ji+1,jj,iktp1i) + zrhdtop_oce(ji+1,jj) )   &
624               &                                  - 0.5_wp * e3w_n(ji,jj,ikt)                                         &
625               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
626               &                                  + ( riceload(ji+1,jj) - riceload(ji,jj))                            ) 
627            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * e3w_n(ji,jj+1,iktp1j)                                    &
628               &                                    * ( 2._wp * znad + rhd(ji,jj+1,iktp1j) + zrhdtop_oce(ji,jj+1) )   &
629               &                                  - 0.5_wp * e3w_n(ji,jj,ikt)                                         & 
630               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
631               &                                  + ( riceload(ji,jj+1) - riceload(ji,jj))                            ) 
632            ! s-coordinate pressure gradient correction (=0 if z coordinate)
633            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
634               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
635            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
636               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
637            ! add to the general momentum trend
638            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
639            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
640         END DO
641      END DO
642!==================================================================================     
643!===== Compute interior value =====================================================
644!==================================================================================
645      ! interior value (2=<jk=<jpkm1)
646      DO jk = 2, jpkm1
647         DO jj = 2, jpjm1
648            DO ji = fs_2, fs_jpim1   ! vector opt.
649               ! hydrostatic pressure gradient along s-surfaces
650               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
651                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) * wmask(ji+1,jj,jk)   &
652                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad ) * wmask(ji  ,jj,jk)   )
653               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
654                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) * wmask(ji,jj+1,jk)   &
655                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad ) * wmask(ji,jj  ,jk)   )
656               ! s-coordinate pressure gradient correction
657               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
658                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) / e1u(ji,jj)
659               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
660                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) / e2v(ji,jj)
661               ! add to the general momentum trend
662               ua(ji,jj,jk) = ua(ji,jj,jk) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
663               va(ji,jj,jk) = va(ji,jj,jk) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
664            END DO
665         END DO
666      END DO
667      !
668   END SUBROUTINE hpg_isf
669
670
671   SUBROUTINE hpg_djc( kt )
672      !!---------------------------------------------------------------------
673      !!                  ***  ROUTINE hpg_djc  ***
674      !!
675      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
676      !!
677      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
678      !!----------------------------------------------------------------------
679      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
680      !!
681      INTEGER  ::   ji, jj, jk          ! dummy loop indices
682      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
683      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
684      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
685      LOGICAL  ::   ll_tmp1, ll_tmp2    ! local logical variables
686      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zhpj
687      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   dzx, dzy, dzz, dzu, dzv, dzw
688      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhox, drhoy, drhoz, drhou, drhov, drhow
689      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   rho_i, rho_j, rho_k
690      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
691      !!----------------------------------------------------------------------
692      !
693      IF( ln_wd_il ) THEN
694         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
695        DO jj = 2, jpjm1
696           DO ji = 2, jpim1 
697             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji+1,jj) ) >                &
698                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
699                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji+1,jj) + ht_0(ji+1,jj) )  &
700                  &                                                      > rn_wdmin1 + rn_wdmin2
701             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji+1,jj) ) > 1.E-12 ) .AND. (        &
702                  &    MAX(   sshn(ji,jj)             ,  sshn(ji+1,jj) ) >                &
703                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
704             IF(ll_tmp1) THEN
705               zcpx(ji,jj) = 1.0_wp
706             ELSE IF(ll_tmp2) THEN
707               ! no worries about  sshn(ji+1,jj) -  sshn(ji  ,jj) = 0, it won't happen ! here
708               zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
709                           &    / (sshn(ji+1,jj) - sshn(ji  ,jj)) )
710             ELSE
711               zcpx(ji,jj) = 0._wp
712             END IF
713     
714             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji,jj+1) ) >                &
715                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
716                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji,jj+1) + ht_0(ji,jj+1) )  &
717                  &                                                      > rn_wdmin1 + rn_wdmin2
718             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji,jj+1) ) > 1.E-12 ) .AND. (        &
719                  &    MAX(   sshn(ji,jj)             ,  sshn(ji,jj+1) ) >                &
720                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
721
722             IF(ll_tmp1) THEN
723               zcpy(ji,jj) = 1.0_wp
724             ELSE IF(ll_tmp2) THEN
725               ! no worries about  sshn(ji,jj+1) -  sshn(ji,jj  ) = 0, it won't happen ! here
726               zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
727                           &    / (sshn(ji,jj+1) - sshn(ji,jj  )) )
728             ELSE
729               zcpy(ji,jj) = 0._wp
730             END IF
731           END DO
732        END DO
733        CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1., zcpy, 'V', 1. )
734      END IF
735
736      IF( kt == nit000 .AND. lwp) THEN
737         WRITE(numout,*)
738         WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
739         WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
740         IF(lflush) CALL FLUSH(numout)
741      ENDIF
742
743      ! Local constant initialization
744      zcoef0 = - grav * 0.5_wp
745      z1_10  = 1._wp / 10._wp
746      z1_12  = 1._wp / 12._wp
747
748      !----------------------------------------------------------------------------------------
749      !  compute and store in provisional arrays elementary vertical and horizontal differences
750      !----------------------------------------------------------------------------------------
751
752!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
753
754      DO jk = 2, jpkm1
755         DO jj = 2, jpjm1
756            DO ji = fs_2, fs_jpim1   ! vector opt.
757               drhoz(ji,jj,jk) = rhd    (ji  ,jj  ,jk) - rhd    (ji,jj,jk-1)
758               dzz  (ji,jj,jk) = gde3w_n(ji  ,jj  ,jk) - gde3w_n(ji,jj,jk-1)
759               drhox(ji,jj,jk) = rhd    (ji+1,jj  ,jk) - rhd    (ji,jj,jk  )
760               dzx  (ji,jj,jk) = gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk  )
761               drhoy(ji,jj,jk) = rhd    (ji  ,jj+1,jk) - rhd    (ji,jj,jk  )
762               dzy  (ji,jj,jk) = gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk  )
763            END DO
764         END DO
765      END DO
766
767      !-------------------------------------------------------------------------
768      ! compute harmonic averages using eq. 5.18
769      !-------------------------------------------------------------------------
770      zep = 1.e-15
771
772!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
773!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
774
775      DO jk = 2, jpkm1
776         DO jj = 2, jpjm1
777            DO ji = fs_2, fs_jpim1   ! vector opt.
778               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
779
780               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
781               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
782
783               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
784               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
785
786               IF( cffw > zep) THEN
787                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
788                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
789               ELSE
790                  drhow(ji,jj,jk) = 0._wp
791               ENDIF
792
793               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
794                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
795
796               IF( cffu > zep ) THEN
797                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
798                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
799               ELSE
800                  drhou(ji,jj,jk ) = 0._wp
801               ENDIF
802
803               IF( cffx > zep ) THEN
804                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
805                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
806               ELSE
807                  dzu(ji,jj,jk) = 0._wp
808               ENDIF
809
810               IF( cffv > zep ) THEN
811                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
812                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
813               ELSE
814                  drhov(ji,jj,jk) = 0._wp
815               ENDIF
816
817               IF( cffy > zep ) THEN
818                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
819                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
820               ELSE
821                  dzv(ji,jj,jk) = 0._wp
822               ENDIF
823
824            END DO
825         END DO
826      END DO
827
828      !----------------------------------------------------------------------------------
829      ! apply boundary conditions at top and bottom using 5.36-5.37
830      !----------------------------------------------------------------------------------
831      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
832      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
833      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
834
835      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
836      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
837      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
838
839
840      !--------------------------------------------------------------
841      ! Upper half of top-most grid box, compute and store
842      !-------------------------------------------------------------
843
844!!bug gm   :  e3w-gde3w = 0.5*e3w  ....  and gde3w(2)-gde3w(1)=e3w(2) ....   to be verified
845!          true if gde3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
846
847      DO jj = 2, jpjm1
848         DO ji = fs_2, fs_jpim1   ! vector opt.
849            rho_k(ji,jj,1) = -grav * ( e3w_n(ji,jj,1) - gde3w_n(ji,jj,1) )               &
850               &                   * (  rhd(ji,jj,1)                                     &
851               &                     + 0.5_wp * ( rhd    (ji,jj,2) - rhd    (ji,jj,1) )  &
852               &                              * ( e3w_n  (ji,jj,1) - gde3w_n(ji,jj,1) )  &
853               &                              / ( gde3w_n(ji,jj,2) - gde3w_n(ji,jj,1) )  )
854         END DO
855      END DO
856
857!!bug gm    : here also, simplification is possible
858!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
859
860      DO jk = 2, jpkm1
861         DO jj = 2, jpjm1
862            DO ji = fs_2, fs_jpim1   ! vector opt.
863
864               rho_k(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj,jk) + rhd    (ji,jj,jk-1) )                                   &
865                  &                     * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) )                                   &
866                  &            - grav * z1_10 * (                                                                   &
867                  &     ( drhow  (ji,jj,jk) - drhow  (ji,jj,jk-1) )                                                     &
868                  &   * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
869                  &   - ( dzw    (ji,jj,jk) - dzw    (ji,jj,jk-1) )                                                     &
870                  &   * ( rhd    (ji,jj,jk) - rhd    (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
871                  &                             )
872
873               rho_i(ji,jj,jk) = zcoef0 * ( rhd    (ji+1,jj,jk) + rhd    (ji,jj,jk) )                                   &
874                  &                     * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) )                                   &
875                  &            - grav* z1_10 * (                                                                    &
876                  &     ( drhou  (ji+1,jj,jk) - drhou  (ji,jj,jk) )                                                     &
877                  &   * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
878                  &   - ( dzu    (ji+1,jj,jk) - dzu    (ji,jj,jk) )                                                     &
879                  &   * ( rhd    (ji+1,jj,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
880                  &                            )
881
882               rho_j(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj+1,jk) + rhd    (ji,jj,jk) )                                 &
883                  &                     * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) )                                   &
884                  &            - grav* z1_10 * (                                                                    &
885                  &     ( drhov  (ji,jj+1,jk) - drhov  (ji,jj,jk) )                                                     &
886                  &   * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
887                  &   - ( dzv    (ji,jj+1,jk) - dzv    (ji,jj,jk) )                                                     &
888                  &   * ( rhd    (ji,jj+1,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
889                  &                            )
890
891            END DO
892         END DO
893      END DO
894      CALL lbc_lnk_multi( 'dynhpg', rho_k, 'W', 1., rho_i, 'U', 1., rho_j, 'V', 1. )
895
896      ! ---------------
897      !  Surface value
898      ! ---------------
899      DO jj = 2, jpjm1
900         DO ji = fs_2, fs_jpim1   ! vector opt.
901            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
902            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
903            IF( ln_wd_il ) THEN
904              zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
905              zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
906            ENDIF
907            ! add to the general momentum trend
908            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
909            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
910         END DO
911      END DO
912
913      ! ----------------
914      !  interior value   (2=<jk=<jpkm1)
915      ! ----------------
916      DO jk = 2, jpkm1
917         DO jj = 2, jpjm1
918            DO ji = fs_2, fs_jpim1   ! vector opt.
919               ! hydrostatic pressure gradient along s-surfaces
920               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
921                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
922                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) * r1_e1u(ji,jj)
923               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
924                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
925                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) * r1_e2v(ji,jj)
926               IF( ln_wd_il ) THEN
927                 zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
928                 zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
929               ENDIF
930               ! add to the general momentum trend
931               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
932               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
933            END DO
934         END DO
935      END DO
936      !
937      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
938      !
939   END SUBROUTINE hpg_djc
940
941
942   SUBROUTINE hpg_prj( kt )
943      !!---------------------------------------------------------------------
944      !!                  ***  ROUTINE hpg_prj  ***
945      !!
946      !! ** Method  :   s-coordinate case.
947      !!      A Pressure-Jacobian horizontal pressure gradient method
948      !!      based on the constrained cubic-spline interpolation for
949      !!      all vertical coordinate systems
950      !!
951      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
952      !!----------------------------------------------------------------------
953      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
954      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
955      !!
956      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
957      REAL(wp) ::   zcoef0, znad                    ! local scalars
958      !
959      !! The local variables for the correction term
960      INTEGER  :: jk1, jis, jid, jjs, jjd
961      LOGICAL  :: ll_tmp1, ll_tmp2                  ! local logical variables
962      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
963      REAL(wp) :: zrhdt1
964      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
965      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdept, zrhh
966      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
967      REAL(wp), DIMENSION(jpi,jpj)   ::   zsshu_n, zsshv_n
968      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
969      !!----------------------------------------------------------------------
970      !
971      IF( kt == nit000 .AND. lwp) THEN
972         WRITE(numout,*)
973         WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
974         WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
975         IF(lflush) CALL FLUSH(numout)
976      ENDIF
977
978      ! Local constant initialization
979      zcoef0 = - grav
980      znad = 1._wp
981      IF( ln_linssh )   znad = 0._wp
982
983      IF( ln_wd_il ) THEN
984         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
985         DO jj = 2, jpjm1
986           DO ji = 2, jpim1 
987             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji+1,jj) ) >                &
988                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
989                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji+1,jj) + ht_0(ji+1,jj) )  &
990                  &                                                      > rn_wdmin1 + rn_wdmin2
991             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji+1,jj) ) > 1.E-12 ) .AND. (         &
992                  &    MAX(   sshn(ji,jj)             ,  sshn(ji+1,jj) ) >                &
993                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
994
995             IF(ll_tmp1) THEN
996               zcpx(ji,jj) = 1.0_wp
997             ELSE IF(ll_tmp2) THEN
998               ! no worries about  sshn(ji+1,jj) -  sshn(ji  ,jj) = 0, it won't happen ! here
999               zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
1000                           &    / (sshn(ji+1,jj) -  sshn(ji  ,jj)) )
1001             
1002                zcpx(ji,jj) = max(min( zcpx(ji,jj) , 1.0_wp),0.0_wp)
1003             ELSE
1004               zcpx(ji,jj) = 0._wp
1005             END IF
1006     
1007             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji,jj+1) ) >                &
1008                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
1009                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji,jj+1) + ht_0(ji,jj+1) )  &
1010                  &                                                      > rn_wdmin1 + rn_wdmin2
1011             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji,jj+1) ) > 1.E-12 ) .AND. (      &
1012                  &    MAX(   sshn(ji,jj)             ,  sshn(ji,jj+1) ) >                &
1013                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
1014
1015             IF(ll_tmp1) THEN
1016               zcpy(ji,jj) = 1.0_wp
1017             ELSE IF(ll_tmp2) THEN
1018               ! no worries about  sshn(ji,jj+1) -  sshn(ji,jj  ) = 0, it won't happen ! here
1019               zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
1020                           &    / (sshn(ji,jj+1) - sshn(ji,jj  )) )
1021                zcpy(ji,jj) = max(min( zcpy(ji,jj) , 1.0_wp),0.0_wp)
1022
1023               ELSE
1024                  zcpy(ji,jj) = 0._wp
1025               ENDIF
1026            END DO
1027         END DO
1028         CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1., zcpy, 'V', 1. )
1029      ENDIF
1030
1031      ! Clean 3-D work arrays
1032      zhpi(:,:,:) = 0._wp
1033      zrhh(:,:,:) = rhd(:,:,:)
1034
1035      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1036      DO jj = 1, jpj
1037        DO ji = 1, jpi
1038          jk = mbkt(ji,jj)+1
1039          IF(     jk <=  0   ) THEN   ;   zrhh(ji,jj,    :   ) = 0._wp
1040          ELSEIF( jk ==  1   ) THEN   ;   zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
1041          ELSEIF( jk < jpkm1 ) THEN
1042             DO jkk = jk+1, jpk
1043                zrhh(ji,jj,jkk) = interp1(gde3w_n(ji,jj,jkk  ), gde3w_n(ji,jj,jkk-1),   &
1044                   &                      gde3w_n(ji,jj,jkk-2), rhd    (ji,jj,jkk-1), rhd(ji,jj,jkk-2))
1045             END DO
1046          ENDIF
1047        END DO
1048      END DO
1049
1050      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1051      DO jj = 1, jpj
1052         DO ji = 1, jpi
1053            zdept(ji,jj,1) = 0.5_wp * e3w_n(ji,jj,1) - sshn(ji,jj) * znad
1054         END DO
1055      END DO
1056
1057      DO jk = 2, jpk
1058         DO jj = 1, jpj
1059            DO ji = 1, jpi
1060               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w_n(ji,jj,jk)
1061            END DO
1062         END DO
1063      END DO
1064
1065      fsp(:,:,:) = zrhh (:,:,:)
1066      xsp(:,:,:) = zdept(:,:,:)
1067
1068      ! Construct the vertical density profile with the
1069      ! constrained cubic spline interpolation
1070      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1071      CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1072
1073      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1074      DO jj = 2, jpj
1075        DO ji = 2, jpi
1076          zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1),  &
1077             &                                              csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w_n(ji,jj,1)
1078
1079          ! assuming linear profile across the top half surface layer
1080          zhpi(ji,jj,1) =  0.5_wp * e3w_n(ji,jj,1) * zrhdt1
1081        END DO
1082      END DO
1083
1084      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1085      DO jk = 2, jpkm1
1086        DO jj = 2, jpj
1087          DO ji = 2, jpi
1088            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                                  &
1089               &             integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk),   &
1090               &                           asp  (ji,jj,jk-1), bsp  (ji,jj,jk-1), &
1091               &                           csp  (ji,jj,jk-1), dsp  (ji,jj,jk-1)  )
1092          END DO
1093        END DO
1094      END DO
1095
1096      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1097
1098      ! Prepare zsshu_n and zsshv_n
1099      DO jj = 2, jpjm1
1100        DO ji = 2, jpim1
1101!!gm BUG ?    if it is ssh at u- & v-point then it should be:
1102!          zsshu_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji+1,jj) * sshn(ji+1,jj)) * &
1103!                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1104!          zsshv_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji,jj+1) * sshn(ji,jj+1)) * &
1105!                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1106!!gm not this:
1107          zsshu_n(ji,jj) = (e1e2u(ji,jj) * sshn(ji,jj) + e1e2u(ji+1, jj) * sshn(ji+1,jj)) * &
1108                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1109          zsshv_n(ji,jj) = (e1e2v(ji,jj) * sshn(ji,jj) + e1e2v(ji+1, jj) * sshn(ji,jj+1)) * &
1110                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1111        END DO
1112      END DO
1113
1114      CALL lbc_lnk_multi ('dynhpg', zsshu_n, 'U', 1., zsshv_n, 'V', 1. )
1115
1116      DO jj = 2, jpjm1
1117        DO ji = 2, jpim1
1118          zu(ji,jj,1) = - ( e3u_n(ji,jj,1) - zsshu_n(ji,jj) * znad) 
1119          zv(ji,jj,1) = - ( e3v_n(ji,jj,1) - zsshv_n(ji,jj) * znad)
1120        END DO
1121      END DO
1122
1123      DO jk = 2, jpkm1
1124        DO jj = 2, jpjm1
1125          DO ji = 2, jpim1
1126            zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u_n(ji,jj,jk)
1127            zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v_n(ji,jj,jk)
1128          END DO
1129        END DO
1130      END DO
1131
1132      DO jk = 1, jpkm1
1133        DO jj = 2, jpjm1
1134          DO ji = 2, jpim1
1135            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u_n(ji,jj,jk)
1136            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v_n(ji,jj,jk)
1137          END DO
1138        END DO
1139      END DO
1140
1141      DO jk = 1, jpkm1
1142        DO jj = 2, jpjm1
1143          DO ji = 2, jpim1
1144            zu(ji,jj,jk) = MIN(  zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1145            zu(ji,jj,jk) = MAX(  zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1146            zv(ji,jj,jk) = MIN(  zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1147            zv(ji,jj,jk) = MAX(  zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1148          END DO
1149        END DO
1150      END DO
1151
1152
1153      DO jk = 1, jpkm1
1154        DO jj = 2, jpjm1
1155          DO ji = 2, jpim1
1156            zpwes = 0._wp; zpwed = 0._wp
1157            zpnss = 0._wp; zpnsd = 0._wp
1158            zuijk = zu(ji,jj,jk)
1159            zvijk = zv(ji,jj,jk)
1160
1161            !!!!!     for u equation
1162            IF( jk <= mbku(ji,jj) ) THEN
1163               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1164                 jis = ji + 1; jid = ji
1165               ELSE
1166                 jis = ji;     jid = ji +1
1167               ENDIF
1168
1169               ! integrate the pressure on the shallow side
1170               jk1 = jk
1171               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1172                 IF( jk1 == mbku(ji,jj) ) THEN
1173                   zuijk = -zdept(jis,jj,jk1)
1174                   EXIT
1175                 ENDIF
1176                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1177                 zpwes = zpwes +                                    &
1178                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1179                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1180                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1181                 jk1 = jk1 + 1
1182               END DO
1183
1184               ! integrate the pressure on the deep side
1185               jk1 = jk
1186               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1187                 IF( jk1 == 1 ) THEN
1188                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1189                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1190                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1191                                                     dsp(jid,jj,1)) * zdeps
1192                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1193                   EXIT
1194                 ENDIF
1195                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1196                 zpwed = zpwed +                                        &
1197                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1198                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1199                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1200                 jk1 = jk1 - 1
1201               END DO
1202
1203               ! update the momentum trends in u direction
1204
1205               zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1206               IF( .NOT.ln_linssh ) THEN
1207                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1208                    &    ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1209                ELSE
1210                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1211               ENDIF
1212               IF( ln_wd_il ) THEN
1213                  zdpdx1 = zdpdx1 * zcpx(ji,jj) * wdrampu(ji,jj)
1214                  zdpdx2 = zdpdx2 * zcpx(ji,jj) * wdrampu(ji,jj)
1215               ENDIF
1216               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * umask(ji,jj,jk) 
1217            ENDIF
1218
1219            !!!!!     for v equation
1220            IF( jk <= mbkv(ji,jj) ) THEN
1221               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1222                 jjs = jj + 1; jjd = jj
1223               ELSE
1224                 jjs = jj    ; jjd = jj + 1
1225               ENDIF
1226
1227               ! integrate the pressure on the shallow side
1228               jk1 = jk
1229               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1230                 IF( jk1 == mbkv(ji,jj) ) THEN
1231                   zvijk = -zdept(ji,jjs,jk1)
1232                   EXIT
1233                 ENDIF
1234                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1235                 zpnss = zpnss +                                      &
1236                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1237                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1238                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1239                 jk1 = jk1 + 1
1240               END DO
1241
1242               ! integrate the pressure on the deep side
1243               jk1 = jk
1244               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1245                 IF( jk1 == 1 ) THEN
1246                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1247                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1248                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1249                                                     dsp(ji,jjd,1) ) * zdeps
1250                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1251                   EXIT
1252                 ENDIF
1253                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1254                 zpnsd = zpnsd +                                        &
1255                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1256                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1257                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1258                 jk1 = jk1 - 1
1259               END DO
1260
1261
1262               ! update the momentum trends in v direction
1263
1264               zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1265               IF( .NOT.ln_linssh ) THEN
1266                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1267                          ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1268               ELSE
1269                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1270               ENDIF
1271               IF( ln_wd_il ) THEN
1272                  zdpdy1 = zdpdy1 * zcpy(ji,jj) * wdrampv(ji,jj) 
1273                  zdpdy2 = zdpdy2 * zcpy(ji,jj) * wdrampv(ji,jj) 
1274               ENDIF
1275
1276               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2) * vmask(ji,jj,jk)
1277            ENDIF
1278               !
1279            END DO
1280         END DO
1281      END DO
1282      !
1283      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
1284      !
1285   END SUBROUTINE hpg_prj
1286
1287
1288   SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1289      !!----------------------------------------------------------------------
1290      !!                 ***  ROUTINE cspline  ***
1291      !!
1292      !! ** Purpose :   constrained cubic spline interpolation
1293      !!
1294      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1295      !!
1296      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1297      !!----------------------------------------------------------------------
1298      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   fsp, xsp           ! value and coordinate
1299      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   asp, bsp, csp, dsp ! coefficients of the interpoated function
1300      INTEGER                   , INTENT(in   ) ::   polynomial_type    ! 1: cubic spline   ;   2: Linear
1301      !
1302      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1303      INTEGER  ::   jpi, jpj, jpkm1
1304      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1305      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1306      REAL(wp) ::   zdf(size(fsp,3))
1307      !!----------------------------------------------------------------------
1308      !
1309!!gm  WHAT !!!!!   THIS IS VERY DANGEROUS !!!!! 
1310      jpi   = size(fsp,1)
1311      jpj   = size(fsp,2)
1312      jpkm1 = MAX( 1, size(fsp,3) - 1 )
1313      !
1314      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1315         DO ji = 1, jpi
1316            DO jj = 1, jpj
1317           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1318           !    DO jk = 2, jpkm1-1
1319           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1320           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1321           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1322           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1323           !
1324           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1325           !
1326           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1327           !           zdf(jk) = 0._wp
1328           !       ELSE
1329           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1330           !       ENDIF
1331           !    END DO
1332
1333           !!Simply geometric average
1334               DO jk = 2, jpkm1-1
1335                  zdf1 = (fsp(ji,jj,jk  ) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk  ) - xsp(ji,jj,jk-1))
1336                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk  )) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk  ))
1337
1338                  IF(zdf1 * zdf2 <= 0._wp) THEN
1339                     zdf(jk) = 0._wp
1340                  ELSE
1341                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1342                  ENDIF
1343               END DO
1344
1345               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1346                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) )           -  0.5_wp * zdf(2)
1347               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1348                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpkm1 - 1)
1349
1350               DO jk = 1, jpkm1 - 1
1351                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1352                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1353                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1354                 zddf1  = -2._wp * ztmp1 + ztmp2
1355                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1356                 zddf2  =  2._wp * ztmp1 - ztmp2
1357
1358                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1359                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1360                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1361                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1362                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1363                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1364                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1365                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1366                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1367               END DO
1368            END DO
1369         END DO
1370
1371      ELSEIF ( polynomial_type == 2 ) THEN     ! Linear
1372         DO ji = 1, jpi
1373            DO jj = 1, jpj
1374               DO jk = 1, jpkm1-1
1375                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1376                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1377
1378                  dsp(ji,jj,jk) = 0._wp
1379                  csp(ji,jj,jk) = 0._wp
1380                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1381                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1382               END DO
1383            END DO
1384         END DO
1385         !
1386      ELSE
1387         CALL ctl_stop( 'invalid polynomial type in cspline' )
1388      ENDIF
1389      !
1390   END SUBROUTINE cspline
1391
1392
1393   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1394      !!----------------------------------------------------------------------
1395      !!                 ***  ROUTINE interp1  ***
1396      !!
1397      !! ** Purpose :   1-d linear interpolation
1398      !!
1399      !! ** Method  :   interpolation is straight forward
1400      !!                extrapolation is also permitted (no value limit)
1401      !!----------------------------------------------------------------------
1402      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1403      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1404      REAL(wp)             ::  zdeltx
1405      !!----------------------------------------------------------------------
1406      !
1407      zdeltx = xr - xl
1408      IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1409         f = 0.5_wp * (fl + fr)
1410      ELSE
1411         f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1412      ENDIF
1413      !
1414   END FUNCTION interp1
1415
1416
1417   FUNCTION interp2( x, a, b, c, d )  RESULT(f)
1418      !!----------------------------------------------------------------------
1419      !!                 ***  ROUTINE interp1  ***
1420      !!
1421      !! ** Purpose :   1-d constrained cubic spline interpolation
1422      !!
1423      !! ** Method  :  cubic spline interpolation
1424      !!
1425      !!----------------------------------------------------------------------
1426      REAL(wp), INTENT(in) ::  x, a, b, c, d
1427      REAL(wp)             ::  f ! value from the interpolation
1428      !!----------------------------------------------------------------------
1429      !
1430      f = a + x* ( b + x * ( c + d * x ) )
1431      !
1432   END FUNCTION interp2
1433
1434
1435   FUNCTION interp3( x, a, b, c, d )  RESULT(f)
1436      !!----------------------------------------------------------------------
1437      !!                 ***  ROUTINE interp1  ***
1438      !!
1439      !! ** Purpose :   Calculate the first order of derivative of
1440      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1441      !!
1442      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1443      !!
1444      !!----------------------------------------------------------------------
1445      REAL(wp), INTENT(in) ::  x, a, b, c, d
1446      REAL(wp)             ::  f ! value from the interpolation
1447      !!----------------------------------------------------------------------
1448      !
1449      f = b + x * ( 2._wp * c + 3._wp * d * x)
1450      !
1451   END FUNCTION interp3
1452
1453
1454   FUNCTION integ_spline( xl, xr, a, b, c, d )  RESULT(f)
1455      !!----------------------------------------------------------------------
1456      !!                 ***  ROUTINE interp1  ***
1457      !!
1458      !! ** Purpose :   1-d constrained cubic spline integration
1459      !!
1460      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1461      !!
1462      !!----------------------------------------------------------------------
1463      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1464      REAL(wp)             ::  za1, za2, za3
1465      REAL(wp)             ::  f                   ! integration result
1466      !!----------------------------------------------------------------------
1467      !
1468      za1 = 0.5_wp * b
1469      za2 = c / 3.0_wp
1470      za3 = 0.25_wp * d
1471      !
1472      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1473         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1474      !
1475   END FUNCTION integ_spline
1476
1477   !!======================================================================
1478END MODULE dynhpg
1479
Note: See TracBrowser for help on using the repository browser.