New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcfwb.F90 in NEMO/releases/r4.0/r4.0-HEAD/src/OCE/SBC – NEMO

source: NEMO/releases/r4.0/r4.0-HEAD/src/OCE/SBC/sbcfwb.F90

Last change on this file was 15438, checked in by clem, 3 years ago

4.0-HEAD: freshwater budget is now corrected for option nn_fwb=2. The option could be improved. There is a drift the 1st year and the correction applied can lead to oscillations in the solution. It is related to tickets #2718 and part of #2487 though the fix is somewhat different than proposed in the tickets.
  • Property svn:keywords set to Id
File size: 14.8 KB
Line 
1MODULE sbcfwb
2   !!======================================================================
3   !!                       ***  MODULE  sbcfwb  ***
4   !! Ocean fluxes   : domain averaged freshwater budget
5   !!======================================================================
6   !! History :  OPA  ! 2001-02  (E. Durand)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-08  (G. Madec)  Surface module
9   !!            3.2  ! 2009-07  (C. Talandier) emp mean s spread over erp area
10   !!            3.6  ! 2014-11  (P. Mathiot  ) add ice shelf melting
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_fwb       : freshwater budget for global ocean configurations (free surface & forced mode)
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and tracers
17   USE dom_oce        ! ocean space and time domain
18   USE sbc_oce        ! surface ocean boundary condition
19   USE sbc_ice , ONLY : snwice_mass, snwice_mass_b, snwice_fmass
20   USE phycst         ! physical constants
21   USE sbcrnf         ! ocean runoffs
22   USE sbcisf         ! ice shelf melting contribution
23   USE sbcssr         ! Sea-Surface damping terms
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            ! IOM
27   USE lib_mpp        ! distribued memory computing library
28   USE timing         ! Timing
29   USE lbclnk         ! ocean lateral boundary conditions
30   USE lib_fortran    !
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   sbc_fwb    ! routine called by step
36
37   REAL(wp) ::   a_fwb     ! annual domain averaged freshwater budget from the previous year
38   REAL(wp) ::   a_fwb_b   ! annual domain averaged freshwater budget from the year before or at initial state
39   REAL(wp) ::   a_fwb_ini ! initial domain averaged freshwater budget
40   REAL(wp) ::   area      ! global mean ocean surface (interior domain)
41
42   !! * Substitutions
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
46   !! $Id$
47   !! Software governed by the CeCILL license (see ./LICENSE)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc )
52      !!---------------------------------------------------------------------
53      !!                  ***  ROUTINE sbc_fwb  ***
54      !!
55      !! ** Purpose :   Control the mean sea surface drift
56      !!
57      !! ** Method  :   several ways  depending on kn_fwb
58      !!                =0 no control
59      !!                =1 global mean of emp set to zero at each nn_fsbc time step
60      !!                =2 annual global mean corrected from previous year
61      !!                =3 global mean of emp set to zero at each nn_fsbc time step
62      !!                   & spread out over erp area depending its sign
63      !! Note: if sea ice is embedded it is taken into account when computing the budget
64      !!----------------------------------------------------------------------
65      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
66      INTEGER, INTENT( in ) ::   kn_fsbc  !
67      INTEGER, INTENT( in ) ::   kn_fwb   ! ocean time-step index
68      !
69      INTEGER  ::   inum, ikty, iyear     ! local integers
70      REAL(wp) ::   z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp                ! local scalars
71      REAL(wp) ::   zsurf_neg, zsurf_pos, zsurf_tospread, zcoef          !   -      -
72      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztmsk_neg, ztmsk_pos, z_wgt ! 2D workspaces
73      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztmsk_tospread, zerp_cor    !   -      -
74      REAL(wp)   ,DIMENSION(1) ::   z_fwfprv 
75      COMPLEX(wp),DIMENSION(1) ::   y_fwfnow 
76      !!----------------------------------------------------------------------
77      !
78      IF( kt == nit000 ) THEN
79         IF(lwp) THEN
80            WRITE(numout,*)
81            WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction'
82            WRITE(numout,*) '~~~~~~~'
83            IF( kn_fwb == 1 )   WRITE(numout,*) '          instantaneously set to zero'
84            IF( kn_fwb == 2 )   WRITE(numout,*) '          adjusted from previous year budget'
85            IF( kn_fwb == 3 )   WRITE(numout,*) '          fwf set to zero and spread out over erp area'
86         ENDIF
87         !
88         IF( kn_fwb == 3 .AND. nn_sssr /= 2 )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' )
89         IF( kn_fwb == 3 .AND. ln_isfcav    )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 with ln_isfcav = .TRUE. not working, we stop ' )
90         !
91         area = glob_sum( 'sbcfwb', e1e2t(:,:) * tmask(:,:,1))           ! interior global domain surface
92         ! isf cavities are excluded because it can feedback to the melting with generation of inhibition of plumes
93         ! and in case of no melt, it can generate HSSW.
94         !
95#if ! defined key_si3 && ! defined key_cice
96         snwice_mass_b(:,:) = 0.e0               ! no sea-ice model is being used : no snow+ice mass
97         snwice_mass  (:,:) = 0.e0
98         snwice_fmass (:,:) = 0.e0
99#endif
100         !
101      ENDIF
102
103      SELECT CASE ( kn_fwb )
104      !
105      CASE ( 1 )                             !==  global mean fwf set to zero  ==!
106         !
107         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
108            y_fwfnow(1) = local_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf(:,:) - snwice_fmass(:,:) ) )
109            CALL mpp_delay_sum( 'sbcfwb', 'fwb', y_fwfnow(:), z_fwfprv(:), kt == nitend - nn_fsbc + 1 )
110            z_fwfprv(1) = z_fwfprv(1) / area
111            zcoef = z_fwfprv(1) * rcp
112            emp(:,:) = emp(:,:) - z_fwfprv(1)        * tmask(:,:,1)
113            qns(:,:) = qns(:,:) + zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
114            ! outputs
115            IF( iom_use('hflx_fwb_cea') )  CALL iom_put( 'hflx_fwb_cea', zcoef * sst_m(:,:) * tmask(:,:,1) )
116            IF( iom_use('vflx_fwb_cea') )  CALL iom_put( 'vflx_fwb_cea', z_fwfprv(1)        * tmask(:,:,1) )
117         ENDIF
118         !
119      CASE ( 2 )                             !==  fw adjustment based on fw budget at the end of the previous year  ==!
120         !                                                simulation is supposed to start 1st of January
121         IF( kt == nit000 ) THEN                                                                 ! initialisation
122            !                                                                                    ! set the fw adjustment (a_fwb)
123            IF ( ln_rstart .AND. iom_varid( numror, 'a_fwb_b', ldstop = .FALSE. ) > 0     &      !    as read from restart file
124               &           .AND. iom_varid( numror, 'a_fwb',   ldstop = .FALSE. ) > 0 ) THEN
125               IF(lwp)   WRITE(numout,*) 'sbc_fwb : reading freshwater-budget from restart file'
126               CALL iom_get( numror, 'a_fwb_b', a_fwb_b, ldxios = lrxios )
127               CALL iom_get( numror, 'a_fwb',   a_fwb,   ldxios = lrxios )
128               !
129               a_fwb_ini = a_fwb_b
130            ELSE                                                                                 !    as read from EMPave_old.dat file
131               IF(lwp)   WRITE(numout,*) 'sbc_fwb : reading freshwater-budget from EMPave_old.dat file'
132               CALL ctl_opn( inum, 'EMPave_old.dat', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. )
133               READ ( inum, "(24X,I8,2ES24.16)" ) iyear, a_fwb_b, a_fwb
134               CLOSE( inum )
135               !
136               a_fwb_ini = glob_sum( 'sbcfwb', e1e2t(:,:) * ( sshn(:,:) + snwice_mass(:,:) * r1_rau0 ) ) &
137                  &      * rau0 / ( area * rday * REAL(nyear_len(1), wp) )
138            END IF
139            !
140            IF(lwp)   WRITE(numout,*)
141            IF(lwp)   WRITE(numout,*)'sbc_fwb : freshwater-budget at the end of previous year = ', a_fwb    , 'kg/m2/s'
142            IF(lwp)   WRITE(numout,*)'          freshwater-budget at initial state            = ', a_fwb_ini, 'kg/m2/s'
143            !
144            IF( lwxios ) THEN                         ! Activate output of restart variables
145               CALL iom_set_rstw_var_active( 'a_fwb_b' )
146               CALL iom_set_rstw_var_active( 'a_fwb'   )
147            END IF
148            !
149         ELSE
150            ! at the end of year n:
151            ikty = nyear_len(1) * 86400 / NINT(rdt)
152            IF( MOD( kt, ikty ) == 0 ) THEN   ! Update a_fwb at the last time step of a year
153               !                                It should be the first time step of a year MOD(kt-1,ikty) but then the restart would be wrong
154               !                                Hence, we make a small error here but the code is restartable
155               a_fwb_b = a_fwb_ini
156               ! mean sea level taking into account ice+snow
157               a_fwb   = glob_sum( 'sbcfwb', e1e2t(:,:) * ( sshn(:,:) + snwice_mass(:,:) * r1_rau0 ) )
158               a_fwb   = a_fwb * rau0 / ( area * rday * REAL(nyear_len(1), wp) )   ! convert in kg/m2/s
159            ENDIF
160            !
161         ENDIF
162         !
163         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN         ! correct the freshwater fluxes using previous year budget
164            zcoef = ( a_fwb - a_fwb_b )
165            emp(:,:) = emp(:,:) + zcoef * tmask(:,:,1)
166            qns(:,:) = qns(:,:) - zcoef * rcp * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
167            ! outputs
168            IF( iom_use('hflx_fwb_cea') )  CALL iom_put( 'hflx_fwb_cea', -zcoef * rcp * sst_m(:,:) * tmask(:,:,1) )
169            IF( iom_use('vflx_fwb_cea') )  CALL iom_put( 'vflx_fwb_cea', -zcoef * tmask(:,:,1) )
170         ENDIF
171         ! Output restart information
172         IF( lrst_oce ) THEN
173            IF(lwp) WRITE(numout,*)
174            IF(lwp) WRITE(numout,*) 'sbc_fwb : writing FW-budget adjustment to ocean restart file at it = ', kt
175            IF(lwp) WRITE(numout,*) '~~~~'
176            IF( lwxios ) CALL iom_swap( cwxios_context )
177            CALL iom_rstput( kt, nitrst, numrow, 'a_fwb_b', a_fwb_b, ldxios = lwxios )
178            CALL iom_rstput( kt, nitrst, numrow, 'a_fwb',   a_fwb,   ldxios = lwxios )
179            IF( lwxios ) CALL iom_swap( cxios_context  )
180         END IF
181         !
182         IF( kt == nitend .AND. lwm ) THEN            ! save a_fwb value in a file (only one required)
183            CALL ctl_opn( inum, 'EMPave.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea )
184            WRITE( inum, "(24X,I8,2ES24.16)" ) nyear, a_fwb_b, a_fwb
185            CLOSE( inum )
186         ENDIF
187         !
188         IF( kt == nitend .AND. lwp ) THEN
189            WRITE(numout,*) 'sbc_fwb : freshwater-budget at the end of simulation (year now) = ', a_fwb  , 'kg/m2/s'
190            WRITE(numout,*) '          freshwater-budget at initial state                    = ', a_fwb_b, 'kg/m2/s'
191         ENDIF
192         !
193      CASE ( 3 )                             !==  global fwf set to zero and spread out over erp area  ==!
194         !
195         ALLOCATE( ztmsk_neg(jpi,jpj) , ztmsk_pos(jpi,jpj) , ztmsk_tospread(jpi,jpj) , z_wgt(jpi,jpj) , zerp_cor(jpi,jpj) )
196         !
197         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
198            ztmsk_pos(:,:) = tmask_i(:,:)                      ! Select <0 and >0 area of erp
199            WHERE( erp < 0._wp )   ztmsk_pos = 0._wp
200            ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:)
201            !                                                  ! fwf global mean (excluding ocean to ice/snow exchanges)
202            z_fwf     = glob_sum( 'sbcfwb', e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf(:,:) - snwice_fmass(:,:) ) ) / area
203            !           
204            IF( z_fwf < 0._wp ) THEN         ! spread out over >0 erp area to increase evaporation
205               zsurf_pos = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_pos(:,:) )
206               zsurf_tospread      = zsurf_pos
207               ztmsk_tospread(:,:) = ztmsk_pos(:,:)
208            ELSE                             ! spread out over <0 erp area to increase precipitation
209               zsurf_neg = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_neg(:,:) )  ! Area filled by <0 and >0 erp
210               zsurf_tospread      = zsurf_neg
211               ztmsk_tospread(:,:) = ztmsk_neg(:,:)
212            ENDIF
213            !
214            zsum_fwf   = glob_sum( 'sbcfwb', e1e2t(:,:) * z_fwf )         ! fwf global mean over <0 or >0 erp area
215!!gm :  zsum_fwf   = z_fwf * area   ???  it is right?  I think so....
216            z_fwf_nsrf =  zsum_fwf / ( zsurf_tospread + rsmall )
217            !                                                  ! weight to respect erp field 2D structure
218            zsum_erp   = glob_sum( 'sbcfwb', ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) )
219            z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall )
220            !                                                  ! final correction term to apply
221            zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:)
222            !
223!!gm   ===>>>>  lbc_lnk should be useless as all the computation is done over the whole domain !
224            CALL lbc_lnk( 'sbcfwb', zerp_cor, 'T', 1. )
225            !
226            emp(:,:) = emp(:,:) + zerp_cor(:,:)
227            qns(:,:) = qns(:,:) - zerp_cor(:,:) * rcp * sst_m(:,:)  ! account for change to the heat budget due to fw correction
228            erp(:,:) = erp(:,:) + zerp_cor(:,:)
229            ! outputs
230            IF( iom_use('hflx_fwb_cea') )  CALL iom_put( 'hflx_fwb_cea', -zerp_cor(:,:) * rcp * sst_m(:,:) )
231            IF( iom_use('vflx_fwb_cea') )  CALL iom_put( 'vflx_fwb_cea', -zerp_cor(:,:) )
232            !
233            IF( nprint == 1 .AND. lwp ) THEN                   ! control print
234               IF( z_fwf < 0._wp ) THEN
235                  WRITE(numout,*)'   z_fwf < 0'
236                  WRITE(numout,*)'   SUM(erp+)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
237               ELSE
238                  WRITE(numout,*)'   z_fwf >= 0'
239                  WRITE(numout,*)'   SUM(erp-)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
240               ENDIF
241               WRITE(numout,*)'   SUM(empG)     = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv'
242               WRITE(numout,*)'   z_fwf         = ', z_fwf      ,' Kg/m2/s'
243               WRITE(numout,*)'   z_fwf_nsrf    = ', z_fwf_nsrf ,' Kg/m2/s'
244               WRITE(numout,*)'   MIN(zerp_cor) = ', MINVAL(zerp_cor) 
245               WRITE(numout,*)'   MAX(zerp_cor) = ', MAXVAL(zerp_cor) 
246            ENDIF
247         ENDIF
248         DEALLOCATE( ztmsk_neg , ztmsk_pos , ztmsk_tospread , z_wgt , zerp_cor )
249         !
250      CASE DEFAULT                           !==  you should never be there  ==!
251         CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' )
252         !
253      END SELECT
254      !
255   END SUBROUTINE sbc_fwb
256
257   !!======================================================================
258END MODULE sbcfwb
Note: See TracBrowser for help on using the repository browser.