1 | MODULE icethd_do |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE icethd_do *** |
---|
4 | !! sea-ice: sea ice growth in the leads (open water) |
---|
5 | !!====================================================================== |
---|
6 | !! History : ! 2005-12 (M. Vancoppenolle) Original code |
---|
7 | !! 4.0 ! 2018 (many people) SI3 [aka Sea Ice cube] |
---|
8 | !!---------------------------------------------------------------------- |
---|
9 | #if defined key_si3 |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | !! 'key_si3' SI3 sea-ice model |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! ice_thd_do : ice growth in open water (=lateral accretion of ice) |
---|
14 | !! ice_thd_do_init : initialization |
---|
15 | !!---------------------------------------------------------------------- |
---|
16 | USE dom_oce ! ocean space and time domain |
---|
17 | USE phycst ! physical constants |
---|
18 | USE sbc_oce , ONLY : sss_m |
---|
19 | USE sbc_ice , ONLY : utau_ice, vtau_ice |
---|
20 | USE ice1D ! sea-ice: thermodynamics variables |
---|
21 | USE ice ! sea-ice: variables |
---|
22 | USE icetab ! sea-ice: 2D <==> 1D |
---|
23 | USE icectl ! sea-ice: conservation |
---|
24 | USE icethd_ent ! sea-ice: thermodynamics, enthalpy |
---|
25 | USE icevar ! sea-ice: operations |
---|
26 | USE icethd_sal ! sea-ice: salinity profiles |
---|
27 | ! |
---|
28 | USE in_out_manager ! I/O manager |
---|
29 | USE lib_mpp ! MPP library |
---|
30 | USE lib_fortran ! fortran utilities (glob_sum + no signed zero) |
---|
31 | USE lbclnk ! lateral boundary conditions (or mpp links) |
---|
32 | |
---|
33 | IMPLICIT NONE |
---|
34 | PRIVATE |
---|
35 | |
---|
36 | PUBLIC ice_thd_do ! called by ice_thd |
---|
37 | PUBLIC ice_thd_frazil ! called by ice_thd |
---|
38 | PUBLIC ice_thd_do_init ! called by ice_stp |
---|
39 | |
---|
40 | !! * Substitutions |
---|
41 | # include "do_loop_substitute.h90" |
---|
42 | !!---------------------------------------------------------------------- |
---|
43 | !! NEMO/ICE 4.0 , NEMO Consortium (2018) |
---|
44 | !! $Id$ |
---|
45 | !! Software governed by the CeCILL license (see ./LICENSE) |
---|
46 | !!---------------------------------------------------------------------- |
---|
47 | CONTAINS |
---|
48 | |
---|
49 | SUBROUTINE ice_thd_do |
---|
50 | !!------------------------------------------------------------------- |
---|
51 | !! *** ROUTINE ice_thd_do *** |
---|
52 | !! |
---|
53 | !! ** Purpose : Computation of the evolution of the ice thickness and |
---|
54 | !! concentration as a function of the heat balance in the leads |
---|
55 | !! |
---|
56 | !! ** Method : Ice is formed in the open water when ocean looses heat |
---|
57 | !! (heat budget of open water is negative) following |
---|
58 | !! |
---|
59 | !! (dA/dt)acc = F[ (1-A)/(1-a) ] * [ Bl / (Li*h0) ] |
---|
60 | !! where - h0 is the thickness of ice created in the lead |
---|
61 | !! - a is a minimum fraction for leads |
---|
62 | !! - F is a monotonic non-increasing function defined as: |
---|
63 | !! F(X)=( 1 - X**exld )**(1.0/exld) |
---|
64 | !! - exld is the exponent closure rate (=2 default val.) |
---|
65 | !! |
---|
66 | !! ** Action : - Adjustment of snow and ice thicknesses and heat |
---|
67 | !! content in brine pockets |
---|
68 | !! - Updating ice internal temperature |
---|
69 | !! - Computation of variation of ice volume and mass |
---|
70 | !! - Computation of a_i after lateral accretion and |
---|
71 | !! update h_s_1d, h_i_1d |
---|
72 | !!------------------------------------------------------------------------ |
---|
73 | INTEGER :: ji, jj, jk, jl ! dummy loop indices |
---|
74 | ! |
---|
75 | REAL(wp) :: ztmelts |
---|
76 | REAL(wp) :: zdE |
---|
77 | REAL(wp) :: zQm ! enthalpy exchanged with the ocean (J/m2, >0 towards ocean) |
---|
78 | REAL(wp) :: zEi ! sea ice specific enthalpy (J/kg) |
---|
79 | REAL(wp) :: zEw ! seawater specific enthalpy (J/kg) |
---|
80 | REAL(wp) :: zfmdt ! mass flux x time step (kg/m2, >0 towards ocean) |
---|
81 | ! |
---|
82 | REAL(wp) :: zv_newfra |
---|
83 | ! |
---|
84 | INTEGER , DIMENSION(jpij) :: jcat ! indexes of categories where new ice grows |
---|
85 | REAL(wp), DIMENSION(jpij) :: zswinew ! switch for new ice or not |
---|
86 | ! |
---|
87 | REAL(wp), DIMENSION(jpij) :: zv_newice ! volume of accreted ice |
---|
88 | REAL(wp), DIMENSION(jpij) :: za_newice ! fractional area of accreted ice |
---|
89 | REAL(wp), DIMENSION(jpij) :: zh_newice ! thickness of accreted ice |
---|
90 | REAL(wp), DIMENSION(jpij) :: ze_newice ! heat content of accreted ice |
---|
91 | REAL(wp), DIMENSION(jpij) :: zs_newice ! salinity of accreted ice |
---|
92 | REAL(wp), DIMENSION(jpij) :: zo_newice ! age of accreted ice |
---|
93 | REAL(wp), DIMENSION(jpij) :: zdv_res ! residual volume in case of excessive heat budget |
---|
94 | REAL(wp), DIMENSION(jpij) :: zda_res ! residual area in case of excessive heat budget |
---|
95 | REAL(wp), DIMENSION(jpij) :: zv_frazb ! accretion of frazil ice at the ice bottom |
---|
96 | REAL(wp), DIMENSION(jpij) :: zfraz_frac_1d ! relative ice / frazil velocity (1D vector) |
---|
97 | ! |
---|
98 | REAL(wp), DIMENSION(jpij,jpl) :: zv_b ! old volume of ice in category jl |
---|
99 | REAL(wp), DIMENSION(jpij,jpl) :: za_b ! old area of ice in category jl |
---|
100 | ! |
---|
101 | REAL(wp), DIMENSION(jpij,nlay_i,jpl) :: ze_i_2d !: 1-D version of e_i |
---|
102 | ! |
---|
103 | !!-----------------------------------------------------------------------! |
---|
104 | |
---|
105 | IF( ln_icediachk ) CALL ice_cons_hsm( 0, 'icethd_do', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft ) |
---|
106 | IF( ln_icediachk ) CALL ice_cons2D ( 0, 'icethd_do', diag_v, diag_s, diag_t, diag_fv, diag_fs, diag_ft ) |
---|
107 | |
---|
108 | at_i(:,:) = SUM( a_i, dim=3 ) |
---|
109 | !------------------------------------------------------------------------------! |
---|
110 | ! 1) Compute thickness, salinity, enthalpy, age, area and volume of new ice |
---|
111 | !------------------------------------------------------------------------------! |
---|
112 | ! it occurs if cooling |
---|
113 | |
---|
114 | ! Identify grid points where new ice forms |
---|
115 | npti = 0 ; nptidx(:) = 0 |
---|
116 | DO_2D( nn_hls, nn_hls, nn_hls, nn_hls ) |
---|
117 | IF ( qlead(ji,jj) < 0._wp ) THEN |
---|
118 | npti = npti + 1 |
---|
119 | nptidx( npti ) = (jj - 1) * jpi + ji |
---|
120 | ENDIF |
---|
121 | END_2D |
---|
122 | |
---|
123 | ! Move from 2-D to 1-D vectors |
---|
124 | IF ( npti > 0 ) THEN |
---|
125 | |
---|
126 | CALL tab_2d_1d( npti, nptidx(1:npti), at_i_1d(1:npti) , at_i ) |
---|
127 | CALL tab_3d_2d( npti, nptidx(1:npti), a_i_2d (1:npti,1:jpl), a_i (:,:,:) ) |
---|
128 | CALL tab_3d_2d( npti, nptidx(1:npti), v_i_2d (1:npti,1:jpl), v_i (:,:,:) ) |
---|
129 | CALL tab_3d_2d( npti, nptidx(1:npti), sv_i_2d(1:npti,1:jpl), sv_i(:,:,:) ) |
---|
130 | DO jl = 1, jpl |
---|
131 | DO jk = 1, nlay_i |
---|
132 | CALL tab_2d_1d( npti, nptidx(1:npti), ze_i_2d(1:npti,jk,jl), e_i(:,:,jk,jl) ) |
---|
133 | END DO |
---|
134 | END DO |
---|
135 | CALL tab_2d_1d( npti, nptidx(1:npti), qlead_1d (1:npti) , qlead ) |
---|
136 | CALL tab_2d_1d( npti, nptidx(1:npti), t_bo_1d (1:npti) , t_bo ) |
---|
137 | CALL tab_2d_1d( npti, nptidx(1:npti), sfx_opw_1d (1:npti) , sfx_opw ) |
---|
138 | CALL tab_2d_1d( npti, nptidx(1:npti), wfx_opw_1d (1:npti) , wfx_opw ) |
---|
139 | CALL tab_2d_1d( npti, nptidx(1:npti), zh_newice (1:npti) , ht_i_new ) |
---|
140 | CALL tab_2d_1d( npti, nptidx(1:npti), zfraz_frac_1d(1:npti) , fraz_frac ) |
---|
141 | |
---|
142 | CALL tab_2d_1d( npti, nptidx(1:npti), hfx_thd_1d(1:npti) , hfx_thd ) |
---|
143 | CALL tab_2d_1d( npti, nptidx(1:npti), hfx_opw_1d(1:npti) , hfx_opw ) |
---|
144 | CALL tab_2d_1d( npti, nptidx(1:npti), rn_amax_1d(1:npti) , rn_amax_2d ) |
---|
145 | CALL tab_2d_1d( npti, nptidx(1:npti), sss_1d (1:npti) , sss_m ) |
---|
146 | |
---|
147 | ! Convert units for ice internal energy |
---|
148 | DO jl = 1, jpl |
---|
149 | DO jk = 1, nlay_i |
---|
150 | WHERE( v_i_2d(1:npti,jl) > 0._wp ) |
---|
151 | ze_i_2d(1:npti,jk,jl) = ze_i_2d(1:npti,jk,jl) / v_i_2d(1:npti,jl) * REAL( nlay_i ) |
---|
152 | ELSEWHERE |
---|
153 | ze_i_2d(1:npti,jk,jl) = 0._wp |
---|
154 | END WHERE |
---|
155 | END DO |
---|
156 | END DO |
---|
157 | |
---|
158 | ! Keep old ice areas and volume in memory |
---|
159 | zv_b(1:npti,:) = v_i_2d(1:npti,:) |
---|
160 | za_b(1:npti,:) = a_i_2d(1:npti,:) |
---|
161 | |
---|
162 | ! --- Salinity of new ice --- ! |
---|
163 | SELECT CASE ( nn_icesal ) |
---|
164 | CASE ( 1 ) ! Sice = constant |
---|
165 | zs_newice(1:npti) = rn_icesal |
---|
166 | CASE ( 2 ) ! Sice = F(z,t) [Vancoppenolle et al (2005)] |
---|
167 | DO ji = 1, npti |
---|
168 | zs_newice(ji) = MIN( 4.606 + 0.91 / zh_newice(ji) , rn_simax , 0.5 * sss_1d(ji) ) |
---|
169 | END DO |
---|
170 | CASE ( 3 ) ! Sice = F(z) [multiyear ice] |
---|
171 | zs_newice(1:npti) = 2.3 |
---|
172 | END SELECT |
---|
173 | |
---|
174 | ! --- Heat content of new ice --- ! |
---|
175 | ! We assume that new ice is formed at the seawater freezing point |
---|
176 | DO ji = 1, npti |
---|
177 | ztmelts = - rTmlt * zs_newice(ji) ! Melting point (C) |
---|
178 | ze_newice(ji) = rhoi * ( rcpi * ( ztmelts - ( t_bo_1d(ji) - rt0 ) ) & |
---|
179 | & + rLfus * ( 1.0 - ztmelts / MIN( t_bo_1d(ji) - rt0, -epsi10 ) ) & |
---|
180 | & - rcp * ztmelts ) |
---|
181 | END DO |
---|
182 | |
---|
183 | ! --- Age of new ice --- ! |
---|
184 | zo_newice(1:npti) = 0._wp |
---|
185 | |
---|
186 | ! --- Volume of new ice --- ! |
---|
187 | DO ji = 1, npti |
---|
188 | |
---|
189 | zEi = - ze_newice(ji) * r1_rhoi ! specific enthalpy of forming ice [J/kg] |
---|
190 | |
---|
191 | zEw = rcp * ( t_bo_1d(ji) - rt0 ) ! specific enthalpy of seawater at t_bo_1d [J/kg] |
---|
192 | ! clem: we suppose we are already at the freezing point (condition qlead<0 is satisfyied) |
---|
193 | |
---|
194 | zdE = zEi - zEw ! specific enthalpy difference [J/kg] |
---|
195 | |
---|
196 | zfmdt = - qlead_1d(ji) / zdE ! Fm.dt [kg/m2] (<0) |
---|
197 | ! clem: we use qlead instead of zqld (icethd) because we suppose we are at the freezing point |
---|
198 | zv_newice(ji) = - zfmdt * r1_rhoi |
---|
199 | |
---|
200 | zQm = zfmdt * zEw ! heat to the ocean >0 associated with mass flux |
---|
201 | |
---|
202 | ! Contribution to heat flux to the ocean [W.m-2], >0 |
---|
203 | hfx_thd_1d(ji) = hfx_thd_1d(ji) + zfmdt * zEw * r1_Dt_ice |
---|
204 | ! Total heat flux used in this process [W.m-2] |
---|
205 | hfx_opw_1d(ji) = hfx_opw_1d(ji) - zfmdt * zdE * r1_Dt_ice |
---|
206 | ! mass flux |
---|
207 | wfx_opw_1d(ji) = wfx_opw_1d(ji) - zv_newice(ji) * rhoi * r1_Dt_ice |
---|
208 | ! salt flux |
---|
209 | sfx_opw_1d(ji) = sfx_opw_1d(ji) - zv_newice(ji) * rhoi * zs_newice(ji) * r1_Dt_ice |
---|
210 | END DO |
---|
211 | |
---|
212 | ! A fraction fraz_frac of frazil ice is accreted at the ice bottom |
---|
213 | DO ji = 1, npti |
---|
214 | rswitch = 1._wp - MAX( 0._wp, SIGN( 1._wp , - at_i_1d(ji) ) ) |
---|
215 | zv_frazb(ji) = zfraz_frac_1d(ji) * rswitch * zv_newice(ji) |
---|
216 | zv_newice(ji) = ( 1._wp - zfraz_frac_1d(ji) * rswitch ) * zv_newice(ji) |
---|
217 | END DO |
---|
218 | |
---|
219 | ! --- Area of new ice --- ! |
---|
220 | DO ji = 1, npti |
---|
221 | za_newice(ji) = zv_newice(ji) / zh_newice(ji) |
---|
222 | END DO |
---|
223 | |
---|
224 | !------------------------------------------------------------------------------! |
---|
225 | ! 2) Redistribute new ice area and volume into ice categories ! |
---|
226 | !------------------------------------------------------------------------------! |
---|
227 | |
---|
228 | ! --- lateral ice growth --- ! |
---|
229 | ! If lateral ice growth gives an ice concentration > amax, then |
---|
230 | ! we keep the excessive volume in memory and attribute it later to bottom accretion |
---|
231 | DO ji = 1, npti |
---|
232 | IF ( za_newice(ji) > MAX( 0._wp, rn_amax_1d(ji) - at_i_1d(ji) ) ) THEN ! max is for roundoff error |
---|
233 | zda_res(ji) = za_newice(ji) - MAX( 0._wp, rn_amax_1d(ji) - at_i_1d(ji) ) |
---|
234 | zdv_res(ji) = zda_res (ji) * zh_newice(ji) |
---|
235 | za_newice(ji) = MAX( 0._wp, za_newice(ji) - zda_res (ji) ) |
---|
236 | zv_newice(ji) = MAX( 0._wp, zv_newice(ji) - zdv_res (ji) ) |
---|
237 | ELSE |
---|
238 | zda_res(ji) = 0._wp |
---|
239 | zdv_res(ji) = 0._wp |
---|
240 | ENDIF |
---|
241 | END DO |
---|
242 | |
---|
243 | ! find which category to fill |
---|
244 | DO jl = 1, jpl |
---|
245 | DO ji = 1, npti |
---|
246 | IF( zh_newice(ji) > hi_max(jl-1) .AND. zh_newice(ji) <= hi_max(jl) ) THEN |
---|
247 | a_i_2d(ji,jl) = a_i_2d(ji,jl) + za_newice(ji) |
---|
248 | v_i_2d(ji,jl) = v_i_2d(ji,jl) + zv_newice(ji) |
---|
249 | jcat(ji) = jl |
---|
250 | ENDIF |
---|
251 | END DO |
---|
252 | END DO |
---|
253 | at_i_1d(1:npti) = SUM( a_i_2d(1:npti,:), dim=2 ) |
---|
254 | |
---|
255 | ! Heat content |
---|
256 | DO ji = 1, npti |
---|
257 | jl = jcat(ji) ! categroy in which new ice is put |
---|
258 | zswinew (ji) = MAX( 0._wp , SIGN( 1._wp , - za_b(ji,jl) ) ) ! 0 if old ice |
---|
259 | END DO |
---|
260 | |
---|
261 | DO jk = 1, nlay_i |
---|
262 | DO ji = 1, npti |
---|
263 | jl = jcat(ji) |
---|
264 | rswitch = MAX( 0._wp, SIGN( 1._wp , v_i_2d(ji,jl) - epsi20 ) ) |
---|
265 | ze_i_2d(ji,jk,jl) = zswinew(ji) * ze_newice(ji) + & |
---|
266 | & ( 1.0 - zswinew(ji) ) * ( ze_newice(ji) * zv_newice(ji) + ze_i_2d(ji,jk,jl) * zv_b(ji,jl) ) & |
---|
267 | & * rswitch / MAX( v_i_2d(ji,jl), epsi20 ) |
---|
268 | END DO |
---|
269 | END DO |
---|
270 | |
---|
271 | ! --- bottom ice growth + ice enthalpy remapping --- ! |
---|
272 | DO jl = 1, jpl |
---|
273 | |
---|
274 | ! for remapping |
---|
275 | h_i_old (1:npti,0:nlay_i+1) = 0._wp |
---|
276 | eh_i_old(1:npti,0:nlay_i+1) = 0._wp |
---|
277 | DO jk = 1, nlay_i |
---|
278 | DO ji = 1, npti |
---|
279 | h_i_old (ji,jk) = v_i_2d(ji,jl) * r1_nlay_i |
---|
280 | eh_i_old(ji,jk) = ze_i_2d(ji,jk,jl) * h_i_old(ji,jk) |
---|
281 | END DO |
---|
282 | END DO |
---|
283 | |
---|
284 | ! new volumes including lateral/bottom accretion + residual |
---|
285 | DO ji = 1, npti |
---|
286 | rswitch = MAX( 0._wp, SIGN( 1._wp , at_i_1d(ji) - epsi20 ) ) |
---|
287 | zv_newfra = rswitch * ( zdv_res(ji) + zv_frazb(ji) ) * a_i_2d(ji,jl) / MAX( at_i_1d(ji) , epsi20 ) |
---|
288 | a_i_2d(ji,jl) = rswitch * a_i_2d(ji,jl) |
---|
289 | v_i_2d(ji,jl) = v_i_2d(ji,jl) + zv_newfra |
---|
290 | ! for remapping |
---|
291 | h_i_old (ji,nlay_i+1) = zv_newfra |
---|
292 | eh_i_old(ji,nlay_i+1) = ze_newice(ji) * zv_newfra |
---|
293 | END DO |
---|
294 | ! --- Ice enthalpy remapping --- ! |
---|
295 | CALL ice_thd_ent( ze_i_2d(1:npti,:,jl) ) |
---|
296 | END DO |
---|
297 | |
---|
298 | ! --- Update salinity --- ! |
---|
299 | DO jl = 1, jpl |
---|
300 | DO ji = 1, npti |
---|
301 | sv_i_2d(ji,jl) = sv_i_2d(ji,jl) + zs_newice(ji) * ( v_i_2d(ji,jl) - zv_b(ji,jl) ) |
---|
302 | END DO |
---|
303 | END DO |
---|
304 | |
---|
305 | ! Change units for e_i |
---|
306 | DO jl = 1, jpl |
---|
307 | DO jk = 1, nlay_i |
---|
308 | ze_i_2d(1:npti,jk,jl) = ze_i_2d(1:npti,jk,jl) * v_i_2d(1:npti,jl) * r1_nlay_i |
---|
309 | END DO |
---|
310 | END DO |
---|
311 | |
---|
312 | ! Move 2D vectors to 1D vectors |
---|
313 | CALL tab_2d_3d( npti, nptidx(1:npti), a_i_2d (1:npti,1:jpl), a_i (:,:,:) ) |
---|
314 | CALL tab_2d_3d( npti, nptidx(1:npti), v_i_2d (1:npti,1:jpl), v_i (:,:,:) ) |
---|
315 | CALL tab_2d_3d( npti, nptidx(1:npti), sv_i_2d(1:npti,1:jpl), sv_i(:,:,:) ) |
---|
316 | DO jl = 1, jpl |
---|
317 | DO jk = 1, nlay_i |
---|
318 | CALL tab_1d_2d( npti, nptidx(1:npti), ze_i_2d(1:npti,jk,jl), e_i(:,:,jk,jl) ) |
---|
319 | END DO |
---|
320 | END DO |
---|
321 | CALL tab_1d_2d( npti, nptidx(1:npti), sfx_opw_1d(1:npti), sfx_opw ) |
---|
322 | CALL tab_1d_2d( npti, nptidx(1:npti), wfx_opw_1d(1:npti), wfx_opw ) |
---|
323 | CALL tab_1d_2d( npti, nptidx(1:npti), hfx_thd_1d(1:npti), hfx_thd ) |
---|
324 | CALL tab_1d_2d( npti, nptidx(1:npti), hfx_opw_1d(1:npti), hfx_opw ) |
---|
325 | ! |
---|
326 | ENDIF ! npti > 0 |
---|
327 | ! |
---|
328 | IF( ln_icediachk ) CALL ice_cons_hsm(1, 'icethd_do', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) |
---|
329 | IF( ln_icediachk ) CALL ice_cons2D (1, 'icethd_do', diag_v, diag_s, diag_t, diag_fv, diag_fs, diag_ft) |
---|
330 | ! |
---|
331 | END SUBROUTINE ice_thd_do |
---|
332 | |
---|
333 | |
---|
334 | SUBROUTINE ice_thd_frazil |
---|
335 | !!----------------------------------------------------------------------- |
---|
336 | !! *** ROUTINE ice_thd_frazil *** |
---|
337 | !! |
---|
338 | !! ** Purpose : frazil ice collection thickness and fraction |
---|
339 | !! |
---|
340 | !! ** Inputs : u_ice, v_ice, utau_ice, vtau_ice |
---|
341 | !! ** Ouputs : ht_i_new, fraz_frac |
---|
342 | !!----------------------------------------------------------------------- |
---|
343 | INTEGER :: ji, jj ! dummy loop indices |
---|
344 | INTEGER :: iter |
---|
345 | REAL(wp) :: zvfrx, zvgx, ztaux, zf, ztenagm, zvfry, zvgy, ztauy, zvrel2, zfp, ztwogp |
---|
346 | REAL(wp), PARAMETER :: zcai = 1.4e-3_wp ! ice-air drag (clem: should be dependent on coupling/forcing used) |
---|
347 | REAL(wp), PARAMETER :: zhicrit = 0.04_wp ! frazil ice thickness |
---|
348 | REAL(wp), PARAMETER :: zsqcd = 1.0_wp / SQRT( 1.3_wp * zcai ) ! 1/SQRT(airdensity*drag) |
---|
349 | REAL(wp), PARAMETER :: zgamafr = 0.03_wp |
---|
350 | !!----------------------------------------------------------------------- |
---|
351 | ! |
---|
352 | !---------------------------------------------------------! |
---|
353 | ! Collection thickness of ice formed in leads and polynyas |
---|
354 | !---------------------------------------------------------! |
---|
355 | ! ht_i_new is the thickness of new ice formed in open water |
---|
356 | ! ht_i_new can be either prescribed (ln_frazil=F) or computed (ln_frazil=T) |
---|
357 | ! Frazil ice forms in open water, is transported by wind, accumulates at the edge of the consolidated ice edge |
---|
358 | ! where it forms aggregates of a specific thickness called collection thickness. |
---|
359 | ! |
---|
360 | fraz_frac(:,:) = 0._wp |
---|
361 | ! |
---|
362 | ! Default new ice thickness |
---|
363 | WHERE( qlead(:,:) < 0._wp ) ! cooling |
---|
364 | ht_i_new(:,:) = rn_hinew |
---|
365 | ELSEWHERE |
---|
366 | ht_i_new(:,:) = 0._wp |
---|
367 | END WHERE |
---|
368 | |
---|
369 | IF( ln_frazil ) THEN |
---|
370 | ztwogp = 2._wp * rho0 / ( grav * 0.3_wp * ( rho0 - rhoi ) ) ! reduced grav |
---|
371 | ! |
---|
372 | DO_2D( 0, 0, 0, 0 ) |
---|
373 | IF ( qlead(ji,jj) < 0._wp ) THEN ! cooling |
---|
374 | ! -- Wind stress -- ! |
---|
375 | ztaux = ( utau_ice(ji-1,jj ) * umask(ji-1,jj ,1) + utau_ice(ji,jj) * umask(ji,jj,1) ) * 0.5_wp |
---|
376 | ztauy = ( vtau_ice(ji ,jj-1) * vmask(ji ,jj-1,1) + vtau_ice(ji,jj) * vmask(ji,jj,1) ) * 0.5_wp |
---|
377 | ! Square root of wind stress |
---|
378 | ztenagm = SQRT( SQRT( ztaux * ztaux + ztauy * ztauy ) ) |
---|
379 | |
---|
380 | ! -- Frazil ice velocity -- ! |
---|
381 | rswitch = MAX( 0._wp, SIGN( 1._wp , ztenagm - epsi10 ) ) |
---|
382 | zvfrx = rswitch * zgamafr * zsqcd * ztaux / MAX( ztenagm, epsi10 ) |
---|
383 | zvfry = rswitch * zgamafr * zsqcd * ztauy / MAX( ztenagm, epsi10 ) |
---|
384 | |
---|
385 | ! -- Pack ice velocity -- ! |
---|
386 | zvgx = ( u_ice(ji-1,jj ) * umask(ji-1,jj ,1) + u_ice(ji,jj) * umask(ji,jj,1) ) * 0.5_wp |
---|
387 | zvgy = ( v_ice(ji ,jj-1) * vmask(ji ,jj-1,1) + v_ice(ji,jj) * vmask(ji,jj,1) ) * 0.5_wp |
---|
388 | |
---|
389 | ! -- Relative frazil/pack ice velocity -- ! |
---|
390 | rswitch = MAX( 0._wp, SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) |
---|
391 | zvrel2 = MAX( (zvfrx - zvgx)*(zvfrx - zvgx) + (zvfry - zvgy)*(zvfry - zvgy), 0.15_wp*0.15_wp ) * rswitch |
---|
392 | |
---|
393 | ! -- fraction of frazil ice -- ! |
---|
394 | fraz_frac(ji,jj) = rswitch * ( TANH( rn_Cfraz * ( SQRT(zvrel2) - rn_vfraz ) ) + 1._wp ) * 0.5_wp * rn_maxfraz |
---|
395 | |
---|
396 | ! -- new ice thickness (iterative loop) -- ! |
---|
397 | ht_i_new(ji,jj) = zhicrit + ( zhicrit + 0.1_wp ) & |
---|
398 | & / ( ( zhicrit + 0.1_wp ) * ( zhicrit + 0.1_wp ) - zhicrit * zhicrit ) * ztwogp * zvrel2 |
---|
399 | iter = 1 |
---|
400 | DO WHILE ( iter < 20 ) |
---|
401 | zf = ( ht_i_new(ji,jj) - zhicrit ) * ( ht_i_new(ji,jj) * ht_i_new(ji,jj) - zhicrit * zhicrit ) - & |
---|
402 | & ht_i_new(ji,jj) * zhicrit * ztwogp * zvrel2 |
---|
403 | zfp = ( ht_i_new(ji,jj) - zhicrit ) * ( 3.0_wp * ht_i_new(ji,jj) + zhicrit ) - zhicrit * ztwogp * zvrel2 |
---|
404 | |
---|
405 | ht_i_new(ji,jj) = ht_i_new(ji,jj) - zf / MAX( zfp, epsi20 ) |
---|
406 | iter = iter + 1 |
---|
407 | END DO |
---|
408 | ! |
---|
409 | ! bound ht_i_new (though I don't see why it should be necessary) |
---|
410 | ht_i_new(ji,jj) = MAX( 0.01_wp, MIN( ht_i_new(ji,jj), hi_max(jpl) ) ) |
---|
411 | ! |
---|
412 | ELSE |
---|
413 | ht_i_new(ji,jj) = 0._wp |
---|
414 | ENDIF |
---|
415 | ! |
---|
416 | END_2D |
---|
417 | ! |
---|
418 | CALL lbc_lnk( 'icethd_frazil', fraz_frac, 'T', 1.0_wp, ht_i_new, 'T', 1.0_wp ) |
---|
419 | |
---|
420 | ENDIF |
---|
421 | END SUBROUTINE ice_thd_frazil |
---|
422 | |
---|
423 | |
---|
424 | SUBROUTINE ice_thd_do_init |
---|
425 | !!----------------------------------------------------------------------- |
---|
426 | !! *** ROUTINE ice_thd_do_init *** |
---|
427 | !! |
---|
428 | !! ** Purpose : Physical constants and parameters associated with |
---|
429 | !! ice growth in the leads |
---|
430 | !! |
---|
431 | !! ** Method : Read the namthd_do namelist and check the parameters |
---|
432 | !! called at the first timestep (nit000) |
---|
433 | !! |
---|
434 | !! ** input : Namelist namthd_do |
---|
435 | !!------------------------------------------------------------------- |
---|
436 | INTEGER :: ios ! Local integer |
---|
437 | !! |
---|
438 | NAMELIST/namthd_do/ rn_hinew, ln_frazil, rn_maxfraz, rn_vfraz, rn_Cfraz |
---|
439 | !!------------------------------------------------------------------- |
---|
440 | ! |
---|
441 | READ ( numnam_ice_ref, namthd_do, IOSTAT = ios, ERR = 901) |
---|
442 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namthd_do in reference namelist' ) |
---|
443 | READ ( numnam_ice_cfg, namthd_do, IOSTAT = ios, ERR = 902 ) |
---|
444 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namthd_do in configuration namelist' ) |
---|
445 | IF(lwm) WRITE( numoni, namthd_do ) |
---|
446 | ! |
---|
447 | IF(lwp) THEN ! control print |
---|
448 | WRITE(numout,*) |
---|
449 | WRITE(numout,*) 'ice_thd_do_init: Ice growth in open water' |
---|
450 | WRITE(numout,*) '~~~~~~~~~~~~~~~' |
---|
451 | WRITE(numout,*) ' Namelist namthd_do:' |
---|
452 | WRITE(numout,*) ' ice thickness for lateral accretion rn_hinew = ', rn_hinew |
---|
453 | WRITE(numout,*) ' Frazil ice thickness as a function of wind or not ln_frazil = ', ln_frazil |
---|
454 | WRITE(numout,*) ' Maximum proportion of frazil ice collecting at bottom rn_maxfraz = ', rn_maxfraz |
---|
455 | WRITE(numout,*) ' Threshold relative drift speed for collection of frazil rn_vfraz = ', rn_vfraz |
---|
456 | WRITE(numout,*) ' Squeezing coefficient for collection of frazil rn_Cfraz = ', rn_Cfraz |
---|
457 | ENDIF |
---|
458 | ! |
---|
459 | IF ( rn_hinew < rn_himin ) CALL ctl_stop( 'ice_thd_do_init : rn_hinew should be >= rn_himin' ) |
---|
460 | ! |
---|
461 | END SUBROUTINE ice_thd_do_init |
---|
462 | |
---|
463 | #else |
---|
464 | !!---------------------------------------------------------------------- |
---|
465 | !! Default option NO SI3 sea-ice model |
---|
466 | !!---------------------------------------------------------------------- |
---|
467 | #endif |
---|
468 | |
---|
469 | !!====================================================================== |
---|
470 | END MODULE icethd_do |
---|