source: NEMO/trunk/src/NST/agrif_top_interp.F90 @ 9788

Last change on this file since 9788 was 9788, checked in by jchanut, 2 years ago

Fixes top and agrif compilation issues, #1972

  • Property svn:keywords set to Id
File size: 11.0 KB
Line 
1MODULE agrif_top_interp
2   !!======================================================================
3   !!                   ***  MODULE  agrif_top_interp  ***
4   !! AGRIF: interpolation package for TOP
5   !!======================================================================
6   !! History :  2.0  !  ???
7   !!----------------------------------------------------------------------
8#if defined key_agrif && defined key_top
9   !!----------------------------------------------------------------------
10   !!   'key_agrif'                                              AGRIF zoom
11   !!   'key_top'                                           on-line tracers
12   !!----------------------------------------------------------------------
13   USE par_oce
14   USE oce
15   USE dom_oce     
16   USE agrif_oce
17   USE agrif_top_sponge
18   USE par_trc
19   USE trc
20   !
21   USE lib_mpp     ! MPP library
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC Agrif_trc, interptrn
27
28  !!----------------------------------------------------------------------
29   !! NEMO/NST 4.0 , NEMO Consortium (2018)
30   !! $Id$
31   !! Software governed by the CeCILL licence (./LICENSE)
32   !!----------------------------------------------------------------------
33CONTAINS
34
35   SUBROUTINE Agrif_trc
36      !!----------------------------------------------------------------------
37      !!                   ***  ROUTINE Agrif_trc  ***
38      !!----------------------------------------------------------------------
39      !
40      IF( Agrif_Root() )   RETURN
41      !
42      Agrif_SpecialValue    = 0._wp
43      Agrif_UseSpecialValue = .TRUE.
44      !
45      CALL Agrif_Bc_variable( trn_id, procname=interptrn )
46      Agrif_UseSpecialValue = .FALSE.
47      !
48   END SUBROUTINE Agrif_trc
49
50   SUBROUTINE interptrn( ptab, i1, i2, j1, j2, k1, k2, n1, n2, before, nb, ndir )
51      !!----------------------------------------------------------------------
52      !!                  *** ROUTINE interptrn ***
53      !!----------------------------------------------------------------------
54      REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2,n1:n2), INTENT(inout) ::   ptab
55      INTEGER                                     , INTENT(in   ) ::   i1, i2, j1, j2, k1, k2, n1, n2
56      LOGICAL                                     , INTENT(in   ) ::   before
57      INTEGER                                     , INTENT(in   ) ::   nb , ndir
58      !
59      INTEGER  ::   ji, jj, jk, jn, iref, jref, ibdy, jbdy   ! dummy loop indices
60      INTEGER  ::   imin, imax, jmin, jmax, N_in, N_out
61      REAL(wp) ::   zrhox, z1, z2, z3, z4, z5, z6, z7
62      LOGICAL :: western_side, eastern_side,northern_side,southern_side
63      ! vertical interpolation:
64      REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk,n1:n2) :: ptab_child
65      REAL(wp), DIMENSION(k1:k2,n1:n2-1) :: tabin
66      REAL(wp), DIMENSION(k1:k2) :: h_in
67      REAL(wp), DIMENSION(1:jpk) :: h_out
68      REAL(wp) :: h_diff
69
70      IF( before ) THEN         
71         DO jn = 1,jptra
72            DO jk=k1,k2
73               DO jj=j1,j2
74                 DO ji=i1,i2
75                       ptab(ji,jj,jk,jn) = trn(ji,jj,jk,jn)
76                 END DO
77              END DO
78           END DO
79        END DO
80
81# if defined key_vertical
82        DO jk=k1,k2
83           DO jj=j1,j2
84              DO ji=i1,i2
85                 ptab(ji,jj,jk,jptra+1) = tmask(ji,jj,jk) * e3t_n(ji,jj,jk) 
86              END DO
87           END DO
88        END DO
89# endif
90      ELSE
91
92         western_side  = (nb == 1).AND.(ndir == 1)   ;   eastern_side  = (nb == 1).AND.(ndir == 2)
93         southern_side = (nb == 2).AND.(ndir == 1)   ;   northern_side = (nb == 2).AND.(ndir == 2)
94
95# if defined key_vertical             
96         DO jj=j1,j2
97            DO ji=i1,i2
98               iref = ji
99               jref = jj
100               if(western_side) iref=MAX(2,ji)
101               if(eastern_side) iref=MIN(nlci-1,ji)
102               if(southern_side) jref=MAX(2,jj)
103               if(northern_side) jref=MIN(nlcj-1,jj)
104               N_in = 0
105               DO jk=k1,k2 !k2 = jpk of parent grid
106                  IF (ptab(ji,jj,jk,n2) == 0) EXIT
107                  N_in = N_in + 1
108                  tabin(jk,:) = ptab(ji,jj,jk,n1:n2-1)
109                  h_in(N_in) = ptab(ji,jj,jk,n2)
110               END DO
111               N_out = 0
112               DO jk=1,jpk ! jpk of child grid
113                  IF (tmask(iref,jref,jk) == 0) EXIT
114                  N_out = N_out + 1
115                  h_out(jk) = e3t_n(iref,jref,jk)
116               ENDDO
117               IF (N_in > 0) THEN
118                  DO jn=1,jptra
119                     call reconstructandremap(tabin(1:N_in,jn),h_in,ptab_child(ji,jj,1:N_out,jn),h_out,N_in,N_out)
120                  ENDDO
121               ENDIF
122            ENDDO
123         ENDDO
124# else
125         ptab_child(i1:i2,j1:j2,1:jpk,1:jptra) = ptab(i1:i2,j1:j2,1:jpk,1:jptra)
126# endif
127         !
128         DO jn=1, jptra
129            tra(i1:i2,j1:j2,1:jpk,jn)=ptab_child(i1:i2,j1:j2,1:jpk,jn)*tmask(i1:i2,j1:j2,1:jpk) 
130         END DO
131
132         IF ( .NOT.lk_agrif_clp ) THEN 
133            !
134            zrhox = Agrif_Rhox()
135            z1 = ( zrhox - 1. ) * 0.5
136            z3 = ( zrhox - 1. ) / ( zrhox + 1. )
137            z6 = 2. * ( zrhox - 1. ) / ( zrhox + 1. )
138            z7 =    - ( zrhox - 1. ) / ( zrhox + 3. )
139            !
140            z2 = 1. - z1
141            z4 = 1. - z3
142            z5 = 1. - z6 - z7
143            !
144            imin = i1 ; imax = i2
145            jmin = j1 ; jmax = j2
146            !
147            ! Remove CORNERS
148            IF((nbondj == -1).OR.(nbondj == 2)) jmin = 2 + nbghostcells
149            IF((nbondj == +1).OR.(nbondj == 2)) jmax = nlcj - nbghostcells - 1
150            IF((nbondi == -1).OR.(nbondi == 2)) imin = 1 + nbghostcells
151            IF((nbondi == +1).OR.(nbondi == 2)) imax = nlci - nbghostcells - 1     
152            !
153            IF( eastern_side ) THEN
154               ibdy = nlci-nbghostcells
155               DO jn = 1, jptra
156                  tra(ibdy+1,jmin:jmax,k1:k2,jn) = z1 * ptab_child(ibdy+1,jmin:jmax,k1:k2,jn) + z2 * ptab_child(ibdy,jmin:jmax,k1:k2,jn)
157                  DO jk = 1, jpkm1
158                     DO jj = jmin,jmax
159                        IF( umask(ibdy-1,jj,jk) == 0._wp ) THEN
160                           tra(ibdy,jj,jk,jn) = tra(ibdy+1,jj,jk,jn) * tmask(ibdy,jj,jk)
161                        ELSE
162                           tra(ibdy,jj,jk,jn)=(z4*tra(ibdy+1,jj,jk,jn)+z3*tra(ibdy-1,jj,jk,jn))*tmask(ibdy,jj,jk)
163                           IF( un(ibdy-1,jj,jk) > 0._wp ) THEN
164                              tra(ibdy,jj,jk,jn)=( z6*tra(ibdy-1,jj,jk,jn)+z5*tra(ibdy+1,jj,jk,jn) & 
165                                                 + z7*tra(ibdy-2,jj,jk,jn) ) * tmask(ibdy,jj,jk)
166                           ENDIF
167                        ENDIF
168                     END DO
169                  END DO
170                  ! Restore ghost points:
171                  tra(ibdy+1,jmin:jmax,k1:k2,jn) = ptab_child(ibdy+1,jmin:jmax,k1:k2,jn) * tmask(ibdy+1,jmin:jmax,k1:k2)
172               END DO
173            ENDIF
174            !
175            IF( northern_side ) THEN
176               jbdy = nlcj-nbghostcells         
177               DO jn = 1, jptra
178                  tra(imin:imax,jbdy+1,k1:k2,jn) = z1 * ptab_child(imin:imax,jbdy+1,k1:k2,jn) + z2 * ptab_child(imin:imax,jbdy,k1:k2,jn)
179                  DO jk = 1, jpkm1
180                     DO ji = imin,imax
181                        IF( vmask(ji,jbdy-1,jk) == 0._wp ) THEN
182                           tra(ji,jbdy,jk,jn) = tra(ji,jbdy+1,jk,jn) * tmask(ji,jbdy,jk)
183                        ELSE
184                           tra(ji,jbdy,jk,jn)=(z4*tra(ji,jbdy+1,jk,jn)+z3*tra(ji,jbdy-1,jk,jn))*tmask(ji,jbdy,jk)       
185                           IF (vn(ji,jbdy-1,jk) > 0._wp ) THEN
186                              tra(ji,jbdy,jk,jn)=( z6*tra(ji,jbdy-1,jk,jn)+z5*tra(ji,jbdy+1,jk,jn)  &
187                                                 + z7*tra(ji,jbdy-2,jk,jn) ) * tmask(ji,jbdy,jk)
188                           ENDIF
189                        ENDIF
190                     END DO
191                  END DO
192                  ! Restore ghost points:
193                  tra(imin:imax,jbdy+1,k1:k2,jn) = ptab_child(imin:imax,jbdy+1,k1:k2,jn) * tmask(imin:imax,jbdy+1,k1:k2)
194               END DO
195            ENDIF
196            !
197            IF( western_side ) THEN   
198               ibdy = 1+nbghostcells       
199               DO jn = 1, jptra
200                  tra(ibdy-1,jmin:jmax,k1:k2,jn) = z1 * ptab_child(ibdy-1,jmin:jmax,k1:k2,jn) + z2 * ptab_child(ibdy,jmin:jmax,k1:k2,jn)
201                  DO jk = 1, jpkm1
202                     DO jj = jmin,jmax
203                        IF( umask(ibdy,jj,jk) == 0._wp ) THEN
204                           tra(ibdy,jj,jk,jn) = tra(ibdy-1,jj,jk,jn) * tmask(ibdy,jj,jk)
205                        ELSE
206                           tra(ibdy,jj,jk,jn)=(z4*tra(ibdy-1,jj,jk,jn)+z3*tra(ibdy+1,jj,jk,jn))*tmask(ibdy,jj,jk)       
207                           IF( un(ibdy,jj,jk) < 0._wp ) THEN
208                              tra(ibdy,jj,jk,jn)=(z6*tra(ibdy+1,jj,jk,jn)+z5*tra(ibdy-1,jj,jk,jn)+z7*tra(ibdy+2,jj,jk,jn))*tmask(ibdy,jj,jk)
209                           ENDIF
210                        ENDIF
211                     END DO
212                  END DO
213                  ! Restore ghost points:
214                  tra(ibdy-1,jmin:jmax,k1:k2,jn) = ptab_child(ibdy-1,jmin:jmax,k1:k2,jn) * tmask(ibdy-1,jmin:jmax,k1:k2)
215               END DO
216            ENDIF
217            !
218            IF( southern_side ) THEN 
219               jbdy=1+nbghostcells       
220               DO jn = 1, jptra
221                  tra(imin:imax,jbdy-1,k1:k2,jn) = z1 * ptab_child(imin:imax,jbdy-1,k1:k2,jn) + z2 * ptab_child(imin:imax,jbdy,k1:k2,jn)
222                  DO jk = 1, jpk     
223                     DO ji=imin,imax
224                        IF( vmask(ji,jbdy,jk) == 0._wp ) THEN
225                           tra(ji,jbdy,jk,jn)=tra(ji,jbdy-1,jk,jn) * tmask(ji,jbdy,jk)
226                        ELSE
227                           tra(ji,jbdy,jk,jn)=(z4*tra(ji,jbdy-1,jk,jn)+z3*tra(ji,jbdy+1,jk,jn))*tmask(ji,jbdy,jk)
228                           IF( vn(ji,jbdy,jk) < 0._wp ) THEN
229                              tra(ji,jbdy,jk,jn)=(z6*tra(ji,jbdy+1,jk,jn)+z5*tra(ji,jbdy-1,jk,jn)+z7*tra(ji,jbdy+2,jk,jn))*tmask(ji,jbdy,jk)
230                           ENDIF
231                        ENDIF
232                     END DO
233                  END DO
234                  ! Restore ghost points:
235                  tra(imin:imax,jbdy-1,k1:k2,jn) = tra(imin:imax,jbdy-1,k1:k2,jn) * tmask(imin:imax,jbdy-1,k1:k2)
236               END DO
237            ENDIF
238            !
239         ENDIF
240      ENDIF
241      !
242   END SUBROUTINE interptrn
243
244#else
245   !!----------------------------------------------------------------------
246   !!   Empty module                                           no TOP AGRIF
247   !!----------------------------------------------------------------------
248CONTAINS
249   SUBROUTINE Agrif_TOP_Interp_empty
250      !!---------------------------------------------
251      !!   *** ROUTINE agrif_Top_Interp_empty ***
252      !!---------------------------------------------
253      WRITE(*,*)  'agrif_top_interp : You should not have seen this print! error?'
254   END SUBROUTINE Agrif_TOP_Interp_empty
255#endif
256
257   !!======================================================================
258END MODULE agrif_top_interp
Note: See TracBrowser for help on using the repository browser.