| 1 | MODULE bdytra |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE bdytra *** |
|---|
| 4 | !! Ocean tracers: Apply boundary conditions for tracers |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 1.0 ! 2005-01 (J. Chanut, A. Sellar) Original code |
|---|
| 7 | !! 3.0 ! 2008-04 (NEMO team) add in the reference version |
|---|
| 8 | !! 3.4 ! 2011 (D. Storkey) rewrite in preparation for OBC-BDY merge |
|---|
| 9 | !! 3.5 ! 2012 (S. Mocavero, I. Epicoco) Optimization of BDY communications |
|---|
| 10 | !! 4.0 ! 2016 (T. Lovato) Generalize OBC structure |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | !! bdy_tra : Apply open boundary conditions & damping to T and S |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | USE oce ! ocean dynamics and tracers variables |
|---|
| 15 | USE dom_oce ! ocean space and time domain variables |
|---|
| 16 | USE bdy_oce ! ocean open boundary conditions |
|---|
| 17 | USE bdylib ! for orlanski library routines |
|---|
| 18 | ! |
|---|
| 19 | USE in_out_manager ! I/O manager |
|---|
| 20 | USE lib_mpp, ONLY: jpfillnothing |
|---|
| 21 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 22 | USE lib_mpp, ONLY: ctl_stop |
|---|
| 23 | USE timing ! Timing |
|---|
| 24 | |
|---|
| 25 | IMPLICIT NONE |
|---|
| 26 | PRIVATE |
|---|
| 27 | |
|---|
| 28 | ! Local structure to rearrange tracers data |
|---|
| 29 | TYPE, PUBLIC :: ztrabdy |
|---|
| 30 | REAL(wp), POINTER, DIMENSION(:,:) :: tra |
|---|
| 31 | END TYPE |
|---|
| 32 | |
|---|
| 33 | PUBLIC bdy_tra ! called in tranxt.F90 |
|---|
| 34 | PUBLIC bdy_tra_dmp ! called in step.F90 |
|---|
| 35 | |
|---|
| 36 | !!---------------------------------------------------------------------- |
|---|
| 37 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 38 | !! $Id$ |
|---|
| 39 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 40 | !!---------------------------------------------------------------------- |
|---|
| 41 | CONTAINS |
|---|
| 42 | |
|---|
| 43 | SUBROUTINE bdy_tra( kt, Kbb, pts, Kaa ) |
|---|
| 44 | !!---------------------------------------------------------------------- |
|---|
| 45 | !! *** SUBROUTINE bdy_tra *** |
|---|
| 46 | !! |
|---|
| 47 | !! ** Purpose : - Apply open boundary conditions for temperature and salinity |
|---|
| 48 | !! |
|---|
| 49 | !!---------------------------------------------------------------------- |
|---|
| 50 | INTEGER , INTENT(in) :: kt ! Main time step counter |
|---|
| 51 | INTEGER , INTENT(in) :: Kbb, Kaa ! time level indices |
|---|
| 52 | REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts ! tracer fields |
|---|
| 53 | ! |
|---|
| 54 | INTEGER :: ib_bdy, jn, igrd, ir ! Loop indeces |
|---|
| 55 | TYPE(ztrabdy), DIMENSION(jpts) :: zdta ! Temporary data structure |
|---|
| 56 | LOGICAL :: llrim0 ! indicate if rim 0 is treated |
|---|
| 57 | LOGICAL, DIMENSION(8) :: llsend1, llrecv1 ! indicate how communications are to be carried out |
|---|
| 58 | !!---------------------------------------------------------------------- |
|---|
| 59 | igrd = 1 |
|---|
| 60 | llsend1(:) = .false. ; llrecv1(:) = .false. |
|---|
| 61 | DO ir = 1, 0, -1 ! treat rim 1 before rim 0 |
|---|
| 62 | IF( ir == 0 ) THEN ; llrim0 = .TRUE. |
|---|
| 63 | ELSE ; llrim0 = .FALSE. |
|---|
| 64 | ENDIF |
|---|
| 65 | DO ib_bdy=1, nb_bdy |
|---|
| 66 | ! |
|---|
| 67 | zdta(1)%tra => dta_bdy(ib_bdy)%tem |
|---|
| 68 | zdta(2)%tra => dta_bdy(ib_bdy)%sal |
|---|
| 69 | ! |
|---|
| 70 | DO jn = 1, jpts |
|---|
| 71 | ! |
|---|
| 72 | SELECT CASE( cn_tra(ib_bdy) ) |
|---|
| 73 | CASE('none' ) ; CYCLE |
|---|
| 74 | CASE('frs' ) ! treat the whole boundary at once |
|---|
| 75 | IF( ir == 0 ) CALL bdy_frs ( idx_bdy(ib_bdy), pts(:,:,:,jn,Kaa), zdta(jn)%tra ) |
|---|
| 76 | CASE('specified' ) ! treat the whole rim at once |
|---|
| 77 | IF( ir == 0 ) CALL bdy_spe ( idx_bdy(ib_bdy), pts(:,:,:,jn,Kaa), zdta(jn)%tra ) |
|---|
| 78 | CASE('neumann' ) ; CALL bdy_nmn ( idx_bdy(ib_bdy), igrd , pts(:,:,:,jn,Kaa), llrim0 ) ! tsa masked |
|---|
| 79 | CASE('orlanski' ) ; CALL bdy_orl ( idx_bdy(ib_bdy), pts(:,:,:,jn,Kbb), pts(:,:,:,jn,Kaa), zdta(jn)%tra, & |
|---|
| 80 | & llrim0, ll_npo=.FALSE. ) |
|---|
| 81 | CASE('orlanski_npo') ; CALL bdy_orl ( idx_bdy(ib_bdy), pts(:,:,:,jn,Kbb), pts(:,:,:,jn,Kaa), zdta(jn)%tra, & |
|---|
| 82 | & llrim0, ll_npo=.TRUE. ) |
|---|
| 83 | CASE('runoff' ) ; CALL bdy_rnf ( idx_bdy(ib_bdy), pts(:,:,:,jn,Kaa), jn, llrim0 ) |
|---|
| 84 | CASE DEFAULT ; CALL ctl_stop( 'bdy_tra : unrecognised option for open boundaries for T and S' ) |
|---|
| 85 | END SELECT |
|---|
| 86 | ! |
|---|
| 87 | END DO |
|---|
| 88 | END DO |
|---|
| 89 | ! |
|---|
| 90 | IF( nn_hls > 1 .AND. ir == 1 ) CYCLE ! at least 2 halos will be corrected -> no need to correct rim 1 before rim 0 |
|---|
| 91 | IF( nn_hls == 1 ) THEN ; llsend1(:) = .false. ; llrecv1(:) = .false. ; ENDIF |
|---|
| 92 | DO ib_bdy=1, nb_bdy |
|---|
| 93 | SELECT CASE( cn_tra(ib_bdy) ) |
|---|
| 94 | CASE('neumann','runoff') |
|---|
| 95 | llsend1(:) = llsend1(:) .OR. lsend_bdyint(ib_bdy,1,:,ir) ! possibly every direction, T points |
|---|
| 96 | llrecv1(:) = llrecv1(:) .OR. lrecv_bdyint(ib_bdy,1,:,ir) ! possibly every direction, T points |
|---|
| 97 | CASE('orlanski', 'orlanski_npo') |
|---|
| 98 | llsend1(:) = llsend1(:) .OR. lsend_bdyolr(ib_bdy,1,:,ir) ! possibly every direction, T points |
|---|
| 99 | llrecv1(:) = llrecv1(:) .OR. lrecv_bdyolr(ib_bdy,1,:,ir) ! possibly every direction, T points |
|---|
| 100 | END SELECT |
|---|
| 101 | END DO |
|---|
| 102 | IF( ANY(llsend1) .OR. ANY(llrecv1) ) THEN ! if need to send/recv in at least one direction |
|---|
| 103 | CALL lbc_lnk( 'bdytra', pts(:,:,:,jn,Kaa), 'T', 1.0_wp, kfillmode=jpfillnothing ,lsend=llsend1, lrecv=llrecv1 ) |
|---|
| 104 | ENDIF |
|---|
| 105 | ! |
|---|
| 106 | END DO ! ir |
|---|
| 107 | ! |
|---|
| 108 | END SUBROUTINE bdy_tra |
|---|
| 109 | |
|---|
| 110 | |
|---|
| 111 | SUBROUTINE bdy_rnf( idx, pt, jpa, llrim0 ) |
|---|
| 112 | !!---------------------------------------------------------------------- |
|---|
| 113 | !! *** SUBROUTINE bdy_rnf *** |
|---|
| 114 | !! |
|---|
| 115 | !! ** Purpose : Specialized routine to apply TRA runoff values at OBs: |
|---|
| 116 | !! - duplicate the neighbour value for the temperature |
|---|
| 117 | !! - specified to 0.1 PSU for the salinity |
|---|
| 118 | !! |
|---|
| 119 | !!---------------------------------------------------------------------- |
|---|
| 120 | TYPE(OBC_INDEX), INTENT(in) :: idx ! OBC indices |
|---|
| 121 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) :: pt ! tracer trend |
|---|
| 122 | INTEGER, INTENT(in) :: jpa ! TRA index |
|---|
| 123 | LOGICAL, INTENT(in) :: llrim0 ! indicate if rim 0 is treated |
|---|
| 124 | ! |
|---|
| 125 | INTEGER :: ib, ii, ij, igrd ! dummy loop indices |
|---|
| 126 | !!---------------------------------------------------------------------- |
|---|
| 127 | ! |
|---|
| 128 | igrd = 1 ! Everything is at T-points here |
|---|
| 129 | IF( jpa == jp_tem ) THEN |
|---|
| 130 | CALL bdy_nmn( idx, igrd, pt, llrim0 ) |
|---|
| 131 | ELSE IF( jpa == jp_sal ) THEN |
|---|
| 132 | IF( .NOT. llrim0 ) RETURN |
|---|
| 133 | DO ib = 1, idx%nblenrim(igrd) ! if llrim0 then treat the whole rim |
|---|
| 134 | ii = idx%nbi(ib,igrd) |
|---|
| 135 | ij = idx%nbj(ib,igrd) |
|---|
| 136 | pt(ii,ij,1:jpkm1) = 0.1 * tmask(ii,ij,1:jpkm1) |
|---|
| 137 | END DO |
|---|
| 138 | ENDIF |
|---|
| 139 | ! |
|---|
| 140 | END SUBROUTINE bdy_rnf |
|---|
| 141 | |
|---|
| 142 | |
|---|
| 143 | SUBROUTINE bdy_tra_dmp( kt, Kbb, pts, Krhs ) |
|---|
| 144 | !!---------------------------------------------------------------------- |
|---|
| 145 | !! *** SUBROUTINE bdy_tra_dmp *** |
|---|
| 146 | !! |
|---|
| 147 | !! ** Purpose : Apply damping for tracers at open boundaries. |
|---|
| 148 | !! |
|---|
| 149 | !!---------------------------------------------------------------------- |
|---|
| 150 | INTEGER , INTENT(in) :: kt ! time step |
|---|
| 151 | INTEGER , INTENT(in) :: Kbb, Krhs ! time level indices |
|---|
| 152 | REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts ! active tracers and RHS of tracer equation |
|---|
| 153 | ! |
|---|
| 154 | REAL(wp) :: zwgt ! boundary weight |
|---|
| 155 | REAL(wp) :: zta, zsa, ztime |
|---|
| 156 | INTEGER :: ib, ik, igrd ! dummy loop indices |
|---|
| 157 | INTEGER :: ii, ij ! 2D addresses |
|---|
| 158 | INTEGER :: ib_bdy ! Loop index |
|---|
| 159 | !!---------------------------------------------------------------------- |
|---|
| 160 | IF( l_istiled .AND. ntile /= 1 ) RETURN ! Do only for the full domain |
|---|
| 161 | ! |
|---|
| 162 | IF( ln_timing ) CALL timing_start('bdy_tra_dmp') |
|---|
| 163 | ! |
|---|
| 164 | DO ib_bdy = 1, nb_bdy |
|---|
| 165 | IF( ln_tra_dmp(ib_bdy) ) THEN |
|---|
| 166 | igrd = 1 ! Everything is at T-points here |
|---|
| 167 | DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd) |
|---|
| 168 | ii = idx_bdy(ib_bdy)%nbi(ib,igrd) |
|---|
| 169 | ij = idx_bdy(ib_bdy)%nbj(ib,igrd) |
|---|
| 170 | zwgt = idx_bdy(ib_bdy)%nbd(ib,igrd) |
|---|
| 171 | DO ik = 1, jpkm1 |
|---|
| 172 | zta = zwgt * ( dta_bdy(ib_bdy)%tem(ib,ik) - pts(ii,ij,ik,jp_tem,Kbb) ) * tmask(ii,ij,ik) |
|---|
| 173 | zsa = zwgt * ( dta_bdy(ib_bdy)%sal(ib,ik) - pts(ii,ij,ik,jp_sal,Kbb) ) * tmask(ii,ij,ik) |
|---|
| 174 | pts(ii,ij,ik,jp_tem,Krhs) = pts(ii,ij,ik,jp_tem,Krhs) + zta |
|---|
| 175 | pts(ii,ij,ik,jp_sal,Krhs) = pts(ii,ij,ik,jp_sal,Krhs) + zsa |
|---|
| 176 | END DO |
|---|
| 177 | END DO |
|---|
| 178 | ENDIF |
|---|
| 179 | END DO |
|---|
| 180 | ! |
|---|
| 181 | IF( ln_timing ) CALL timing_stop('bdy_tra_dmp') |
|---|
| 182 | ! |
|---|
| 183 | END SUBROUTINE bdy_tra_dmp |
|---|
| 184 | |
|---|
| 185 | !!====================================================================== |
|---|
| 186 | END MODULE bdytra |
|---|
