| 1 | MODULE sbcssr |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcssr *** |
|---|
| 4 | !! Surface module : heat and fresh water fluxes a restoring term toward observed SST/SSS |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.0 ! 2006-06 (G. Madec) Original code |
|---|
| 7 | !! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put |
|---|
| 8 | !!---------------------------------------------------------------------- |
|---|
| 9 | |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | !! sbc_ssr : add to sbc a restoring term toward SST/SSS climatology |
|---|
| 12 | !! sbc_ssr_init : initialisation of surface restoring |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | USE oce ! ocean dynamics and tracers |
|---|
| 15 | USE dom_oce ! ocean space and time domain |
|---|
| 16 | USE sbc_oce ! surface boundary condition |
|---|
| 17 | USE phycst ! physical constants |
|---|
| 18 | USE sbcrnf ! surface boundary condition : runoffs |
|---|
| 19 | ! |
|---|
| 20 | USE fldread ! read input fields |
|---|
| 21 | USE in_out_manager ! I/O manager |
|---|
| 22 | USE iom ! I/O manager |
|---|
| 23 | USE lib_mpp ! distribued memory computing library |
|---|
| 24 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 25 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 26 | |
|---|
| 27 | IMPLICIT NONE |
|---|
| 28 | PRIVATE |
|---|
| 29 | |
|---|
| 30 | PUBLIC sbc_ssr ! routine called in sbcmod |
|---|
| 31 | PUBLIC sbc_ssr_init ! routine called in sbcmod |
|---|
| 32 | PUBLIC sbc_ssr_alloc ! routine called in sbcmod |
|---|
| 33 | |
|---|
| 34 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: erp !: evaporation damping [kg/m2/s] |
|---|
| 35 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: qrp !: heat flux damping [w/m2] |
|---|
| 36 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: coefice !: under ice relaxation coefficient |
|---|
| 37 | |
|---|
| 38 | ! !!* Namelist namsbc_ssr * |
|---|
| 39 | INTEGER, PUBLIC :: nn_sstr ! SST/SSS restoring indicator |
|---|
| 40 | INTEGER, PUBLIC :: nn_sssr ! SST/SSS restoring indicator |
|---|
| 41 | REAL(wp) :: rn_dqdt ! restoring factor on SST and SSS |
|---|
| 42 | REAL(wp) :: rn_deds ! restoring factor on SST and SSS |
|---|
| 43 | LOGICAL :: ln_sssr_bnd ! flag to bound erp term |
|---|
| 44 | REAL(wp) :: rn_sssr_bnd ! ABS(Max./Min.) value of erp term [mm/day] |
|---|
| 45 | INTEGER :: nn_sssr_ice ! Control of restoring under ice |
|---|
| 46 | |
|---|
| 47 | REAL(wp) , ALLOCATABLE, DIMENSION(:) :: buffer ! Temporary buffer for exchange |
|---|
| 48 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_sst ! structure of input SST (file informations, fields read) |
|---|
| 49 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_sss ! structure of input SSS (file informations, fields read) |
|---|
| 50 | |
|---|
| 51 | !!---------------------------------------------------------------------- |
|---|
| 52 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 53 | !! $Id$ |
|---|
| 54 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 55 | !!---------------------------------------------------------------------- |
|---|
| 56 | CONTAINS |
|---|
| 57 | |
|---|
| 58 | SUBROUTINE sbc_ssr( kt ) |
|---|
| 59 | !!--------------------------------------------------------------------- |
|---|
| 60 | !! *** ROUTINE sbc_ssr *** |
|---|
| 61 | !! |
|---|
| 62 | !! ** Purpose : Add to heat and/or freshwater fluxes a damping term |
|---|
| 63 | !! toward observed SST and/or SSS. |
|---|
| 64 | !! |
|---|
| 65 | !! ** Method : - Read namelist namsbc_ssr |
|---|
| 66 | !! - Read observed SST and/or SSS |
|---|
| 67 | !! - at each nscb time step |
|---|
| 68 | !! add a retroaction term on qns (nn_sstr = 1) |
|---|
| 69 | !! add a damping term on sfx (nn_sssr = 1) |
|---|
| 70 | !! add a damping term on emp (nn_sssr = 2) |
|---|
| 71 | !!--------------------------------------------------------------------- |
|---|
| 72 | INTEGER, INTENT(in ) :: kt ! ocean time step |
|---|
| 73 | !! |
|---|
| 74 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 75 | REAL(wp) :: zerp ! local scalar for evaporation damping |
|---|
| 76 | REAL(wp) :: zqrp ! local scalar for heat flux damping |
|---|
| 77 | REAL(wp) :: zsrp ! local scalar for unit conversion of rn_deds factor |
|---|
| 78 | REAL(wp) :: zerp_bnd ! local scalar for unit conversion of rn_epr_max factor |
|---|
| 79 | INTEGER :: ierror ! return error code |
|---|
| 80 | !! |
|---|
| 81 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssr files |
|---|
| 82 | TYPE(FLD_N) :: sn_sst, sn_sss ! informations about the fields to be read |
|---|
| 83 | !!---------------------------------------------------------------------- |
|---|
| 84 | ! |
|---|
| 85 | IF( nn_sstr + nn_sssr /= 0 ) THEN |
|---|
| 86 | ! |
|---|
| 87 | IF( nn_sstr == 1) CALL fld_read( kt, nn_fsbc, sf_sst ) ! Read SST data and provides it at kt |
|---|
| 88 | IF( nn_sssr >= 1) CALL fld_read( kt, nn_fsbc, sf_sss ) ! Read SSS data and provides it at kt |
|---|
| 89 | ! |
|---|
| 90 | ! ! ========================= ! |
|---|
| 91 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN ! Add restoring term ! |
|---|
| 92 | ! ! ========================= ! |
|---|
| 93 | qrp(:,:) = 0._wp ! necessary init |
|---|
| 94 | erp(:,:) = 0._wp |
|---|
| 95 | ! |
|---|
| 96 | IF( nn_sstr == 1 ) THEN !* Temperature restoring term |
|---|
| 97 | DO jj = 1, jpj |
|---|
| 98 | DO ji = 1, jpi |
|---|
| 99 | zqrp = rn_dqdt * ( sst_m(ji,jj) - sf_sst(1)%fnow(ji,jj,1) ) * tmask(ji,jj,1) |
|---|
| 100 | qns(ji,jj) = qns(ji,jj) + zqrp |
|---|
| 101 | qrp(ji,jj) = zqrp |
|---|
| 102 | END DO |
|---|
| 103 | END DO |
|---|
| 104 | ENDIF |
|---|
| 105 | ! |
|---|
| 106 | IF( nn_sssr /= 0 .AND. nn_sssr_ice /= 1 ) THEN |
|---|
| 107 | ! use fraction of ice ( fr_i ) to adjust relaxation under ice if nn_sssr_ice .ne. 1 |
|---|
| 108 | ! n.b. coefice is initialised and fixed to 1._wp if nn_sssr_ice = 1 |
|---|
| 109 | DO jj = 1, jpj |
|---|
| 110 | DO ji = 1, jpi |
|---|
| 111 | SELECT CASE ( nn_sssr_ice ) |
|---|
| 112 | CASE ( 0 ) ; coefice(ji,jj) = 1._wp - fr_i(ji,jj) ! no/reduced damping under ice |
|---|
| 113 | CASE DEFAULT ; coefice(ji,jj) = 1._wp + ( nn_sssr_ice - 1 ) * fr_i(ji,jj) ! reinforced damping (x nn_sssr_ice) under ice ) |
|---|
| 114 | END SELECT |
|---|
| 115 | END DO |
|---|
| 116 | END DO |
|---|
| 117 | ENDIF |
|---|
| 118 | ! |
|---|
| 119 | IF( nn_sssr == 1 ) THEN !* Salinity damping term (salt flux only (sfx)) |
|---|
| 120 | zsrp = rn_deds / rday ! from [mm/day] to [kg/m2/s] |
|---|
| 121 | DO jj = 1, jpj |
|---|
| 122 | DO ji = 1, jpi |
|---|
| 123 | zerp = zsrp * ( 1. - 2.*rnfmsk(ji,jj) ) & ! No damping in vicinity of river mouths |
|---|
| 124 | & * coefice(ji,jj) & ! Optional control of damping under sea-ice |
|---|
| 125 | & * ( sss_m(ji,jj) - sf_sss(1)%fnow(ji,jj,1) ) * tmask(ji,jj,1) |
|---|
| 126 | sfx(ji,jj) = sfx(ji,jj) + zerp ! salt flux |
|---|
| 127 | erp(ji,jj) = zerp / MAX( sss_m(ji,jj), 1.e-20 ) ! converted into an equivalent volume flux (diagnostic only) |
|---|
| 128 | END DO |
|---|
| 129 | END DO |
|---|
| 130 | ! |
|---|
| 131 | ELSEIF( nn_sssr == 2 ) THEN !* Salinity damping term (volume flux (emp) and associated heat flux (qns) |
|---|
| 132 | zsrp = rn_deds / rday ! from [mm/day] to [kg/m2/s] |
|---|
| 133 | zerp_bnd = rn_sssr_bnd / rday ! - - |
|---|
| 134 | DO jj = 1, jpj |
|---|
| 135 | DO ji = 1, jpi |
|---|
| 136 | zerp = zsrp * ( 1. - 2.*rnfmsk(ji,jj) ) & ! No damping in vicinity of river mouths |
|---|
| 137 | & * coefice(ji,jj) & ! Optional control of damping under sea-ice |
|---|
| 138 | & * ( sss_m(ji,jj) - sf_sss(1)%fnow(ji,jj,1) ) & |
|---|
| 139 | & / MAX( sss_m(ji,jj), 1.e-20 ) * tmask(ji,jj,1) |
|---|
| 140 | IF( ln_sssr_bnd ) zerp = SIGN( 1., zerp ) * MIN( zerp_bnd, ABS(zerp) ) |
|---|
| 141 | emp(ji,jj) = emp (ji,jj) + zerp |
|---|
| 142 | qns(ji,jj) = qns(ji,jj) - zerp * rcp * sst_m(ji,jj) |
|---|
| 143 | erp(ji,jj) = zerp |
|---|
| 144 | qrp(ji,jj) = qrp(ji,jj) - zerp * rcp * sst_m(ji,jj) |
|---|
| 145 | END DO |
|---|
| 146 | END DO |
|---|
| 147 | ENDIF |
|---|
| 148 | ! |
|---|
| 149 | ! outputs |
|---|
| 150 | CALL iom_put( 'hflx_ssr_cea', qrp(:,:) ) |
|---|
| 151 | IF( nn_sssr == 1 ) CALL iom_put( 'sflx_ssr_cea', erp(:,:) * sss_m(:,:) ) |
|---|
| 152 | IF( nn_sssr == 2 ) CALL iom_put( 'vflx_ssr_cea', -erp(:,:) ) |
|---|
| 153 | ! |
|---|
| 154 | ENDIF |
|---|
| 155 | ! |
|---|
| 156 | ENDIF |
|---|
| 157 | ! |
|---|
| 158 | END SUBROUTINE sbc_ssr |
|---|
| 159 | |
|---|
| 160 | |
|---|
| 161 | SUBROUTINE sbc_ssr_init |
|---|
| 162 | !!--------------------------------------------------------------------- |
|---|
| 163 | !! *** ROUTINE sbc_ssr_init *** |
|---|
| 164 | !! |
|---|
| 165 | !! ** Purpose : initialisation of surface damping term |
|---|
| 166 | !! |
|---|
| 167 | !! ** Method : - Read namelist namsbc_ssr |
|---|
| 168 | !! - Read observed SST and/or SSS if required |
|---|
| 169 | !!--------------------------------------------------------------------- |
|---|
| 170 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 171 | REAL(wp) :: zerp ! local scalar for evaporation damping |
|---|
| 172 | REAL(wp) :: zqrp ! local scalar for heat flux damping |
|---|
| 173 | REAL(wp) :: zsrp ! local scalar for unit conversion of rn_deds factor |
|---|
| 174 | REAL(wp) :: zerp_bnd ! local scalar for unit conversion of rn_epr_max factor |
|---|
| 175 | INTEGER :: ierror ! return error code |
|---|
| 176 | !! |
|---|
| 177 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssr files |
|---|
| 178 | TYPE(FLD_N) :: sn_sst, sn_sss ! informations about the fields to be read |
|---|
| 179 | NAMELIST/namsbc_ssr/ cn_dir, nn_sstr, nn_sssr, rn_dqdt, rn_deds, sn_sst, & |
|---|
| 180 | & sn_sss, ln_sssr_bnd, rn_sssr_bnd, nn_sssr_ice |
|---|
| 181 | INTEGER :: ios |
|---|
| 182 | !!---------------------------------------------------------------------- |
|---|
| 183 | ! |
|---|
| 184 | IF(lwp) THEN |
|---|
| 185 | WRITE(numout,*) |
|---|
| 186 | WRITE(numout,*) 'sbc_ssr : SST and/or SSS damping term ' |
|---|
| 187 | WRITE(numout,*) '~~~~~~~ ' |
|---|
| 188 | ENDIF |
|---|
| 189 | ! |
|---|
| 190 | REWIND( numnam_ref ) ! Namelist namsbc_ssr in reference namelist : |
|---|
| 191 | READ ( numnam_ref, namsbc_ssr, IOSTAT = ios, ERR = 901) |
|---|
| 192 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_ssr in reference namelist' ) |
|---|
| 193 | |
|---|
| 194 | REWIND( numnam_cfg ) ! Namelist namsbc_ssr in configuration namelist : |
|---|
| 195 | READ ( numnam_cfg, namsbc_ssr, IOSTAT = ios, ERR = 902 ) |
|---|
| 196 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namsbc_ssr in configuration namelist' ) |
|---|
| 197 | IF(lwm) WRITE ( numond, namsbc_ssr ) |
|---|
| 198 | |
|---|
| 199 | IF(lwp) THEN !* control print |
|---|
| 200 | WRITE(numout,*) ' Namelist namsbc_ssr :' |
|---|
| 201 | WRITE(numout,*) ' SST restoring term (Yes=1) nn_sstr = ', nn_sstr |
|---|
| 202 | WRITE(numout,*) ' dQ/dT (restoring magnitude on SST) rn_dqdt = ', rn_dqdt, ' W/m2/K' |
|---|
| 203 | WRITE(numout,*) ' SSS damping term (Yes=1, salt flux) nn_sssr = ', nn_sssr |
|---|
| 204 | WRITE(numout,*) ' (Yes=2, volume flux) ' |
|---|
| 205 | WRITE(numout,*) ' dE/dS (restoring magnitude on SST) rn_deds = ', rn_deds, ' mm/day' |
|---|
| 206 | WRITE(numout,*) ' flag to bound erp term ln_sssr_bnd = ', ln_sssr_bnd |
|---|
| 207 | WRITE(numout,*) ' ABS(Max./Min.) erp threshold rn_sssr_bnd = ', rn_sssr_bnd, ' mm/day' |
|---|
| 208 | WRITE(numout,*) ' Cntrl of surface restoration under ice nn_sssr_ice = ', nn_sssr_ice |
|---|
| 209 | WRITE(numout,*) ' ( 0 = no restoration under ice)' |
|---|
| 210 | WRITE(numout,*) ' ( 1 = restoration everywhere )' |
|---|
| 211 | WRITE(numout,*) ' (>1 = enhanced restoration under ice )' |
|---|
| 212 | ENDIF |
|---|
| 213 | ! |
|---|
| 214 | IF( nn_sstr == 1 ) THEN !* set sf_sst structure & allocate arrays |
|---|
| 215 | ! |
|---|
| 216 | ALLOCATE( sf_sst(1), STAT=ierror ) |
|---|
| 217 | IF( ierror > 0 ) CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sst structure' ) |
|---|
| 218 | ALLOCATE( sf_sst(1)%fnow(jpi,jpj,1), STAT=ierror ) |
|---|
| 219 | IF( ierror > 0 ) CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sst now array' ) |
|---|
| 220 | ! |
|---|
| 221 | ! fill sf_sst with sn_sst and control print |
|---|
| 222 | CALL fld_fill( sf_sst, (/ sn_sst /), cn_dir, 'sbc_ssr', 'SST restoring term toward SST data', 'namsbc_ssr', no_print ) |
|---|
| 223 | IF( sf_sst(1)%ln_tint ) ALLOCATE( sf_sst(1)%fdta(jpi,jpj,1,2), STAT=ierror ) |
|---|
| 224 | IF( ierror > 0 ) CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sst data array' ) |
|---|
| 225 | ! |
|---|
| 226 | ENDIF |
|---|
| 227 | ! |
|---|
| 228 | IF( nn_sssr >= 1 ) THEN !* set sf_sss structure & allocate arrays |
|---|
| 229 | ! |
|---|
| 230 | ALLOCATE( sf_sss(1), STAT=ierror ) |
|---|
| 231 | IF( ierror > 0 ) CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sss structure' ) |
|---|
| 232 | ALLOCATE( sf_sss(1)%fnow(jpi,jpj,1), STAT=ierror ) |
|---|
| 233 | IF( ierror > 0 ) CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sss now array' ) |
|---|
| 234 | ! |
|---|
| 235 | ! fill sf_sss with sn_sss and control print |
|---|
| 236 | CALL fld_fill( sf_sss, (/ sn_sss /), cn_dir, 'sbc_ssr', 'SSS restoring term toward SSS data', 'namsbc_ssr', no_print ) |
|---|
| 237 | IF( sf_sss(1)%ln_tint ) ALLOCATE( sf_sss(1)%fdta(jpi,jpj,1,2), STAT=ierror ) |
|---|
| 238 | IF( ierror > 0 ) CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sss data array' ) |
|---|
| 239 | ! |
|---|
| 240 | ENDIF |
|---|
| 241 | ! |
|---|
| 242 | coefice(:,:) = 1._wp ! Initialise coefice to 1._wp ; will not need to be changed if nn_sssr_ice=1 |
|---|
| 243 | ! !* Initialize qrp and erp if no restoring |
|---|
| 244 | IF( nn_sstr /= 1 ) qrp(:,:) = 0._wp |
|---|
| 245 | IF( nn_sssr /= 1 .OR. nn_sssr /= 2 ) erp(:,:) = 0._wp |
|---|
| 246 | ! |
|---|
| 247 | END SUBROUTINE sbc_ssr_init |
|---|
| 248 | |
|---|
| 249 | INTEGER FUNCTION sbc_ssr_alloc() |
|---|
| 250 | !!---------------------------------------------------------------------- |
|---|
| 251 | !! *** FUNCTION sbc_ssr_alloc *** |
|---|
| 252 | !!---------------------------------------------------------------------- |
|---|
| 253 | sbc_ssr_alloc = 0 ! set to zero if no array to be allocated |
|---|
| 254 | IF( .NOT. ALLOCATED( erp ) ) THEN |
|---|
| 255 | ALLOCATE( qrp(jpi,jpj), erp(jpi,jpj), coefice(jpi,jpj), STAT= sbc_ssr_alloc ) |
|---|
| 256 | ! |
|---|
| 257 | IF( lk_mpp ) CALL mpp_sum ( 'sbcssr', sbc_ssr_alloc ) |
|---|
| 258 | IF( sbc_ssr_alloc /= 0 ) CALL ctl_warn('sbc_ssr_alloc: failed to allocate arrays.') |
|---|
| 259 | ! |
|---|
| 260 | ENDIF |
|---|
| 261 | END FUNCTION |
|---|
| 262 | |
|---|
| 263 | !!====================================================================== |
|---|
| 264 | END MODULE sbcssr |
|---|
