New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icesbc.F90 in NEMO/trunk/src/ICE – NEMO

source: NEMO/trunk/src/ICE/icesbc.F90 @ 14433

Last change on this file since 14433 was 14433, checked in by smasson, 3 years ago

trunk: merge dev_r14312_MPI_Interface into the trunk, #2598
  • Property svn:keywords set to Id
File size: 17.8 KB
Line 
1MODULE icesbc
2   !!======================================================================
3   !!                       ***  MODULE  icesbc  ***
4   !! Sea-Ice :   air-ice sbc fields
5   !!=====================================================================
6   !! History :  4.0  !  2017-08  (C. Rousset)       Original code
7   !!            4.0  !  2018     (many people)      SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3' :                                     SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers
14   USE dom_oce        ! ocean space and time domain
15   USE ice            ! sea-ice: variables
16   USE sbc_oce        ! Surface boundary condition: ocean fields
17   USE sbc_ice        ! Surface boundary condition: ice   fields
18   USE usrdef_sbc     ! Surface boundary condition: user defined
19   USE sbcblk         ! Surface boundary condition: bulk
20   USE sbccpl         ! Surface boundary condition: coupled interface
21   USE icealb         ! sea-ice: albedo
22   !
23   USE in_out_manager ! I/O manager
24   USE iom            ! I/O manager library
25   USE lib_mpp        ! MPP library
26   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
27   USE lbclnk         ! lateral boundary conditions (or mpp links)
28   USE timing         ! Timing
29   USE fldread        !!GS: needed by agrif
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC ice_sbc_tau   ! called by icestp.F90
35   PUBLIC ice_sbc_flx   ! called by icestp.F90
36   PUBLIC ice_sbc_init  ! called by icestp.F90
37
38   !! * Substitutions
39#  include "do_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
42   !! $Id$
43   !! Software governed by the CeCILL license (see ./LICENSE)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE ice_sbc_tau( kt, ksbc, utau_ice, vtau_ice )
48      !!-------------------------------------------------------------------
49      !!                  ***  ROUTINE ice_sbc_tau  ***
50      !!
51      !! ** Purpose : provide surface boundary condition for sea ice (momentum)
52      !!
53      !! ** Action  : It provides the following fields:
54      !!              utau_ice, vtau_ice : surface ice stress (U- & V-points) [N/m2]
55      !!-------------------------------------------------------------------
56      INTEGER                     , INTENT(in   ) ::   kt                   ! ocean time step
57      INTEGER                     , INTENT(in   ) ::   ksbc                 ! type of sbc flux
58      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   utau_ice, vtau_ice   ! air-ice stress   [N/m2]
59      !!
60      INTEGER  ::   ji, jj                 ! dummy loop index
61      REAL(wp), DIMENSION(jpi,jpj) ::   zutau_ice, zvtau_ice
62      !!-------------------------------------------------------------------
63      !
64      IF( ln_timing )   CALL timing_start('icesbc')
65      !
66      IF( kt == nit000 .AND. lwp ) THEN
67         WRITE(numout,*)
68         WRITE(numout,*)'ice_sbc_tau: Surface boundary condition for sea ice (momentum)'
69         WRITE(numout,*)'~~~~~~~~~~~~~~~'
70      ENDIF
71      !
72      SELECT CASE( ksbc )
73         CASE( jp_usr     )   ;    CALL usrdef_sbc_ice_tau( kt )                 ! user defined formulation
74      CASE( jp_blk     )
75         CALL blk_ice_1( sf(jp_wndi)%fnow(:,:,1), sf(jp_wndj)%fnow(:,:,1),   &
76            &                                      theta_air_zt(:,:), q_air_zt(:,:),   &   ! #LB: known from "sbc_oce" module...
77            &                                      sf(jp_slp )%fnow(:,:,1), u_ice, v_ice, tm_su    ,   &   ! inputs
78            &                                      putaui = utau_ice, pvtaui = vtau_ice            )       ! outputs
79 !        CASE( jp_abl     )    utau_ice & vtau_ice are computed in ablmod
80         CASE( jp_purecpl )   ;    CALL sbc_cpl_ice_tau( utau_ice , vtau_ice )   ! Coupled      formulation
81      END SELECT
82      !
83      IF( ln_mixcpl) THEN                                                        ! Case of a mixed Bulk/Coupled formulation
84                                   CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
85         DO_2D( 0, 0, 0, 0 )
86            utau_ice(ji,jj) = utau_ice(ji,jj) * xcplmask(ji,jj,0) + zutau_ice(ji,jj) * ( 1. - xcplmask(ji,jj,0) )
87            vtau_ice(ji,jj) = vtau_ice(ji,jj) * xcplmask(ji,jj,0) + zvtau_ice(ji,jj) * ( 1. - xcplmask(ji,jj,0) )
88         END_2D
89         CALL lbc_lnk( 'icesbc', utau_ice, 'U', -1.0_wp, vtau_ice, 'V', -1.0_wp )
90      ENDIF
91      !
92      IF( ln_timing )   CALL timing_stop('icesbc')
93      !
94   END SUBROUTINE ice_sbc_tau
95
96
97   SUBROUTINE ice_sbc_flx( kt, ksbc )
98      !!-------------------------------------------------------------------
99      !!                  ***  ROUTINE ice_sbc_flx  ***
100      !!
101      !! ** Purpose : provide surface boundary condition for sea ice (flux)
102      !!
103      !! ** Action  : It provides the following fields used in sea ice model:
104      !!                emp_oce , emp_ice                        = E-P over ocean and sea ice                    [Kg/m2/s]
105      !!                sprecip                                  = solid precipitation                           [Kg/m2/s]
106      !!                evap_ice                                 = sublimation                                   [Kg/m2/s]
107      !!                qsr_tot , qns_tot                        = solar & non solar heat flux (total)           [W/m2]
108      !!                qsr_ice , qns_ice                        = solar & non solar heat flux over ice          [W/m2]
109      !!                dqns_ice                                 = non solar  heat sensistivity                  [W/m2]
110      !!                qemp_oce, qemp_ice, qprec_ice, qevap_ice = sensible heat (associated with evap & precip) [W/m2]
111      !!            + some fields that are not used outside this module:
112      !!                qla_ice                                  = latent heat flux over ice                     [W/m2]
113      !!                dqla_ice                                 = latent heat sensistivity                      [W/m2]
114      !!                tprecip                                  = total  precipitation                          [Kg/m2/s]
115      !!                alb_ice                                  = albedo above sea ice
116      !!-------------------------------------------------------------------
117      INTEGER, INTENT(in) ::   kt     ! ocean time step
118      INTEGER, INTENT(in) ::   ksbc   ! flux formulation (user defined, bulk or Pure Coupled)
119      !
120      INTEGER  ::   ji, jj, jl      ! dummy loop index
121      REAL(wp) ::   zmiss_val       ! missing value retrieved from xios
122      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zalb, zmsk00      ! 2D workspace
123      !!--------------------------------------------------------------------
124      !
125      IF( ln_timing )   CALL timing_start('icesbc')
126
127      IF( kt == nit000 .AND. lwp ) THEN
128         WRITE(numout,*)
129         WRITE(numout,*)'ice_sbc_flx: Surface boundary condition for sea ice (flux)'
130         WRITE(numout,*)'~~~~~~~~~~~~~~~'
131      ENDIF
132
133      ! get missing value from xml
134      CALL iom_miss_val( "icetemp", zmiss_val )
135
136      ! --- ice albedo --- !
137      CALL ice_alb( t_su, h_i, h_s, ln_pnd_alb, a_ip_eff, h_ip, cloud_fra, alb_ice )
138
139      !
140      SELECT CASE( ksbc )   !== fluxes over sea ice ==!
141      !
142      CASE( jp_usr )              !--- user defined formulation
143                                  CALL usrdef_sbc_ice_flx( kt, h_s, h_i )
144      CASE( jp_blk, jp_abl )  !--- bulk formulation & ABL formulation
145                                  CALL blk_ice_2    ( t_su, h_s, h_i, alb_ice, &
146            &                                         theta_air_zt(:,:), q_air_zt(:,:),    &   ! #LB: known from "sbc_oce" module...
147            &                                         sf(jp_slp)%fnow(:,:,1), sf(jp_qlw)%fnow(:,:,1), &
148            &                                         sf(jp_prec)%fnow(:,:,1), sf(jp_snow)%fnow(:,:,1) )
149         IF( ln_mixcpl        )   CALL sbc_cpl_ice_flx( picefr=at_i_b, palbi=alb_ice, psst=sst_m, pist=t_su, phs=h_s, phi=h_i )
150         IF( nn_flxdist /= -1 )   CALL ice_flx_dist   ( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_flxdist )
151         !                        !    compute conduction flux and surface temperature (as in Jules surface module)
152         IF( ln_cndflx .AND. .NOT.ln_cndemulate ) &
153            &                     CALL blk_ice_qcn    ( ln_virtual_itd, t_su, t_bo, h_s, h_i )
154      CASE ( jp_purecpl )         !--- coupled formulation
155                                  CALL sbc_cpl_ice_flx( picefr=at_i_b, palbi=alb_ice, psst=sst_m, pist=t_su, phs=h_s, phi=h_i )
156         IF( nn_flxdist /= -1 )   CALL ice_flx_dist   ( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_flxdist )
157      END SELECT
158
159      !--- output ice albedo and surface albedo ---!
160      IF( iom_use('icealb') .OR. iom_use('albedo') ) THEN
161
162         ALLOCATE( zalb(jpi,jpj), zmsk00(jpi,jpj) )
163
164         WHERE( at_i_b < 1.e-03 )
165            zmsk00(:,:) = 0._wp
166            zalb  (:,:) = rn_alb_oce
167         ELSEWHERE
168            zmsk00(:,:) = 1._wp
169            zalb  (:,:) = SUM( alb_ice * a_i_b, dim=3 ) / at_i_b
170         END WHERE
171         ! ice albedo
172         CALL iom_put( 'icealb' , zalb * zmsk00 + zmiss_val * ( 1._wp - zmsk00 ) )
173         ! ice+ocean albedo
174         zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) + rn_alb_oce * ( 1._wp - at_i_b )
175         CALL iom_put( 'albedo' , zalb )
176
177         DEALLOCATE( zalb, zmsk00 )
178
179      ENDIF
180      !
181      IF( ln_timing )   CALL timing_stop('icesbc')
182      !
183   END SUBROUTINE ice_sbc_flx
184
185
186   SUBROUTINE ice_flx_dist( ptn_ice, palb_ice, pqns_ice, pqsr_ice, pdqn_ice, pevap_ice, pdevap_ice, k_flxdist )
187      !!-------------------------------------------------------------------
188      !!                  ***  ROUTINE ice_flx_dist  ***
189      !!
190      !! ** Purpose :   update the ice surface boundary condition by averaging
191      !!              and/or redistributing fluxes on ice categories
192      !!
193      !! ** Method  :   average then redistribute
194      !!
195      !! ** Action  :   depends on k_flxdist
196      !!                = -1  Do nothing (needs N(cat) fluxes)
197      !!                =  0  Average N(cat) fluxes then apply the average over the N(cat) ice
198      !!                =  1  Average N(cat) fluxes then redistribute over the N(cat) ice
199      !!                                                 using T-ice and albedo sensitivity
200      !!                =  2  Redistribute a single flux over categories
201      !!-------------------------------------------------------------------
202      INTEGER                   , INTENT(in   ) ::   k_flxdist  ! redistributor
203      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   ptn_ice    ! ice surface temperature
204      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   palb_ice   ! ice albedo
205      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqns_ice   ! non solar flux
206      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqsr_ice   ! net solar flux
207      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdqn_ice   ! non solar flux sensitivity
208      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pevap_ice  ! sublimation
209      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdevap_ice ! sublimation sensitivity
210      !
211      INTEGER  ::   jl      ! dummy loop index
212      !
213      REAL(wp), DIMENSION(jpi,jpj) ::   z1_at_i   ! inverse of concentration
214      !
215      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_qsr_m   ! Mean solar heat flux over all categories
216      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_qns_m   ! Mean non solar heat flux over all categories
217      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_evap_m  ! Mean sublimation over all categories
218      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_dqn_m   ! Mean d(qns)/dT over all categories
219      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_devap_m ! Mean d(evap)/dT over all categories
220      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   zalb_m    ! Mean albedo over all categories
221      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztem_m    ! Mean temperature over all categories
222      !!----------------------------------------------------------------------
223      !
224      WHERE ( at_i (:,:) > 0._wp )   ; z1_at_i(:,:) = 1._wp / at_i (:,:)
225      ELSEWHERE                      ; z1_at_i(:,:) = 0._wp
226      END WHERE
227
228      SELECT CASE( k_flxdist )       !==  averaged on all ice categories  ==!
229      !
230      CASE( 0 , 1 )
231         !
232         ALLOCATE( z_qns_m(jpi,jpj), z_qsr_m(jpi,jpj), z_dqn_m(jpi,jpj), z_evap_m(jpi,jpj), z_devap_m(jpi,jpj) )
233         !
234         z_qns_m  (:,:) = SUM( a_i(:,:,:) * pqns_ice  (:,:,:) , dim=3 ) * z1_at_i(:,:)
235         z_qsr_m  (:,:) = SUM( a_i(:,:,:) * pqsr_ice  (:,:,:) , dim=3 ) * z1_at_i(:,:)
236         z_dqn_m  (:,:) = SUM( a_i(:,:,:) * pdqn_ice  (:,:,:) , dim=3 ) * z1_at_i(:,:)
237         z_evap_m (:,:) = SUM( a_i(:,:,:) * pevap_ice (:,:,:) , dim=3 ) * z1_at_i(:,:)
238         z_devap_m(:,:) = SUM( a_i(:,:,:) * pdevap_ice(:,:,:) , dim=3 ) * z1_at_i(:,:)
239         DO jl = 1, jpl
240            pqns_ice  (:,:,jl) = z_qns_m (:,:)
241            pqsr_ice  (:,:,jl) = z_qsr_m (:,:)
242            pdqn_ice  (:,:,jl) = z_dqn_m  (:,:)
243            pevap_ice (:,:,jl) = z_evap_m(:,:)
244            pdevap_ice(:,:,jl) = z_devap_m(:,:)
245         END DO
246         !
247         DEALLOCATE( z_qns_m, z_qsr_m, z_dqn_m, z_evap_m, z_devap_m )
248         !
249      END SELECT
250      !
251      SELECT CASE( k_flxdist )       !==  redistribution on all ice categories  ==!
252      !
253      CASE( 1 , 2 )
254         !
255         ALLOCATE( zalb_m(jpi,jpj), ztem_m(jpi,jpj) )
256         !
257         zalb_m(:,:) = SUM( a_i(:,:,:) * palb_ice(:,:,:) , dim=3 ) * z1_at_i(:,:)
258         ztem_m(:,:) = SUM( a_i(:,:,:) * ptn_ice (:,:,:) , dim=3 ) * z1_at_i(:,:)
259         DO jl = 1, jpl
260            pqns_ice (:,:,jl) = pqns_ice (:,:,jl) + pdqn_ice  (:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
261            pevap_ice(:,:,jl) = pevap_ice(:,:,jl) + pdevap_ice(:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
262            pqsr_ice (:,:,jl) = pqsr_ice (:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) )
263         END DO
264         !
265         DEALLOCATE( zalb_m, ztem_m )
266         !
267      END SELECT
268      !
269   END SUBROUTINE ice_flx_dist
270
271
272   SUBROUTINE ice_sbc_init
273      !!-------------------------------------------------------------------
274      !!                  ***  ROUTINE ice_sbc_init  ***
275      !!
276      !! ** Purpose :   Physical constants and parameters linked to the ice dynamics
277      !!
278      !! ** Method  :   Read the namsbc namelist and check the ice-dynamic
279      !!              parameter values called at the first timestep (nit000)
280      !!
281      !! ** input   :   Namelist namsbc
282      !!-------------------------------------------------------------------
283      INTEGER ::   ios, ioptio   ! Local integer
284      !!
285      NAMELIST/namsbc/ rn_cio, nn_snwfra, rn_snwblow, nn_flxdist, ln_cndflx, ln_cndemulate, nn_qtrice
286      !!-------------------------------------------------------------------
287      !
288      READ  ( numnam_ice_ref, namsbc, IOSTAT = ios, ERR = 901)
289901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in reference namelist' )
290      READ  ( numnam_ice_cfg, namsbc, IOSTAT = ios, ERR = 902 )
291902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc in configuration namelist' )
292      IF(lwm) WRITE( numoni, namsbc )
293      !
294      IF(lwp) THEN                     ! control print
295         WRITE(numout,*)
296         WRITE(numout,*) 'ice_sbc_init: ice parameters for ice dynamics '
297         WRITE(numout,*) '~~~~~~~~~~~~~~~~'
298         WRITE(numout,*) '   Namelist namsbc:'
299         WRITE(numout,*) '      drag coefficient for oceanic stress                       rn_cio        = ', rn_cio
300         WRITE(numout,*) '      fraction of ice covered by snow (options 0,1,2)           nn_snwfra     = ', nn_snwfra
301         WRITE(numout,*) '      coefficient for ice-lead partition of snowfall            rn_snwblow    = ', rn_snwblow
302         WRITE(numout,*) '      Multicategory heat flux formulation                       nn_flxdist    = ', nn_flxdist
303         WRITE(numout,*) '      Use conduction flux as surface condition                  ln_cndflx     = ', ln_cndflx
304         WRITE(numout,*) '         emulate conduction flux                                ln_cndemulate = ', ln_cndemulate
305         WRITE(numout,*) '      solar flux transmitted thru the surface scattering layer  nn_qtrice     = ', nn_qtrice
306         WRITE(numout,*) '         = 0  Grenfell and Maykut 1977'
307         WRITE(numout,*) '         = 1  Lebrun 2019'
308      ENDIF
309      !
310      IF(lwp) WRITE(numout,*)
311      SELECT CASE( nn_flxdist )         ! SI3 Multi-category heat flux formulation
312      CASE( -1  )
313         IF(lwp) WRITE(numout,*) '   SI3: use per-category fluxes (nn_flxdist = -1) '
314      CASE(  0  )
315         IF(lwp) WRITE(numout,*) '   SI3: use average per-category fluxes (nn_flxdist = 0) '
316      CASE(  1  )
317         IF(lwp) WRITE(numout,*) '   SI3: use average then redistribute per-category fluxes (nn_flxdist = 1) '
318         IF( ln_cpl )         CALL ctl_stop( 'ice_thd_init: the chosen nn_flxdist for SI3 in coupled mode must be /=1' )
319      CASE(  2  )
320         IF(lwp) WRITE(numout,*) '   SI3: Redistribute a single flux over categories (nn_flxdist = 2) '
321         IF( .NOT. ln_cpl )   CALL ctl_stop( 'ice_thd_init: the chosen nn_flxdist for SI3 in forced mode must be /=2' )
322      CASE DEFAULT
323         CALL ctl_stop( 'ice_thd_init: SI3 option, nn_flxdist, should be between -1 and 2' )
324      END SELECT
325      !
326   END SUBROUTINE ice_sbc_init
327
328#else
329   !!----------------------------------------------------------------------
330   !!   Default option :         Empty module         NO SI3 sea-ice model
331   !!----------------------------------------------------------------------
332#endif
333
334   !!======================================================================
335END MODULE icesbc
Note: See TracBrowser for help on using the repository browser.