Context Navigation

← Previous Revision
Next Revision →
Blame
Revision Log

icethd.F90

Last change on this file was 15813, checked in by clem, 13 months ago
SI3: change heat budget to avoid supercooling. The rest: cosmetics
Property svn:keywords set to `Id`
File size: 36.3 KB

Line
1	MODULE icethd
2	!!======================================================================
3	!! * MODULE icethd *
4	!! sea-ice : master routine for thermodynamics
5	!!======================================================================
6	!! History : 1.0 ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) original code 1D
7	!! 4.0 ! 2018 (many people) SI3 [aka Sea Ice cube]
8	!!----------------------------------------------------------------------
9	#if defined key_si3
10	!!----------------------------------------------------------------------
11	!! 'key_si3' SI3 sea-ice model
12	!!----------------------------------------------------------------------
13	!! ice_thd : thermodynamics of sea ice
14	!! ice_thd_init : initialisation of sea-ice thermodynamics
15	!!----------------------------------------------------------------------
16	USE phycst ! physical constants
17	USE dom_oce ! ocean space and time domain variables
18	USE ice ! sea-ice: variables
19	!!gm list trop longue ==>>> why not passage en argument d'appel ?
20	USE sbc_oce , ONLY : sss_m, sst_m, e3t_m, utau, vtau, ssu_m, ssv_m, frq_m, sprecip, ln_cpl
21	USE sbc_ice , ONLY : qsr_oce, qns_oce, qemp_oce, qsr_ice, qns_ice, dqns_ice, evap_ice, qprec_ice, qevap_ice, &
22	& qml_ice, qcn_ice, qtr_ice_top
23	USE ice1D ! sea-ice: thermodynamics variables
24	USE icethd_zdf ! sea-ice: vertical heat diffusion
25	USE icethd_dh ! sea-ice: ice-snow growth and melt
26	USE icethd_da ! sea-ice: lateral melting
27	USE icethd_sal ! sea-ice: salinity
28	USE icethd_ent ! sea-ice: enthalpy redistribution
29	USE icethd_do ! sea-ice: growth in open water
30	USE icethd_pnd ! sea-ice: melt ponds
31	USE iceitd ! sea-ice: remapping thickness distribution
32	USE icecor ! sea-ice: corrections
33	USE icetab ! sea-ice: 1D <==> 2D transformation
34	USE icevar ! sea-ice: operations
35	USE icectl ! sea-ice: control print
36	!
37	USE in_out_manager ! I/O manager
38	USE iom ! I/O manager library
39	USE lib_mpp ! MPP library
40	USE lib_fortran ! fortran utilities (glob_sum + no signed zero)
41	USE lbclnk ! lateral boundary conditions (or mpp links)
42	USE timing ! Timing
43
44	IMPLICIT NONE
45	PRIVATE
46
47	PUBLIC ice_thd ! called by limstp module
48	PUBLIC ice_thd_init ! called by ice_init
49
50	!! namelist (namthd)
51	LOGICAL :: ln_icedH ! activate ice thickness change from growing/melting (T) or not (F)
52	LOGICAL :: ln_icedA ! activate lateral melting param. (T) or not (F)
53	LOGICAL :: ln_icedO ! activate ice growth in open-water (T) or not (F)
54	LOGICAL :: ln_icedS ! activate gravity drainage and flushing (T) or not (F)
55	LOGICAL :: ln_leadhfx ! heat in the leads is used to melt sea-ice before warming the ocean
56
57	!! for convergence tests
58	REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: ztice_cvgerr, ztice_cvgstp
59
60	!! * Substitutions
61	# include "vectopt_loop_substitute.h90"
62	!!----------------------------------------------------------------------
63	!! NEMO/ICE 4.0 , NEMO Consortium (2018)
64	!! $Id$
65	!! Software governed by the CeCILL license (see ./LICENSE)
66	!!----------------------------------------------------------------------
67	CONTAINS
68
69	SUBROUTINE ice_thd( kt )
70	!!-------------------------------------------------------------------
71	!! * ROUTINE ice_thd *
72	!!
73	!! ** Purpose : This routine manages ice thermodynamics
74	!!
75	!! ** Action : - computation of oceanic sensible heat flux at the ice base
76	!! energy budget in the leads
77	!! net fluxes on top of ice and of ocean
78	!! - selection of grid cells with ice
79	!! - call ice_thd_zdf for vertical heat diffusion
80	!! - call ice_thd_dh for vertical ice growth and melt
81	!! - call ice_thd_pnd for melt ponds
82	!! - call ice_thd_ent for enthalpy remapping
83	!! - call ice_thd_sal for ice desalination
84	!! - call ice_thd_temp to retrieve temperature from ice enthalpy
85	!! - call ice_thd_mono for extra lateral ice melt if active virtual thickness distribution
86	!! - call ice_thd_da for lateral ice melt
87	!! - back to the geographic grid
88	!! - call ice_thd_rem for remapping thickness distribution
89	!! - call ice_thd_do for ice growth in leads
90	!!-------------------------------------------------------------------
91	INTEGER, INTENT(in) :: kt ! number of iteration
92	!
93	INTEGER :: ji, jj, jk, jl ! dummy loop indices
94	REAL(wp) :: zfric_u, zqld, zqfr, zqfr_neg, zqfr_pos
95	REAL(wp), PARAMETER :: zfric_umin = 0._wp ! lower bound for the friction velocity (cice value=5.e-04)
96	REAL(wp), PARAMETER :: zch = 0.0057_wp ! heat transfer coefficient
97	REAL(wp), DIMENSION(jpi,jpj) :: zu_io, zv_io, zfric, zvel ! ice-ocean velocity (m/s) and frictional velocity (m2/s2)
98	!
99	!!-------------------------------------------------------------------
100	! controls
101	IF( ln_timing ) CALL timing_start('icethd') ! timing
102	IF( ln_icediachk ) CALL ice_cons_hsm(0, 'icethd', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation
103	IF( ln_icediachk ) CALL ice_cons2D (0, 'icethd', diag_v, diag_s, diag_t, diag_fv, diag_fs, diag_ft) ! conservation
104
105	IF( kt == nit000 .AND. lwp ) THEN
106	WRITE(numout,*)
107	WRITE(numout,*) 'ice_thd: sea-ice thermodynamics'
108	WRITE(numout,*) '~~~~~~~'
109	ENDIF
110
111	! convergence tests
112	IF( ln_zdf_chkcvg ) THEN
113	ALLOCATE( ztice_cvgerr(jpi,jpj,jpl) , ztice_cvgstp(jpi,jpj,jpl) )
114	ztice_cvgerr = 0._wp ; ztice_cvgstp = 0._wp
115	ENDIF
116
117	!---------------------------------------------!
118	! computation of friction velocity at T points
119	!---------------------------------------------!
120	IF( ln_icedyn ) THEN
121	zu_io(:,:) = u_ice(:,:) - ssu_m(:,:)
122	zv_io(:,:) = v_ice(:,:) - ssv_m(:,:)
123	DO jj = 2, jpjm1
124	DO ji = fs_2, fs_jpim1
125	zfric(ji,jj) = rn_cio * ( 0.5_wp * &
126	& ( zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj) &
127	& + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1) ) ) * tmask(ji,jj,1)
128	zvel(ji,jj) = 0.5_wp * SQRT( ( u_ice(ji-1,jj) + u_ice(ji,jj) ) * ( u_ice(ji-1,jj) + u_ice(ji,jj) ) + &
129	& ( v_ice(ji,jj-1) + v_ice(ji,jj) ) * ( v_ice(ji,jj-1) + v_ice(ji,jj) ) )
130	END DO
131	END DO
132	ELSE ! if no ice dynamics => transfer directly the atmospheric stress to the ocean
133	DO jj = 2, jpjm1
134	DO ji = fs_2, fs_jpim1
135	zfric(ji,jj) = r1_rau0 * SQRT( 0.5_wp * &
136	& ( utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj) &
137	& + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) ) ) * tmask(ji,jj,1)
138	zvel(ji,jj) = 0._wp
139	END DO
140	END DO
141	ENDIF
142	CALL lbc_lnk_multi( 'icethd', zfric, 'T', 1._wp, zvel, 'T', 1._wp )
143	!
144	!--------------------------------------------------------------------!
145	! Partial computation of forcing for the thermodynamic sea ice model
146	!--------------------------------------------------------------------!
147	DO jj = 1, jpj
148	DO ji = 1, jpi
149	rswitch = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
150	!
151	! --- Energy received in the lead from atm-oce exchanges, zqld is defined everywhere (J.m-2) --- !
152	zqld = tmask(ji,jj,1) * rdt_ice * &
153	& ( ( 1._wp - at_i_b(ji,jj) ) * qsr_oce(ji,jj) * frq_m(ji,jj) + &
154	& ( 1._wp - at_i_b(ji,jj) ) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
155
156	! --- Energy needed to bring ocean surface layer until its freezing, zqfr is defined everywhere (J.m-2) --- !
157	! (mostly<0 but >0 if supercooling)
158	zqfr = rau0 * rcp * e3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) ) * tmask(ji,jj,1) ! both < 0 (t_bo < sst) and > 0 (t_bo > sst)
159	zqfr_neg = MIN( zqfr , 0._wp ) ! only < 0
160	zqfr_pos = MAX( zqfr , 0._wp ) ! only > 0
161
162	! --- Sensible ocean-to-ice heat flux (W/m2) --- !
163	! (mostly>0 but <0 if supercooling)
164	zfric_u = MAX( SQRT( zfric(ji,jj) ), zfric_umin )
165	qsb_ice_bot(ji,jj) = rswitch * rau0 * rcp * zch * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) )
166
167	! upper bound for qsb_ice_bot: the heat retrieved from the ocean must be smaller than the heat necessary to reach
168	! the freezing point, so that we do not have SST < T_freeze
169	! This implies: qsb_ice_bot(ji,jj) * at_i(ji,jj) * rtdice <= - zqfr_neg
170	! The following formulation is ok for both normal conditions and supercooling
171	qsb_ice_bot(ji,jj) = rswitch * MIN( qsb_ice_bot(ji,jj), - zqfr_neg * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
172
173	! If conditions are always supercooled (such as at the mouth of ice-shelves), then ice grows continuously
174	! ==> stop ice formation by artificially setting up the turbulent fluxes to 0 when volume > 20m (arbitrary)
175	IF( ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) ) > 0._wp .AND. vt_i(ji,jj) >= 20._wp ) THEN
176	zqfr = 0._wp
177	zqfr_pos = 0._wp
178	qsb_ice_bot(ji,jj) = 0._wp
179	ENDIF
180	!
181	! --- Energy Budget of the leads (qlead, J.m-2) --- !
182	! qlead is the energy received from the atm. in the leads.
183	! If warming (zqld >= 0), then the energy in the leads is used to melt ice (bottom melting) => fhld (W/m2)
184	! If cooling (zqld < 0), then the energy in the leads is used to grow ice in open water => qlead (J.m-2)
185	IF( ( zqld - zqfr ) < 0._wp .OR. at_i(ji,jj) < epsi10 ) THEN
186	fhld (ji,jj) = 0._wp
187	! upper bound for qlead: qlead should be equal to zqld
188	! but before using this heat for ice formation, we suppose that the ocean cools down till the freezing point.
189	! The energy for this cooling down is zqfr and freezing point is reached if zqfr = zqld
190	! so the max heat that can be pulled out of the ocean is zqld - zqfr
191	! The following formulation is ok for both normal conditions and supercooling
192	qlead(ji,jj) = MIN( 0._wp , zqld - zqfr )
193	ELSE
194	! upper bound for fhld: fhld should be equal to zqld
195	! but we have to make sure that this heat will not make the sst drop below the freezing point
196	! so the max heat that can be pulled out of the ocean is zqld - zqfr_pos
197	! The following formulation is ok for both normal conditions and supercooling
198	fhld (ji,jj) = rswitch * MAX( 0._wp, ( zqld - zqfr_pos ) * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ) ! divided by at_i since this is (re)multiplied by a_i in icethd_dh.F90
199	qlead(ji,jj) = 0._wp
200	ENDIF
201	!
202	! If ice is landfast and ice concentration reaches its max
203	! => stop ice formation in open water
204	IF( zvel(ji,jj) <= 5.e-04_wp .AND. at_i(ji,jj) >= rn_amax_2d(ji,jj)-epsi06 ) qlead(ji,jj) = 0._wp
205	!
206	! If the grid cell is almost fully covered by ice (no leads)
207	! => stop ice formation in open water
208	IF( at_i(ji,jj) >= (1._wp - epsi10) ) qlead(ji,jj) = 0._wp
209	!
210	! If ln_leadhfx is false
211	! => do not use energy of the leads to melt sea-ice
212	IF( .NOT.ln_leadhfx ) fhld(ji,jj) = 0._wp
213	!
214	END DO
215	END DO
216
217	! In case we bypass open-water ice formation
218	IF( .NOT. ln_icedO ) qlead(:,:) = 0._wp
219	! In case we bypass growing/melting from top and bottom
220	IF( .NOT. ln_icedH ) THEN
221	qsb_ice_bot(:,:) = 0._wp
222	fhld (:,:) = 0._wp
223	ENDIF
224
225	!-------------------------------------------------------------------------------------------!
226	! Thermodynamic computation (only on grid points covered by ice) => loop over ice categories
227	!-------------------------------------------------------------------------------------------!
228	DO jl = 1, jpl
229
230	! select ice covered grid points
231	npti = 0 ; nptidx(:) = 0
232	DO jj = 1, jpj
233	DO ji = 1, jpi
234	IF ( a_i(ji,jj,jl) > epsi10 ) THEN
235	npti = npti + 1
236	nptidx(npti) = (jj - 1) * jpi + ji
237	ENDIF
238	END DO
239	END DO
240
241	IF( npti > 0 ) THEN ! If there is no ice, do nothing.
242	!
243	CALL ice_thd_1d2d( jl, 1 ) ! --- Move to 1D arrays --- !
244	! ! --- & Change units of e_i, e_s from J/m2 to J/m3 --- !
245	!
246	s_i_new (1:npti) = 0._wp ; dh_s_tot(1:npti) = 0._wp ! --- some init --- ! (important to have them here)
247	dh_i_sum (1:npti) = 0._wp ; dh_i_bom(1:npti) = 0._wp ; dh_i_itm (1:npti) = 0._wp
248	dh_i_sub (1:npti) = 0._wp ; dh_i_bog(1:npti) = 0._wp
249	dh_snowice(1:npti) = 0._wp ; dh_s_mlt(1:npti) = 0._wp
250	!
251	CALL ice_thd_zdf ! --- Ice-Snow temperature --- !
252	!
253	IF( ln_icedH ) THEN ! --- Growing/Melting --- !
254	CALL ice_thd_dh ! Ice-Snow thickness
255	CALL ice_thd_ent( e_i_1d(1:npti,:) ) ! Ice enthalpy remapping
256	ENDIF
257	CALL ice_thd_sal( ln_icedS ) ! --- Ice salinity --- !
258	!
259	CALL ice_thd_temp ! --- Temperature update --- !
260	!
261	IF( ln_icedH .AND. ln_virtual_itd ) &
262	& CALL ice_thd_mono ! --- Extra lateral melting if virtual_itd --- !
263	!
264	IF( ln_icedA ) CALL ice_thd_da ! --- Lateral melting --- !
265	!
266	IF( ln_pnd .AND. ln_icedH ) &
267	& CALL ice_thd_pnd ! --- Melt ponds formation --- !
268	!
269	CALL ice_thd_1d2d( jl, 2 ) ! --- Change units of e_i, e_s from J/m3 to J/m2 --- !
270	! ! --- & Move to 2D arrays --- !
271	ENDIF
272	!
273	END DO
274	!
275	IF( ln_icediachk ) CALL ice_cons_hsm(1, 'icethd', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft)
276	IF( ln_icediachk ) CALL ice_cons2D (1, 'icethd', diag_v, diag_s, diag_t, diag_fv, diag_fs, diag_ft)
277	!
278	IF( jpl > 1 ) CALL ice_itd_rem( kt ) ! --- Transport ice between thickness categories --- !
279	!
280	IF( ln_icedO ) CALL ice_thd_do ! --- Frazil ice growth in leads --- !
281	!
282	CALL ice_cor( kt , 2 ) ! --- Corrections --- !
283	!
284	oa_i(:,:,:) = oa_i(:,:,:) + a_i(:,:,:) * rdt_ice ! ice natural aging incrementation
285	!
286	! convergence tests
287	IF( ln_zdf_chkcvg ) THEN
288	CALL iom_put( 'tice_cvgerr', ztice_cvgerr ) ; DEALLOCATE( ztice_cvgerr )
289	CALL iom_put( 'tice_cvgstp', ztice_cvgstp ) ; DEALLOCATE( ztice_cvgstp )
290	ENDIF
291	!
292	! controls
293	IF( ln_icectl ) CALL ice_prt (kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ') ! prints
294	IF( ln_ctl ) CALL ice_prt3D ('icethd') ! prints
295	IF( ln_timing ) CALL timing_stop('icethd') ! timing
296	!
297	END SUBROUTINE ice_thd
298
299
300	SUBROUTINE ice_thd_temp
301	!!-----------------------------------------------------------------------
302	!! * ROUTINE ice_thd_temp *
303	!!
304	!! ** Purpose : Computes sea ice temperature (Kelvin) from enthalpy
305	!!
306	!! ** Method : Formula (Bitz and Lipscomb, 1999)
307	!!-------------------------------------------------------------------
308	INTEGER :: ji, jk ! dummy loop indices
309	REAL(wp) :: ztmelts, zbbb, zccc ! local scalar
310	!!-------------------------------------------------------------------
311	! Recover ice temperature
312	DO jk = 1, nlay_i
313	DO ji = 1, npti
314	ztmelts = -rTmlt * sz_i_1d(ji,jk)
315	! Conversion q(S,T) -> T (second order equation)
316	zbbb = ( rcp - rcpi ) * ztmelts + e_i_1d(ji,jk) * r1_rhoi - rLfus
317	zccc = SQRT( MAX( zbbb * zbbb - 4._wp * rcpi * rLfus * ztmelts, 0._wp ) )
318	t_i_1d(ji,jk) = rt0 - ( zbbb + zccc ) * 0.5_wp * r1_rcpi
319
320	! mask temperature
321	rswitch = 1._wp - MAX( 0._wp , SIGN( 1._wp , - h_i_1d(ji) ) )
322	t_i_1d(ji,jk) = rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
323	END DO
324	END DO
325	!
326	END SUBROUTINE ice_thd_temp
327
328
329	SUBROUTINE ice_thd_mono
330	!!-----------------------------------------------------------------------
331	!! * ROUTINE ice_thd_mono *
332	!!
333	!! ** Purpose : Lateral melting in case virtual_itd
334	!! ( dA = A/2h dh )
335	!!-----------------------------------------------------------------------
336	INTEGER :: ji ! dummy loop indices
337	REAL(wp) :: zhi_bef ! ice thickness before thermo
338	REAL(wp) :: zdh_mel, zda_mel ! net melting
339	REAL(wp) :: zvi, zvs ! ice/snow volumes
340	!!-----------------------------------------------------------------------
341	!
342	DO ji = 1, npti
343	zdh_mel = MIN( 0._wp, dh_i_itm(ji) + dh_i_sum(ji) + dh_i_bom(ji) + dh_snowice(ji) + dh_i_sub(ji) )
344	IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp ) THEN
345	zvi = a_i_1d(ji) * h_i_1d(ji)
346	zvs = a_i_1d(ji) * h_s_1d(ji)
347	! lateral melting = concentration change
348	zhi_bef = h_i_1d(ji) - zdh_mel
349	rswitch = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
350	zda_mel = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
351	a_i_1d(ji) = MAX( epsi20, a_i_1d(ji) + zda_mel )
352	! adjust thickness
353	h_i_1d(ji) = zvi / a_i_1d(ji)
354	h_s_1d(ji) = zvs / a_i_1d(ji)
355	! retrieve total concentration
356	at_i_1d(ji) = a_i_1d(ji)
357	END IF
358	END DO
359	!
360	END SUBROUTINE ice_thd_mono
361
362
363	SUBROUTINE ice_thd_1d2d( kl, kn )
364	!!-----------------------------------------------------------------------
365	!! * ROUTINE ice_thd_1d2d *
366	!!
367	!! ** Purpose : move arrays from 1d to 2d and the reverse
368	!!-----------------------------------------------------------------------
369	INTEGER, INTENT(in) :: kl ! index of the ice category
370	INTEGER, INTENT(in) :: kn ! 1= from 2D to 1D ; 2= from 1D to 2D
371	!
372	INTEGER :: jk ! dummy loop indices
373	!!-----------------------------------------------------------------------
374	!
375	SELECT CASE( kn )
376	! !---------------------!
377	CASE( 1 ) !== from 2D to 1D ==!
378	! !---------------------!
379	CALL tab_2d_1d( npti, nptidx(1:npti), at_i_1d(1:npti), at_i )
380	CALL tab_2d_1d( npti, nptidx(1:npti), a_i_1d (1:npti), a_i (:,:,kl) )
381	CALL tab_2d_1d( npti, nptidx(1:npti), h_i_1d (1:npti), h_i (:,:,kl) )
382	CALL tab_2d_1d( npti, nptidx(1:npti), h_s_1d (1:npti), h_s (:,:,kl) )
383	CALL tab_2d_1d( npti, nptidx(1:npti), t_su_1d(1:npti), t_su(:,:,kl) )
384	CALL tab_2d_1d( npti, nptidx(1:npti), s_i_1d (1:npti), s_i (:,:,kl) )
385	DO jk = 1, nlay_s
386	CALL tab_2d_1d( npti, nptidx(1:npti), t_s_1d(1:npti,jk), t_s(:,:,jk,kl) )
387	CALL tab_2d_1d( npti, nptidx(1:npti), e_s_1d(1:npti,jk), e_s(:,:,jk,kl) )
388	END DO
389	DO jk = 1, nlay_i
390	CALL tab_2d_1d( npti, nptidx(1:npti), t_i_1d (1:npti,jk), t_i (:,:,jk,kl) )
391	CALL tab_2d_1d( npti, nptidx(1:npti), e_i_1d (1:npti,jk), e_i (:,:,jk,kl) )
392	CALL tab_2d_1d( npti, nptidx(1:npti), sz_i_1d(1:npti,jk), sz_i(:,:,jk,kl) )
393	END DO
394	CALL tab_2d_1d( npti, nptidx(1:npti), a_ip_1d (1:npti), a_ip (:,:,kl) )
395	CALL tab_2d_1d( npti, nptidx(1:npti), h_ip_1d (1:npti), h_ip (:,:,kl) )
396	CALL tab_2d_1d( npti, nptidx(1:npti), h_il_1d (1:npti), h_il (:,:,kl) )
397	!
398	CALL tab_2d_1d( npti, nptidx(1:npti), qprec_ice_1d (1:npti), qprec_ice )
399	CALL tab_2d_1d( npti, nptidx(1:npti), qsr_ice_1d (1:npti), qsr_ice (:,:,kl) )
400	CALL tab_2d_1d( npti, nptidx(1:npti), qns_ice_1d (1:npti), qns_ice (:,:,kl) )
401	CALL tab_2d_1d( npti, nptidx(1:npti), evap_ice_1d (1:npti), evap_ice(:,:,kl) )
402	CALL tab_2d_1d( npti, nptidx(1:npti), dqns_ice_1d (1:npti), dqns_ice(:,:,kl) )
403	CALL tab_2d_1d( npti, nptidx(1:npti), t_bo_1d (1:npti), t_bo )
404	CALL tab_2d_1d( npti, nptidx(1:npti), sprecip_1d (1:npti), sprecip )
405	CALL tab_2d_1d( npti, nptidx(1:npti), qsb_ice_bot_1d(1:npti), qsb_ice_bot )
406	CALL tab_2d_1d( npti, nptidx(1:npti), fhld_1d (1:npti), fhld )
407
408	CALL tab_2d_1d( npti, nptidx(1:npti), qml_ice_1d (1:npti), qml_ice (:,:,kl) )
409	CALL tab_2d_1d( npti, nptidx(1:npti), qcn_ice_1d (1:npti), qcn_ice (:,:,kl) )
410	CALL tab_2d_1d( npti, nptidx(1:npti), qtr_ice_top_1d(1:npti), qtr_ice_top(:,:,kl) )
411	!
412	CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sni_1d(1:npti), wfx_snw_sni )
413	CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sum_1d(1:npti), wfx_snw_sum )
414	CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sub_1d (1:npti), wfx_sub )
415	CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sub_1d(1:npti), wfx_snw_sub )
416	CALL tab_2d_1d( npti, nptidx(1:npti), wfx_ice_sub_1d(1:npti), wfx_ice_sub )
417	CALL tab_2d_1d( npti, nptidx(1:npti), wfx_err_sub_1d(1:npti), wfx_err_sub )
418	!
419	CALL tab_2d_1d( npti, nptidx(1:npti), wfx_bog_1d (1:npti), wfx_bog )
420	CALL tab_2d_1d( npti, nptidx(1:npti), wfx_bom_1d (1:npti), wfx_bom )
421	CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sum_1d (1:npti), wfx_sum )
422	CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sni_1d (1:npti), wfx_sni )
423	CALL tab_2d_1d( npti, nptidx(1:npti), wfx_res_1d (1:npti), wfx_res )
424	CALL tab_2d_1d( npti, nptidx(1:npti), wfx_spr_1d (1:npti), wfx_spr )
425	CALL tab_2d_1d( npti, nptidx(1:npti), wfx_lam_1d (1:npti), wfx_lam )
426	CALL tab_2d_1d( npti, nptidx(1:npti), wfx_pnd_1d (1:npti), wfx_pnd )
427	!
428	CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bog_1d (1:npti), sfx_bog )
429	CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bom_1d (1:npti), sfx_bom )
430	CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sum_1d (1:npti), sfx_sum )
431	CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sni_1d (1:npti), sfx_sni )
432	CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bri_1d (1:npti), sfx_bri )
433	CALL tab_2d_1d( npti, nptidx(1:npti), sfx_res_1d (1:npti), sfx_res )
434	CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sub_1d (1:npti), sfx_sub )
435	CALL tab_2d_1d( npti, nptidx(1:npti), sfx_lam_1d (1:npti), sfx_lam )
436	!
437	CALL tab_2d_1d( npti, nptidx(1:npti), hfx_thd_1d (1:npti), hfx_thd )
438	CALL tab_2d_1d( npti, nptidx(1:npti), hfx_spr_1d (1:npti), hfx_spr )
439	CALL tab_2d_1d( npti, nptidx(1:npti), hfx_sum_1d (1:npti), hfx_sum )
440	CALL tab_2d_1d( npti, nptidx(1:npti), hfx_bom_1d (1:npti), hfx_bom )
441	CALL tab_2d_1d( npti, nptidx(1:npti), hfx_bog_1d (1:npti), hfx_bog )
442	CALL tab_2d_1d( npti, nptidx(1:npti), hfx_dif_1d (1:npti), hfx_dif )
443	CALL tab_2d_1d( npti, nptidx(1:npti), hfx_opw_1d (1:npti), hfx_opw )
444	CALL tab_2d_1d( npti, nptidx(1:npti), hfx_snw_1d (1:npti), hfx_snw )
445	CALL tab_2d_1d( npti, nptidx(1:npti), hfx_sub_1d (1:npti), hfx_sub )
446	CALL tab_2d_1d( npti, nptidx(1:npti), hfx_res_1d (1:npti), hfx_res )
447	CALL tab_2d_1d( npti, nptidx(1:npti), hfx_err_dif_1d(1:npti), hfx_err_dif )
448	!
449	! ocean surface fields
450	CALL tab_2d_1d( npti, nptidx(1:npti), sst_1d(1:npti), sst_m )
451	CALL tab_2d_1d( npti, nptidx(1:npti), sss_1d(1:npti), sss_m )
452	CALL tab_2d_1d( npti, nptidx(1:npti), frq_m_1d(1:npti), frq_m )
453	!
454	! to update ice age
455	CALL tab_2d_1d( npti, nptidx(1:npti), o_i_1d (1:npti), o_i (:,:,kl) )
456	CALL tab_2d_1d( npti, nptidx(1:npti), oa_i_1d(1:npti), oa_i(:,:,kl) )
457	!
458	! --- Change units of e_i, e_s from J/m2 to J/m3 --- !
459	DO jk = 1, nlay_i
460	WHERE( h_i_1d(1:npti)>0._wp ) e_i_1d(1:npti,jk) = e_i_1d(1:npti,jk) / (h_i_1d(1:npti) * a_i_1d(1:npti)) * nlay_i
461	END DO
462	DO jk = 1, nlay_s
463	WHERE( h_s_1d(1:npti)>0._wp ) e_s_1d(1:npti,jk) = e_s_1d(1:npti,jk) / (h_s_1d(1:npti) * a_i_1d(1:npti)) * nlay_s
464	END DO
465	!
466	! !---------------------!
467	CASE( 2 ) !== from 1D to 2D ==!
468	! !---------------------!
469	! --- Change units of e_i, e_s from J/m3 to J/m2 --- !
470	DO jk = 1, nlay_i
471	e_i_1d(1:npti,jk) = e_i_1d(1:npti,jk) * h_i_1d(1:npti) * a_i_1d(1:npti) * r1_nlay_i
472	END DO
473	DO jk = 1, nlay_s
474	e_s_1d(1:npti,jk) = e_s_1d(1:npti,jk) * h_s_1d(1:npti) * a_i_1d(1:npti) * r1_nlay_s
475	END DO
476	!
477	! Change thickness to volume (replaces routine ice_var_eqv2glo)
478	v_i_1d (1:npti) = h_i_1d (1:npti) * a_i_1d (1:npti)
479	v_s_1d (1:npti) = h_s_1d (1:npti) * a_i_1d (1:npti)
480	sv_i_1d(1:npti) = s_i_1d (1:npti) * v_i_1d (1:npti)
481	v_ip_1d(1:npti) = h_ip_1d(1:npti) * a_ip_1d(1:npti)
482	v_il_1d(1:npti) = h_il_1d(1:npti) * a_ip_1d(1:npti)
483	oa_i_1d(1:npti) = o_i_1d (1:npti) * a_i_1d (1:npti)
484
485	CALL tab_1d_2d( npti, nptidx(1:npti), at_i_1d(1:npti), at_i )
486	CALL tab_1d_2d( npti, nptidx(1:npti), a_i_1d (1:npti), a_i (:,:,kl) )
487	CALL tab_1d_2d( npti, nptidx(1:npti), h_i_1d (1:npti), h_i (:,:,kl) )
488	CALL tab_1d_2d( npti, nptidx(1:npti), h_s_1d (1:npti), h_s (:,:,kl) )
489	CALL tab_1d_2d( npti, nptidx(1:npti), t_su_1d(1:npti), t_su(:,:,kl) )
490	CALL tab_1d_2d( npti, nptidx(1:npti), s_i_1d (1:npti), s_i (:,:,kl) )
491	DO jk = 1, nlay_s
492	CALL tab_1d_2d( npti, nptidx(1:npti), t_s_1d(1:npti,jk), t_s(:,:,jk,kl) )
493	CALL tab_1d_2d( npti, nptidx(1:npti), e_s_1d(1:npti,jk), e_s(:,:,jk,kl) )
494	END DO
495	DO jk = 1, nlay_i
496	CALL tab_1d_2d( npti, nptidx(1:npti), t_i_1d (1:npti,jk), t_i (:,:,jk,kl) )
497	CALL tab_1d_2d( npti, nptidx(1:npti), e_i_1d (1:npti,jk), e_i (:,:,jk,kl) )
498	CALL tab_1d_2d( npti, nptidx(1:npti), sz_i_1d(1:npti,jk), sz_i(:,:,jk,kl) )
499	END DO
500	CALL tab_1d_2d( npti, nptidx(1:npti), a_ip_1d (1:npti), a_ip (:,:,kl) )
501	CALL tab_1d_2d( npti, nptidx(1:npti), h_ip_1d (1:npti), h_ip (:,:,kl) )
502	CALL tab_1d_2d( npti, nptidx(1:npti), h_il_1d (1:npti), h_il (:,:,kl) )
503	!
504	CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sni_1d(1:npti), wfx_snw_sni )
505	CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sum_1d(1:npti), wfx_snw_sum )
506	CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sub_1d (1:npti), wfx_sub )
507	CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sub_1d(1:npti), wfx_snw_sub )
508	CALL tab_1d_2d( npti, nptidx(1:npti), wfx_ice_sub_1d(1:npti), wfx_ice_sub )
509	CALL tab_1d_2d( npti, nptidx(1:npti), wfx_err_sub_1d(1:npti), wfx_err_sub )
510	!
511	CALL tab_1d_2d( npti, nptidx(1:npti), wfx_bog_1d (1:npti), wfx_bog )
512	CALL tab_1d_2d( npti, nptidx(1:npti), wfx_bom_1d (1:npti), wfx_bom )
513	CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sum_1d (1:npti), wfx_sum )
514	CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sni_1d (1:npti), wfx_sni )
515	CALL tab_1d_2d( npti, nptidx(1:npti), wfx_res_1d (1:npti), wfx_res )
516	CALL tab_1d_2d( npti, nptidx(1:npti), wfx_spr_1d (1:npti), wfx_spr )
517	CALL tab_1d_2d( npti, nptidx(1:npti), wfx_lam_1d (1:npti), wfx_lam )
518	CALL tab_1d_2d( npti, nptidx(1:npti), wfx_pnd_1d (1:npti), wfx_pnd )
519	!
520	CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bog_1d (1:npti), sfx_bog )
521	CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bom_1d (1:npti), sfx_bom )
522	CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sum_1d (1:npti), sfx_sum )
523	CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sni_1d (1:npti), sfx_sni )
524	CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bri_1d (1:npti), sfx_bri )
525	CALL tab_1d_2d( npti, nptidx(1:npti), sfx_res_1d (1:npti), sfx_res )
526	CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sub_1d (1:npti), sfx_sub )
527	CALL tab_1d_2d( npti, nptidx(1:npti), sfx_lam_1d (1:npti), sfx_lam )
528	!
529	CALL tab_1d_2d( npti, nptidx(1:npti), hfx_thd_1d (1:npti), hfx_thd )
530	CALL tab_1d_2d( npti, nptidx(1:npti), hfx_spr_1d (1:npti), hfx_spr )
531	CALL tab_1d_2d( npti, nptidx(1:npti), hfx_sum_1d (1:npti), hfx_sum )
532	CALL tab_1d_2d( npti, nptidx(1:npti), hfx_bom_1d (1:npti), hfx_bom )
533	CALL tab_1d_2d( npti, nptidx(1:npti), hfx_bog_1d (1:npti), hfx_bog )
534	CALL tab_1d_2d( npti, nptidx(1:npti), hfx_dif_1d (1:npti), hfx_dif )
535	CALL tab_1d_2d( npti, nptidx(1:npti), hfx_opw_1d (1:npti), hfx_opw )
536	CALL tab_1d_2d( npti, nptidx(1:npti), hfx_snw_1d (1:npti), hfx_snw )
537	CALL tab_1d_2d( npti, nptidx(1:npti), hfx_sub_1d (1:npti), hfx_sub )
538	CALL tab_1d_2d( npti, nptidx(1:npti), hfx_res_1d (1:npti), hfx_res )
539	CALL tab_1d_2d( npti, nptidx(1:npti), hfx_err_dif_1d(1:npti), hfx_err_dif )
540	!
541	CALL tab_1d_2d( npti, nptidx(1:npti), qns_ice_1d (1:npti), qns_ice (:,:,kl) )
542	CALL tab_1d_2d( npti, nptidx(1:npti), qtr_ice_bot_1d(1:npti), qtr_ice_bot(:,:,kl) )
543	! effective conductivity and 1st layer temperature (ln_cndflx=T)
544	CALL tab_1d_2d( npti, nptidx(1:npti), cnd_ice_1d(1:npti), cnd_ice(:,:,kl) )
545	CALL tab_1d_2d( npti, nptidx(1:npti), t1_ice_1d (1:npti), t1_ice (:,:,kl) )
546	! SIMIP diagnostics
547	CALL tab_1d_2d( npti, nptidx(1:npti), t_si_1d (1:npti), t_si (:,:,kl) )
548	CALL tab_1d_2d( npti, nptidx(1:npti), qcn_ice_bot_1d(1:npti), qcn_ice_bot(:,:,kl) )
549	CALL tab_1d_2d( npti, nptidx(1:npti), qcn_ice_top_1d(1:npti), qcn_ice_top(:,:,kl) )
550	CALL tab_1d_2d( npti, nptidx(1:npti), qml_ice_1d (1:npti), qml_ice (:,:,kl) )
551	! extensive variables
552	CALL tab_1d_2d( npti, nptidx(1:npti), v_i_1d (1:npti), v_i (:,:,kl) )
553	CALL tab_1d_2d( npti, nptidx(1:npti), v_s_1d (1:npti), v_s (:,:,kl) )
554	CALL tab_1d_2d( npti, nptidx(1:npti), sv_i_1d(1:npti), sv_i(:,:,kl) )
555	CALL tab_1d_2d( npti, nptidx(1:npti), v_ip_1d(1:npti), v_ip(:,:,kl) )
556	CALL tab_1d_2d( npti, nptidx(1:npti), v_il_1d(1:npti), v_il(:,:,kl) )
557	CALL tab_1d_2d( npti, nptidx(1:npti), oa_i_1d(1:npti), oa_i(:,:,kl) )
558	! check convergence of heat diffusion scheme
559	IF( ln_zdf_chkcvg ) THEN
560	CALL tab_1d_2d( npti, nptidx(1:npti), tice_cvgerr_1d(1:npti), ztice_cvgerr(:,:,kl) )
561	CALL tab_1d_2d( npti, nptidx(1:npti), tice_cvgstp_1d(1:npti), ztice_cvgstp(:,:,kl) )
562	ENDIF
563	!
564	END SELECT
565	!
566	END SUBROUTINE ice_thd_1d2d
567
568
569	SUBROUTINE ice_thd_init
570	!!-------------------------------------------------------------------
571	!! * ROUTINE ice_thd_init *
572	!!
573	!! ** Purpose : Physical constants and parameters associated with
574	!! ice thermodynamics
575	!!
576	!! ** Method : Read the namthd namelist and check the parameters
577	!! called at the first timestep (nit000)
578	!!
579	!! ** input : Namelist namthd
580	!!-------------------------------------------------------------------
581	INTEGER :: ios ! Local integer output status for namelist read
582	!!
583	NAMELIST/namthd/ ln_icedH, ln_icedA, ln_icedO, ln_icedS, ln_leadhfx
584	!!-------------------------------------------------------------------
585	!
586	REWIND( numnam_ice_ref ) ! Namelist namthd in reference namelist : Ice thermodynamics
587	READ ( numnam_ice_ref, namthd, IOSTAT = ios, ERR = 901)
588	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namthd in reference namelist' )
589	REWIND( numnam_ice_cfg ) ! Namelist namthd in configuration namelist : Ice thermodynamics
590	READ ( numnam_ice_cfg, namthd, IOSTAT = ios, ERR = 902 )
591	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namthd in configuration namelist' )
592	IF(lwm) WRITE( numoni, namthd )
593	!
594	IF(lwp) THEN ! control print
595	WRITE(numout,*)
596	WRITE(numout,*) 'ice_thd_init: Ice Thermodynamics'
597	WRITE(numout,*) '~~~~~~~~~~~~'
598	WRITE(numout,*) ' Namelist namthd:'
599	WRITE(numout,*) ' activate ice thick change from top/bot (T) or not (F) ln_icedH = ', ln_icedH
600	WRITE(numout,*) ' activate lateral melting (T) or not (F) ln_icedA = ', ln_icedA
601	WRITE(numout,*) ' activate ice growth in open-water (T) or not (F) ln_icedO = ', ln_icedO
602	WRITE(numout,*) ' activate gravity drainage and flushing (T) or not (F) ln_icedS = ', ln_icedS
603	WRITE(numout,*) ' heat in the leads is used to melt sea-ice before warming the ocean ln_leadhfx = ', ln_leadhfx
604	ENDIF
605	!
606	CALL ice_thd_zdf_init ! set ice heat diffusion parameters
607	IF( ln_icedA ) CALL ice_thd_da_init ! set ice lateral melting parameters
608	IF( ln_icedO ) CALL ice_thd_do_init ! set ice growth in open water parameters
609	CALL ice_thd_sal_init ! set ice salinity parameters
610	CALL ice_thd_pnd_init ! set melt ponds parameters
611	!
612	END SUBROUTINE ice_thd_init
613
614	#else
615	!!----------------------------------------------------------------------
616	!! Default option Dummy module NO SI3 sea-ice model
617	!!----------------------------------------------------------------------
618	#endif
619
620	!!======================================================================
621	END MODULE icethd

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: NEMO/releases/r4.0/r4.0-HEAD/src/ICE/icethd.F90

Download in other formats: