New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcapr.F90 in NEMO/branches/UKMO/v15531_cpl-mslp-apr/src/OCE/SBC – NEMO

source: NEMO/branches/UKMO/v15531_cpl-mslp-apr/src/OCE/SBC/sbcapr.F90 @ 15537

Last change on this file since 15537 was 15537, checked in by jcastill, 3 years ago

Changes compatible with the ticket (not tested in this revision)
  • Property svn:keywords set to Id
File size: 9.3 KB
Line 
1MODULE sbcapr
2   !!======================================================================
3   !!                       ***  MODULE  sbcapr  ***
4   !! Surface module :   atmospheric pressure forcing
5   !!======================================================================
6   !! History :  3.3  !   2010-09  (J. Chanut, C. Bricaud, G. Madec)  Original code
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   sbc_apr        : read atmospheric pressure in netcdf files
11   !!----------------------------------------------------------------------
12   USE dom_oce         ! ocean space and time domain
13   USE sbc_oce         ! surface boundary condition
14   USE phycst          ! physical constants
15   !
16   USE fldread         ! read input fields
17   USE in_out_manager  ! I/O manager
18   USE lib_fortran     ! distributed memory computing library
19   USE iom             ! IOM library
20   USE lib_mpp         ! MPP library
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   sbc_apr       ! routine called in sbcmod
26   PUBLIC   sbc_apr_init  ! routine called in sbcmod
27
28   !                                          !!* namsbc_apr namelist (Atmospheric PRessure) *
29   LOGICAL, PUBLIC ::   ln_apr_obc = .false.   !: inverse barometer added to OBC ssh data
30   LOGICAL, PUBLIC ::   ln_ref_apr             !: ref. pressure: global mean Patm (F) or a constant (F)
31   REAL(wp),PUBLIC ::   rn_pref                !  reference atmospheric pressure   [N/m2]
32
33   REAL(wp), ALLOCATABLE, SAVE, PUBLIC, DIMENSION(:,:) ::   ssh_ib    ! Inverse barometer now    sea surface height   [m]
34   REAL(wp), ALLOCATABLE, SAVE, PUBLIC, DIMENSION(:,:) ::   ssh_ibb   ! Inverse barometer before sea surface height   [m]
35   REAL(wp), ALLOCATABLE, SAVE, PUBLIC, DIMENSION(:,:) ::   apr       ! atmospheric pressure at kt                 [N/m2]
36
37   REAL(wp), PUBLIC ::  tarea                  ! whole domain mean masked ocean surface
38   REAL(wp), PUBLIC ::  r1_grau                ! = 1.e0 / (grav * rho0)
39
40   LOGICAL, PUBLIC ::   cpl_mslp = .FALSE. ! Presure is passed via coupling
41
42   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_apr   ! structure of input fields (file informations, fields read)
43
44   !!----------------------------------------------------------------------
45   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
46   !! $Id$
47   !! Software governed by the CeCILL license (see ./LICENSE)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE sbc_apr_init
52      !!---------------------------------------------------------------------
53      !!                     ***  ROUTINE sbc_apr  ***
54      !!
55      !! ** Purpose :   read atmospheric pressure fields in netcdf files.
56      !!
57      !! ** Method  : - Read namelist namsbc_apr
58      !!              - Read Patm fields in netcdf files
59      !!              - Compute reference atmospheric pressure
60      !!              - Compute inverse barometer ssh
61      !! ** action  :   apr      : atmospheric pressure at kt
62      !!                ssh_ib   : inverse barometer ssh at kt
63      !!---------------------------------------------------------------------
64      INTEGER            ::   ierror  ! local integer
65      INTEGER            ::   ios     ! Local integer output status for namelist read
66      !!
67      CHARACTER(len=100) ::  cn_dir   ! Root directory for location of ssr files
68      TYPE(FLD_N)        ::  sn_apr   ! informations about the fields to be read
69      !!
70      NAMELIST/namsbc_apr/ cn_dir, sn_apr, ln_ref_apr, rn_pref, ln_apr_obc
71      !!----------------------------------------------------------------------
72      READ  ( numnam_ref, namsbc_apr, IOSTAT = ios, ERR = 901)
73901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc_apr in reference namelist' )
74
75      READ  ( numnam_cfg, namsbc_apr, IOSTAT = ios, ERR = 902 )
76902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc_apr in configuration namelist' )
77      IF(lwm) WRITE ( numond, namsbc_apr )
78      !
79      IF( .NOT. cpl_mslp ) THEN
80         ALLOCATE( sf_apr(1), STAT=ierror )           !* allocate and fill sf_sst (forcing structure) with sn_sst
81         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_apr: unable to allocate sf_apr structure' )
82         !
83         CALL fld_fill( sf_apr, (/ sn_apr /), cn_dir, 'sbc_apr', 'Atmospheric pressure ', 'namsbc_apr' )
84                                ALLOCATE( sf_apr(1)%fnow(jpi,jpj,1)   )
85         IF( sn_apr%ln_tint )   ALLOCATE( sf_apr(1)%fdta(jpi,jpj,1,2) )
86      ENDIF
87                                ALLOCATE( ssh_ib(jpi,jpj) , ssh_ibb(jpi,jpj) )
88                                ALLOCATE( apr (jpi,jpj) )
89      !
90      IF( lwp )THEN                                 !* control print
91         WRITE(numout,*)
92         IF( cpl_mslp ) THEN
93            WRITE(numout,*) '   Namelist namsbc_apr : Atmospheric Pressure as coupling field'
94         ELSE
95            WRITE(numout,*) '   Namelist namsbc_apr : Atmospheric Pressure as external forcing'
96         ENDIF
97         WRITE(numout,*) '      ref. pressure: global mean Patm (T) or a constant (F)  ln_ref_apr = ', ln_ref_apr
98      ENDIF
99      !
100      IF( ln_ref_apr ) THEN                        !* Compute whole inner domain mean masked ocean surface
101         tarea = glob_sum( 'sbcapr', e1e2t(:,:) )
102         IF(lwp) WRITE(numout,*) '         Variable ref. Patm computed over a ocean surface of ', tarea*1e-6, 'km2'
103      ELSE
104         IF(lwp) WRITE(numout,*) '         Reference Patm used : ', rn_pref, ' N/m2'
105      ENDIF
106      !
107      r1_grau = 1.e0 / (grav * rho0)               !* constant for optimization
108      !
109      !                                            !* control check
110      IF( ln_apr_obc  ) THEN
111         IF(lwp) WRITE(numout,*) '         Inverse barometer added to OBC ssh data'
112      ENDIF
113!jc: stop below should rather be a warning
114      IF( ln_apr_obc .AND. .NOT.ln_apr_dyn   )   &
115            CALL ctl_warn( 'sbc_apr: use inverse barometer ssh at open boundary ONLY requires ln_apr_dyn=T' )
116      !
117   END SUBROUTINE sbc_apr_init
118
119   SUBROUTINE sbc_apr( kt )
120      !!---------------------------------------------------------------------
121      !!                     ***  ROUTINE sbc_apr  ***
122      !!
123      !! ** Purpose :   read atmospheric pressure fields in netcdf files.
124      !!
125      !! ** Method  : - Read namelist namsbc_apr
126      !!              - Read Patm fields in netcdf files
127      !!              - Compute reference atmospheric pressure
128      !!              - Compute inverse barometer ssh
129      !! ** action  :   apr      : atmospheric pressure at kt
130      !!                ssh_ib   : inverse barometer ssh at kt
131      !!---------------------------------------------------------------------
132      INTEGER, INTENT(in)::   kt   ! ocean time step
133      !
134      !!----------------------------------------------------------------------
135
136      !                                         ! ========================== !
137      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN      !    At each sbc time-step   !
138         !                                      ! ===========+++============ !
139         !
140         IF( kt /= nit000 )   ssh_ibb(:,:) = ssh_ib(:,:)    !* Swap of ssh_ib fields
141         !
142         CALL fld_read( kt, nn_fsbc, sf_apr )               !* input Patm provided at kt + nn_fsbc/2
143         !
144         !                                                  !* update the reference atmospheric pressure (if necessary)
145         IF( ln_ref_apr )   rn_pref = glob_sum( 'sbcapr', sf_apr(1)%fnow(:,:,1) * e1e2t(:,:) ) / tarea
146         !
147         !                                                  !* Patm related forcing at kt
148         ssh_ib(:,:) = - ( sf_apr(1)%fnow(:,:,1) - rn_pref ) * r1_grau    ! equivalent ssh (inverse barometer)
149         apr   (:,:) =     sf_apr(1)%fnow(:,:,1)                        ! atmospheric pressure
150         !
151         CALL iom_put( "ssh_ib", ssh_ib )                   !* output the inverse barometer ssh
152      ENDIF
153
154      !                                         ! ---------------------------------------- !
155      IF( kt == nit000 ) THEN                   !   set the forcing field at nit000 - 1    !
156         !                                      ! ---------------------------------------- !
157         !                                            !* Restart: read in restart file
158         IF( ln_rstart .AND. .NOT.l_1st_euler ) THEN
159            IF(lwp) WRITE(numout,*) 'sbc_apr:   ssh_ibb read in the restart file'
160            CALL iom_get( numror, jpdom_auto, 'ssh_ibb', ssh_ibb )   ! before inv. barometer ssh
161            !
162         ELSE                                         !* no restart: set from nit000 values
163            IF(lwp) WRITE(numout,*) 'sbc_apr:   ssh_ibb set to nit000 values'
164            ssh_ibb(:,:) = ssh_ib(:,:)
165         ENDIF
166      ENDIF
167      !                                         ! ---------------------------------------- !
168      IF( lrst_oce ) THEN                       !      Write in the ocean restart file     !
169         !                                      ! ---------------------------------------- !
170         IF(lwp) WRITE(numout,*)
171         IF(lwp) WRITE(numout,*) 'sbc_apr : ssh_ib written in ocean restart file at it= ', kt,' date= ', ndastp
172         IF(lwp) WRITE(numout,*) '~~~~'
173         CALL iom_rstput( kt, nitrst, numrow, 'ssh_ibb' , ssh_ib )
174      ENDIF
175      !
176   END SUBROUTINE sbc_apr
177
178   !!======================================================================
179END MODULE sbcapr
Note: See TracBrowser for help on using the repository browser.